lisp/disp-table.el

   1 ;;; disp-table.el --- functions for dealing with char tables
   2
   3 ;; Copyright (C) 1987, 1994-1995, 1999, 2001-2012
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Erik Naggum <erik@naggum.no>
   7 ;; Based on a previous version by Howard Gayle
   8 ;; Maintainer: FSF
   9 ;; Keywords: i18n
  10 ;; Package: emacs
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (put 'display-table 'char-table-extra-slots 6)
  32
  33 ;;;###autoload
  34 (defun make-display-table ()
  35   "Return a new, empty display table."
  36   (make-char-table 'display-table nil))
  37
  38 (or standard-display-table
  39     (setq standard-display-table (make-display-table)))
  40
  41 ;;; Display-table slot names.  The property value says which slot.
  42
  43 (put 'truncation 'display-table-slot 0)
  44 (put 'wrap 'display-table-slot 1)
  45 (put 'escape 'display-table-slot 2)
  46 (put 'control 'display-table-slot 3)
  47 (put 'selective-display 'display-table-slot 4)
  48 (put 'vertical-border 'display-table-slot 5)
  49
  50 ;;;###autoload
  51 (defun display-table-slot (display-table slot)
  52   "Return the value of the extra slot in DISPLAY-TABLE named SLOT.
  53 SLOT may be a number from 0 to 5 inclusive, or a slot name (symbol).
  54 Valid symbols are `truncation', `wrap', `escape', `control',
  55 `selective-display', and `vertical-border'."
  56   (let ((slot-number
  57          (if (numberp slot) slot
  58            (or (get slot 'display-table-slot)
  59                (error "Invalid display-table slot name: %s" slot)))))
  60     (char-table-extra-slot display-table slot-number)))
  61
  62 ;;;###autoload
  63 (defun set-display-table-slot (display-table slot value)
  64   "Set the value of the extra slot in DISPLAY-TABLE named SLOT to VALUE.
  65 SLOT may be a number from 0 to 5 inclusive, or a name (symbol).
  66 Valid symbols are `truncation', `wrap', `escape', `control',
  67 `selective-display', and `vertical-border'."
  68   (let ((slot-number
  69          (if (numberp slot) slot
  70            (or (get slot 'display-table-slot)
  71                (error "Invalid display-table slot name: %s" slot)))))
  72     (set-char-table-extra-slot display-table slot-number value)))
  73
  74 ;;;###autoload
  75 (defun describe-display-table (dt)
  76   "Describe the display table DT in a help buffer."
  77   (with-help-window "*Help*"
  78     (princ "\nTruncation glyph: ")
  79     (prin1 (display-table-slot dt 'truncation))
  80     (princ "\nWrap glyph: ")
  81     (prin1 (display-table-slot dt 'wrap))
  82     (princ "\nEscape glyph: ")
  83     (prin1 (display-table-slot dt 'escape))
  84     (princ "\nCtrl glyph: ")
  85     (prin1 (display-table-slot dt 'control))
  86     (princ "\nSelective display glyph sequence: ")
  87     (prin1 (display-table-slot dt 'selective-display))
  88     (princ "\nVertical window border glyph: ")
  89     (prin1 (display-table-slot dt 'vertical-border))
  90     (princ "\nCharacter display glyph sequences:\n")
  91     (with-current-buffer standard-output
  92       (let ((vector (make-vector 256 nil))
  93             (i 0))
  94         (while (< i 256)
  95           (aset vector i (aref dt i))
  96           (setq i (1+ i)))
  97         (describe-vector
  98          vector 'display-table-print-array))
  99       (help-mode))))
 100
 101 (defun display-table-print-array (desc)
 102   (insert "[")
 103   (let ((column (current-column))
 104         (width (window-width))
 105         string)
 106     (dotimes (i (length desc))
 107       (setq string (format "%s" (aref desc i)))
 108       (cond
 109        ((>= (+ (current-column) (length string) 1)
 110             width)
 111         (insert "\n")
 112         (insert (make-string column ? )))
 113        ((> i 0)
 114         (insert " ")))
 115       (insert string)))
 116   (insert "]\n"))
 117
 118 ;;;###autoload
 119 (defun describe-current-display-table ()
 120   "Describe the display table in use in the selected window and buffer."
 121   (interactive)
 122   (let ((disptab (or (window-display-table (selected-window))
 123                      buffer-display-table
 124                      standard-display-table)))
 125     (if disptab
 126         (describe-display-table disptab)
 127       (message "No display table"))))
 128
 129 ;;;###autoload
 130 (defun standard-display-8bit (l h)
 131   "Display characters representing raw bytes in the range L to H literally.
 132
 133 On a terminal display, each character in the range is displayed
 134 by sending the corresponding byte directly to the terminal.
 135
 136 On a graphic display, each character in the range is displayed
 137 using the default font by a glyph whose code is the corresponding
 138 byte.
 139
 140 Note that ASCII printable characters (SPC to TILDA) are displayed
 141 in the default way after this call."
 142   (or standard-display-table
 143       (setq standard-display-table (make-display-table)))
 144   (if (> h 255)
 145       (setq h 255))
 146   (while (<= l h)
 147     (if (< l 128)
 148         (aset standard-display-table l
 149               (if (or (< l ?\s) (= l 127)) (vector l)))
 150       (let ((c (unibyte-char-to-multibyte l)))
 151         (aset standard-display-table c (vector c))))
 152     (setq l (1+ l))))
 153
 154 ;;;###autoload
 155 (defun standard-display-default (l h)
 156   "Display characters in the range L to H using the default notation."
 157   (or standard-display-table
 158       (setq standard-display-table (make-display-table)))
 159   (while (<= l h)
 160     (if (and (>= l ?\s) (characterp l))
 161         (aset standard-display-table l nil))
 162     (setq l (1+ l))))
 163
 164 ;; This function does NOT take terminal-dependent escape sequences.
 165 ;; For that, you need to go through create-glyph.  Use one of the
 166 ;; other functions below, or roll your own.
 167 ;;;###autoload
 168 (defun standard-display-ascii (c s)
 169   "Display character C using printable string S."
 170   (or standard-display-table
 171       (setq standard-display-table (make-display-table)))
 172   (aset standard-display-table c (vconcat s)))
 173
 174 ;;;###autoload
 175 (defun standard-display-g1 (c sc)
 176   "Display character C as character SC in the g1 character set.
 177 This function assumes that your terminal uses the SO/SI characters;
 178 it is meaningless for an X frame."
 179   (if (memq window-system '(x w32 ns))
 180       (error "Cannot use string glyphs in a windowing system"))
 181   (or standard-display-table
 182       (setq standard-display-table (make-display-table)))
 183   (aset standard-display-table c
 184         (vector (create-glyph (concat "\016" (char-to-string sc) "\017")))))
 185
 186 ;;;###autoload
 187 (defun standard-display-graphic (c gc)
 188   "Display character C as character GC in graphics character set.
 189 This function assumes VT100-compatible escapes; it is meaningless for an
 190 X frame."
 191   (if (memq window-system '(x w32 ns))
 192       (error "Cannot use string glyphs in a windowing system"))
 193   (or standard-display-table
 194       (setq standard-display-table (make-display-table)))
 195   (aset standard-display-table c
 196         (vector (create-glyph (concat "\e(0" (char-to-string gc) "\e(B")))))
 197
 198 ;;;###autoload
 199 (defun standard-display-underline (c uc)
 200   "Display character C as character UC plus underlining."
 201   (or standard-display-table
 202       (setq standard-display-table (make-display-table)))
 203   (aset standard-display-table c
 204         (vector
 205          (if window-system
 206              (make-glyph-code uc 'underline)
 207            (create-glyph (concat "\e[4m" (char-to-string uc) "\e[m"))))))
 208
 209 ;;;###autoload
 210 (defun create-glyph (string)
 211   "Allocate a glyph code to display by sending STRING to the terminal."
 212   (if (= (length glyph-table) 65536)
 213       (error "No free glyph codes remain"))
 214   ;; Don't use slots that correspond to ASCII characters.
 215   (if (= (length glyph-table) 32)
 216       (setq glyph-table (vconcat glyph-table (make-vector 224 nil))))
 217   (setq glyph-table (vconcat glyph-table (list string)))
 218   (1- (length glyph-table)))
 219
 220 ;;;###autoload
 221 (defun make-glyph-code (char &optional face)
 222   "Return a glyph code representing char CHAR with face FACE."
 223   ;; Due to limitations on Emacs integer values, faces with
 224   ;; face id greater that 512 are silently ignored.
 225   (if (not face)
 226       char
 227     (let ((fid (face-id face)))
 228       (if (< fid 64) ; we have 32 - 3(LSB) - 1(SIGN) - 22(CHAR) = 6 bits for face id
 229           (logior char (lsh fid 22))
 230         (cons char fid)))))
 231
 232 ;;;###autoload
 233 (defun glyph-char (glyph)
 234   "Return the character of glyph code GLYPH."
 235   (if (consp glyph)
 236       (car glyph)
 237     (logand glyph #x3fffff)))
 238
 239 ;;;###autoload
 240 (defun glyph-face (glyph)
 241   "Return the face of glyph code GLYPH, or nil if glyph has default face."
 242   (let ((face-id (if (consp glyph) (cdr glyph) (lsh glyph -22))))
 243     (and (> face-id 0)
 244          (catch 'face
 245            (dolist (face (face-list))
 246              (when (eq (face-id face) face-id)
 247                (throw 'face face)))))))
 248
 249 ;;;###autoload
 250 (defun standard-display-european (arg)
 251   "Semi-obsolete way to toggle display of ISO 8859 European characters.
 252
 253 This function is semi-obsolete; you probably don't need it, or else you
 254 probably should use `set-language-environment' or `set-locale-environment'.
 255
 256 This function enables European character display if ARG is positive,
 257 disables it if negative.  Otherwise, it toggles European character display.
 258
 259 When this mode is enabled, characters in the range of 160 to 255
 260 display not as octal escapes, but as accented characters.  Codes 146
 261 and 160 display as apostrophe and space, even though they are not the
 262 ASCII codes for apostrophe and space.
 263
 264 Enabling European character display with this command noninteractively
 265 from Lisp code also selects Latin-1 as the language environment.
 266 This provides increased compatibility for users who call this function
 267 in `.emacs'."
 268
 269   (if (or (<= (prefix-numeric-value arg) 0)
 270           (and (null arg)
 271                (char-table-p standard-display-table)
 272                ;; Test 161, because 160 displays as a space.
 273                (equal (aref standard-display-table
 274                             (unibyte-char-to-multibyte 161))
 275                       (vector (unibyte-char-to-multibyte 161)))))
 276       (progn
 277         (standard-display-default
 278          (unibyte-char-to-multibyte 160) (unibyte-char-to-multibyte 255))
 279         (unless (or (memq window-system '(x w32 ns)))
 280           (and (terminal-coding-system)
 281                (set-terminal-coding-system nil))))
 282
 283     (display-warning 'i18n
 284                      "`standard-display-european' is semi-obsolete; see its doc string for details"
 285                      :warning)
 286
 287     ;; Switch to Latin-1 language environment
 288     ;; unless some other has been specified.
 289     (if (equal current-language-environment "English")
 290         (set-language-environment "latin-1"))
 291     (unless (or noninteractive (memq window-system '(x w32 ns)))
 292       ;; Send those codes literally to a character-based terminal.
 293       ;; If we are using single-byte characters,
 294       ;; it doesn't matter which coding system we use.
 295       (set-terminal-coding-system
 296        (let ((c (intern (downcase current-language-environment))))
 297          (if (coding-system-p c) c 'latin-1))))
 298     (standard-display-european-internal)))
 299
 300 (provide 'disp-table)
 301
 302 ;;; disp-table.el ends here