lib-src/b2m.pl

   1 #!/usr/bin/perl
   2
   3 # b2m.pl - Script to convert a Babyl file to an mbox file
   4
   5 # Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007
   6 #   Free Software Foundation, Inc.
   7
   8 # This program is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12
  13 # This program is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # General Public License for more details.
  17
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301
  21 # USA.
  22
  23 # Maintained by Jonathan Kamens <jik@kamens.brookline.ma.us>.
  24
  25 # Requires CPAN modules: MailTools (for Mail::Address), TimeDate (for
  26 # Date::Parse).
  27
  28 use warnings;
  29 use strict;
  30 use File::Basename;
  31 use Getopt::Long;
  32 use Mail::Address;
  33 use Date::Parse;
  34
  35 my($whoami) = basename $0;
  36 my($version) = '$Revision$';
  37 my($usage) = "Usage: $whoami [--help] [--version] [--[no]full-headers] [Babyl-file]
  38 \tBy default, full headers are printed.\n";
  39
  40 my($opt_help, $opt_version);
  41 my($opt_full_headers) = 1;
  42
  43 die $usage if (! GetOptions(
  44                             'help' => \$opt_help,
  45                             'version' => \$opt_version,
  46                             'full-headers!' => \$opt_full_headers,
  47                             ));
  48
  49 if ($opt_help) {
  50     print $usage;
  51     exit;
  52 }
  53 elsif ($opt_version) {
  54     print "$whoami version: $version\n";
  55     exit;
  56 }
  57
  58 die $usage if (@ARGV > 1);
  59
  60 $/ = "\n\037";
  61
  62 if (<> !~ /^BABYL OPTIONS:/) {
  63     die "$whoami: $ARGV is not a Babyl file\n$usage";
  64 }
  65
  66 while (<>) {
  67     my($msg_num) = $. - 1;
  68     my($labels, $pruned, $full_header, $header);
  69     my($from_line, $from_addr);
  70     my($time);
  71
  72     # This will strip the initial form feed, any whitespace that may
  73     # be following it, and then a newline
  74     s/^\s+//;
  75     # This will strip the ^_ off of the end of the message
  76     s/\037$//;
  77
  78     if (! s/(.*)\n//) {
  79       malformatted:
  80         warn "$whoami: message $msg_num in $ARGV is malformatted\n";
  81         next;
  82     }
  83     $labels = $1;
  84
  85     # Strip the integer indicating whether the header is pruned
  86     $labels =~ s/^(\d+)[,\s]*//;
  87     $pruned = $1;
  88
  89     s/(?:((?:.+\n)+)\n*)?\*\*\* EOOH \*\*\*\n+// || goto malformatted;
  90     $full_header = $1;
  91
  92     if (s/((?:.+\n)+)\n+//) {
  93         $header = $1;
  94     }
  95     else {
  96         # Message has no body
  97         $header = $_;
  98         $_ = '';
  99     }
 100
 101     # "$pruned eq '0'" is different from "! $pruned".  We want to make
 102     # sure that we found a valid label line which explicitly indicated
 103     # that the header was not pruned.
 104     if ((! $full_header) || ($pruned eq '0')) {
 105         $full_header = $header;
 106     }
 107
 108     # End message with two newlines (some mbox parsers require a blank
 109     # line before the next "From " line).
 110     s/\s+$/\n\n/;
 111
 112     # Quote "^From "
 113     s/(^|\n)From /$1>From /g;
 114
 115     # Strip extra commas and whitespace from the end
 116     $labels =~ s/[,\s]+$//;
 117     # Now collapse extra commas and whitespace in the remaining label string
 118     $labels =~ s/[,\s]+/, /g;
 119
 120     foreach my $rmail_header qw(summary-line x-coding-system) {
 121         $full_header =~ s/(^|\n)$rmail_header:.*\n/$1/i;
 122     }
 123
 124     if ($full_header =~ s/(^|\n)mail-from:\s*(From .*)\n/$1/i) {
 125         ($from_line = $2) =~ s/\s*$/\n/;
 126     }
 127     else {
 128         foreach my $addr_header qw(return-path from really-from sender) {
 129             if ($full_header =~ /(?:^|\n)$addr_header:\s*(.*\n(?:\B.*\n)*)/i) {
 130                 my($addr) = Mail::Address->parse($1);
 131                 $from_addr = $addr->address($addr);
 132                 last;
 133             }
 134         }
 135
 136         if (! $from_addr) {
 137             $from_addr = "Babyl_to_mail_by_$whoami\@localhost";
 138         }
 139
 140         if ($full_header =~ /(?:^|\n)date:\s*(\S.*\S)/i) {
 141             $time = str2time($1);
 142         }
 143
 144         if (! $time) {
 145             # No Date header or we failed to parse it
 146             $time = time;
 147         }
 148
 149         $from_line = "From " . $from_addr . " " . localtime($time) . "\n";
 150     }
 151
 152     print($from_line, ($opt_full_headers ? $full_header : $header),
 153           ($labels ? "X-Babyl-Labels: $labels\n" : ""), "\n",
 154           $_) || die "$whoami: error writing to stdout: $!\n";
 155 }
 156
 157 close(STDOUT) || die "$whoami: Error closing stdout: $!\n";
 158
 159 # arch-tag: 8c7c8ab0-721c-46d7-ba3e-139801240aa8