lisp/org/org-src.el

   1 ;;; org-src.el --- Source code examples in Org
   2 ;;
   3 ;; Copyright (C) 2004-2016 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;;         Bastien Guerry <bzg@gnu.org>
   7 ;;         Dan Davison <davison at stats dot ox dot ac dot uk>
   8 ;; Keywords: outlines, hypermedia, calendar, wp
   9 ;; Homepage: http://orgmode.org
  10 ;;
  11 ;; This file is part of GNU Emacs.
  12 ;;
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26 ;;
  27 ;;; Commentary:
  28
  29 ;; This file contains the code dealing with source code examples in Org-mode.
  30
  31 ;;; Code:
  32
  33 (require 'org-macs)
  34 (require 'org-compat)
  35 (require 'ob-keys)
  36 (require 'ob-comint)
  37 (eval-when-compile
  38   (require 'cl))
  39
  40 (declare-function org-do-remove-indentation "org" (&optional n))
  41 (declare-function org-at-table.el-p "org" ())
  42 (declare-function org-in-src-block-p "org" (&optional inside))
  43 (declare-function org-in-block-p "org" (names))
  44 (declare-function org-get-indentation "org" (&optional line))
  45 (declare-function org-switch-to-buffer-other-window "org" (&rest args))
  46 (declare-function org-pop-to-buffer-same-window
  47                   "org-compat" (&optional buffer-or-name norecord label))
  48 (declare-function org-base-buffer "org" (buffer))
  49
  50 (defcustom org-edit-src-region-extra nil
  51   "Additional regexps to identify regions for editing with `org-edit-src-code'.
  52 For examples see the function `org-edit-src-find-region-and-lang'.
  53 The regular expression identifying the begin marker should end with a newline,
  54 and the regexp marking the end line should start with a newline, to make sure
  55 there are kept outside the narrowed region."
  56   :group 'org-edit-structure
  57   :type '(repeat
  58           (list
  59            (regexp :tag "begin regexp")
  60            (regexp :tag "end regexp")
  61            (choice :tag "language"
  62                    (string :tag "specify")
  63                    (integer :tag "from match group")
  64                    (const :tag "from `lang' element")
  65                    (const :tag "from `style' element")))))
  66
  67 (defcustom org-edit-src-turn-on-auto-save nil
  68   "Non-nil means turn `auto-save-mode' on when editing a source block.
  69 This will save the content of the source code editing buffer into
  70 a newly created file, not the base buffer for this source block.
  71
  72 If you want to regularly save the base buffer instead of the source
  73 code editing buffer, see `org-edit-src-auto-save-idle-delay' instead."
  74   :group 'org-edit-structure
  75   :version "24.4"
  76   :package-version '(Org . "8.0")
  77   :type 'boolean)
  78
  79 (defcustom org-edit-src-auto-save-idle-delay 0
  80   "Delay before saving a source code buffer back into its base buffer.
  81 When a positive integer N, save after N seconds of idle time.
  82 When 0 (the default), don't auto-save.
  83
  84 If you want to save the source code buffer itself, don't use this.
  85 Check `org-edit-src-turn-on-auto-save' instead."
  86   :group 'org-edit-structure
  87   :version "24.4"
  88   :package-version '(Org . "8.0")
  89   :type 'integer)
  90
  91 (defcustom org-coderef-label-format "(ref:%s)"
  92   "The default coderef format.
  93 This format string will be used to search for coderef labels in literal
  94 examples (EXAMPLE and SRC blocks).  The format can be overwritten in
  95 an individual literal example with the -l option, like
  96
  97 #+BEGIN_SRC pascal +n -r -l \"((%s))\"
  98 ...
  99 #+END_SRC
 100
 101 If you want to use this for HTML export, make sure that the format does
 102 not introduce special font-locking, and avoid the HTML special
 103 characters `<', `>', and `&'.  The reason for this restriction is that
 104 the labels are searched for only after htmlize has done its job."
 105   :group 'org-edit-structure ; FIXME this is not in the right group
 106   :type 'string)
 107
 108 (defcustom org-edit-fixed-width-region-mode 'artist-mode
 109   "The mode that should be used to edit fixed-width regions.
 110 These are the regions where each line starts with a colon."
 111   :group 'org-edit-structure
 112   :type '(choice
 113           (const artist-mode)
 114           (const picture-mode)
 115           (const fundamental-mode)
 116           (function :tag "Other (specify)")))
 117
 118 (defcustom org-src-preserve-indentation nil
 119   "If non-nil preserve leading whitespace characters on export.
 120 If non-nil leading whitespace characters in source code blocks
 121 are preserved on export, and when switching between the org
 122 buffer and the language mode edit buffer.  If this variable is nil
 123 then, after editing with \\[org-edit-src-code], the
 124 minimum (across-lines) number of leading whitespace characters
 125 are removed from all lines, and the code block is uniformly
 126 indented according to the value of `org-edit-src-content-indentation'."
 127   :group 'org-edit-structure
 128   :type 'boolean)
 129
 130 (defcustom org-edit-src-content-indentation 2
 131   "Indentation for the content of a source code block.
 132 This should be the number of spaces added to the indentation of the #+begin
 133 line in order to compute the indentation of the block content after
 134 editing it with \\[org-edit-src-code].  Has no effect if
 135 `org-src-preserve-indentation' is non-nil."
 136   :group 'org-edit-structure
 137   :type 'integer)
 138
 139 (defvar org-src-strip-leading-and-trailing-blank-lines nil
 140   "If non-nil, blank lines are removed when exiting the code edit buffer.")
 141
 142 (defcustom org-edit-src-persistent-message t
 143   "Non-nil means show persistent exit help message while editing src examples.
 144 The message is shown in the header-line, which will be created in the
 145 first line of the window showing the editing buffer."
 146   :group 'org-edit-structure
 147   :type 'boolean)
 148
 149 (defcustom org-src-window-setup 'reorganize-frame
 150   "How the source code edit buffer should be displayed.
 151 Possible values for this option are:
 152
 153 current-window    Show edit buffer in the current window, keeping all other
 154                   windows.
 155 other-window      Use `switch-to-buffer-other-window' to display edit buffer.
 156 reorganize-frame  Show only two windows on the current frame, the current
 157                   window and the edit buffer.  When exiting the edit buffer,
 158                   return to one window.
 159 other-frame       Use `switch-to-buffer-other-frame' to display edit buffer.
 160                   Also, when exiting the edit buffer, kill that frame."
 161   :group 'org-edit-structure
 162   :type '(choice
 163           (const current-window)
 164           (const other-frame)
 165           (const other-window)
 166           (const reorganize-frame)))
 167
 168 (defvar org-src-mode-hook nil
 169   "Hook run after Org switched a source code snippet to its Emacs mode.
 170 This hook will run
 171
 172 - when editing a source code snippet with `\\[org-src-mode-map]'.
 173 - When formatting a source code snippet for export with htmlize.
 174
 175 You may want to use this hook for example to turn off `outline-minor-mode'
 176 or similar things which you want to have when editing a source code file,
 177 but which mess up the display of a snippet in Org exported files.")
 178
 179 (defcustom org-src-lang-modes
 180   '(("ocaml" . tuareg) ("elisp" . emacs-lisp) ("ditaa" . artist)
 181     ("asymptote" . asy) ("dot" . fundamental) ("sqlite" . sql)
 182     ("calc" . fundamental) ("C" . c) ("cpp" . c++) ("C++" . c++)
 183     ("screen" . shell-script))
 184   "Alist mapping languages to their major mode.
 185 The key is the language name, the value is the string that should
 186 be inserted as the name of the major mode.  For many languages this is
 187 simple, but for language where this is not the case, this variable
 188 provides a way to simplify things on the user side.
 189 For example, there is no ocaml-mode in Emacs, but the mode to use is
 190 `tuareg-mode'."
 191   :group 'org-edit-structure
 192   :type '(repeat
 193           (cons
 194            (string "Language name")
 195            (symbol "Major mode"))))
 196
 197 ;;; Editing source examples
 198
 199 (defvar org-src-mode-map (make-sparse-keymap))
 200 (define-key org-src-mode-map "\C-c'" 'org-edit-src-exit)
 201 (define-key org-src-mode-map "\C-c\C-k" 'org-edit-src-abort)
 202 (define-key org-src-mode-map "\C-x\C-s" 'org-edit-src-save)
 203
 204 (defvar org-edit-src-force-single-line nil)
 205 (defvar org-edit-src-from-org-mode nil)
 206 (defvar org-edit-src-allow-write-back-p t)
 207 (defvar org-edit-src-picture nil)
 208 (defvar org-edit-src-beg-marker nil)
 209 (defvar org-edit-src-end-marker nil)
 210 (defvar org-edit-src-overlay nil)
 211 (defvar org-edit-src-block-indentation nil)
 212 (defvar org-edit-src-saved-temp-window-config nil)
 213
 214 (defcustom org-src-ask-before-returning-to-edit-buffer t
 215   "If nil, when org-edit-src code is used on a block that already
 216 has an active edit buffer, it will switch to that edit buffer
 217 immediately; otherwise it will ask whether you want to return to
 218 the existing edit buffer."
 219   :group 'org-edit-structure
 220   :version "24.4"
 221   :package-version '(Org . "8.0")
 222   :type 'boolean)
 223
 224 (defvar org-src-babel-info nil)
 225
 226 (define-minor-mode org-src-mode
 227   "Minor mode for language major mode buffers generated by org.
 228 This minor mode is turned on in two situations:
 229 - when editing a source code snippet with `\\[org-src-mode-map]'.
 230 - When formatting a source code snippet for export with htmlize.
 231 There is a mode hook, and keybindings for `org-edit-src-exit' and
 232 `org-edit-src-save'")
 233
 234 (defvar org-edit-src-code-timer nil)
 235 (defvar org-inhibit-startup)
 236
 237 (defun org-edit-src-code (&optional context code edit-buffer-name)
 238   "Edit the source CODE block at point.
 239 The code is copied to a separate buffer and the appropriate mode
 240 is turned on.  When done, exit with \\[org-edit-src-exit].  This will
 241 remove the original code in the Org buffer, and replace it with the
 242 edited version.  An optional argument CONTEXT is used by \\[org-edit-src-save]
 243 when calling this function.  See `org-src-window-setup' to configure
 244 the display of windows containing the Org buffer and the code buffer."
 245   (interactive)
 246   (if (not (or (org-in-block-p '("src" "example" "latex" "html"))
 247                (org-at-table.el-p)))
 248       (user-error "Not in a source code or example block")
 249     (unless (eq context 'save)
 250       (setq org-edit-src-saved-temp-window-config (current-window-configuration)))
 251     (let* ((mark (and (org-region-active-p) (mark)))
 252            (case-fold-search t)
 253            (info
 254             ;; If the src region consists in no lines, we insert a blank
 255             ;; line.
 256             (let* ((temp (org-edit-src-find-region-and-lang))
 257                    (beg (nth 0 temp))
 258                    (end (nth 1 temp)))
 259               (if (>= end beg) temp
 260                 (goto-char beg)
 261                 (insert "\n")
 262                 (org-edit-src-find-region-and-lang))))
 263            (full-info (org-babel-get-src-block-info 'light))
 264            (org-mode-p (derived-mode-p 'org-mode)) ;; derived-mode-p is reflexive
 265            (beg (make-marker))
 266            ;; Move marker with inserted text for case when src block is
 267            ;; just one empty line, i.e. beg == end.
 268            (end (copy-marker (make-marker) t))
 269            (allow-write-back-p (null code))
 270            block-nindent total-nindent ovl lang lang-f single buffer msg
 271            begline markline markcol line col transmitted-variables)
 272       (setq beg (move-marker beg (nth 0 info))
 273             end (move-marker end (nth 1 info))
 274             msg (if allow-write-back-p
 275                     "Edit, then exit with C-c ' (C-c and single quote) -- C-c C-k to abort"
 276                   "Exit with C-c ' (C-c and single quote) -- C-c C-k to abort")
 277             code (or code (buffer-substring-no-properties beg end))
 278             lang (or (cdr (assoc (nth 2 info) org-src-lang-modes))
 279                      (nth 2 info))
 280             lang (if (symbolp lang) (symbol-name lang) lang)
 281             single (nth 3 info)
 282             block-nindent (nth 5 info)
 283             lang-f (intern (concat lang "-mode"))
 284             begline (save-excursion (goto-char beg) (org-current-line))
 285             transmitted-variables
 286             `((org-edit-src-content-indentation
 287                ,org-edit-src-content-indentation)
 288               (org-edit-src-force-single-line ,single)
 289               (org-edit-src-from-org-mode ,org-mode-p)
 290               (org-edit-src-allow-write-back-p ,allow-write-back-p)
 291               (org-src-preserve-indentation ,org-src-preserve-indentation)
 292               (org-src-babel-info ,(org-babel-get-src-block-info 'light))
 293               (org-coderef-label-format
 294                ,(or (nth 4 info) org-coderef-label-format))
 295               (org-edit-src-beg-marker ,beg)
 296               (org-edit-src-end-marker ,end)
 297               (org-edit-src-block-indentation ,block-nindent)))
 298       (if (and mark (>= mark beg) (<= mark (1+ end)))
 299           (save-excursion (goto-char (min mark end))
 300                           (setq markline (org-current-line)
 301                                 markcol (current-column))))
 302       (if (equal lang-f 'table.el-mode)
 303           (setq lang-f (lambda ()
 304                          (text-mode)
 305                          (if (org-bound-and-true-p flyspell-mode)
 306                              (flyspell-mode -1))
 307                          (table-recognize)
 308                          (org-set-local 'org-edit-src-content-indentation 0))))
 309       (unless (functionp lang-f)
 310         (error "No such language mode: %s" lang-f))
 311       (save-excursion
 312         (if (> (point) end) (goto-char end))
 313         (setq line (org-current-line)
 314               col (current-column)))
 315       (if (and (setq buffer (org-edit-src-find-buffer beg end))
 316                (or (eq context 'save)
 317                    (if org-src-ask-before-returning-to-edit-buffer
 318                        (y-or-n-p "Return to existing edit buffer ([n] will revert changes)? ") t)))
 319           (org-src-switch-to-buffer buffer 'return)
 320         (when buffer
 321           (with-current-buffer buffer
 322             (if (boundp 'org-edit-src-overlay)
 323                 (delete-overlay org-edit-src-overlay)))
 324           (kill-buffer buffer))
 325         (setq buffer (generate-new-buffer
 326                       (or edit-buffer-name
 327                           (org-src-construct-edit-buffer-name (buffer-name) lang))))
 328         (setq ovl (make-overlay beg end))
 329         (overlay-put ovl 'edit-buffer buffer)
 330         (overlay-put ovl 'help-echo "Click with mouse-1 to switch to buffer editing this segment")
 331         (overlay-put ovl 'face 'secondary-selection)
 332         (overlay-put ovl
 333                      'keymap
 334                      (let ((map (make-sparse-keymap)))
 335                        (define-key map [mouse-1] 'org-edit-src-continue)
 336                        map))
 337         (overlay-put ovl :read-only "Leave me alone")
 338         (setq transmitted-variables
 339               (append transmitted-variables `((org-edit-src-overlay ,ovl))))
 340         (org-src-switch-to-buffer buffer 'edit)
 341         (if (eq single 'macro-definition)
 342             (setq code (replace-regexp-in-string "\\\\n" "\n" code t t)))
 343         (insert code)
 344         (remove-text-properties (point-min) (point-max)
 345                                 '(display nil invisible nil intangible nil))
 346         (unless (cadr (assq 'org-src-preserve-indentation transmitted-variables))
 347           (setq total-nindent (or (org-do-remove-indentation) 0)))
 348         (let ((org-inhibit-startup t))
 349           (condition-case e
 350               (funcall lang-f)
 351             (error
 352              (message "Language mode `%s' fails with: %S" lang-f (nth 1 e)))))
 353         (dolist (pair transmitted-variables)
 354           (org-set-local (car pair) (cadr pair)))
 355         ;; Remove protecting commas from visible part of buffer.
 356         (org-unescape-code-in-region (point-min) (point-max))
 357         (when markline
 358           (org-goto-line (1+ (- markline begline)))
 359           (org-move-to-column
 360            (if org-src-preserve-indentation markcol
 361              (max 0 (- markcol total-nindent))))
 362           (push-mark (point) 'no-message t)
 363           (setq deactivate-mark nil))
 364         (org-goto-line (1+ (- line begline)))
 365         (org-move-to-column
 366          (if org-src-preserve-indentation col (max 0 (- col total-nindent))))
 367         (org-src-mode)
 368         (set-buffer-modified-p nil)
 369         (setq buffer-file-name nil)
 370         (when org-edit-src-turn-on-auto-save
 371           (setq buffer-auto-save-file-name
 372                 (concat (make-temp-name "org-src-")
 373                         (format-time-string "-%Y-%d-%m") ".txt")))
 374         (and org-edit-src-persistent-message
 375              (org-set-local 'header-line-format msg))
 376         (let ((edit-prep-func (intern (concat "org-babel-edit-prep:" lang))))
 377           (when (fboundp edit-prep-func)
 378             (funcall edit-prep-func full-info)))
 379         (or org-edit-src-code-timer
 380             (zerop org-edit-src-auto-save-idle-delay)
 381             (setq org-edit-src-code-timer
 382                   (run-with-idle-timer
 383                    org-edit-src-auto-save-idle-delay t
 384                    (lambda ()
 385                      (cond
 386                       ((org-string-match-p "\\`\\*Org Src" (buffer-name))
 387                        (when (buffer-modified-p) (org-edit-src-save)))
 388                       ((not (org-some (lambda (b)
 389                                         (org-string-match-p "\\`\\*Org Src"
 390                                                             (buffer-name b)))
 391                                       (buffer-list)))
 392                        (cancel-timer org-edit-src-code-timer)
 393                        (setq org-edit-src-code-timer nil))))))))
 394       t)))
 395
 396 (defun org-edit-src-continue (e)
 397   "Continue editing source blocks." ;; Fixme: be more accurate
 398   (interactive "e")
 399   (mouse-set-point e)
 400   (let ((buf (get-char-property (point) 'edit-buffer)))
 401     (if buf (org-src-switch-to-buffer buf 'continue)
 402       (error "Something is wrong here"))))
 403
 404 (defun org-src-switch-to-buffer (buffer context)
 405   (case org-src-window-setup
 406     ('current-window
 407      (org-pop-to-buffer-same-window buffer))
 408     ('other-window
 409      (switch-to-buffer-other-window buffer))
 410     ('other-frame
 411      (case context
 412        ('exit
 413         (let ((frame (selected-frame)))
 414           (switch-to-buffer-other-frame buffer)
 415           (delete-frame frame)))
 416        ('save
 417         (kill-buffer (current-buffer))
 418         (org-pop-to-buffer-same-window buffer))
 419        (t
 420         (switch-to-buffer-other-frame buffer))))
 421     ('reorganize-frame
 422      (if (eq context 'edit) (delete-other-windows))
 423      (org-switch-to-buffer-other-window buffer)
 424      (if (eq context 'exit) (delete-other-windows)))
 425     ('switch-invisibly
 426      (set-buffer buffer))
 427     (t
 428      (message "Invalid value %s for org-src-window-setup"
 429               (symbol-name org-src-window-setup))
 430      (org-pop-to-buffer-same-window buffer))))
 431
 432 (defun org-src-construct-edit-buffer-name (org-buffer-name lang)
 433   "Construct the buffer name for a source editing buffer."
 434   (concat "*Org Src " org-buffer-name "[ " lang " ]*"))
 435
 436 (defun org-src-edit-buffer-p (&optional buffer)
 437   "Test whether BUFFER (or the current buffer if BUFFER is nil)
 438 is a source block editing buffer."
 439   (let ((buffer (org-base-buffer (or buffer (current-buffer)))))
 440     (and (buffer-name buffer)
 441          (string-match "\\`*Org Src " (buffer-name buffer))
 442          (local-variable-p 'org-edit-src-beg-marker buffer)
 443          (local-variable-p 'org-edit-src-end-marker buffer))))
 444
 445 (defun org-edit-src-find-buffer (beg end)
 446   "Find a source editing buffer that is already editing the region BEG to END."
 447   (catch 'exit
 448     (mapc
 449      (lambda (b)
 450        (with-current-buffer b
 451          (if (and (string-match "\\`*Org Src " (buffer-name))
 452                   (local-variable-p 'org-edit-src-beg-marker (current-buffer))
 453                   (local-variable-p 'org-edit-src-end-marker (current-buffer))
 454                   (equal beg org-edit-src-beg-marker)
 455                   (equal end org-edit-src-end-marker))
 456              (throw 'exit (current-buffer)))))
 457      (buffer-list))
 458     nil))
 459
 460 (defun org-edit-fixed-width-region ()
 461   "Edit the fixed-width ascii drawing at point.
 462 This must be a region where each line starts with a colon followed by
 463 a space character.
 464 An new buffer is created and the fixed-width region is copied into it,
 465 and the buffer is switched into `artist-mode' for editing.  When done,
 466 exit with \\[org-edit-src-exit].  The edited text will then replace
 467 the fragment in the Org-mode buffer."
 468   (interactive)
 469   (let ((line (org-current-line))
 470         (col (current-column))
 471         (case-fold-search t)
 472         (msg "Edit, then exit with C-c ' (C-c and single quote) -- C-c C-k to abort")
 473         (org-mode-p (derived-mode-p 'org-mode))
 474         (beg (make-marker))
 475         (end (make-marker))
 476         block-nindent ovl beg1 end1 code begline buffer)
 477     (beginning-of-line 1)
 478     (if (looking-at "[ \t]*[^:\n \t]")
 479         nil
 480       (if (looking-at "[ \t]*\\(\n\\|\\'\\)")
 481           (setq beg1 (point) end1 beg1)
 482         (save-excursion
 483           (if (re-search-backward "^[ \t]*[^: \t]" nil 'move)
 484               (setq beg1 (point-at-bol 2))
 485             (setq beg1 (point))))
 486         (save-excursion
 487           (if (re-search-forward "^[ \t]*[^: \t]" nil 'move)
 488               (setq end1 (1- (match-beginning 0)))
 489             (setq end1 (point))))
 490         (org-goto-line line))
 491       (setq beg (move-marker beg beg1)
 492             end (move-marker end end1)
 493             code (buffer-substring-no-properties beg end)
 494             begline (save-excursion (goto-char beg) (org-current-line)))
 495       (if (and (setq buffer (org-edit-src-find-buffer beg end))
 496                (y-or-n-p "Return to existing edit buffer ([n] will revert changes)? "))
 497           (org-pop-to-buffer-same-window buffer)
 498         (when buffer
 499           (with-current-buffer buffer
 500             (if (boundp 'org-edit-src-overlay)
 501                 (delete-overlay org-edit-src-overlay)))
 502           (kill-buffer buffer))
 503         (setq buffer (generate-new-buffer
 504                       (org-src-construct-edit-buffer-name
 505                        (buffer-name) "Fixed Width")))
 506         (setq ovl (make-overlay beg end))
 507         (overlay-put ovl 'face 'secondary-selection)
 508         (overlay-put ovl 'edit-buffer buffer)
 509         (overlay-put ovl 'help-echo "Click with mouse-1 to switch to buffer editing this segment")
 510         (overlay-put ovl 'face 'secondary-selection)
 511         (overlay-put ovl
 512                      'keymap
 513                      (let ((map (make-sparse-keymap)))
 514                        (define-key map [mouse-1] 'org-edit-src-continue)
 515                        map))
 516         (overlay-put ovl :read-only "Leave me alone")
 517         (org-pop-to-buffer-same-window buffer)
 518         (insert code)
 519         (remove-text-properties (point-min) (point-max)
 520                                 '(display nil invisible nil intangible nil))
 521         (setq block-nindent (or (org-do-remove-indentation) 0))
 522         (cond
 523          ((eq org-edit-fixed-width-region-mode 'artist-mode)
 524           (fundamental-mode)
 525           (artist-mode 1))
 526          (t (funcall org-edit-fixed-width-region-mode)))
 527         (set (make-local-variable 'org-edit-src-force-single-line) nil)
 528         (set (make-local-variable 'org-edit-src-from-org-mode) org-mode-p)
 529         (set (make-local-variable 'org-edit-src-picture) t)
 530         (goto-char (point-min))
 531         (while (re-search-forward "^[ \t]*: ?" nil t)
 532           (replace-match ""))
 533         (org-goto-line (1+ (- line begline)))
 534         (org-move-to-column (max 0 (- col block-nindent 2)))
 535         (org-set-local 'org-edit-src-beg-marker beg)
 536         (org-set-local 'org-edit-src-end-marker end)
 537         (org-set-local 'org-edit-src-overlay ovl)
 538         (org-set-local 'org-edit-src-block-indentation block-nindent)
 539         (org-set-local 'org-edit-src-content-indentation 0)
 540         (org-set-local 'org-src-preserve-indentation nil)
 541         (org-src-mode)
 542         (set-buffer-modified-p nil)
 543         (and org-edit-src-persistent-message
 544              (org-set-local 'header-line-format msg)))
 545       (message "%s" msg)
 546       t)))
 547
 548 (defun org-edit-src-find-region-and-lang ()
 549   "Find the region and language for a local edit.
 550 Return a list with beginning and end of the region, a string representing
 551 the language, a switch telling if the content should be in a single line."
 552   (let ((re-list
 553          (append
 554           org-edit-src-region-extra
 555           '(
 556             ("<src\\>[^<]*>[ \t]*\n?" "\n?[ \t]*</src>" lang)
 557             ("<literal\\>[^<]*>[ \t]*\n?" "\n?[ \t]*</literal>" style)
 558             ("<example>[ \t]*\n?" "\n?[ \t]*</example>" "fundamental")
 559             ("<lisp>[ \t]*\n?" "\n?[ \t]*</lisp>" "emacs-lisp")
 560             ("<perl>[ \t]*\n?" "\n?[ \t]*</perl>" "perl")
 561             ("<python>[ \t]*\n?" "\n?[ \t]*</python>" "python")
 562             ("<ruby>[ \t]*\n?" "\n?[ \t]*</ruby>" "ruby")
 563             ("^[ \t]*#\\+begin_src\\( \\([^ \t\n]+\\)\\)?.*\n" "\n[ \t]*#\\+end_src" 2)
 564             ("^[ \t]*#\\+begin_example.*\n" "\n[ \t]*#\\+end_example" "fundamental")
 565             ("^[ \t]*#\\+html:" "\n" "html" single-line)
 566             ("^[ \t]*#\\+begin_html.*\n" "\n[ \t]*#\\+end_html" "html")
 567             ("^[ \t]*#\\+latex:" "\n" "latex" single-line)
 568             ("^[ \t]*#\\+begin_latex.*\n" "\n[ \t]*#\\+end_latex" "latex")
 569             ("^[ \t]*#\\+ascii:" "\n" "fundamental" single-line)
 570             ("^[ \t]*#\\+begin_ascii.*\n" "\n[ \t]*#\\+end_ascii" "fundamental")
 571             ("^[ \t]*#\\+macro:[ \t]+\\S-+\\( \\|$\\)"
 572              "\n" "fundamental" macro-definition)
 573             )))
 574         (pos (point))
 575         re1 re2 single beg end lang lfmt match-re1 ind entry)
 576     (catch 'exit
 577       (while (setq entry (pop re-list))
 578         (setq re1 (car entry) re2 (nth 1 entry) lang (nth 2 entry)
 579               single (nth 3 entry))
 580         (save-excursion
 581           (if (or (looking-at re1)
 582                   (re-search-backward re1 nil t))
 583               (progn
 584                 (setq match-re1 (match-string 0))
 585                 (setq beg (match-end 0)
 586                       lang (org-edit-src-get-lang lang)
 587                       lfmt (org-edit-src-get-label-format match-re1)
 588                       ind (org-edit-src-get-indentation (match-beginning 0)))
 589                 (if (and (re-search-forward re2 nil t)
 590                          (>= (match-end 0) pos))
 591                     (throw 'exit (list beg (match-beginning 0)
 592                                        lang single lfmt ind))))
 593             (if (or (looking-at re2)
 594                     (re-search-forward re2 nil t))
 595                 (progn
 596                   (setq end (match-beginning 0))
 597                   (if (and (re-search-backward re1 nil t)
 598                            (<= (match-beginning 0) pos))
 599                       (progn
 600                         (setq lfmt (org-edit-src-get-label-format
 601                                     (match-string 0))
 602                               ind (org-edit-src-get-indentation
 603                                    (match-beginning 0)))
 604                         (throw 'exit
 605                                (list (match-end 0) end
 606                                      (org-edit-src-get-lang lang)
 607                                      single lfmt ind)))))))))
 608       (when (org-at-table.el-p)
 609         (re-search-backward "^[\t]*[^ \t|\\+]" nil t)
 610         (setq beg (1+ (point-at-eol)))
 611         (goto-char beg)
 612         (or (re-search-forward "^[\t]*[^ \t|\\+]" nil t)
 613             (progn (goto-char (point-max)) (newline)))
 614         (setq end (1- (point-at-bol)))
 615         (throw 'exit (list beg end 'table.el nil nil 0))))))
 616
 617 (defun org-edit-src-get-lang (lang)
 618   "Extract the src language."
 619   (let ((m (match-string 0)))
 620     (cond
 621      ((stringp lang) lang)
 622      ((integerp lang) (match-string lang))
 623      ((and (eq lang 'lang)
 624            (string-match "\\<lang=\"\\([^ \t\n\"]+\\)\"" m))
 625       (match-string 1 m))
 626      ((and (eq lang 'style)
 627            (string-match "\\<style=\"\\([^ \t\n\"]+\\)\"" m))
 628       (match-string 1 m))
 629      (t "fundamental"))))
 630
 631 (defun org-edit-src-get-label-format (s)
 632   "Extract the label format."
 633   (save-match-data
 634     (if (string-match "-l[ \t]+\\\\?\"\\([^\t\r\n\"]+\\)\\\\?\"" s)
 635         (match-string 1 s))))
 636
 637 (defun org-edit-src-get-indentation (pos)
 638   "Count leading whitespace characters on line."
 639   (save-match-data
 640     (goto-char pos)
 641     (org-get-indentation)))
 642
 643 (defun org-escape-code-in-region (beg end)
 644   "Escape lines between BEG and END.
 645 Escaping happens when a line starts with \"*\", \"#+\", \",*\" or
 646 \",#+\" by appending a comma to it."
 647   (interactive "r")
 648   (save-excursion
 649     (goto-char beg)
 650     (while (re-search-forward "^[ \t]*,?\\(\\*\\|#\\+\\)" end t)
 651       (replace-match ",\\1" nil nil nil 1))))
 652
 653 (defun org-escape-code-in-string (s)
 654   "Escape lines in string S.
 655 Escaping happens when a line starts with \"*\", \"#+\", \",*\" or
 656 \",#+\" by appending a comma to it."
 657   (replace-regexp-in-string "^[ \t]*,?\\(\\*\\|#\\+\\)" ",\\1" s nil nil 1))
 658
 659 (defun org-unescape-code-in-region (beg end)
 660   "Un-escape lines between BEG and END.
 661 Un-escaping happens by removing the first comma on lines starting
 662 with \",*\", \",#+\", \",,*\" and \",,#+\"."
 663   (interactive "r")
 664   (save-excursion
 665     (goto-char beg)
 666     (while (re-search-forward "^[ \t]*,?\\(,\\)\\(?:\\*\\|#\\+\\)" end t)
 667       (replace-match "" nil nil nil 1))))
 668
 669 (defun org-unescape-code-in-string (s)
 670   "Un-escape lines in string S.
 671 Un-escaping happens by removing the first comma on lines starting
 672 with \",*\", \",#+\", \",,*\" and \",,#+\"."
 673   (replace-regexp-in-string
 674    "^[ \t]*,?\\(,\\)\\(?:\\*\\|#\\+\\)" "" s nil nil 1))
 675
 676 (defun org-edit-src-exit (&optional context)
 677   "Exit special edit and protect problematic lines."
 678   (interactive)
 679   (unless (org-bound-and-true-p org-edit-src-from-org-mode)
 680     (error "This is not a sub-editing buffer, something is wrong"))
 681   (widen)
 682   (let* ((fixed-width-p (string-match "Fixed Width" (buffer-name)))
 683          (beg org-edit-src-beg-marker)
 684          (end org-edit-src-end-marker)
 685          (ovl org-edit-src-overlay)
 686          (bufstr (buffer-string))
 687          (buffer (current-buffer))
 688          (single (org-bound-and-true-p org-edit-src-force-single-line))
 689          (macro (eq single 'macro-definition))
 690          (total-nindent (+ (or org-edit-src-block-indentation 0)
 691                            org-edit-src-content-indentation))
 692          (preserve-indentation org-src-preserve-indentation)
 693          (allow-write-back-p (org-bound-and-true-p org-edit-src-allow-write-back-p))
 694          (delta 0) code line col indent)
 695     (when allow-write-back-p
 696       (unless preserve-indentation (untabify (point-min) (point-max)))
 697       (if org-src-strip-leading-and-trailing-blank-lines
 698           (save-excursion
 699             (goto-char (point-min))
 700             (if (looking-at "[ \t\n]*\n") (replace-match ""))
 701             (unless macro
 702               (if (re-search-forward "\n[ \t\n]*\\'" nil t) (replace-match ""))))))
 703     (setq line (if (org-bound-and-true-p org-edit-src-force-single-line)
 704                    1
 705                  (org-current-line))
 706           col (current-column))
 707     (when allow-write-back-p
 708       (when single
 709         (goto-char (point-min))
 710         (if (re-search-forward "\\s-+\\'" nil t) (replace-match ""))
 711         (goto-char (point-min))
 712         (let ((cnt 0))
 713           (while (re-search-forward "\n" nil t)
 714             (setq cnt (1+ cnt))
 715             (replace-match (if macro "\\n" " ") t t))
 716           (when (and macro (> cnt 0))
 717             (goto-char (point-max)) (insert "\\n")))
 718         (goto-char (point-min))
 719         (if (looking-at "\\s-*") (replace-match " ")))
 720       (when (and (org-bound-and-true-p org-edit-src-from-org-mode)
 721                  (not fixed-width-p))
 722         (org-escape-code-in-region (point-min) (point-max))
 723         (setq delta (+ delta
 724                        (save-excursion
 725                          (org-goto-line line)
 726                          (if (looking-at "[ \t]*\\(,,\\)?\\(\\*\\|#+\\)") 1
 727                            0)))))
 728       (when (org-bound-and-true-p org-edit-src-picture)
 729         (setq preserve-indentation nil)
 730         (untabify (point-min) (point-max))
 731         (goto-char (point-min))
 732         (while (re-search-forward "^" nil t)
 733           (replace-match ": ")))
 734       (unless (or single preserve-indentation (= total-nindent 0))
 735         (setq indent (make-string total-nindent ?\ ))
 736         (goto-char (point-min))
 737         (while (re-search-forward "\\(^\\).+" nil t)
 738           (replace-match indent nil nil nil 1)))
 739       (if (org-bound-and-true-p org-edit-src-picture)
 740           (setq total-nindent (+ total-nindent 2)))
 741       (setq code (buffer-string))
 742       (when (eq context 'save)
 743         (erase-buffer)
 744         (insert bufstr))
 745       (set-buffer-modified-p nil))
 746     (org-src-switch-to-buffer (marker-buffer beg) (or context 'exit))
 747     (if (eq context 'save) (save-buffer)
 748       (with-current-buffer buffer
 749         (set-buffer-modified-p nil))
 750       (kill-buffer buffer))
 751     (goto-char beg)
 752     (when allow-write-back-p
 753       (undo-boundary)
 754       (delete-region beg (max beg end))
 755       (unless (string-match "\\`[ \t]*\\'" code)
 756         (insert code))
 757       ;; Make sure the overlay stays in place
 758       (when (eq context 'save) (move-overlay ovl beg (point)))
 759       (goto-char beg)
 760       (if single (just-one-space)))
 761     (if (memq t (mapcar (lambda (overlay)
 762                           (eq (overlay-get overlay 'invisible)
 763                               'org-hide-block))
 764                         (overlays-at (point))))
 765         ;; Block is hidden; put point at start of block
 766         (beginning-of-line 0)
 767       ;; Block is visible, put point where it was in the code buffer
 768       (when allow-write-back-p
 769         (org-goto-line (1- (+ (org-current-line) line)))
 770         (org-move-to-column (if preserve-indentation col (+ col total-nindent delta)))))
 771     (unless (eq context 'save)
 772       (move-marker beg nil)
 773       (move-marker end nil)))
 774   (unless (eq context 'save)
 775     (when org-edit-src-saved-temp-window-config
 776       (set-window-configuration org-edit-src-saved-temp-window-config)
 777       (setq org-edit-src-saved-temp-window-config nil))))
 778
 779 (defun org-edit-src-abort ()
 780   "Abort editing of the src code and return to the Org buffer."
 781   (interactive)
 782   (let (org-edit-src-allow-write-back-p)
 783     (org-edit-src-exit 'exit)))
 784
 785 (defmacro org-src-in-org-buffer (&rest body)
 786   `(let ((p (point)) (m (mark)) (ul buffer-undo-list) msg)
 787      (save-window-excursion
 788        (org-edit-src-exit 'save)
 789        ,@body
 790        (setq msg (current-message))
 791        (if (eq org-src-window-setup 'other-frame)
 792            (let ((org-src-window-setup 'current-window))
 793              (org-edit-src-code 'save))
 794          (org-edit-src-code 'save)))
 795      (setq buffer-undo-list ul)
 796      (push-mark m 'nomessage)
 797      (goto-char (min p (point-max)))
 798      (message (or msg ""))))
 799 (def-edebug-spec org-src-in-org-buffer (body))
 800
 801 (defun org-edit-src-save ()
 802   "Save parent buffer with current state source-code buffer."
 803   (interactive)
 804   (if (string-match "Fixed Width" (buffer-name))
 805       (user-error "%s" "Use C-c ' to save and exit, C-c C-k to abort editing")
 806     (org-src-in-org-buffer (save-buffer))))
 807
 808 (declare-function org-babel-tangle "ob-tangle" (&optional arg target-file lang))
 809
 810 (defun org-src-tangle (arg)
 811   "Tangle the parent buffer."
 812   (interactive)
 813   (org-src-in-org-buffer (org-babel-tangle arg)))
 814
 815 (defun org-src-mode-configure-edit-buffer ()
 816   (when (org-bound-and-true-p org-edit-src-from-org-mode)
 817     (org-add-hook 'kill-buffer-hook
 818                   #'(lambda () (delete-overlay org-edit-src-overlay)) nil 'local)
 819     (if (org-bound-and-true-p org-edit-src-allow-write-back-p)
 820         (progn
 821           (setq buffer-offer-save t)
 822           (setq buffer-file-name
 823                 (concat (buffer-file-name (marker-buffer org-edit-src-beg-marker))
 824                         "[" (buffer-name) "]"))
 825           (if (featurep 'xemacs)
 826               (progn
 827                 (make-variable-buffer-local 'write-contents-hooks) ; needed only for 21.4
 828                 (setq write-contents-hooks '(org-edit-src-save)))
 829             (setq write-contents-functions '(org-edit-src-save))))
 830       (setq buffer-read-only t))))
 831
 832 (org-add-hook 'org-src-mode-hook 'org-src-mode-configure-edit-buffer)
 833
 834
 835 (defun org-src-associate-babel-session (info)
 836   "Associate edit buffer with comint session."
 837   (interactive)
 838   (let ((session (cdr (assoc :session (nth 2 info)))))
 839     (and session (not (string= session "none"))
 840          (org-babel-comint-buffer-livep session)
 841          (let ((f (intern (format "org-babel-%s-associate-session"
 842                                   (nth 0 info)))))
 843            (and (fboundp f) (funcall f session))))))
 844
 845 (defun org-src-babel-configure-edit-buffer ()
 846   (when org-src-babel-info
 847     (org-src-associate-babel-session org-src-babel-info)))
 848
 849 (org-add-hook 'org-src-mode-hook 'org-src-babel-configure-edit-buffer)
 850 (defmacro org-src-do-at-code-block (&rest body)
 851   "Execute a command from an edit buffer in the Org-mode buffer."
 852   `(let ((beg-marker org-edit-src-beg-marker))
 853      (if beg-marker
 854          (with-current-buffer (marker-buffer beg-marker)
 855            (goto-char (marker-position beg-marker))
 856            ,@body))))
 857 (def-edebug-spec org-src-do-at-code-block (body))
 858
 859 (defun org-src-do-key-sequence-at-code-block (&optional key)
 860   "Execute key sequence at code block in the source Org buffer.
 861 The command bound to KEY in the Org-babel key map is executed
 862 remotely with point temporarily at the start of the code block in
 863 the Org buffer.
 864
 865 This command is not bound to a key by default, to avoid conflicts
 866 with language major mode bindings.  To bind it to C-c @ in all
 867 language major modes, you could use
 868
 869   (add-hook \\='org-src-mode-hook
 870             (lambda () (define-key org-src-mode-map \"\\C-c@\"
 871                     \\='org-src-do-key-sequence-at-code-block)))
 872
 873 In that case, for example, C-c @ t issued in code edit buffers
 874 would tangle the current Org code block, C-c @ e would execute
 875 the block and C-c @ h would display the other available
 876 Org-babel commands."
 877   (interactive "kOrg-babel key: ")
 878   (if (equal key (kbd "C-g")) (keyboard-quit)
 879     (org-edit-src-save)
 880     (org-src-do-at-code-block
 881      (call-interactively
 882       (lookup-key org-babel-map key)))))
 883
 884 (defcustom org-src-tab-acts-natively nil
 885   "If non-nil, the effect of TAB in a code block is as if it were
 886 issued in the language major mode buffer."
 887   :type 'boolean
 888   :version "24.1"
 889   :group 'org-babel)
 890
 891 (defun org-src-native-tab-command-maybe ()
 892   "Perform language-specific TAB action.
 893 Alter code block according to what TAB does in the language major mode."
 894   (and org-src-tab-acts-natively
 895        (org-in-src-block-p)
 896        (not (equal this-command 'org-shifttab))
 897        (let ((org-src-strip-leading-and-trailing-blank-lines nil))
 898          (org-babel-do-key-sequence-in-edit-buffer (kbd "TAB")))))
 899
 900 (add-hook 'org-tab-first-hook 'org-src-native-tab-command-maybe)
 901
 902 (defun org-src-font-lock-fontify-block (lang start end)
 903   "Fontify code block.
 904 This function is called by emacs automatic fontification, as long
 905 as `org-src-fontify-natively' is non-nil.  For manual
 906 fontification of code blocks see `org-src-fontify-block' and
 907 `org-src-fontify-buffer'"
 908   (let ((lang-mode (org-src-get-lang-mode lang)))
 909     (if (fboundp lang-mode)
 910         (let ((string (buffer-substring-no-properties start end))
 911               (modified (buffer-modified-p))
 912               (org-buffer (current-buffer)) pos next)
 913           (remove-text-properties start end '(face nil))
 914           (with-current-buffer
 915               (get-buffer-create
 916                (concat " org-src-fontification:" (symbol-name lang-mode)))
 917             (delete-region (point-min) (point-max))
 918             (insert string " ") ;; so there's a final property change
 919             (unless (eq major-mode lang-mode) (funcall lang-mode))
 920             (org-font-lock-ensure)
 921             (setq pos (point-min))
 922             (while (setq next (next-single-property-change pos 'face))
 923               (put-text-property
 924                (+ start (1- pos)) (1- (+ start next)) 'face
 925                (get-text-property pos 'face) org-buffer)
 926               (setq pos next)))
 927           (add-text-properties
 928            start end
 929            '(font-lock-fontified t fontified t font-lock-multiline t))
 930           (set-buffer-modified-p modified)))))
 931
 932 (defvar org-src-fontify-natively)
 933
 934 (defun org-src-fontify-block ()
 935   "Fontify code block at point."
 936   (interactive)
 937   (save-excursion
 938     (let ((org-src-fontify-natively t)
 939           (info (org-edit-src-find-region-and-lang)))
 940       (font-lock-fontify-region (nth 0 info) (nth 1 info)))))
 941
 942 (defun org-src-fontify-buffer ()
 943   "Fontify all code blocks in the current buffer."
 944   (interactive)
 945   (org-babel-map-src-blocks nil
 946     (org-src-fontify-block)))
 947
 948 (defun org-src-get-lang-mode (lang)
 949   "Return major mode that should be used for LANG.
 950 LANG is a string, and the returned major mode is a symbol."
 951   (intern
 952    (concat
 953     (let ((l (or (cdr (assoc lang org-src-lang-modes)) lang)))
 954       (if (symbolp l) (symbol-name l) l))
 955     "-mode")))
 956
 957 (provide 'org-src)
 958
 959 ;;; org-src.el ends here