lisp/tabify.el

   1 ;;; tabify.el --- tab conversion commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1994 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; Commands to optimize spaces to tabs or expand tabs to spaces in a region
  27 ;; (`tabify' and `untabify').  The variable tab-width does the obvious.
  28
  29 ;;; Code:
  30
  31 ;;;###autoload
  32 (defun untabify (start end)
  33   "Convert all tabs in region to multiple spaces, preserving columns.
  34 Called non-interactively, the region is specified by arguments
  35 START and END, rather than by the position of point and mark.
  36 The variable `tab-width' controls the spacing of tab stops."
  37   (interactive "r")
  38   (save-excursion
  39     (save-restriction
  40       (narrow-to-region (point-min) end)
  41       (goto-char start)
  42       (while (search-forward "\t" nil t)        ; faster than re-search
  43         (let ((tab-beg (point))
  44               (column (current-column))
  45               (indent-tabs-mode nil))
  46           (skip-chars-backward "\t" start)
  47           (delete-region tab-beg (point))
  48           (indent-to column))))))
  49
  50 ;;;###autoload
  51 (defun tabify (start end)
  52   "Convert multiple spaces in region to tabs when possible.
  53 A group of spaces is partially replaced by tabs
  54 when this can be done without changing the column they end at.
  55 Called non-interactively, the region is specified by arguments
  56 START and END, rather than by the position of point and mark.
  57 The variable `tab-width' controls the spacing of tab stops."
  58   (interactive "r")
  59   (save-excursion
  60     (save-restriction
  61       ;; Include the beginning of the line in the narrowing
  62       ;; since otherwise it will throw off current-column.
  63       (goto-char start)
  64       (beginning-of-line)
  65       (narrow-to-region (point) end)
  66       (goto-char start)
  67       (while (re-search-forward "[ \t][ \t][ \t]*" nil t)
  68         (let ((column (current-column))
  69               (indent-tabs-mode t))
  70           (delete-region (match-beginning 0) (point))
  71           (indent-to column))))))
  72
  73 (provide 'tabify)
  74
  75 ;;; tabify.el ends here