lisp/minibuf-eldef.el

   1 ;;; minibuf-eldef.el --- Only show defaults in prompts when applicable
   2 ;;
   3 ;; Copyright (C) 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
   5 ;;
   6 ;; Author: Miles Bader <miles@gnu.org>
   7 ;; Keywords: convenience
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; Defines the mode `minibuffer-electric-default-mode'.
  29 ;;
  30 ;; When active, minibuffer prompts that show a default value only show
  31 ;; the default when it's applicable -- that is, when hitting RET would
  32 ;; yield the default value.  If the user modifies the input such that
  33 ;; hitting RET would enter a non-default value, the prompt is modified
  34 ;; to remove the default indication (which is restored if the input is
  35 ;; ever restore to the match the initial input).
  36
  37 ;;; Code:
  38
  39 (defvar minibuffer-default-in-prompt-regexps
  40   '(("\\( (default\\>.*)\\):? \\'" . 1) ("\\( \\[.*\\]\\):? *\\'" . 1))
  41   "*A list of regexps matching the parts of minibuffer prompts showing defaults.
  42 When `minibuffer-electric-default-mode' is active, these regexps are
  43 used to identify the portions of prompts to elide.
  44
  45 Each entry is either a string, which should be a regexp matching the
  46 default portion of the prompt, or a cons cell, who's car is a regexp
  47 matching the default part of the prompt, and who's cdr indicates the
  48 regexp subexpression that matched.")
  49
  50 \f
  51 ;;; Internal variables
  52
  53 ;; A list of minibuffers to which we've added a post-command-hook.
  54 (defvar minibuf-eldef-frobbed-minibufs nil)
  55
  56 ;;; The following are all local variables in the minibuffer
  57
  58 ;; Input pre-inserted into the minibuffer before the user can edit it.
  59 (defvar minibuf-eldef-initial-input)
  60 (make-variable-buffer-local 'minibuf-eldef-initial-input)
  61 ;; and the length of the buffer with it inserted.
  62 (defvar minibuf-eldef-initial-buffer-length)
  63 (make-variable-buffer-local 'minibuf-eldef-initial-buffer-length)
  64
  65 ;; True if the current minibuffer prompt contains the default spec.
  66 (defvar minibuf-eldef-showing-default-in-prompt)
  67 (make-variable-buffer-local 'minibuf-eldef-showing-default-in-prompt)
  68
  69 ;; An overlay covering the default portion of the prompt
  70 (defvar minibuf-eldef-overlay)
  71 (make-variable-buffer-local 'minibuf-eldef-overlay)
  72
  73 \f
  74 ;;; Hook functions
  75
  76 ;; This function goes on minibuffer-setup-hook
  77 (defun minibuf-eldef-setup-minibuffer ()
  78   "Set up a minibuffer for `minibuffer-electric-default-mode'.
  79 The prompt and initial input should already have been inserted."
  80   (let ((regexps minibuffer-default-in-prompt-regexps)
  81         (match nil)
  82         (inhibit-point-motion-hooks t))
  83     (save-excursion
  84       (save-restriction
  85         ;; Narrow to only the prompt
  86         (goto-char (point-min))
  87         (narrow-to-region (point) (minibuffer-prompt-end))
  88         ;; See the prompt contains a default input indicator
  89         (while regexps
  90           (setq match (pop regexps))
  91           (if (re-search-forward (if (stringp match) match (car match)) nil t)
  92               (setq regexps nil)
  93             (setq match nil)))))
  94     (if (not match)
  95         ;; Nope, so just make sure our post-command-hook isn't left around.
  96         (remove-hook 'post-command-hook #'minibuf-eldef-update-minibuffer t)
  97       ;; Yup; set things up so we can frob the prompt as the state of
  98       ;; the input string changes.
  99       (setq match (if (consp match) (cdr match) 0))
 100       (setq minibuf-eldef-overlay
 101             (make-overlay (match-beginning match) (match-end match)))
 102       (setq minibuf-eldef-showing-default-in-prompt t)
 103       (setq minibuf-eldef-initial-input
 104             (minibuffer-contents-no-properties))
 105       (setq minibuf-eldef-initial-buffer-length (point-max))
 106       (add-to-list 'minibuf-eldef-frobbed-minibufs (current-buffer))
 107       (add-hook 'post-command-hook #'minibuf-eldef-update-minibuffer nil t))))
 108
 109 ;; post-command-hook to swap prompts when necessary
 110 (defun minibuf-eldef-update-minibuffer ()
 111   "Update a minibuffer's prompt to include a default only when applicable.
 112 This is intended to be used as a minibuffer post-command-hook for
 113 `minibuffer-electric-default-mode'; the minibuffer should have already
 114 been set up by `minibuf-eldef-setup-minibuffer'."
 115   (unless (eq minibuf-eldef-showing-default-in-prompt
 116               (and (= (point-max) minibuf-eldef-initial-buffer-length)
 117                    (string-equal (minibuffer-contents-no-properties)
 118                                  minibuf-eldef-initial-input)))
 119     ;; swap state
 120     (setq minibuf-eldef-showing-default-in-prompt
 121           (not minibuf-eldef-showing-default-in-prompt))
 122     (cond (minibuf-eldef-showing-default-in-prompt
 123            (overlay-put minibuf-eldef-overlay 'invisible nil)
 124            (overlay-put minibuf-eldef-overlay 'intangible nil))
 125           (t
 126            (overlay-put minibuf-eldef-overlay 'invisible t)
 127            (overlay-put minibuf-eldef-overlay 'intangible t)))))
 128
 129 \f
 130 ;;; Note this definition must be at the end of the file, because
 131 ;;; `define-minor-mode' actually calls the mode-function if the
 132 ;;; associated variable is non-nil, which requires that all needed
 133 ;;; functions be already defined.  [This is arguably a bug in d-m-m]
 134 ;;;###autoload
 135 (define-minor-mode minibuffer-electric-default-mode
 136   "Toggle Minibuffer Electric Default mode.
 137 When active, minibuffer prompts that show a default value only show the
 138 default when it's applicable -- that is, when hitting RET would yield
 139 the default value.  If the user modifies the input such that hitting RET
 140 would enter a non-default value, the prompt is modified to remove the
 141 default indication.
 142
 143 With prefix argument ARG, turn on if positive, otherwise off.
 144 Returns non-nil if the new state is enabled."
 145   :global t
 146   :group 'minibuffer
 147   (if minibuffer-electric-default-mode
 148       ;; Enable the mode
 149       (add-hook 'minibuffer-setup-hook 'minibuf-eldef-setup-minibuffer)
 150     ;; Disable the mode
 151     (remove-hook 'minibuffer-setup-hook 'minibuf-eldef-setup-minibuffer)
 152     ;; Remove our entry from any post-command-hook variable's it's still in
 153     (dolist (minibuf minibuf-eldef-frobbed-minibufs)
 154       (with-current-buffer minibuf
 155         (remove-hook 'post-command-hook #'minibuf-eldef-update-minibuffer t)))
 156     (setq minibuf-eldef-frobbed-minibufs nil)))
 157
 158
 159 (provide 'minibuf-eldef)
 160
 161 ;; arch-tag: 7e421fae-c275-4729-b0da-7836af377d3d
 162 ;;; minibuf-eldef.el ends here