lisp/calc/calc-misc.el

   1 ;;; calc-misc.el --- miscellaneous functions for Calc
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 2001, 2002, 2003, 2004
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: David Gillespie <daveg@synaptics.com>
   7 ;; Maintainer: Jay Belanger <jay.p.belanger@gmail.com>
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 ;; This file is autoloaded from calc.el.
  31
  32 (require 'calc)
  33 (require 'calc-macs)
  34
  35 ;; Declare functions which are defined elsewhere.
  36 (declare-function calc-do-keypad "calc-keypd" (&optional full-display interactive))
  37 (declare-function calc-inv-hyp-prefix-help "calc-help" ())
  38 (declare-function calc-inverse-prefix-help "calc-help" ())
  39 (declare-function calc-hyperbolic-prefix-help "calc-help" ())
  40 (declare-function calc-explain-why "calc-stuff" (why &optional more))
  41 (declare-function calc-clear-command-flag "calc-ext" (f))
  42 (declare-function calc-roll-down-with-selections "calc-sel" (n m))
  43 (declare-function calc-roll-up-with-selections "calc-sel" (n m))
  44 (declare-function calc-last-args "calc-undo" (n))
  45 (declare-function calc-is-inverse "calc-ext" ())
  46 (declare-function calc-do-prefix-help "calc-ext" (msgs group key))
  47 (declare-function math-objvecp "calc-ext" (a))
  48 (declare-function math-known-scalarp "calc-arith" (a &optional assume-scalar))
  49 (declare-function math-vectorp "calc-ext" (a))
  50 (declare-function math-matrixp "calc-ext" (a))
  51 (declare-function math-trunc-special "calc-arith" (a prec))
  52 (declare-function math-trunc-fancy "calc-arith" (a))
  53 (declare-function math-floor-special "calc-arith" (a prec))
  54 (declare-function math-floor-fancy "calc-arith" (a))
  55 (declare-function math-square-matrixp "calc-ext" (a))
  56 (declare-function math-matrix-inv-raw "calc-mtx" (m))
  57 (declare-function math-known-matrixp "calc-arith" (a))
  58 (declare-function math-mod-fancy "calc-arith" (a b))
  59 (declare-function math-pow-of-zero "calc-arith" (a b))
  60 (declare-function math-pow-zero "calc-arith" (a b))
  61 (declare-function math-pow-fancy "calc-arith" (a b))
  62
  63
  64 ;;;###autoload
  65 (defun calc-dispatch-help (arg)
  66   "C-x* is a prefix key sequence; follow it with one of these letters:
  67
  68 For turning Calc on and off:
  69   C  calc.  Start the Calculator in a window at the bottom of the screen.
  70   O  calc-other-window.  Start the Calculator but don't select its window.
  71   B  calc-big-or-small.  Control whether to use the full Emacs screen for Calc.
  72   Q  quick-calc.  Use the Calculator in the minibuffer.
  73   K  calc-keypad.  Start the Calculator in keypad mode (X window system only).
  74   E  calc-embedded.  Use the Calculator on a formula in this editing buffer.
  75   J  calc-embedded-select.  Like E, but select appropriate half of => or :=.
  76   W  calc-embedded-word.  Like E, but activate a single word, i.e., a number.
  77   Z  calc-user-invocation.  Invoke Calc in the way you defined with `Z I' cmd.
  78   X  calc-quit.  Turn Calc off.
  79
  80 For moving data into and out of Calc:
  81   G  calc-grab-region.  Grab the region defined by mark and point into Calc.
  82   R  calc-grab-rectangle.  Grab the rectangle defined by mark, point into Calc.
  83   :  calc-grab-sum-down.  Grab a rectangle and sum the columns.
  84   _  calc-grab-sum-across.  Grab a rectangle and sum the rows.
  85   Y  calc-copy-to-buffer.  Copy a value from the stack into the editing buffer.
  86
  87 For use with Embedded mode:
  88   A  calc-embedded-activate.  Find and activate all :='s and =>'s in buffer.
  89   D  calc-embedded-duplicate.  Make a copy of this formula and select it.
  90   F  calc-embedded-new-formula.  Insert a new formula at current point.
  91   N  calc-embedded-next.  Advance cursor to next known formula in buffer.
  92   P  calc-embedded-previous.  Advance cursor to previous known formula.
  93   U  calc-embedded-update-formula.  Re-evaluate formula at point.
  94   `  calc-embedded-edit.  Use calc-edit to edit formula at point.
  95
  96 Documentation:
  97   I  calc-info.  Read the Calculator manual in the Emacs Info system.
  98   T  calc-tutorial.  Run the Calculator Tutorial using the Emacs Info system.
  99   S  calc-summary.  Read the Summary from the Calculator manual in Info.
 100
 101 Miscellaneous:
 102   L  calc-load-everything.  Load all parts of the Calculator into memory.
 103   M  read-kbd-macro.  Read a region of keystroke names as a keyboard macro.
 104   0  (zero) calc-reset.  Reset Calc stack and modes to default state.
 105
 106 Press `*' twice (`C-x * *') to turn Calc on or off using the same
 107 Calc user interface as before (either C-x * C or C-x * K; initially C-x * C).
 108 "
 109   (interactive "P")
 110   (calc-check-defines)
 111   (if calc-dispatch-help
 112       (progn
 113         (save-window-excursion
 114           (describe-function 'calc-dispatch-help)
 115           (let ((win (get-buffer-window "*Help*")))
 116             (if win
 117                 (let (key)
 118                   (select-window win)
 119                   (while (progn
 120                            (message "Calc options: Calc, Keypad, ...  %s"
 121                                     "press SPC, DEL to scroll, C-g to cancel")
 122                            (memq (car (setq key (calc-read-key t)))
 123                                  '(?  ?\C-h ?\C-? ?\C-v ?\M-v)))
 124                     (condition-case err
 125                         (if (memq (car key) '(?  ?\C-v))
 126                             (scroll-up)
 127                           (scroll-down))
 128                       (error (beep))))
 129                       (calc-unread-command (cdr key))))))
 130         (calc-do-dispatch nil))
 131     (let ((calc-dispatch-help t))
 132       (calc-do-dispatch arg))))
 133
 134
 135 ;;;###autoload
 136 (defun calc-big-or-small (arg)
 137   "Toggle Calc between full-screen and regular mode."
 138   (interactive "P")
 139   (let ((cwin (get-buffer-window "*Calculator*"))
 140         (twin (get-buffer-window "*Calc Trail*"))
 141         (kwin (get-buffer-window "*Calc Keypad*")))
 142     (if cwin
 143         (setq calc-full-mode
 144               (if kwin
 145                   (and twin (eq (window-width twin) (frame-width)))
 146                 (eq (window-height cwin) (1- (frame-height))))))
 147     (setq calc-full-mode (if arg
 148                              (> (prefix-numeric-value arg) 0)
 149                            (not calc-full-mode)))
 150     (if kwin
 151         (progn
 152           (calc-quit)
 153           (calc-do-keypad calc-full-mode nil))
 154       (if cwin
 155           (progn
 156             (calc-quit)
 157             (calc nil calc-full-mode nil))))
 158     (message (if calc-full-mode
 159                  "Now using full screen for Calc"
 160                "Now using partial screen for Calc"))))
 161
 162 ;;;###autoload
 163 (defun calc-other-window (&optional interactive)
 164   "Invoke the Calculator in another window."
 165   (interactive "p")
 166   (if (memq major-mode '(calc-mode calc-trail-mode))
 167       (progn
 168         (other-window 1)
 169         (if (memq major-mode '(calc-mode calc-trail-mode))
 170             (other-window 1)))
 171     (if (get-buffer-window "*Calculator*")
 172         (calc-quit)
 173       (let ((win (selected-window)))
 174         (calc nil win interactive)))))
 175
 176 ;;;###autoload
 177 (defun another-calc ()
 178   "Create another, independent Calculator buffer."
 179   (interactive)
 180   (if (eq major-mode 'calc-mode)
 181       (mapc (function
 182              (lambda (v)
 183               (set-default v (symbol-value v)))) calc-local-var-list))
 184   (set-buffer (generate-new-buffer "*Calculator*"))
 185   (pop-to-buffer (current-buffer))
 186   (calc-mode))
 187
 188 ;;;###autoload
 189 (defun calc-info ()
 190   "Run the Emacs Info system on the Calculator documentation."
 191   (interactive)
 192   (select-window (get-largest-window))
 193   (info "Calc"))
 194
 195 ;;;###autoload
 196 (defun calc-info-goto-node (node)
 197   "Go to a node in the Calculator info documentation."
 198   (interactive)
 199   (select-window (get-largest-window))
 200   (info (concat "(Calc)" node)))
 201
 202 ;;;###autoload
 203 (defun calc-tutorial ()
 204   "Run the Emacs Info system on the Calculator Tutorial."
 205   (interactive)
 206   (if (get-buffer-window "*Calculator*")
 207       (calc-quit))
 208   (calc-info-goto-node "Interactive Tutorial")
 209   (calc-other-window)
 210   (message "Welcome to the Calc Tutorial!"))
 211
 212 ;;;###autoload
 213 (defun calc-info-summary ()
 214   "Run the Emacs Info system on the Calculator Summary."
 215   (interactive)
 216   (calc-info-goto-node "Summary"))
 217
 218 ;;;###autoload
 219 (defun calc-help ()
 220   (interactive)
 221   (let ((msgs (append
 222          '("Press `h' for complete help; press `?' repeatedly for a summary"
 223            "Letter keys: Negate; Precision; Yank; Why; Xtended cmd; Quit"
 224            "Letter keys: SHIFT + Undo, reDo; Keep-args; Inverse, Hyperbolic"
 225            "Letter keys: SHIFT + sQrt; Sin, Cos, Tan; Exp, Ln, logB"
 226            "Letter keys: SHIFT + Floor, Round; Abs, conJ, arG; Pi"
 227            "Letter keys: SHIFT + Num-eval; More-recn; eXec-kbd-macro"
 228            "Other keys: +, -, *, /, ^, \\ (int div), : (frac div)"
 229            "Other keys: & (1/x), | (concat), % (modulo), ! (factorial)"
 230            "Other keys: ' (alg-entry), = (eval), ` (edit); M-RET (last-args)"
 231            "Other keys: SPC/RET (enter/dup), LFD (over); < > (scroll horiz)"
 232            "Other keys: DEL (drop), M-DEL (drop-above); { } (scroll vert)"
 233            "Other keys: TAB (swap/roll-dn), M-TAB (roll-up)"
 234            "Other keys: [ , ; ] (vector), ( , ) (complex), ( ; ) (polar)"
 235            "Prefix keys: Algebra, Binary/business, Convert, Display"
 236            "Prefix keys: Functions, Graphics, Help, J (select)"
 237            "Prefix keys: Kombinatorics/statistics, Modes, Store/recall"
 238            "Prefix keys: Trail/time, Units/statistics, Vector/matrix"
 239            "Prefix keys: Z (user), SHIFT + Z (define)"
 240            "Prefix keys: prefix + ? gives further help for that prefix")
 241          (list (format
 242                 "  Calc %s by Dave Gillespie, daveg@synaptics.com"
 243                 calc-version)))))
 244     (if calc-full-help-flag
 245         msgs
 246       (if (or calc-inverse-flag calc-hyperbolic-flag)
 247           (if calc-inverse-flag
 248               (if calc-hyperbolic-flag
 249                   (calc-inv-hyp-prefix-help)
 250                 (calc-inverse-prefix-help))
 251             (calc-hyperbolic-prefix-help))
 252         (setq calc-help-phase
 253               (if (eq this-command last-command)
 254                   (% (1+ calc-help-phase) (1+ (length msgs)))
 255                 0))
 256         (let ((msg (nth calc-help-phase msgs)))
 257           (message "%s" (if msg
 258                             (concat msg ":"
 259                                     (make-string (- (apply 'max
 260                                                            (mapcar 'length
 261                                                                    msgs))
 262                                                     (length msg)) 32)
 263                                     "  [?=MORE]")
 264                           "")))))))
 265
 266
 267
 268
 269 ;;;; Stack and buffer management.
 270
 271 ;; The variable calc-last-why-command is set in calc-do-handly-whys
 272 ;; and used in calc-why (in calc-stuff.el).
 273 (defvar calc-last-why-command)
 274
 275 ;;;###autoload
 276 (defun calc-do-handle-whys ()
 277   (setq calc-why (sort calc-next-why
 278                        (function
 279                         (lambda (x y)
 280                           (and (eq (car x) '*) (not (eq (car y) '*))))))
 281         calc-next-why nil)
 282   (if (and calc-why (or (eq calc-auto-why t)
 283                         (and (eq (car (car calc-why)) '*)
 284                              calc-auto-why)))
 285       (progn
 286         (require 'calc-ext)
 287         (calc-explain-why (car calc-why)
 288                           (if (eq calc-auto-why t)
 289                               (cdr calc-why)
 290                             (if calc-auto-why
 291                                 (eq (car (nth 1 calc-why)) '*))))
 292         (setq calc-last-why-command this-command)
 293         (calc-clear-command-flag 'clear-message))))
 294
 295 ;;;###autoload
 296 (defun calc-record-why (&rest stuff)
 297   (if (eq (car stuff) 'quiet)
 298       (setq stuff (cdr stuff))
 299     (if (and (symbolp (car stuff))
 300              (cdr stuff)
 301              (or (Math-objectp (nth 1 stuff))
 302                  (and (Math-vectorp (nth 1 stuff))
 303                       (math-constp (nth 1 stuff)))
 304                  (math-infinitep (nth 1 stuff))))
 305         (setq stuff (cons '* stuff))
 306       (if (and (stringp (car stuff))
 307                (string-match "\\`\\*" (car stuff)))
 308           (setq stuff (cons '* (cons (substring (car stuff) 1)
 309                                      (cdr stuff)))))))
 310   (setq calc-next-why (cons stuff calc-next-why))
 311   nil)
 312
 313 ;; True if A is a constant or vector of constants.  [P x] [Public]
 314 ;;;###autoload
 315 (defun math-constp (a)
 316   (or (Math-scalarp a)
 317       (and (memq (car a) '(sdev intv mod vec))
 318            (progn
 319              (while (and (setq a (cdr a))
 320                          (or (Math-scalarp (car a))  ; optimization
 321                              (math-constp (car a)))))
 322              (null a)))))
 323
 324
 325 ;;;###autoload
 326 (defun calc-roll-down-stack (n &optional m)
 327   (if (< n 0)
 328       (calc-roll-up-stack (- n) m)
 329     (if (or (= n 0) (> n (calc-stack-size))) (setq n (calc-stack-size)))
 330     (or m (setq m 1))
 331     (and (> n 1)
 332          (< m n)
 333          (if (and calc-any-selections
 334                   (not calc-use-selections))
 335              (calc-roll-down-with-selections n m)
 336            (calc-pop-push-list n
 337                                (append (calc-top-list m 1)
 338                                        (calc-top-list (- n m) (1+ m))))))))
 339
 340 ;;;###autoload
 341 (defun calc-roll-up-stack (n &optional m)
 342   (if (< n 0)
 343       (calc-roll-down-stack (- n) m)
 344     (if (or (= n 0) (> n (calc-stack-size))) (setq n (calc-stack-size)))
 345     (or m (setq m 1))
 346     (and (> n 1)
 347          (< m n)
 348          (if (and calc-any-selections
 349                   (not calc-use-selections))
 350              (calc-roll-up-with-selections n m)
 351            (calc-pop-push-list n
 352                                (append (calc-top-list (- n m) 1)
 353                                        (calc-top-list m (- n m -1))))))))
 354
 355
 356 ;;;###autoload
 357 (defun calc-do-refresh ()
 358   (if calc-hyperbolic-flag
 359       (progn
 360         (setq calc-display-dirty t)
 361         nil)
 362     (calc-refresh)
 363     t))
 364
 365
 366 ;;;###autoload
 367 (defun calc-record-list (vals &optional prefix)
 368   (while vals
 369     (or (eq (car vals) 'top-of-stack)
 370         (progn
 371           (calc-record (car vals) prefix)
 372           (setq prefix "...")))
 373     (setq vals (cdr vals))))
 374
 375
 376 ;;;###autoload
 377 (defun calc-last-args-stub (arg)
 378   (interactive "p")
 379   (require 'calc-ext)
 380   (calc-last-args arg))
 381
 382
 383 ;;;###autoload
 384 (defun calc-power (arg)
 385   (interactive "P")
 386   (calc-slow-wrapper
 387    (if (and (featurep 'calc-ext)
 388             (calc-is-inverse))
 389        (calc-binary-op "root" 'calcFunc-nroot arg nil nil)
 390      (calc-binary-op "^" 'calcFunc-pow arg nil nil '^))))
 391
 392 ;;;###autoload
 393 (defun calc-mod (arg)
 394   (interactive "P")
 395   (calc-slow-wrapper
 396    (calc-binary-op "%" 'calcFunc-mod arg nil nil '%)))
 397
 398 ;;;###autoload
 399 (defun calc-inv (arg)
 400   (interactive "P")
 401   (calc-slow-wrapper
 402    (calc-unary-op "inv" 'calcFunc-inv arg)))
 403
 404 ;;;###autoload
 405 (defun calc-percent ()
 406   (interactive)
 407   (calc-slow-wrapper
 408    (calc-pop-push-record-list
 409     1 "%" (list (list 'calcFunc-percent (calc-top-n 1))))))
 410
 411
 412 ;;;###autoload
 413 (defun calc-over (n)
 414   (interactive "P")
 415   (if n
 416       (calc-enter (- (prefix-numeric-value n)))
 417     (calc-enter -2)))
 418
 419
 420 ;;;###autoload
 421 (defun calc-pop-above (n)
 422   (interactive "P")
 423   (if n
 424       (calc-pop (- (prefix-numeric-value n)))
 425     (calc-pop -2)))
 426
 427 ;;;###autoload
 428 (defun calc-roll-down (n)
 429   (interactive "P")
 430   (calc-wrapper
 431    (let ((nn (prefix-numeric-value n)))
 432      (cond ((null n)
 433             (calc-roll-down-stack 2))
 434            ((> nn 0)
 435             (calc-roll-down-stack nn))
 436            ((= nn 0)
 437             (calc-pop-push-list (calc-stack-size)
 438                                 (reverse
 439                                  (calc-top-list (calc-stack-size)))))
 440            (t
 441             (calc-roll-down-stack (calc-stack-size) (- nn)))))))
 442
 443 ;;;###autoload
 444 (defun calc-roll-up (n)
 445   (interactive "P")
 446   (calc-wrapper
 447    (let ((nn (prefix-numeric-value n)))
 448      (cond ((null n)
 449             (calc-roll-up-stack 3))
 450            ((> nn 0)
 451             (calc-roll-up-stack nn))
 452            ((= nn 0)
 453             (calc-pop-push-list (calc-stack-size)
 454                                 (reverse
 455                                  (calc-top-list (calc-stack-size)))))
 456            (t
 457             (calc-roll-up-stack (calc-stack-size) (- nn)))))))
 458
 459
 460
 461
 462 ;;; Other commands.
 463
 464 ;;;###autoload
 465 (defun calc-num-prefix-name (n)
 466   (cond ((eq n '-) "- ")
 467         ((equal n '(4)) "C-u ")
 468         ((consp n) (format "%d " (car n)))
 469         ((integerp n) (format "%d " n))
 470         (t "")))
 471
 472 ;;;###autoload
 473 (defun calc-missing-key (n)
 474   "This is a placeholder for a command which needs to be loaded from calc-ext.
 475 When this key is used, calc-ext (the Calculator extensions module) will be
 476 loaded and the keystroke automatically re-typed."
 477   (interactive "P")
 478   (require 'calc-ext)
 479   (if (keymapp (key-binding (char-to-string last-command-char)))
 480       (message "%s%c-" (calc-num-prefix-name n) last-command-char))
 481   (calc-unread-command)
 482   (setq prefix-arg n))
 483
 484 ;;;###autoload
 485 (defun calc-shift-Y-prefix-help ()
 486   (interactive)
 487   (require 'calc-ext)
 488   (calc-do-prefix-help calc-Y-help-msgs "other" ?Y))
 489
 490
 491
 492
 493 ;;;###autoload
 494 (defun calcDigit-letter ()
 495   (interactive)
 496   (if (calc-minibuffer-contains "[-+]?\\(1[1-9]\\|[2-9][0-9]\\)#.*")
 497       (progn
 498         (setq last-command-char (upcase last-command-char))
 499         (calcDigit-key))
 500     (calcDigit-nondigit)))
 501
 502
 503 ;; A Lisp version of temp_minibuffer_message from minibuf.c.
 504 ;;;###autoload
 505 (defun calc-temp-minibuffer-message (m)
 506   (let ((savemax (point-max)))
 507     (save-excursion
 508       (goto-char (point-max))
 509       (insert m))
 510     (let ((okay nil))
 511       (unwind-protect
 512           (progn
 513             (sit-for 2)
 514             (identity 1)   ; this forces a call to QUIT; in bytecode.c.
 515             (setq okay t))
 516         (progn
 517           (delete-region savemax (point-max))
 518           (or okay (abort-recursive-edit)))))))
 519
 520
 521 (put 'math-with-extra-prec 'lisp-indent-hook 1)
 522
 523
 524 ;; Concatenate two vectors, or a vector and an object.  [V O O] [Public]
 525 ;;;###autoload
 526 (defun math-concat (v1 v2)
 527   (if (stringp v1)
 528       (concat v1 v2)
 529     (require 'calc-ext)
 530     (if (and (or (math-objvecp v1) (math-known-scalarp v1))
 531              (or (math-objvecp v2) (math-known-scalarp v2)))
 532         (append (if (and (math-vectorp v1)
 533                          (or (math-matrixp v1)
 534                              (not (math-matrixp v2))))
 535                     v1
 536                   (list 'vec v1))
 537                 (if (and (math-vectorp v2)
 538                          (or (math-matrixp v2)
 539                              (not (math-matrixp v1))))
 540                     (cdr v2)
 541                   (list v2)))
 542       (list '| v1 v2))))
 543
 544
 545 ;; True if A is zero.  Works for un-normalized values.  [P n] [Public]
 546 ;;;###autoload
 547 (defun math-zerop (a)
 548   (if (consp a)
 549       (cond ((memq (car a) '(bigpos bigneg))
 550              (while (eq (car (setq a (cdr a))) 0))
 551              (null a))
 552             ((memq (car a) '(frac float polar mod))
 553              (math-zerop (nth 1 a)))
 554             ((eq (car a) 'cplx)
 555              (and (math-zerop (nth 1 a)) (math-zerop (nth 2 a))))
 556             ((eq (car a) 'hms)
 557              (and (math-zerop (nth 1 a))
 558                   (math-zerop (nth 2 a))
 559                   (math-zerop (nth 3 a)))))
 560     (eq a 0)))
 561
 562
 563 ;; True if A is real and negative.  [P n] [Public]
 564
 565 ;;;###autoload
 566 (defun math-negp (a)
 567   (if (consp a)
 568       (cond ((eq (car a) 'bigpos) nil)
 569             ((eq (car a) 'bigneg) (cdr a))
 570             ((memq (car a) '(float frac))
 571              (Math-integer-negp (nth 1 a)))
 572             ((eq (car a) 'hms)
 573              (if (math-zerop (nth 1 a))
 574                  (if (math-zerop (nth 2 a))
 575                      (math-negp (nth 3 a))
 576                    (math-negp (nth 2 a)))
 577                (math-negp (nth 1 a))))
 578             ((eq (car a) 'date)
 579              (math-negp (nth 1 a)))
 580             ((eq (car a) 'intv)
 581              (or (math-negp (nth 3 a))
 582                  (and (math-zerop (nth 3 a))
 583                       (memq (nth 1 a) '(0 2)))))
 584             ((equal a '(neg (var inf var-inf))) t))
 585     (< a 0)))
 586
 587 ;; True if A is a negative number or an expression the starts with '-'.
 588 ;;;###autoload
 589 (defun math-looks-negp (a)   ; [P x] [Public]
 590   (or (Math-negp a)
 591       (eq (car-safe a) 'neg)
 592       (and (memq (car-safe a) '(* /))
 593            (or (math-looks-negp (nth 1 a))
 594                (math-looks-negp (nth 2 a))))
 595       (and (eq (car-safe a) '-)
 596            (math-looks-negp (nth 1 a)))))
 597
 598
 599 ;; True if A is real and positive.  [P n] [Public]
 600 ;;;###autoload
 601 (defun math-posp (a)
 602   (if (consp a)
 603       (cond ((eq (car a) 'bigpos) (cdr a))
 604             ((eq (car a) 'bigneg) nil)
 605             ((memq (car a) '(float frac))
 606              (Math-integer-posp (nth 1 a)))
 607             ((eq (car a) 'hms)
 608              (if (math-zerop (nth 1 a))
 609                  (if (math-zerop (nth 2 a))
 610                      (math-posp (nth 3 a))
 611                    (math-posp (nth 2 a)))
 612                (math-posp (nth 1 a))))
 613             ((eq (car a) 'date)
 614              (math-posp (nth 1 a)))
 615             ((eq (car a) 'mod)
 616              (not (math-zerop (nth 1 a))))
 617             ((eq (car a) 'intv)
 618              (or (math-posp (nth 2 a))
 619                  (and (math-zerop (nth 2 a))
 620                       (memq (nth 1 a) '(0 1)))))
 621             ((equal a '(var inf var-inf)) t))
 622     (> a 0)))
 623
 624 ;;;###autoload
 625 (defalias 'math-fixnump 'integerp)
 626 ;;;###autoload
 627 (defalias 'math-fixnatnump 'natnump)
 628
 629
 630 ;; True if A is an even integer.  [P R R] [Public]
 631 ;;;###autoload
 632 (defun math-evenp (a)
 633   (if (consp a)
 634       (and (memq (car a) '(bigpos bigneg))
 635            (= (% (nth 1 a) 2) 0))
 636     (= (% a 2) 0)))
 637
 638 ;; Compute A / 2, for small or big integer A.  [I i]
 639 ;; If A is negative, type of truncation is undefined.
 640 ;;;###autoload
 641 (defun math-div2 (a)
 642   (if (consp a)
 643       (if (cdr a)
 644           (math-normalize (cons (car a) (math-div2-bignum (cdr a))))
 645         0)
 646     (/ a 2)))
 647
 648 ;;;###autoload
 649 (defun math-div2-bignum (a)   ; [l l]
 650   (if (cdr a)
 651       (cons (+ (/ (car a) 2) (* (% (nth 1 a) 2) (/ math-bignum-digit-size 2)))
 652             (math-div2-bignum (cdr a)))
 653     (list (/ (car a) 2))))
 654
 655
 656 ;; Reject an argument to a calculator function.  [Public]
 657 ;;;###autoload
 658 (defun math-reject-arg (&optional a p option)
 659   (if option
 660       (calc-record-why option p a)
 661     (if p
 662         (calc-record-why p a)))
 663   (signal 'wrong-type-argument (and a (if p (list p a) (list a)))))
 664
 665
 666 ;; Coerce A to be an integer (by truncation toward zero).  [I N] [Public]
 667
 668 ;; The variable math-trunc-prec is local to math-trunc, but used by
 669 ;; math-trunc-fancy in calc-arith.el, which is called by math-trunc.
 670
 671 ;;;###autoload
 672 (defun math-trunc (a &optional math-trunc-prec)
 673   (cond (math-trunc-prec
 674          (require 'calc-ext)
 675          (math-trunc-special a math-trunc-prec))
 676         ((Math-integerp a) a)
 677         ((Math-looks-negp a)
 678          (math-neg (math-trunc (math-neg a))))
 679         ((eq (car a) 'float)
 680          (math-scale-int (nth 1 a) (nth 2 a)))
 681         (t (require 'calc-ext)
 682            (math-trunc-fancy a))))
 683 ;;;###autoload
 684 (defalias 'calcFunc-trunc 'math-trunc)
 685
 686 ;; Coerce A to be an integer (by truncation toward minus infinity).  [I N]
 687
 688 ;; The variable math-floor-prec is local to math-floor, but used by
 689 ;; math-floor-fancy in calc-arith.el, which is called by math-floor.
 690
 691 ;;;###autoload
 692 (defun math-floor (a &optional math-floor-prec)    ;  [Public]
 693   (cond (math-floor-prec
 694          (require 'calc-ext)
 695          (math-floor-special a math-floor-prec))
 696         ((Math-integerp a) a)
 697         ((Math-messy-integerp a) (math-trunc a))
 698         ((Math-realp a)
 699          (if (Math-negp a)
 700              (math-add (math-trunc a) -1)
 701            (math-trunc a)))
 702         (t (require 'calc-ext)
 703            (math-floor-fancy a))))
 704 ;;;###autoload
 705 (defalias 'calcFunc-floor 'math-floor)
 706
 707
 708 ;;;###autoload
 709 (defun math-imod (a b)   ; [I I I] [Public]
 710   (if (and (not (consp a)) (not (consp b)))
 711       (if (= b 0)
 712           (math-reject-arg a "*Division by zero")
 713         (% a b))
 714     (cdr (math-idivmod a b))))
 715
 716
 717 ;;;###autoload
 718 (defun calcFunc-inv (m)
 719   (if (Math-vectorp m)
 720       (progn
 721         (require 'calc-ext)
 722         (if (math-square-matrixp m)
 723             (or (math-with-extra-prec 2 (math-matrix-inv-raw m))
 724                 (math-reject-arg m "*Singular matrix"))
 725           (math-reject-arg m 'square-matrixp)))
 726     (if (and
 727          (require 'calc-arith)
 728          (math-known-matrixp m))
 729         (math-pow m -1)
 730       (math-div 1 m))))
 731
 732 ;;;###autoload
 733 (defun math-do-working (msg arg)
 734   (or executing-kbd-macro
 735       (progn
 736         (calc-set-command-flag 'clear-message)
 737         (if math-working-step
 738             (if math-working-step-2
 739                 (setq msg (format "[%d/%d] %s"
 740                                   math-working-step math-working-step-2 msg))
 741               (setq msg (format "[%d] %s" math-working-step msg))))
 742         (message "Working... %s = %s" msg
 743                  (math-showing-full-precision (math-format-number arg))))))
 744
 745
 746 ;; Compute A modulo B, defined in terms of truncation toward minus infinity.
 747 ;;;###autoload
 748 (defun math-mod (a b)   ; [R R R] [Public]
 749   (cond ((and (Math-zerop a) (not (eq (car-safe a) 'mod))) a)
 750         ((Math-zerop b)
 751          (math-reject-arg a "*Division by zero"))
 752         ((and (Math-natnump a) (Math-natnump b))
 753          (math-imod a b))
 754         ((and (Math-anglep a) (Math-anglep b))
 755          (math-sub a (math-mul (math-floor (math-div a b)) b)))
 756         (t (require 'calc-ext)
 757            (math-mod-fancy a b))))
 758
 759
 760
 761 ;;; General exponentiation.
 762
 763 ;;;###autoload
 764 (defun math-pow (a b)   ; [O O N] [Public]
 765   (cond ((equal b '(var nan var-nan))
 766          b)
 767         ((Math-zerop a)
 768          (if (and (Math-scalarp b) (Math-posp b))
 769              (if (math-floatp b) (math-float a) a)
 770            (require 'calc-ext)
 771            (math-pow-of-zero a b)))
 772         ((or (eq a 1) (eq b 1)) a)
 773         ((or (equal a '(float 1 0)) (equal b '(float 1 0))) a)
 774         ((Math-zerop b)
 775          (if (Math-scalarp a)
 776              (if (or (math-floatp a) (math-floatp b))
 777                  '(float 1 0) 1)
 778            (require 'calc-ext)
 779            (math-pow-zero a b)))
 780         ((and (Math-integerp b) (or (Math-numberp a) (Math-vectorp a)))
 781          (if (and (equal a '(float 1 1)) (integerp b))
 782              (math-make-float 1 b)
 783            (math-with-extra-prec 2
 784              (math-ipow a b))))
 785         (t
 786          (require 'calc-ext)
 787          (math-pow-fancy a b))))
 788
 789 ;;;###autoload
 790 (defun math-ipow (a n)   ; [O O I] [Public]
 791   (cond ((Math-integer-negp n)
 792          (math-ipow (math-div 1 a) (Math-integer-neg n)))
 793         ((not (consp n))
 794          (if (and (Math-ratp a) (> n 20))
 795              (math-iipow-show a n)
 796            (math-iipow a n)))
 797         ((math-evenp n)
 798          (math-ipow (math-mul a a) (math-div2 n)))
 799         (t
 800          (math-mul a (math-ipow (math-mul a a)
 801                                 (math-div2 (math-add n -1)))))))
 802
 803 (defun math-iipow (a n)   ; [O O S]
 804   (cond ((= n 0) 1)
 805         ((= n 1) a)
 806         ((= (% n 2) 0) (math-iipow (math-mul a a) (/ n 2)))
 807         (t (math-mul a (math-iipow (math-mul a a) (/ n 2))))))
 808
 809 (defun math-iipow-show (a n)   ; [O O S]
 810   (math-working "pow" a)
 811   (let ((val (cond
 812               ((= n 0) 1)
 813               ((= n 1) a)
 814               ((= (% n 2) 0) (math-iipow-show (math-mul a a) (/ n 2)))
 815               (t (math-mul a (math-iipow-show (math-mul a a) (/ n 2)))))))
 816     (math-working "pow" val)
 817     val))
 818
 819
 820 ;;;###autoload
 821 (defun math-read-radix-digit (dig)   ; [D S; Z S]
 822   (if (> dig ?9)
 823       (if (< dig ?A)
 824           nil
 825         (- dig 55))
 826     (if (>= dig ?0)
 827         (- dig ?0)
 828       nil)))
 829
 830
 831 ;;; Bug reporting
 832
 833 ;;;###autoload
 834 (defun report-calc-bug ()
 835   "Report a bug in Calc, the GNU Emacs calculator.
 836 Prompts for bug subject.  Leaves you in a mail buffer."
 837   (interactive)
 838   (let ((reporter-prompt-for-summary-p t))
 839     (reporter-submit-bug-report calc-bug-address "Calc" '(calc-version)
 840                                 nil nil
 841                                 "Please describe exactly what actions triggered the bug and the
 842 precise symptoms of the bug.  If possible, include a backtrace by
 843 doing 'M-x toggle-debug-on-error', then reproducing the bug.
 844 " )))
 845 ;;;###autoload
 846 (defalias 'calc-report-bug 'report-calc-bug)
 847
 848 (provide 'calc-misc)
 849
 850 ;; Local variables:
 851 ;; generated-autoload-file: "calc-loaddefs.el"
 852 ;; End:
 853
 854 ;; arch-tag: 7984d9d0-62e5-41dc-afb8-e904b975f250
 855 ;;; calc-misc.el ends here