lisp/tutorial.el

   1 ;;; tutorial.el --- tutorial for Emacs
   2
   3 ;; Copyright (C) 2006, 2007 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: help, internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Code for running the Emacs tutorial.
  28
  29 ;;; History:
  30
  31 ;; File was created 2006-09.
  32
  33 ;;; Code:
  34
  35 (require 'help-mode) ;; for function help-buffer
  36
  37 (defface tutorial-warning-face
  38   '((t :inherit font-lock-warning-face))
  39   "Face used to highlight warnings in the tutorial."
  40   :group 'help)
  41
  42 (defvar tutorial--point-before-chkeys 0
  43   "Point before display of key changes.")
  44 (make-variable-buffer-local 'tutorial--point-before-chkeys)
  45
  46 (defvar tutorial--point-after-chkeys 0
  47   "Point after display of key changes.")
  48 (make-variable-buffer-local 'tutorial--point-after-chkeys)
  49
  50 (defvar tutorial--lang nil
  51   "Tutorial language.")
  52 (make-variable-buffer-local 'tutorial--lang)
  53
  54 (defun tutorial--describe-nonstandard-key (value)
  55   "Give more information about a changed key binding.
  56 This is used in `help-with-tutorial'.  The information includes
  57 the key sequence that no longer has a default binding, the
  58 default binding and the current binding.  It also tells in what
  59 keymap the new binding has been done and how to access the
  60 function in the default binding from the keyboard.
  61
  62 For `cua-mode' key bindings that try to combine CUA key bindings
  63 with default Emacs bindings information about this is shown.
  64
  65 VALUE should have either of these formats:
  66
  67   \(cua-mode)
  68   \(current-binding KEY-FUN DEF-FUN KEY WHERE)
  69
  70 Where
  71   KEY         is a key sequence whose standard binding has been changed
  72   KEY-FUN     is the actual binding for KEY
  73   DEF-FUN     is the standard binding of KEY
  74   WHERE       is a text describing the key sequences to which DEF-FUN is
  75               bound now (or, if it is remapped, a key sequence
  76               for the function it is remapped to)"
  77   (with-output-to-temp-buffer (help-buffer)
  78     (help-setup-xref (list #'tutorial--describe-nonstandard-key value)
  79                      (interactive-p))
  80     (with-current-buffer (help-buffer)
  81       (insert
  82        "Your Emacs customizations override the default binding for this key:"
  83        "\n\n")
  84       (let ((inhibit-read-only t))
  85         (cond
  86          ((eq (car value) 'cua-mode)
  87           (insert
  88            "CUA mode is enabled.
  89
  90 When CUA mode is enabled, you can use C-z, C-x, C-c, and C-v to
  91 undo, cut, copy, and paste in addition to the normal Emacs
  92 bindings.  The C-x and C-c keys only do cut and copy when the
  93 region is active, so in most cases, they do not conflict with the
  94 normal function of these prefix keys.
  95
  96 If you really need to perform a command which starts with one of
  97 the prefix keys even when the region is active, you have three
  98 options:
  99 - press the prefix key twice very quickly (within 0.2 seconds),
 100 - press the prefix key and the following key within 0.2 seconds, or
 101 - use the SHIFT key with the prefix key, i.e. C-S-x or C-S-c."))
 102          ((eq (car value) 'current-binding)
 103           (let ((cb    (nth 1 value))
 104                 (db    (nth 2 value))
 105                 (key   (nth 3 value))
 106                 (where (nth 4 value))
 107                 map
 108                 (maps (current-active-maps))
 109                 mapsym)
 110             ;; Look at the currently active keymaps and try to find
 111             ;; first the keymap where the current binding occurs:
 112             (while maps
 113               (let* ((m (car maps))
 114                      (mb (lookup-key m key t)))
 115                 (setq maps (cdr maps))
 116                 (when (eq mb cb)
 117                   (setq map m)
 118                   (setq maps nil))))
 119             ;; Now, if a keymap was found we must found the symbol
 120             ;; name for it to display to the user.  This can not
 121             ;; always be found since all keymaps does not have a
 122             ;; symbol pointing to them, but here they should have
 123             ;; that:
 124             (when map
 125               (mapatoms (lambda (s)
 126                           (and
 127                            ;; If not already found
 128                            (not mapsym)
 129                            ;; and if s is a keymap
 130                            (and (boundp s)
 131                                 (keymapp (symbol-value s)))
 132                            ;; and not the local symbol map
 133                            (not (eq s 'map))
 134                            ;; and the value of s is map
 135                            (eq map (symbol-value s))
 136                            ;; then save this value in mapsym
 137                            (setq mapsym s)))))
 138             (insert "The default Emacs binding for the key "
 139                     (key-description key)
 140                     " is the command `")
 141             (insert (format "%s" db))
 142             (insert "'.  "
 143                     "However, your customizations have rebound it to the command `")
 144             (insert (format "%s" cb))
 145             (insert "'.")
 146             (when mapsym
 147               (insert "  (For the more advanced user:"
 148                       " This binding is in the keymap `"
 149                       (format "%s" mapsym)
 150                       "'.)"))
 151             (if (string= where "")
 152                 (unless (keymapp db)
 153                   (insert "\n\nYou can use M-x "
 154                           (format "%s" db)
 155                           " RET instead."))
 156               (insert "\n\nWith your current key bindings"
 157                       " you can use "
 158                       (if (string-match "^the .*menus?$" where)
 159                           ""
 160                         "the key")
 161                       where
 162                       " to get the function `"
 163                       (format "%s" db)
 164                       "'.")))
 165           (fill-region (point-min) (point)))))
 166       (print-help-return-message))))
 167
 168 (defun tutorial--sort-keys (left right)
 169   "Sort predicate for use with `tutorial--default-keys'.
 170 This is a predicate function to `sort'.
 171
 172 The sorting is for presentation purpose only and is done on the
 173 key sequence.
 174
 175 LEFT and RIGHT are the elements to compare."
 176   (let ((x (append (cadr left)  nil))
 177         (y (append (cadr right) nil)))
 178     ;; Skip the front part of the key sequences if they are equal:
 179     (while (and x y
 180                 (listp x) (listp y)
 181                 (equal (car x) (car y)))
 182       (setq x (cdr x))
 183       (setq y (cdr y)))
 184     ;; Try to make a comparision that is useful for presentation (this
 185     ;; could be made nicer perhaps):
 186     (let ((cx (car x))
 187           (cy (car y)))
 188       ;;(message "x=%s, y=%s;;;; cx=%s, cy=%s" x y cx cy)
 189       (cond
 190        ;; Lists? Then call this again
 191        ((and cx cy
 192              (listp cx)
 193              (listp cy))
 194         (tutorial--sort-keys cx cy))
 195        ;; Are both numbers? Then just compare them
 196        ((and (wholenump cx)
 197              (wholenump cy))
 198         (> cx cy))
 199        ;; Is one of them a number? Let that be bigger then.
 200        ((wholenump cx)
 201         t)
 202        ((wholenump cy)
 203         nil)
 204        ;; Are both symbols? Compare the names then.
 205        ((and (symbolp cx)
 206              (symbolp cy))
 207         (string< (symbol-name cy)
 208                  (symbol-name cx)))))))
 209
 210 (defconst tutorial--default-keys
 211   ;; On window system, `suspend-emacs' is replaced in the default
 212   ;; keymap
 213   (let* ((suspend-emacs 'suspend-frame)
 214          (default-keys
 215            `((ESC-prefix [27])
 216              (Control-X-prefix [?\C-x])
 217              (mode-specific-command-prefix [?\C-c])
 218              (save-buffers-kill-terminal [?\C-x ?\C-c])
 219
 220              ;; * SUMMARY
 221              (scroll-up [?\C-v])
 222              (scroll-down [?\M-v])
 223              (recenter [?\C-l])
 224
 225              ;; * BASIC CURSOR CONTROL
 226              (forward-char [?\C-f])
 227              (backward-char [?\C-b])
 228              (forward-word [?\M-f])
 229              (backward-word [?\M-b])
 230              (next-line [?\C-n])
 231              (previous-line [?\C-p])
 232              (move-beginning-of-line [?\C-a])
 233              (move-end-of-line [?\C-e])
 234              (backward-sentence [?\M-a])
 235              (forward-sentence [?\M-e])
 236              (newline "\r")
 237              (beginning-of-buffer [?\M-<])
 238              (end-of-buffer [?\M->])
 239              (universal-argument [?\C-u])
 240
 241              ;; * WHEN EMACS IS HUNG
 242              (keyboard-quit [?\C-g])
 243
 244              ;; * DISABLED COMMANDS
 245              (downcase-region [?\C-x ?\C-l])
 246
 247              ;; * WINDOWS
 248              (delete-other-windows [?\C-x ?1])
 249              ;; C-u 0 C-l
 250              ;; Type CONTROL-h k CONTROL-f.
 251
 252              ;; * INSERTING AND DELETING
 253              ;; C-u 8 * to insert ********.
 254              (delete-backward-char "\d")
 255              (delete-char [?\C-d])
 256              (backward-kill-word [?\M-\d])
 257              (kill-word [?\M-d])
 258              (kill-line [?\C-k])
 259              (kill-sentence [?\M-k])
 260              (set-mark-command [?\C-@])
 261              (set-mark-command [?\C- ])
 262              (kill-region [?\C-w])
 263              (yank [?\C-y])
 264              (yank-pop [?\M-y])
 265
 266              ;; * UNDO
 267              (advertised-undo [?\C-x ?u])
 268              (advertised-undo [?\C-x ?u])
 269
 270              ;; * FILES
 271              (find-file [?\C-x ?\C-f])
 272              (save-buffer [?\C-x ?\C-s])
 273
 274              ;; * BUFFERS
 275              (list-buffers [?\C-x ?\C-b])
 276              (switch-to-buffer [?\C-x ?b])
 277              (save-some-buffers [?\C-x ?s])
 278
 279              ;; * EXTENDING THE COMMAND SET
 280              ;; C-x     Character eXtend.  Followed by one character.
 281              (execute-extended-command [?\M-x])
 282              ;; C-x C-f         Find file
 283              ;; C-x C-s         Save file
 284              ;; C-x s           Save some buffers
 285              ;; C-x C-b         List buffers
 286              ;; C-x b           Switch buffer
 287              ;; C-x C-c         Quit Emacs
 288              ;; C-x 1           Delete all but one window
 289              ;; C-x u           Undo
 290
 291              ;; * MODE LINE
 292              (describe-mode [?\C-h ?m])
 293              (set-fill-column [?\C-x ?f])
 294              (fill-paragraph-or-region [?\M-q])
 295
 296              ;; * SEARCHING
 297              (isearch-forward [?\C-s])
 298              (isearch-backward [?\C-r])
 299
 300              ;; * MULTIPLE WINDOWS
 301              (split-window-vertically [?\C-x ?2])
 302              (scroll-other-window [?\C-\M-v])
 303              (other-window [?\C-x ?o])
 304              (find-file-other-window [?\C-x ?4 ?\C-f])
 305
 306              ;; * RECURSIVE EDITING LEVELS
 307              (keyboard-escape-quit [27 27 27])
 308
 309              ;; * GETTING MORE HELP
 310              ;; The most basic HELP feature is C-h c
 311              (describe-key-briefly [?\C-h ?c])
 312              (describe-key [?\C-h ?k])
 313
 314              ;; * MORE FEATURES
 315              ;; F10
 316
 317              ;; * CONCLUSION
 318              ;;(iconify-or-deiconify-frame [?\C-z])
 319              (,suspend-emacs [?\C-z]))))
 320     (sort default-keys 'tutorial--sort-keys))
 321   "Default Emacs key bindings that the tutorial depends on.")
 322
 323 (defun tutorial--detailed-help (button)
 324   "Give detailed help about changed keys."
 325   (with-output-to-temp-buffer (help-buffer)
 326     (help-setup-xref (list #'tutorial--detailed-help button)
 327                      (interactive-p))
 328     (with-current-buffer (help-buffer)
 329       (let* ((tutorial-buffer  (button-get button 'tutorial-buffer))
 330              (explain-key-desc (button-get button 'explain-key-desc))
 331              (changed-keys (with-current-buffer tutorial-buffer
 332                              (save-excursion
 333                                (goto-char (point-min))
 334                                (tutorial--find-changed-keys
 335                                 tutorial--default-keys)))))
 336         (when changed-keys
 337           (insert
 338            "The following key bindings used in the tutorial have been changed
 339 from the Emacs default:\n\n" )
 340           (let ((frm "   %-14s %-27s %-16s\n"))
 341             (insert (format frm
 342                             "Standard Key" "Command" "In Your Emacs")))
 343           (dolist (tk changed-keys)
 344             (let* ((def-fun     (nth 1 tk))
 345                    (key         (nth 0 tk))
 346                    (def-fun-txt (nth 2 tk))
 347                    (where       (nth 3 tk))
 348                    (remark      (nth 4 tk))
 349                    (rem-fun (command-remapping def-fun))
 350                    (key-txt (key-description key))
 351                    (key-fun (with-current-buffer tutorial-buffer (key-binding key)))
 352                    tot-len)
 353               (unless (eq def-fun key-fun)
 354                 ;; Insert key binding description:
 355                 (when (string= key-txt explain-key-desc)
 356                   (put-text-property 0 (length key-txt)
 357                                      'face 'tutorial-warning-face key-txt))
 358                 (insert "   " key-txt " ")
 359                 (indent-to 18)
 360                 ;; Insert a link describing the old binding:
 361                 (insert-button def-fun-txt
 362                                'value def-fun
 363                                'action
 364                                (lambda (button) (interactive)
 365                                  (describe-function
 366                                   (button-get button 'value)))
 367                                'follow-link t)
 368                 (indent-to 45)
 369                 (when (listp where)
 370                   (setq where "list"))
 371                 ;; Tell where the old binding is now:
 372                 (insert (format " %-16s "
 373                                 (if (string= "" where)
 374                                     (format "M-x %s" def-fun-txt)
 375                                   where)))
 376                 ;; Insert a link with more information, for example
 377                 ;; current binding and keymap or information about
 378                 ;; cua-mode replacements:
 379                 (insert-button (car remark)
 380                                'action
 381                                (lambda (b) (interactive)
 382                                  (let ((value (button-get b 'value)))
 383                                    (tutorial--describe-nonstandard-key value)))
 384                                'value (cdr remark)
 385                                'follow-link t)
 386                 (insert "\n")))))
 387
 388         (insert "
 389 It is OK to change key bindings, but changed bindings do not
 390 correspond to what the tutorial says.\n\n")
 391         (print-help-return-message)))))
 392
 393 (defun tutorial--find-changed-keys (default-keys)
 394   "Find the key bindings used in the tutorial that have changed.
 395 Return a list with elements of the form
 396
 397   '(KEY DEF-FUN DEF-FUN-TXT WHERE REMARK QUIET)
 398
 399 where
 400
 401   KEY         is a key sequence whose standard binding has been changed
 402   DEF-FUN     is the standard binding of KEY
 403   DEF-FUN-TXT is a short descriptive text for DEF-FUN
 404   WHERE       is a text describing the key sequences to which DEF-FUN is
 405               bound now (or, if it is remapped, a key sequence
 406               for the function it is remapped to)
 407   REMARK      is a list with info about rebinding. It has either of
 408               these formats:
 409
 410                 \(TEXT cua-mode)
 411                 \(TEXT current-binding KEY-FUN DEF-FUN KEY WHERE)
 412
 413               Here TEXT is a link text to show to the user.  The
 414               rest of the list is used to show information when
 415               the user clicks the link.
 416
 417               KEY-FUN is the actual binding for KEY.
 418   QUIET       is t if this changed keybinding should be handled quietly.
 419               This is used by `tutorial--display-changes'."
 420   (let (changed-keys remark)
 421     ;; Look up the bindings in a Fundamental mode buffer
 422     ;; so we do not get fooled by some other major mode.
 423     (with-temp-buffer
 424       (fundamental-mode)
 425       (dolist (kdf default-keys)
 426         ;; The variables below corresponds to those with the same names
 427         ;; described in the doc string.
 428         (let* ((key     (nth 1 kdf))
 429                (def-fun (nth 0 kdf))
 430                (def-fun-txt (format "%s" def-fun))
 431                (rem-fun (command-remapping def-fun))
 432                ;; Handle prefix definitions specially
 433                ;; so that a mode that rebinds some subcommands
 434                ;; won't make it appear that the whole prefix is gone.
 435                (key-fun (if (eq def-fun 'ESC-prefix)
 436                             (lookup-key global-map [27])
 437                           (if (eq def-fun 'Control-X-prefix)
 438                               (lookup-key global-map [24])
 439                             (key-binding key))))
 440                (where (where-is-internal (if rem-fun rem-fun def-fun)))
 441                cwhere)
 442
 443           (if where
 444               (progn
 445                 (setq cwhere (car where)
 446                       where (key-description cwhere))
 447                 (when (and (< 10 (length where))
 448                            (string= (substring where 0 (length "<menu-bar>"))
 449                                     "<menu-bar>"))
 450                   (setq where
 451                         (if (and (vectorp cwhere)
 452                                  (setq cwhere (elt cwhere 1))
 453                                  (setq cwhere
 454                                        (cadr
 455                                         (assoc cwhere
 456                                                (lookup-key global-map
 457                                                            [menu-bar]))))
 458                                  (stringp cwhere))
 459                             (format "the `%s' menu" cwhere)
 460                           "the menus"))))
 461             (setq where ""))
 462           (setq remark nil)
 463           (unless
 464               (cond ((eq key-fun def-fun)
 465                      ;; No rebinding, return t
 466                      t)
 467                     ((and key-fun
 468                           (eq key-fun (command-remapping def-fun)))
 469                      ;; Just a remapping, return t
 470                      t)
 471                     ;; cua-mode specials:
 472                     ((and cua-mode
 473                           (or (and
 474                                (equal key [?\C-v])
 475                                (eq key-fun 'cua-paste))
 476                               (and
 477                                (equal key [?\C-z])
 478                                (eq key-fun 'undo))))
 479                      (setq remark (list "cua-mode, more info" 'cua-mode))
 480                      nil)
 481                     ((and cua-mode
 482                           (or (and (eq def-fun 'ESC-prefix)
 483                                    (equal key-fun
 484                                           `(keymap
 485                                             (118 . cua-repeat-replace-region)))
 486                                    (setq def-fun-txt "\"ESC prefix\""))
 487                               (and (eq def-fun 'mode-specific-command-prefix)
 488                                    (equal key-fun
 489                                           '(keymap
 490                                             (timeout . copy-region-as-kill)))
 491                                    (setq def-fun-txt "\"C-c prefix\""))
 492                               (and (eq def-fun 'Control-X-prefix)
 493                                    (equal key-fun
 494                                           '(keymap (timeout . kill-region)))
 495                                    (setq def-fun-txt "\"C-x prefix\""))))
 496                      (setq remark (list "cua-mode replacement" 'cua-mode))
 497                      (setq where "Same key")
 498                      nil)
 499                     ;; viper-mode specials:
 500                     ((and (boundp 'viper-mode-string)
 501                           (boundp 'viper-current-state)
 502                           (eq viper-current-state 'vi-state)
 503                           (or (and (eq def-fun 'isearch-forward)
 504                                    (eq key-fun 'viper-isearch-forward))
 505                               (and (eq def-fun 'isearch-backward)
 506                                    (eq key-fun 'viper-isearch-backward))))
 507                      ;; These bindings works as the default bindings,
 508                      ;; return t
 509                      t)
 510                     ((when normal-erase-is-backspace
 511                        (or (and (equal key [C-delete])
 512                                 (equal key-fun 'kill-word))
 513                            (and (equal key [C-backspace])
 514                                 (equal key-fun 'backward-kill-word))))
 515                      ;; This is the strange handling of C-delete and
 516                      ;; C-backspace, return t
 517                      t)
 518                     (t
 519                      ;; This key has indeed been rebound. Put information
 520                      ;; in `remark' and return nil
 521                      (setq remark
 522                            (list "more info" 'current-binding
 523                                  key-fun def-fun key where))
 524                      nil))
 525             (add-to-list 'changed-keys
 526                          (list key def-fun def-fun-txt where remark nil))))))
 527     changed-keys))
 528
 529 (defun tutorial--key-description (key)
 530   (let ((desc (key-description key)))
 531     (cond ((string= "ESC" desc) "<ESC>")
 532           ((string= "RET" desc) "<Return>")
 533           ((string= "DEL" desc) "<Delback>")
 534           (t desc))))
 535
 536 (defun tutorial--display-changes ()
 537   "Display changes to some default key bindings.
 538 If some of the default key bindings that the tutorial depends on
 539 have been changed then display the changes in the tutorial buffer
 540 with some explanatory links."
 541   (let* ((changed-keys (tutorial--find-changed-keys
 542                         tutorial--default-keys))
 543          ;; Alist of element (DESC . CK) where DESC is the
 544          ;; key-description of a changed key and CK is the
 545          ;; corresponding element in `changed-keys'.
 546          (changed-keys-alist
 547           (mapcar (lambda (ck) (cons (tutorial--key-description (car ck)) ck))
 548                   changed-keys))
 549          changed-key
 550          (start (point))
 551          (case-fold-search nil)
 552          (keybindings-regexp
 553           (concat "[[:space:]]\\("
 554                   (mapconcat (lambda (kdf) (regexp-quote
 555                                             (tutorial--key-description
 556                                              (nth 1 kdf))))
 557                              tutorial--default-keys
 558                              "\\|")
 559                   "\\)[[:punct:][:space:]]")))
 560     ;; Need the custom button face for viper buttons:
 561     (if (boundp 'viper-mode-string) (require 'cus-edit))
 562
 563     (if (or changed-keys (boundp 'viper-mode-string))
 564         (let ((head  (get-lang-string tutorial--lang 'tut-chgdhead))
 565               (head2 (get-lang-string tutorial--lang 'tut-chgdhead2)))
 566           (when (and head head2)
 567             (goto-char tutorial--point-before-chkeys)
 568             (insert head " [")
 569             (insert-button head2 'tutorial-buffer (current-buffer)
 570                            'action 'tutorial--detailed-help
 571                            'follow-link t 'face 'link)
 572             (insert "]\n\n")
 573             (add-text-properties tutorial--point-before-chkeys (point)
 574                                  '(tutorial-remark remark
 575                                    face tutorial-warning-face
 576                                    read-only t)))))
 577
 578     ;; Scan the tutorial for all key sequences.
 579     (goto-char (point-min))
 580     (while (re-search-forward keybindings-regexp (point-max) t)
 581       ;; Then highlight each rebound key sequence.
 582       ;; This avoids issuing a warning for, e.g., C-x C-b if C-b is rebound.
 583       (setq changed-key (assoc (match-string 1) changed-keys-alist))
 584       (and changed-key
 585            (not (get-text-property (match-beginning 1) 'tutorial-remark))
 586            (let* ((desc    (car changed-key))
 587                   (ck      (cdr changed-key))
 588                   (key     (nth 0 ck))
 589                   (def-fun (nth 1 ck))
 590                   (where   (nth 3 ck))
 591                   s1 s2 help-string)
 592              (unless (string= where "Same key")
 593                (when (string= where "")
 594                  (setq where (format "M-x %s" def-fun)))
 595                (setq tutorial--point-after-chkeys (point-marker)
 596                      s1 (get-lang-string tutorial--lang 'tut-chgdkey)
 597                      s2 (get-lang-string tutorial--lang 'tut-chgdkey2)
 598                      help-string (and s1 s2 (format s1 desc where)))
 599                (add-text-properties (match-beginning 1) (match-end 1)
 600                                     '(face tutorial-warning-face
 601                                       tutorial-remark key-sequence))
 602                (if help-string
 603                    (if (nth 5 ck)
 604                        ;; Put help string in the tooltip.
 605                        (put-text-property (match-beginning 1) (match-end 1)
 606                                           'help-echo help-string)
 607                      ;; Put help string in the buffer.
 608                      (save-excursion
 609                        (setcar (nthcdr 5 ck) t)
 610                        (forward-line)
 611                        ;; Two or more changed keys were on the same line.
 612                        (while (eq (get-text-property (point) 'tutorial-remark)
 613                                   'remark)
 614                          (forward-line))
 615                        (setq start (point))
 616                        (insert "** " help-string " [")
 617                        (insert-button s2 'tutorial-buffer (current-buffer)
 618                                       'action 'tutorial--detailed-help
 619                                       'explain-key-desc desc 'follow-link t
 620                                       'face 'link)
 621                        (insert "] **\n")
 622                        (add-text-properties start (point)
 623                                             '(tutorial-remark remark
 624                                               rear-nonsticky t
 625                                               face tutorial-warning-face
 626                                               read-only t)))))))))))
 627
 628 (defun tutorial--saved-dir ()
 629   "Directory to which tutorials are saved."
 630   (expand-file-name "tutorial" user-emacs-directory))
 631
 632 (defun tutorial--saved-file ()
 633   "File name in which to save tutorials."
 634   (let ((file-name tutorial--lang)
 635         (ext (file-name-extension tutorial--lang)))
 636     (when (or (not ext)
 637               (string= ext ""))
 638       (setq file-name (concat file-name ".tut")))
 639     (expand-file-name file-name (tutorial--saved-dir))))
 640
 641 (defun tutorial--remove-remarks ()
 642   "Remove the remark lines that was added to the tutorial buffer."
 643   (save-excursion
 644     (goto-char (point-min))
 645     (let (prop-start
 646           prop-end
 647           prop-val)
 648       ;; Catch the case when we already are on a remark line
 649       (while (if (get-text-property (point) 'tutorial-remark)
 650                  (setq prop-start (point))
 651                (setq prop-start (next-single-property-change (point) 'tutorial-remark)))
 652         (setq prop-end (next-single-property-change prop-start 'tutorial-remark))
 653         (setq prop-val (get-text-property prop-start 'tutorial-remark))
 654         (unless prop-end
 655           (setq prop-end (point-max)))
 656         (goto-char prop-end)
 657         (unless (eq prop-val 'key-sequence)
 658           (delete-region prop-start prop-end))))))
 659
 660 (defun tutorial--save-tutorial ()
 661   "Save the tutorial buffer.
 662 This saves the part of the tutorial before and after the area
 663 showing changed keys.  It also saves the point position and the
 664 position where the display of changed bindings was inserted."
 665   ;; This runs in a hook so protect it:
 666   (condition-case err
 667       (if (y-or-n-p "Save your position in the tutorial? ")
 668           (tutorial--save-tutorial-to (tutorial--saved-file)))
 669     (error (message "Error saving tutorial state: %s"
 670                     (error-message-string err)))))
 671
 672 (defun tutorial--save-tutorial-to (saved-file)
 673   "Save the tutorial buffer to SAVED-FILE.
 674 See `tutorial--save-tutorial' for more information."
 675   ;; Anything to save?
 676   (when (or (buffer-modified-p)
 677             (< 1 (point)))
 678     (let ((tutorial-dir (tutorial--saved-dir))
 679           save-err)
 680       ;; The tutorial is saved in a subdirectory in the user home
 681       ;; directory. Create this subdirectory first.
 682       (unless (file-directory-p tutorial-dir)
 683         (condition-case err
 684             (make-directory tutorial-dir nil)
 685           (error (setq save-err t)
 686                  (warn "Could not create directory %s: %s" tutorial-dir
 687                        (error-message-string err)))))
 688       ;; Make sure we have that directory.
 689       (if (file-directory-p tutorial-dir)
 690           (let ((tut-point (if (= 0 tutorial--point-after-chkeys)
 691                                ;; No info about changed keys is
 692                                ;; displayed.
 693                                (point)
 694                              (if (< (point) tutorial--point-after-chkeys)
 695                                  (- (point))
 696                                (- (point) tutorial--point-after-chkeys))))
 697                 (old-point (point))
 698                 ;; Use a special undo list so that we easily can undo
 699                 ;; the changes we make to the tutorial buffer.  This is
 700                 ;; currently not needed since we now delete the buffer
 701                 ;; after saving, but kept for possible future use of
 702                 ;; this function.
 703                 buffer-undo-list
 704                 (inhibit-read-only t))
 705             ;; Delete the area displaying info about changed keys.
 706             ;;             (when (< 0 tutorial--point-after-chkeys)
 707             ;;               (delete-region tutorial--point-before-chkeys
 708             ;;                              tutorial--point-after-chkeys))
 709             ;; Delete the remarks:
 710             (tutorial--remove-remarks)
 711             ;; Put the value of point first in the buffer so it will
 712             ;; be saved with the tutorial.
 713             (goto-char (point-min))
 714             (insert (number-to-string tut-point)
 715                     "\n"
 716                     (number-to-string (marker-position
 717                                        tutorial--point-before-chkeys))
 718                     "\n")
 719             (condition-case err
 720                 (write-region nil nil saved-file)
 721               (error (setq save-err t)
 722                      (warn "Could not save tutorial to %s: %s"
 723                            saved-file
 724                            (error-message-string err))))
 725             ;; An error is raised here?? Is this a bug?
 726             (condition-case err
 727                 (undo-only)
 728               (error nil))
 729             ;; Restore point
 730             (goto-char old-point)
 731             (if save-err
 732                 (message "Could not save tutorial state.")
 733               (message "Saved tutorial state.")))
 734         (message "Can't save tutorial: %s is not a directory"
 735                  tutorial-dir)))))
 736
 737
 738 ;;;###autoload
 739 (defun help-with-tutorial (&optional arg dont-ask-for-revert)
 740   "Select the Emacs learn-by-doing tutorial.
 741 If there is a tutorial version written in the language
 742 of the selected language environment, that version is used.
 743 If there's no tutorial in that language, `TUTORIAL' is selected.
 744 With ARG, you are asked to choose which language.
 745 If DONT-ASK-FOR-REVERT is non-nil the buffer is reverted without
 746 any question when restarting the tutorial.
 747
 748 If any of the standard Emacs key bindings that are used in the
 749 tutorial have been changed then an explanatory note about this is
 750 shown in the beginning of the tutorial buffer.
 751
 752 When the tutorial buffer is killed the content and the point
 753 position in the buffer is saved so that the tutorial may be
 754 resumed later."
 755   (interactive "P")
 756   (if (boundp 'viper-current-state)
 757       (let ((prompt1
 758              "You can not run the Emacs tutorial directly because you have \
 759 enabled Viper.")
 760             (prompt2 "\nThere is however a Viper tutorial you can run instead.
 761 Run the Viper tutorial? "))
 762         (if (fboundp 'viper-tutorial)
 763             (if (y-or-n-p (concat prompt1 prompt2))
 764                 (progn (message "")
 765                        (funcall 'viper-tutorial 0))
 766               (message "Tutorial aborted by user"))
 767           (message prompt1)))
 768     (let* ((lang (if arg
 769                      (let ((minibuffer-setup-hook minibuffer-setup-hook))
 770                        (add-hook 'minibuffer-setup-hook
 771                                  'minibuffer-completion-help)
 772                        (read-language-name 'tutorial "Language: " "English"))
 773                    (if (get-language-info current-language-environment 'tutorial)
 774                        current-language-environment
 775                      "English")))
 776            (filename (get-language-info lang 'tutorial))
 777            ;; Choose a buffer name including the language so that
 778            ;; several languages can be tested simultaneously:
 779            (tut-buf-name (concat "TUTORIAL (" lang ")"))
 780            (old-tut-buf (get-buffer tut-buf-name))
 781            (old-tut-win (when old-tut-buf (get-buffer-window old-tut-buf t)))
 782            (old-tut-is-ok (when old-tut-buf
 783                             (not (buffer-modified-p old-tut-buf))))
 784            old-tut-file
 785            (old-tut-point 1))
 786       (setq tutorial--point-after-chkeys (point-min))
 787       ;; Try to display the tutorial buffer before asking to revert it.
 788       ;; If the tutorial buffer is shown in some window make sure it is
 789       ;; selected and displayed:
 790       (if old-tut-win
 791           (raise-frame
 792            (window-frame
 793             (select-window (get-buffer-window old-tut-buf t))))
 794         ;; Else, is there an old tutorial buffer? Then display it:
 795         (when old-tut-buf
 796           (switch-to-buffer old-tut-buf)))
 797       ;; Use whole frame for tutorial
 798       (delete-other-windows)
 799       ;; If the tutorial buffer has been changed then ask if it should
 800       ;; be reverted:
 801       (when (and old-tut-buf
 802                  (not old-tut-is-ok))
 803         (setq old-tut-is-ok
 804               (if dont-ask-for-revert
 805                   nil
 806                 (not (y-or-n-p
 807                       "You have changed the Tutorial buffer.  Revert it? ")))))
 808       ;; (Re)build the tutorial buffer if it is not ok
 809       (unless old-tut-is-ok
 810         (switch-to-buffer (get-buffer-create tut-buf-name))
 811         (unless old-tut-buf (text-mode))
 812         (unless lang (error "Variable lang is nil"))
 813         (setq tutorial--lang lang)
 814         (setq old-tut-file (file-exists-p (tutorial--saved-file)))
 815         (let ((inhibit-read-only t))
 816           (erase-buffer))
 817         (message "Preparing tutorial ...") (sit-for 0)
 818
 819         ;; Do not associate the tutorial buffer with a file. Instead use
 820         ;; a hook to save it when the buffer is killed.
 821         (setq buffer-auto-save-file-name nil)
 822         (add-hook 'kill-buffer-hook 'tutorial--save-tutorial nil t)
 823
 824         ;; Insert the tutorial. First offer to resume last tutorial
 825         ;; editing session.
 826         (when dont-ask-for-revert
 827           (setq old-tut-file nil))
 828         (when old-tut-file
 829           (setq old-tut-file
 830                 (y-or-n-p "Resume your last saved tutorial? ")))
 831         (if old-tut-file
 832             (progn
 833               (insert-file-contents (tutorial--saved-file))
 834               (goto-char (point-min))
 835               (setq old-tut-point
 836                     (string-to-number
 837                      (buffer-substring-no-properties
 838                       (line-beginning-position) (line-end-position))))
 839               (forward-line)
 840               (setq tutorial--point-before-chkeys
 841                     (string-to-number
 842                      (buffer-substring-no-properties
 843                       (line-beginning-position) (line-end-position))))
 844               (forward-line)
 845               (delete-region (point-min) (point))
 846               (goto-char tutorial--point-before-chkeys)
 847               (setq tutorial--point-before-chkeys (point-marker)))
 848           (insert-file-contents (expand-file-name filename tutorial-directory))
 849           (forward-line)
 850           (setq tutorial--point-before-chkeys (point-marker)))
 851
 852         (tutorial--display-changes)
 853
 854         ;; Clear message:
 855         (unless dont-ask-for-revert
 856           (message "") (sit-for 0))
 857
 858
 859         (if old-tut-file
 860             ;; Just move to old point in saved tutorial.
 861             (let ((old-point
 862                    (if (> 0 old-tut-point)
 863                        (- old-tut-point)
 864                      (+ old-tut-point tutorial--point-after-chkeys))))
 865               (when (< old-point 1)
 866                 (setq old-point 1))
 867               (goto-char old-point))
 868           (goto-char (point-min))
 869           (search-forward "\n<<")
 870           (beginning-of-line)
 871           ;; Convert the <<...>> line to the proper [...] line,
 872           ;; or just delete the <<...>> line if a [...] line follows.
 873           (cond ((save-excursion
 874                    (forward-line 1)
 875                    (looking-at "\\["))
 876                  (delete-region (point) (progn (forward-line 1) (point))))
 877                 ((looking-at "<<Blank lines inserted.*>>")
 878                  (replace-match "[Middle of page left blank for didactic purposes.   Text continues below]"))
 879                 (t
 880                  (looking-at "<<")
 881                  (replace-match "[")
 882                  (search-forward ">>")
 883                  (replace-match "]")))
 884           (beginning-of-line)
 885           (let ((n (- (window-height (selected-window))
 886                       (count-lines (point-min) (point))
 887                       6)))
 888             (if (< n 8)
 889                 (progn
 890                   ;; For a short gap, we don't need the [...] line,
 891                   ;; so delete it.
 892                   (delete-region (point) (progn (end-of-line) (point)))
 893                   (newline n))
 894               ;; Some people get confused by the large gap.
 895               (newline (/ n 2))
 896
 897               ;; Skip the [...] line (don't delete it).
 898               (forward-line 1)
 899               (newline (- n (/ n 2)))))
 900           (goto-char (point-min)))
 901         (setq buffer-undo-list nil)
 902         (set-buffer-modified-p nil)))))
 903
 904
 905 ;; Below is some attempt to handle language specific strings. These
 906 ;; are currently only used in the tutorial.
 907
 908 (defconst lang-strings
 909   '(("English" .
 910      ((tut-chgdkey . "%s has been rebound, but you can use %s instead")
 911       (tut-chgdkey2 . "More")
 912       (tut-chgdhead . "
 913  NOTICE: The main purpose of the Emacs tutorial is to teach you
 914  the most important standard Emacs commands (key bindings).
 915  However, your Emacs has been customized by changing some of
 916  these basic editing commands, so it doesn't correspond to the
 917  tutorial.  We have inserted colored notices where the altered
 918  commands have been introduced.")
 919       (tut-chgdhead2 . "More"))))
 920   "Language specific strings for Emacs.
 921 This is an association list with the keys equal to the strings
 922 that can be returned by `read-language-name'.  The elements in
 923 the list are themselves association lists with keys that are
 924 string ids and values that are the language specific strings.
 925
 926 See `get-lang-string' for more information.")
 927
 928 (defun get-lang-string (lang stringid &optional no-eng-fallback)
 929   "Get a language specific string for Emacs.
 930 In certain places Emacs can replace a string shown to the user with
 931 a language specific string.  This function retrieves such strings.
 932
 933 LANG is the language specification. It should be one of those
 934 strings that can be returned by `read-language-name'.  STRINGID
 935 is a symbol that specifies the string to retrieve.
 936
 937 If no string is found for STRINGID in the chosen language then
 938 the English string is returned unless NO-ENG-FALLBACK is non-nil.
 939
 940 See `lang-strings' for more information.
 941
 942 Currently this feature is only used in `help-with-tutorial'."
 943   (let ((my-lang-strings (assoc lang lang-strings))
 944         (found-string))
 945     (when my-lang-strings
 946       (let ((entry (assoc stringid (cdr my-lang-strings))))
 947         (when entry
 948           (setq found-string (cdr entry)))))
 949     ;; Fallback to English strings
 950     (unless (or found-string
 951                 no-eng-fallback)
 952       (setq found-string (get-lang-string "English" stringid t)))
 953     found-string))
 954
 955 ;;(get-lang-string "English" 'tut-chgdkey)
 956
 957 (provide 'tutorial)
 958
 959 ;; arch-tag: c8e80aef-c3bb-4ffb-8af6-22171bf0c100
 960 ;;; tutorial.el ends here