lisp/cmuscheme.el

   1 ;;; cmuscheme.el --- Scheme process in a buffer. Adapted from tea.el.
   2
   3 ;; Copyright (C) 1988, 1994, 1997 Free Software Foundation, Inc.
   4
   5 ;; Author: Olin Shivers <olin.shivers@cs.cmu.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: processes, lisp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;    This is a customisation of comint-mode (see comint.el)
  29 ;;
  30 ;; Written by Olin Shivers (olin.shivers@cs.cmu.edu). With bits and pieces
  31 ;; lifted from scheme.el, shell.el, clisp.el, newclisp.el, cobol.el, et al..
  32 ;; 8/88
  33 ;;
  34 ;; Please send me bug reports, bug fixes, and extensions, so that I can
  35 ;; merge them into the master source.
  36 ;;
  37 ;; The changelog is at the end of this file.
  38 ;;
  39 ;; NOTE: MIT Cscheme, when invoked with the -emacs flag, has a special user
  40 ;; interface that communicates process state back to the superior emacs by
  41 ;; outputting special control sequences. The gnumacs package, xscheme.el, has
  42 ;; lots and lots of special purpose code to read these control sequences, and
  43 ;; so is very tightly integrated with the cscheme process. The cscheme
  44 ;; interrupt handler and debugger read single character commands in cbreak
  45 ;; mode; when this happens, xscheme.el switches to special keymaps that bind
  46 ;; the single letter command keys to emacs functions that directly send the
  47 ;; character to the scheme process.  Cmuscheme mode does *not* provide this
  48 ;; functionality. If you are a cscheme user, you may prefer to use the
  49 ;; xscheme.el/cscheme -emacs interaction.
  50 ;;
  51 ;; Here's a summary of the pros and cons, as I see them.
  52 ;; xscheme: Tightly integrated with inferior cscheme process!  A few commands
  53 ;;           not in cmuscheme. But. Integration is a bit of a hack.  Input
  54 ;;           history only keeps the immediately prior input. Bizarre
  55 ;;           keybindings.
  56 ;;
  57 ;; cmuscheme: Not tightly integrated with inferior cscheme process.  But.
  58 ;;            Carefully integrated functionality with the entire suite of
  59 ;;            comint-derived CMU process modes. Keybindings reminiscent of
  60 ;;            Zwei and Hemlock. Good input history. A few commands not in
  61 ;;            xscheme.
  62 ;;
  63 ;; It's a tradeoff. Pay your money; take your choice. If you use a Scheme
  64 ;; that isn't Cscheme, of course, there isn't a choice. Xscheme.el is *very*
  65 ;; Cscheme-specific; you must use cmuscheme.el.  Interested parties are
  66 ;; invited to port xscheme functionality on top of comint mode...
  67
  68 ;;; CHANGE LOG
  69 ;;; ===========================================================================
  70 ;;; 8/88 Olin
  71 ;;; Created.
  72 ;;;
  73 ;;; 2/15/89 Olin
  74 ;;; Removed -emacs flag from process invocation. It's only useful for
  75 ;;; cscheme, and makes cscheme assume it's running under xscheme.el,
  76 ;;; which messes things up royally. A bug.
  77 ;;;
  78 ;;; 5/22/90 Olin
  79 ;;; - Upgraded to use comint-send-string and comint-send-region.
  80 ;;; - run-scheme now offers to let you edit the command line if
  81 ;;;   you invoke it with a prefix-arg. M-x scheme is redundant, and
  82 ;;;   has been removed.
  83 ;;; - Explicit references to process "scheme" have been replaced with
  84 ;;;   (scheme-proc). This allows better handling of multiple process bufs.
  85 ;;; - Added scheme-send-last-sexp, bound to C-x C-e. A gnu convention.
  86 ;;; - Have not added process query facility a la cmulisp.el's lisp-show-arglist
  87 ;;;   and friends, but interested hackers might find a useful application
  88 ;;;   of this facility.
  89 ;;;
  90 ;;; 3/12/90 Olin
  91 ;;; - scheme-load-file and scheme-compile-file no longer switch-to-scheme.
  92 ;;;   Tale suggested this.
  93
  94 ;;; Code:
  95
  96 (require 'scheme)
  97 (require 'comint)
  98
  99
 100 (defgroup cmuscheme nil
 101   "Run a scheme process in a buffer."
 102   :group 'lisp)
 103
 104 ;;; INFERIOR SCHEME MODE STUFF
 105 ;;;============================================================================
 106
 107 (defcustom inferior-scheme-mode-hook nil
 108   "*Hook for customising inferior-scheme mode."
 109   :type 'hook
 110   :group 'cmuscheme)
 111
 112 (defvar inferior-scheme-mode-map
 113   (let ((m (make-sparse-keymap)))
 114     (define-key m "\M-\C-x" 'scheme-send-definition) ;gnu convention
 115     (define-key m "\C-x\C-e" 'scheme-send-last-sexp)
 116     (define-key m "\C-c\C-l" 'scheme-load-file)
 117     (define-key m "\C-c\C-k" 'scheme-compile-file)
 118     (scheme-mode-commands m)
 119     m))
 120
 121 ;; Install the process communication commands in the scheme-mode keymap.
 122 (define-key scheme-mode-map "\M-\C-x" 'scheme-send-definition);gnu convention
 123 (define-key scheme-mode-map "\C-x\C-e" 'scheme-send-last-sexp);gnu convention
 124 (define-key scheme-mode-map "\C-c\C-e" 'scheme-send-definition)
 125 (define-key scheme-mode-map "\C-c\M-e" 'scheme-send-definition-and-go)
 126 (define-key scheme-mode-map "\C-c\C-r" 'scheme-send-region)
 127 (define-key scheme-mode-map "\C-c\M-r" 'scheme-send-region-and-go)
 128 (define-key scheme-mode-map "\C-c\M-c" 'scheme-compile-definition)
 129 (define-key scheme-mode-map "\C-c\C-c" 'scheme-compile-definition-and-go)
 130 (define-key scheme-mode-map "\C-c\C-z" 'switch-to-scheme)
 131 (define-key scheme-mode-map "\C-c\C-l" 'scheme-load-file)
 132 (define-key scheme-mode-map "\C-c\C-k" 'scheme-compile-file) ;k for "kompile"
 133
 134 (let ((map (lookup-key scheme-mode-map [menu-bar scheme])))
 135   (define-key map [separator-eval] '("--"))
 136   (define-key map [compile-file]
 137     '("Compile Scheme File" . scheme-compile-file))
 138   (define-key map [load-file]
 139     '("Load Scheme File" . scheme-load-file))
 140   (define-key map [switch]
 141     '("Switch to Scheme" . switch-to-scheme))
 142   (define-key map [com-def-go]
 143     '("Compile Definitiion & Go" . scheme-compile-definition-and-go))
 144   (define-key map [com-def]
 145     '("Compile Definitiion" . scheme-compile-definition))
 146   (define-key map [send-def-go]
 147     '("Evaluate Last Definition & Go" . scheme-send-definition-and-go))
 148   (define-key map [send-def]
 149     '("Evaluate Last Definition" . scheme-send-definition))
 150   (define-key map [send-region-go]
 151     '("Evaluate Region & Go" . scheme-send-region-and-go))
 152   (define-key map [send-region]
 153     '("Evaluate Region" . scheme-send-region))
 154   (define-key map [send-sexp]
 155     '("Evaluate Last S-expression" . scheme-send-last-sexp))
 156 )
 157
 158 (defvar scheme-buffer)
 159
 160 (define-derived-mode inferior-scheme-mode comint-mode "Inferior Scheme"
 161   "Major mode for interacting with an inferior Scheme process.
 162
 163 The following commands are available:
 164 \\{inferior-scheme-mode-map}
 165
 166 A Scheme process can be fired up with M-x run-scheme.
 167
 168 Customisation: Entry to this mode runs the hooks on comint-mode-hook and
 169 inferior-scheme-mode-hook (in that order).
 170
 171 You can send text to the inferior Scheme process from other buffers containing
 172 Scheme source.
 173     switch-to-scheme switches the current buffer to the Scheme process buffer.
 174     scheme-send-definition sends the current definition to the Scheme process.
 175     scheme-compile-definition compiles the current definition.
 176     scheme-send-region sends the current region to the Scheme process.
 177     scheme-compile-region compiles the current region.
 178
 179     scheme-send-definition-and-go, scheme-compile-definition-and-go,
 180         scheme-send-region-and-go, and scheme-compile-region-and-go
 181         switch to the Scheme process buffer after sending their text.
 182 For information on running multiple processes in multiple buffers, see
 183 documentation for variable scheme-buffer.
 184
 185 Commands:
 186 Return after the end of the process' output sends the text from the
 187     end of process to point.
 188 Return before the end of the process' output copies the sexp ending at point
 189     to the end of the process' output, and sends it.
 190 Delete converts tabs to spaces as it moves back.
 191 Tab indents for Scheme; with argument, shifts rest
 192     of expression rigidly with the current line.
 193 C-M-q does Tab on each line starting within following expression.
 194 Paragraphs are separated only by blank lines.  Semicolons start comments.
 195 If you accidentally suspend your process, use \\[comint-continue-subjob]
 196 to continue it."
 197   ;; Customise in inferior-scheme-mode-hook
 198   (setq comint-prompt-regexp "^[^>\n]*>+ *") ; OK for cscheme, oaklisp, T,...
 199   (scheme-mode-variables)
 200   (setq mode-line-process '(":%s"))
 201   (setq comint-input-filter (function scheme-input-filter))
 202   (setq comint-get-old-input (function scheme-get-old-input)))
 203
 204 (defcustom inferior-scheme-filter-regexp "\\`\\s *\\S ?\\S ?\\s *\\'"
 205   "*Input matching this regexp are not saved on the history list.
 206 Defaults to a regexp ignoring all inputs of 0, 1, or 2 letters."
 207   :type 'regexp
 208   :group 'cmuscheme)
 209
 210 (defun scheme-input-filter (str)
 211   "Don't save anything matching inferior-scheme-filter-regexp"
 212   (not (string-match inferior-scheme-filter-regexp str)))
 213
 214 (defun scheme-get-old-input ()
 215   "Snarf the sexp ending at point"
 216   (save-excursion
 217     (let ((end (point)))
 218       (backward-sexp)
 219       (buffer-substring (point) end))))
 220
 221 (defun scheme-args-to-list (string)
 222   (let ((where (string-match "[ \t]" string)))
 223     (cond ((null where) (list string))
 224           ((not (= where 0))
 225            (cons (substring string 0 where)
 226                  (scheme-args-to-list (substring string (+ 1 where)
 227                                                  (length string)))))
 228           (t (let ((pos (string-match "[^ \t]" string)))
 229                (if (null pos)
 230                    nil
 231                  (scheme-args-to-list (substring string pos
 232                                                  (length string)))))))))
 233
 234 (defcustom cmuscheme-program-name "scheme"
 235   "*Program invoked by the run-scheme command"
 236   :type 'string
 237   :group 'cmuscheme)
 238
 239 ;;;###autoload
 240 (defun run-scheme (cmd)
 241   "Run an inferior Scheme process, input and output via buffer *scheme*.
 242 If there is a process already running in `*scheme*', switch to that buffer.
 243 With argument, allows you to edit the command line (default is value
 244 of `cmuscheme-program-name').  Runs the hooks `inferior-scheme-mode-hook'
 245 \(after the `comint-mode-hook' is run).
 246 \(Type \\[describe-mode] in the process buffer for a list of commands.)"
 247
 248   (interactive (list (if current-prefix-arg
 249                          (read-string "Run Scheme: " cmuscheme-program-name)
 250                          cmuscheme-program-name)))
 251   (if (not (comint-check-proc "*scheme*"))
 252       (let ((cmdlist (scheme-args-to-list cmd)))
 253         (set-buffer (apply 'make-comint "scheme" (car cmdlist)
 254                            nil (cdr cmdlist)))
 255         (inferior-scheme-mode)))
 256   (setq cmuscheme-program-name cmd)
 257   (setq scheme-buffer "*scheme*")
 258   (pop-to-buffer "*scheme*"))
 259 ;;;###autoload (add-hook 'same-window-buffer-names "*scheme*")
 260
 261 (defun scheme-send-region (start end)
 262   "Send the current region to the inferior Scheme process."
 263   (interactive "r")
 264   (comint-send-region (scheme-proc) start end)
 265   (comint-send-string (scheme-proc) "\n"))
 266
 267 (defun scheme-send-definition ()
 268   "Send the current definition to the inferior Scheme process."
 269   (interactive)
 270   (save-excursion
 271    (end-of-defun)
 272    (let ((end (point)))
 273      (beginning-of-defun)
 274      (scheme-send-region (point) end))))
 275
 276 (defun scheme-send-last-sexp ()
 277   "Send the previous sexp to the inferior Scheme process."
 278   (interactive)
 279   (scheme-send-region (save-excursion (backward-sexp) (point)) (point)))
 280
 281 (defcustom scheme-compile-exp-command "(compile '%s)"
 282   "*Template for issuing commands to compile arbitrary Scheme expressions."
 283   :type 'string
 284   :group 'cmuscheme)
 285
 286 (defun scheme-compile-region (start end)
 287   "Compile the current region in the inferior Scheme process.
 288 \(A BEGIN is wrapped around the region: (BEGIN <region>))"
 289   (interactive "r")
 290   (comint-send-string (scheme-proc) (format scheme-compile-exp-command
 291                                             (format "(begin %s)"
 292                                                     (buffer-substring start end))))
 293   (comint-send-string (scheme-proc) "\n"))
 294
 295 (defun scheme-compile-definition ()
 296   "Compile the current definition in the inferior Scheme process."
 297   (interactive)
 298   (save-excursion
 299    (end-of-defun)
 300    (let ((end (point)))
 301      (beginning-of-defun)
 302      (scheme-compile-region (point) end))))
 303
 304 (defun switch-to-scheme (eob-p)
 305   "Switch to the scheme process buffer.
 306 With argument, positions cursor at end of buffer."
 307   (interactive "P")
 308   (if (get-buffer scheme-buffer)
 309       (pop-to-buffer scheme-buffer)
 310       (error "No current process buffer. See variable scheme-buffer."))
 311   (cond (eob-p
 312          (push-mark)
 313          (goto-char (point-max)))))
 314
 315 (defun scheme-send-region-and-go (start end)
 316   "Send the current region to the inferior Scheme process.
 317 Then switch to the process buffer."
 318   (interactive "r")
 319   (scheme-send-region start end)
 320   (switch-to-scheme t))
 321
 322 (defun scheme-send-definition-and-go ()
 323   "Send the current definition to the inferior Scheme.
 324 Then switch to the process buffer."
 325   (interactive)
 326   (scheme-send-definition)
 327   (switch-to-scheme t))
 328
 329 (defun scheme-compile-definition-and-go ()
 330   "Compile the current definition in the inferior Scheme.
 331 Then switch to the process buffer."
 332   (interactive)
 333   (scheme-compile-definition)
 334   (switch-to-scheme t))
 335
 336 (defun scheme-compile-region-and-go (start end)
 337   "Compile the current region in the inferior Scheme.
 338 Then switch to the process buffer."
 339   (interactive "r")
 340   (scheme-compile-region start end)
 341   (switch-to-scheme t))
 342
 343 (defcustom scheme-source-modes '(scheme-mode)
 344   "*Used to determine if a buffer contains Scheme source code.
 345 If it's loaded into a buffer that is in one of these major modes, it's
 346 considered a scheme source file by scheme-load-file and scheme-compile-file.
 347 Used by these commands to determine defaults."
 348   :type '(repeat function)
 349   :group 'cmuscheme)
 350
 351 (defvar scheme-prev-l/c-dir/file nil
 352   "Caches the last (directory . file) pair.
 353 Caches the last pair used in the last scheme-load-file or
 354 scheme-compile-file command. Used for determining the default in the
 355 next one.")
 356
 357 (defun scheme-load-file (file-name)
 358   "Load a Scheme file into the inferior Scheme process."
 359   (interactive (comint-get-source "Load Scheme file: " scheme-prev-l/c-dir/file
 360                                   scheme-source-modes t)) ; T because LOAD
 361                                                           ; needs an exact name
 362   (comint-check-source file-name) ; Check to see if buffer needs saved.
 363   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 364                                        (file-name-nondirectory file-name)))
 365   (comint-send-string (scheme-proc) (concat "(load \""
 366                                             file-name
 367                                             "\"\)\n")))
 368
 369 (defun scheme-compile-file (file-name)
 370   "Compile a Scheme file in the inferior Scheme process."
 371   (interactive (comint-get-source "Compile Scheme file: "
 372                                   scheme-prev-l/c-dir/file
 373                                   scheme-source-modes
 374                                   nil)) ; NIL because COMPILE doesn't
 375                                         ; need an exact name.
 376   (comint-check-source file-name) ; Check to see if buffer needs saved.
 377   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 378                                        (file-name-nondirectory file-name)))
 379   (comint-send-string (scheme-proc) (concat "(compile-file \""
 380                                             file-name
 381                                             "\"\)\n")))
 382
 383 \f
 384 (defvar scheme-buffer nil "*The current scheme process buffer.
 385
 386 MULTIPLE PROCESS SUPPORT
 387 ===========================================================================
 388 Cmuscheme.el supports, in a fairly simple fashion, running multiple Scheme
 389 processes. To run multiple Scheme processes, you start the first up with
 390 \\[run-scheme]. It will be in a buffer named *scheme*. Rename this buffer
 391 with \\[rename-buffer]. You may now start up a new process with another
 392 \\[run-scheme]. It will be in a new buffer, named *scheme*. You can
 393 switch between the different process buffers with \\[switch-to-buffer].
 394
 395 Commands that send text from source buffers to Scheme processes --
 396 like scheme-send-definition or scheme-compile-region -- have to choose a
 397 process to send to, when you have more than one Scheme process around. This
 398 is determined by the global variable scheme-buffer. Suppose you
 399 have three inferior Schemes running:
 400     Buffer      Process
 401     foo         scheme
 402     bar         scheme<2>
 403     *scheme*    scheme<3>
 404 If you do a \\[scheme-send-definition-and-go] command on some Scheme source
 405 code, what process do you send it to?
 406
 407 - If you're in a process buffer (foo, bar, or *scheme*),
 408   you send it to that process.
 409 - If you're in some other buffer (e.g., a source file), you
 410   send it to the process attached to buffer scheme-buffer.
 411 This process selection is performed by function scheme-proc.
 412
 413 Whenever \\[run-scheme] fires up a new process, it resets scheme-buffer
 414 to be the new process's buffer. If you only run one process, this will
 415 do the right thing. If you run multiple processes, you can change
 416 scheme-buffer to another process buffer with \\[set-variable].
 417
 418 More sophisticated approaches are, of course, possible. If you find yourself
 419 needing to switch back and forth between multiple processes frequently,
 420 you may wish to consider ilisp.el, a larger, more sophisticated package
 421 for running inferior Lisp and Scheme processes. The approach taken here is
 422 for a minimal, simple implementation. Feel free to extend it.")
 423
 424 (defun scheme-proc ()
 425   "Returns the current scheme process. See variable scheme-buffer."
 426   (let ((proc (get-buffer-process (if (eq major-mode 'inferior-scheme-mode)
 427                                       (current-buffer)
 428                                       scheme-buffer))))
 429     (or proc
 430         (error "No current process. See variable scheme-buffer"))))
 431
 432
 433 ;;; Do the user's customisation...
 434
 435 (defcustom cmuscheme-load-hook nil
 436   "This hook is run when cmuscheme is loaded in.
 437 This is a good place to put keybindings."
 438   :type 'hook
 439   :group 'cmuscheme)
 440
 441 (run-hooks 'cmuscheme-load-hook)
 442
 443 (provide 'cmuscheme)
 444
 445 ;;; cmuscheme.el ends here