lisp/url/url-handlers.el

   1 ;;; url-handlers.el --- file-name-handler stuff for URL loading
   2
   3 ;; Copyright (C) 1996-1999, 2004-2011  Free Software Foundation, Inc.
   4
   5 ;; Keywords: comm, data, processes, hypermedia
   6
   7 ;; This file is part of GNU Emacs.
   8 ;;
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 ;; (require 'url)
  27 (require 'url-parse)
  28 ;; (require 'url-util)
  29 (eval-when-compile (require 'mm-decode))
  30 ;; (require 'mailcap)
  31 ;; The following functions in the byte compiler's warnings are known not
  32 ;; to cause any real problem for the following reasons:
  33 ;; - mm-save-part-to-file, mm-destroy-parts: always used
  34 ;;   after mm-dissect-buffer and defined in the same file.
  35 ;; The following are autoloaded instead of `require'd to avoid eagerly
  36 ;; loading all of URL when turning on url-handler-mode in the .emacs.
  37 (autoload 'url-expand-file-name "url-expand" "Convert url to a fully specified url, and canonicalize it.")
  38 (autoload 'mm-dissect-buffer "mm-decode" "Dissect the current buffer and return a list of MIME handles.")
  39 (autoload 'url-scheme-get-property "url-methods" "Get property of a URL SCHEME.")
  40
  41 ;; Implementation status
  42 ;; ---------------------
  43 ;; Function                             Status
  44 ;; ------------------------------------------------------------
  45 ;; add-name-to-file                     Needs DAV Bindings
  46 ;; copy-file                            Broken (assumes 1st item is URL)
  47 ;; delete-directory                     Finished (DAV)
  48 ;; delete-file                          Finished (DAV)
  49 ;; diff-latest-backup-file
  50 ;; directory-file-name                  unnecessary (what about VMS)?
  51 ;; directory-files                      Finished (DAV)
  52 ;; dired-call-process
  53 ;; dired-compress-file
  54 ;; dired-uncache
  55 ;; expand-file-name                     Finished
  56 ;; file-accessible-directory-p
  57 ;; file-attributes                      Finished, better with DAV
  58 ;; file-directory-p                     Needs DAV, finished
  59 ;; file-executable-p                    Finished
  60 ;; file-exists-p                        Finished
  61 ;; file-local-copy
  62 ;; file-modes
  63 ;; file-name-all-completions            Finished (DAV)
  64 ;; file-name-as-directory
  65 ;; file-name-completion                 Finished (DAV)
  66 ;; file-name-directory
  67 ;; file-name-nondirectory
  68 ;; file-name-sans-versions              why?
  69 ;; file-newer-than-file-p
  70 ;; file-ownership-preserved-p           No way to know
  71 ;; file-readable-p                      Finished
  72 ;; file-regular-p                       !directory_p
  73 ;; file-remote-p                        Finished
  74 ;; file-symlink-p                       Needs DAV bindings
  75 ;; file-truename                        Needs DAV bindings
  76 ;; file-writable-p                      Check for LOCK?
  77 ;; find-backup-file-name                why?
  78 ;; get-file-buffer                      why?
  79 ;; insert-directory                     Use DAV
  80 ;; insert-file-contents                 Finished
  81 ;; load
  82 ;; make-directory                       Finished (DAV)
  83 ;; make-symbolic-link                   Needs DAV bindings
  84 ;; rename-file                          Finished (DAV)
  85 ;; set-file-modes                       Use mod_dav specific executable flag?
  86 ;; set-visited-file-modtime             Impossible?
  87 ;; shell-command                        Impossible?
  88 ;; unhandled-file-name-directory
  89 ;; vc-registered                        Finished (DAV)
  90 ;; verify-visited-file-modtime
  91 ;; write-region
  92
  93 (defvar url-handler-regexp
  94   "\\`\\(https?\\|ftp\\|file\\|nfs\\)://"
  95   "*A regular expression for matching URLs handled by `file-name-handler-alist'.
  96 Some valid URL protocols just do not make sense to visit interactively
  97 \(about, data, info, irc, mailto, etc\).  This regular expression
  98 avoids conflicts with local files that look like URLs \(Gnus is
  99 particularly bad at this\).")
 100
 101 ;;;###autoload
 102 (define-minor-mode url-handler-mode
 103   "Use URL to handle URL-like file names."
 104   :global t :group 'url
 105   (if (not (boundp 'file-name-handler-alist))
 106       ;; Can't be turned ON anyway.
 107       (setq url-handler-mode nil)
 108     ;; Remove old entry, if any.
 109     (setq file-name-handler-alist
 110           (delq (rassq 'url-file-handler file-name-handler-alist)
 111                 file-name-handler-alist))
 112     (if url-handler-mode
 113         (push (cons url-handler-regexp 'url-file-handler)
 114               file-name-handler-alist))))
 115
 116 (defun url-run-real-handler (operation args)
 117   (let ((inhibit-file-name-handlers (cons 'url-file-handler
 118                                           (if (eq operation inhibit-file-name-operation)
 119                                               inhibit-file-name-handlers)))
 120         (inhibit-file-name-operation operation))
 121     (apply operation args)))
 122
 123 ;;;###autoload
 124 (defun url-file-handler (operation &rest args)
 125   "Function called from the `file-name-handler-alist' routines.
 126 OPERATION is what needs to be done (`file-exists-p', etc).  ARGS are
 127 the arguments that would have been passed to OPERATION."
 128   (let ((fn (or (get operation 'url-file-handlers)
 129                 (intern-soft (format "url-%s" operation))))
 130         (val nil)
 131         (hooked nil))
 132     (if (and fn (fboundp fn))
 133         (setq hooked t
 134               val (save-match-data (apply fn args)))
 135       (setq hooked nil
 136             val (url-run-real-handler operation args)))
 137     (url-debug 'handlers "%s %S%S => %S" (if hooked "Hooked" "Real")
 138                operation args val)
 139     val))
 140
 141 (defun url-file-handler-identity (&rest args)
 142   ;; Identity function
 143   (car args))
 144
 145 ;; These are operations that we can fully support
 146 (put 'file-readable-p 'url-file-handlers 'url-file-exists-p)
 147 (put 'substitute-in-file-name 'url-file-handlers 'url-file-handler-identity)
 148 (put 'file-name-absolute-p 'url-file-handlers (lambda (&rest ignored) t))
 149 (put 'expand-file-name 'url-file-handlers 'url-handler-expand-file-name)
 150 (put 'directory-file-name 'url-file-handlers 'url-handler-directory-file-name)
 151 (put 'unhandled-file-name-directory 'url-file-handlers 'url-handler-unhandled-file-name-directory)
 152 (put 'file-remote-p 'url-file-handlers 'url-handler-file-remote-p)
 153 ;; (put 'file-name-as-directory 'url-file-handlers 'url-handler-file-name-as-directory)
 154
 155 ;; These are operations that we do not support yet (DAV!!!)
 156 (put 'file-writable-p 'url-file-handlers 'ignore)
 157 (put 'file-symlink-p 'url-file-handlers 'ignore)
 158 ;; Just like for ange-ftp: let's not waste time trying to look for RCS/foo,v
 159 ;; files and such since we can't do anything clever with them anyway.
 160 (put 'vc-registered 'url-file-handlers 'ignore)
 161
 162 (defun url-handler-expand-file-name (file &optional base)
 163   ;; When we see "/foo/bar" in a file whose working dir is "http://bla/bla",
 164   ;; there are two interpretations possible: either it's a local "/foo/bar"
 165   ;; or it's "http:/bla/foo/bar".  When working with URLs, the second
 166   ;; interpretation is the right one, but when working with Emacs file
 167   ;; names, the first is preferred.
 168   (if (file-name-absolute-p file)
 169       (expand-file-name file "/")
 170     (url-expand-file-name file base)))
 171
 172 ;; directory-file-name and file-name-as-directory are kind of hard to
 173 ;; implement really right for URLs since URLs can have repeated / chars.
 174 ;; We'd want the following behavior:
 175 ;; idempotence: (d-f-n (d-f-n X) == (d-f-n X)
 176 ;; idempotence: (f-n-a-d (f-n-a-d X) == (f-n-a-d X)
 177 ;; reversible:  (d-f-n (f-n-a-d (d-f-n X))) == (d-f-n X)
 178 ;; reversible:  (f-n-a-d (d-f-n (f-n-a-d X))) == (f-n-a-d X)
 179 (defun url-handler-directory-file-name (dir)
 180   ;; When there's more than a single /, just don't touch the slashes at all.
 181   (if (string-match "//\\'" dir) dir
 182     (url-run-real-handler 'directory-file-name (list dir))))
 183
 184 (defun url-handler-unhandled-file-name-directory (filename)
 185   (let ((url (url-generic-parse-url filename)))
 186     (if (equal (url-type url) "file")
 187         ;; `file' URLs are actually local.  The filename part may be ""
 188         ;; which really stands for "/".
 189         ;; FIXME: maybe we should check that the host part is "" or "localhost"
 190         ;; or some name that represents the local host?
 191         (or (file-name-directory (url-filename url)) "/")
 192       ;; All other URLs are not expected to be directly accessible from
 193       ;; a local process.
 194       nil)))
 195
 196 (defun url-handler-file-remote-p (filename &optional identification connected)
 197   (let ((url (url-generic-parse-url filename)))
 198     (if (and (url-type url) (not (equal (url-type url) "file")))
 199         ;; Maybe we can find a suitable check for CONNECTED.  For now,
 200         ;; we ignore it.
 201         (cond
 202          ((eq identification 'method) (url-type url))
 203          ((eq identification 'user) (url-user url))
 204          ((eq identification 'host) (url-host url))
 205          ((eq identification 'localname) (url-filename url))
 206          (t (url-recreate-url
 207              (url-parse-make-urlobj (url-type url) (url-user url) nil
 208                                     (url-host url) (url-port url)))))
 209       ;; If there is no URL type, or it is a "file://" URL, the
 210       ;; filename is expected to be non remote.  A more subtle check
 211       ;; for "file://" URLs could be applied, as said in
 212       ;; `url-handler-unhandled-file-name-directory'.
 213       nil)))
 214
 215 ;; The actual implementation
 216 ;;;###autoload
 217 (defun url-copy-file (url newname &optional ok-if-already-exists
 218                           keep-time preserve-uid-gid)
 219   "Copy URL to NEWNAME.  Both args must be strings.
 220 Signals a `file-already-exists' error if file NEWNAME already exists,
 221 unless a third argument OK-IF-ALREADY-EXISTS is supplied and non-nil.
 222 A number as third arg means request confirmation if NEWNAME already exists.
 223 This is what happens in interactive use with M-x.
 224 Fourth arg KEEP-TIME non-nil means give the new file the same
 225 last-modified time as the old one.  (This works on only some systems.)
 226 Fifth arg PRESERVE-UID-GID is ignored.
 227 A prefix arg makes KEEP-TIME non-nil."
 228   (if (and (file-exists-p newname)
 229            (not ok-if-already-exists))
 230       (error "Opening output file: File already exists, %s" newname))
 231   (let ((buffer (url-retrieve-synchronously url))
 232         (handle nil))
 233     (if (not buffer)
 234         (error "Opening input file: No such file or directory, %s" url))
 235     (with-current-buffer buffer
 236       (setq handle (mm-dissect-buffer t)))
 237     (mm-save-part-to-file handle newname)
 238     (kill-buffer buffer)
 239     (mm-destroy-parts handle)))
 240
 241 ;;;###autoload
 242 (defun url-file-local-copy (url &rest ignored)
 243   "Copy URL into a temporary file on this machine.
 244 Returns the name of the local copy, or nil, if FILE is directly
 245 accessible."
 246   (let ((filename (make-temp-file "url")))
 247     (url-copy-file url filename 'ok-if-already-exists)
 248     filename))
 249
 250 (defun url-insert (buffer &optional beg end)
 251   "Insert the body of a URL object.
 252 BUFFER should be a complete URL buffer as returned by `url-retrieve'.
 253 If the headers specify a coding-system, it is applied to the body before it is inserted.
 254 Returns a list of the form (SIZE CHARSET), where SIZE is the size in bytes
 255 of the inserted text and CHARSET is the charset that was specified in the header,
 256 or nil if none was found.
 257 BEG and END can be used to only insert a subpart of the body.
 258 They count bytes from the beginning of the body."
 259   (let* ((handle (with-current-buffer buffer (mm-dissect-buffer t)))
 260          (data (with-current-buffer (mm-handle-buffer handle)
 261                  (if beg
 262                      (buffer-substring (+ (point-min) beg)
 263                                        (if end (+ (point-min) end) (point-max)))
 264                    (buffer-string))))
 265          (charset (mail-content-type-get (mm-handle-type handle)
 266                                           'charset)))
 267     (mm-destroy-parts handle)
 268     (if charset
 269         (insert (mm-decode-string data (mm-charset-to-coding-system charset)))
 270       (insert data))
 271     (list (length data) charset)))
 272
 273 ;;;###autoload
 274 (defun url-insert-file-contents (url &optional visit beg end replace)
 275   (let ((buffer (url-retrieve-synchronously url)))
 276     (if (not buffer)
 277         (error "Opening input file: No such file or directory, %s" url))
 278     (if visit (setq buffer-file-name url))
 279     (save-excursion
 280       (let* ((start (point))
 281              (size-and-charset (url-insert buffer beg end)))
 282         (kill-buffer buffer)
 283         (when replace
 284           (delete-region (point-min) start)
 285           (delete-region (point) (point-max)))
 286         (unless (cadr size-and-charset)
 287           ;; If the headers don't specify any particular charset, use the
 288           ;; usual heuristic/rules that we apply to files.
 289           (decode-coding-inserted-region start (point) url visit beg end replace))
 290         (list url (car size-and-charset))))))
 291
 292 (defun url-file-name-completion (url directory &optional predicate)
 293   (error "Unimplemented"))
 294
 295 (defun url-file-name-all-completions (file directory)
 296   (error "Unimplemented"))
 297
 298 ;; All other handlers map onto their respective backends.
 299 (defmacro url-handlers-create-wrapper (method args)
 300   `(defun ,(intern (format "url-%s" method)) ,args
 301      ,(format "URL file-name-handler wrapper for `%s' call.\n---\n%s" method
 302               (or (documentation method t) "No original documentation."))
 303      (setq url (url-generic-parse-url url))
 304      (when (url-type url)
 305        (funcall (url-scheme-get-property (url-type url) (quote ,method))
 306                 ,@(remove '&rest (remove '&optional args))))))
 307
 308 (url-handlers-create-wrapper file-exists-p (url))
 309 (url-handlers-create-wrapper file-attributes (url &optional id-format))
 310 (url-handlers-create-wrapper file-symlink-p (url))
 311 (url-handlers-create-wrapper file-writable-p (url))
 312 (url-handlers-create-wrapper file-directory-p (url))
 313 (url-handlers-create-wrapper file-executable-p (url))
 314 (url-handlers-create-wrapper directory-files (url &optional full match nosort))
 315 (url-handlers-create-wrapper file-truename (url &optional counter prev-dirs))
 316
 317 (add-hook 'find-file-hook 'url-handlers-set-buffer-mode)
 318
 319 (defun url-handlers-set-buffer-mode ()
 320   "Set correct modes for the current buffer if visiting a remote file."
 321   (and (stringp buffer-file-name)
 322        (string-match url-handler-regexp buffer-file-name)
 323        (auto-save-mode 0)))
 324
 325 (provide 'url-handlers)
 326
 327 ;;; url-handlers.el ends here