lisp/server.el

   1 ;;; server.el --- Lisp code for GNU Emacs running as server process.
   2
   3 ;; Copyright (C) 1986, 1987, 1992 Free Software Foundation, Inc.
   4
   5 ;; Author: William Sommerfeld <wesommer@athena.mit.edu>
   6 ;; Keywords: processes
   7
   8 ;; Changes by peck@sun.com and by rms.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  24 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; This Lisp code is run in Emacs when it is to operate as
  29 ;;; a server for other processes.
  30
  31 ;;; Load this library and do M-x server-edit to enable Emacs as a server.
  32 ;;; Emacs runs the program ../arch-lib/emacsserver as a subprocess
  33 ;;; for communication with clients.  If there are no client buffers to edit,
  34 ;;; server-edit acts like (switch-to-buffer (other-buffer))
  35
  36 ;;; When some other program runs "the editor" to edit a file,
  37 ;;; "the editor" can be the Emacs client program ../lib-src/emacsclient.
  38 ;;; This program transmits the file names to Emacs through
  39 ;;; the server subprocess, and Emacs visits them and lets you edit them.
  40
  41 ;;; Note that any number of clients may dispatch files to emacs to be edited.
  42
  43 ;;; When you finish editing a Server buffer, again call server-edit
  44 ;;; to mark that buffer as done for the client and switch to the next
  45 ;;; Server buffer.  When all the buffers for a client have been edited
  46 ;;; and exited with server-edit, the client "editor" will return
  47 ;;; to the program that invoked it.
  48
  49 ;;; Your editing commands and Emacs's display output go to and from
  50 ;;; the terminal in the usual way.  Thus, server operation is possible
  51 ;;; only when Emacs can talk to the terminal at the time you invoke
  52 ;;; the client.  This is possible in four cases:
  53
  54 ;;; 1. On a window system, where Emacs runs in one window and the
  55 ;;; program that wants to use "the editor" runs in another.
  56
  57 ;;; 2. On a multi-terminal system, where Emacs runs on one terminal and the
  58 ;;; program that wants to use "the editor" runs on another.
  59
  60 ;;; 3. When the program that wants to use "the editor" is running
  61 ;;; as a subprocess of Emacs.
  62
  63 ;;; 4. On a system with job control, when Emacs is suspended, the program
  64 ;;; that wants to use "the editor" will stop and display
  65 ;;; "Waiting for Emacs...".  It can then be suspended, and Emacs can be
  66 ;;; brought into the foreground for editing.  When done editing, Emacs is
  67 ;;; suspended again, and the client program is brought into the foreground.
  68
  69 ;;; The buffer local variable "server-buffer-clients" lists
  70 ;;; the clients who are waiting for this buffer to be edited.
  71 ;;; The global variable "server-clients" lists all the waiting clients,
  72 ;;; and which files are yet to be edited for each.
  73
  74 ;;; Code:
  75 \f
  76 (defvar server-program "emacsserver"
  77   "*The program to use as the edit server")
  78
  79 (defvar server-visit-hook nil
  80   "*List of hooks to call when visiting a file for the Emacs server.")
  81
  82 (defvar server-switch-hook nil
  83   "*List of hooks to call when switching to a buffer for the Emacs server.")
  84
  85 (defvar server-process nil
  86   "the current server process")
  87
  88 (defvar server-previous-string "")
  89
  90 (defvar server-clients nil
  91   "List of current server clients.
  92 Each element is (CLIENTID FILES...) where CLIENTID is a string
  93 that can be given to the server process to identify a client.
  94 When a buffer is marked as \"done\", it is removed from this list.")
  95
  96 (defvar server-buffer-clients nil
  97   "List of clientids for clients requesting editing of current buffer.")
  98 ;; Changing major modes should not erase this local.
  99 (put 'server-buffer-clients 'permanent-local t)
 100
 101 (defvar server-window nil
 102   "*The window to use for selecting Emacs server buffers.
 103 If nil, use the selected window.
 104 If it is a frame, use the frame's selected window.")
 105
 106 (defvar server-temp-file-regexp "^/tmp/Re\\|/draft$"
 107   "*Regexp which should match filenames of temporary files
 108 which are deleted and reused after each edit
 109 by the programs that invoke the emacs server.")
 110
 111 (make-variable-buffer-local 'server-buffer-clients)
 112 (put 'server-buffer-clients 'permanent-local t)
 113 (setq-default server-buffer-clients nil)
 114 (or (assq 'server-buffer-clients minor-mode-alist)
 115     (setq minor-mode-alist (cons '(server-buffer-clients " Server") minor-mode-alist)))
 116
 117 ;; If a *server* buffer exists,
 118 ;; write STRING to it for logging purposes.
 119 (defun server-log (string)
 120   (if (get-buffer "*server*")
 121       (save-excursion
 122         (set-buffer "*server*")
 123         (goto-char (point-max))
 124         (insert string)
 125         (or (bobp) (newline)))))
 126
 127 (defun server-sentinel (proc msg)
 128   (cond ((eq (process-status proc) 'exit)
 129          (server-log (message "Server subprocess exited")))
 130         ((eq (process-status proc) 'signal)
 131          (server-log (message "Server subprocess killed")))))
 132
 133 ;;;###autoload
 134 (defun server-start (&optional leave-dead)
 135   "Allow this Emacs process to be a server for client processes.
 136 This starts a server communications subprocess through which
 137 client \"editors\" can send your editing commands to this Emacs job.
 138 To use the server, set up the program `etc/emacsclient' in the
 139 Emacs distribution as your standard \"editor\".
 140
 141 Prefix arg means just kill any existing server communications subprocess."
 142   (interactive "P")
 143   ;; kill it dead!
 144   (if server-process
 145       (progn
 146         (set-process-sentinel server-process nil)
 147         (condition-case () (delete-process server-process) (error nil))))
 148   (condition-case () (delete-file "~/.emacs_server") (error nil))
 149   ;; If we already had a server, clear out associated status.
 150   (while server-clients
 151     (let ((buffer (nth 1 (car server-clients))))
 152       (server-buffer-done buffer)))
 153   (if leave-dead
 154       nil
 155     (if server-process
 156         (server-log (message "Restarting server")))
 157     (setq server-process (start-process "server" nil server-program))
 158     (set-process-sentinel server-process 'server-sentinel)
 159     (set-process-filter server-process 'server-process-filter)
 160     (process-kill-without-query server-process)))
 161 \f
 162 ;Process a request from the server to edit some files.
 163 ;Format of STRING is "Client: CLIENTID PATH PATH PATH... \n"
 164 (defun server-process-filter (proc string)
 165   (server-log string)
 166   (setq string (concat server-previous-string string))
 167   (if (not (and (eq ?\n (aref string (1- (length string))))
 168                 (eq 0 (string-match "Client: " string))))
 169       ;; If input is not complete, save it for later.
 170       (setq server-previous-string string)
 171     ;; If it is complete, process it now, and discard what was saved.
 172     (setq string (substring string (match-end 0)))
 173     (setq server-previous-string "")
 174     (let ((client (list (substring string 0 (string-match " " string))))
 175           (files nil)
 176           (lineno 1))
 177       (setq string (substring string (match-end 0)))
 178       (while (string-match "[^ ]+ " string)
 179         (let ((arg
 180                (substring string (match-beginning 0) (1- (match-end 0)))))
 181           (setq string (substring string (match-end 0)))
 182           (if (string-match "\\`\\+[0-9]+\\'" arg)
 183               (setq lineno (read (substring arg 1)))
 184             (setq files
 185                   (cons (list arg lineno)
 186                         files))
 187             (setq lineno 1))))
 188       (server-visit-files files client)
 189       ;; CLIENT is now a list (CLIENTNUM BUFFERS...)
 190       (setq server-clients (cons client server-clients))
 191       (server-switch-buffer (nth 1 client))
 192       (run-hooks 'server-switch-hook)
 193       (message (substitute-command-keys
 194                 "When done with a buffer, type \\[server-edit].")))))
 195
 196 (defun server-visit-files (files client)
 197   "Finds FILES and returns the list CLIENT with the buffers nconc'd.
 198 FILES is an alist whose elements are (FILENAME LINENUMBER)."
 199   (let (client-record (obuf (current-buffer)))
 200     ;; Restore the current buffer afterward, but not using save-excursion,
 201     ;; because we don't want to save point in this buffer
 202     ;; if it happens to be one of those specified by the server.
 203     (unwind-protect
 204         (while files
 205           ;; If there is an existing buffer modified or the file is modified,
 206           ;; revert it.
 207           ;; If there is an existing buffer with deleted file, offer to write it.
 208           (let* ((filen (car (car files)))
 209                  (obuf (get-file-buffer filen)))
 210             (if (and obuf (set-buffer obuf))
 211                 (if (file-exists-p filen)
 212                     (if (or (not (verify-visited-file-modtime obuf))
 213                             (buffer-modified-p obuf))
 214                         (revert-buffer t nil))
 215                   (if (y-or-n-p
 216                        (concat "File no longer exists: "
 217                                filen
 218                                ", write buffer to file? "))
 219                       (write-file filen)))
 220               (set-buffer (find-file-noselect filen))
 221               (run-hooks 'server-visit-hook)))
 222           (goto-line (nth 1 (car files)))
 223           (setq server-buffer-clients (cons (car client) server-buffer-clients))
 224           (setq client-record (cons (current-buffer) client-record))
 225           (setq files (cdr files)))
 226       (set-buffer obuf))
 227     (nconc client client-record)))
 228 \f
 229 (defun server-buffer-done (buffer)
 230   "Mark BUFFER as \"done\" for its client(s).
 231 Buries the buffer, and returns another server buffer
 232 as a suggestion for what to select next."
 233   (let ((running (eq (process-status server-process) 'run))
 234         (next-buffer nil)
 235         (old-clients server-clients))
 236     (while old-clients
 237       (let ((client (car old-clients)))
 238         (or next-buffer
 239             (setq next-buffer (nth 1 (memq buffer client))))
 240         (delq buffer client)
 241         ;; If client now has no pending buffers,
 242         ;; tell it that it is done, and forget it entirely.
 243         (if (cdr client) nil
 244           (if running
 245               (progn
 246                 (send-string server-process
 247                              (format "Close: %s Done\n" (car client)))
 248                 (server-log (format "Close: %s Done\n" (car client)))))
 249           (setq server-clients (delq client server-clients))))
 250       (setq old-clients (cdr old-clients)))
 251     (if (buffer-name buffer)
 252         (save-excursion
 253           (set-buffer buffer)
 254           (setq server-buffer-clients nil)))
 255     (bury-buffer buffer)
 256     next-buffer))
 257
 258 (defun server-temp-file-p (buffer)
 259   "Return non-nil if BUFFER contains a file considered temporary.
 260 These are files whose names suggest they are repeatedly
 261 reused to pass information to another program.
 262
 263 The variable `server-temp-file-regexp' controls which filenames
 264 are considered temporary."
 265   (and (buffer-file-name buffer)
 266        (string-match server-temp-file-regexp (buffer-file-name buffer))))
 267
 268 (defun server-done ()
 269   "Offer to save current buffer, mark it as \"done\" for clients.
 270 Then bury it, and return a suggested buffer to select next."
 271   (let ((buffer (current-buffer)))
 272     (if server-buffer-clients
 273         (progn
 274           (if (server-temp-file-p buffer)
 275               ;; For a temp file, save, and do make a non-numeric backup
 276               ;; (unless make-backup-files is nil).
 277               (let ((version-control nil)
 278                     (buffer-backed-up nil))
 279                 (save-buffer)
 280                 (kill-buffer buffer))
 281             (if (and (buffer-modified-p)
 282                      (y-or-n-p (concat "Save file " buffer-file-name "? ")))
 283                 (save-buffer buffer)))
 284           (server-buffer-done buffer)))))
 285 \f
 286 (defun server-edit (&optional arg)
 287   "Switch to next server editing buffer; say \"Done\" for current buffer.
 288 If a server buffer is current, it is marked \"done\" and optionally saved.
 289 When all of a client's buffers are marked as \"done\", the client is notified.
 290
 291 Temporary files such as MH <draft> files are always saved and backed up,
 292 no questions asked.  (The variable `make-backup-files', if nil, still
 293 inhibits a backup; you can set it locally in a particular buffer to
 294 prevent a backup for it.)  The variable `server-temp-file-regexp' controls
 295 which filenames are considered temporary.
 296
 297 If invoked with a prefix argument, or if there is no server process running,
 298 starts server process and that is all.  Invoked by \\[server-edit]."
 299
 300   (interactive "P")
 301   (if (or arg
 302           (not server-process)
 303           (memq (process-status server-process) '(signal exit)))
 304       (server-start nil)
 305     (server-switch-buffer (server-done))))
 306
 307 (defun server-switch-buffer (next-buffer)
 308   "Switch to another buffer, preferably one that has a client.
 309 Arg NEXT-BUFFER is a suggestion; if it is a live buffer, use it."
 310   (cond ((windowp server-window)
 311          (select-window server-window))
 312         ((framep server-window)
 313          (select-window (frame-selected-window server-window))))
 314   (if next-buffer
 315       (if (and (bufferp next-buffer)
 316                (buffer-name next-buffer))
 317           (switch-to-buffer next-buffer)
 318         ;; If NEXT-BUFFER is a dead buffer,
 319         ;; remove the server records for it
 320         ;; and try the next surviving server buffer.
 321         (server-switch-buffer
 322          (server-buffer-done next-buffer)))
 323     (if server-clients
 324         (server-switch-buffer (nth 1 (car server-clients)))
 325       (switch-to-buffer (other-buffer)))))
 326
 327 (global-set-key "\C-x#" 'server-edit)
 328 \f
 329 (provide 'server)
 330
 331 ;;; server.el ends here