lisp/arc-mode.el

   1 ;;; arc-mode.el --- simple editing of archives
   2
   3 ;; Copyright (C) 1995, 1997, 1998, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Morten Welinder <terra@gnu.org>
   7 ;; Keywords: archives msdog editing major-mode
   8 ;; Favourite-brand-of-beer: None, I hate beer.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; NAMING: "arc" is short for "archive" and does not refer specifically
  30 ;; to files whose name end in ".arc"
  31 ;;
  32 ;; This code does not decode any files internally, although it does
  33 ;; understand the directory level of the archives.  For this reason,
  34 ;; you should expect this code to need more fiddling than tar-mode.el
  35 ;; (although it at present has fewer bugs :-)  In particular, I have
  36 ;; not tested this under Ms-Dog myself.
  37 ;; -------------------------------------
  38 ;; INTERACTION: arc-mode.el should play together with
  39 ;;
  40 ;; * ange-ftp.el: Remote archives (i.e., ones that ange-ftp has brought
  41 ;;                to you) are handled by doing all updates on a local
  42 ;;                copy.  When you make changes to a remote file the
  43 ;;                changes will first take effect when the archive buffer
  44 ;;                is saved.  You will be warned about this.
  45 ;;
  46 ;; * dos-fns.el:  (Part of Emacs 19).  You get automatic ^M^J <--> ^J
  47 ;;                conversion.
  48 ;;
  49 ;; arc-mode.el does not work well with crypt++.el; for the archives as
  50 ;; such this could be fixed (but wouldn't be useful) by declaring such
  51 ;; archives to be "remote".  For the members this is a general Emacs
  52 ;; problem that 19.29's file formats may fix.
  53 ;; -------------------------------------
  54 ;; ARCHIVE TYPES: Currently only the archives below are handled, but the
  55 ;; structure for handling just about anything is in place.
  56 ;;
  57 ;;                        Arc     Lzh     Zip     Zoo
  58 ;;                        --------------------------------
  59 ;; View listing           Intern  Intern  Intern  Intern
  60 ;; Extract member         Y       Y       Y       Y
  61 ;; Save changed member    Y       Y       Y       Y
  62 ;; Add new member         N       N       N       N
  63 ;; Delete member          Y       Y       Y       Y
  64 ;; Rename member          Y       Y       N       N
  65 ;; Chmod                  -       Y       Y       -
  66 ;; Chown                  -       Y       -       -
  67 ;; Chgrp                  -       Y       -       -
  68 ;;
  69 ;; Special thanks to Bill Brodie <wbrodie@panix.com> for very useful tips
  70 ;; on the first released version of this package.
  71 ;;
  72 ;; This code is partly based on tar-mode.el from Emacs.
  73 ;; -------------------------------------
  74 ;; ARCHIVE STRUCTURES:
  75 ;; (This is mostly for myself.)
  76 ;;
  77 ;; ARC         A series of (header,file).  No interactions among members.
  78 ;;
  79 ;; LZH         A series of (header,file).  Headers are checksummed.  No
  80 ;;             interaction among members.
  81 ;;             Headers come in three flavours called level 0, 1 and 2 headers.
  82 ;;             Level 2 header is free of DOS specific restrictions and most
  83 ;;             prevalently used.  Also level 1 and 2 headers consist of base
  84 ;;             and extension headers.  For more details see
  85 ;;             http://homepage1.nifty.com/dangan/en/Content/Program/Java/jLHA/Notes/Notes.html
  86 ;;             http://www.osirusoft.com/joejared/lzhformat.html
  87 ;;
  88 ;; ZIP         A series of (lheader,fil) followed by a "central directory"
  89 ;;             which is a series of (cheader) followed by an end-of-
  90 ;;             central-dir record possibly followed by junk.  The e-o-c-d
  91 ;;             links to c-d.  cheaders link to lheaders which are basically
  92 ;;             cut-down versions of the cheaders.
  93 ;;
  94 ;; ZOO         An archive header followed by a series of (header,file).
  95 ;;             Each member header points to the next.  The archive is
  96 ;;             terminated by a bogus header with a zero next link.
  97 ;; -------------------------------------
  98 ;; HOOKS: `foo' means one of the supported archive types.
  99 ;;
 100 ;; archive-mode-hook
 101 ;; archive-foo-mode-hook
 102 ;; archive-extract-hooks
 103
 104 ;;; Code:
 105
 106 ;; -------------------------------------------------------------------------
 107 ;; Section: Configuration.
 108
 109 (defgroup archive nil
 110   "Simple editing of archives."
 111   :group 'data)
 112
 113 (defgroup archive-arc nil
 114   "ARC-specific options to archive."
 115   :group 'archive)
 116
 117 (defgroup archive-lzh nil
 118   "LZH-specific options to archive."
 119   :group 'archive)
 120
 121 (defgroup archive-zip nil
 122   "ZIP-specific options to archive."
 123   :group 'archive)
 124
 125 (defgroup archive-zoo nil
 126   "ZOO-specific options to archive."
 127   :group 'archive)
 128
 129 (defcustom archive-tmpdir
 130   ;; make-temp-name is safe here because we use this name
 131   ;; to create a directory.
 132   (make-temp-name
 133    (expand-file-name (if (eq system-type 'ms-dos) "ar" "archive.tmp")
 134                      temporary-file-directory))
 135   "Directory for temporary files made by `arc-mode.el'."
 136   :type 'directory
 137   :group 'archive)
 138
 139 (defcustom archive-remote-regexp "^/[^/:]*[^/:.]:"
 140   "*Regexp recognizing archive files names that are not local.
 141 A non-local file is one whose file name is not proper outside Emacs.
 142 A local copy of the archive will be used when updating."
 143   :type 'regexp
 144   :group 'archive)
 145
 146 (defcustom archive-extract-hooks nil
 147   "*Hooks to run when an archive member has been extracted."
 148   :type 'hook
 149   :group 'archive)
 150 ;; ------------------------------
 151 ;; Arc archive configuration
 152
 153 ;; We always go via a local file since there seems to be no reliable way
 154 ;; to extract to stdout without junk getting added.
 155 (defcustom archive-arc-extract
 156   '("arc" "x")
 157   "*Program and its options to run in order to extract an arc file member.
 158 Extraction should happen to the current directory.  Archive and member
 159 name will be added."
 160   :type '(list (string :tag "Program")
 161                 (repeat :tag "Options"
 162                         :inline t
 163                         (string :format "%v")))
 164   :group 'archive-arc)
 165
 166 (defcustom archive-arc-expunge
 167   '("arc" "d")
 168   "*Program and its options to run in order to delete arc file members.
 169 Archive and member names will be added."
 170   :type '(list (string :tag "Program")
 171                 (repeat :tag "Options"
 172                         :inline t
 173                         (string :format "%v")))
 174   :group 'archive-arc)
 175
 176 (defcustom archive-arc-write-file-member
 177   '("arc" "u")
 178   "*Program and its options to run in order to update an arc file member.
 179 Archive and member name will be added."
 180   :type '(list (string :tag "Program")
 181                 (repeat :tag "Options"
 182                         :inline t
 183                         (string :format "%v")))
 184   :group 'archive-arc)
 185 ;; ------------------------------
 186 ;; Lzh archive configuration
 187
 188 (defcustom archive-lzh-extract
 189   '("lha" "pq")
 190   "*Program and its options to run in order to extract an lzh file member.
 191 Extraction should happen to standard output.  Archive and member name will
 192 be added."
 193   :type '(list (string :tag "Program")
 194                 (repeat :tag "Options"
 195                         :inline t
 196                         (string :format "%v")))
 197   :group 'archive-lzh)
 198
 199 (defcustom archive-lzh-expunge
 200   '("lha" "d")
 201   "*Program and its options to run in order to delete lzh file members.
 202 Archive and member names will be added."
 203   :type '(list (string :tag "Program")
 204                 (repeat :tag "Options"
 205                         :inline t
 206                         (string :format "%v")))
 207   :group 'archive-lzh)
 208
 209 (defcustom archive-lzh-write-file-member
 210   '("lha" "a")
 211   "*Program and its options to run in order to update an lzh file member.
 212 Archive and member name will be added."
 213   :type '(list (string :tag "Program")
 214                 (repeat :tag "Options"
 215                         :inline t
 216                         (string :format "%v")))
 217   :group 'archive-lzh)
 218 ;; ------------------------------
 219 ;; Zip archive configuration
 220
 221 (defcustom archive-zip-extract
 222   (if (and (not (executable-find "unzip"))
 223            (executable-find "pkunzip"))
 224       '("pkunzip" "-e" "-o-")
 225     '("unzip" "-qq" "-c"))
 226   "*Program and its options to run in order to extract a zip file member.
 227 Extraction should happen to standard output.  Archive and member name will
 228 be added."
 229   :type '(list (string :tag "Program")
 230                 (repeat :tag "Options"
 231                         :inline t
 232                         (string :format "%v")))
 233   :group 'archive-zip)
 234
 235 ;; For several reasons the latter behaviour is not desirable in general.
 236 ;; (1) It uses more disk space.  (2) Error checking is worse or non-
 237 ;; existent.  (3) It tends to do funny things with other systems' file
 238 ;; names.
 239
 240 (defcustom archive-zip-expunge
 241   (if (and (not (executable-find "zip"))
 242            (executable-find "pkzip"))
 243       '("pkzip" "-d")
 244     '("zip" "-d" "-q"))
 245   "*Program and its options to run in order to delete zip file members.
 246 Archive and member names will be added."
 247   :type '(list (string :tag "Program")
 248                 (repeat :tag "Options"
 249                         :inline t
 250                         (string :format "%v")))
 251   :group 'archive-zip)
 252
 253 (defcustom archive-zip-update
 254   (if (and (not (executable-find "zip"))
 255            (executable-find "pkzip"))
 256       '("pkzip" "-u" "-P")
 257     '("zip" "-q"))
 258   "*Program and its options to run in order to update a zip file member.
 259 Options should ensure that specified directory will be put into the zip
 260 file.  Archive and member name will be added."
 261   :type '(list (string :tag "Program")
 262                 (repeat :tag "Options"
 263                         :inline t
 264                         (string :format "%v")))
 265   :group 'archive-zip)
 266
 267 (defcustom archive-zip-update-case
 268   (if (and (not (executable-find "zip"))
 269            (executable-find "pkzip"))
 270       '("pkzip" "-u" "-P")
 271     '("zip" "-q" "-k"))
 272   "*Program and its options to run in order to update a case fiddled zip member.
 273 Options should ensure that specified directory will be put into the zip file.
 274 Archive and member name will be added."
 275   :type '(list (string :tag "Program")
 276                 (repeat :tag "Options"
 277                         :inline t
 278                         (string :format "%v")))
 279   :group 'archive-zip)
 280
 281 (defcustom archive-zip-case-fiddle t
 282   "*If non-nil then zip file members may be down-cased.
 283 This case fiddling will only happen for members created by a system
 284 that uses caseless file names."
 285   :type 'boolean
 286   :group 'archive-zip)
 287 ;; ------------------------------
 288 ;; Zoo archive configuration
 289
 290 (defcustom archive-zoo-extract
 291   '("zoo" "xpq")
 292   "*Program and its options to run in order to extract a zoo file member.
 293 Extraction should happen to standard output.  Archive and member name will
 294 be added."
 295   :type '(list (string :tag "Program")
 296                 (repeat :tag "Options"
 297                         :inline t
 298                         (string :format "%v")))
 299   :group 'archive-zoo)
 300
 301 (defcustom archive-zoo-expunge
 302   '("zoo" "DqPP")
 303   "*Program and its options to run in order to delete zoo file members.
 304 Archive and member names will be added."
 305   :type '(list (string :tag "Program")
 306                 (repeat :tag "Options"
 307                         :inline t
 308                         (string :format "%v")))
 309   :group 'archive-zoo)
 310
 311 (defcustom archive-zoo-write-file-member
 312   '("zoo" "a")
 313   "*Program and its options to run in order to update a zoo file member.
 314 Archive and member name will be added."
 315   :type '(list (string :tag "Program")
 316                 (repeat :tag "Options"
 317                         :inline t
 318                         (string :format "%v")))
 319   :group 'archive-zoo)
 320 ;; -------------------------------------------------------------------------
 321 ;; Section: Variables
 322
 323 (defvar archive-subtype nil "Symbol describing archive type.")
 324 (defvar archive-file-list-start nil "Position of first contents line.")
 325 (defvar archive-file-list-end nil "Position just after last contents line.")
 326 (defvar archive-proper-file-start nil "Position of real archive's start.")
 327 (defvar archive-read-only nil "Non-nil if the archive is read-only on disk.")
 328 (defvar archive-local-name nil "Name of local copy of remote archive.")
 329 (defvar archive-mode-map
 330   (let ((map (make-keymap)))
 331     (suppress-keymap map)
 332     (define-key map " " 'archive-next-line)
 333     (define-key map "a" 'archive-alternate-display)
 334     ;;(define-key map "c" 'archive-copy)
 335     (define-key map "d" 'archive-flag-deleted)
 336     (define-key map "\C-d" 'archive-flag-deleted)
 337     (define-key map "e" 'archive-extract)
 338     (define-key map "f" 'archive-extract)
 339     (define-key map "\C-m" 'archive-extract)
 340     (define-key map "g" 'revert-buffer)
 341     (define-key map "h" 'describe-mode)
 342     (define-key map "m" 'archive-mark)
 343     (define-key map "n" 'archive-next-line)
 344     (define-key map "\C-n" 'archive-next-line)
 345     (define-key map [down] 'archive-next-line)
 346     (define-key map "o" 'archive-extract-other-window)
 347     (define-key map "p" 'archive-previous-line)
 348     (define-key map "q" 'quit-window)
 349     (define-key map "\C-p" 'archive-previous-line)
 350     (define-key map [up] 'archive-previous-line)
 351     (define-key map "r" 'archive-rename-entry)
 352     (define-key map "u" 'archive-unflag)
 353     (define-key map "\M-\C-?" 'archive-unmark-all-files)
 354     (define-key map "v" 'archive-view)
 355     (define-key map "x" 'archive-expunge)
 356     (define-key map "\177" 'archive-unflag-backwards)
 357     (define-key map "E" 'archive-extract-other-window)
 358     (define-key map "M" 'archive-chmod-entry)
 359     (define-key map "G" 'archive-chgrp-entry)
 360     (define-key map "O" 'archive-chown-entry)
 361
 362     (if (fboundp 'command-remapping)
 363         (progn
 364           (define-key map [remap advertised-undo] 'archive-undo)
 365           (define-key map [remap undo] 'archive-undo))
 366       (substitute-key-definition 'advertised-undo 'archive-undo map global-map)
 367       (substitute-key-definition 'undo 'archive-undo map global-map))
 368
 369     (define-key map
 370       (if (featurep 'xemacs) 'button2 [mouse-2]) 'archive-extract)
 371
 372     (if (featurep 'xemacs)
 373         ()                              ; out of luck
 374
 375       (define-key map [menu-bar immediate]
 376         (cons "Immediate" (make-sparse-keymap "Immediate")))
 377       (define-key map [menu-bar immediate alternate]
 378         '(menu-item "Alternate Display" archive-alternate-display
 379           :enable (boundp (archive-name "alternate-display"))
 380           :help "Toggle alternate file info display"))
 381       (define-key map [menu-bar immediate view]
 382         '(menu-item "View This File" archive-view
 383           :help "Display file at cursor in View Mode"))
 384       (define-key map [menu-bar immediate display]
 385         '(menu-item "Display in Other Window" archive-display-other-window
 386           :help "Display file at cursor in another window"))
 387       (define-key map [menu-bar immediate find-file-other-window]
 388         '(menu-item "Find in Other Window" archive-extract-other-window
 389           :help "Edit file at cursor in another window"))
 390       (define-key map [menu-bar immediate find-file]
 391         '(menu-item "Find This File" archive-extract
 392           :help "Extract file at cursor and edit it"))
 393
 394       (define-key map [menu-bar mark]
 395         (cons "Mark" (make-sparse-keymap "Mark")))
 396       (define-key map [menu-bar mark unmark-all]
 397         '(menu-item "Unmark All" archive-unmark-all-files
 398           :help "Unmark all marked files"))
 399       (define-key map [menu-bar mark deletion]
 400         '(menu-item "Flag" archive-flag-deleted
 401           :help "Flag file at cursor for deletion"))
 402       (define-key map [menu-bar mark unmark]
 403         '(menu-item "Unflag" archive-unflag
 404           :help "Unmark file at cursor"))
 405       (define-key map [menu-bar mark mark]
 406         '(menu-item "Mark" archive-mark
 407           :help "Mark file at cursor"))
 408
 409       (define-key map [menu-bar operate]
 410         (cons "Operate" (make-sparse-keymap "Operate")))
 411       (define-key map [menu-bar operate chown]
 412         '(menu-item "Change Owner..." archive-chown-entry
 413           :enable (fboundp (archive-name "chown-entry"))
 414           :help "Change owner of marked files"))
 415       (define-key map [menu-bar operate chgrp]
 416         '(menu-item "Change Group..." archive-chgrp-entry
 417           :enable (fboundp (archive-name "chgrp-entry"))
 418           :help "Change group ownership of marked files"))
 419       (define-key map [menu-bar operate chmod]
 420         '(menu-item "Change Mode..." archive-chmod-entry
 421           :enable (fboundp (archive-name "chmod-entry"))
 422           :help "Change mode (permissions) of marked files"))
 423       (define-key map [menu-bar operate rename]
 424         '(menu-item "Rename to..." archive-rename-entry
 425           :enable (fboundp (archive-name "rename-entry"))
 426           :help "Rename marked files"))
 427       ;;(define-key map [menu-bar operate copy]
 428       ;;  '(menu-item "Copy to..." archive-copy))
 429       (define-key map [menu-bar operate expunge]
 430         '(menu-item "Expunge Marked Files" archive-expunge
 431           :help "Delete all flagged files from archive"))
 432       map))
 433   "Local keymap for archive mode listings.")
 434 (defvar archive-file-name-indent nil "Column where file names start.")
 435
 436 (defvar archive-remote nil "Non-nil if the archive is outside file system.")
 437 (make-variable-buffer-local 'archive-remote)
 438 (put 'archive-remote 'permanent-local t)
 439
 440 (defvar archive-member-coding-system nil "Coding-system of archive member.")
 441 (make-variable-buffer-local 'archive-member-coding-system)
 442
 443 (defvar archive-alternate-display nil
 444   "Non-nil when alternate information is shown.")
 445 (make-variable-buffer-local 'archive-alternate-display)
 446 (put 'archive-alternate-display 'permanent-local t)
 447
 448 (defvar archive-superior-buffer nil "In archive members, points to archive.")
 449 (put 'archive-superior-buffer 'permanent-local t)
 450
 451 (defvar archive-subfile-mode nil "Non-nil in archive member buffers.")
 452 (make-variable-buffer-local 'archive-subfile-mode)
 453 (put 'archive-subfile-mode 'permanent-local t)
 454
 455 (defvar archive-files nil
 456   "Vector of file descriptors.
 457 Each descriptor is a vector of the form
 458  [EXT-FILE-NAME INT-FILE-NAME CASE-FIDDLED MODE ...]")
 459 (make-variable-buffer-local 'archive-files)
 460
 461 ;; -------------------------------------------------------------------------
 462 ;; Section: Support functions.
 463
 464 (defsubst archive-name (suffix)
 465   (intern (concat "archive-" (symbol-name archive-subtype) "-" suffix)))
 466
 467 (defun archive-l-e (str &optional len float)
 468   "Convert little endian string/vector STR to integer.
 469 Alternatively, STR may be a buffer position in the current buffer
 470 in which case a second argument, length LEN, should be supplied.
 471 FLOAT, if non-nil, means generate and return a float instead of an integer
 472 \(use this for numbers that can overflow the Emacs integer)."
 473   (if (stringp str)
 474       (setq len (length str))
 475     (setq str (buffer-substring str (+ str len))))
 476   (let ((result 0)
 477         (i 0))
 478     (while (< i len)
 479       (setq i (1+ i)
 480             result (+ (if float (* result 256.0) (ash result 8))
 481                       (aref str (- len i)))))
 482     result))
 483
 484 (defun archive-int-to-mode (mode)
 485   "Turn an integer like 0700 (i.e., 448) into a mode string like -rwx------."
 486   ;; FIXME: merge with tar-grind-file-mode.
 487   (string
 488     (if (zerop (logand  8192 mode))
 489         (if (zerop (logand 16384 mode)) ?- ?d)
 490       ?c) ; completeness
 491     (if (zerop (logand   256 mode)) ?- ?r)
 492     (if (zerop (logand   128 mode)) ?- ?w)
 493     (if (zerop (logand    64 mode))
 494         (if (zerop (logand  1024 mode)) ?- ?S)
 495       (if (zerop (logand  1024 mode)) ?x ?s))
 496     (if (zerop (logand    32 mode)) ?- ?r)
 497     (if (zerop (logand    16 mode)) ?- ?w)
 498     (if (zerop (logand     8 mode))
 499         (if (zerop (logand  2048 mode)) ?- ?S)
 500       (if (zerop (logand  2048 mode)) ?x ?s))
 501     (if (zerop (logand     4 mode)) ?- ?r)
 502     (if (zerop (logand     2 mode)) ?- ?w)
 503     (if (zerop (logand     1 mode)) ?- ?x)))
 504
 505 (defun archive-calc-mode (oldmode newmode &optional error)
 506   "From the integer OLDMODE and the string NEWMODE calculate a new file mode.
 507 NEWMODE may be an octal number including a leading zero in which case it
 508 will become the new mode.\n
 509 NEWMODE may also be a relative specification like \"og-rwx\" in which case
 510 OLDMODE will be modified accordingly just like chmod(2) would have done.\n
 511 If optional third argument ERROR is non-nil an error will be signaled if
 512 the mode is invalid.  If ERROR is nil then nil will be returned."
 513   (cond ((string-match "^0[0-7]*$" newmode)
 514          (let ((result 0)
 515                (len (length newmode))
 516                (i 1))
 517            (while (< i len)
 518              (setq result (+ (lsh result 3) (aref newmode i) (- ?0))
 519                    i (1+ i)))
 520            (logior (logand oldmode 65024) result)))
 521         ((string-match "^\\([agou]+\\)\\([---+=]\\)\\([rwxst]+\\)$" newmode)
 522          (let ((who 0)
 523                (result oldmode)
 524                (op (aref newmode (match-beginning 2)))
 525                (bits 0)
 526                (i (match-beginning 3)))
 527            (while (< i (match-end 3))
 528              (let ((rwx (aref newmode i)))
 529                (setq bits (logior bits (cond ((= rwx ?r)  292)
 530                                              ((= rwx ?w)  146)
 531                                              ((= rwx ?x)   73)
 532                                              ((= rwx ?s) 3072)
 533                                              ((= rwx ?t)  512)))
 534                      i (1+ i))))
 535            (while (< who (match-end 1))
 536              (let* ((whoc (aref newmode who))
 537                     (whomask (cond ((= whoc ?a) 4095)
 538                                    ((= whoc ?u) 1472)
 539                                    ((= whoc ?g) 2104)
 540                                    ((= whoc ?o)    7))))
 541                (if (= op ?=)
 542                    (setq result (logand result (lognot whomask))))
 543                (if (= op ?-)
 544                    (setq result (logand result (lognot (logand whomask bits))))
 545                  (setq result (logior result (logand whomask bits)))))
 546              (setq who (1+ who)))
 547            result))
 548         (t
 549          (if error
 550              (error "Invalid mode specification: %s" newmode)))))
 551
 552 (defun archive-dosdate (date)
 553   "Stringify dos packed DATE record."
 554   (let ((year (+ 1980 (logand (ash date -9) 127)))
 555         (month (logand (ash date -5) 15))
 556         (day (logand date 31)))
 557     (if (or (> month 12) (< month 1))
 558         ""
 559       (format "%2d-%s-%d"
 560               day
 561               (aref ["Jan" "Feb" "Mar" "Apr" "May" "Jun"
 562                      "Jul" "Aug" "Sep" "Oct" "Nov" "Dec"] (1- month))
 563               year))))
 564
 565 (defun archive-dostime (time)
 566   "Stringify dos packed TIME record."
 567   (let ((hour (logand (ash time -11) 31))
 568         (minute (logand (ash time -5) 63))
 569         (second (* 2 (logand time 31)))) ; 2 seconds resolution
 570     (format "%02d:%02d:%02d" hour minute second)))
 571
 572 (defun archive-unixdate (low high)
 573   "Stringify Unix (LOW HIGH) date."
 574   (let ((str (current-time-string (cons high low))))
 575     (format "%s-%s-%s"
 576             (substring str 8 10)
 577             (substring str 4 7)
 578             (substring str 20 24))))
 579
 580 (defun archive-unixtime (low high)
 581   "Stringify Unix (LOW HIGH) time."
 582   (let ((str (current-time-string (cons high low))))
 583     (substring str 11 19)))
 584
 585 (defun archive-get-lineno ()
 586   (if (>= (point) archive-file-list-start)
 587       (count-lines archive-file-list-start
 588                    (save-excursion (beginning-of-line) (point)))
 589     0))
 590
 591 (defun archive-get-descr (&optional noerror)
 592   "Return the descriptor vector for file at point.
 593 Does not signal an error if optional argument NOERROR is non-nil."
 594   (let ((no (archive-get-lineno)))
 595     (if (and (>= (point) archive-file-list-start)
 596              (< no (length archive-files)))
 597         (let ((item (aref archive-files no)))
 598           (if (vectorp item)
 599               item
 600             (if (not noerror)
 601                 (error "Entry is not a regular member of the archive"))))
 602       (if (not noerror)
 603           (error "Line does not describe a member of the archive")))))
 604 ;; -------------------------------------------------------------------------
 605 ;; Section: the mode definition
 606
 607 ;;;###autoload
 608 (defun archive-mode (&optional force)
 609   "Major mode for viewing an archive file in a dired-like way.
 610 You can move around using the usual cursor motion commands.
 611 Letters no longer insert themselves.
 612 Type `e' to pull a file out of the archive and into its own buffer;
 613 or click mouse-2 on the file's line in the archive mode buffer.
 614
 615 If you edit a sub-file of this archive (as with the `e' command) and
 616 save it, the contents of that buffer will be saved back into the
 617 archive.
 618
 619 \\{archive-mode-map}"
 620   ;; This is not interactive because you shouldn't be turning this
 621   ;; mode on and off.  You can corrupt things that way.
 622   (if (zerop (buffer-size))
 623       ;; At present we cannot create archives from scratch
 624       (funcall default-major-mode)
 625     (if (and (not force) archive-files) nil
 626       (let* ((type (archive-find-type))
 627              (typename (capitalize (symbol-name type))))
 628         (kill-all-local-variables)
 629         (make-local-variable 'archive-subtype)
 630         (setq archive-subtype type)
 631
 632         ;; Buffer contains treated image of file before the file contents
 633         (make-local-variable 'revert-buffer-function)
 634         (setq revert-buffer-function 'archive-mode-revert)
 635         (auto-save-mode 0)
 636
 637         ;; Remote archives are not written by a hook.
 638         (if archive-remote nil
 639           (add-hook 'write-contents-functions 'archive-write-file nil t))
 640
 641         (make-local-variable 'require-final-newline)
 642         (setq require-final-newline nil)
 643         (make-local-variable 'local-enable-local-variables)
 644         (setq local-enable-local-variables nil)
 645
 646         ;; Prevent loss of data when saving the file.
 647         (make-local-variable 'file-precious-flag)
 648         (setq file-precious-flag t)
 649
 650         (make-local-variable 'archive-read-only)
 651         ;; Archives which are inside other archives and whose
 652         ;; names are invalid for this OS, can't be written.
 653         (setq archive-read-only
 654               (or (not (file-writable-p (buffer-file-name)))
 655                   (and archive-subfile-mode
 656                        (string-match file-name-invalid-regexp
 657                                      (aref archive-subfile-mode 0)))))
 658
 659         ;; Should we use a local copy when accessing from outside Emacs?
 660         (make-local-variable 'archive-local-name)
 661
 662         ;; An archive can contain another archive whose name is invalid
 663         ;; on local filesystem.  Treat such archives as remote.
 664         (or archive-remote
 665             (setq archive-remote
 666                   (or (string-match archive-remote-regexp (buffer-file-name))
 667                       (string-match file-name-invalid-regexp
 668                                     (buffer-file-name)))))
 669
 670         (setq major-mode 'archive-mode)
 671         (setq mode-name (concat typename "-Archive"))
 672         ;; Run archive-foo-mode-hook and archive-mode-hook
 673         (run-mode-hooks (archive-name "mode-hook") 'archive-mode-hook)
 674         (use-local-map archive-mode-map))
 675
 676       (make-local-variable 'archive-proper-file-start)
 677       (make-local-variable 'archive-file-list-start)
 678       (make-local-variable 'archive-file-list-end)
 679       (make-local-variable 'archive-file-name-indent)
 680       (archive-summarize nil)
 681       (setq buffer-read-only t))))
 682
 683 ;; Archive mode is suitable only for specially formatted data.
 684 (put 'archive-mode 'mode-class 'special)
 685
 686 (let ((item1 '(archive-subfile-mode " Archive")))
 687   (or (member item1 minor-mode-alist)
 688       (setq minor-mode-alist (cons item1 minor-mode-alist))))
 689 ;; -------------------------------------------------------------------------
 690 (defun archive-find-type ()
 691   (widen)
 692   (goto-char (point-min))
 693   ;; The funny [] here make it unlikely that the .elc file will be treated
 694   ;; as an archive by other software.
 695   (let (case-fold-search)
 696     (cond ((looking-at "[P]K\003\004") 'zip)
 697           ((looking-at "..-l[hz][0-9ds]-") 'lzh)
 698           ((looking-at "....................[\334]\247\304\375") 'zoo)
 699           ((and (looking-at "\C-z")     ; signature too simple, IMHO
 700                 (string-match "\\.[aA][rR][cC]$"
 701                               (or buffer-file-name (buffer-name))))
 702            'arc)
 703           ;; This pattern modelled on the BSD/GNU+Linux `file' command.
 704           ;; Have seen capital "LHA's", and file has lower case "LHa's" too.
 705           ;; Note this regexp is also in archive-exe-p.
 706           ((looking-at "MZ\\(.\\|\n\\)\\{34\\}LH[aA]'s SFX ") 'lzh-exe)
 707           (t (error "Buffer format not recognized")))))
 708 ;; -------------------------------------------------------------------------
 709 (defun archive-summarize (&optional shut-up)
 710   "Parse the contents of the archive file in the current buffer.
 711 Place a dired-like listing on the front;
 712 then narrow to it, so that only that listing
 713 is visible (and the real data of the buffer is hidden).
 714 Optional argument SHUT-UP, if non-nil, means don't print messages
 715 when parsing the archive."
 716   (widen)
 717   (set-buffer-multibyte nil)
 718   (let ((inhibit-read-only t))
 719     (or shut-up
 720         (message "Parsing archive file..."))
 721     (buffer-disable-undo (current-buffer))
 722     (setq archive-files (funcall (archive-name "summarize")))
 723     (or shut-up
 724         (message "Parsing archive file...done."))
 725     (setq archive-proper-file-start (point-marker))
 726     (narrow-to-region (point-min) (point))
 727     (set-buffer-modified-p nil)
 728     (buffer-enable-undo))
 729   (goto-char archive-file-list-start)
 730   (archive-next-line 0))
 731
 732 (defun archive-resummarize ()
 733   "Recreate the contents listing of an archive."
 734   (let ((modified (buffer-modified-p))
 735         (no (archive-get-lineno))
 736         (inhibit-read-only t))
 737     (widen)
 738     (delete-region (point-min) archive-proper-file-start)
 739     (archive-summarize t)
 740     (restore-buffer-modified-p modified)
 741     (goto-char archive-file-list-start)
 742     (archive-next-line no)))
 743
 744 (defun archive-summarize-files (files)
 745   "Insert a description of a list of files annotated with proper mouse face."
 746   (setq archive-file-list-start (point-marker))
 747   (setq archive-file-name-indent (if files (aref (car files) 1) 0))
 748   ;; We don't want to do an insert for each element since that takes too
 749   ;; long when the archive -- which has to be moved in memory -- is large.
 750   (insert
 751    (apply
 752     (function concat)
 753     (mapcar
 754      (lambda (fil)
 755        ;; Using `concat' here copies the text also, so we can add
 756        ;; properties without problems.
 757        (let ((text (concat (aref fil 0) "\n")))
 758          (if (featurep 'xemacs)
 759              ()                         ; out of luck
 760            (add-text-properties
 761             (aref fil 1) (aref fil 2)
 762             '(mouse-face highlight
 763               help-echo "mouse-2: extract this file into a buffer")
 764             text))
 765          text))
 766      files)))
 767   (setq archive-file-list-end (point-marker)))
 768
 769 (defun archive-alternate-display ()
 770   "Toggle alternative display.
 771 To avoid very long lines archive mode does not show all information.
 772 This function changes the set of information shown for each files."
 773   (interactive)
 774   (setq archive-alternate-display (not archive-alternate-display))
 775   (archive-resummarize))
 776 ;; -------------------------------------------------------------------------
 777 ;; Section: Local archive copy handling
 778
 779 (defun archive-unique-fname (fname dir)
 780   "Make sure a file FNAME can be created uniquely in directory DIR.
 781
 782 If FNAME can be uniquely created in DIR, it is returned unaltered.
 783 If FNAME is something our underlying filesystem can't grok, or if another
 784 file by that name already exists in DIR, a unique new name is generated
 785 using `make-temp-file', and the generated name is returned."
 786   (let ((fullname (expand-file-name fname dir))
 787         (alien (string-match file-name-invalid-regexp fname)))
 788     (if (or alien (file-exists-p fullname))
 789         (make-temp-file
 790          (expand-file-name
 791           (if (if (fboundp 'msdos-long-file-names)
 792                   (not (msdos-long-file-names)))
 793               "am"
 794             "arc-mode.")
 795           dir))
 796       fullname)))
 797
 798 (defun archive-maybe-copy (archive)
 799   (let ((coding-system-for-write 'no-conversion))
 800     (if archive-remote
 801         (let ((start (point-max))
 802               ;; Sometimes ARCHIVE is invalid while its actual name, as
 803               ;; recorded in its parent archive, is not.  For example, an
 804               ;; archive bar.zip inside another archive foo.zip gets a name
 805               ;; "foo.zip:bar.zip", which is invalid on DOS/Windows.
 806               ;; So use the actual name if available.
 807               (archive-name
 808                (or (and archive-subfile-mode (aref archive-subfile-mode 0))
 809                    archive)))
 810           (setq archive-local-name
 811                 (archive-unique-fname archive-name archive-tmpdir))
 812           ;; Maked sure all the leading directories in
 813           ;; archive-local-name exist under archive-tmpdir, so that
 814           ;; the directory structure recorded in the archive is
 815           ;; reconstructed in the temporary directory.
 816           (make-directory (file-name-directory archive-local-name) t)
 817           (save-restriction
 818             (widen)
 819             (write-region start (point-max) archive-local-name nil 'nomessage))
 820           archive-local-name)
 821       (if (buffer-modified-p) (save-buffer))
 822       archive)))
 823
 824 (defun archive-maybe-update (unchanged)
 825   (if archive-remote
 826       (let ((name archive-local-name)
 827             (modified (buffer-modified-p))
 828             (coding-system-for-read 'no-conversion)
 829             (lno (archive-get-lineno))
 830             (inhibit-read-only t))
 831         (if unchanged nil
 832           (setq archive-files nil)
 833           (erase-buffer)
 834           (insert-file-contents name)
 835           (archive-mode t)
 836           (goto-char archive-file-list-start)
 837           (archive-next-line lno))
 838         (archive-delete-local name)
 839         (if (not unchanged)
 840             (message
 841              "Buffer `%s' must be saved for changes to take effect"
 842              (buffer-name (current-buffer))))
 843         (set-buffer-modified-p (or modified (not unchanged))))))
 844
 845 (defun archive-delete-local (name)
 846   "Delete file NAME and its parents up to and including `archive-tmpdir'."
 847   (let ((again t)
 848         (top (directory-file-name (file-name-as-directory archive-tmpdir))))
 849     (condition-case nil
 850         (delete-file name)
 851       (error nil))
 852     (while again
 853       (setq name (directory-file-name (file-name-directory name)))
 854       (condition-case nil
 855           (delete-directory name)
 856         (error nil))
 857       (if (string= name top) (setq again nil)))))
 858 ;; -------------------------------------------------------------------------
 859 ;; Section: Member extraction
 860
 861 (defun archive-file-name-handler (op &rest args)
 862   (or (eq op 'file-exists-p)
 863       (let ((file-name-handler-alist nil))
 864         (apply op args))))
 865
 866 (defun archive-set-buffer-as-visiting-file (filename)
 867   "Set the current buffer as if it were visiting FILENAME."
 868   (save-excursion
 869     (goto-char (point-min))
 870     (let ((buffer-undo-list t)
 871           (coding
 872            (or coding-system-for-read
 873                (and set-auto-coding-function
 874                     (save-excursion
 875                       (funcall set-auto-coding-function
 876                                filename (- (point-max) (point-min)))))
 877                ;; dos-w32.el defines the function
 878                ;; find-buffer-file-type-coding-system for DOS/Windows
 879                ;; systems which preserves the coding-system of existing files.
 880                ;; (That function is called via file-coding-system-alist.)
 881                ;; Here, we want it to act as if the extracted file existed.
 882                ;; The following let-binding of file-name-handler-alist forces
 883                ;; find-file-not-found-set-buffer-file-coding-system to ignore
 884                ;; the file's name (see dos-w32.el).
 885                (let ((file-name-handler-alist
 886                       '(("" . archive-file-name-handler))))
 887                  (car (find-operation-coding-system
 888                        'insert-file-contents
 889                        (cons filename (current-buffer)) t))))))
 890       (if (and (not coding-system-for-read)
 891                (not enable-multibyte-characters))
 892           (setq coding
 893                 (coding-system-change-text-conversion coding 'raw-text)))
 894       (if (and coding
 895                (not (eq coding 'no-conversion)))
 896           (decode-coding-region (point-min) (point-max) coding)
 897         (setq last-coding-system-used coding))
 898       (set-buffer-modified-p nil)
 899       (kill-local-variable 'buffer-file-coding-system)
 900       (after-insert-file-set-coding (- (point-max) (point-min))))))
 901
 902 (define-obsolete-function-alias 'archive-mouse-extract 'archive-extract "22.1")
 903
 904 (defun archive-extract (&optional other-window-p event)
 905   "In archive mode, extract this entry of the archive into its own buffer."
 906   (interactive (list nil last-input-event))
 907   (if event (posn-set-point (event-end event)))
 908   (let* ((view-p (eq other-window-p 'view))
 909          (descr (archive-get-descr))
 910          (ename (aref descr 0))
 911          (iname (aref descr 1))
 912          (archive-buffer (current-buffer))
 913          (arcdir default-directory)
 914          (archive (buffer-file-name))
 915          (arcname (file-name-nondirectory archive))
 916          (bufname (concat (file-name-nondirectory iname) " (" arcname ")"))
 917          (extractor (archive-name "extract"))
 918          ;; Members with file names which aren't valid for the
 919          ;; underlying filesystem, are treated as read-only.
 920          (read-only-p (or archive-read-only
 921                           view-p
 922                           (string-match file-name-invalid-regexp ename)))
 923          (arcfilename (expand-file-name (concat arcname ":" iname)))
 924          (buffer (get-buffer bufname))
 925          (just-created nil))
 926       (if (and buffer
 927                (string= (buffer-file-name buffer) arcfilename))
 928           nil
 929         (setq archive (archive-maybe-copy archive))
 930         (setq bufname (generate-new-buffer-name bufname))
 931         (setq buffer (get-buffer-create bufname))
 932         (setq just-created t)
 933         (with-current-buffer buffer
 934           (setq buffer-file-name arcfilename)
 935           (setq buffer-file-truename
 936                 (abbreviate-file-name buffer-file-name))
 937           ;; Set the default-directory to the dir of the superior buffer.
 938           (setq default-directory arcdir)
 939           (make-local-variable 'archive-superior-buffer)
 940           (setq archive-superior-buffer archive-buffer)
 941           (add-hook 'write-file-functions 'archive-write-file-member nil t)
 942           (setq archive-subfile-mode descr)
 943           (if (and
 944                (null
 945                 (let (;; We may have to encode file name arguement for
 946                       ;; external programs.
 947                       (coding-system-for-write
 948                        (and enable-multibyte-characters
 949                             file-name-coding-system))
 950                       ;; We read an archive member by no-conversion at
 951                       ;; first, then decode appropriately by calling
 952                       ;; archive-set-buffer-as-visiting-file later.
 953                       (coding-system-for-read 'no-conversion))
 954                   (condition-case err
 955                       (if (fboundp extractor)
 956                           (funcall extractor archive ename)
 957                         (archive-*-extract archive ename
 958                                            (symbol-value extractor)))
 959                     (error
 960                      (ding (message "%s" (error-message-string err)))
 961                      nil))))
 962                just-created)
 963               (progn
 964                 (set-buffer-modified-p nil)
 965                 (kill-buffer buffer))
 966             (archive-set-buffer-as-visiting-file ename)
 967             (goto-char (point-min))
 968             (rename-buffer bufname)
 969             (setq buffer-read-only read-only-p)
 970             (setq buffer-undo-list nil)
 971             (set-buffer-modified-p nil)
 972             (setq buffer-saved-size (buffer-size))
 973             (normal-mode)
 974             ;; Just in case an archive occurs inside another archive.
 975             (when (derived-mode-p 'archive-mode)
 976               (setq archive-remote t)
 977               (if read-only-p (setq archive-read-only t))
 978               ;; We will write out the archive ourselves if it is
 979               ;; part of another archive.
 980               (remove-hook 'write-contents-functions 'archive-write-file t))
 981             (run-hooks 'archive-extract-hooks)
 982             (if archive-read-only
 983                 (message "Note: altering this archive is not implemented."))))
 984         (archive-maybe-update t))
 985       (or (not (buffer-name buffer))
 986           (cond
 987            (view-p (view-buffer buffer (and just-created 'kill-buffer)))
 988            ((eq other-window-p 'display) (display-buffer buffer))
 989            (other-window-p (switch-to-buffer-other-window buffer))
 990            (t (switch-to-buffer buffer))))))
 991
 992 (defun archive-*-extract (archive name command)
 993   (let* ((default-directory (file-name-as-directory archive-tmpdir))
 994          (tmpfile (expand-file-name (file-name-nondirectory name)
 995                                     default-directory))
 996          exit-status success)
 997     (make-directory (directory-file-name default-directory) t)
 998     (setq exit-status
 999           (apply 'call-process
1000                  (car command)
1001                  nil
1002                  nil
1003                  nil
1004                  (append (cdr command) (list archive name))))
1005     (cond ((and (numberp exit-status) (= exit-status 0))
1006            (if (not (file-exists-p tmpfile))
1007                (ding (message "`%s': no such file or directory" tmpfile))
1008              (insert-file-contents tmpfile)
1009              (setq success t)))
1010           ((numberp exit-status)
1011            (ding
1012             (message "`%s' exited with status %d" (car command) exit-status)))
1013           ((stringp exit-status)
1014            (ding (message "`%s' aborted: %s" (car command) exit-status)))
1015           (t
1016            (ding (message "`%s' failed" (car command)))))
1017     (archive-delete-local tmpfile)
1018     success))
1019
1020 (defun archive-extract-by-stdout (archive name command)
1021   (apply 'call-process
1022          (car command)
1023          nil
1024          t
1025          nil
1026          (append (cdr command) (list archive name))))
1027
1028 (defun archive-extract-other-window ()
1029   "In archive mode, find this member in another window."
1030   (interactive)
1031   (archive-extract t))
1032
1033 (defun archive-display-other-window ()
1034   "In archive mode, display this member in another window."
1035   (interactive)
1036   (archive-extract 'display))
1037
1038 (defun archive-view ()
1039   "In archive mode, view the member on this line."
1040   (interactive)
1041   (archive-extract 'view))
1042
1043 (defun archive-add-new-member (arcbuf name)
1044   "Add current buffer to the archive in ARCBUF naming it NAME."
1045   (interactive
1046    (list (get-buffer
1047           (read-buffer "Buffer containing archive: "
1048                        ;; Find first archive buffer and suggest that
1049                        (let ((bufs (buffer-list)))
1050                          (while (and bufs
1051                                      (not (with-current-buffer (car bufs)
1052                                             (derived-mode-p 'archive-mode))))
1053                            (setq bufs (cdr bufs)))
1054                          (if bufs
1055                              (car bufs)
1056                            (error "There are no archive buffers")))
1057                        t))
1058          (read-string "File name in archive: "
1059                       (if buffer-file-name
1060                           (file-name-nondirectory buffer-file-name)
1061                         ""))))
1062   (with-current-buffer arcbuf
1063     (or (eq major-mode 'archive-mode)
1064         (error "Buffer is not an archive buffer"))
1065     (if archive-read-only
1066         (error "Archive is read-only")))
1067   (if (eq arcbuf (current-buffer))
1068       (error "An archive buffer cannot be added to itself"))
1069   (if (string= name "")
1070       (error "Archive members may not be given empty names"))
1071   (let ((func (with-current-buffer arcbuf
1072                 (archive-name "add-new-member")))
1073         (membuf (current-buffer)))
1074     (if (fboundp func)
1075         (with-current-buffer arcbuf
1076           (funcall func buffer-file-name membuf name))
1077       (error "Adding a new member is not supported for this archive type"))))
1078 ;; -------------------------------------------------------------------------
1079 ;; Section: IO stuff
1080
1081 (defun archive-write-file-member ()
1082   (save-excursion
1083     (save-restriction
1084       (message "Updating archive...")
1085       (widen)
1086       (let ((writer  (with-current-buffer archive-superior-buffer
1087                        (archive-name "write-file-member")))
1088             (archive (with-current-buffer archive-superior-buffer
1089                        (archive-maybe-copy (buffer-file-name)))))
1090         (if (fboundp writer)
1091             (funcall writer archive archive-subfile-mode)
1092           (archive-*-write-file-member archive
1093                                        archive-subfile-mode
1094                                        (symbol-value writer)))
1095         (set-buffer-modified-p nil)
1096         (message "Updating archive...done"))
1097       (set-buffer archive-superior-buffer)
1098       (if (not archive-remote) (revert-buffer) (archive-maybe-update nil))))
1099   ;; Restore the value of last-coding-system-used, so that basic-save-buffer
1100   ;; won't reset the coding-system of this archive member.
1101   (if (local-variable-p 'archive-member-coding-system)
1102       (setq last-coding-system-used archive-member-coding-system))
1103   t)
1104
1105 (defun archive-*-write-file-member (archive descr command)
1106   (let* ((ename (aref descr 0))
1107          (tmpfile (expand-file-name ename archive-tmpdir))
1108          (top (directory-file-name (file-name-as-directory archive-tmpdir)))
1109          (default-directory (file-name-as-directory top)))
1110     (unwind-protect
1111         (progn
1112           (make-directory (file-name-directory tmpfile) t)
1113           ;; If the member is itself an archive, write it without
1114           ;; the dired-like listing we created.
1115           (if (eq major-mode 'archive-mode)
1116               (archive-write-file tmpfile)
1117             (write-region (point-min) (point-max) tmpfile nil 'nomessage))
1118           ;; basic-save-buffer needs last-coding-system-used to have
1119           ;; the value used to write the file, so save it before any
1120           ;; further processing clobbers it (we restore it in
1121           ;; archive-write-file-member, above).
1122           (setq archive-member-coding-system last-coding-system-used)
1123           (if (aref descr 3)
1124               ;; Set the file modes, but make sure we can read it.
1125               (set-file-modes tmpfile (logior ?\400 (aref descr 3))))
1126           (if enable-multibyte-characters
1127               (setq ename
1128                     (encode-coding-string ename file-name-coding-system)))
1129           (let ((exitcode (apply 'call-process
1130                                  (car command)
1131                                  nil
1132                                  nil
1133                                  nil
1134                                  (append (cdr command) (list archive ename)))))
1135             (if (equal exitcode 0)
1136                 nil
1137               (error "Updating was unsuccessful (%S)" exitcode))))
1138       (archive-delete-local tmpfile))))
1139
1140 (defun archive-write-file (&optional file)
1141   (save-excursion
1142     (let ((coding-system-for-write 'no-conversion))
1143       (write-region archive-proper-file-start (point-max)
1144                     (or file buffer-file-name) nil t)
1145       (set-buffer-modified-p nil))
1146     t))
1147 ;; -------------------------------------------------------------------------
1148 ;; Section: Marking and unmarking.
1149
1150 (defun archive-flag-deleted (p &optional type)
1151   "In archive mode, mark this member to be deleted from the archive.
1152 With a prefix argument, mark that many files."
1153   (interactive "p")
1154   (or type (setq type ?D))
1155   (beginning-of-line)
1156   (let ((sign (if (>= p 0) +1 -1))
1157         (modified (buffer-modified-p))
1158         (inhibit-read-only t))
1159     (while (not (zerop p))
1160       (if (archive-get-descr t)
1161           (progn
1162             (delete-char 1)
1163             (insert type)))
1164       (forward-line sign)
1165       (setq p (- p sign)))
1166     (restore-buffer-modified-p modified))
1167   (archive-next-line 0))
1168
1169 (defun archive-unflag (p)
1170   "In archive mode, un-mark this member if it is marked to be deleted.
1171 With a prefix argument, un-mark that many files forward."
1172   (interactive "p")
1173   (archive-flag-deleted p ?\s))
1174
1175 (defun archive-unflag-backwards (p)
1176   "In archive mode, un-mark this member if it is marked to be deleted.
1177 With a prefix argument, un-mark that many members backward."
1178   (interactive "p")
1179   (archive-flag-deleted (- p) ?\s))
1180
1181 (defun archive-unmark-all-files ()
1182   "Remove all marks."
1183   (interactive)
1184   (let ((modified (buffer-modified-p))
1185         (inhibit-read-only t))
1186     (save-excursion
1187       (goto-char archive-file-list-start)
1188       (while (< (point) archive-file-list-end)
1189         (or (= (following-char) ?\s)
1190             (progn (delete-char 1) (insert ?\s)))
1191         (forward-line 1)))
1192     (restore-buffer-modified-p modified)))
1193
1194 (defun archive-mark (p)
1195   "In archive mode, mark this member for group operations.
1196 With a prefix argument, mark that many members.
1197 Use \\[archive-unmark-all-files] to remove all marks."
1198   (interactive "p")
1199   (archive-flag-deleted p ?*))
1200
1201 (defun archive-get-marked (mark &optional default)
1202   (let (files)
1203     (save-excursion
1204       (goto-char archive-file-list-start)
1205       (while (< (point) archive-file-list-end)
1206         (if (= (following-char) mark)
1207             (setq files (cons (archive-get-descr) files)))
1208         (forward-line 1)))
1209     (or (nreverse files)
1210         (and default
1211              (list (archive-get-descr))))))
1212 ;; -------------------------------------------------------------------------
1213 ;; Section: Operate
1214
1215 (defun archive-next-line (p)
1216   (interactive "p")
1217   (forward-line p)
1218   (or (eobp)
1219       (forward-char archive-file-name-indent)))
1220
1221 (defun archive-previous-line (p)
1222   (interactive "p")
1223   (archive-next-line (- p)))
1224
1225 (defun archive-chmod-entry (new-mode)
1226   "Change the protection bits associated with all marked or this member.
1227 The new protection bits can either be specified as an octal number or
1228 as a relative change like \"g+rw\" as for chmod(2)."
1229   (interactive "sNew mode (octal or relative): ")
1230   (if archive-read-only (error "Archive is read-only"))
1231   (let ((func (archive-name "chmod-entry")))
1232     (if (fboundp func)
1233         (progn
1234           (funcall func new-mode (archive-get-marked ?* t))
1235           (archive-resummarize))
1236       (error "Setting mode bits is not supported for this archive type"))))
1237
1238 (defun archive-chown-entry (new-uid)
1239   "Change the owner of all marked or this member."
1240   (interactive "nNew uid: ")
1241   (if archive-read-only (error "Archive is read-only"))
1242   (let ((func (archive-name "chown-entry")))
1243     (if (fboundp func)
1244         (progn
1245           (funcall func new-uid (archive-get-marked ?* t))
1246           (archive-resummarize))
1247       (error "Setting owner is not supported for this archive type"))))
1248
1249 (defun archive-chgrp-entry (new-gid)
1250   "Change the group of all marked or this member."
1251   (interactive "nNew gid: ")
1252   (if archive-read-only (error "Archive is read-only"))
1253   (let ((func (archive-name "chgrp-entry")))
1254     (if (fboundp func)
1255         (progn
1256           (funcall func new-gid (archive-get-marked ?* t))
1257           (archive-resummarize))
1258       (error "Setting group is not supported for this archive type"))))
1259
1260 (defun archive-expunge ()
1261   "Do the flagged deletions."
1262   (interactive)
1263   (let (files)
1264     (save-excursion
1265       (goto-char archive-file-list-start)
1266       (while (< (point) archive-file-list-end)
1267         (if (= (following-char) ?D)
1268             (setq files (cons (aref (archive-get-descr) 0) files)))
1269         (forward-line 1)))
1270     (setq files (nreverse files))
1271     (and files
1272          (or (not archive-read-only)
1273              (error "Archive is read-only"))
1274          (or (yes-or-no-p (format "Really delete %d member%s? "
1275                                   (length files)
1276                                   (if (null (cdr files)) "" "s")))
1277              (error "Operation aborted"))
1278          (let ((archive (archive-maybe-copy (buffer-file-name)))
1279                (expunger (archive-name "expunge")))
1280            (if (fboundp expunger)
1281                (funcall expunger archive files)
1282              (archive-*-expunge archive files (symbol-value expunger)))
1283            (archive-maybe-update nil)
1284            (if archive-remote
1285                (archive-resummarize)
1286              (revert-buffer))))))
1287
1288 (defun archive-*-expunge (archive files command)
1289   (apply 'call-process
1290          (car command)
1291          nil
1292          nil
1293          nil
1294          (append (cdr command) (cons archive files))))
1295
1296 (defun archive-rename-entry (newname)
1297   "Change the name associated with this entry in the archive file."
1298   (interactive "sNew name: ")
1299   (if archive-read-only (error "Archive is read-only"))
1300   (if (string= newname "")
1301       (error "Archive members may not be given empty names"))
1302   (let ((func (archive-name "rename-entry"))
1303         (descr (archive-get-descr)))
1304     (if (fboundp func)
1305         (progn
1306           (funcall func
1307                    (if enable-multibyte-characters
1308                        (encode-coding-string newname file-name-coding-system)
1309                      newname)
1310                    descr)
1311           (archive-resummarize))
1312       (error "Renaming is not supported for this archive type"))))
1313
1314 ;; Revert the buffer and recompute the dired-like listing.
1315 (defun archive-mode-revert (&optional no-auto-save no-confirm)
1316   (let ((no (archive-get-lineno)))
1317     (setq archive-files nil)
1318     (let ((revert-buffer-function nil)
1319           (coding-system-for-read 'no-conversion))
1320       (set-buffer-multibyte nil)
1321       (revert-buffer t t))
1322     (archive-mode)
1323     (goto-char archive-file-list-start)
1324     (archive-next-line no)))
1325
1326 (defun archive-undo ()
1327   "Undo in an archive buffer.
1328 This doesn't recover lost files, it just undoes changes in the buffer itself."
1329   (interactive)
1330   (let ((inhibit-read-only t))
1331     (undo)))
1332 ;; -------------------------------------------------------------------------
1333 ;; Section: Arc Archives
1334
1335 (defun archive-arc-summarize ()
1336   (let ((p 1)
1337         (totalsize 0)
1338         (maxlen 8)
1339         files
1340         visual)
1341     (while (and (< (+ p 29) (point-max))
1342                 (= (char-after p) ?\C-z)
1343                 (> (char-after (1+ p)) 0))
1344       (let* ((namefld (buffer-substring (+ p 2) (+ p 2 13)))
1345              (fnlen   (or (string-match "\0" namefld) 13))
1346              (efnname (substring namefld 0 fnlen))
1347              ;; Convert to float to avoid overflow for very large files.
1348              (csize   (archive-l-e (+ p 15) 4 'float))
1349              (moddate (archive-l-e (+ p 19) 2))
1350              (modtime (archive-l-e (+ p 21) 2))
1351              (ucsize  (archive-l-e (+ p 25) 4 'float))
1352              (fiddle  (string= efnname (upcase efnname)))
1353              (ifnname (if fiddle (downcase efnname) efnname))
1354              (text    (format "  %8.0f  %-11s  %-8s  %s"
1355                               ucsize
1356                               (archive-dosdate moddate)
1357                               (archive-dostime modtime)
1358                               ifnname)))
1359         (setq maxlen (max maxlen fnlen)
1360               totalsize (+ totalsize ucsize)
1361               visual (cons (vector text
1362                                    (- (length text) (length ifnname))
1363                                    (length text))
1364                            visual)
1365               files (cons (vector efnname ifnname fiddle nil (1- p))
1366                           files)
1367               ;; p needs to stay an integer, since we use it in char-after
1368               ;; above.  Passing through `round' limits the compressed size
1369               ;; to most-positive-fixnum, but if the compressed size exceeds
1370               ;; that, we cannot visit the archive anyway.
1371               p (+ p 29 (round csize)))))
1372     (goto-char (point-min))
1373     (let ((dash (concat "- --------  -----------  --------  "
1374                         (make-string maxlen ?-)
1375                         "\n")))
1376       (insert "M   Length  Date         Time      File\n"
1377               dash)
1378       (archive-summarize-files (nreverse visual))
1379       (insert dash
1380               (format "  %8.0f                         %d file%s"
1381                       totalsize
1382                       (length files)
1383                       (if (= 1 (length files)) "" "s"))
1384               "\n"))
1385     (apply 'vector (nreverse files))))
1386
1387 (defun archive-arc-rename-entry (newname descr)
1388   (if (string-match "[:\\\\/]" newname)
1389       (error "File names in arc files must not contain a directory component"))
1390   (if (> (length newname) 12)
1391       (error "File names in arc files are limited to 12 characters"))
1392   (let ((name (concat newname (substring "\0\0\0\0\0\0\0\0\0\0\0\0\0"
1393                                          (length newname))))
1394         (inhibit-read-only t))
1395     (save-restriction
1396       (save-excursion
1397         (widen)
1398         (set-buffer-multibyte nil)
1399         (goto-char (+ archive-proper-file-start (aref descr 4) 2))
1400         (delete-char 13)
1401         (insert name)))))
1402 ;; -------------------------------------------------------------------------
1403 ;; Section: Lzh Archives
1404
1405 (defun archive-lzh-summarize (&optional start)
1406   (let ((p (or start 1)) ;; 1 for .lzh, something further on for .exe
1407         (totalsize 0)
1408         (maxlen 8)
1409         files
1410         visual)
1411     (while (progn (goto-char p)         ;beginning of a base header.
1412                   (looking-at "\\(.\\|\n\\)\\(.\\|\n\\)-l[hz][0-9ds]-"))
1413       (let* ((hsize   (char-after p))   ;size of the base header (level 0 and 1)
1414              ;; Convert to float to avoid overflow for very large files.
1415              (csize   (archive-l-e (+ p 7) 4 'float)) ;size of a compressed file to follow (level 0 and 2),
1416                                         ;size of extended headers + the compressed file to follow (level 1).
1417              (ucsize  (archive-l-e (+ p 11) 4 'float))  ;size of an uncompressed file.
1418              (time1   (archive-l-e (+ p 15) 2)) ;date/time (MSDOS format in level 0, 1 headers
1419              (time2   (archive-l-e (+ p 17) 2)) ;and UNIX format in level 2 header.)
1420              (hdrlvl  (char-after (+ p 20))) ;header level
1421              thsize             ;total header size (base + extensions)
1422              fnlen efnname osid fiddle ifnname width p2
1423              neh        ;beginning of next extension header (level 1 and 2)
1424              mode modestr uid gid text dir prname
1425              gname uname modtime moddate)
1426         (if (= hdrlvl 3) (error "can't handle lzh level 3 header type"))
1427         (when (or (= hdrlvl 0) (= hdrlvl 1))
1428           (setq fnlen   (char-after (+ p 21))) ;filename length
1429           (setq efnname (let ((str (buffer-substring (+ p 22) (+ p 22 fnlen)))) ;filename from offset 22
1430                         (if file-name-coding-system
1431                             (decode-coding-string str file-name-coding-system)
1432                           (string-as-multibyte str))))
1433           (setq p2      (+ p 22 fnlen))) ;
1434         (if (= hdrlvl 1)
1435             (setq neh (+ p2 3))         ;specific to level 1 header
1436           (if (= hdrlvl 2)
1437               (setq neh (+ p 24))))     ;specific to level 2 header
1438         (if neh         ;if level 1 or 2 we expect extension headers to follow
1439             (let* ((ehsize (archive-l-e neh 2)) ;size of the extension header
1440                    (etype (char-after (+ neh 2)))) ;extension type
1441               (while (not (= ehsize 0))
1442                   (cond
1443                  ((= etype 1)   ;file name
1444                   (let ((i (+ neh 3)))
1445                     (while (< i (+ neh ehsize))
1446                       (setq efnname (concat efnname (char-to-string (char-after i))))
1447                       (setq i (1+ i)))))
1448                  ((= etype 2)   ;directory name
1449                   (let ((i (+ neh 3)))
1450                     (while (< i (+ neh ehsize))
1451                                     (setq dir (concat dir
1452                                                        (if (= (char-after i)
1453                                                               255)
1454                                                            "/"
1455                                                          (char-to-string
1456                                                           (char-after i)))))
1457                                     (setq i (1+ i)))))
1458                  ((= etype 80)          ;Unix file permission
1459                   (setq mode (archive-l-e (+ neh 3) 2)))
1460                  ((= etype 81)          ;UNIX file group/user ID
1461                   (progn (setq uid (archive-l-e (+ neh 3) 2))
1462                          (setq gid (archive-l-e (+ neh 5) 2))))
1463                  ((= etype 82)          ;UNIX file group name
1464                   (let ((i (+ neh 3)))
1465                     (while (< i (+ neh ehsize))
1466                       (setq gname (concat gname (char-to-string (char-after i))))
1467                       (setq i (1+ i)))))
1468                  ((= etype 83)          ;UNIX file user name
1469                   (let ((i (+ neh 3)))
1470                     (while (< i (+ neh ehsize))
1471                       (setq uname (concat uname (char-to-string (char-after i))))
1472                       (setq i (1+ i)))))
1473                    )
1474                 (setq neh (+ neh ehsize))
1475                 (setq ehsize (archive-l-e neh 2))
1476                 (setq etype (char-after (+ neh 2))))
1477               ;;get total header size for level 1 and 2 headers
1478               (setq thsize (- neh p))))
1479         (if (= hdrlvl 0)  ;total header size
1480             (setq thsize hsize))
1481         ;; OS ID field not present in level 0 header, use code 0 "generic"
1482         ;; in that case as per lha program header.c get_header()
1483         (setq osid (cond ((= hdrlvl 0)  0)
1484                          ((= hdrlvl 1)  (char-after (+ p 22 fnlen 2)))
1485                          ((= hdrlvl 2)  (char-after (+ p 23)))))
1486         ;; Filename fiddling must follow the lha program, otherwise the name
1487         ;; passed to "lha pq" etc won't match (which for an extract silently
1488         ;; results in no output).  As of version 1.14i it goes from the OS ID,
1489         ;; - For 'M' MSDOS: msdos_to_unix_filename() downcases always, and
1490         ;;   converts "\" to "/".
1491         ;; - For 0 generic: generic_to_unix_filename() downcases if there's
1492         ;;   no lower case already present, and converts "\" to "/".
1493         ;; - For 'm' MacOS: macos_to_unix_filename() changes "/" to ":" and
1494         ;;   ":" to "/"
1495         (setq fiddle (cond ((= ?M osid) t)
1496                            ((= 0 osid)  (string= efnname (upcase efnname)))))
1497         (setq ifnname (if fiddle (downcase efnname) efnname))
1498         (setq prname (if dir (concat dir ifnname) ifnname))
1499         (setq width (if prname (string-width prname) 0))
1500         (setq modestr (if mode (archive-int-to-mode mode) "??????????"))
1501         (setq moddate (if (= hdrlvl 2)
1502                           (archive-unixdate time1 time2) ;level 2 header in UNIX format
1503                         (archive-dosdate time2))) ;level 0 and 1 header in DOS format
1504         (setq modtime (if (= hdrlvl 2)
1505                           (archive-unixtime time1 time2)
1506                         (archive-dostime time1)))
1507         (setq text    (if archive-alternate-display
1508                           (format "  %8.0f  %5S  %5S  %s"
1509                                   ucsize
1510                                   (or uid "?")
1511                                   (or gid "?")
1512                                   ifnname)
1513                         (format "  %10s  %8.0f  %-11s  %-8s  %s"
1514                                 modestr
1515                                 ucsize
1516                                 moddate
1517                                 modtime
1518                                 prname)))
1519         (setq maxlen (max maxlen width)
1520               totalsize (+ totalsize ucsize)
1521               visual (cons (vector text
1522                                    (- (length text) (length prname))
1523                                    (length text))
1524                            visual)
1525               files (cons (vector prname ifnname fiddle mode (1- p))
1526                           files))
1527         (cond ((= hdrlvl 1)
1528                ;; p needs to stay an integer, since we use it in goto-char
1529                ;; above.  Passing through `round' limits the compressed size
1530                ;; to most-positive-fixnum, but if the compressed size exceeds
1531                ;; that, we cannot visit the archive anyway.
1532                (setq p (+ p hsize 2 (round csize))))
1533               ((or (= hdrlvl 2) (= hdrlvl 0))
1534                (setq p (+ p thsize 2 (round csize)))))
1535         ))
1536     (goto-char (point-min))
1537     (set-buffer-multibyte default-enable-multibyte-characters)
1538     (let ((dash (concat (if archive-alternate-display
1539                             "- --------  -----  -----  "
1540                           "- ----------  --------  -----------  --------  ")
1541                         (make-string maxlen ?-)
1542                         "\n"))
1543           (header (if archive-alternate-display
1544                        "M   Length    Uid    Gid  File\n"
1545                     "M   Filemode    Length  Date         Time      File\n"))
1546           (sumline (if archive-alternate-display
1547                        "  %8.0f                %d file%s"
1548                      "              %8.0f                         %d file%s")))
1549       (insert header dash)
1550       (archive-summarize-files (nreverse visual))
1551       (insert dash
1552               (format sumline
1553                       totalsize
1554                       (length files)
1555                       (if (= 1 (length files)) "" "s"))
1556               "\n"))
1557     (apply 'vector (nreverse files))))
1558
1559 (defconst archive-lzh-alternate-display t)
1560
1561 (defun archive-lzh-extract (archive name)
1562   (archive-extract-by-stdout archive name archive-lzh-extract))
1563
1564 (defun archive-lzh-resum (p count)
1565   (let ((sum 0))
1566     (while (> count 0)
1567       (setq count (1- count)
1568             sum (+ sum (char-after p))
1569             p (1+ p)))
1570     (logand sum 255)))
1571
1572 (defun archive-lzh-rename-entry (newname descr)
1573   (save-restriction
1574     (save-excursion
1575       (widen)
1576       (set-buffer-multibyte nil)
1577       (let* ((p        (+ archive-proper-file-start (aref descr 4)))
1578              (oldhsize (char-after p))
1579              (oldfnlen (char-after (+ p 21)))
1580              (newfnlen (length newname))
1581              (newhsize (+ oldhsize newfnlen (- oldfnlen)))
1582              (inhibit-read-only t))
1583         (if (> newhsize 255)
1584             (error "The file name is too long"))
1585         (goto-char (+ p 21))
1586         (delete-char (1+ oldfnlen))
1587         (insert newfnlen newname)
1588         (goto-char p)
1589         (delete-char 2)
1590         (insert newhsize (archive-lzh-resum p newhsize))))))
1591
1592 (defun archive-lzh-ogm (newval files errtxt ofs)
1593   (save-excursion
1594     (save-restriction
1595       (widen)
1596       (set-buffer-multibyte nil)
1597       (dolist (fil files)
1598         (let* ((p (+ archive-proper-file-start (aref fil 4)))
1599                (hsize   (char-after p))
1600                (fnlen   (char-after (+ p 21)))
1601                (p2      (+ p 22 fnlen))
1602                (creator (if (>= (- hsize fnlen) 24) (char-after (+ p2 2)) 0))
1603                (inhibit-read-only t))
1604           (if (= creator ?U)
1605               (progn
1606                 (or (numberp newval)
1607                     (setq newval (funcall newval (archive-l-e (+ p2 ofs) 2))))
1608                 (goto-char (+ p2 ofs))
1609                 (delete-char 2)
1610                 (insert (logand newval 255) (lsh newval -8))
1611                 (goto-char (1+ p))
1612                 (delete-char 1)
1613                 (insert (archive-lzh-resum (1+ p) hsize)))
1614             (message "Member %s does not have %s field"
1615                      (aref fil 1) errtxt)))))))
1616
1617 (defun archive-lzh-chown-entry (newuid files)
1618   (archive-lzh-ogm newuid files "an uid" 10))
1619
1620 (defun archive-lzh-chgrp-entry (newgid files)
1621   (archive-lzh-ogm newgid files "a gid" 12))
1622
1623 (defun archive-lzh-chmod-entry (newmode files)
1624   (archive-lzh-ogm
1625    ;; This should work even though newmode will be dynamically accessed.
1626    (lambda (old) (archive-calc-mode old newmode t))
1627    files "a unix-style mode" 8))
1628
1629 ;; -------------------------------------------------------------------------
1630 ;; Section: Lzh Self-Extracting .exe Archives
1631 ;;
1632 ;; No support for modifying these files.  It looks like the lha for unix
1633 ;; program (as of version 1.14i) can't create or retain the DOS exe part.
1634 ;; If you do an "lha a" on a .exe for instance it renames and writes to a
1635 ;; plain .lzh.
1636
1637 (defun archive-lzh-exe-summarize ()
1638   "Summarize the contents of an LZH self-extracting exe, for `archive-mode'."
1639
1640   ;; Skip the initial executable code part and apply archive-lzh-summarize
1641   ;; to the archive part proper.  The "-lh5-" etc regexp here for the start
1642   ;; is the same as in archive-find-type.
1643   ;;
1644   ;; The lha program (version 1.14i) does this in skip_msdos_sfx1_code() by
1645   ;; a similar scan.  It looks for "..-l..-" plus for level 0 or 1 a test of
1646   ;; the header checksum, or level 2 a test of the "attribute" and size.
1647   ;;
1648   (re-search-forward "..-l[hz][0-9ds]-" nil)
1649   (archive-lzh-summarize (match-beginning 0)))
1650
1651 ;; `archive-lzh-extract' runs "lha pq", and that works for .exe as well as
1652 ;; .lzh files
1653 (defalias 'archive-lzh-exe-extract 'archive-lzh-extract
1654   "Extract a member from an LZH self-extracting exe, for `archive-mode'.")
1655
1656 ;; -------------------------------------------------------------------------
1657 ;; Section: Zip Archives
1658
1659 (defun archive-zip-summarize ()
1660   (goto-char (- (point-max) (- 22 18)))
1661   (search-backward-regexp "[P]K\005\006")
1662   (let ((p (+ (point-min) (archive-l-e (+ (point) 16) 4)))
1663         (maxlen 8)
1664         (totalsize 0)
1665         files
1666         visual)
1667     (while (string= "PK\001\002" (buffer-substring p (+ p 4)))
1668       (let* ((creator (char-after (+ p 5)))
1669              ;; (method  (archive-l-e (+ p 10) 2))
1670              (modtime (archive-l-e (+ p 12) 2))
1671              (moddate (archive-l-e (+ p 14) 2))
1672              ;; Convert to float to avoid overflow for very large files.
1673              (ucsize  (archive-l-e (+ p 24) 4 'float))
1674              (fnlen   (archive-l-e (+ p 28) 2))
1675              (exlen   (archive-l-e (+ p 30) 2))
1676              (fclen   (archive-l-e (+ p 32) 2))
1677              (lheader (archive-l-e (+ p 42) 4))
1678              (efnname (let ((str (buffer-substring (+ p 46) (+ p 46 fnlen))))
1679                         (if file-name-coding-system
1680                             (decode-coding-string str file-name-coding-system)
1681                           (string-as-multibyte str))))
1682              (isdir   (and (= ucsize 0)
1683                            (string= (file-name-nondirectory efnname) "")))
1684              (mode    (cond ((memq creator '(2 3)) ; Unix + VMS
1685                              (archive-l-e (+ p 40) 2))
1686                             ((memq creator '(0 5 6 7 10 11 15)) ; Dos etc.
1687                              (logior ?\444
1688                                      (if isdir (logior 16384 ?\111) 0)
1689                                      (if (zerop
1690                                           (logand 1 (char-after (+ p 38))))
1691                                          ?\222 0)))
1692                             (t nil)))
1693              (modestr (if mode (archive-int-to-mode mode) "??????????"))
1694              (fiddle  (and archive-zip-case-fiddle
1695                            (not (not (memq creator '(0 2 4 5 9))))
1696                            (string= (upcase efnname) efnname)))
1697              (ifnname (if fiddle (downcase efnname) efnname))
1698              (width (string-width ifnname))
1699              (text    (format "  %10s  %8.0f  %-11s  %-8s  %s"
1700                               modestr
1701                               ucsize
1702                               (archive-dosdate moddate)
1703                               (archive-dostime modtime)
1704                               ifnname)))
1705         (setq maxlen (max maxlen width)
1706               totalsize (+ totalsize ucsize)
1707               visual (cons (vector text
1708                                    (- (length text) (length ifnname))
1709                                    (length text))
1710                            visual)
1711               files (cons (if isdir
1712                               nil
1713                             (vector efnname ifnname fiddle mode
1714                                     (list (1- p) lheader)))
1715                           files)
1716               p (+ p 46 fnlen exlen fclen))))
1717     (goto-char (point-min))
1718     (let ((dash (concat "- ----------  --------  -----------  --------  "
1719                         (make-string maxlen ?-)
1720                         "\n")))
1721       (insert "M Filemode      Length  Date         Time      File\n"
1722               dash)
1723       (archive-summarize-files (nreverse visual))
1724       (insert dash
1725               (format "              %8.0f                         %d file%s"
1726                       totalsize
1727                       (length files)
1728                       (if (= 1 (length files)) "" "s"))
1729               "\n"))
1730     (apply 'vector (nreverse files))))
1731
1732 (defun archive-zip-extract (archive name)
1733   (if (equal (car archive-zip-extract) "pkzip")
1734       (archive-*-extract archive name archive-zip-extract)
1735     (archive-extract-by-stdout archive name archive-zip-extract)))
1736
1737 (defun archive-zip-write-file-member (archive descr)
1738   (archive-*-write-file-member
1739    archive
1740    descr
1741    (if (aref descr 2) archive-zip-update-case archive-zip-update)))
1742
1743 (defun archive-zip-chmod-entry (newmode files)
1744   (save-restriction
1745     (save-excursion
1746       (widen)
1747       (set-buffer-multibyte nil)
1748       (dolist (fil files)
1749         (let* ((p (+ archive-proper-file-start (car (aref fil 4))))
1750                (creator (char-after (+ p 5)))
1751                (oldmode (aref fil 3))
1752                (newval  (archive-calc-mode oldmode newmode t))
1753                (inhibit-read-only t))
1754           (cond ((memq creator '(2 3)) ; Unix + VMS
1755                  (goto-char (+ p 40))
1756                  (delete-char 2)
1757                  (insert (logand newval 255) (lsh newval -8)))
1758                 ((memq creator '(0 5 6 7 10 11 15)) ; Dos etc.
1759                  (goto-char (+ p 38))
1760                  (insert (logior (logand (char-after (point)) 254)
1761                                  (logand (logxor 1 (lsh newval -7)) 1)))
1762                  (delete-char 1))
1763                 (t (message "Don't know how to change mode for this member"))))
1764         ))))
1765 ;; -------------------------------------------------------------------------
1766 ;; Section: Zoo Archives
1767
1768 (defun archive-zoo-summarize ()
1769   (let ((p (1+ (archive-l-e 25 4)))
1770         (maxlen 8)
1771         (totalsize 0)
1772         files
1773         visual)
1774     (while (and (string= "\334\247\304\375" (buffer-substring p (+ p 4)))
1775                 (> (archive-l-e (+ p 6) 4) 0))
1776       (let* ((next    (1+ (archive-l-e (+ p 6) 4)))
1777              (moddate (archive-l-e (+ p 14) 2))
1778              (modtime (archive-l-e (+ p 16) 2))
1779              ;; Convert to float to avoid overflow for very large files.
1780              (ucsize  (archive-l-e (+ p 20) 4 'float))
1781              (namefld (buffer-substring (+ p 38) (+ p 38 13)))
1782              (dirtype (char-after (+ p 4)))
1783              (lfnlen  (if (= dirtype 2) (char-after (+ p 56)) 0))
1784              (ldirlen (if (= dirtype 2) (char-after (+ p 57)) 0))
1785              (fnlen   (or (string-match "\0" namefld) 13))
1786              (efnname (let ((str
1787                              (concat
1788                               (if (> ldirlen 0)
1789                                   (concat (buffer-substring
1790                                            (+ p 58 lfnlen)
1791                                            (+ p 58 lfnlen ldirlen -1))
1792                                           "/")
1793                                 "")
1794                               (if (> lfnlen 0)
1795                                   (buffer-substring (+ p 58)
1796                                                     (+ p 58 lfnlen -1))
1797                                 (substring namefld 0 fnlen)))))
1798                         (if file-name-coding-system
1799                             (decode-coding-string str file-name-coding-system)
1800                           (string-as-multibyte str))))
1801              (fiddle  (and (= lfnlen 0) (string= efnname (upcase efnname))))
1802              (ifnname (if fiddle (downcase efnname) efnname))
1803              (width (string-width ifnname))
1804              (text    (format "  %8.0f  %-11s  %-8s  %s"
1805                               ucsize
1806                               (archive-dosdate moddate)
1807                               (archive-dostime modtime)
1808                               ifnname)))
1809         (setq maxlen (max maxlen width)
1810               totalsize (+ totalsize ucsize)
1811               visual (cons (vector text
1812                                    (- (length text) (length ifnname))
1813                                    (length text))
1814                            visual)
1815               files (cons (vector efnname ifnname fiddle nil (1- p))
1816                           files)
1817               p next)))
1818     (goto-char (point-min))
1819     (let ((dash (concat "- --------  -----------  --------  "
1820                         (make-string maxlen ?-)
1821                         "\n")))
1822       (insert "M   Length  Date         Time      File\n"
1823               dash)
1824       (archive-summarize-files (nreverse visual))
1825       (insert dash
1826               (format "  %8.0f                         %d file%s"
1827                       totalsize
1828                       (length files)
1829                       (if (= 1 (length files)) "" "s"))
1830               "\n"))
1831     (apply 'vector (nreverse files))))
1832
1833 (defun archive-zoo-extract (archive name)
1834   (archive-extract-by-stdout archive name archive-zoo-extract))
1835 ;; -------------------------------------------------------------------------
1836 ;; This line was a mistake; it is kept now for compatibility.
1837 ;; rms  15 Oct 98
1838 (provide 'archive-mode)
1839
1840 (provide 'arc-mode)
1841
1842 ;; arch-tag: e5966a01-35ec-4f27-8095-a043a79b457b
1843 ;;; arc-mode.el ends here