lisp/vc-git.el

   1 ;;; vc-git.el --- VC backend for the git version control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   4
   5 ;; Author: Alexandre Julliard <julliard@winehq.org>
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This file contains a VC backend for the git version control
  26 ;; system.
  27 ;;
  28
  29 ;;; Installation:
  30
  31 ;; To install: put this file on the load-path and add Git to the list
  32 ;; of supported backends in `vc-handled-backends'; the following line,
  33 ;; placed in your ~/.emacs, will accomplish this:
  34 ;;
  35 ;;     (add-to-list 'vc-handled-backends 'Git)
  36
  37 ;;; Todo:
  38 ;;  - check if more functions could use vc-git-command instead
  39 ;;     of start-process.
  40 ;;  - changelog generation
  41
  42 ;; Implement the rest of the vc interface. See the comment at the
  43 ;; beginning of vc.el. The current status is:
  44 ;; ("??" means: "figure out what to do about it")
  45 ;;
  46 ;; FUNCTION NAME                                   STATUS
  47 ;; BACKEND PROPERTIES
  48 ;; * revision-granularity                          OK
  49 ;; STATE-QUERYING FUNCTIONS
  50 ;; * registered (file)                             OK
  51 ;; * state (file)                                  OK
  52 ;; - state-heuristic (file)                        NOT NEEDED
  53 ;; * working-revision (file)                       OK
  54 ;; - latest-on-branch-p (file)                     NOT NEEDED
  55 ;; * checkout-model (files)                        OK
  56 ;; - workfile-unchanged-p (file)                   OK
  57 ;; - mode-line-string (file)                       OK
  58 ;; STATE-CHANGING FUNCTIONS
  59 ;; * create-repo ()                                OK
  60 ;; * register (files &optional rev comment)        OK
  61 ;; - init-revision (file)                          NOT NEEDED
  62 ;; - responsible-p (file)                          OK
  63 ;; - could-register (file)                         NOT NEEDED, DEFAULT IS GOOD
  64 ;; - receive-file (file rev)                       NOT NEEDED
  65 ;; - unregister (file)                             OK
  66 ;; * checkin (files rev comment)                   OK
  67 ;; * find-revision (file rev buffer)               OK
  68 ;; * checkout (file &optional editable rev)        OK
  69 ;; * revert (file &optional contents-done)         OK
  70 ;; - rollback (files)                              COULD BE SUPPORTED
  71 ;; - merge (file rev1 rev2)                   It would be possible to merge
  72 ;;                                          changes into a single file, but when
  73 ;;                                          committing they wouldn't
  74 ;;                                          be identified as a merge
  75 ;;                                          by git, so it's probably
  76 ;;                                          not a good idea.
  77 ;; - merge-news (file)                     see `merge'
  78 ;; - steal-lock (file &optional revision)          NOT NEEDED
  79 ;; HISTORY FUNCTIONS
  80 ;; * print-log (files buffer &optional shortlog limit)   OK
  81 ;; - log-view-mode ()                              OK
  82 ;; - show-log-entry (revision)                     OK
  83 ;; - comment-history (file)                        ??
  84 ;; - update-changelog (files)                      COULD BE SUPPORTED
  85 ;; * diff (file &optional rev1 rev2 buffer)        OK
  86 ;; - revision-completion-table (files)             OK
  87 ;; - annotate-command (file buf &optional rev)     OK
  88 ;; - annotate-time ()                              OK
  89 ;; - annotate-current-time ()                      NOT NEEDED
  90 ;; - annotate-extract-revision-at-line ()          OK
  91 ;; TAG SYSTEM
  92 ;; - create-tag (dir name branchp)                 OK
  93 ;; - retrieve-tag (dir name update)                OK
  94 ;; MISCELLANEOUS
  95 ;; - make-version-backups-p (file)                 NOT NEEDED
  96 ;; - repository-hostname (dirname)                 NOT NEEDED
  97 ;; - previous-revision (file rev)                  OK
  98 ;; - next-revision (file rev)                      OK
  99 ;; - check-headers ()                              COULD BE SUPPORTED
 100 ;; - clear-headers ()                              NOT NEEDED
 101 ;; - delete-file (file)                            OK
 102 ;; - rename-file (old new)                         OK
 103 ;; - find-file-hook ()                             NOT NEEDED
 104
 105 (eval-when-compile
 106   (require 'cl)
 107   (require 'vc)
 108   (require 'vc-dir)
 109   (require 'grep))
 110
 111 (defcustom vc-git-diff-switches t
 112   "String or list of strings specifying switches for Git diff under VC.
 113 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
 114   :type '(choice (const :tag "Unspecified" nil)
 115                  (const :tag "None" t)
 116                  (string :tag "Argument String")
 117                  (repeat :tag "Argument List" :value ("") string))
 118   :version "23.1"
 119   :group 'vc)
 120
 121 (defcustom vc-git-add-signoff nil
 122   "Add a Signed-off-by line when committing."
 123   :type 'boolean
 124   :version "23.2"
 125   :group 'vc)
 126
 127
 128 (defvar git-commits-coding-system 'utf-8
 129   "Default coding system for git commits.")
 130
 131 ;;; BACKEND PROPERTIES
 132
 133 (defun vc-git-revision-granularity () 'repository)
 134 (defun vc-git-checkout-model (files) 'implicit)
 135
 136 ;;; STATE-QUERYING FUNCTIONS
 137
 138 ;;;###autoload (defun vc-git-registered (file)
 139 ;;;###autoload   "Return non-nil if FILE is registered with git."
 140 ;;;###autoload   (if (vc-find-root file ".git")       ; short cut
 141 ;;;###autoload       (progn
 142 ;;;###autoload         (load "vc-git")
 143 ;;;###autoload         (vc-git-registered file))))
 144
 145 (defun vc-git-registered (file)
 146   "Check whether FILE is registered with git."
 147   (when (vc-git-root file)
 148     (with-temp-buffer
 149       (let* (process-file-side-effects
 150              ;; do not use the `file-name-directory' here: git-ls-files
 151              ;; sometimes fails to return the correct status for relative
 152              ;; path specs.
 153              ;; see also: http://marc.info/?l=git&m=125787684318129&w=2
 154              (dir (vc-git-root file))
 155              (name (file-relative-name file dir))
 156              (str (ignore-errors
 157                     (when dir (cd dir))
 158                     (vc-git--out-ok "ls-files" "-c" "-z" "--" name)
 159                     ;; if result is empty, use ls-tree to check for deleted file
 160                     (when (eq (point-min) (point-max))
 161                       (vc-git--out-ok "ls-tree" "--name-only" "-z" "HEAD" "--" name))
 162                     (buffer-string))))
 163         (and str
 164              (> (length str) (length name))
 165              (string= (substring str 0 (1+ (length name)))
 166                       (concat name "\0")))))))
 167
 168 (defun vc-git--state-code (code)
 169   "Convert from a string to a added/deleted/modified state."
 170   (case (string-to-char code)
 171     (?M 'edited)
 172     (?A 'added)
 173     (?D 'removed)
 174     (?U 'edited)     ;; FIXME
 175     (?T 'edited)))   ;; FIXME
 176
 177 (defun vc-git-state (file)
 178   "Git-specific version of `vc-state'."
 179   ;; FIXME: This can't set 'ignored yet
 180   (if (not (vc-git-registered file))
 181       'unregistered
 182     (vc-git--call nil "add" "--refresh" "--" (file-relative-name file))
 183     (let ((diff (vc-git--run-command-string file "diff-index" "-z" "HEAD" "--")))
 184       (if (and diff (string-match ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\([ADMUT]\\)\0[^\0]+\0"
 185                                   diff))
 186           (vc-git--state-code (match-string 1 diff))
 187         (if (vc-git--empty-db-p) 'added 'up-to-date)))))
 188
 189 (defun vc-git-working-revision (file)
 190   "Git-specific version of `vc-working-revision'."
 191   (let* (process-file-side-effects
 192          (str (with-output-to-string
 193                 (with-current-buffer standard-output
 194                   (vc-git--out-ok "symbolic-ref" "HEAD")))))
 195     (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 196         (match-string 2 str)
 197       str)))
 198
 199 (defun vc-git-workfile-unchanged-p (file)
 200   (eq 'up-to-date (vc-git-state file)))
 201
 202 (defun vc-git-mode-line-string (file)
 203   "Return string for placement into the modeline for FILE."
 204   (let* ((branch (vc-git-working-revision file))
 205          (def-ml (vc-default-mode-line-string 'Git file))
 206          (help-echo (get-text-property 0 'help-echo def-ml)))
 207     (if (zerop (length branch))
 208         (propertize
 209          (concat def-ml "!")
 210          'help-echo (concat help-echo "\nNo current branch (detached HEAD)"))
 211       (propertize def-ml
 212                   'help-echo (concat help-echo "\nCurrent branch: " branch)))))
 213
 214 (defstruct (vc-git-extra-fileinfo
 215             (:copier nil)
 216             (:constructor vc-git-create-extra-fileinfo (old-perm new-perm &optional rename-state orig-name))
 217             (:conc-name vc-git-extra-fileinfo->))
 218   old-perm new-perm   ;; permission flags
 219   rename-state        ;; rename or copy state
 220   orig-name)          ;; original name for renames or copies
 221
 222 (defun vc-git-escape-file-name (name)
 223   "Escape a file name if necessary."
 224   (if (string-match "[\n\t\"\\]" name)
 225       (concat "\""
 226               (mapconcat (lambda (c)
 227                    (case c
 228                      (?\n "\\n")
 229                      (?\t "\\t")
 230                      (?\\ "\\\\")
 231                      (?\" "\\\"")
 232                      (t (char-to-string c))))
 233                  name "")
 234               "\"")
 235     name))
 236
 237 (defun vc-git-file-type-as-string (old-perm new-perm)
 238   "Return a string describing the file type based on its permissions."
 239   (let* ((old-type (lsh (or old-perm 0) -9))
 240          (new-type (lsh (or new-perm 0) -9))
 241          (str (case new-type
 242                 (?\100  ;; file
 243                  (case old-type
 244                    (?\100 nil)
 245                    (?\120 "   (type change symlink -> file)")
 246                    (?\160 "   (type change subproject -> file)")))
 247                  (?\120  ;; symlink
 248                   (case old-type
 249                     (?\100 "   (type change file -> symlink)")
 250                     (?\160 "   (type change subproject -> symlink)")
 251                     (t "   (symlink)")))
 252                   (?\160  ;; subproject
 253                    (case old-type
 254                      (?\100 "   (type change file -> subproject)")
 255                      (?\120 "   (type change symlink -> subproject)")
 256                      (t "   (subproject)")))
 257                   (?\110 nil)  ;; directory (internal, not a real git state)
 258                   (?\000  ;; deleted or unknown
 259                    (case old-type
 260                      (?\120 "   (symlink)")
 261                      (?\160 "   (subproject)")))
 262                   (t (format "   (unknown type %o)" new-type)))))
 263     (cond (str (propertize str 'face 'font-lock-comment-face))
 264           ((eq new-type ?\110) "/")
 265           (t ""))))
 266
 267 (defun vc-git-rename-as-string (state extra)
 268   "Return a string describing the copy or rename associated with INFO, or an empty string if none."
 269   (let ((rename-state (when extra
 270                         (vc-git-extra-fileinfo->rename-state extra))))
 271     (if rename-state
 272         (propertize
 273          (concat "   ("
 274                  (if (eq rename-state 'copy) "copied from "
 275                    (if (eq state 'added) "renamed from "
 276                      "renamed to "))
 277                  (vc-git-escape-file-name (vc-git-extra-fileinfo->orig-name extra))
 278                  ")") 'face 'font-lock-comment-face)
 279       "")))
 280
 281 (defun vc-git-permissions-as-string (old-perm new-perm)
 282   "Format a permission change as string."
 283   (propertize
 284    (if (or (not old-perm)
 285            (not new-perm)
 286            (eq 0 (logand ?\111 (logxor old-perm new-perm))))
 287        "  "
 288      (if (eq 0 (logand ?\111 old-perm)) "+x" "-x"))
 289   'face 'font-lock-type-face))
 290
 291 (defun vc-git-dir-printer (info)
 292   "Pretty-printer for the vc-dir-fileinfo structure."
 293   (let* ((isdir (vc-dir-fileinfo->directory info))
 294          (state (if isdir "" (vc-dir-fileinfo->state info)))
 295          (extra (vc-dir-fileinfo->extra info))
 296          (old-perm (when extra (vc-git-extra-fileinfo->old-perm extra)))
 297          (new-perm (when extra (vc-git-extra-fileinfo->new-perm extra))))
 298     (insert
 299      "  "
 300      (propertize (format "%c" (if (vc-dir-fileinfo->marked info) ?* ? ))
 301                  'face 'font-lock-type-face)
 302      "  "
 303      (propertize
 304       (format "%-12s" state)
 305       'face (cond ((eq state 'up-to-date) 'font-lock-builtin-face)
 306                   ((eq state 'missing) 'font-lock-warning-face)
 307                   (t 'font-lock-variable-name-face))
 308       'mouse-face 'highlight)
 309      "  " (vc-git-permissions-as-string old-perm new-perm)
 310      "    "
 311      (propertize (vc-git-escape-file-name (vc-dir-fileinfo->name info))
 312                  'face (if isdir 'font-lock-comment-delimiter-face 'font-lock-function-name-face)
 313                  'help-echo
 314                  (if isdir
 315                      "Directory\nVC operations can be applied to it\nmouse-3: Pop-up menu"
 316                    "File\nmouse-3: Pop-up menu")
 317                  'keymap vc-dir-filename-mouse-map
 318                  'mouse-face 'highlight)
 319      (vc-git-file-type-as-string old-perm new-perm)
 320      (vc-git-rename-as-string state extra))))
 321
 322 (defun vc-git-after-dir-status-stage (stage files update-function)
 323   "Process sentinel for the various dir-status stages."
 324   (let (remaining next-stage result)
 325     (goto-char (point-min))
 326     (case stage
 327       ('update-index
 328        (setq next-stage (if (vc-git--empty-db-p) 'ls-files-added
 329                           (if files 'ls-files-up-to-date 'diff-index))))
 330       ('ls-files-added
 331        (setq next-stage 'ls-files-unknown)
 332        (while (re-search-forward "\\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} 0\t\\([^\0]+\\)\0" nil t)
 333          (let ((new-perm (string-to-number (match-string 1) 8))
 334                (name (match-string 2)))
 335            (push (list name 'added (vc-git-create-extra-fileinfo 0 new-perm)) result))))
 336       ('ls-files-up-to-date
 337        (setq next-stage 'diff-index)
 338        (while (re-search-forward "\\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} 0\t\\([^\0]+\\)\0" nil t)
 339          (let ((perm (string-to-number (match-string 1) 8))
 340                (name (match-string 2)))
 341            (push (list name 'up-to-date (vc-git-create-extra-fileinfo perm perm)) result))))
 342       ('ls-files-unknown
 343        (when files (setq next-stage 'ls-files-ignored))
 344        (while (re-search-forward "\\([^\0]*?\\)\0" nil t 1)
 345          (push (list (match-string 1) 'unregistered (vc-git-create-extra-fileinfo 0 0)) result)))
 346       ('ls-files-ignored
 347        (while (re-search-forward "\\([^\0]*?\\)\0" nil t 1)
 348          (push (list (match-string 1) 'ignored (vc-git-create-extra-fileinfo 0 0)) result)))
 349       ('diff-index
 350        (setq next-stage 'ls-files-unknown)
 351        (while (re-search-forward
 352                ":\\([0-7]\\{6\\}\\) \\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\(\\([ADMUT]\\)\0\\([^\0]+\\)\\|\\([CR]\\)[0-9]*\0\\([^\0]+\\)\0\\([^\0]+\\)\\)\0"
 353                nil t 1)
 354          (let ((old-perm (string-to-number (match-string 1) 8))
 355                (new-perm (string-to-number (match-string 2) 8))
 356                (state (or (match-string 4) (match-string 6)))
 357                (name (or (match-string 5) (match-string 7)))
 358                (new-name (match-string 8)))
 359            (if new-name  ; copy or rename
 360                (if (eq ?C (string-to-char state))
 361                    (push (list new-name 'added (vc-git-create-extra-fileinfo old-perm new-perm 'copy name)) result)
 362                  (push (list name 'removed (vc-git-create-extra-fileinfo 0 0 'rename new-name)) result)
 363                  (push (list new-name 'added (vc-git-create-extra-fileinfo old-perm new-perm 'rename name)) result))
 364              (push (list name (vc-git--state-code state) (vc-git-create-extra-fileinfo old-perm new-perm)) result))))))
 365     (when result
 366       (setq result (nreverse result))
 367       (when files
 368         (dolist (entry result) (setq files (delete (car entry) files)))
 369         (unless files (setq next-stage nil))))
 370     (when (or result (not next-stage)) (funcall update-function result next-stage))
 371     (when next-stage (vc-git-dir-status-goto-stage next-stage files update-function))))
 372
 373 (defun vc-git-dir-status-goto-stage (stage files update-function)
 374   (erase-buffer)
 375   (case stage
 376     ('update-index
 377      (if files
 378          (vc-git-command (current-buffer) 'async files "add" "--refresh" "--")
 379        (vc-git-command (current-buffer) 'async nil "update-index" "--refresh")))
 380     ('ls-files-added
 381      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-c" "-s" "--"))
 382     ('ls-files-up-to-date
 383      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-c" "-s" "--"))
 384     ('ls-files-unknown
 385      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-o"
 386                      "--directory" "--no-empty-directory" "--exclude-standard" "--"))
 387     ('ls-files-ignored
 388      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-o" "-i"
 389                      "--directory" "--no-empty-directory" "--exclude-standard" "--"))
 390     ('diff-index
 391      (vc-git-command (current-buffer) 'async files "diff-index" "-z" "-M" "HEAD" "--")))
 392   (vc-exec-after
 393    `(vc-git-after-dir-status-stage (quote ,stage) (quote ,files) (quote ,update-function))))
 394
 395 (defun vc-git-dir-status (dir update-function)
 396   "Return a list of (FILE STATE EXTRA) entries for DIR."
 397   ;; Further things that would have to be fixed later:
 398   ;; - how to handle unregistered directories
 399   ;; - how to support vc-dir on a subdir of the project tree
 400   (vc-git-dir-status-goto-stage 'update-index nil update-function))
 401
 402 (defun vc-git-dir-status-files (dir files default-state update-function)
 403   "Return a list of (FILE STATE EXTRA) entries for FILES in DIR."
 404   (vc-git-dir-status-goto-stage 'update-index files update-function))
 405
 406 (defvar vc-git-stash-map
 407   (let ((map (make-sparse-keymap)))
 408     (define-key map "\C-k" 'vc-git-stash-delete-at-point)
 409     (define-key map "=" 'vc-git-stash-show-at-point)
 410     (define-key map "\C-m" 'vc-git-stash-show-at-point)
 411     map))
 412
 413 (defun vc-git-dir-extra-headers (dir)
 414   (let ((str (with-output-to-string
 415                (with-current-buffer standard-output
 416                  (vc-git--out-ok "symbolic-ref" "HEAD"))))
 417         (stash (vc-git-stash-list))
 418         branch remote remote-url)
 419     (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 420         (progn
 421           (setq branch (match-string 2 str))
 422           (setq remote
 423                 (with-output-to-string
 424                   (with-current-buffer standard-output
 425                     (vc-git--out-ok "config" (concat "branch." branch ".remote")))))
 426           (when (string-match "\\([^\n]+\\)" remote)
 427             (setq remote (match-string 1 remote)))
 428           (when remote
 429             (setq remote-url
 430                   (with-output-to-string
 431                     (with-current-buffer standard-output
 432                       (vc-git--out-ok "config" (concat "remote." remote ".url"))))))
 433           (when (string-match "\\([^\n]+\\)" remote-url)
 434             (setq remote-url (match-string 1 remote-url))))
 435       (setq branch "not (detached HEAD)"))
 436     ;; FIXME: maybe use a different face when nothing is stashed.
 437     (concat
 438      (propertize "Branch     : " 'face 'font-lock-type-face)
 439      (propertize branch
 440                  'face 'font-lock-variable-name-face)
 441      (when remote
 442        (concat
 443         "\n"
 444         (propertize "Remote     : " 'face 'font-lock-type-face)
 445         (propertize remote-url
 446                     'face 'font-lock-variable-name-face)))
 447      "\n"
 448      (if stash
 449        (concat
 450         (propertize "Stash      :\n" 'face 'font-lock-type-face)
 451         (mapconcat
 452          (lambda (x)
 453            (propertize x
 454                        'face 'font-lock-variable-name-face
 455                        'mouse-face 'highlight
 456                        'keymap vc-git-stash-map))
 457          stash "\n"))
 458        (concat
 459         (propertize "Stash      : " 'face 'font-lock-type-face)
 460         (propertize "Nothing stashed"
 461                     'face 'font-lock-variable-name-face))))))
 462
 463 ;;; STATE-CHANGING FUNCTIONS
 464
 465 (defun vc-git-create-repo ()
 466   "Create a new Git repository."
 467   (vc-git-command nil 0 nil "init"))
 468
 469 (defun vc-git-register (files &optional rev comment)
 470   "Register FILES into the git version-control system."
 471   (let (flist dlist)
 472     (dolist (crt files)
 473       (if (file-directory-p crt)
 474           (push crt dlist)
 475         (push crt flist)))
 476     (when flist
 477       (vc-git-command nil 0 flist "update-index" "--add" "--"))
 478     (when dlist
 479       (vc-git-command nil 0 dlist "add"))))
 480
 481 (defalias 'vc-git-responsible-p 'vc-git-root)
 482
 483 (defun vc-git-unregister (file)
 484   (vc-git-command nil 0 file "rm" "-f" "--cached" "--"))
 485
 486
 487 (defun vc-git-checkin (files rev comment)
 488   (let ((coding-system-for-write git-commits-coding-system))
 489     (vc-git-command nil 0 files "commit"
 490                     (if vc-git-add-signoff "-s") "-m" comment "--only" "--")))
 491
 492 (defun vc-git-find-revision (file rev buffer)
 493   (let* (process-file-side-effects
 494          (coding-system-for-read 'binary)
 495          (coding-system-for-write 'binary)
 496          (fullname (substring
 497                     (vc-git--run-command-string
 498                      file "ls-files" "-z" "--full-name" "--")
 499                     0 -1)))
 500     (vc-git-command
 501      buffer 0
 502      (concat (if rev rev "HEAD") ":" fullname) "cat-file" "blob")))
 503
 504 (defun vc-git-checkout (file &optional editable rev)
 505   (vc-git-command nil 0 file "checkout" (or rev "HEAD")))
 506
 507 (defun vc-git-revert (file &optional contents-done)
 508   "Revert FILE to the version stored in the git repository."
 509   (if contents-done
 510       (vc-git-command nil 0 file "update-index" "--")
 511     (vc-git-command nil 0 file "checkout" "HEAD")))
 512
 513 ;;; HISTORY FUNCTIONS
 514
 515 (defun vc-git-print-log (files buffer &optional shortlog limit)
 516   "Get change log associated with FILES."
 517   (let ((coding-system-for-read git-commits-coding-system))
 518     ;; `vc-do-command' creates the buffer, but we need it before running
 519     ;; the command.
 520     (vc-setup-buffer buffer)
 521     ;; If the buffer exists from a previous invocation it might be
 522     ;; read-only.
 523     (let ((inhibit-read-only t))
 524       (with-current-buffer
 525           buffer
 526         (if shortlog
 527         (vc-git-command buffer 'async files
 528                             "log" ;; "--graph"
 529                             "--date=short" "--pretty=format:%h  %ad  %s" "--abbrev-commit"
 530                             "--")
 531           (vc-git-command buffer 'async files
 532                           "rev-list" ;; "--graph"
 533                           "--pretty" "HEAD" "--")))
 534         (when limit 'limit-unsupported))))
 535
 536 (defvar log-view-message-re)
 537 (defvar log-view-file-re)
 538 (defvar log-view-font-lock-keywords)
 539 (defvar log-view-per-file-logs)
 540
 541 ;; Dynamically bound.
 542 (defvar vc-short-log)
 543
 544 (define-derived-mode vc-git-log-view-mode log-view-mode "Git-Log-View"
 545   (require 'add-log) ;; we need the faces add-log
 546   ;; Don't have file markers, so use impossible regexp.
 547   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 548   (set (make-local-variable 'log-view-per-file-logs) nil)
 549   (set (make-local-variable 'log-view-message-re)
 550        (if vc-short-log
 551          "^\\(?:[*/\\| ]+ \\)?\\([0-9a-z]+\\)  \\([-a-z0-9]+\\)  \\(.*\\)"
 552          "^commit *\\([0-9a-z]+\\)"))
 553   (set (make-local-variable 'log-view-font-lock-keywords)
 554        (if vc-short-log
 555            (append
 556             `((,log-view-message-re
 557                (1 'change-log-acknowledgement)
 558                (2 'change-log-date))))
 559        (append
 560         `((,log-view-message-re  (1 'change-log-acknowledgement)))
 561         ;; Handle the case:
 562         ;; user: foo@bar
 563         '(("^Author:[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 564            (1 'change-log-email))
 565           ;; Handle the case:
 566           ;; user: FirstName LastName <foo@bar>
 567           ("^Author:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 568            (1 'change-log-name)
 569            (2 'change-log-email))
 570           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 571            (1 'change-log-name))
 572           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 573            (1 'change-log-name)
 574            (2 'change-log-email))
 575           ("^Merge: \\([0-9a-z]+\\) \\([0-9a-z]+\\)"
 576            (1 'change-log-acknowledgement)
 577            (2 'change-log-acknowledgement))
 578           ("^Date:   \\(.+\\)" (1 'change-log-date))
 579             ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message)))))))
 580
 581
 582 (defun vc-git-show-log-entry (revision)
 583   "Move to the log entry for REVISION.
 584 REVISION may have the form BRANCH, BRANCH~N,
 585 or BRANCH^ (where \"^\" can be repeated)."
 586   (goto-char (point-min))
 587   (when revision
 588     (search-forward (format "\ncommit %s" revision) nil t
 589                     (cond ((string-match "~\\([0-9]\\)$" revision)
 590                            (1+ (string-to-number (match-string 1 revision))))
 591                           ((string-match "\\^+$" revision)
 592                            (1+ (length (match-string 0 revision))))
 593                           (t nil))))
 594   (beginning-of-line))
 595
 596 (defun vc-git-diff (files &optional rev1 rev2 buffer)
 597   "Get a difference report using Git between two revisions of FILES."
 598   (let (process-file-side-effects)
 599     (apply #'vc-git-command (or buffer "*vc-diff*") 1 files
 600            (if (and rev1 rev2) "diff-tree" "diff-index")
 601            "--exit-code"
 602            (append (vc-switches 'git 'diff)
 603                    (list "-p" (or rev1 "HEAD") rev2 "--")))))
 604
 605 (defun vc-git-revision-table (files)
 606   ;; What about `files'?!?  --Stef
 607   (let (process-file-side-effects
 608         (table (list "HEAD")))
 609     (with-temp-buffer
 610       (vc-git-command t nil nil "for-each-ref" "--format=%(refname)")
 611       (goto-char (point-min))
 612       (while (re-search-forward "^refs/\\(heads\\|tags\\)/\\(.*\\)$" nil t)
 613         (push (match-string 2) table)))
 614     table))
 615
 616 (defun vc-git-revision-completion-table (files)
 617   (lexical-let ((files files)
 618                 table)
 619     (setq table (lazy-completion-table
 620                  table (lambda () (vc-git-revision-table files))))
 621     table))
 622
 623 (defun vc-git-annotate-command (file buf &optional rev)
 624   (let ((name (file-relative-name file)))
 625     (vc-git-command buf 'async name "blame" "--date=iso" "-C" "-C" rev)))
 626
 627 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 628
 629 (defun vc-git-annotate-time ()
 630   (and (re-search-forward "[0-9a-f]+[^()]+(.* \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\) \\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\) \\([-+0-9]+\\) +[0-9]+) " nil t)
 631        (vc-annotate-convert-time
 632         (apply #'encode-time (mapcar (lambda (match)
 633                                        (string-to-number (match-string match)))
 634                                      '(6 5 4 3 2 1 7))))))
 635
 636 (defun vc-git-annotate-extract-revision-at-line ()
 637   (save-excursion
 638     (move-beginning-of-line 1)
 639     (when (looking-at "\\([0-9a-f^][0-9a-f]+\\) \\(\\([^(]+\\) \\)?")
 640       (let ((revision (match-string-no-properties 1)))
 641         (if (match-beginning 2)
 642           (cons revision (expand-file-name (match-string-no-properties 3)))
 643           revision)))))
 644
 645 ;;; TAG SYSTEM
 646
 647 (defun vc-git-create-tag (dir name branchp)
 648   (let ((default-directory dir))
 649     (and (vc-git-command nil 0 nil "update-index" "--refresh")
 650          (if branchp
 651              (vc-git-command nil 0 nil "checkout" "-b" name)
 652            (vc-git-command nil 0 nil "tag" name)))))
 653
 654 (defun vc-git-retrieve-tag (dir name update)
 655   (let ((default-directory dir))
 656     (vc-git-command nil 0 nil "checkout" name)
 657     ;; FIXME: update buffers if `update' is true
 658     ))
 659
 660
 661 ;;; MISCELLANEOUS
 662
 663 (defun vc-git-previous-revision (file rev)
 664   "Git-specific version of `vc-previous-revision'."
 665   (if file
 666       (let* ((default-directory (file-name-directory (expand-file-name file)))
 667              (file (file-name-nondirectory file))
 668              (prev-rev (with-temp-buffer
 669                          (and
 670                           (vc-git--out-ok "rev-list" "-2" rev "--" file)
 671                           (goto-char (point-max))
 672                           (bolp)
 673                           (zerop (forward-line -1))
 674                           (not (bobp))
 675                           (buffer-substring-no-properties
 676                            (point)
 677                            (1- (point-max)))))))
 678         (or (vc-git-symbolic-commit prev-rev) prev-rev))
 679     (with-temp-buffer
 680       (and
 681        (vc-git--out-ok "rev-parse" (concat rev "^"))
 682        (buffer-substring-no-properties (point-min) (+ (point-min) 40))))))
 683
 684 (defun vc-git-next-revision (file rev)
 685   "Git-specific version of `vc-next-revision'."
 686   (let* ((default-directory (file-name-directory
 687                              (expand-file-name file)))
 688          (file (file-name-nondirectory file))
 689          (current-rev
 690           (with-temp-buffer
 691             (and
 692              (vc-git--out-ok "rev-list" "-1" rev "--" file)
 693              (goto-char (point-max))
 694              (bolp)
 695              (zerop (forward-line -1))
 696              (bobp)
 697              (buffer-substring-no-properties
 698               (point)
 699               (1- (point-max))))))
 700          (next-rev
 701           (and current-rev
 702                (with-temp-buffer
 703                  (and
 704                   (vc-git--out-ok "rev-list" "HEAD" "--" file)
 705                   (goto-char (point-min))
 706                   (search-forward current-rev nil t)
 707                   (zerop (forward-line -1))
 708                   (buffer-substring-no-properties
 709                    (point)
 710                    (progn (forward-line 1) (1- (point)))))))))
 711     (or (vc-git-symbolic-commit next-rev) next-rev)))
 712
 713 (defun vc-git-delete-file (file)
 714   (vc-git-command nil 0 file "rm" "-f" "--"))
 715
 716 (defun vc-git-rename-file (old new)
 717   (vc-git-command nil 0 (list old new) "mv" "-f" "--"))
 718
 719 (defvar vc-git-extra-menu-map
 720   (let ((map (make-sparse-keymap)))
 721     (define-key map [git-grep]
 722       '(menu-item "Git grep..." vc-git-grep
 723                   :help "Run the `git grep' command"))
 724     (define-key map [git-st]
 725       '(menu-item "Stash..." vc-git-stash
 726                   :help "Stash away changes"))
 727     (define-key map [git-ss]
 728       '(menu-item "Show Stash..." vc-git-stash-show
 729                   :help "Show stash contents"))
 730     (define-key map [git-sig]
 731       '(menu-item "Add Signed-off-by on commit" vc-git-toggle-signoff
 732               :help "Add Add Signed-off-by when commiting (i.e. add the -s flag)"
 733               :button (:toggle . vc-git-add-signoff)))
 734     map))
 735
 736 (defun vc-git-extra-menu () vc-git-extra-menu-map)
 737
 738 (defun vc-git-extra-status-menu () vc-git-extra-menu-map)
 739
 740 (defun vc-git-root (file)
 741   (vc-find-root file ".git"))
 742
 743 (defun vc-git-toggle-signoff ()
 744   (interactive)
 745   (setq vc-git-add-signoff (not vc-git-add-signoff)))
 746
 747 ;; Derived from `lgrep'.
 748 (defun vc-git-grep (regexp &optional files dir)
 749   "Run git grep, searching for REGEXP in FILES in directory DIR.
 750 The search is limited to file names matching shell pattern FILES.
 751 FILES may use abbreviations defined in `grep-files-aliases', e.g.
 752 entering `ch' is equivalent to `*.[ch]'.
 753
 754 With \\[universal-argument] prefix, you can edit the constructed shell command line
 755 before it is executed.
 756 With two \\[universal-argument] prefixes, directly edit and run `grep-command'.
 757
 758 Collect output in a buffer.  While git grep runs asynchronously, you
 759 can use \\[next-error] (M-x next-error), or \\<grep-mode-map>\\[compile-goto-error] \
 760 in the grep output buffer,
 761 to go to the lines where grep found matches.
 762
 763 This command shares argument histories with \\[rgrep] and \\[grep]."
 764   (interactive
 765    (progn
 766      (grep-compute-defaults)
 767      (cond
 768       ((equal current-prefix-arg '(16))
 769        (list (read-from-minibuffer "Run: " "git grep"
 770                                    nil nil 'grep-history)
 771              nil))
 772       (t (let* ((regexp (grep-read-regexp))
 773                 (files (grep-read-files regexp))
 774                 (dir (read-directory-name "In directory: "
 775                                           nil default-directory t)))
 776            (list regexp files dir))))))
 777   (require 'grep)
 778   (when (and (stringp regexp) (> (length regexp) 0))
 779     (let ((command regexp))
 780       (if (null files)
 781           (if (string= command "git grep")
 782               (setq command nil))
 783         (setq dir (file-name-as-directory (expand-file-name dir)))
 784         (setq command
 785               (grep-expand-template "git grep -n -e <R> -- <F>" regexp files))
 786         (when command
 787           (if (equal current-prefix-arg '(4))
 788               (setq command
 789                     (read-from-minibuffer "Confirm: "
 790                                           command nil nil 'grep-history))
 791             (add-to-history 'grep-history command))))
 792       (when command
 793         (let ((default-directory dir)
 794               (compilation-environment '("PAGER=")))
 795           ;; Setting process-setup-function makes exit-message-function work
 796           ;; even when async processes aren't supported.
 797           (compilation-start command 'grep-mode))
 798         (if (eq next-error-last-buffer (current-buffer))
 799             (setq default-directory dir))))))
 800
 801 (defun vc-git-stash (name)
 802   "Create a stash."
 803   (interactive "sStash name: ")
 804   (let ((root (vc-git-root default-directory)))
 805     (when root
 806       (vc-git--call nil "stash" "save" name)
 807       (vc-resynch-buffer root t t))))
 808
 809 (defun vc-git-stash-show (name)
 810   "Show the contents of stash NAME."
 811   (interactive "sStash name: ")
 812   (vc-setup-buffer "*vc-git-stash*")
 813   (vc-git-command "*vc-git-stash*" 'async nil "stash" "show" "-p" name)
 814   (set-buffer "*vc-git-stash*")
 815   (diff-mode)
 816   (setq buffer-read-only t)
 817   (pop-to-buffer (current-buffer)))
 818
 819 (defun vc-git-stash-list ()
 820   (delete
 821    ""
 822    (split-string
 823     (replace-regexp-in-string
 824      "^stash@" "             " (vc-git--run-command-string nil "stash" "list"))
 825     "\n")))
 826
 827 (defun vc-git-stash-get-at-point (point)
 828   (save-excursion
 829     (goto-char point)
 830     (beginning-of-line)
 831     (if (looking-at "^ +\\({[0-9]+}\\):")
 832         (match-string 1)
 833       (error "Cannot find stash at point"))))
 834
 835 (defun vc-git-stash-delete-at-point ()
 836   (interactive)
 837   (let ((stash (vc-git-stash-get-at-point (point))))
 838     (when (y-or-n-p (format "Remove stash %s ?" stash))
 839       (vc-git--run-command-string nil "stash" "drop" (format "stash@%s" stash))
 840       (vc-dir-refresh))))
 841
 842 (defun vc-git-stash-show-at-point ()
 843   (interactive)
 844   (vc-git-stash-show (format "stash@%s" (vc-git-stash-get-at-point (point)))))
 845
 846 \f
 847 ;;; Internal commands
 848
 849 (defun vc-git-command (buffer okstatus file-or-list &rest flags)
 850   "A wrapper around `vc-do-command' for use in vc-git.el.
 851 The difference to vc-do-command is that this function always invokes `git'."
 852   (apply 'vc-do-command (or buffer "*vc*") okstatus "git" file-or-list flags))
 853
 854 (defun vc-git--empty-db-p ()
 855   "Check if the git db is empty (no commit done yet)."
 856   (let (process-file-side-effects)
 857     (not (eq 0 (vc-git--call nil "rev-parse" "--verify" "HEAD")))))
 858
 859 (defun vc-git--call (buffer command &rest args)
 860   ;; We don't need to care the arguments.  If there is a file name, it
 861   ;; is always a relative one.  This works also for remote
 862   ;; directories.
 863   (apply 'process-file "git" nil buffer nil command args))
 864
 865 (defun vc-git--out-ok (command &rest args)
 866   (zerop (apply 'vc-git--call '(t nil) command args)))
 867
 868 (defun vc-git--run-command-string (file &rest args)
 869   "Run a git command on FILE and return its output as string.
 870 FILE can be nil."
 871   (let* ((ok t)
 872          (str (with-output-to-string
 873                 (with-current-buffer standard-output
 874                   (unless (apply 'vc-git--out-ok
 875                                  (if file
 876                                      (append args (list (file-relative-name
 877                                                          file)))
 878                                    args))
 879                     (setq ok nil))))))
 880     (and ok str)))
 881
 882 (defun vc-git-symbolic-commit (commit)
 883   "Translate COMMIT string into symbolic form.
 884 Returns nil if not possible."
 885   (and commit
 886        (let ((name (with-temp-buffer
 887                      (and
 888                       (vc-git--out-ok "name-rev" "--name-only" commit)
 889                       (goto-char (point-min))
 890                       (= (forward-line 2) 1)
 891                       (bolp)
 892                       (buffer-substring-no-properties (point-min) (1- (point-max)))))))
 893          (and name (not (string= name "undefined")) name))))
 894
 895 (provide 'vc-git)
 896
 897 ;; arch-tag: bd10664a-0e5b-48f5-a877-6c17b135be12
 898 ;;; vc-git.el ends here