lisp/emacs-lisp/cl-extra.el

   1 ;;; cl-extra.el --- Common Lisp features, part 2 -*-byte-compile-dynamic: t;-*-
   2
   3 ;; Copyright (C) 1993, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Author: Dave Gillespie <daveg@synaptics.com>
   7 ;; Keywords: extensions
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; These are extensions to Emacs Lisp that provide a degree of
  27 ;; Common Lisp compatibility, beyond what is already built-in
  28 ;; in Emacs Lisp.
  29 ;;
  30 ;; This package was written by Dave Gillespie; it is a complete
  31 ;; rewrite of Cesar Quiroz's original cl.el package of December 1986.
  32 ;;
  33 ;; Bug reports, comments, and suggestions are welcome!
  34
  35 ;; This file contains portions of the Common Lisp extensions
  36 ;; package which are autoloaded since they are relatively obscure.
  37
  38 ;;; Code:
  39
  40 (require 'cl)
  41
  42 ;;; Type coercion.
  43
  44 ;;;###autoload
  45 (defun coerce (x type)
  46   "Coerce OBJECT to type TYPE.
  47 TYPE is a Common Lisp type specifier.
  48 \n(fn OBJECT TYPE)"
  49   (cond ((eq type 'list) (if (listp x) x (append x nil)))
  50         ((eq type 'vector) (if (vectorp x) x (vconcat x)))
  51         ((eq type 'string) (if (stringp x) x (concat x)))
  52         ((eq type 'array) (if (arrayp x) x (vconcat x)))
  53         ((and (eq type 'character) (stringp x) (= (length x) 1)) (aref x 0))
  54         ((and (eq type 'character) (symbolp x)) (coerce (symbol-name x) type))
  55         ((eq type 'float) (float x))
  56         ((typep x type) x)
  57         (t (error "Can't coerce %s to type %s" x type))))
  58
  59
  60 ;;; Predicates.
  61
  62 ;;;###autoload
  63 (defun equalp (x y)
  64   "Return t if two Lisp objects have similar structures and contents.
  65 This is like `equal', except that it accepts numerically equal
  66 numbers of different types (float vs. integer), and also compares
  67 strings case-insensitively."
  68   (cond ((eq x y) t)
  69         ((stringp x)
  70          (and (stringp y) (= (length x) (length y))
  71               (or (string-equal x y)
  72                   (string-equal (downcase x) (downcase y)))))   ; lazy but simple!
  73         ((numberp x)
  74          (and (numberp y) (= x y)))
  75         ((consp x)
  76          (while (and (consp x) (consp y) (equalp (car x) (car y)))
  77            (setq x (cdr x) y (cdr y)))
  78          (and (not (consp x)) (equalp x y)))
  79         ((vectorp x)
  80          (and (vectorp y) (= (length x) (length y))
  81               (let ((i (length x)))
  82                 (while (and (>= (setq i (1- i)) 0)
  83                             (equalp (aref x i) (aref y i))))
  84                 (< i 0))))
  85         (t (equal x y))))
  86
  87
  88 ;;; Control structures.
  89
  90 ;;;###autoload
  91 (defun cl-mapcar-many (cl-func cl-seqs)
  92   (if (cdr (cdr cl-seqs))
  93       (let* ((cl-res nil)
  94              (cl-n (apply 'min (mapcar 'length cl-seqs)))
  95              (cl-i 0)
  96              (cl-args (copy-sequence cl-seqs))
  97              cl-p1 cl-p2)
  98         (setq cl-seqs (copy-sequence cl-seqs))
  99         (while (< cl-i cl-n)
 100           (setq cl-p1 cl-seqs cl-p2 cl-args)
 101           (while cl-p1
 102             (setcar cl-p2
 103                     (if (consp (car cl-p1))
 104                         (prog1 (car (car cl-p1))
 105                           (setcar cl-p1 (cdr (car cl-p1))))
 106                       (aref (car cl-p1) cl-i)))
 107             (setq cl-p1 (cdr cl-p1) cl-p2 (cdr cl-p2)))
 108           (push (apply cl-func cl-args) cl-res)
 109           (setq cl-i (1+ cl-i)))
 110         (nreverse cl-res))
 111     (let ((cl-res nil)
 112           (cl-x (car cl-seqs))
 113           (cl-y (nth 1 cl-seqs)))
 114       (let ((cl-n (min (length cl-x) (length cl-y)))
 115             (cl-i -1))
 116         (while (< (setq cl-i (1+ cl-i)) cl-n)
 117           (push (funcall cl-func
 118                             (if (consp cl-x) (pop cl-x) (aref cl-x cl-i))
 119                             (if (consp cl-y) (pop cl-y) (aref cl-y cl-i)))
 120                    cl-res)))
 121       (nreverse cl-res))))
 122
 123 ;;;###autoload
 124 (defun map (cl-type cl-func cl-seq &rest cl-rest)
 125   "Map a FUNCTION across one or more SEQUENCEs, returning a sequence.
 126 TYPE is the sequence type to return.
 127 \n(fn TYPE FUNCTION SEQUENCE...)"
 128   (let ((cl-res (apply 'mapcar* cl-func cl-seq cl-rest)))
 129     (and cl-type (coerce cl-res cl-type))))
 130
 131 ;;;###autoload
 132 (defun maplist (cl-func cl-list &rest cl-rest)
 133   "Map FUNCTION to each sublist of LIST or LISTs.
 134 Like `mapcar', except applies to lists and their cdr's rather than to
 135 the elements themselves.
 136 \n(fn FUNCTION LIST...)"
 137   (if cl-rest
 138       (let ((cl-res nil)
 139             (cl-args (cons cl-list (copy-sequence cl-rest)))
 140             cl-p)
 141         (while (not (memq nil cl-args))
 142           (push (apply cl-func cl-args) cl-res)
 143           (setq cl-p cl-args)
 144           (while cl-p (setcar cl-p (cdr (pop cl-p)) )))
 145         (nreverse cl-res))
 146     (let ((cl-res nil))
 147       (while cl-list
 148         (push (funcall cl-func cl-list) cl-res)
 149         (setq cl-list (cdr cl-list)))
 150       (nreverse cl-res))))
 151
 152 (defun cl-mapc (cl-func cl-seq &rest cl-rest)
 153   "Like `mapcar', but does not accumulate values returned by the function.
 154 \n(fn FUNCTION SEQUENCE...)"
 155   (if cl-rest
 156       (progn (apply 'map nil cl-func cl-seq cl-rest)
 157              cl-seq)
 158     (mapc cl-func cl-seq)))
 159
 160 ;;;###autoload
 161 (defun mapl (cl-func cl-list &rest cl-rest)
 162   "Like `maplist', but does not accumulate values returned by the function.
 163 \n(fn FUNCTION LIST...)"
 164   (if cl-rest
 165       (apply 'maplist cl-func cl-list cl-rest)
 166     (let ((cl-p cl-list))
 167       (while cl-p (funcall cl-func cl-p) (setq cl-p (cdr cl-p)))))
 168   cl-list)
 169
 170 ;;;###autoload
 171 (defun mapcan (cl-func cl-seq &rest cl-rest)
 172   "Like `mapcar', but nconc's together the values returned by the function.
 173 \n(fn FUNCTION SEQUENCE...)"
 174   (apply 'nconc (apply 'mapcar* cl-func cl-seq cl-rest)))
 175
 176 ;;;###autoload
 177 (defun mapcon (cl-func cl-list &rest cl-rest)
 178   "Like `maplist', but nconc's together the values returned by the function.
 179 \n(fn FUNCTION LIST...)"
 180   (apply 'nconc (apply 'maplist cl-func cl-list cl-rest)))
 181
 182 ;;;###autoload
 183 (defun some (cl-pred cl-seq &rest cl-rest)
 184   "Return true if PREDICATE is true of any element of SEQ or SEQs.
 185 If so, return the true (non-nil) value returned by PREDICATE.
 186 \n(fn PREDICATE SEQ...)"
 187   (if (or cl-rest (nlistp cl-seq))
 188       (catch 'cl-some
 189         (apply 'map nil
 190                (function (lambda (&rest cl-x)
 191                            (let ((cl-res (apply cl-pred cl-x)))
 192                              (if cl-res (throw 'cl-some cl-res)))))
 193                cl-seq cl-rest) nil)
 194     (let ((cl-x nil))
 195       (while (and cl-seq (not (setq cl-x (funcall cl-pred (pop cl-seq))))))
 196       cl-x)))
 197
 198 ;;;###autoload
 199 (defun every (cl-pred cl-seq &rest cl-rest)
 200   "Return true if PREDICATE is true of every element of SEQ or SEQs.
 201 \n(fn PREDICATE SEQ...)"
 202   (if (or cl-rest (nlistp cl-seq))
 203       (catch 'cl-every
 204         (apply 'map nil
 205                (function (lambda (&rest cl-x)
 206                            (or (apply cl-pred cl-x) (throw 'cl-every nil))))
 207                cl-seq cl-rest) t)
 208     (while (and cl-seq (funcall cl-pred (car cl-seq)))
 209       (setq cl-seq (cdr cl-seq)))
 210     (null cl-seq)))
 211
 212 ;;;###autoload
 213 (defun notany (cl-pred cl-seq &rest cl-rest)
 214   "Return true if PREDICATE is false of every element of SEQ or SEQs.
 215 \n(fn PREDICATE SEQ...)"
 216   (not (apply 'some cl-pred cl-seq cl-rest)))
 217
 218 ;;;###autoload
 219 (defun notevery (cl-pred cl-seq &rest cl-rest)
 220   "Return true if PREDICATE is false of some element of SEQ or SEQs.
 221 \n(fn PREDICATE SEQ...)"
 222   (not (apply 'every cl-pred cl-seq cl-rest)))
 223
 224 ;;; Support for `loop'.
 225 ;;;###autoload
 226 (defalias 'cl-map-keymap 'map-keymap)
 227
 228 ;;;###autoload
 229 (defun cl-map-keymap-recursively (cl-func-rec cl-map &optional cl-base)
 230   (or cl-base
 231       (setq cl-base (copy-sequence [0])))
 232   (map-keymap
 233    (function
 234     (lambda (cl-key cl-bind)
 235       (aset cl-base (1- (length cl-base)) cl-key)
 236       (if (keymapp cl-bind)
 237           (cl-map-keymap-recursively
 238            cl-func-rec cl-bind
 239            (vconcat cl-base (list 0)))
 240         (funcall cl-func-rec cl-base cl-bind))))
 241    cl-map))
 242
 243 ;;;###autoload
 244 (defun cl-map-intervals (cl-func &optional cl-what cl-prop cl-start cl-end)
 245   (or cl-what (setq cl-what (current-buffer)))
 246   (if (bufferp cl-what)
 247       (let (cl-mark cl-mark2 (cl-next t) cl-next2)
 248         (with-current-buffer cl-what
 249           (setq cl-mark (copy-marker (or cl-start (point-min))))
 250           (setq cl-mark2 (and cl-end (copy-marker cl-end))))
 251         (while (and cl-next (or (not cl-mark2) (< cl-mark cl-mark2)))
 252           (setq cl-next (if cl-prop (next-single-property-change
 253                                      cl-mark cl-prop cl-what)
 254                           (next-property-change cl-mark cl-what))
 255                 cl-next2 (or cl-next (with-current-buffer cl-what
 256                                        (point-max))))
 257           (funcall cl-func (prog1 (marker-position cl-mark)
 258                              (set-marker cl-mark cl-next2))
 259                    (if cl-mark2 (min cl-next2 cl-mark2) cl-next2)))
 260         (set-marker cl-mark nil) (if cl-mark2 (set-marker cl-mark2 nil)))
 261     (or cl-start (setq cl-start 0))
 262     (or cl-end (setq cl-end (length cl-what)))
 263     (while (< cl-start cl-end)
 264       (let ((cl-next (or (if cl-prop (next-single-property-change
 265                                       cl-start cl-prop cl-what)
 266                            (next-property-change cl-start cl-what))
 267                          cl-end)))
 268         (funcall cl-func cl-start (min cl-next cl-end))
 269         (setq cl-start cl-next)))))
 270
 271 ;;;###autoload
 272 (defun cl-map-overlays (cl-func &optional cl-buffer cl-start cl-end cl-arg)
 273   (or cl-buffer (setq cl-buffer (current-buffer)))
 274   (if (fboundp 'overlay-lists)
 275
 276       ;; This is the preferred algorithm, though overlay-lists is undocumented.
 277       (let (cl-ovl)
 278         (with-current-buffer cl-buffer
 279           (setq cl-ovl (overlay-lists))
 280           (if cl-start (setq cl-start (copy-marker cl-start)))
 281           (if cl-end (setq cl-end (copy-marker cl-end))))
 282         (setq cl-ovl (nconc (car cl-ovl) (cdr cl-ovl)))
 283         (while (and cl-ovl
 284                     (or (not (overlay-start (car cl-ovl)))
 285                         (and cl-end (>= (overlay-start (car cl-ovl)) cl-end))
 286                         (and cl-start (<= (overlay-end (car cl-ovl)) cl-start))
 287                         (not (funcall cl-func (car cl-ovl) cl-arg))))
 288           (setq cl-ovl (cdr cl-ovl)))
 289         (if cl-start (set-marker cl-start nil))
 290         (if cl-end (set-marker cl-end nil)))
 291
 292     ;; This alternate algorithm fails to find zero-length overlays.
 293     (let ((cl-mark (with-current-buffer cl-buffer
 294                      (copy-marker (or cl-start (point-min)))))
 295           (cl-mark2 (and cl-end (with-current-buffer cl-buffer
 296                                   (copy-marker cl-end))))
 297           cl-pos cl-ovl)
 298       (while (save-excursion
 299                (and (setq cl-pos (marker-position cl-mark))
 300                     (< cl-pos (or cl-mark2 (point-max)))
 301                     (progn
 302                       (set-buffer cl-buffer)
 303                       (setq cl-ovl (overlays-at cl-pos))
 304                       (set-marker cl-mark (next-overlay-change cl-pos)))))
 305         (while (and cl-ovl
 306                     (or (/= (overlay-start (car cl-ovl)) cl-pos)
 307                         (not (and (funcall cl-func (car cl-ovl) cl-arg)
 308                                   (set-marker cl-mark nil)))))
 309           (setq cl-ovl (cdr cl-ovl))))
 310       (set-marker cl-mark nil) (if cl-mark2 (set-marker cl-mark2 nil)))))
 311
 312 ;;; Support for `setf'.
 313 ;;;###autoload
 314 (defun cl-set-frame-visible-p (frame val)
 315   (cond ((null val) (make-frame-invisible frame))
 316         ((eq val 'icon) (iconify-frame frame))
 317         (t (make-frame-visible frame)))
 318   val)
 319
 320 ;;; Support for `progv'.
 321 (defvar cl-progv-save)
 322 ;;;###autoload
 323 (defun cl-progv-before (syms values)
 324   (while syms
 325     (push (if (boundp (car syms))
 326                  (cons (car syms) (symbol-value (car syms)))
 327                (car syms)) cl-progv-save)
 328     (if values
 329         (set (pop syms) (pop values))
 330       (makunbound (pop syms)))))
 331
 332 (defun cl-progv-after ()
 333   (while cl-progv-save
 334     (if (consp (car cl-progv-save))
 335         (set (car (car cl-progv-save)) (cdr (car cl-progv-save)))
 336       (makunbound (car cl-progv-save)))
 337     (pop cl-progv-save)))
 338
 339
 340 ;;; Numbers.
 341
 342 ;;;###autoload
 343 (defun gcd (&rest args)
 344   "Return the greatest common divisor of the arguments."
 345   (let ((a (abs (or (pop args) 0))))
 346     (while args
 347       (let ((b (abs (pop args))))
 348         (while (> b 0) (setq b (% a (setq a b))))))
 349     a))
 350
 351 ;;;###autoload
 352 (defun lcm (&rest args)
 353   "Return the least common multiple of the arguments."
 354   (if (memq 0 args)
 355       0
 356     (let ((a (abs (or (pop args) 1))))
 357       (while args
 358         (let ((b (abs (pop args))))
 359           (setq a (* (/ a (gcd a b)) b))))
 360       a)))
 361
 362 ;;;###autoload
 363 (defun isqrt (x)
 364   "Return the integer square root of the argument."
 365   (if (and (integerp x) (> x 0))
 366       (let ((g (cond ((<= x 100) 10) ((<= x 10000) 100)
 367                      ((<= x 1000000) 1000) (t x)))
 368             g2)
 369         (while (< (setq g2 (/ (+ g (/ x g)) 2)) g)
 370           (setq g g2))
 371         g)
 372     (if (eq x 0) 0 (signal 'arith-error nil))))
 373
 374 ;;;###autoload
 375 (defun floor* (x &optional y)
 376   "Return a list of the floor of X and the fractional part of X.
 377 With two arguments, return floor and remainder of their quotient."
 378   (let ((q (floor x y)))
 379     (list q (- x (if y (* y q) q)))))
 380
 381 ;;;###autoload
 382 (defun ceiling* (x &optional y)
 383   "Return a list of the ceiling of X and the fractional part of X.
 384 With two arguments, return ceiling and remainder of their quotient."
 385   (let ((res (floor* x y)))
 386     (if (= (car (cdr res)) 0) res
 387       (list (1+ (car res)) (- (car (cdr res)) (or y 1))))))
 388
 389 ;;;###autoload
 390 (defun truncate* (x &optional y)
 391   "Return a list of the integer part of X and the fractional part of X.
 392 With two arguments, return truncation and remainder of their quotient."
 393   (if (eq (>= x 0) (or (null y) (>= y 0)))
 394       (floor* x y) (ceiling* x y)))
 395
 396 ;;;###autoload
 397 (defun round* (x &optional y)
 398   "Return a list of X rounded to the nearest integer and the remainder.
 399 With two arguments, return rounding and remainder of their quotient."
 400   (if y
 401       (if (and (integerp x) (integerp y))
 402           (let* ((hy (/ y 2))
 403                  (res (floor* (+ x hy) y)))
 404             (if (and (= (car (cdr res)) 0)
 405                      (= (+ hy hy) y)
 406                      (/= (% (car res) 2) 0))
 407                 (list (1- (car res)) hy)
 408               (list (car res) (- (car (cdr res)) hy))))
 409         (let ((q (round (/ x y))))
 410           (list q (- x (* q y)))))
 411     (if (integerp x) (list x 0)
 412       (let ((q (round x)))
 413         (list q (- x q))))))
 414
 415 ;;;###autoload
 416 (defun mod* (x y)
 417   "The remainder of X divided by Y, with the same sign as Y."
 418   (nth 1 (floor* x y)))
 419
 420 ;;;###autoload
 421 (defun rem* (x y)
 422   "The remainder of X divided by Y, with the same sign as X."
 423   (nth 1 (truncate* x y)))
 424
 425 ;;;###autoload
 426 (defun signum (x)
 427   "Return 1 if X is positive, -1 if negative, 0 if zero."
 428   (cond ((> x 0) 1) ((< x 0) -1) (t 0)))
 429
 430
 431 ;; Random numbers.
 432
 433 (defvar *random-state*)
 434 ;;;###autoload
 435 (defun random* (lim &optional state)
 436   "Return a random nonnegative number less than LIM, an integer or float.
 437 Optional second arg STATE is a random-state object."
 438   (or state (setq state *random-state*))
 439   ;; Inspired by "ran3" from Numerical Recipes.  Additive congruential method.
 440   (let ((vec (aref state 3)))
 441     (if (integerp vec)
 442         (let ((i 0) (j (- 1357335 (% (abs vec) 1357333))) (k 1))
 443           (aset state 3 (setq vec (make-vector 55 nil)))
 444           (aset vec 0 j)
 445           (while (> (setq i (% (+ i 21) 55)) 0)
 446             (aset vec i (setq j (prog1 k (setq k (- j k))))))
 447           (while (< (setq i (1+ i)) 200) (random* 2 state))))
 448     (let* ((i (aset state 1 (% (1+ (aref state 1)) 55)))
 449            (j (aset state 2 (% (1+ (aref state 2)) 55)))
 450            (n (logand 8388607 (aset vec i (- (aref vec i) (aref vec j))))))
 451       (if (integerp lim)
 452           (if (<= lim 512) (% n lim)
 453             (if (> lim 8388607) (setq n (+ (lsh n 9) (random* 512 state))))
 454             (let ((mask 1023))
 455               (while (< mask (1- lim)) (setq mask (1+ (+ mask mask))))
 456               (if (< (setq n (logand n mask)) lim) n (random* lim state))))
 457         (* (/ n '8388608e0) lim)))))
 458
 459 ;;;###autoload
 460 (defun make-random-state (&optional state)
 461   "Return a copy of random-state STATE, or of `*random-state*' if omitted.
 462 If STATE is t, return a new state object seeded from the time of day."
 463   (cond ((null state) (make-random-state *random-state*))
 464         ((vectorp state) (cl-copy-tree state t))
 465         ((integerp state) (vector 'cl-random-state-tag -1 30 state))
 466         (t (make-random-state (cl-random-time)))))
 467
 468 ;;;###autoload
 469 (defun random-state-p (object)
 470   "Return t if OBJECT is a random-state object."
 471   (and (vectorp object) (= (length object) 4)
 472        (eq (aref object 0) 'cl-random-state-tag)))
 473
 474
 475 ;; Implementation limits.
 476
 477 (defun cl-finite-do (func a b)
 478   (condition-case err
 479       (let ((res (funcall func a b)))   ; check for IEEE infinity
 480         (and (numberp res) (/= res (/ res 2)) res))
 481     (arith-error nil)))
 482
 483 (defvar most-positive-float)
 484 (defvar most-negative-float)
 485 (defvar least-positive-float)
 486 (defvar least-negative-float)
 487 (defvar least-positive-normalized-float)
 488 (defvar least-negative-normalized-float)
 489 (defvar float-epsilon)
 490 (defvar float-negative-epsilon)
 491
 492 ;;;###autoload
 493 (defun cl-float-limits ()
 494   (or most-positive-float (not (numberp '2e1))
 495       (let ((x '2e0) y z)
 496         ;; Find maximum exponent (first two loops are optimizations)
 497         (while (cl-finite-do '* x x) (setq x (* x x)))
 498         (while (cl-finite-do '* x (/ x 2)) (setq x (* x (/ x 2))))
 499         (while (cl-finite-do '+ x x) (setq x (+ x x)))
 500         (setq z x y (/ x 2))
 501         ;; Now fill in 1's in the mantissa.
 502         (while (and (cl-finite-do '+ x y) (/= (+ x y) x))
 503           (setq x (+ x y) y (/ y 2)))
 504         (setq most-positive-float x
 505               most-negative-float (- x))
 506         ;; Divide down until mantissa starts rounding.
 507         (setq x (/ x z) y (/ 16 z) x (* x y))
 508         (while (condition-case err (and (= x (* (/ x 2) 2)) (> (/ y 2) 0))
 509                  (arith-error nil))
 510           (setq x (/ x 2) y (/ y 2)))
 511         (setq least-positive-normalized-float y
 512               least-negative-normalized-float (- y))
 513         ;; Divide down until value underflows to zero.
 514         (setq x (/ 1 z) y x)
 515         (while (condition-case err (> (/ x 2) 0) (arith-error nil))
 516           (setq x (/ x 2)))
 517         (setq least-positive-float x
 518               least-negative-float (- x))
 519         (setq x '1e0)
 520         (while (/= (+ '1e0 x) '1e0) (setq x (/ x 2)))
 521         (setq float-epsilon (* x 2))
 522         (setq x '1e0)
 523         (while (/= (- '1e0 x) '1e0) (setq x (/ x 2)))
 524         (setq float-negative-epsilon (* x 2))))
 525   nil)
 526
 527
 528 ;;; Sequence functions.
 529
 530 ;;;###autoload
 531 (defun subseq (seq start &optional end)
 532   "Return the subsequence of SEQ from START to END.
 533 If END is omitted, it defaults to the length of the sequence.
 534 If START or END is negative, it counts from the end."
 535   (if (stringp seq) (substring seq start end)
 536     (let (len)
 537       (and end (< end 0) (setq end (+ end (setq len (length seq)))))
 538       (if (< start 0) (setq start (+ start (or len (setq len (length seq))))))
 539       (cond ((listp seq)
 540              (if (> start 0) (setq seq (nthcdr start seq)))
 541              (if end
 542                  (let ((res nil))
 543                    (while (>= (setq end (1- end)) start)
 544                      (push (pop seq) res))
 545                    (nreverse res))
 546                (copy-sequence seq)))
 547             (t
 548              (or end (setq end (or len (length seq))))
 549              (let ((res (make-vector (max (- end start) 0) nil))
 550                    (i 0))
 551                (while (< start end)
 552                  (aset res i (aref seq start))
 553                  (setq i (1+ i) start (1+ start)))
 554                res))))))
 555
 556 ;;;###autoload
 557 (defun concatenate (type &rest seqs)
 558   "Concatenate, into a sequence of type TYPE, the argument SEQUENCEs.
 559 \n(fn TYPE SEQUENCE...)"
 560   (cond ((eq type 'vector) (apply 'vconcat seqs))
 561         ((eq type 'string) (apply 'concat seqs))
 562         ((eq type 'list) (apply 'append (append seqs '(nil))))
 563         (t (error "Not a sequence type name: %s" type))))
 564
 565
 566 ;;; List functions.
 567
 568 ;;;###autoload
 569 (defun revappend (x y)
 570   "Equivalent to (append (reverse X) Y)."
 571   (nconc (reverse x) y))
 572
 573 ;;;###autoload
 574 (defun nreconc (x y)
 575   "Equivalent to (nconc (nreverse X) Y)."
 576   (nconc (nreverse x) y))
 577
 578 ;;;###autoload
 579 (defun list-length (x)
 580   "Return the length of list X.  Return nil if list is circular."
 581   (let ((n 0) (fast x) (slow x))
 582     (while (and (cdr fast) (not (and (eq fast slow) (> n 0))))
 583       (setq n (+ n 2) fast (cdr (cdr fast)) slow (cdr slow)))
 584     (if fast (if (cdr fast) nil (1+ n)) n)))
 585
 586 ;;;###autoload
 587 (defun tailp (sublist list)
 588   "Return true if SUBLIST is a tail of LIST."
 589   (while (and (consp list) (not (eq sublist list)))
 590     (setq list (cdr list)))
 591   (if (numberp sublist) (equal sublist list) (eq sublist list)))
 592
 593 (defalias 'cl-copy-tree 'copy-tree)
 594
 595
 596 ;;; Property lists.
 597
 598 ;;;###autoload
 599 (defun get* (sym tag &optional def)    ; See compiler macro in cl-macs.el
 600   "Return the value of SYMBOL's PROPNAME property, or DEFAULT if none.
 601 \n(fn SYMBOL PROPNAME &optional DEFAULT)"
 602   (or (get sym tag)
 603       (and def
 604            (let ((plist (symbol-plist sym)))
 605              (while (and plist (not (eq (car plist) tag)))
 606                (setq plist (cdr (cdr plist))))
 607              (if plist (car (cdr plist)) def)))))
 608
 609 ;;;###autoload
 610 (defun getf (plist tag &optional def)
 611   "Search PROPLIST for property PROPNAME; return its value or DEFAULT.
 612 PROPLIST is a list of the sort returned by `symbol-plist'.
 613 \n(fn PROPLIST PROPNAME &optional DEFAULT)"
 614   (setplist '--cl-getf-symbol-- plist)
 615   (or (get '--cl-getf-symbol-- tag)
 616       ;; Originally we called get* here,
 617       ;; but that fails, because get* has a compiler macro
 618       ;; definition that uses getf!
 619       (when def
 620         (while (and plist (not (eq (car plist) tag)))
 621           (setq plist (cdr (cdr plist))))
 622         (if plist (car (cdr plist)) def))))
 623
 624 ;;;###autoload
 625 (defun cl-set-getf (plist tag val)
 626   (let ((p plist))
 627     (while (and p (not (eq (car p) tag))) (setq p (cdr (cdr p))))
 628     (if p (progn (setcar (cdr p) val) plist) (list* tag val plist))))
 629
 630 ;;;###autoload
 631 (defun cl-do-remf (plist tag)
 632   (let ((p (cdr plist)))
 633     (while (and (cdr p) (not (eq (car (cdr p)) tag))) (setq p (cdr (cdr p))))
 634     (and (cdr p) (progn (setcdr p (cdr (cdr (cdr p)))) t))))
 635
 636 ;;;###autoload
 637 (defun cl-remprop (sym tag)
 638   "Remove from SYMBOL's plist the property PROPNAME and its value.
 639 \n(fn SYMBOL PROPNAME)"
 640   (let ((plist (symbol-plist sym)))
 641     (if (and plist (eq tag (car plist)))
 642         (progn (setplist sym (cdr (cdr plist))) t)
 643       (cl-do-remf plist tag))))
 644 ;;;###autoload
 645 (defalias 'remprop 'cl-remprop)
 646
 647
 648
 649 ;;; Hash tables.
 650 ;; This is just kept for compatibility with code byte-compiled by Emacs-20.
 651
 652 ;; No idea if this might still be needed.
 653 (defun cl-not-hash-table (x &optional y &rest z)
 654   (signal 'wrong-type-argument (list 'cl-hash-table-p (or y x))))
 655
 656 (defvar cl-builtin-gethash (symbol-function 'gethash))
 657 (defvar cl-builtin-remhash (symbol-function 'remhash))
 658 (defvar cl-builtin-clrhash (symbol-function 'clrhash))
 659 (defvar cl-builtin-maphash (symbol-function 'maphash))
 660
 661 ;;;###autoload
 662 (defalias 'cl-gethash 'gethash)
 663 ;;;###autoload
 664 (defalias 'cl-puthash 'puthash)
 665 ;;;###autoload
 666 (defalias 'cl-remhash 'remhash)
 667 ;;;###autoload
 668 (defalias 'cl-clrhash 'clrhash)
 669 ;;;###autoload
 670 (defalias 'cl-maphash 'maphash)
 671 ;; These three actually didn't exist in Emacs-20.
 672 ;;;###autoload
 673 (defalias 'cl-make-hash-table 'make-hash-table)
 674 ;;;###autoload
 675 (defalias 'cl-hash-table-p 'hash-table-p)
 676 ;;;###autoload
 677 (defalias 'cl-hash-table-count 'hash-table-count)
 678
 679 ;;; Some debugging aids.
 680
 681 (defun cl-prettyprint (form)
 682   "Insert a pretty-printed rendition of a Lisp FORM in current buffer."
 683   (let ((pt (point)) last)
 684     (insert "\n" (prin1-to-string form) "\n")
 685     (setq last (point))
 686     (goto-char (1+ pt))
 687     (while (search-forward "(quote " last t)
 688       (delete-backward-char 7)
 689       (insert "'")
 690       (forward-sexp)
 691       (delete-char 1))
 692     (goto-char (1+ pt))
 693     (cl-do-prettyprint)))
 694
 695 (defun cl-do-prettyprint ()
 696   (skip-chars-forward " ")
 697   (if (looking-at "(")
 698       (let ((skip (or (looking-at "((") (looking-at "(prog")
 699                       (looking-at "(unwind-protect ")
 700                       (looking-at "(function (")
 701                       (looking-at "(cl-block-wrapper ")))
 702             (two (or (looking-at "(defun ") (looking-at "(defmacro ")))
 703             (let (or (looking-at "(let\\*? ") (looking-at "(while ")))
 704             (set (looking-at "(p?set[qf] ")))
 705         (if (or skip let
 706                 (progn
 707                   (forward-sexp)
 708                   (and (>= (current-column) 78) (progn (backward-sexp) t))))
 709             (let ((nl t))
 710               (forward-char 1)
 711               (cl-do-prettyprint)
 712               (or skip (looking-at ")") (cl-do-prettyprint))
 713               (or (not two) (looking-at ")") (cl-do-prettyprint))
 714               (while (not (looking-at ")"))
 715                 (if set (setq nl (not nl)))
 716                 (if nl (insert "\n"))
 717                 (lisp-indent-line)
 718                 (cl-do-prettyprint))
 719               (forward-char 1))))
 720     (forward-sexp)))
 721
 722 (defvar cl-macroexpand-cmacs nil)
 723 (defvar cl-closure-vars nil)
 724
 725 ;;;###autoload
 726 (defun cl-macroexpand-all (form &optional env)
 727   "Expand all macro calls through a Lisp FORM.
 728 This also does some trivial optimizations to make the form prettier."
 729   (while (or (not (eq form (setq form (macroexpand form env))))
 730              (and cl-macroexpand-cmacs
 731                   (not (eq form (setq form (compiler-macroexpand form)))))))
 732   (cond ((not (consp form)) form)
 733         ((memq (car form) '(let let*))
 734          (if (null (nth 1 form))
 735              (cl-macroexpand-all (cons 'progn (cddr form)) env)
 736            (let ((letf nil) (res nil) (lets (cadr form)))
 737              (while lets
 738                (push (if (consp (car lets))
 739                             (let ((exp (cl-macroexpand-all (caar lets) env)))
 740                               (or (symbolp exp) (setq letf t))
 741                               (cons exp (cl-macroexpand-body (cdar lets) env)))
 742                           (let ((exp (cl-macroexpand-all (car lets) env)))
 743                             (if (symbolp exp) exp
 744                               (setq letf t) (list exp nil)))) res)
 745                (setq lets (cdr lets)))
 746              (list* (if letf (if (eq (car form) 'let) 'letf 'letf*) (car form))
 747                     (nreverse res) (cl-macroexpand-body (cddr form) env)))))
 748         ((eq (car form) 'cond)
 749          (cons (car form)
 750                (mapcar (function (lambda (x) (cl-macroexpand-body x env)))
 751                        (cdr form))))
 752         ((eq (car form) 'condition-case)
 753          (list* (car form) (nth 1 form) (cl-macroexpand-all (nth 2 form) env)
 754                 (mapcar (function
 755                          (lambda (x)
 756                            (cons (car x) (cl-macroexpand-body (cdr x) env))))
 757                         (cdddr form))))
 758         ((memq (car form) '(quote function))
 759          (if (eq (car-safe (nth 1 form)) 'lambda)
 760              (let ((body (cl-macroexpand-body (cddadr form) env)))
 761                (if (and cl-closure-vars (eq (car form) 'function)
 762                         (cl-expr-contains-any body cl-closure-vars))
 763                    (let* ((new (mapcar 'gensym cl-closure-vars))
 764                           (sub (pairlis cl-closure-vars new)) (decls nil))
 765                      (while (or (stringp (car body))
 766                                 (eq (car-safe (car body)) 'interactive))
 767                        (push (list 'quote (pop body)) decls))
 768                      (put (car (last cl-closure-vars)) 'used t)
 769                      (append
 770                       (list 'list '(quote lambda) '(quote (&rest --cl-rest--)))
 771                       (sublis sub (nreverse decls))
 772                       (list
 773                        (list* 'list '(quote apply)
 774                               (list 'function
 775                                     (list* 'lambda
 776                                            (append new (cadadr form))
 777                                            (sublis sub body)))
 778                               (nconc (mapcar (function
 779                                               (lambda (x)
 780                                                 (list 'list '(quote quote) x)))
 781                                              cl-closure-vars)
 782                                      '((quote --cl-rest--)))))))
 783                  (list (car form) (list* 'lambda (cadadr form) body))))
 784            (let ((found (assq (cadr form) env)))
 785              (if (and found (ignore-errors
 786                               (eq (cadr (caddr found)) 'cl-labels-args)))
 787                  (cl-macroexpand-all (cadr (caddr (cadddr found))) env)
 788                form))))
 789         ((memq (car form) '(defun defmacro))
 790          (list* (car form) (nth 1 form) (cl-macroexpand-body (cddr form) env)))
 791         ((and (eq (car form) 'progn) (not (cddr form)))
 792          (cl-macroexpand-all (nth 1 form) env))
 793         ((eq (car form) 'setq)
 794          (let* ((args (cl-macroexpand-body (cdr form) env)) (p args))
 795            (while (and p (symbolp (car p))) (setq p (cddr p)))
 796            (if p (cl-macroexpand-all (cons 'setf args)) (cons 'setq args))))
 797         ((consp (car form))
 798          (cl-macroexpand-all (list* 'funcall
 799                                     (list 'function (car form))
 800                                     (cdr form))
 801                              env))
 802         (t (cons (car form) (cl-macroexpand-body (cdr form) env)))))
 803
 804 (defun cl-macroexpand-body (body &optional env)
 805   (mapcar (function (lambda (x) (cl-macroexpand-all x env))) body))
 806
 807 ;;;###autoload
 808 (defun cl-prettyexpand (form &optional full)
 809   (message "Expanding...")
 810   (let ((cl-macroexpand-cmacs full) (cl-compiling-file full)
 811         (byte-compile-macro-environment nil))
 812     (setq form (cl-macroexpand-all form
 813                                    (and (not full) '((block) (eval-when)))))
 814     (message "Formatting...")
 815     (prog1 (cl-prettyprint form)
 816       (message ""))))
 817
 818
 819
 820 (run-hooks 'cl-extra-load-hook)
 821
 822 ;; Local variables:
 823 ;; generated-autoload-file: "cl-loaddefs.el"
 824 ;; End:
 825
 826 ;; arch-tag: bcd03437-0871-43fb-a8f1-ad0e0b5427ed
 827 ;;; cl-extra.el ends here