lisp/avoid.el

   1 ;;; avoid.el --- make mouse pointer stay out of the way of editing
   2
   3 ;;; Copyright (C) 1993, 1994, 2000 Free Software Foundation, Inc.
   4
   5 ;; Author: Boris Goldowsky <boris@gnu.org>
   6 ;; Keywords: mouse
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; For those who are annoyed by the mouse pointer obscuring text,
  28 ;; this mode moves the mouse pointer - either just a little out of
  29 ;; the way, or all the way to the corner of the frame.
  30 ;; To use, load or evaluate this file and type M-x mouse-avoidance-mode .
  31 ;; To set up permanently, put the following in your .emacs:
  32 ;;
  33 ;; (if (display-mouse-p) (mouse-avoidance-mode 'animate))
  34 ;;
  35 ;; Other legitimate alternatives include
  36 ;; `banish', `exile', `jump', `cat-and-mouse', and `proteus'.
  37 ;; They do somewhat different things.
  38 ;; See the documentation for function `mouse-avoidance-mode' for
  39 ;; details of the different modes.
  40 ;;
  41 ;; For added silliness, make the animatee animate...
  42 ;; put something similar to the following into your .emacs:
  43 ;;
  44 ;; (if (eq window-system 'x)
  45 ;;     (mouse-avoidance-set-pointer-shape
  46 ;;           (eval (nth (random 4)
  47 ;;                      '(x-pointer-man x-pointer-spider
  48 ;;                        x-pointer-gobbler x-pointer-gumby)))))
  49 ;;
  50 ;; For completely random pointer shape, replace the setq above with:
  51 ;; (setq x-pointer-shape (mouse-avoidance-random-shape))
  52 ;;
  53 ;; Bugs / Warnings / To-Do:
  54 ;;
  55 ;; - Using this code does slow emacs down.  "banish" mode shouldn't
  56 ;;   be too bad, and on my workstation even "animate" is reasonable.
  57 ;;
  58 ;; - It ought to find out where any overlapping frames are and avoid them,
  59 ;;   rather than always raising the frame.
  60
  61 ;; Credits:
  62 ;; This code was helped by all those who contributed suggestions,
  63 ;;   fixes, and additions
  64 ;; Joe Harrington (and his advisor), for the original inspiration.
  65 ;; Ken Manheimer, for dreaming up the Protean mode.
  66 ;; Richard Stallman, for the awful cat-and-mouse pun, among other things.
  67 ;; Mike Williams, Denis Howe, Bill Benedetto, Chris Moore, Don Morris,
  68 ;; Simon Marshall, and M.S. Ashton, for their feedback.
  69
  70 ;;; Code:
  71
  72 (provide 'avoid)
  73
  74 (defgroup avoid nil
  75   "Make mouse pointer stay out of the way of editing."
  76   :prefix "mouse-avoidance-"
  77   :group 'mouse)
  78
  79 ;;;###autoload
  80 (defcustom mouse-avoidance-mode nil
  81   "Activate mouse avoidance mode.
  82 See function `mouse-avoidance-mode' for possible values.
  83 Setting this variable directly does not take effect;
  84 use either \\[customize] or the function `mouse-avoidance-mode'."
  85   :set (lambda (symbol value)
  86          ;; 'none below prevents toggling when value is nil.
  87          (mouse-avoidance-mode (or value 'none)))
  88   :initialize 'custom-initialize-default
  89   :type '(choice (const :tag "none" nil) (const banish) (const jump)
  90                  (const animate) (const exile) (const proteus)
  91                  )
  92   :group 'avoid
  93   :require 'avoid
  94   :version "20.3")
  95
  96
  97 (defcustom mouse-avoidance-nudge-dist 15
  98   "*Average distance that mouse will be moved when approached by cursor.
  99 Only applies in mouse-avoidance-mode `jump' and its derivatives.
 100 For best results make this larger than `mouse-avoidance-threshold'."
 101   :type 'integer
 102   :group 'avoid)
 103
 104 (defcustom mouse-avoidance-nudge-var 10
 105   "*Variability of `mouse-avoidance-nudge-dist' (which see)."
 106   :type 'integer
 107   :group 'avoid)
 108
 109 (defcustom mouse-avoidance-animation-delay .01
 110   "Delay between animation steps, in seconds."
 111   :type 'number
 112   :group 'avoid)
 113
 114 (defcustom mouse-avoidance-threshold 5
 115   "*Mouse-pointer's flight distance.
 116 If the cursor gets closer than this, the mouse pointer will move away.
 117 Only applies in mouse-avoidance-modes `animate' and `jump'."
 118   :type 'integer
 119   :group 'avoid)
 120
 121 ;; Internal variables
 122 (defvar mouse-avoidance-state nil)
 123 (defvar mouse-avoidance-pointer-shapes nil)
 124 (defvar mouse-avoidance-n-pointer-shapes 0)
 125 (defvar mouse-avoidance-old-pointer-shape nil)
 126
 127 ;; This timer is used to run something when Emacs is idle.
 128 (defvar mouse-avoidance-timer nil)
 129
 130 ;;; Functions:
 131
 132 (defsubst mouse-avoidance-set-pointer-shape (shape)
 133   "Set the shape of the mouse pointer to SHAPE."
 134   (when (boundp 'x-pointer-shape)
 135     (setq x-pointer-shape shape)
 136     (set-mouse-color nil)))
 137
 138 (defun mouse-avoidance-point-position ()
 139   "Return the position of point as (FRAME X . Y).
 140 Analogous to mouse-position."
 141   (let* ((w (selected-window))
 142          (edges (window-edges w))
 143          (list
 144           (compute-motion (max (window-start w) (point-min))   ; start pos
 145                           ;; window-start can be < point-min if the
 146                           ;; latter has changed since the last redisplay
 147                           '(0 . 0)                             ; start XY
 148                           (point)                              ; stop pos
 149                           (cons (window-width) (window-height)); stop XY: none
 150                           (1- (window-width))                  ; width
 151                           (cons (window-hscroll w) 0)          ; 0 may not be right?
 152                           (selected-window))))
 153     ;; compute-motion returns (pos HPOS VPOS prevhpos contin)
 154     ;; we want:               (frame hpos . vpos)
 155     (cons (selected-frame)
 156           (cons (+ (car edges)       (car (cdr list)))
 157                 (+ (car (cdr edges)) (car (cdr (cdr list))))))))
 158
 159 ;(defun mouse-avoidance-point-position-test ()
 160 ;  (interactive)
 161 ;  (message (format "point=%s mouse=%s"
 162 ;                  (cdr (mouse-avoidance-point-position))
 163 ;                  (cdr (mouse-position)))))
 164
 165 (defun mouse-avoidance-set-mouse-position (pos)
 166   ;; Carefully set mouse position to given position (X . Y)
 167   ;; Ideally, should check if X,Y is in the current frame, and if not,
 168   ;; leave the mouse where it was.  However, this is currently
 169   ;; difficult to do, so we just raise the frame to avoid frame switches.
 170   ;; Returns t if it moved the mouse.
 171   (let ((f (selected-frame)))
 172     (raise-frame f)
 173     (set-mouse-position f (car pos) (cdr pos))
 174     t))
 175
 176 (defun mouse-avoidance-too-close-p (mouse)
 177   "Return t if mouse pointer and point cursor are too close.
 178 MOUSE is the current mouse position as returned by `mouse-position'.
 179 Acceptable distance is defined by `mouse-avoidance-threshold'."
 180   (let* ((frame (car mouse))
 181          (mouse-y (cdr (cdr mouse)))
 182          (tool-bar-lines (frame-parameter nil 'tool-bar-lines)))
 183     (or tool-bar-lines
 184         (setq tool-bar-lines 0))
 185     (if (and mouse-y (< mouse-y tool-bar-lines))
 186         nil
 187       (let ((point (mouse-avoidance-point-position))
 188             (mouse-x (car (cdr mouse))))
 189         (and (eq frame (car point))
 190              (not (null mouse-x))
 191              (< (abs (- mouse-x (car (cdr point))))
 192                 mouse-avoidance-threshold)
 193              (< (abs (- mouse-y (cdr (cdr point))))
 194                 mouse-avoidance-threshold))))))
 195
 196 (defun mouse-avoidance-banish-destination ()
 197   "The position to which mouse-avoidance-mode `banish' moves the mouse.
 198 You can redefine this if you want the mouse banished to a different corner."
 199  (cons (1- (frame-width))
 200        0))
 201
 202 (defun mouse-avoidance-banish-mouse ()
 203   ;; Put the mouse pointer in the upper-right corner of the current frame.
 204   (mouse-avoidance-set-mouse-position (mouse-avoidance-banish-destination)))
 205
 206 (defsubst mouse-avoidance-delta (cur delta dist var min max)
 207   ;; Decide how far to move in either dimension.
 208   ;; Args are the CURRENT location, the desired DELTA for
 209   ;; warp-conservation, the DISTANCE we like to move, the VARIABILITY
 210   ;; in distance allowed, and the MIN and MAX possible window positions.
 211   ;; Returns something as close to DELTA as possible within the constraints.
 212   (let ((L1 (max (- min cur) (+ (- dist) (- var))))
 213         (R1                  (+ (- dist)    var ))
 214         (L2                  (+    dist  (- var)))
 215         (R2 (min (- max cur) (+    dist     var))))
 216     (if (< R1 (- min cur)) (setq L1 nil R1 nil))
 217     (if (> L2 (- max cur)) (setq L2 nil R2 nil))
 218     (cond ((and L1 (< delta L1)) L1)
 219           ((and R1 (< delta R1)) delta)
 220           ((and R1 (< delta 0)) R1)
 221           ((and L2 (< delta L2)) L2)
 222           ((and R2 (< delta R2)) delta)
 223           (R2)
 224           ((or R1 L2))
 225           (t 0))))
 226
 227 (defun mouse-avoidance-nudge-mouse ()
 228   ;; Push the mouse a little way away, possibly animating the move
 229   ;; For these modes, state keeps track of the total offset that we've
 230   ;; accumulated, and tries to keep it close to zero.
 231   (let* ((cur (mouse-position))
 232          (cur-frame (car cur))
 233          (cur-pos (cdr cur))
 234          (deltax (mouse-avoidance-delta
 235                   (car cur-pos) (- (random mouse-avoidance-nudge-var)
 236                                    (car mouse-avoidance-state))
 237                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 238                   0 (frame-width)))
 239          (deltay (mouse-avoidance-delta
 240                   (cdr cur-pos) (- (random mouse-avoidance-nudge-var)
 241                                    (cdr mouse-avoidance-state))
 242                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 243                   0 (frame-height))))
 244     (setq mouse-avoidance-state
 245           (cons (+ (car mouse-avoidance-state) deltax)
 246                 (+ (cdr mouse-avoidance-state) deltay)))
 247     (if (or (eq mouse-avoidance-mode 'animate)
 248             (eq mouse-avoidance-mode 'proteus))
 249         (let ((i 0.0))
 250           (while (<= i 1)
 251             (mouse-avoidance-set-mouse-position
 252              (cons (+ (car cur-pos) (round (* i deltax)))
 253                    (+ (cdr cur-pos) (round (* i deltay)))))
 254             (setq i (+ i (max .1 (/ 1.0 mouse-avoidance-nudge-dist))))
 255             (if (eq mouse-avoidance-mode 'proteus)
 256                 (mouse-avoidance-set-pointer-shape
 257                  (mouse-avoidance-random-shape)))
 258             (sit-for mouse-avoidance-animation-delay)))
 259       (mouse-avoidance-set-mouse-position (cons (+ (car (cdr cur)) deltax)
 260                                                 (+ (cdr (cdr cur)) deltay))))))
 261
 262 (defun mouse-avoidance-random-shape ()
 263   "Return a random cursor shape.
 264 This assumes that any variable whose name begins with x-pointer- and
 265 has an integer value is a valid cursor shape.  You might want to
 266 redefine this function to suit your own tastes."
 267   (if (null mouse-avoidance-pointer-shapes)
 268       (progn
 269         (setq mouse-avoidance-pointer-shapes
 270               (mapcar (lambda (x) (symbol-value (intern x)))
 271                       (all-completions "x-pointer-" obarray
 272                                        (lambda (x)
 273                                           (and (boundp x)
 274                                                (integerp (symbol-value x)))))))
 275         (setq mouse-avoidance-n-pointer-shapes
 276               (length mouse-avoidance-pointer-shapes))))
 277   (nth (random mouse-avoidance-n-pointer-shapes)
 278        mouse-avoidance-pointer-shapes))
 279
 280 (defun mouse-avoidance-banish-hook ()
 281   (if (and (not executing-kbd-macro)    ; don't check inside macro
 282            (cadr (mouse-position))      ; don't move unless in an Emacs frame
 283            ;; Don't do anything if last event was a mouse event.
 284            (not (and (consp last-input-event)
 285                      (symbolp (car last-input-event))
 286                      (let ((modifiers (event-modifiers (car last-input-event))))
 287                        (or (memq (car last-input-event)
 288                                  '(mouse-movement scroll-bar-movement))
 289                            (memq 'click modifiers)
 290                            (memq 'drag modifiers)
 291                            (memq 'down modifiers))))))
 292       (mouse-avoidance-banish-mouse)))
 293
 294 (defun mouse-avoidance-exile-hook ()
 295   ;; For exile mode, the state is nil when the mouse is in its normal
 296   ;; position, and set to the old mouse-position when the mouse is in exile.
 297   (if (and (not executing-kbd-macro)
 298            ;; Don't do anything if last event was a mouse event.
 299            (not (and (consp last-input-event)
 300                      (symbolp (car last-input-event))
 301                      (let ((modifiers (event-modifiers (car last-input-event))))
 302                        (or (memq (car last-input-event)
 303                                  '(mouse-movement scroll-bar-movement))
 304                            (memq 'click modifiers)
 305                            (memq 'drag modifiers)
 306                            (memq 'down modifiers))))))
 307       (let ((mp (mouse-position)))
 308         (cond ((and (not mouse-avoidance-state)
 309                     (mouse-avoidance-too-close-p mp))
 310                (setq mouse-avoidance-state mp)
 311                (mouse-avoidance-banish-mouse))
 312               ((and mouse-avoidance-state
 313                     (not (mouse-avoidance-too-close-p mouse-avoidance-state)))
 314                (if (and (eq (car mp) (selected-frame))
 315                         (equal (cdr mp) (mouse-avoidance-banish-destination)))
 316                    (mouse-avoidance-set-mouse-position
 317                     ;; move back only if user has not moved mouse
 318                     (cdr mouse-avoidance-state)))
 319                ;; but clear state anyway, to be ready for another move
 320                (setq mouse-avoidance-state nil))))))
 321
 322 (defun mouse-avoidance-fancy-hook ()
 323   ;; Used for the "fancy" modes, ie jump et al.
 324   (if (and (not executing-kbd-macro)    ; don't check inside macro
 325            ;; Don't do anything if last event was a mouse event.
 326            (not (and (consp last-input-event)
 327                      (symbolp (car last-input-event))
 328                      (let ((modifiers (event-modifiers (car last-input-event))))
 329                        (or (memq (car last-input-event)
 330                                  '(mouse-movement scroll-bar-movement))
 331                            (memq 'click modifiers)
 332                            (memq 'drag modifiers)
 333                            (memq 'down modifiers)))))
 334            (mouse-avoidance-too-close-p (mouse-position)))
 335       (let ((old-pos (mouse-position)))
 336         (mouse-avoidance-nudge-mouse)
 337         (if (not (eq (selected-frame) (car old-pos)))
 338             ;; This should never happen.
 339             (apply 'set-mouse-position old-pos)))))
 340
 341 ;;;###autoload
 342 (defun mouse-avoidance-mode (&optional mode)
 343   "Set cursor avoidance mode to MODE.
 344 MODE should be one of the symbols `banish', `exile', `jump', `animate',
 345 `cat-and-mouse', `proteus', or `none'.
 346
 347 If MODE is nil, toggle mouse avoidance between `none' and `banish'
 348 modes.  Positive numbers and symbols other than the above are treated
 349 as equivalent to `banish'; negative numbers and `-' are equivalent to `none'.
 350
 351 Effects of the different modes:
 352  * banish: Move the mouse to the upper-right corner on any keypress.
 353  * exile: Move the mouse to the corner only if the cursor gets too close,
 354      and allow it to return once the cursor is out of the way.
 355  * jump: If the cursor gets too close to the mouse, displace the mouse
 356      a random distance & direction.
 357  * animate: As `jump', but shows steps along the way for illusion of motion.
 358  * cat-and-mouse: Same as `animate'.
 359  * proteus: As `animate', but changes the shape of the mouse pointer too.
 360
 361 Whenever the mouse is moved, the frame is also raised.
 362
 363 \(see `mouse-avoidance-threshold' for definition of \"too close\",
 364 and `mouse-avoidance-nudge-dist' and `mouse-avoidance-nudge-var' for
 365 definition of \"random distance\".)"
 366   (interactive
 367    (list (intern (completing-read
 368                   "Select cursor avoidance technique (SPACE for list): "
 369                   '(("banish") ("exile") ("jump") ("animate")
 370                     ("cat-and-mouse") ("proteus") ("none"))
 371                   nil t))))
 372   (if (eq mode 'cat-and-mouse)
 373       (setq mode 'animate))
 374   (if mouse-avoidance-timer
 375       (cancel-timer mouse-avoidance-timer))
 376   (setq mouse-avoidance-timer nil)
 377
 378   ;; Restore pointer shape if necessary
 379   (if (eq mouse-avoidance-mode 'proteus)
 380       (mouse-avoidance-set-pointer-shape mouse-avoidance-old-pointer-shape))
 381
 382   ;; Do additional setup depending on version of mode requested
 383   (cond ((eq mode 'none)
 384          (setq mouse-avoidance-mode nil))
 385         ((or (eq mode 'jump)
 386              (eq mode 'animate)
 387              (eq mode 'proteus))
 388          (setq mouse-avoidance-timer
 389                (run-with-idle-timer 0.1 t 'mouse-avoidance-fancy-hook))
 390          (setq mouse-avoidance-mode mode
 391                mouse-avoidance-state (cons 0 0)
 392                mouse-avoidance-old-pointer-shape
 393                (and (boundp 'x-pointer-shape) x-pointer-shape)))
 394         ((eq mode 'exile)
 395          (setq mouse-avoidance-timer
 396                (run-with-idle-timer 0.1 t 'mouse-avoidance-exile-hook))
 397          (setq mouse-avoidance-mode mode
 398                mouse-avoidance-state nil))
 399         ((or (eq mode 'banish)
 400              (eq mode t)
 401              (and (null mode) (null mouse-avoidance-mode))
 402              (and mode (> (prefix-numeric-value mode) 0)))
 403          (setq mouse-avoidance-timer
 404                (run-with-idle-timer 0.1 t 'mouse-avoidance-banish-hook))
 405          (setq mouse-avoidance-mode 'banish))
 406         (t (setq mouse-avoidance-mode nil)))
 407   (force-mode-line-update))
 408
 409 ;; Most people who use avoid mode leave it on all the time, so it's not
 410 ;; very informative to announce it in the mode line.
 411 ;;(or (assq 'mouse-avoidance-mode minor-mode-alist)
 412 ;;    (setq minor-mode-alist (cons '(mouse-avoidance-mode " Avoid")
 413 ;;                               minor-mode-alist)))
 414
 415 ;; Needed for custom.
 416 (if mouse-avoidance-mode
 417     (mouse-avoidance-mode mouse-avoidance-mode))
 418
 419 ;;; avoid.el ends here