lisp/help-mode.el

   1 ;;; help-mode.el --- `help-mode' used by *Help* buffers
   2
   3 ;; Copyright (C) 1985-1986, 1993-1994, 1998-2018 Free Software
   4 ;; Foundation, Inc.
   5
   6 ;; Maintainer: emacs-devel@gnu.org
   7 ;; Keywords: help, internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Defines `help-mode', which is the mode used by *Help* buffers, and
  28 ;; associated support machinery, such as adding hyperlinks, etc.,
  29
  30 ;;; Code:
  31
  32 (require 'button)
  33 (require 'cl-lib)
  34 (eval-when-compile (require 'easymenu))
  35
  36 (defvar help-mode-map
  37   (let ((map (make-sparse-keymap)))
  38     (set-keymap-parent map (make-composed-keymap button-buffer-map
  39                                                  special-mode-map))
  40     (define-key map [mouse-2] 'help-follow-mouse)
  41     (define-key map "l" 'help-go-back)
  42     (define-key map "r" 'help-go-forward)
  43     (define-key map "\C-c\C-b" 'help-go-back)
  44     (define-key map "\C-c\C-f" 'help-go-forward)
  45     (define-key map [XF86Back] 'help-go-back)
  46     (define-key map [XF86Forward] 'help-go-forward)
  47     (define-key map "\C-c\C-c" 'help-follow-symbol)
  48     (define-key map "\r" 'help-follow)
  49     map)
  50   "Keymap for help mode.")
  51
  52 (easy-menu-define help-mode-menu help-mode-map
  53   "Menu for Help Mode."
  54   '("Help-Mode"
  55     ["Show Help for Symbol" help-follow-symbol
  56      :help "Show the docs for the symbol at point"]
  57     ["Previous Topic" help-go-back
  58      :help "Go back to previous topic in this help buffer"]
  59     ["Next Topic" help-go-forward
  60      :help "Go back to next topic in this help buffer"]
  61     ["Move to Previous Button" backward-button
  62      :help "Move to the Next Button in the help buffer"]
  63     ["Move to Next Button" forward-button
  64       :help "Move to the Next Button in the help buffer"]))
  65
  66 (defvar help-xref-stack nil
  67   "A stack of ways by which to return to help buffers after following xrefs.
  68 Used by `help-follow' and `help-xref-go-back'.
  69 An element looks like (POSITION FUNCTION ARGS...).
  70 To use the element, do (apply FUNCTION ARGS) then goto the point.")
  71 (put 'help-xref-stack 'permanent-local t)
  72 (make-variable-buffer-local 'help-xref-stack)
  73
  74 (defvar help-xref-forward-stack nil
  75   "A stack used to navigate help forwards after using the back button.
  76 Used by `help-follow' and `help-xref-go-forward'.
  77 An element looks like (POSITION FUNCTION ARGS...).
  78 To use the element, do (apply FUNCTION ARGS) then goto the point.")
  79 (put 'help-xref-forward-stack 'permanent-local t)
  80 (make-variable-buffer-local 'help-xref-forward-stack)
  81
  82 (defvar help-xref-stack-item nil
  83   "An item for `help-follow' in this buffer to push onto `help-xref-stack'.
  84 The format is (FUNCTION ARGS...).")
  85 (put 'help-xref-stack-item 'permanent-local t)
  86 (make-variable-buffer-local 'help-xref-stack-item)
  87
  88 (defvar help-xref-stack-forward-item nil
  89   "An item for `help-go-back' to push onto `help-xref-forward-stack'.
  90 The format is (FUNCTION ARGS...).")
  91 (put 'help-xref-stack-forward-item 'permanent-local t)
  92 (make-variable-buffer-local 'help-xref-stack-forward-item)
  93
  94 (setq-default help-xref-stack nil help-xref-stack-item nil)
  95 (setq-default help-xref-forward-stack nil help-xref-forward-stack-item nil)
  96
  97 (defcustom help-mode-hook nil
  98   "Hook run by `help-mode'."
  99   :type 'hook
 100   :group 'help)
 101 \f
 102 ;; Button types used by help
 103
 104 (define-button-type 'help-xref
 105   'follow-link t
 106   'action #'help-button-action)
 107
 108 (defun help-button-action (button)
 109   "Call BUTTON's help function."
 110   (help-do-xref nil
 111                 (button-get button 'help-function)
 112                 (button-get button 'help-args)))
 113
 114 ;; These 6 calls to define-button-type were generated in a dolist
 115 ;; loop, but that is bad because it means these button types don't
 116 ;; have an easily found definition.
 117
 118 (define-button-type 'help-function
 119   :supertype 'help-xref
 120   'help-function 'describe-function
 121   'help-echo (purecopy "mouse-2, RET: describe this function"))
 122
 123 (define-button-type 'help-variable
 124   :supertype 'help-xref
 125   'help-function 'describe-variable
 126   'help-echo (purecopy "mouse-2, RET: describe this variable"))
 127
 128 (define-button-type 'help-face
 129   :supertype 'help-xref
 130   'help-function 'describe-face
 131   'help-echo (purecopy "mouse-2, RET: describe this face"))
 132
 133 (define-button-type 'help-coding-system
 134   :supertype 'help-xref
 135   'help-function 'describe-coding-system
 136   'help-echo (purecopy "mouse-2, RET: describe this coding system"))
 137
 138 (define-button-type 'help-input-method
 139   :supertype 'help-xref
 140   'help-function 'describe-input-method
 141   'help-echo (purecopy "mouse-2, RET: describe this input method"))
 142
 143 (define-button-type 'help-character-set
 144   :supertype 'help-xref
 145   'help-function 'describe-character-set
 146   'help-echo (purecopy "mouse-2, RET: describe this character set"))
 147
 148 ;; Make some more idiosyncratic button types.
 149
 150 (define-button-type 'help-symbol
 151   :supertype 'help-xref
 152   'help-function #'describe-symbol
 153   'help-echo (purecopy "mouse-2, RET: describe this symbol"))
 154
 155 (define-button-type 'help-back
 156   :supertype 'help-xref
 157   'help-function #'help-xref-go-back
 158   'help-echo (purecopy "mouse-2, RET: go back to previous help buffer"))
 159
 160 (define-button-type 'help-forward
 161   :supertype 'help-xref
 162   'help-function #'help-xref-go-forward
 163   'help-echo (purecopy "mouse-2, RET: move forward to next help buffer"))
 164
 165 (define-button-type 'help-info-variable
 166   :supertype 'help-xref
 167   ;; the name of the variable is put before the argument to Info
 168   'help-function (lambda (_a v) (info v))
 169   'help-echo (purecopy "mouse-2, RET: read this Info node"))
 170
 171 (define-button-type 'help-info
 172   :supertype 'help-xref
 173   'help-function #'info
 174   'help-echo (purecopy "mouse-2, RET: read this Info node"))
 175
 176 (define-button-type 'help-url
 177   :supertype 'help-xref
 178   'help-function #'browse-url
 179   'help-echo (purecopy "mouse-2, RET: view this URL in a browser"))
 180
 181 (define-button-type 'help-customize-variable
 182   :supertype 'help-xref
 183   'help-function (lambda (v)
 184                    (customize-variable v))
 185   'help-echo (purecopy "mouse-2, RET: customize variable"))
 186
 187 (define-button-type 'help-customize-face
 188   :supertype 'help-xref
 189   'help-function (lambda (v)
 190                    (customize-face v))
 191   'help-echo (purecopy "mouse-2, RET: customize face"))
 192
 193 (define-button-type 'help-function-def
 194   :supertype 'help-xref
 195   'help-function (lambda (fun &optional file type)
 196                    (or file
 197                        (setq file (find-lisp-object-file-name fun type)))
 198                    (if (not file)
 199                        (message "Unable to find defining file")
 200                      (require 'find-func)
 201                      (when (eq file 'C-source)
 202                        (setq file
 203                              (help-C-file-name (indirect-function fun) 'fun)))
 204                      ;; Don't use find-function-noselect because it follows
 205                      ;; aliases (which fails for built-in functions).
 206                      (let* ((location
 207                              (find-function-search-for-symbol fun type file))
 208                             (position (cdr location)))
 209                        (pop-to-buffer (car location))
 210                        (run-hooks 'find-function-after-hook)
 211                        (if position
 212                            (progn
 213                              ;; Widen the buffer if necessary to go to this position.
 214                              (when (or (< position (point-min))
 215                                        (> position (point-max)))
 216                                (widen))
 217                              (goto-char position))
 218                          (message "Unable to find location in file")))))
 219   'help-echo (purecopy "mouse-2, RET: find function's definition"))
 220
 221 (define-button-type 'help-function-cmacro ; FIXME: Obsolete since 24.4.
 222   :supertype 'help-xref
 223   'help-function (lambda (fun file)
 224                    (setq file (locate-library file t))
 225                    (if (and file (file-readable-p file))
 226                        (progn
 227                          (pop-to-buffer (find-file-noselect file))
 228                          (widen)
 229                          (goto-char (point-min))
 230                          (if (re-search-forward
 231                               (format "^[ \t]*(\\(cl-\\)?define-compiler-macro[ \t]+%s"
 232                                       (regexp-quote (symbol-name fun)))
 233                               nil t)
 234                              (forward-line 0)
 235                            (message "Unable to find location in file")))
 236                      (message "Unable to find file")))
 237   'help-echo (purecopy "mouse-2, RET: find function's compiler macro"))
 238
 239 (define-button-type 'help-variable-def
 240   :supertype 'help-xref
 241   'help-function (lambda (var &optional file)
 242                    (when (eq file 'C-source)
 243                      (setq file (help-C-file-name var 'var)))
 244                    (let* ((location (find-variable-noselect var file))
 245                           (position (cdr location)))
 246                      (pop-to-buffer (car location))
 247                      (run-hooks 'find-function-after-hook)
 248                      (if position
 249                            (progn
 250                              ;; Widen the buffer if necessary to go to this position.
 251                              (when (or (< position (point-min))
 252                                        (> position (point-max)))
 253                                (widen))
 254                              (goto-char position))
 255                        (message "Unable to find location in file"))))
 256   'help-echo (purecopy "mouse-2, RET: find variable's definition"))
 257
 258 (define-button-type 'help-face-def
 259   :supertype 'help-xref
 260   'help-function (lambda (fun file)
 261                    (require 'find-func)
 262                    ;; Don't use find-function-noselect because it follows
 263                    ;; aliases (which fails for built-in functions).
 264                    (let* ((location
 265                           (find-function-search-for-symbol fun 'defface file))
 266                          (position (cdr location)))
 267                      (pop-to-buffer (car location))
 268                      (if position
 269                            (progn
 270                              ;; Widen the buffer if necessary to go to this position.
 271                              (when (or (< position (point-min))
 272                                        (> position (point-max)))
 273                                (widen))
 274                              (goto-char position))
 275                        (message "Unable to find location in file"))))
 276   'help-echo (purecopy "mouse-2, RET: find face's definition"))
 277
 278 (define-button-type 'help-package
 279   :supertype 'help-xref
 280   'help-function 'describe-package
 281   'help-echo (purecopy "mouse-2, RET: Describe package"))
 282
 283 (define-button-type 'help-package-def
 284   :supertype 'help-xref
 285   'help-function (lambda (file) (dired file))
 286   'help-echo (purecopy "mouse-2, RET: visit package directory"))
 287
 288 (define-button-type 'help-theme-def
 289   :supertype 'help-xref
 290   'help-function 'find-file
 291   'help-echo (purecopy "mouse-2, RET: visit theme file"))
 292
 293 (define-button-type 'help-theme-edit
 294   :supertype 'help-xref
 295   'help-function 'customize-create-theme
 296   'help-echo (purecopy "mouse-2, RET: edit this theme file"))
 297
 298 (define-button-type 'help-dir-local-var-def
 299   :supertype 'help-xref
 300   'help-function (lambda (_var &optional file)
 301                    ;; FIXME: this should go to the point where the
 302                    ;; local variable was defined.
 303                    (find-file file))
 304   'help-echo (purecopy "mouse-2, RET: open directory-local variables file"))
 305
 306 \f
 307 (defvar bookmark-make-record-function)
 308
 309 ;;;###autoload
 310 (define-derived-mode help-mode special-mode "Help"
 311   "Major mode for viewing help text and navigating references in it.
 312 Entry to this mode runs the normal hook `help-mode-hook'.
 313 Commands:
 314 \\{help-mode-map}"
 315   (set (make-local-variable 'revert-buffer-function)
 316        'help-mode-revert-buffer)
 317   (set (make-local-variable 'bookmark-make-record-function)
 318        'help-bookmark-make-record))
 319
 320 ;;;###autoload
 321 (defun help-mode-setup ()
 322   "Enter Help Mode in the current buffer."
 323   (help-mode)
 324   (setq buffer-read-only nil))
 325
 326 ;;;###autoload
 327 (defun help-mode-finish ()
 328   "Finalize Help Mode setup in current buffer."
 329   (when (derived-mode-p 'help-mode)
 330     (setq buffer-read-only t)
 331     (help-make-xrefs (current-buffer))))
 332 \f
 333 ;; Grokking cross-reference information in doc strings and
 334 ;; hyperlinking it.
 335
 336 ;; This may have some scope for extension and the same or something
 337 ;; similar should be done for widget doc strings, which currently use
 338 ;; another mechanism.
 339
 340 (defvar help-back-label (purecopy "[back]")
 341   "Label to use by `help-make-xrefs' for the go-back reference.")
 342
 343 (defvar help-forward-label (purecopy "[forward]")
 344   "Label to use by `help-make-xrefs' for the go-forward reference.")
 345
 346 (defconst help-xref-symbol-regexp
 347   (purecopy (concat "\\(\\<\\(\\(variable\\|option\\)\\|"  ; Link to var
 348                     "\\(function\\|command\\|call\\)\\|"   ; Link to function
 349                     "\\(face\\)\\|"                        ; Link to face
 350                     "\\(symbol\\|program\\|property\\)\\|" ; Don't link
 351                     "\\(source \\(?:code \\)?\\(?:of\\|for\\)\\)\\)"
 352                     "[ \t\n]+\\)?"
 353                     ;; Note starting with word-syntax character:
 354                     "['`‘]\\(\\sw\\(\\sw\\|\\s_\\)+\\|`\\)['’]"))
 355   "Regexp matching doc string references to symbols.
 356
 357 The words preceding the quoted symbol can be used in doc strings to
 358 distinguish references to variables, functions and symbols.")
 359
 360 (defvar help-xref-mule-regexp nil
 361   "Regexp matching doc string references to MULE-related keywords.
 362
 363 It is usually nil, and is temporarily bound to an appropriate regexp
 364 when help commands related to multilingual environment (e.g.,
 365 `describe-coding-system') are invoked.")
 366
 367
 368 (defconst help-xref-info-regexp
 369   (purecopy
 370    "\\<[Ii]nfo[ \t\n]+\\(node\\|anchor\\)[ \t\n]+['`‘]\\([^'’]+\\)['’]")
 371   "Regexp matching doc string references to an Info node.")
 372
 373 (defconst help-xref-url-regexp
 374   (purecopy "\\<[Uu][Rr][Ll][ \t\n]+['`‘]\\([^'’]+\\)['’]")
 375   "Regexp matching doc string references to a URL.")
 376
 377 ;;;###autoload
 378 (defun help-setup-xref (item interactive-p)
 379   "Invoked from commands using the \"*Help*\" buffer to install some xref info.
 380
 381 ITEM is a (FUNCTION . ARGS) pair appropriate for recreating the help
 382 buffer after following a reference.  INTERACTIVE-P is non-nil if the
 383 calling command was invoked interactively.  In this case the stack of
 384 items for help buffer \"back\" buttons is cleared.
 385
 386 This should be called very early, before the output buffer is cleared,
 387 because we want to record the \"previous\" position of point so we can
 388 restore it properly when going back."
 389   (with-current-buffer (help-buffer)
 390     (when help-xref-stack-item
 391       (push (cons (point) help-xref-stack-item) help-xref-stack)
 392       (setq help-xref-forward-stack nil))
 393     (when interactive-p
 394       (let ((tail (nthcdr 10 help-xref-stack)))
 395         ;; Truncate the stack.
 396         (if tail (setcdr tail nil))))
 397     (setq help-xref-stack-item item)))
 398
 399 (defvar help-xref-following nil
 400   "Non-nil when following a help cross-reference.")
 401
 402 ;;;###autoload
 403 (defun help-buffer ()
 404   "Return the name of a buffer for inserting help.
 405 If `help-xref-following' is non-nil, this is the name of the
 406 current buffer.  Signal an error if this buffer is not derived
 407 from `help-mode'.
 408 Otherwise, return \"*Help*\", creating a buffer with that name if
 409 it does not already exist."
 410   (buffer-name                          ;for with-output-to-temp-buffer
 411    (if (not help-xref-following)
 412        (get-buffer-create "*Help*")
 413      (unless (derived-mode-p 'help-mode)
 414        (error "Current buffer is not in Help mode"))
 415      (current-buffer))))
 416
 417 (defvar describe-symbol-backends
 418   `((nil ,#'fboundp ,(lambda (s _b _f) (describe-function s)))
 419     (nil
 420      ,(lambda (symbol)
 421         (or (and (boundp symbol) (not (keywordp symbol)))
 422             (get symbol 'variable-documentation)))
 423      ,#'describe-variable)
 424     ("face" ,#'facep ,(lambda (s _b _f) (describe-face s))))
 425   "List of providers of information about symbols.
 426 Each element has the form (NAME TESTFUN DESCFUN) where:
 427   NAME is a string naming a category of object, such as \"type\" or \"face\".
 428   TESTFUN is a predicate which takes a symbol and returns non-nil if the
 429     symbol is such an object.
 430   DESCFUN is a function which takes three arguments (a symbol, a buffer,
 431     and a frame), inserts the description of that symbol in the current buffer
 432     and returns that text as well.")
 433
 434 ;;;###autoload
 435 (defun help-make-xrefs (&optional buffer)
 436   "Parse and hyperlink documentation cross-references in the given BUFFER.
 437
 438 Find cross-reference information in a buffer and activate such cross
 439 references for selection with `help-follow'.  Cross-references have
 440 the canonical form `...'  and the type of reference may be
 441 disambiguated by the preceding word(s) used in
 442 `help-xref-symbol-regexp'.  Faces only get cross-referenced if
 443 preceded or followed by the word `face'.  Variables without
 444 variable documentation do not get cross-referenced, unless
 445 preceded by the word `variable' or `option'.
 446
 447 If the variable `help-xref-mule-regexp' is non-nil, find also
 448 cross-reference information related to multilingual environment
 449 \(e.g., coding-systems).  This variable is also used to disambiguate
 450 the type of reference as the same way as `help-xref-symbol-regexp'.
 451
 452 A special reference `back' is made to return back through a stack of
 453 help buffers.  Variable `help-back-label' specifies the text for
 454 that."
 455   (interactive "b")
 456   (with-current-buffer (or buffer (current-buffer))
 457     (save-excursion
 458       (goto-char (point-min))
 459       ;; Skip the header-type info, though it might be useful to parse
 460       ;; it at some stage (e.g. "function in `library'").
 461       (forward-paragraph)
 462       (let ((old-modified (buffer-modified-p)))
 463         (let ((stab (syntax-table))
 464               (case-fold-search t)
 465               (inhibit-read-only t))
 466           (set-syntax-table emacs-lisp-mode-syntax-table)
 467           ;; The following should probably be abstracted out.
 468           (unwind-protect
 469               (progn
 470                 ;; Info references
 471                 (save-excursion
 472                   (while (re-search-forward help-xref-info-regexp nil t)
 473                     (let ((data (match-string 2)))
 474                       (save-match-data
 475                         (unless (string-match "^([^)]+)" data)
 476                           (setq data (concat "(emacs)" data)))
 477                         (setq data ;; possible newlines if para filled
 478                               (replace-regexp-in-string "[ \t\n]+" " " data t t)))
 479                       (help-xref-button 2 'help-info data))))
 480                 ;; URLs
 481                 (save-excursion
 482                   (while (re-search-forward help-xref-url-regexp nil t)
 483                     (let ((data (match-string 1)))
 484                       (help-xref-button 1 'help-url data))))
 485                 ;; Mule related keywords.  Do this before trying
 486                 ;; `help-xref-symbol-regexp' because some of Mule
 487                 ;; keywords have variable or function definitions.
 488                 (if help-xref-mule-regexp
 489                     (save-excursion
 490                       (while (re-search-forward help-xref-mule-regexp nil t)
 491                         (let* ((data (match-string 7))
 492                                (sym (intern-soft data)))
 493                           (cond
 494                            ((match-string 3) ; coding system
 495                             (and sym (coding-system-p sym)
 496                                  (help-xref-button 6 'help-coding-system sym)))
 497                            ((match-string 4) ; input method
 498                             (and (assoc data input-method-alist)
 499                                  (help-xref-button 7 'help-input-method data)))
 500                            ((or (match-string 5) (match-string 6)) ; charset
 501                             (and sym (charsetp sym)
 502                                  (help-xref-button 7 'help-character-set sym)))
 503                            ((assoc data input-method-alist)
 504                             (help-xref-button 7 'help-character-set data))
 505                            ((and sym (coding-system-p sym))
 506                             (help-xref-button 7 'help-coding-system sym))
 507                            ((and sym (charsetp sym))
 508                             (help-xref-button 7 'help-character-set sym)))))))
 509                 ;; Quoted symbols
 510                 (save-excursion
 511                   (while (re-search-forward help-xref-symbol-regexp nil t)
 512                     (let* ((data (match-string 8))
 513                            (sym (intern-soft data)))
 514                       (if sym
 515                           (cond
 516                            ((match-string 3) ; `variable' &c
 517                             (and (or (boundp sym) ; `variable' doesn't ensure
 518                                         ; it's actually bound
 519                                      (get sym 'variable-documentation))
 520                                  (help-xref-button 8 'help-variable sym)))
 521                            ((match-string 4) ; `function' &c
 522                             (and (fboundp sym) ; similarly
 523                                  (help-xref-button 8 'help-function sym)))
 524                            ((match-string 5) ; `face'
 525                             (and (facep sym)
 526                                  (help-xref-button 8 'help-face sym)))
 527                            ((match-string 6)) ; nothing for `symbol'
 528                            ((match-string 7)
 529                             (help-xref-button 8 'help-function-def sym))
 530                            ((cl-some (lambda (x) (funcall (nth 1 x) sym))
 531                                      describe-symbol-backends)
 532                             (help-xref-button 8 'help-symbol sym)))))))
 533                 ;; An obvious case of a key substitution:
 534                 (save-excursion
 535                   (while (re-search-forward
 536                           ;; Assume command name is only word and symbol
 537                           ;; characters to get things like `use M-x foo->bar'.
 538                           ;; Command required to end with word constituent
 539                           ;; to avoid `.' at end of a sentence.
 540                           "\\<M-x\\s-+\\(\\sw\\(\\sw\\|\\s_\\)*\\sw\\)" nil t)
 541                     (let ((sym (intern-soft (match-string 1))))
 542                       (if (fboundp sym)
 543                           (help-xref-button 1 'help-function sym)))))
 544                 ;; Look for commands in whole keymap substitutions:
 545                 (save-excursion
 546                   ;; Make sure to find the first keymap.
 547                   (goto-char (point-min))
 548                   ;; Find a header and the column at which the command
 549                   ;; name will be found.
 550
 551                   ;; If the keymap substitution isn't the last thing in
 552                   ;; the doc string, and if there is anything on the same
 553                   ;; line after it, this code won't recognize the end of it.
 554                   (while (re-search-forward "^key +binding\n\\(-+ +\\)-+\n\n"
 555                                             nil t)
 556                     (let ((col (- (match-end 1) (match-beginning 1))))
 557                       (while
 558                           (and (not (eobp))
 559                                ;; Stop at a pair of blank lines.
 560                                (not (looking-at-p "\n\\s-*\n")))
 561                         ;; Skip a single blank line.
 562                         (and (eolp) (forward-line))
 563                         (end-of-line)
 564                         (skip-chars-backward "^ \t\n")
 565                         (if (and (>= (current-column) col)
 566                                  (looking-at "\\(\\sw\\|\\s_\\)+$"))
 567                             (let ((sym (intern-soft (match-string 0))))
 568                               (if (fboundp sym)
 569                                   (help-xref-button 0 'help-function sym))))
 570                         (forward-line))))))
 571             (set-syntax-table stab))
 572           ;; Delete extraneous newlines at the end of the docstring
 573           (goto-char (point-max))
 574           (while (and (not (bobp)) (bolp))
 575             (delete-char -1))
 576           (insert "\n")
 577           (when (or help-xref-stack help-xref-forward-stack)
 578             (insert "\n"))
 579           ;; Make a back-reference in this buffer if appropriate.
 580           (when help-xref-stack
 581             (help-insert-xref-button help-back-label 'help-back
 582                                      (current-buffer)))
 583           ;; Make a forward-reference in this buffer if appropriate.
 584           (when help-xref-forward-stack
 585             (when help-xref-stack
 586               (insert "\t"))
 587             (help-insert-xref-button help-forward-label 'help-forward
 588                                      (current-buffer)))
 589           (when (or help-xref-stack help-xref-forward-stack)
 590             (insert "\n")))
 591         (set-buffer-modified-p old-modified)))))
 592
 593 ;;;###autoload
 594 (defun help-xref-button (match-number type &rest args)
 595   "Make a hyperlink for cross-reference text previously matched.
 596 MATCH-NUMBER is the subexpression of interest in the last matched
 597 regexp.  TYPE is the type of button to use.  Any remaining arguments are
 598 passed to the button's help-function when it is invoked.
 599 See `help-make-xrefs'."
 600   ;; Don't mung properties we've added specially in some instances.
 601   (unless (button-at (match-beginning match-number))
 602     (make-text-button (match-beginning match-number)
 603                       (match-end match-number)
 604                       'type type 'help-args args)))
 605
 606 ;;;###autoload
 607 (defun help-insert-xref-button (string type &rest args)
 608   "Insert STRING and make a hyperlink from cross-reference text on it.
 609 TYPE is the type of button to use.  Any remaining arguments are passed
 610 to the button's help-function when it is invoked.
 611 See `help-make-xrefs'."
 612   (unless (button-at (point))
 613     (insert-text-button string 'type type 'help-args args)))
 614
 615 ;;;###autoload
 616 (defun help-xref-on-pp (from to)
 617   "Add xrefs for symbols in `pp's output between FROM and TO."
 618   (if (> (- to from) 5000) nil
 619     (with-syntax-table emacs-lisp-mode-syntax-table
 620       (save-excursion
 621         (save-restriction
 622           (narrow-to-region from to)
 623           (goto-char (point-min))
 624           (ignore-errors
 625             (while (not (eobp))
 626               (cond
 627                ((looking-at-p "\"") (forward-sexp 1))
 628                ((looking-at-p "#<") (search-forward ">" nil 'move))
 629                ((looking-at "\\(\\(\\sw\\|\\s_\\)+\\)")
 630                 (let* ((sym (intern-soft (match-string 1)))
 631                        (type (cond ((fboundp sym) 'help-function)
 632                                    ((or (memq sym '(t nil))
 633                                         (keywordp sym))
 634                                     nil)
 635                                    ((and sym
 636                                          (or (boundp sym)
 637                                              (get sym
 638                                                   'variable-documentation)))
 639                                     'help-variable))))
 640                   (when type (help-xref-button 1 type sym)))
 641                 (goto-char (match-end 1)))
 642                (t (forward-char 1))))))))))
 643
 644 \f
 645 ;; Additional functions for (re-)creating types of help buffers.
 646
 647 ;;;###autoload
 648 (define-obsolete-function-alias 'help-xref-interned 'describe-symbol "25.1")
 649
 650 \f
 651 ;; Navigation/hyperlinking with xrefs
 652
 653 (defun help-xref-go-back (buffer)
 654   "From BUFFER, go back to previous help buffer text using `help-xref-stack'."
 655   (let (item position method args)
 656     (with-current-buffer buffer
 657       (push (cons (point) help-xref-stack-item) help-xref-forward-stack)
 658       (when help-xref-stack
 659         (setq item (pop help-xref-stack)
 660               ;; Clear the current item so that it won't get pushed
 661               ;; by the function we're about to call.  TODO: We could also
 662               ;; push it onto a "forward" stack and add a `forw' button.
 663               help-xref-stack-item nil
 664               position (car item)
 665               method (cadr item)
 666               args (cddr item))))
 667     (apply method args)
 668     (with-current-buffer buffer
 669       (if (get-buffer-window buffer)
 670           (set-window-point (get-buffer-window buffer) position)
 671         (goto-char position)))))
 672
 673 (defun help-xref-go-forward (buffer)
 674   "From BUFFER, go forward to next help buffer."
 675   (let (item position method args)
 676     (with-current-buffer buffer
 677       (push (cons (point) help-xref-stack-item) help-xref-stack)
 678       (when help-xref-forward-stack
 679         (setq item (pop help-xref-forward-stack)
 680               ;; Clear the current item so that it won't get pushed
 681               ;; by the function we're about to call.  TODO: We could also
 682               ;; push it onto a "forward" stack and add a `forw' button.
 683               help-xref-stack-item nil
 684               position (car item)
 685               method (cadr item)
 686               args (cddr item))))
 687     (apply method args)
 688     (with-current-buffer buffer
 689       (if (get-buffer-window buffer)
 690           (set-window-point (get-buffer-window buffer) position)
 691         (goto-char position)))))
 692
 693 (defun help-go-back ()
 694   "Go back to previous topic in this help buffer."
 695   (interactive)
 696   (if help-xref-stack
 697       (help-xref-go-back (current-buffer))
 698     (user-error "No previous help buffer")))
 699
 700 (defun help-go-forward ()
 701   "Go to the next topic in this help buffer."
 702   (interactive)
 703   (if help-xref-forward-stack
 704       (help-xref-go-forward (current-buffer))
 705     (user-error "No next help buffer")))
 706
 707 (defun help-do-xref (_pos function args)
 708   "Call the help cross-reference function FUNCTION with args ARGS.
 709 Things are set up properly so that the resulting help-buffer has
 710 a proper [back] button."
 711   ;; There is a reference at point.  Follow it.
 712   (let ((help-xref-following t))
 713     (apply function (if (eq function 'info)
 714                         (append args (list (generate-new-buffer-name "*info*"))) args))))
 715
 716 ;; The doc string is meant to explain what buttons do.
 717 (defun help-follow-mouse ()
 718   "Follow the cross-reference that you click on."
 719   (interactive)
 720   (error "No cross-reference here"))
 721
 722 ;; The doc string is meant to explain what buttons do.
 723 (defun help-follow ()
 724   "Follow cross-reference at point.
 725
 726 For the cross-reference format, see `help-make-xrefs'."
 727   (interactive)
 728   (user-error "No cross-reference here"))
 729
 730 (defun help-follow-symbol (&optional pos)
 731   "In help buffer, show docs for symbol at POS, defaulting to point.
 732 Show all docs for that symbol as either a variable, function or face."
 733   (interactive "d")
 734   (unless pos
 735     (setq pos (point)))
 736   ;; check if the symbol under point is a function, variable or face
 737   (let ((sym
 738          (intern
 739           (save-excursion
 740             (goto-char pos) (skip-syntax-backward "w_")
 741             (buffer-substring (point)
 742                               (progn (skip-syntax-forward "w_")
 743                                      (point)))))))
 744     (when (or (boundp sym)
 745               (get sym 'variable-documentation)
 746               (fboundp sym) (facep sym))
 747       (help-do-xref pos #'describe-symbol (list sym)))))
 748
 749 (defun help-mode-revert-buffer (_ignore-auto noconfirm)
 750   (when (or noconfirm (yes-or-no-p "Revert help buffer? "))
 751     (let ((pos (point))
 752           (item help-xref-stack-item)
 753           ;; Pretend there is no current item to add to the history.
 754           (help-xref-stack-item nil)
 755           ;; Use the current buffer.
 756           (help-xref-following t))
 757       (apply (car item) (cdr item))
 758       (goto-char pos))))
 759
 760 (defun help-insert-string (string)
 761   "Insert STRING to the help buffer and install xref info for it.
 762 This function can be used to restore the old contents of the help buffer
 763 when going back to the previous topic in the xref stack.  It is needed
 764 in case when it is impossible to recompute the old contents of the
 765 help buffer by other means."
 766   (setq help-xref-stack-item (list #'help-insert-string string))
 767   (with-output-to-temp-buffer (help-buffer)
 768     (insert string)))
 769
 770 \f
 771 ;; Bookmark support
 772
 773 (declare-function bookmark-prop-get "bookmark" (bookmark prop))
 774 (declare-function bookmark-make-record-default "bookmark"
 775                   (&optional no-file no-context posn))
 776
 777 (defun help-bookmark-make-record ()
 778   "Create and return a help-mode bookmark record.
 779 Implements `bookmark-make-record-function' for help-mode buffers."
 780   (unless (car help-xref-stack-item)
 781     (error "Cannot create bookmark - help command not known"))
 782   `(,@(bookmark-make-record-default 'NO-FILE 'NO-CONTEXT)
 783       (help-fn     . ,(car help-xref-stack-item))
 784       (help-args   . ,(cdr help-xref-stack-item))
 785       (position    . ,(point))
 786       (handler     . help-bookmark-jump)))
 787
 788 ;;;###autoload
 789 (defun help-bookmark-jump (bookmark)
 790   "Jump to help-mode bookmark BOOKMARK.
 791 Handler function for record returned by `help-bookmark-make-record'.
 792 BOOKMARK is a bookmark name or a bookmark record."
 793   (let ((help-fn    (bookmark-prop-get bookmark 'help-fn))
 794         (help-args  (bookmark-prop-get bookmark 'help-args))
 795         (position   (bookmark-prop-get bookmark 'position)))
 796     (apply help-fn help-args)
 797     (pop-to-buffer "*Help*")
 798     (goto-char position)))
 799
 800
 801 (provide 'help-mode)
 802
 803 ;;; help-mode.el ends here