lisp/descr-text.el

   1 ;;; descr-text.el --- describe text mode
   2
   3 ;; Copyright (C) 1994, 1995, 1996, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Boris Goldowsky <boris@gnu.org>
   7 ;; Maintainer: FSF
   8 ;; Keywords: faces, i18n, Unicode, multilingual
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Describe-Text Mode.
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'quail))
  32 (require 'help-fns)
  33
  34 ;;; Describe-Text Utilities.
  35
  36 (defun describe-text-widget (widget)
  37   "Insert text to describe WIDGET in the current buffer."
  38   (insert-text-button
  39    (symbol-name (if (symbolp widget) widget (car widget)))
  40    'action `(lambda (&rest ignore)
  41               (widget-browse ',widget))
  42    'help-echo "mouse-2, RET: browse this widget")
  43   (insert " ")
  44   (insert-text-button
  45    "(widget)Top" 'type 'help-info 'help-args '("(widget)Top")))
  46
  47 (defun describe-text-sexp (sexp)
  48   "Insert a short description of SEXP in the current buffer."
  49   (let ((pp (condition-case signal
  50                 (pp-to-string sexp)
  51               (error (prin1-to-string signal)))))
  52     (when (string-match-p "\n\\'" pp)
  53       (setq pp (substring pp 0 (1- (length pp)))))
  54
  55     (if (and (not (string-match-p "\n" pp))
  56              (<= (length pp) (- (window-width) (current-column))))
  57         (insert pp)
  58       (insert-text-button
  59        "[Show]" 'action `(lambda (&rest ignore)
  60                            (with-output-to-temp-buffer
  61                                "*Pp Eval Output*"
  62                              (princ ',pp)))
  63        'help-echo "mouse-2, RET: pretty print value in another buffer"))))
  64
  65 (defun describe-property-list (properties)
  66   "Insert a description of PROPERTIES in the current buffer.
  67 PROPERTIES should be a list of overlay or text properties.
  68 The `category', `face' and `font-lock-face' properties are made
  69 into help buttons that call `describe-text-category' or
  70 `describe-face' when pushed."
  71   ;; Sort the properties by the size of their value.
  72   (dolist (elt (sort (let (ret)
  73                        (while properties
  74                          (push (list (pop properties) (pop properties)) ret))
  75                        ret)
  76                      (lambda (a b) (string< (prin1-to-string (nth 0 a) t)
  77                                             (prin1-to-string (nth 0 b) t)))))
  78     (let ((key (nth 0 elt))
  79           (value (nth 1 elt)))
  80       (insert (propertize (format "  %-20s " key)
  81                           'face 'help-argument-name))
  82       (cond ((eq key 'category)
  83              (insert-text-button
  84               (symbol-name value)
  85               'action `(lambda (&rest ignore)
  86                          (describe-text-category ',value))
  87               'help-echo "mouse-2, RET: describe this category"))
  88             ((memq key '(face font-lock-face mouse-face))
  89              (insert-text-button
  90               (format "%S" value)
  91               'type 'help-face 'help-args (list value)))
  92             ((widgetp value)
  93              (describe-text-widget value))
  94             (t
  95              (describe-text-sexp value))))
  96     (insert "\n")))
  97 \f
  98 ;;; Describe-Text Commands.
  99
 100 (defun describe-text-category (category)
 101   "Describe a text property category."
 102   (interactive "SCategory: ")
 103   (help-setup-xref (list #'describe-text-category category) (interactive-p))
 104   (save-excursion
 105     (with-output-to-temp-buffer "*Help*"
 106       (set-buffer standard-output)
 107       (insert "Category " (format "%S" category) ":\n\n")
 108       (describe-property-list (symbol-plist category))
 109       (goto-char (point-min)))))
 110
 111 ;;;###autoload
 112 (defun describe-text-properties (pos &optional output-buffer)
 113   "Describe widgets, buttons, overlays and text properties at POS.
 114 Interactively, describe them for the character after point.
 115 If optional second argument OUTPUT-BUFFER is non-nil,
 116 insert the output into that buffer, and don't initialize or clear it
 117 otherwise."
 118   (interactive "d")
 119   (if (>= pos (point-max))
 120       (error "No character follows specified position"))
 121   (if output-buffer
 122       (describe-text-properties-1 pos output-buffer)
 123     (if (not (or (text-properties-at pos) (overlays-at pos)))
 124         (message "This is plain text.")
 125       (let ((buffer (current-buffer))
 126             (target-buffer "*Help*"))
 127         (when (eq buffer (get-buffer target-buffer))
 128           (setq target-buffer "*Help*<2>"))
 129         (save-excursion
 130           (with-output-to-temp-buffer target-buffer
 131             (set-buffer standard-output)
 132             (setq output-buffer (current-buffer))
 133             (insert "Text content at position " (format "%d" pos) ":\n\n")
 134             (with-current-buffer buffer
 135               (describe-text-properties-1 pos output-buffer))
 136             (goto-char (point-min))))))))
 137
 138 (defun describe-text-properties-1 (pos output-buffer)
 139   (let* ((properties (text-properties-at pos))
 140          (overlays (overlays-at pos))
 141          (wid-field (get-char-property pos 'field))
 142          (wid-button (get-char-property pos 'button))
 143          (wid-doc (get-char-property pos 'widget-doc))
 144          ;; If button.el is not loaded, we have no buttons in the text.
 145          (button (and (fboundp 'button-at) (button-at pos)))
 146          (button-type (and button (button-type button)))
 147          (button-label (and button (button-label button)))
 148          (widget (or wid-field wid-button wid-doc)))
 149     (with-current-buffer output-buffer
 150       ;; Widgets
 151       (when (widgetp widget)
 152         (newline)
 153         (insert (cond (wid-field "This is an editable text area")
 154                       (wid-button "This is an active area")
 155                       (wid-doc "This is documentation text")))
 156         (insert " of a ")
 157         (describe-text-widget widget)
 158         (insert ".\n\n"))
 159       ;; Buttons
 160       (when (and button (not (widgetp wid-button)))
 161         (newline)
 162         (insert "Here is a `" (format "%S" button-type)
 163                 "' button labeled `" button-label "'.\n\n"))
 164       ;; Overlays
 165       (when overlays
 166         (newline)
 167         (if (eq (length overlays) 1)
 168             (insert "There is an overlay here:\n")
 169           (insert "There are " (format "%d" (length overlays))
 170                          " overlays here:\n"))
 171         (dolist (overlay overlays)
 172           (insert " From " (format "%d" (overlay-start overlay))
 173                          " to " (format "%d" (overlay-end overlay)) "\n")
 174           (describe-property-list (overlay-properties overlay)))
 175         (insert "\n"))
 176       ;; Text properties
 177       (when properties
 178         (newline)
 179         (insert "There are text properties here:\n")
 180         (describe-property-list properties)))))
 181 \f
 182 (defcustom describe-char-unidata-list nil
 183   "List of Unicode-based character property names shown by `describe-char'."
 184   :group 'mule
 185   :version "23.1"
 186   :type '(choice (const :tag "All properties" t)
 187           (set
 188            (const :tag "Unicode Name" name)
 189            (const :tag "Unicode general category " general-category)
 190            (const :tag "Unicode canonical combining class"
 191                   canonical-combining-class)
 192            (const :tag "Unicode bidi class" bidi-class)
 193            (const :tag "Unicode decomposition mapping" decomposition)
 194            (const :tag "Unicode decimal digit value" decimal-digit-value)
 195            (const :tag "Unicode digit value" digit-value)
 196            (const :tag "Unicode numeric value" numeric-value)
 197            (const :tag "Unicode mirrored" mirrored)
 198            (const :tag "Unicode old name" old-name)
 199            (const :tag "Unicode ISO 10646 comment" iso-10646-comment)
 200            (const :tag "Unicode simple uppercase mapping" uppercase)
 201            (const :tag "Unicode simple lowercase mapping" lowercase)
 202            (const :tag "Unicode simple titlecase mapping" titlecase))))
 203
 204 (defcustom describe-char-unicodedata-file nil
 205   "Location of Unicode data file.
 206 This is the UnicodeData.txt file from the Unicode Consortium, used for
 207 diagnostics.  If it is non-nil `describe-char' will print data
 208 looked up from it.  This facility is mostly of use to people doing
 209 multilingual development.
 210
 211 This is a fairly large file, not typically present on GNU systems.
 212 At the time of writing it is at the URL
 213 `http://www.unicode.org/Public/UNIDATA/UnicodeData.txt'."
 214   :group 'mule
 215   :version "22.1"
 216   :type '(choice (const :tag "None" nil)
 217                  file))
 218
 219 (defun describe-char-unicode-data (char)
 220   "Return a list of Unicode data for unicode CHAR.
 221 Each element is a list of a property description and the property value.
 222 The list is null if CHAR isn't found in `describe-char-unicodedata-file'.
 223 This function is semi-obsolete.  Use `get-char-code-property'."
 224   (when describe-char-unicodedata-file
 225     (unless (file-exists-p describe-char-unicodedata-file)
 226       (error "`unicodedata-file' %s not found" describe-char-unicodedata-file))
 227     (with-current-buffer (get-buffer-create " *Unicode Data*")
 228       (when (zerop (buffer-size))
 229         ;; Don't use -literally in case of DOS line endings.
 230         (insert-file-contents describe-char-unicodedata-file))
 231       (goto-char (point-min))
 232       (let ((hex (format "%04X" char))
 233             found first last)
 234         (if (re-search-forward (concat "^" hex) nil t)
 235             (setq found t)
 236           ;; It's not listed explicitly.  Look for ranges, e.g. CJK
 237           ;; ideographs, and check whether it's in one of them.
 238           (while (and (re-search-forward "^\\([^;]+\\);[^;]+First>;" nil t)
 239                       (>= char (setq first
 240                                      (string-to-number (match-string 1) 16)))
 241                       (progn
 242                         (forward-line 1)
 243                         (looking-at "^\\([^;]+\\);[^;]+Last>;")
 244                         (> char
 245                            (setq last
 246                                  (string-to-number (match-string 1) 16))))))
 247           (if (and (>= char first)
 248                    (<= char last))
 249               (setq found t)))
 250         (if found
 251             (let ((fields (mapcar (lambda (elt)
 252                                     (if (> (length elt) 0)
 253                                         elt))
 254                                   (cdr (split-string
 255                                         (buffer-substring
 256                                          (line-beginning-position)
 257                                          (line-end-position))
 258                                         ";")))))
 259               ;; The length depends on whether the last field was empty.
 260               (unless (or (= 13 (length fields))
 261                           (= 14 (length fields)))
 262                 (error "Invalid contents in %s" describe-char-unicodedata-file))
 263               ;; The field names and values lists are slightly
 264               ;; modified from Mule-UCS unidata.el.
 265               (list
 266                (list "Name" (let ((name (nth 0 fields)))
 267                               ;; Check for <..., First>, <..., Last>
 268                               (if (string-match "\\`\\(<[^,]+\\)," name)
 269                                   (concat (match-string 1 name) ">")
 270                                 name)))
 271                (list "Category"
 272                      (let ((val (nth 1 fields)))
 273                        (or (char-code-property-description
 274                             'general-category (intern val))
 275                            val)))
 276                (list "Combining class"
 277                      (let ((val (nth 1 fields)))
 278                        (or (char-code-property-description
 279                             'canonical-combining-class (intern val))
 280                            val)))
 281                (list "Bidi category"
 282                      (let ((val (nth 1 fields)))
 283                        (or (char-code-property-description
 284                             'bidi-class (intern val))
 285                            val)))
 286                (list
 287                 "Decomposition"
 288                 (if (nth 4 fields)
 289                     (let* ((parts (split-string (nth 4 fields)))
 290                            (info (car parts)))
 291                       (if (string-match "\\`<\\(.+\\)>\\'" info)
 292                           (setq info (match-string 1 info))
 293                         (setq info nil))
 294                       (if info (setq parts (cdr parts)))
 295                       (setq parts (mapconcat
 296                                    (lambda (arg)
 297                                      (string (string-to-number arg 16)))
 298                                    parts " "))
 299                       (concat info parts))))
 300                (list "Decimal digit value"
 301                      (nth 5 fields))
 302                (list "Digit value"
 303                      (nth 6 fields))
 304                (list "Numeric value"
 305                      (nth 7 fields))
 306                (list "Mirrored"
 307                      (if (equal "Y" (nth 8 fields))
 308                          "yes"))
 309                (list "Old name" (nth 9 fields))
 310                (list "ISO 10646 comment" (nth 10 fields))
 311                (list "Uppercase" (and (nth 11 fields)
 312                                       (string (string-to-number
 313                                                (nth 11 fields) 16))))
 314                (list "Lowercase" (and (nth 12 fields)
 315                                       (string (string-to-number
 316                                                (nth 12 fields) 16))))
 317                (list "Titlecase" (and (nth 13 fields)
 318                                       (string (string-to-number
 319                                                (nth 13 fields) 16)))))))))))
 320
 321 ;; Not defined on builds without X, but behind display-graphic-p.
 322 (declare-function internal-char-font "fontset.c" (position &optional ch))
 323
 324 ;; Return information about how CHAR is displayed at the buffer
 325 ;; position POS.  If the selected frame is on a graphic display,
 326 ;; return a cons (FONTNAME . GLYPH-CODE) where GLYPH-CODE is a
 327 ;; hexadigit string representing the glyph-ID.  Otherwise, return a
 328 ;; string describing the terminal codes for the character.
 329 (defun describe-char-display (pos char)
 330   (if (display-graphic-p (selected-frame))
 331       (let ((char-font-info (internal-char-font pos char)))
 332         (if char-font-info
 333             (if (integerp (cdr char-font-info))
 334                 (setcdr char-font-info (format "%02X" (cdr char-font-info)))
 335               (setcdr char-font-info
 336                       (format "%04X%04X"
 337                               (cadr char-font-info) (cddr char-font-info)))))
 338         char-font-info)
 339     (let* ((coding (terminal-coding-system))
 340            (encoded (encode-coding-char char coding)))
 341       (if encoded
 342           (encoded-string-description encoded coding)))))
 343
 344 \f
 345 ;;;###autoload
 346 (defun describe-char (pos)
 347   "Describe the character after POS (interactively, the character after point).
 348 The information includes character code, charset and code points in it,
 349 syntax, category, how the character is encoded in a file,
 350 character composition information (if relevant),
 351 as well as widgets, buttons, overlays, and text properties."
 352   (interactive "d")
 353   (if (>= pos (point-max))
 354       (error "No character follows specified position"))
 355   (let* ((char (char-after pos))
 356          (charset (char-charset char))
 357          (composition (find-composition pos nil nil t))
 358          (component-chars nil)
 359          (display-table (or (window-display-table)
 360                             buffer-display-table
 361                             standard-display-table))
 362          (disp-vector (and display-table (aref display-table char)))
 363          (multibyte-p enable-multibyte-characters)
 364          (overlays (mapcar #'(lambda (o) (overlay-properties o))
 365                            (overlays-at pos)))
 366          (char-description (if (not multibyte-p)
 367                                (single-key-description char)
 368                              (if (< char 128)
 369                                  (single-key-description char)
 370                                (string-to-multibyte
 371                                 (char-to-string char)))))
 372          (text-props-desc
 373           (let ((tmp-buf (generate-new-buffer " *text-props*")))
 374             (unwind-protect
 375                 (progn
 376                   (describe-text-properties pos tmp-buf)
 377                   (with-current-buffer tmp-buf (buffer-string)))
 378               (kill-buffer tmp-buf))))
 379          item-list max-width code)
 380
 381     (setq code (encode-char char charset))
 382     (setq item-list
 383           `(("character"
 384              ,(format "%s (%d, #o%o, #x%x)"
 385                       (apply 'propertize char-description
 386                              (text-properties-at pos))
 387                       char char char))
 388             ("preferred charset"
 389              ,`(insert-text-button
 390                 ,(symbol-name charset)
 391                 'type 'help-character-set 'help-args '(,charset))
 392              ,(format "(%s)" (charset-description charset)))
 393             ("code point"
 394              ,(let ((str (if (integerp code)
 395                              (format (if (< code 256) "0x%02X" "0x%04X") code)
 396                            (format "0x%04X%04X" (car code) (cdr code)))))
 397                 (if (<= (charset-dimension charset) 2)
 398                     `(insert-text-button
 399                       ,str
 400                       'action (lambda (&rest ignore)
 401                                 (list-charset-chars ',charset)
 402                                 (with-selected-window
 403                                     (get-buffer-window "*Character List*" 0)
 404                                   (goto-char (point-min))
 405                                   (forward-line 2) ;Skip the header.
 406                                   (let ((case-fold-search nil))
 407                                     (if (search-forward ,(char-to-string char)
 408                                                         nil t)
 409                                         (goto-char (match-beginning 0))))))
 410                       'help-echo
 411                       "mouse-2, RET: show this character in its character set")
 412                   str)))
 413             ("syntax"
 414              ,(let ((syntax (syntax-after pos)))
 415                 (with-temp-buffer
 416                   (internal-describe-syntax-value syntax)
 417                   (buffer-string))))
 418             ("category"
 419              ,@(let ((category-set (char-category-set char)))
 420                  (if (not category-set)
 421                      '("-- none --")
 422                    (mapcar #'(lambda (x) (format "%c:%s"
 423                                                  x (category-docstring x)))
 424                            (category-set-mnemonics category-set)))))
 425             ("to input"
 426              ,@(let ((key-list (and (eq input-method-function
 427                                         'quail-input-method)
 428                                     (quail-find-key char))))
 429                  (if (consp key-list)
 430                      (list "type"
 431                            (mapconcat #'(lambda (x) (concat "\"" x "\""))
 432                                       key-list " or ")
 433                            "with"
 434                            `(insert-text-button
 435                              ,current-input-method
 436                              'type 'help-input-method
 437                              'help-args '(,current-input-method))))))
 438             ("buffer code"
 439              ,(encoded-string-description
 440                (string-as-unibyte (char-to-string char)) nil))
 441             ("file code"
 442              ,@(let* ((coding buffer-file-coding-system)
 443                       (encoded (encode-coding-char char coding)))
 444                  (if encoded
 445                      (list (encoded-string-description encoded coding)
 446                            (format "(encoded by coding system %S)" coding))
 447                    (list "not encodable by coding system"
 448                          (symbol-name coding)))))
 449             ("display"
 450              ,(cond
 451                (disp-vector
 452                 (setq disp-vector (copy-sequence disp-vector))
 453                 (dotimes (i (length disp-vector))
 454                   (setq char (aref disp-vector i))
 455                   (aset disp-vector i
 456                         (cons char (describe-char-display
 457                                     pos (glyph-char char)))))
 458                 (format "by display table entry [%s] (see below)"
 459                         (mapconcat
 460                          #'(lambda (x)
 461                              (format "?%c" (glyph-char (car x))))
 462                          disp-vector " ")))
 463                (composition
 464                 (let ((from (car composition))
 465                       (to (nth 1 composition))
 466                       (next (1+ pos))
 467                       (components (nth 2 composition))
 468                       ch)
 469                   (setcar composition
 470                           (and (< from pos) (buffer-substring from pos)))
 471                   (setcar (cdr composition)
 472                           (and (< next to) (buffer-substring next to)))
 473                   (dotimes (i (length components))
 474                     (if (integerp (setq ch (aref components i)))
 475                         (push (cons ch (describe-char-display pos ch))
 476                               component-chars)))
 477                   (setq component-chars (nreverse component-chars))
 478                   (format "composed to form \"%s\" (see below)"
 479                           (buffer-substring from to))))
 480                (t
 481                 (let ((display (describe-char-display pos char)))
 482                   (if (display-graphic-p (selected-frame))
 483                       (if display
 484                           (concat
 485                            "by this font (glyph code)\n"
 486                            (format "     %s (#x%s)"
 487                                    (car display) (cdr display)))
 488                         "no font available")
 489                     (if display
 490                         (format "terminal code %s" display)
 491                       "not encodable for terminal"))))))
 492             ,@(let ((face
 493                      (if (not (or disp-vector composition))
 494                          (cond
 495                           ((and show-trailing-whitespace
 496                                 (save-excursion (goto-char pos)
 497                                                 (looking-at-p "[ \t]+$")))
 498                            'trailing-whitespace)
 499                           ((and nobreak-char-display char (eq char '#xa0))
 500                            'nobreak-space)
 501                           ((and nobreak-char-display char (eq char '#xad))
 502                            'escape-glyph)
 503                           ((and (< char 32) (not (memq char '(9 10))))
 504                            'escape-glyph)))))
 505                 (if face (list (list "hardcoded face"
 506                                      `(insert-text-button
 507                                        ,(symbol-name face)
 508                                        'type 'help-face 'help-args '(,face))))))
 509             ,@(let ((unicodedata (describe-char-unicode-data char)))
 510                 (if unicodedata
 511                     (cons (list "Unicode data" " ") unicodedata)))))
 512     (setq max-width (apply #'max (mapcar #'(lambda (x)
 513                                              (if (cadr x) (length (car x)) 0))
 514                                          item-list)))
 515     (help-setup-xref nil (interactive-p))
 516     (with-help-window (help-buffer)
 517       (with-current-buffer standard-output
 518         (set-buffer-multibyte multibyte-p)
 519         (let ((formatter (format "%%%ds:" max-width)))
 520           (dolist (elt item-list)
 521             (when (cadr elt)
 522               (insert (format formatter (car elt)))
 523               (dolist (clm (cdr elt))
 524                 (if (eq (car-safe clm) 'insert-text-button)
 525                     (progn (insert " ") (eval clm))
 526                   (when (>= (+ (current-column)
 527                                (or (string-match-p "\n" clm)
 528                                    (string-width clm))
 529                                1)
 530                             (window-width))
 531                     (insert "\n")
 532                     (indent-to (1+ max-width)))
 533                   (insert " " clm)))
 534               (insert "\n"))))
 535
 536         (when overlays
 537           (save-excursion
 538             (goto-char (point-min))
 539             (re-search-forward "character:[ \t\n]+")
 540             (let* ((end (+ (point) (length char-description))))
 541               (mapc #'(lambda (props)
 542                         (let ((o (make-overlay (point) end)))
 543                           (while props
 544                             (overlay-put o (car props) (nth 1 props))
 545                             (setq props (cddr props)))))
 546                     overlays))))
 547
 548         (when disp-vector
 549           (insert
 550            "\nThe display table entry is displayed by ")
 551           (if (display-graphic-p (selected-frame))
 552               (progn
 553                 (insert "these fonts (glyph codes):\n")
 554                 (dotimes (i (length disp-vector))
 555                   (insert (glyph-char (car (aref disp-vector i))) ?:
 556                           (propertize " " 'display '(space :align-to 5))
 557                           (if (cdr (aref disp-vector i))
 558                               (format "%s (#x%s)" (cadr (aref disp-vector i))
 559                                       (cddr (aref disp-vector i)))
 560                             "-- no font --")
 561                           "\n")
 562                   (let ((face (glyph-face (car (aref disp-vector i)))))
 563                     (when face
 564                       (insert (propertize " " 'display '(space :align-to 5))
 565                               "face: ")
 566                       (insert (concat "`" (symbol-name face) "'"))
 567                       (insert "\n")))))
 568             (insert "these terminal codes:\n")
 569             (dotimes (i (length disp-vector))
 570               (insert (car (aref disp-vector i))
 571                       (propertize " " 'display '(space :align-to 5))
 572                       (or (cdr (aref disp-vector i)) "-- not encodable --")
 573                       "\n"))))
 574
 575         (when composition
 576           (insert "\nComposed")
 577           (if (car composition)
 578               (if (cadr composition)
 579                   (insert " with the surrounding characters \""
 580                           (car composition) "\" and \""
 581                           (cadr composition) "\"")
 582                 (insert " with the preceding character(s) \""
 583                         (car composition) "\""))
 584             (if (cadr composition)
 585                 (insert " with the following character(s) \""
 586                         (cadr composition) "\"")))
 587           (if (and (vectorp (nth 2 composition))
 588                    (vectorp (aref (nth 2 composition) 0)))
 589               (progn
 590                 (insert " using this font:\n  "
 591                         (aref (query-font (aref (aref (nth 2 composition) 0) 0))
 592                               0)
 593                         "\nby these glyphs:\n")
 594                 (mapc (lambda (x) (insert (format "  %S\n" x)))
 595                       (nth 2 composition)))
 596             (insert " by the rule:\n\t("
 597                     (mapconcat (lambda (x)
 598                                  (if (consp x) (format "%S" x)
 599                                    (if (= x ?\t)
 600                                        (single-key-description x)
 601                                      (string ?? x))))
 602                                (nth 2 composition)
 603                                " ")
 604                     ")")
 605             (insert  "\nThe component character(s) are displayed by ")
 606             (if (display-graphic-p (selected-frame))
 607                 (progn
 608                   (insert "these fonts (glyph codes):")
 609                   (dolist (elt component-chars)
 610                     (if (/= (car elt) ?\t)
 611                         (insert "\n " (car elt) ?:
 612                                 (propertize " " 'display '(space :align-to 5))
 613                                 (if (cdr elt)
 614                                     (format "%s (#x%s)" (cadr elt) (cddr elt))
 615                                   "-- no font --")))))
 616               (insert "these terminal codes:")
 617               (dolist (elt component-chars)
 618                 (insert "\n  " (car elt) ":"
 619                         (propertize " " 'display '(space :align-to 4))
 620                         (or (cdr elt) "-- not encodable --"))))
 621             (insert "\nSee the variable `reference-point-alist' for "
 622                     "the meaning of the rule.\n")))
 623
 624         (insert (if (not describe-char-unidata-list)
 625                     "\nCharacter code properties are not shown: "
 626                   "\nCharacter code properties: "))
 627         (insert-text-button
 628          "customize what to show"
 629          'action (lambda (&rest ignore)
 630                    (customize-variable
 631                     'describe-char-unidata-list)))
 632         (insert "\n")
 633         (dolist (elt (if (eq describe-char-unidata-list t)
 634                          (nreverse (mapcar 'car char-code-property-alist))
 635                        describe-char-unidata-list))
 636           (let ((val (get-char-code-property char elt))
 637                 description)
 638             (when val
 639               (setq description (char-code-property-description elt val))
 640               (insert (if description
 641                           (format "  %s: %s (%s)\n" elt val description)
 642                         (format "  %s: %s\n" elt val))))))
 643
 644         (if text-props-desc (insert text-props-desc))
 645         (setq help-xref-stack-item (list 'help-insert-string (buffer-string)))
 646         (toggle-read-only 1)))))
 647
 648 (define-obsolete-function-alias 'describe-char-after 'describe-char "22.1")
 649
 650 (provide 'descr-text)
 651
 652 ;; arch-tag: fc55a498-f3e9-4312-b5bd-98cc02480af1
 653 ;;; descr-text.el ends here