lisp/image.el

   1 ;;; image.el --- image API
   2
   3 ;; Copyright (C) 1998-2012 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: multimedia
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28
  29 (defgroup image ()
  30   "Image support."
  31   :group 'multimedia)
  32
  33 (defalias 'image-refresh 'image-flush)
  34
  35 (defconst image-type-header-regexps
  36   `(("\\`/[\t\n\r ]*\\*.*XPM.\\*/" . xpm)
  37     ("\\`P[1-6][[:space:]]+\\(?:#.*[[:space:]]+\\)*[0-9]+[[:space:]]+[0-9]+" . pbm)
  38     ("\\`GIF8[79]a" . gif)
  39     ("\\`\x89PNG\r\n\x1a\n" . png)
  40     ("\\`[\t\n\r ]*#define \\([a-z0-9_]+\\)_width [0-9]+\n\
  41 #define \\1_height [0-9]+\n\\(\
  42 #define \\1_x_hot [0-9]+\n\
  43 #define \\1_y_hot [0-9]+\n\\)?\
  44 static \\(unsigned \\)?char \\1_bits" . xbm)
  45     ("\\`\\(?:MM\0\\*\\|II\\*\0\\)" . tiff)
  46     ("\\`[\t\n\r ]*%!PS" . postscript)
  47     ("\\`\xff\xd8" . jpeg)    ; used to be (image-jpeg-p . jpeg)
  48     (,(let* ((incomment-re "\\(?:[^-]\\|-[^-]\\)")
  49              (comment-re (concat "\\(?:!--" incomment-re "*-->[ \t\r\n]*<\\)")))
  50         (concat "\\(?:<\\?xml[ \t\r\n]+[^>]*>\\)?[ \t\r\n]*<"
  51                 comment-re "*"
  52                 "\\(?:!DOCTYPE[ \t\r\n]+[^>]*>[ \t\r\n]*<[ \t\r\n]*" comment-re "*\\)?"
  53                 "[Ss][Vv][Gg]"))
  54      . svg)
  55     )
  56   "Alist of (REGEXP . IMAGE-TYPE) pairs used to auto-detect image types.
  57 When the first bytes of an image file match REGEXP, it is assumed to
  58 be of image type IMAGE-TYPE if IMAGE-TYPE is a symbol.  If not a symbol,
  59 IMAGE-TYPE must be a pair (PREDICATE . TYPE).  PREDICATE is called
  60 with one argument, a string containing the image data.  If PREDICATE returns
  61 a non-nil value, TYPE is the image's type.")
  62
  63 (defvar image-type-file-name-regexps
  64   '(("\\.png\\'" . png)
  65     ("\\.gif\\'" . gif)
  66     ("\\.jpe?g\\'" . jpeg)
  67     ("\\.bmp\\'" . bmp)
  68     ("\\.xpm\\'" . xpm)
  69     ("\\.pbm\\'" . pbm)
  70     ("\\.xbm\\'" . xbm)
  71     ("\\.ps\\'" . postscript)
  72     ("\\.tiff?\\'" . tiff)
  73     ("\\.svgz?\\'" . svg)
  74     )
  75   "Alist of (REGEXP . IMAGE-TYPE) pairs used to identify image files.
  76 When the name of an image file match REGEXP, it is assumed to
  77 be of image type IMAGE-TYPE.")
  78
  79 ;; We rely on `auto-mode-alist' to detect xbm and xpm files, instead
  80 ;; of content autodetection.  Their contents are just C code, so it is
  81 ;; easy to generate false matches.
  82 (defvar image-type-auto-detectable
  83   '((pbm . t)
  84     (xbm . nil)
  85     (bmp . maybe)
  86     (gif . maybe)
  87     (png . maybe)
  88     (xpm . nil)
  89     (jpeg . maybe)
  90     (tiff . maybe)
  91     (svg . maybe)
  92     (postscript . nil))
  93   "Alist of (IMAGE-TYPE . AUTODETECT) pairs used to auto-detect image files.
  94 \(See `image-type-auto-detected-p').
  95
  96 AUTODETECT can be
  97  - t      always auto-detect.
  98  - nil    never auto-detect.
  99  - maybe  auto-detect only if the image type is available
 100             (see `image-type-available-p').")
 101
 102 (defcustom image-load-path
 103   (list (file-name-as-directory (expand-file-name "images" data-directory))
 104         'data-directory 'load-path)
 105   "List of locations in which to search for image files.
 106 If an element is a string, it defines a directory to search.
 107 If an element is a variable symbol whose value is a string, that
 108 value defines a directory to search.
 109 If an element is a variable symbol whose value is a list, the
 110 value is used as a list of directories to search."
 111   :type '(repeat (choice directory variable))
 112   :initialize 'custom-initialize-delay)
 113
 114
 115 (defun image-load-path-for-library (library image &optional path no-error)
 116   "Return a suitable search path for images used by LIBRARY.
 117
 118 It searches for IMAGE in `image-load-path' (excluding
 119 \"`data-directory'/images\") and `load-path', followed by a path
 120 suitable for LIBRARY, which includes \"../../etc/images\" and
 121 \"../etc/images\" relative to the library file itself, and then
 122 in \"`data-directory'/images\".
 123
 124 Then this function returns a list of directories which contains
 125 first the directory in which IMAGE was found, followed by the
 126 value of `load-path'.  If PATH is given, it is used instead of
 127 `load-path'.
 128
 129 If NO-ERROR is non-nil and a suitable path can't be found, don't
 130 signal an error.  Instead, return a list of directories as before,
 131 except that nil appears in place of the image directory.
 132
 133 Here is an example that uses a common idiom to provide
 134 compatibility with versions of Emacs that lack the variable
 135 `image-load-path':
 136
 137     ;; Shush compiler.
 138     (defvar image-load-path)
 139
 140     (let* ((load-path (image-load-path-for-library \"mh-e\" \"mh-logo.xpm\"))
 141            (image-load-path (cons (car load-path)
 142                                   (when (boundp 'image-load-path)
 143                                     image-load-path))))
 144       (mh-tool-bar-folder-buttons-init))"
 145   (unless library (error "No library specified"))
 146   (unless image   (error "No image specified"))
 147   (let (image-directory image-directory-load-path)
 148     ;; Check for images in image-load-path or load-path.
 149     (let ((img image)
 150           (dir (or
 151                 ;; Images in image-load-path.
 152                 (image-search-load-path image)
 153                 ;; Images in load-path.
 154                 (locate-library image)))
 155           parent)
 156       ;; Since the image might be in a nested directory (for
 157       ;; example, mail/attach.pbm), adjust `image-directory'
 158       ;; accordingly.
 159       (when dir
 160         (setq dir (file-name-directory dir))
 161         (while (setq parent (file-name-directory img))
 162           (setq img (directory-file-name parent)
 163                 dir (expand-file-name "../" dir))))
 164       (setq image-directory-load-path dir))
 165
 166     ;; If `image-directory-load-path' isn't Emacs's image directory,
 167     ;; it's probably a user preference, so use it. Then use a
 168     ;; relative setting if possible; otherwise, use
 169     ;; `image-directory-load-path'.
 170     (cond
 171      ;; User-modified image-load-path?
 172      ((and image-directory-load-path
 173            (not (equal image-directory-load-path
 174                        (file-name-as-directory
 175                         (expand-file-name "images" data-directory)))))
 176       (setq image-directory image-directory-load-path))
 177      ;; Try relative setting.
 178      ((let (library-name d1ei d2ei)
 179         ;; First, find library in the load-path.
 180         (setq library-name (locate-library library))
 181         (if (not library-name)
 182             (error "Cannot find library %s in load-path" library))
 183         ;; And then set image-directory relative to that.
 184         (setq
 185          ;; Go down 2 levels.
 186          d2ei (file-name-as-directory
 187                (expand-file-name
 188                 (concat (file-name-directory library-name) "../../etc/images")))
 189          ;; Go down 1 level.
 190          d1ei (file-name-as-directory
 191                (expand-file-name
 192                 (concat (file-name-directory library-name) "../etc/images"))))
 193         (setq image-directory
 194               ;; Set it to nil if image is not found.
 195               (cond ((file-exists-p (expand-file-name image d2ei)) d2ei)
 196                     ((file-exists-p (expand-file-name image d1ei)) d1ei)))))
 197      ;; Use Emacs's image directory.
 198      (image-directory-load-path
 199       (setq image-directory image-directory-load-path))
 200      (no-error
 201       (message "Could not find image %s for library %s" image library))
 202      (t
 203       (error "Could not find image %s for library %s" image library)))
 204
 205     ;; Return an augmented `path' or `load-path'.
 206     (nconc (list image-directory)
 207            (delete image-directory (copy-sequence (or path load-path))))))
 208
 209
 210 ;; Used to be in image-type-header-regexps, but now not used anywhere
 211 ;; (since 2009-08-28).
 212 (defun image-jpeg-p (data)
 213   "Value is non-nil if DATA, a string, consists of JFIF image data.
 214 We accept the tag Exif because that is the same format."
 215   (setq data (ignore-errors (string-to-unibyte data)))
 216   (when (and data (string-match-p "\\`\xff\xd8" data))
 217     (catch 'jfif
 218       (let ((len (length data)) (i 2))
 219         (while (< i len)
 220           (when (/= (aref data i) #xff)
 221             (throw 'jfif nil))
 222           (setq i (1+ i))
 223           (when (>= (+ i 2) len)
 224             (throw 'jfif nil))
 225           (let ((nbytes (+ (lsh (aref data (+ i 1)) 8)
 226                            (aref data (+ i 2))))
 227                 (code (aref data i)))
 228             (when (and (>= code #xe0) (<= code #xef))
 229               ;; APP0 LEN1 LEN2 "JFIF\0"
 230               (throw 'jfif
 231                      (string-match-p "JFIF\\|Exif"
 232                                      (substring data i (min (+ i nbytes) len)))))
 233             (setq i (+ i 1 nbytes))))))))
 234
 235
 236 ;;;###autoload
 237 (defun image-type-from-data (data)
 238   "Determine the image type from image data DATA.
 239 Value is a symbol specifying the image type or nil if type cannot
 240 be determined."
 241   (let ((types image-type-header-regexps)
 242         type)
 243     (while types
 244       (let ((regexp (car (car types)))
 245             (image-type (cdr (car types))))
 246         (if (or (and (symbolp image-type)
 247                      (string-match-p regexp data))
 248                 (and (consp image-type)
 249                      (funcall (car image-type) data)
 250                      (setq image-type (cdr image-type))))
 251             (setq type image-type
 252                   types nil)
 253           (setq types (cdr types)))))
 254     type))
 255
 256
 257 ;;;###autoload
 258 (defun image-type-from-buffer ()
 259   "Determine the image type from data in the current buffer.
 260 Value is a symbol specifying the image type or nil if type cannot
 261 be determined."
 262   (let ((types image-type-header-regexps)
 263         type
 264         (opoint (point)))
 265     (goto-char (point-min))
 266     (while types
 267       (let ((regexp (car (car types)))
 268             (image-type (cdr (car types)))
 269             data)
 270         (if (or (and (symbolp image-type)
 271                      (looking-at-p regexp))
 272                 (and (consp image-type)
 273                      (funcall (car image-type)
 274                               (or data
 275                                   (setq data
 276                                         (buffer-substring
 277                                          (point-min)
 278                                          (min (point-max)
 279                                               (+ (point-min) 256))))))
 280                      (setq image-type (cdr image-type))))
 281             (setq type image-type
 282                   types nil)
 283           (setq types (cdr types)))))
 284     (goto-char opoint)
 285     type))
 286
 287
 288 ;;;###autoload
 289 (defun image-type-from-file-header (file)
 290   "Determine the type of image file FILE from its first few bytes.
 291 Value is a symbol specifying the image type, or nil if type cannot
 292 be determined."
 293   (unless (or (file-readable-p file)
 294               (file-name-absolute-p file))
 295     (setq file (image-search-load-path file)))
 296   (and file
 297        (file-readable-p file)
 298        (with-temp-buffer
 299          (set-buffer-multibyte nil)
 300          (insert-file-contents-literally file nil 0 256)
 301          (image-type-from-buffer))))
 302
 303
 304 ;;;###autoload
 305 (defun image-type-from-file-name (file)
 306   "Determine the type of image file FILE from its name.
 307 Value is a symbol specifying the image type, or nil if type cannot
 308 be determined."
 309   (assoc-default file image-type-file-name-regexps 'string-match-p))
 310
 311
 312 ;;;###autoload
 313 (defun image-type (source &optional type data-p)
 314   "Determine and return image type.
 315 SOURCE is an image file name or image data.
 316 Optional TYPE is a symbol describing the image type.  If TYPE is omitted
 317 or nil, try to determine the image type from its first few bytes
 318 of image data.  If that doesn't work, and SOURCE is a file name,
 319 use its file extension as image type.
 320 Optional DATA-P non-nil means SOURCE is a string containing image data."
 321   (when (and (not data-p) (not (stringp source)))
 322     (error "Invalid image file name `%s'" source))
 323   (unless type
 324     (setq type (if data-p
 325                    (image-type-from-data source)
 326                  (or (image-type-from-file-header source)
 327                      (image-type-from-file-name source))))
 328     (or type (error "Cannot determine image type")))
 329   (or (memq type (and (boundp 'image-types) image-types))
 330       (error "Invalid image type `%s'" type))
 331   type)
 332
 333
 334 (if (fboundp 'image-metadata)           ; eg not --without-x
 335     (define-obsolete-function-alias 'image-extension-data
 336       'image-metadata' "24.1"))
 337
 338 (define-obsolete-variable-alias
 339     'image-library-alist
 340     'dynamic-library-alist "24.1")
 341
 342 ;;;###autoload
 343 (defun image-type-available-p (type)
 344   "Return non-nil if image type TYPE is available.
 345 Image types are symbols like `xbm' or `jpeg'."
 346   (and (fboundp 'init-image-library)
 347        (init-image-library type dynamic-library-alist)))
 348
 349
 350 ;;;###autoload
 351 (defun image-type-auto-detected-p ()
 352   "Return t if the current buffer contains an auto-detectable image.
 353 This function is intended to be used from `magic-fallback-mode-alist'.
 354
 355 The buffer is considered to contain an auto-detectable image if
 356 its beginning matches an image type in `image-type-header-regexps',
 357 and that image type is present in `image-type-auto-detectable' with a
 358 non-nil value.  If that value is non-nil, but not t, then the image type
 359 must be available."
 360   (let* ((type (image-type-from-buffer))
 361          (auto (and type (cdr (assq type image-type-auto-detectable)))))
 362     (and auto
 363          (or (eq auto t) (image-type-available-p type)))))
 364
 365
 366 ;;;###autoload
 367 (defun create-image (file-or-data &optional type data-p &rest props)
 368   "Create an image.
 369 FILE-OR-DATA is an image file name or image data.
 370 Optional TYPE is a symbol describing the image type.  If TYPE is omitted
 371 or nil, try to determine the image type from its first few bytes
 372 of image data.  If that doesn't work, and FILE-OR-DATA is a file name,
 373 use its file extension as image type.
 374 Optional DATA-P non-nil means FILE-OR-DATA is a string containing image data.
 375 Optional PROPS are additional image attributes to assign to the image,
 376 like, e.g. `:mask MASK'.
 377 Value is the image created, or nil if images of type TYPE are not supported.
 378
 379 Images should not be larger than specified by `max-image-size'.
 380
 381 Image file names that are not absolute are searched for in the
 382 \"images\" sub-directory of `data-directory' and
 383 `x-bitmap-file-path' (in that order)."
 384   ;; It is x_find_image_file in image.c that sets the search path.
 385   (setq type (image-type file-or-data type data-p))
 386   (when (image-type-available-p type)
 387     (append (list 'image :type type (if data-p :data :file) file-or-data)
 388             props)))
 389
 390
 391 ;;;###autoload
 392 (defun put-image (image pos &optional string area)
 393   "Put image IMAGE in front of POS in the current buffer.
 394 IMAGE must be an image created with `create-image' or `defimage'.
 395 IMAGE is displayed by putting an overlay into the current buffer with a
 396 `before-string' STRING that has a `display' property whose value is the
 397 image.  STRING is defaulted if you omit it.
 398 The overlay created will have the `put-image' property set to t.
 399 POS may be an integer or marker.
 400 AREA is where to display the image.  AREA nil or omitted means
 401 display it in the text area, a value of `left-margin' means
 402 display it in the left marginal area, a value of `right-margin'
 403 means display it in the right marginal area."
 404   (unless string (setq string "x"))
 405   (let ((buffer (current-buffer)))
 406     (unless (eq (car-safe image) 'image)
 407       (error "Not an image: %s" image))
 408     (unless (or (null area) (memq area '(left-margin right-margin)))
 409       (error "Invalid area %s" area))
 410     (setq string (copy-sequence string))
 411     (let ((overlay (make-overlay pos pos buffer))
 412           (prop (if (null area) image (list (list 'margin area) image))))
 413       (put-text-property 0 (length string) 'display prop string)
 414       (overlay-put overlay 'put-image t)
 415       (overlay-put overlay 'before-string string)
 416       overlay)))
 417
 418
 419 ;;;###autoload
 420 (defun insert-image (image &optional string area slice)
 421   "Insert IMAGE into current buffer at point.
 422 IMAGE is displayed by inserting STRING into the current buffer
 423 with a `display' property whose value is the image.  STRING
 424 defaults to the empty string if you omit it.
 425 AREA is where to display the image.  AREA nil or omitted means
 426 display it in the text area, a value of `left-margin' means
 427 display it in the left marginal area, a value of `right-margin'
 428 means display it in the right marginal area.
 429 SLICE specifies slice of IMAGE to insert.  SLICE nil or omitted
 430 means insert whole image.  SLICE is a list (X Y WIDTH HEIGHT)
 431 specifying the X and Y positions and WIDTH and HEIGHT of image area
 432 to insert.  A float value 0.0 - 1.0 means relative to the width or
 433 height of the image; integer values are taken as pixel values."
 434   ;; Use a space as least likely to cause trouble when it's a hidden
 435   ;; character in the buffer.
 436   (unless string (setq string " "))
 437   (unless (eq (car-safe image) 'image)
 438     (error "Not an image: %s" image))
 439   (unless (or (null area) (memq area '(left-margin right-margin)))
 440     (error "Invalid area %s" area))
 441   (if area
 442       (setq image (list (list 'margin area) image))
 443     ;; Cons up a new spec equal but not eq to `image' so that
 444     ;; inserting it twice in a row (adjacently) displays two copies of
 445     ;; the image.  Don't try to avoid this by looking at the display
 446     ;; properties on either side so that we DTRT more often with
 447     ;; cut-and-paste.  (Yanking killed image text next to another copy
 448     ;; of it loses anyway.)
 449     (setq image (cons 'image (cdr image))))
 450   (let ((start (point)))
 451     (insert string)
 452     (add-text-properties start (point)
 453                          `(display ,(if slice
 454                                         (list (cons 'slice slice) image)
 455                                       image) rear-nonsticky (display)))))
 456
 457
 458 ;;;###autoload
 459 (defun insert-sliced-image (image &optional string area rows cols)
 460   "Insert IMAGE into current buffer at point.
 461 IMAGE is displayed by inserting STRING into the current buffer
 462 with a `display' property whose value is the image.  STRING is
 463 defaulted if you omit it.
 464 AREA is where to display the image.  AREA nil or omitted means
 465 display it in the text area, a value of `left-margin' means
 466 display it in the left marginal area, a value of `right-margin'
 467 means display it in the right marginal area.
 468 The image is automatically split into ROWS x COLS slices."
 469   (unless string (setq string " "))
 470   (unless (eq (car-safe image) 'image)
 471     (error "Not an image: %s" image))
 472   (unless (or (null area) (memq area '(left-margin right-margin)))
 473     (error "Invalid area %s" area))
 474   (if area
 475       (setq image (list (list 'margin area) image))
 476     ;; Cons up a new spec equal but not eq to `image' so that
 477     ;; inserting it twice in a row (adjacently) displays two copies of
 478     ;; the image.  Don't try to avoid this by looking at the display
 479     ;; properties on either side so that we DTRT more often with
 480     ;; cut-and-paste.  (Yanking killed image text next to another copy
 481     ;; of it loses anyway.)
 482     (setq image (cons 'image (cdr image))))
 483   (let ((x 0.0) (dx (/ 1.0001 (or cols 1)))
 484          (y 0.0) (dy (/ 1.0001 (or rows 1))))
 485     (while (< y 1.0)
 486       (while (< x 1.0)
 487         (let ((start (point)))
 488           (insert string)
 489           (add-text-properties start (point)
 490                                `(display ,(list (list 'slice x y dx dy) image)
 491                                          rear-nonsticky (display)))
 492           (setq x (+ x dx))))
 493       (setq x 0.0
 494             y (+ y dy))
 495       (insert (propertize "\n" 'line-height t)))))
 496
 497
 498
 499 ;;;###autoload
 500 (defun remove-images (start end &optional buffer)
 501   "Remove images between START and END in BUFFER.
 502 Remove only images that were put in BUFFER with calls to `put-image'.
 503 BUFFER nil or omitted means use the current buffer."
 504   (unless buffer
 505     (setq buffer (current-buffer)))
 506   (let ((overlays (overlays-in start end)))
 507     (while overlays
 508       (let ((overlay (car overlays)))
 509         (when (overlay-get overlay 'put-image)
 510           (delete-overlay overlay)))
 511       (setq overlays (cdr overlays)))))
 512
 513 (defun image-search-load-path (file &optional path)
 514   (unless path
 515     (setq path image-load-path))
 516   (let (element found filename)
 517     (while (and (not found) (consp path))
 518       (setq element (car path))
 519       (cond
 520        ((stringp element)
 521         (setq found
 522               (file-readable-p
 523                (setq filename (expand-file-name file element)))))
 524        ((and (symbolp element) (boundp element))
 525         (setq element (symbol-value element))
 526         (cond
 527          ((stringp element)
 528           (setq found
 529                 (file-readable-p
 530                  (setq filename (expand-file-name file element)))))
 531          ((consp element)
 532           (if (setq filename (image-search-load-path file element))
 533               (setq found t))))))
 534       (setq path (cdr path)))
 535     (if found filename)))
 536
 537 ;;;###autoload
 538 (defun find-image (specs)
 539   "Find an image, choosing one of a list of image specifications.
 540
 541 SPECS is a list of image specifications.
 542
 543 Each image specification in SPECS is a property list.  The contents of
 544 a specification are image type dependent.  All specifications must at
 545 least contain the properties `:type TYPE' and either `:file FILE' or
 546 `:data DATA', where TYPE is a symbol specifying the image type,
 547 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 548 string containing the actual image data.  The specification whose TYPE
 549 is supported, and FILE exists, is used to construct the image
 550 specification to be returned.  Return nil if no specification is
 551 satisfied.
 552
 553 The image is looked for in `image-load-path'.
 554
 555 Image files should not be larger than specified by `max-image-size'."
 556   (let (image)
 557     (while (and specs (null image))
 558       (let* ((spec (car specs))
 559              (type (plist-get spec :type))
 560              (data (plist-get spec :data))
 561              (file (plist-get spec :file))
 562              found)
 563         (when (image-type-available-p type)
 564           (cond ((stringp file)
 565                  (if (setq found (image-search-load-path file))
 566                      (setq image
 567                            (cons 'image (plist-put (copy-sequence spec)
 568                                                    :file found)))))
 569                 ((not (null data))
 570                  (setq image (cons 'image spec)))))
 571         (setq specs (cdr specs))))
 572     image))
 573
 574
 575 ;;;###autoload
 576 (defmacro defimage (symbol specs &optional doc)
 577   "Define SYMBOL as an image.
 578
 579 SPECS is a list of image specifications.  DOC is an optional
 580 documentation string.
 581
 582 Each image specification in SPECS is a property list.  The contents of
 583 a specification are image type dependent.  All specifications must at
 584 least contain the properties `:type TYPE' and either `:file FILE' or
 585 `:data DATA', where TYPE is a symbol specifying the image type,
 586 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 587 string containing the actual image data.  The first image
 588 specification whose TYPE is supported, and FILE exists, is used to
 589 define SYMBOL.
 590
 591 Example:
 592
 593    (defimage test-image ((:type xpm :file \"~/test1.xpm\")
 594                          (:type xbm :file \"~/test1.xbm\")))"
 595   (declare (doc-string 3))
 596   `(defvar ,symbol (find-image ',specs) ,doc))
 597
 598 \f
 599 ;;; Animated image API
 600
 601 (defconst image-animated-types '(gif)
 602   "List of supported animated image types.")
 603
 604 (defun image-animated-p (image)
 605   "Return non-nil if IMAGE can be animated.
 606 To be capable of being animated, an image must be of a type
 607 listed in `image-animated-types', and contain more than one
 608 sub-image, with a specified animation delay.  The actual return
 609 value is a cons (NIMAGES . DELAY), where NIMAGES is the number
 610 of sub-images in the animated image and DELAY is the delay in
 611 seconds until the next sub-image should be displayed."
 612   (cond
 613    ((memq (plist-get (cdr image) :type) image-animated-types)
 614     (let* ((metadata (image-metadata image))
 615            (images (plist-get metadata 'count))
 616            (delay (plist-get metadata 'delay)))
 617       (when (and images (> images 1) (numberp delay))
 618         (if (< delay 0) (setq delay 0.1))
 619         (cons images delay))))))
 620
 621 ;; "Destructively"?
 622 (defun image-animate (image &optional index limit)
 623   "Start animating IMAGE.
 624 Animation occurs by destructively altering the IMAGE spec list.
 625
 626 With optional INDEX, begin animating from that animation frame.
 627 LIMIT specifies how long to animate the image.  If omitted or
 628 nil, play the animation until the end.  If t, loop forever.  If a
 629 number, play until that number of seconds has elapsed."
 630   (let ((animation (image-animated-p image))
 631         timer)
 632     (when animation
 633       (if (setq timer (image-animate-timer image))
 634           (cancel-timer timer))
 635       (run-with-timer 0.2 nil 'image-animate-timeout
 636                       image (or index 0) (car animation)
 637                       0 limit))))
 638
 639 (defun image-animate-timer (image)
 640   "Return the animation timer for image IMAGE."
 641   ;; See cancel-function-timers
 642   (let ((tail timer-list) timer)
 643     (while tail
 644       (setq timer (car tail)
 645             tail (cdr tail))
 646       (if (and (eq (aref timer 5) 'image-animate-timeout)
 647                (eq (car-safe (aref timer 6)) image))
 648           (setq tail nil)
 649         (setq timer nil)))
 650     timer))
 651
 652 ;; FIXME? The delay may not be the same for different sub-images,
 653 ;; hence we need to call image-animated-p to return it.
 654 ;; But it also returns count, so why do we bother passing that as an
 655 ;; argument?
 656 (defun image-animate-timeout (image n count time-elapsed limit)
 657   "Display animation frame N of IMAGE.
 658 N=0 refers to the initial animation frame.
 659 COUNT is the total number of frames in the animation.
 660 TIME-ELAPSED is the total time that has elapsed since
 661 `image-animate-start' was called.
 662 LIMIT determines when to stop.  If t, loop forever.  If nil, stop
 663  after displaying the last animation frame.  Otherwise, stop
 664  after LIMIT seconds have elapsed.
 665 The minimum delay between successive frames is 0.01s."
 666   (plist-put (cdr image) :index n)
 667   (force-window-update)
 668   (setq n (1+ n))
 669   (let* ((time (float-time))
 670          (animation (image-animated-p image))
 671          ;; Subtract off the time we took to load the image from the
 672          ;; stated delay time.
 673          (delay (max (+ (cdr animation) time (- (float-time)))
 674                      0.01))
 675          done)
 676     (if (>= n count)
 677         (if limit
 678             (setq n 0)
 679           (setq done t)))
 680     (setq time-elapsed (+ delay time-elapsed))
 681     (if (numberp limit)
 682         (setq done (>= time-elapsed limit)))
 683     (unless done
 684       (run-with-timer delay nil 'image-animate-timeout
 685                       image n count time-elapsed limit))))
 686
 687 \f
 688 (defvar imagemagick--file-regexp nil
 689   "File extension regexp for ImageMagick files, if any.
 690 This is the extension installed into `auto-mode-alist' and
 691 `image-type-file-name-regexps' by `imagemagick-register-types'.")
 692
 693 ;;;###autoload
 694 (defun imagemagick-register-types ()
 695   "Register file types that can be handled by ImageMagick.
 696 This function is called at startup, after loading the init file.
 697 It registers the ImageMagick types listed in `imagemagick-types',
 698 excluding those listed in `imagemagick-types-inhibit'.
 699
 700 Registered image types are added to `auto-mode-alist', so that
 701 Emacs visits them in Image mode.  They are also added to
 702 `image-type-file-name-regexps', so that the `image-type' function
 703 recognizes these files as having image type `imagemagick'.
 704
 705 If Emacs is compiled without ImageMagick support, do nothing."
 706   (when (fboundp 'imagemagick-types)
 707     (let ((re (if (eq imagemagick-types-inhibit t)
 708                   ;; Use a bogus regexp to inhibit matches.
 709                   "\\'a"
 710                 (let ((types))
 711                   (dolist (type (imagemagick-types))
 712                     (unless (memq type imagemagick-types-inhibit)
 713                       (push (downcase (symbol-name type)) types)))
 714                   (concat "\\." (regexp-opt types) "\\'"))))
 715           (ama-elt (car (member (cons imagemagick--file-regexp 'image-mode)
 716                                 auto-mode-alist)))
 717           (itfnr-elt (car (member (cons imagemagick--file-regexp 'imagemagick)
 718                                   image-type-file-name-regexps))))
 719       (if ama-elt
 720           (setcar ama-elt re)
 721         (push (cons re 'image-mode) auto-mode-alist))
 722       (if itfnr-elt
 723           (setcar itfnr-elt re)
 724         (push (cons re 'imagemagick) image-type-file-name-regexps))
 725       (setq imagemagick--file-regexp re))))
 726
 727 (defcustom imagemagick-types-inhibit
 728   '(C HTML HTM TXT PDF)
 729   "List of ImageMagick types that should not be treated as images.
 730 This should be a list of symbols, each of which should be one of
 731 the ImageMagick types listed in `imagemagick-types'.  The listed
 732 image types are not registered by `imagemagick-register-types'.
 733
 734 If the value is t, inhibit the use of ImageMagick for images.
 735
 736 If Emacs is compiled without ImageMagick support, this variable
 737 has no effect."
 738   :type '(choice (const :tag "Support all ImageMagick types" nil)
 739                  (const :tag "Disable all ImageMagick types" t)
 740                  (repeat symbol))
 741   :set (lambda (symbol value)
 742          (set-default symbol value)
 743          (imagemagick-register-types))
 744   :version "24.1"
 745   :group 'image)
 746
 747 (provide 'image)
 748
 749 ;;; image.el ends here