lisp/wid-edit.el

   1 ;;; wid-edit.el --- Functions for creating and using widgets -*-byte-compile-dynamic: t;-*-
   2 ;;
   3 ;; Copyright (C) 1996, 1997, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5 ;;
   6 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   7 ;; Maintainer: FSF
   8 ;; Keywords: extensions
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Wishlist items (from widget.texi):
  28
  29 ;; * The `menu-choice' tag should be prettier, something like the
  30 ;;   abbreviated menus in Open Look.
  31
  32 ;; * Finish `:tab-order'.
  33
  34 ;; * Make indentation work with glyphs and proportional fonts.
  35
  36 ;; * Add commands to show overview of object and class hierarchies to
  37 ;;   the browser.
  38
  39 ;; * Find a way to disable mouse highlight for inactive widgets.
  40
  41 ;; * Find a way to make glyphs look inactive.
  42
  43 ;; * Add `key-binding' widget.
  44
  45 ;; * Add `widget' widget for editing widget specifications.
  46
  47 ;; * Find clean way to implement variable length list.  See
  48 ;;   `TeX-printer-list' for an explanation.
  49
  50 ;; * `C-h' in `widget-prompt-value' should give type specific help.
  51
  52 ;; * A mailto widget. [This should work OK as a url-link if with
  53 ;;   browse-url-browser-function' set up appropriately.]
  54
  55 ;;; Commentary:
  56 ;;
  57 ;; See `widget.el'.
  58
  59 ;;; Code:
  60
  61 (defvar widget)
  62
  63 ;;; Compatibility.
  64
  65 (defun widget-event-point (event)
  66   "Character position of the end of event if that exists, or nil."
  67   (posn-point (event-end event)))
  68
  69 (defun widget-button-release-event-p (event)
  70   "Non-nil if EVENT is a mouse-button-release event object."
  71   (and (eventp event)
  72        (memq (event-basic-type event) '(mouse-1 mouse-2 mouse-3))
  73        (or (memq 'click (event-modifiers event))
  74            (memq  'drag (event-modifiers event)))))
  75
  76 ;;; Customization.
  77
  78 (defgroup widgets nil
  79   "Customization support for the Widget Library."
  80   :link '(custom-manual "(widget)Top")
  81   :link '(emacs-library-link :tag "Lisp File" "widget.el")
  82   :prefix "widget-"
  83   :group 'extensions
  84   :group 'hypermedia)
  85
  86 (defgroup widget-documentation nil
  87   "Options controlling the display of documentation strings."
  88   :group 'widgets)
  89
  90 (defgroup widget-faces nil
  91   "Faces used by the widget library."
  92   :group 'widgets
  93   :group 'faces)
  94
  95 (defvar widget-documentation-face 'widget-documentation
  96   "Face used for documentation strings in widgets.
  97 This exists as a variable so it can be set locally in certain buffers.")
  98
  99 (defface widget-documentation '((((class color)
 100                                   (background dark))
 101                                  (:foreground "lime green"))
 102                                 (((class color)
 103                                   (background light))
 104                                  (:foreground "dark green"))
 105                                 (t nil))
 106   "Face used for documentation text."
 107   :group 'widget-documentation
 108   :group 'widget-faces)
 109 ;; backward compatibility alias
 110 (put 'widget-documentation-face 'face-alias 'widget-documentation)
 111
 112 (defvar widget-button-face 'widget-button
 113   "Face used for buttons in widgets.
 114 This exists as a variable so it can be set locally in certain buffers.")
 115
 116 (defface widget-button '((t (:weight bold)))
 117   "Face used for widget buttons."
 118   :group 'widget-faces)
 119 ;; backward compatibility alias
 120 (put 'widget-button-face 'face-alias 'widget-button)
 121
 122 (defcustom widget-mouse-face 'highlight
 123   "Face used for widget buttons when the mouse is above them."
 124   :type 'face
 125   :group 'widget-faces)
 126
 127 ;; TTY gets special definitions here and in the next defface, because
 128 ;; the gray colors defined for other displays cause black text on a black
 129 ;; background, at least on light-background TTYs.
 130 (defface widget-field '((((type tty))
 131                          :background "yellow3"
 132                          :foreground "black")
 133                         (((class grayscale color)
 134                           (background light))
 135                          :background "gray85")
 136                         (((class grayscale color)
 137                           (background dark))
 138                          :background "dim gray")
 139                         (t
 140                          :slant italic))
 141   "Face used for editable fields."
 142   :group 'widget-faces)
 143 ;; backward-compatibility alias
 144 (put 'widget-field-face 'face-alias 'widget-field)
 145
 146 (defface widget-single-line-field '((((type tty))
 147                                      :background "green3"
 148                                      :foreground "black")
 149                                     (((class grayscale color)
 150                                       (background light))
 151                                      :background "gray85")
 152                                     (((class grayscale color)
 153                                       (background dark))
 154                                      :background "dim gray")
 155                                     (t
 156                                      :slant italic))
 157   "Face used for editable fields spanning only a single line."
 158   :group 'widget-faces)
 159 ;; backward-compatibility alias
 160 (put 'widget-single-line-field-face 'face-alias 'widget-single-line-field)
 161
 162 ;;; This causes display-table to be loaded, and not usefully.
 163 ;;;(defvar widget-single-line-display-table
 164 ;;;  (let ((table (make-display-table)))
 165 ;;;    (aset table 9  "^I")
 166 ;;;    (aset table 10 "^J")
 167 ;;;    table)
 168 ;;;  "Display table used for single-line editable fields.")
 169
 170 ;;;(when (fboundp 'set-face-display-table)
 171 ;;;  (set-face-display-table 'widget-single-line-field-face
 172 ;;;                       widget-single-line-display-table))
 173
 174 ;;; Utility functions.
 175 ;;
 176 ;; These are not really widget specific.
 177
 178 (defun widget-princ-to-string (object)
 179   "Return string representation of OBJECT, any Lisp object.
 180 No quoting characters are used; no delimiters are printed around
 181 the contents of strings."
 182   (with-output-to-string
 183       (princ object)))
 184
 185 (defun widget-clear-undo ()
 186   "Clear all undo information."
 187   (buffer-disable-undo (current-buffer))
 188   (buffer-enable-undo))
 189
 190 (defcustom widget-menu-max-size 40
 191   "Largest number of items allowed in a popup-menu.
 192 Larger menus are read through the minibuffer."
 193   :group 'widgets
 194   :type 'integer)
 195
 196 (defcustom widget-menu-max-shortcuts 40
 197   "Largest number of items for which it works to choose one with a character.
 198 For a larger number of items, the minibuffer is used."
 199   :group 'widgets
 200   :type 'integer)
 201
 202 (defcustom widget-menu-minibuffer-flag nil
 203   "*Control how to ask for a choice from the keyboard.
 204 Non-nil means use the minibuffer;
 205 nil means read a single character."
 206   :group 'widgets
 207   :type 'boolean)
 208
 209 (defun widget-choose (title items &optional event)
 210   "Choose an item from a list.
 211
 212 First argument TITLE is the name of the list.
 213 Second argument ITEMS is a list whose members are either
 214  (NAME . VALUE), to indicate selectable items, or just strings to
 215  indicate unselectable items.
 216 Optional third argument EVENT is an input event.
 217
 218 The user is asked to choose between each NAME from the items alist,
 219 and the VALUE of the chosen element will be returned.  If EVENT is a
 220 mouse event, and the number of elements in items is less than
 221 `widget-menu-max-size', a popup menu will be used, otherwise the
 222 minibuffer."
 223   (cond ((and (< (length items) widget-menu-max-size)
 224               event (display-popup-menus-p))
 225          ;; Mouse click.
 226          (x-popup-menu event
 227                        (list title (cons "" items))))
 228         ((or widget-menu-minibuffer-flag
 229              (> (length items) widget-menu-max-shortcuts))
 230          ;; Read the choice of name from the minibuffer.
 231          (setq items (widget-remove-if 'stringp items))
 232          (let ((val (completing-read (concat title ": ") items nil t)))
 233            (if (stringp val)
 234                (let ((try (try-completion val items)))
 235                  (when (stringp try)
 236                    (setq val try))
 237                  (cdr (assoc val items))))))
 238         (t
 239          ;; Construct a menu of the choices
 240          ;; and then use it for prompting for a single character.
 241          (let* ((overriding-terminal-local-map (make-sparse-keymap))
 242                 (next-digit ?0)
 243                 map choice some-choice-enabled value)
 244            ;; Define SPC as a prefix char to get to this menu.
 245            (define-key overriding-terminal-local-map " "
 246              (setq map (make-sparse-keymap title)))
 247            (with-current-buffer (get-buffer-create " widget-choose")
 248              (erase-buffer)
 249              (insert "Available choices:\n\n")
 250              (while items
 251                (setq choice (car items) items (cdr items))
 252                (if (consp choice)
 253                    (let* ((name (car choice))
 254                          (function (cdr choice)))
 255                      (insert (format "%c = %s\n" next-digit name))
 256                      (define-key map (vector next-digit) function)
 257                      (setq some-choice-enabled t)))
 258                ;; Allocate digits to disabled alternatives
 259                ;; so that the digit of a given alternative never varies.
 260                (setq next-digit (1+ next-digit)))
 261              (insert "\nC-g = Quit"))
 262            (or some-choice-enabled
 263                (error "None of the choices is currently meaningful"))
 264            (define-key map [?\C-g] 'keyboard-quit)
 265            (define-key map [t] 'keyboard-quit)
 266            (define-key map [?\M-\C-v] 'scroll-other-window)
 267            (define-key map [?\M--] 'negative-argument)
 268            (setcdr map (nreverse (cdr map)))
 269            ;; Read a char with the menu, and return the result
 270            ;; that corresponds to it.
 271            (save-window-excursion
 272              (let ((buf (get-buffer " widget-choose")))
 273                (fit-window-to-buffer (display-buffer buf))
 274                (let ((cursor-in-echo-area t)
 275                      keys
 276                      (char 0)
 277                      (arg 1))
 278                  (while (not (or (and (integerp char)
 279                                       (>= char ?0) (< char next-digit))
 280                                  (eq value 'keyboard-quit)))
 281                    ;; Unread a SPC to lead to our new menu.
 282                    (setq unread-command-events (cons ?\s unread-command-events))
 283                    (setq keys (read-key-sequence title))
 284                    (setq value
 285                          (lookup-key overriding-terminal-local-map keys t)
 286                          char (aref keys 1))
 287                    (cond ((eq value 'scroll-other-window)
 288                           (let ((minibuffer-scroll-window
 289                                  (get-buffer-window buf)))
 290                             (if (> 0 arg)
 291                                 (scroll-other-window-down
 292                                  (window-height minibuffer-scroll-window))
 293                               (scroll-other-window))
 294                             (setq arg 1)))
 295                          ((eq value 'negative-argument)
 296                           (setq arg -1))
 297                          (t
 298                           (setq arg 1)))))))
 299            (when (eq value 'keyboard-quit)
 300              (error "Canceled"))
 301            value))))
 302
 303 (defun widget-remove-if (predictate list)
 304   (let (result (tail list))
 305     (while tail
 306       (or (funcall predictate (car tail))
 307           (setq result (cons (car tail) result)))
 308       (setq tail (cdr tail)))
 309     (nreverse result)))
 310
 311 ;;; Widget text specifications.
 312 ;;
 313 ;; These functions are for specifying text properties.
 314
 315 ;; We can set it to nil now that get_local_map uses get_pos_property.
 316 (defconst widget-field-add-space nil
 317   "Non-nil means add extra space at the end of editable text fields.
 318 If you don't add the space, it will become impossible to edit a zero
 319 size field.")
 320
 321 (defvar widget-field-use-before-change t
 322   "Non-nil means use `before-change-functions' to track editable fields.
 323 This enables the use of undo, but doesn't work on Emacs 19.34 and earlier.
 324 Using before hooks also means that the :notify function can't know the
 325 new value.")
 326
 327 (defun widget-specify-field (widget from to)
 328   "Specify editable button for WIDGET between FROM and TO."
 329   ;; Terminating space is not part of the field, but necessary in
 330   ;; order for local-map to work.  Remove next sexp if local-map works
 331   ;; at the end of the overlay.
 332   (save-excursion
 333     (goto-char to)
 334     (cond ((null (widget-get widget :size))
 335            (forward-char 1))
 336           (widget-field-add-space
 337            (insert-and-inherit " ")))
 338     (setq to (point)))
 339   (let ((keymap (widget-get widget :keymap))
 340         (face (or (widget-get widget :value-face) 'widget-field))
 341         (help-echo (widget-get widget :help-echo))
 342         (follow-link (widget-get widget :follow-link))
 343         (rear-sticky
 344          (or (not widget-field-add-space) (widget-get widget :size))))
 345     (if (functionp help-echo)
 346       (setq help-echo 'widget-mouse-help))
 347     (when (= (char-before to) ?\n)
 348       ;; When the last character in the field is a newline, we want to
 349       ;; give it a `field' char-property of `boundary', which helps the
 350       ;; C-n/C-p act more naturally when entering/leaving the field.  We
 351      ;; do this by making a small secondary overlay to contain just that
 352       ;; one character.
 353       (let ((overlay (make-overlay (1- to) to nil t nil)))
 354         (overlay-put overlay 'field 'boundary)
 355         ;; We need the real field for tabbing.
 356         (overlay-put overlay 'real-field widget)
 357         ;; Use `local-map' here, not `keymap', so that normal editing
 358         ;; works in the field when, say, Custom uses `suppress-keymap'.
 359         (overlay-put overlay 'local-map keymap)
 360         (overlay-put overlay 'face face)
 361         (overlay-put overlay 'follow-link follow-link)
 362         (overlay-put overlay 'help-echo help-echo))
 363       (setq to (1- to))
 364       (setq rear-sticky t))
 365     (let ((overlay (make-overlay from to nil nil rear-sticky)))
 366       (widget-put widget :field-overlay overlay)
 367       ;;(overlay-put overlay 'detachable nil)
 368       (overlay-put overlay 'field widget)
 369       (overlay-put overlay 'local-map keymap)
 370       (overlay-put overlay 'face face)
 371       (overlay-put overlay 'follow-link follow-link)
 372       (overlay-put overlay 'help-echo help-echo)))
 373   (widget-specify-secret widget))
 374
 375 (defun widget-specify-secret (field)
 376   "Replace text in FIELD with value of `:secret', if non-nil."
 377   (let ((secret (widget-get field :secret))
 378         (size (widget-get field :size)))
 379     (when secret
 380       (let ((begin (widget-field-start field))
 381             (end (widget-field-end field)))
 382         (when size
 383           (while (and (> end begin)
 384                       (eq (char-after (1- end)) ?\s))
 385             (setq end (1- end))))
 386         (while (< begin end)
 387           (let ((old (char-after begin)))
 388             (unless (eq old secret)
 389               (subst-char-in-region begin (1+ begin) old secret)
 390               (put-text-property begin (1+ begin) 'secret old))
 391             (setq begin (1+ begin))))))))
 392
 393 (defun widget-specify-button (widget from to)
 394   "Specify button for WIDGET between FROM and TO."
 395   (let ((overlay (make-overlay from to nil t nil))
 396         (follow-link (widget-get widget :follow-link))
 397         (help-echo (widget-get widget :help-echo)))
 398     (widget-put widget :button-overlay overlay)
 399     (if (functionp help-echo)
 400       (setq help-echo 'widget-mouse-help))
 401     (overlay-put overlay 'button widget)
 402     (overlay-put overlay 'keymap (widget-get widget :keymap))
 403     (overlay-put overlay 'evaporate t)
 404     ;; We want to avoid the face with image buttons.
 405     (unless (widget-get widget :suppress-face)
 406       (overlay-put overlay 'face (widget-apply widget :button-face-get))
 407       (overlay-put overlay 'mouse-face
 408                    (widget-apply widget :mouse-face-get)))
 409     (overlay-put overlay 'pointer 'hand)
 410     (overlay-put overlay 'follow-link follow-link)
 411     (overlay-put overlay 'help-echo help-echo)))
 412
 413 (defun widget-mouse-help (window overlay point)
 414   "Help-echo callback for widgets whose :help-echo is a function."
 415   (with-current-buffer (overlay-buffer overlay)
 416     (let* ((widget (widget-at (overlay-start overlay)))
 417            (help-echo (if widget (widget-get widget :help-echo))))
 418       (if (functionp help-echo)
 419           (funcall help-echo widget)
 420         help-echo))))
 421
 422 (defun widget-specify-sample (widget from to)
 423   "Specify sample for WIDGET between FROM and TO."
 424   (let ((overlay (make-overlay from to nil t nil)))
 425     (overlay-put overlay 'face (widget-apply widget :sample-face-get))
 426     (overlay-put overlay 'evaporate t)
 427     (widget-put widget :sample-overlay overlay)))
 428
 429 (defun widget-specify-doc (widget from to)
 430   "Specify documentation for WIDGET between FROM and TO."
 431   (let ((overlay (make-overlay from to nil t nil)))
 432     (overlay-put overlay 'widget-doc widget)
 433     (overlay-put overlay 'face widget-documentation-face)
 434     (overlay-put overlay 'evaporate t)
 435     (widget-put widget :doc-overlay overlay)))
 436
 437 (defmacro widget-specify-insert (&rest form)
 438   "Execute FORM without inheriting any text properties."
 439   `(save-restriction
 440     (let ((inhibit-read-only t)
 441           (inhibit-modification-hooks t))
 442       (narrow-to-region (point) (point))
 443       (prog1 (progn ,@form)
 444         (goto-char (point-max))))))
 445
 446 (defface widget-inactive
 447   '((t :inherit shadow))
 448   "Face used for inactive widgets."
 449   :group 'widget-faces)
 450 ;; backward-compatibility alias
 451 (put 'widget-inactive-face 'face-alias 'widget-inactive)
 452
 453 (defun widget-specify-inactive (widget from to)
 454   "Make WIDGET inactive for user modifications."
 455   (unless (widget-get widget :inactive)
 456     (let ((overlay (make-overlay from to nil t nil)))
 457       (overlay-put overlay 'face 'widget-inactive)
 458       ;; This is disabled, as it makes the mouse cursor change shape.
 459       ;; (overlay-put overlay 'mouse-face 'widget-inactive)
 460       (overlay-put overlay 'evaporate t)
 461       (overlay-put overlay 'priority 100)
 462       (overlay-put overlay 'modification-hooks '(widget-overlay-inactive))
 463       (widget-put widget :inactive overlay))))
 464
 465 (defun widget-overlay-inactive (&rest junk)
 466   "Ignoring the arguments, signal an error."
 467   (unless inhibit-read-only
 468     (error "The widget here is not active")))
 469
 470
 471 (defun widget-specify-active (widget)
 472   "Make WIDGET active for user modifications."
 473   (let ((inactive (widget-get widget :inactive)))
 474     (when inactive
 475       (delete-overlay inactive)
 476       (widget-put widget :inactive nil))))
 477
 478 ;;; Widget Properties.
 479
 480 (defsubst widget-type (widget)
 481   "Return the type of WIDGET, a symbol."
 482   (car widget))
 483
 484 ;;;###autoload
 485 (defun widgetp (widget)
 486   "Return non-nil if WIDGET is a widget."
 487   (if (symbolp widget)
 488       (get widget 'widget-type)
 489     (and (consp widget)
 490          (symbolp (car widget))
 491          (get (car widget) 'widget-type))))
 492
 493 (defun widget-get-indirect (widget property)
 494   "In WIDGET, get the value of PROPERTY.
 495 If the value is a symbol, return its binding.
 496 Otherwise, just return the value."
 497   (let ((value (widget-get widget property)))
 498     (if (symbolp value)
 499         (symbol-value value)
 500       value)))
 501
 502 (defun widget-member (widget property)
 503   "Non-nil if there is a definition in WIDGET for PROPERTY."
 504   (cond ((plist-member (cdr widget) property)
 505          t)
 506         ((car widget)
 507          (widget-member (get (car widget) 'widget-type) property))
 508         (t nil)))
 509
 510 (defun widget-value (widget)
 511   "Extract the current value of WIDGET."
 512   (widget-apply widget
 513                 :value-to-external (widget-apply widget :value-get)))
 514
 515 (defun widget-value-set (widget value)
 516   "Set the current value of WIDGET to VALUE."
 517   (widget-apply widget
 518                 :value-set (widget-apply widget
 519                                          :value-to-internal value)))
 520
 521 (defun widget-default-get (widget)
 522   "Extract the default external value of WIDGET."
 523   (widget-apply widget :value-to-external
 524                 (or (widget-get widget :value)
 525                     (widget-apply widget :default-get))))
 526
 527 (defun widget-match-inline (widget vals)
 528   "In WIDGET, match the start of VALS."
 529   (cond ((widget-get widget :inline)
 530          (widget-apply widget :match-inline vals))
 531         ((and (listp vals)
 532               (widget-apply widget :match (car vals)))
 533          (cons (list (car vals)) (cdr vals)))
 534         (t nil)))
 535
 536 (defun widget-apply-action (widget &optional event)
 537   "Apply :action in WIDGET in response to EVENT."
 538   (if (widget-apply widget :active)
 539       (widget-apply widget :action event)
 540     (error "Attempt to perform action on inactive widget")))
 541
 542 ;;; Helper functions.
 543 ;;
 544 ;; These are widget specific.
 545
 546 ;;;###autoload
 547 (defun widget-prompt-value (widget prompt &optional value unbound)
 548   "Prompt for a value matching WIDGET, using PROMPT.
 549 The current value is assumed to be VALUE, unless UNBOUND is non-nil."
 550   (unless (listp widget)
 551     (setq widget (list widget)))
 552   (setq prompt (format "[%s] %s" (widget-type widget) prompt))
 553   (setq widget (widget-convert widget))
 554   (let ((answer (widget-apply widget :prompt-value prompt value unbound)))
 555     (unless (widget-apply widget :match answer)
 556       (error "Value does not match %S type" (car widget)))
 557     answer))
 558
 559 (defun widget-get-sibling (widget)
 560   "Get the item WIDGET is assumed to toggle.
 561 This is only meaningful for radio buttons or checkboxes in a list."
 562   (let* ((children (widget-get (widget-get widget :parent) :children))
 563          child)
 564     (catch 'child
 565       (while children
 566         (setq child (car children)
 567               children (cdr children))
 568         (when (eq (widget-get child :button) widget)
 569           (throw 'child child)))
 570       nil)))
 571
 572 (defun widget-map-buttons (function &optional buffer maparg)
 573   "Map FUNCTION over the buttons in BUFFER.
 574 FUNCTION is called with the arguments WIDGET and MAPARG.
 575
 576 If FUNCTION returns non-nil, the walk is cancelled.
 577
 578 The arguments MAPARG, and BUFFER default to nil and (current-buffer),
 579 respectively."
 580   (let ((cur (point-min))
 581         (widget nil)
 582         (overlays (if buffer
 583                       (with-current-buffer buffer (overlay-lists))
 584                     (overlay-lists))))
 585     (setq overlays (append (car overlays) (cdr overlays)))
 586     (while (setq cur (pop overlays))
 587       (setq widget (overlay-get cur 'button))
 588       (if (and widget (funcall function widget maparg))
 589           (setq overlays nil)))))
 590
 591 ;;; Images.
 592
 593 (defcustom widget-image-directory (file-name-as-directory
 594                                    (expand-file-name "custom" data-directory))
 595   "Where widget button images are located.
 596 If this variable is nil, widget will try to locate the directory
 597 automatically."
 598   :group 'widgets
 599   :type 'directory)
 600
 601 (defcustom widget-image-enable t
 602   "If non-nil, use image buttons in widgets when available."
 603   :version "21.1"
 604   :group 'widgets
 605   :type 'boolean)
 606
 607 (defcustom widget-image-conversion
 608   '((xpm ".xpm") (gif ".gif") (png ".png") (jpeg ".jpg" ".jpeg")
 609     (xbm ".xbm"))
 610   "Conversion alist from image formats to file name suffixes."
 611   :group 'widgets
 612   :type '(repeat (cons :format "%v"
 613                        (symbol :tag "Image Format" unknown)
 614                        (repeat :tag "Suffixes"
 615                                (string :format "%v")))))
 616
 617 (defun widget-image-find (image)
 618   "Create a graphical button from IMAGE.
 619 IMAGE should either already be an image, or be a file name sans
 620 extension (xpm, xbm, gif, jpg, or png) located in
 621 `widget-image-directory' or otherwise where `find-image' will find it."
 622   (cond ((not (and image widget-image-enable (display-graphic-p)))
 623          ;; We don't want or can't use images.
 624          nil)
 625         ((and (consp image)
 626               (eq 'image (car image)))
 627          ;; Already an image spec.  Use it.
 628          image)
 629         ((stringp image)
 630          ;; A string.  Look it up in relevant directories.
 631          (let* ((load-path (cons widget-image-directory load-path))
 632                 specs)
 633            (dolist (elt widget-image-conversion)
 634              (dolist (ext (cdr elt))
 635                (push (list :type (car elt) :file (concat image ext)) specs)))
 636            (setq specs (nreverse specs))
 637            (find-image specs)))
 638         (t
 639          ;; Oh well.
 640          nil)))
 641
 642 (defvar widget-button-pressed-face 'widget-button-pressed
 643   "Face used for pressed buttons in widgets.
 644 This exists as a variable so it can be set locally in certain
 645 buffers.")
 646
 647 (defun widget-image-insert (widget tag image &optional down inactive)
 648   "In WIDGET, insert the text TAG or, if supported, IMAGE.
 649 IMAGE should either be an image or an image file name sans extension
 650 \(xpm, xbm, gif, jpg, or png) located in `widget-image-directory'.
 651
 652 Optional arguments DOWN and INACTIVE are used instead of IMAGE when the
 653 button is pressed or inactive, respectively.  These are currently ignored."
 654   (if (and (display-graphic-p)
 655            (setq image (widget-image-find image)))
 656       (progn (widget-put widget :suppress-face t)
 657              (insert-image image
 658                            (propertize
 659                             tag 'mouse-face widget-button-pressed-face)))
 660     (insert tag)))
 661
 662 (defun widget-move-and-invoke (event)
 663   "Move to where you click, and if it is an active field, invoke it."
 664   (interactive "e")
 665   (mouse-set-point event)
 666   (let ((pos (widget-event-point event)))
 667     (if (and pos (get-char-property pos 'button))
 668         (widget-button-click event))))
 669
 670 ;;; Buttons.
 671
 672 (defgroup widget-button nil
 673   "The look of various kinds of buttons."
 674   :group 'widgets)
 675
 676 (defcustom widget-button-prefix ""
 677   "String used as prefix for buttons."
 678   :type 'string
 679   :group 'widget-button)
 680
 681 (defcustom widget-button-suffix ""
 682   "String used as suffix for buttons."
 683   :type 'string
 684   :group 'widget-button)
 685
 686 ;;; Creating Widgets.
 687
 688 ;;;###autoload
 689 (defun widget-create (type &rest args)
 690   "Create widget of TYPE.
 691 The optional ARGS are additional keyword arguments."
 692   (let ((widget (apply 'widget-convert type args)))
 693     (widget-apply widget :create)
 694     widget))
 695
 696 (defun widget-create-child-and-convert (parent type &rest args)
 697   "As part of the widget PARENT, create a child widget TYPE.
 698 The child is converted, using the keyword arguments ARGS."
 699   (let ((widget (apply 'widget-convert type args)))
 700     (widget-put widget :parent parent)
 701     (unless (widget-get widget :indent)
 702       (widget-put widget :indent (+ (or (widget-get parent :indent) 0)
 703                                     (or (widget-get widget :extra-offset) 0)
 704                                     (widget-get parent :offset))))
 705     (widget-apply widget :create)
 706     widget))
 707
 708 (defun widget-create-child (parent type)
 709   "Create widget of TYPE."
 710   (let ((widget (widget-copy type)))
 711     (widget-put widget :parent parent)
 712     (unless (widget-get widget :indent)
 713       (widget-put widget :indent (+ (or (widget-get parent :indent) 0)
 714                                     (or (widget-get widget :extra-offset) 0)
 715                                     (widget-get parent :offset))))
 716     (widget-apply widget :create)
 717     widget))
 718
 719 (defun widget-create-child-value (parent type value)
 720   "Create widget of TYPE with value VALUE."
 721   (let ((widget (widget-copy type)))
 722     (widget-put widget :value (widget-apply widget :value-to-internal value))
 723     (widget-put widget :parent parent)
 724     (unless (widget-get widget :indent)
 725       (widget-put widget :indent (+ (or (widget-get parent :indent) 0)
 726                                     (or (widget-get widget :extra-offset) 0)
 727                                     (widget-get parent :offset))))
 728     (widget-apply widget :create)
 729     widget))
 730
 731 ;;;###autoload
 732 (defun widget-delete (widget)
 733   "Delete WIDGET."
 734   (widget-apply widget :delete))
 735
 736 (defun widget-copy (widget)
 737   "Make a deep copy of WIDGET."
 738   (widget-apply (copy-sequence widget) :copy))
 739
 740 (defun widget-convert (type &rest args)
 741   "Convert TYPE to a widget without inserting it in the buffer.
 742 The optional ARGS are additional keyword arguments."
 743   ;; Don't touch the type.
 744   (let* ((widget (if (symbolp type)
 745                      (list type)
 746                    (copy-sequence type)))
 747          (current widget)
 748          done
 749          (keys args))
 750     ;; First set the :args keyword.
 751     (while (cdr current)                ;Look in the type.
 752       (if (and (keywordp (cadr current))
 753                ;; If the last element is a keyword,
 754                ;; it is still the :args element,
 755                ;; even though it is a keyword.
 756                (cddr current))
 757           (if (eq (cadr current) :args)
 758               ;; If :args is explicitly specified, obey it.
 759               (setq current nil)
 760             ;; Some other irrelevant keyword.
 761             (setq current (cdr (cdr current))))
 762         (setcdr current (list :args (cdr current)))
 763         (setq current nil)))
 764     (while (and args (not done))        ;Look in ARGS.
 765       (cond ((eq (car args) :args)
 766              ;; Handle explicit specification of :args.
 767              (setq args (cadr args)
 768                    done t))
 769             ((keywordp (car args))
 770              (setq args (cddr args)))
 771             (t (setq done t))))
 772     (when done
 773       (widget-put widget :args args))
 774     ;; Then Convert the widget.
 775     (setq type widget)
 776     (while type
 777       (let ((convert-widget (plist-get (cdr type) :convert-widget)))
 778         (if convert-widget
 779             (setq widget (funcall convert-widget widget))))
 780       (setq type (get (car type) 'widget-type)))
 781     ;; Finally set the keyword args.
 782     (while keys
 783       (let ((next (nth 0 keys)))
 784         (if (keywordp next)
 785             (progn
 786               (widget-put widget next (nth 1 keys))
 787               (setq keys (nthcdr 2 keys)))
 788           (setq keys nil))))
 789     ;; Convert the :value to internal format.
 790     (if (widget-member widget :value)
 791         (widget-put widget
 792                     :value (widget-apply widget
 793                                          :value-to-internal
 794                                          (widget-get widget :value))))
 795     ;; Return the newly create widget.
 796     widget))
 797
 798 ;;;###autoload
 799 (defun widget-insert (&rest args)
 800   "Call `insert' with ARGS even if surrounding text is read only."
 801   (let ((inhibit-read-only t)
 802         (inhibit-modification-hooks t))
 803     (apply 'insert args)))
 804
 805 (defun widget-convert-text (type from to
 806                                  &optional button-from button-to
 807                                  &rest args)
 808   "Return a widget of type TYPE with endpoint FROM TO.
 809 No text will be inserted to the buffer, instead the text between FROM
 810 and TO will be used as the widgets end points.  If optional arguments
 811 BUTTON-FROM and BUTTON-TO are given, these will be used as the widgets
 812 button end points.
 813 Optional ARGS are extra keyword arguments for TYPE."
 814   (let ((widget (apply 'widget-convert type :delete 'widget-leave-text args))
 815         (from (copy-marker from))
 816         (to (copy-marker to)))
 817     (set-marker-insertion-type from t)
 818     (set-marker-insertion-type to nil)
 819     (widget-put widget :from from)
 820     (widget-put widget :to to)
 821     (when button-from
 822       (widget-specify-button widget button-from button-to))
 823     widget))
 824
 825 (defun widget-convert-button (type from to &rest args)
 826   "Return a widget of type TYPE with endpoint FROM TO.
 827 Optional ARGS are extra keyword arguments for TYPE.
 828 No text will be inserted to the buffer, instead the text between FROM
 829 and TO will be used as the widgets end points, as well as the widgets
 830 button end points."
 831   (apply 'widget-convert-text type from to from to args))
 832
 833 (defun widget-leave-text (widget)
 834   "Remove markers and overlays from WIDGET and its children."
 835   (let ((button (widget-get widget :button-overlay))
 836         (sample (widget-get widget :sample-overlay))
 837         (doc (widget-get widget :doc-overlay))
 838         (field (widget-get widget :field-overlay)))
 839     (set-marker (widget-get widget :from) nil)
 840     (set-marker (widget-get widget :to) nil)
 841     (when button
 842       (delete-overlay button))
 843     (when sample
 844       (delete-overlay sample))
 845     (when doc
 846       (delete-overlay doc))
 847     (when field
 848       (delete-overlay field))
 849     (mapc 'widget-leave-text (widget-get widget :children))))
 850
 851 ;;; Keymap and Commands.
 852
 853 ;;;###autoload
 854 (defalias 'advertised-widget-backward 'widget-backward)
 855
 856 ;;;###autoload
 857 (defvar widget-keymap
 858   (let ((map (make-sparse-keymap)))
 859     (define-key map "\t" 'widget-forward)
 860     (define-key map "\e\t" 'widget-backward)
 861     (define-key map [(shift tab)] 'advertised-widget-backward)
 862     (define-key map [backtab] 'widget-backward)
 863     (define-key map [down-mouse-2] 'widget-button-click)
 864     (define-key map [down-mouse-1] 'widget-button-click)
 865     (define-key map "\C-m" 'widget-button-press)
 866     map)
 867   "Keymap containing useful binding for buffers containing widgets.
 868 Recommended as a parent keymap for modes using widgets.")
 869
 870 (defvar widget-global-map global-map
 871   "Keymap used for events a widget does not handle itself.")
 872 (make-variable-buffer-local 'widget-global-map)
 873
 874 (defvar widget-field-keymap
 875   (let ((map (copy-keymap widget-keymap)))
 876     (define-key map "\C-k" 'widget-kill-line)
 877     (define-key map "\M-\t" 'widget-complete)
 878     (define-key map "\C-m" 'widget-field-activate)
 879     ;; Since the widget code uses a `field' property to identify fields,
 880     ;; ordinary beginning-of-line does the right thing.
 881     ;;  (define-key map "\C-a" 'widget-beginning-of-line)
 882     (define-key map "\C-e" 'widget-end-of-line)
 883     map)
 884   "Keymap used inside an editable field.")
 885
 886 (defvar widget-text-keymap
 887   (let ((map (copy-keymap widget-keymap)))
 888     ;; Since the widget code uses a `field' property to identify fields,
 889     ;; ordinary beginning-of-line does the right thing.
 890     ;;  (define-key map "\C-a" 'widget-beginning-of-line)
 891     (define-key map "\C-e" 'widget-end-of-line)
 892     map)
 893   "Keymap used inside a text field.")
 894
 895 (defun widget-field-activate (pos &optional event)
 896   "Invoke the editable field at point."
 897   (interactive "@d")
 898   (let ((field (widget-field-at pos)))
 899     (if field
 900         (widget-apply-action field event)
 901       (call-interactively
 902        (lookup-key widget-global-map (this-command-keys))))))
 903
 904 (defface widget-button-pressed
 905   '((((min-colors 88) (class color))
 906      (:foreground "red1"))
 907     (((class color))
 908      (:foreground "red"))
 909     (t
 910      (:weight bold :underline t)))
 911   "Face used for pressed buttons."
 912   :group 'widget-faces)
 913 ;; backward-compatibility alias
 914 (put 'widget-button-pressed-face 'face-alias 'widget-button-pressed)
 915
 916 (defvar widget-button-click-moves-point nil
 917   "If non-nil, `widget-button-click' moves point to a button after invoking it.
 918 If nil, point returns to its original position after invoking a button.")
 919
 920 (defun widget-button-click (event)
 921   "Invoke the button that the mouse is pointing at."
 922   (interactive "e")
 923   (if (widget-event-point event)
 924       (let* ((oevent event)
 925              (mouse-1 (memq (event-basic-type event) '(mouse-1 down-mouse-1)))
 926              (pos (widget-event-point event))
 927              (start (event-start event))
 928              (button (get-char-property
 929                       pos 'button (and (windowp (posn-window start))
 930                                        (window-buffer (posn-window start)))))
 931              newpoint)
 932         (when (or (null button)
 933                   (catch 'button-press-cancelled
 934               ;; Mouse click on a widget button.  Do the following
 935               ;; in a save-excursion so that the click on the button
 936               ;; doesn't change point.
 937               (save-selected-window
 938                 (select-window (posn-window (event-start event)))
 939                 (save-excursion
 940                   (goto-char (posn-point (event-start event)))
 941                   (let* ((overlay (widget-get button :button-overlay))
 942                          (pressed-face (or (widget-get button :pressed-face)
 943                                            widget-button-pressed-face))
 944                          (face (overlay-get overlay 'face))
 945                          (mouse-face (overlay-get overlay 'mouse-face)))
 946                     (unwind-protect
 947                         ;; Read events, including mouse-movement
 948                         ;; events, waiting for a release event.  If we
 949                         ;; began with a mouse-1 event and receive a
 950                         ;; movement event, that means the user wants
 951                         ;; to perform drag-selection, so cancel the
 952                         ;; button press and do the default mouse-1
 953                         ;; action.  For mouse-2, just highlight/
 954                         ;; unhighlight the button the mouse was
 955                         ;; initially on when we move over it.
 956                         (save-excursion
 957                           (when face    ; avoid changing around image
 958                             (overlay-put overlay 'face pressed-face)
 959                             (overlay-put overlay 'mouse-face pressed-face))
 960                           (unless (widget-apply button :mouse-down-action event)
 961                             (let ((track-mouse t))
 962                               (while (not (widget-button-release-event-p event))
 963                                 (setq event (read-event))
 964                                 (when (and mouse-1 (mouse-movement-p event))
 965                                   (push event unread-command-events)
 966                                   (setq event oevent)
 967                                   (throw 'button-press-cancelled t))
 968                                 (unless (or (integerp event)
 969                                             (memq (car event) '(switch-frame select-window))
 970                                             (eq (car event) 'scroll-bar-movement))
 971                                   (setq pos (widget-event-point event))
 972                                   (if (and pos
 973                                            (eq (get-char-property pos 'button)
 974                                                button))
 975                                       (when face
 976                                         (overlay-put overlay 'face pressed-face)
 977                                         (overlay-put overlay 'mouse-face pressed-face))
 978                                     (overlay-put overlay 'face face)
 979                                     (overlay-put overlay 'mouse-face mouse-face))))))
 980
 981                           ;; When mouse is released over the button, run
 982                           ;; its action function.
 983                           (when (and pos (eq (get-char-property pos 'button) button))
 984                             (goto-char pos)
 985                             (widget-apply-action button event)
 986                             (if widget-button-click-moves-point
 987                                 (setq newpoint (point)))))
 988                       (overlay-put overlay 'face face)
 989                       (overlay-put overlay 'mouse-face mouse-face))))
 990
 991                 (if newpoint (goto-char newpoint))
 992                 ;; This loses if the widget action switches windows. -- cyd
 993                 ;; (unless (pos-visible-in-window-p (widget-event-point event))
 994                 ;;   (mouse-set-point event)
 995                 ;;   (beginning-of-line)
 996                 ;;   (recenter))
 997                 )
 998               nil))
 999           (let ((up t) command)
1000             ;; Mouse click not on a widget button.  Find the global
1001             ;; command to run, and check whether it is bound to an
1002             ;; up event.
1003             (if mouse-1
1004                 (cond ((setq command    ;down event
1005                              (lookup-key widget-global-map [down-mouse-1]))
1006                        (setq up nil))
1007                       ((setq command    ;up event
1008                              (lookup-key widget-global-map [mouse-1]))))
1009               (cond ((setq command      ;down event
1010                            (lookup-key widget-global-map [down-mouse-2]))
1011                      (setq up nil))
1012                     ((setq command      ;up event
1013                            (lookup-key widget-global-map [mouse-2])))))
1014             (when up
1015               ;; Don't execute up events twice.
1016               (while (not (widget-button-release-event-p event))
1017                 (setq event (read-event))))
1018             (when command
1019               (call-interactively command)))))
1020     (message "You clicked somewhere weird.")))
1021
1022 (defun widget-button-press (pos &optional event)
1023   "Invoke button at POS."
1024   (interactive "@d")
1025   (let ((button (get-char-property pos 'button)))
1026     (if button
1027         (widget-apply-action button event)
1028       (let ((command (lookup-key widget-global-map (this-command-keys))))
1029         (when (commandp command)
1030           (call-interactively command))))))
1031
1032 (defun widget-tabable-at (&optional pos)
1033   "Return the tabable widget at POS, or nil.
1034 POS defaults to the value of (point)."
1035   (let ((widget (widget-at pos)))
1036     (if widget
1037         (let ((order (widget-get widget :tab-order)))
1038           (if order
1039               (if (>= order 0)
1040                   widget)
1041             widget)))))
1042
1043 (defvar widget-use-overlay-change t
1044   "If non-nil, use overlay change functions to tab around in the buffer.
1045 This is much faster, but doesn't work reliably on Emacs 19.34.")
1046
1047 (defun widget-move (arg)
1048   "Move point to the ARG next field or button.
1049 ARG may be negative to move backward."
1050   (or (bobp) (> arg 0) (backward-char))
1051   (let ((wrapped 0)
1052         (number arg)
1053         (old (widget-tabable-at)))
1054     ;; Forward.
1055     (while (> arg 0)
1056       (cond ((eobp)
1057              (goto-char (point-min))
1058              (setq wrapped (1+ wrapped)))
1059             (widget-use-overlay-change
1060              (goto-char (next-overlay-change (point))))
1061             (t
1062              (forward-char 1)))
1063       (and (= wrapped 2)
1064            (eq arg number)
1065            (error "No buttons or fields found"))
1066       (let ((new (widget-tabable-at)))
1067         (when new
1068           (unless (eq new old)
1069             (setq arg (1- arg))
1070             (setq old new)))))
1071     ;; Backward.
1072     (while (< arg 0)
1073       (cond ((bobp)
1074              (goto-char (point-max))
1075              (setq wrapped (1+ wrapped)))
1076             (widget-use-overlay-change
1077              (goto-char (previous-overlay-change (point))))
1078             (t
1079              (backward-char 1)))
1080       (and (= wrapped 2)
1081            (eq arg number)
1082            (error "No buttons or fields found"))
1083       (let ((new (widget-tabable-at)))
1084         (when new
1085           (unless (eq new old)
1086             (setq arg (1+ arg))))))
1087     (let ((new (widget-tabable-at)))
1088       (while (eq (widget-tabable-at) new)
1089         (backward-char)))
1090     (forward-char))
1091   (widget-echo-help (point))
1092   (run-hooks 'widget-move-hook))
1093
1094 (defun widget-forward (arg)
1095   "Move point to the next field or button.
1096 With optional ARG, move across that many fields."
1097   (interactive "p")
1098   (run-hooks 'widget-forward-hook)
1099   (widget-move arg))
1100
1101 (defun widget-backward (arg)
1102   "Move point to the previous field or button.
1103 With optional ARG, move across that many fields."
1104   (interactive "p")
1105   (run-hooks 'widget-backward-hook)
1106   (widget-move (- arg)))
1107
1108 ;; Since the widget code uses a `field' property to identify fields,
1109 ;; ordinary beginning-of-line does the right thing.
1110 (defalias 'widget-beginning-of-line 'beginning-of-line)
1111
1112 (defun widget-end-of-line ()
1113   "Go to end of field or end of line, whichever is first.
1114 Trailing spaces at the end of padded fields are not considered part of
1115 the field."
1116   (interactive)
1117   ;; Ordinary end-of-line does the right thing, because we're inside
1118   ;; text with a `field' property.
1119   (end-of-line)
1120   (unless (eolp)
1121     ;; ... except that we want to ignore trailing spaces in fields that
1122     ;; aren't terminated by a newline, because they are used as padding,
1123     ;; and ignored when extracting the entered value of the field.
1124     (skip-chars-backward " " (field-beginning (1- (point))))))
1125
1126 (defun widget-kill-line ()
1127   "Kill to end of field or end of line, whichever is first."
1128   (interactive)
1129   (let* ((field (widget-field-find (point)))
1130          (end (and field (widget-field-end field))))
1131     (if (and field (> (line-beginning-position 2) end))
1132         (kill-region (point) end)
1133       (call-interactively 'kill-line))))
1134
1135 (defcustom widget-complete-field (lookup-key global-map "\M-\t")
1136   "Default function to call for completion inside fields."
1137   :options '(ispell-complete-word complete-tag lisp-complete-symbol)
1138   :type 'function
1139   :group 'widgets)
1140
1141 (defun widget-narrow-to-field ()
1142   "Narrow to field."
1143   (interactive)
1144   (let ((field (widget-field-find (point))))
1145     (if field
1146         (narrow-to-region (line-beginning-position) (line-end-position)))))
1147
1148 (defun widget-complete ()
1149   "Complete content of editable field from point.
1150 When not inside a field, move to the previous button or field."
1151   (interactive)
1152   (let ((field (widget-field-find (point))))
1153     (if field
1154         (save-restriction
1155           (widget-narrow-to-field)
1156           (widget-apply field :complete))
1157           (error "Not in an editable field"))))
1158
1159 ;;; Setting up the buffer.
1160
1161 (defvar widget-field-new nil
1162   "List of all newly created editable fields in the buffer.")
1163 (make-variable-buffer-local 'widget-field-new)
1164
1165 (defvar widget-field-list nil
1166   "List of all editable fields in the buffer.")
1167 (make-variable-buffer-local 'widget-field-list)
1168
1169 (defun widget-at (&optional pos)
1170   "The button or field at POS (default, point)."
1171   (or (get-char-property (or pos (point)) 'button)
1172       (widget-field-at pos)))
1173
1174 ;;;###autoload
1175 (defun widget-setup ()
1176   "Setup current buffer so editing string widgets works."
1177   (let ((inhibit-read-only t)
1178         (inhibit-modification-hooks t)
1179         field)
1180     (while widget-field-new
1181       (setq field (car widget-field-new)
1182             widget-field-new (cdr widget-field-new)
1183             widget-field-list (cons field widget-field-list))
1184       (let ((from (car (widget-get field :field-overlay)))
1185             (to (cdr (widget-get field :field-overlay))))
1186         (widget-specify-field field
1187                               (marker-position from) (marker-position to))
1188         (set-marker from nil)
1189         (set-marker to nil))))
1190   (widget-clear-undo)
1191   (widget-add-change))
1192
1193 (defvar widget-field-last nil)
1194 ;; Last field containing point.
1195 (make-variable-buffer-local 'widget-field-last)
1196
1197 (defvar widget-field-was nil)
1198 ;; The widget data before the change.
1199 (make-variable-buffer-local 'widget-field-was)
1200
1201 (defun widget-field-at (pos)
1202   "Return the widget field at POS, or nil if none."
1203   (let ((field (get-char-property (or pos (point)) 'field)))
1204     (if (eq field 'boundary)
1205         (get-char-property (or pos (point)) 'real-field)
1206       field)))
1207
1208 (defun widget-field-buffer (widget)
1209   "Return the buffer of WIDGET's editing field."
1210   (let ((overlay (widget-get widget :field-overlay)))
1211     (cond ((overlayp overlay)
1212            (overlay-buffer overlay))
1213           ((consp overlay)
1214            (marker-buffer (car overlay))))))
1215
1216 (defun widget-field-start (widget)
1217   "Return the start of WIDGET's editing field."
1218   (let ((overlay (widget-get widget :field-overlay)))
1219     (if (overlayp overlay)
1220         (overlay-start overlay)
1221       (car overlay))))
1222
1223 (defun widget-field-end (widget)
1224   "Return the end of WIDGET's editing field."
1225   (let ((overlay (widget-get widget :field-overlay)))
1226     ;; Don't subtract one if local-map works at the end of the overlay,
1227     ;; or if a special `boundary' field has been added after the widget
1228     ;; field.
1229     (if (overlayp overlay)
1230         ;; Don't proceed if overlay has been removed from buffer.
1231         (when (overlay-buffer overlay)
1232           (if (and (not (eq (with-current-buffer
1233                                 (widget-field-buffer widget)
1234                               (save-restriction
1235                                 ;; `widget-narrow-to-field' can be
1236                                 ;; active when this function is called
1237                                 ;; from an change-functions hook. So
1238                                 ;; temporarily remove field narrowing
1239                                 ;; before to call `get-char-property'.
1240                                 (widen)
1241                                 (get-char-property (overlay-end overlay)
1242                                                    'field)))
1243                             'boundary))
1244                    (or widget-field-add-space
1245                        (null (widget-get widget :size))))
1246               (1- (overlay-end overlay))
1247             (overlay-end overlay)))
1248       (cdr overlay))))
1249
1250 (defun widget-field-find (pos)
1251   "Return the field at POS.
1252 Unlike (get-char-property POS 'field), this works with empty fields too."
1253   (let ((fields widget-field-list)
1254         field found)
1255     (while fields
1256       (setq field (car fields)
1257             fields (cdr fields))
1258       (when (and (<= (widget-field-start field) pos)
1259                  (<= pos (widget-field-end field)))
1260         (when found
1261           (error "Overlapping fields"))
1262         (setq found field)))
1263     found))
1264
1265 (defun widget-before-change (from to)
1266   ;; This is how, for example, a variable changes its state to `modified'.
1267   ;; when it is being edited.
1268   (unless inhibit-read-only
1269     (let ((from-field (widget-field-find from))
1270           (to-field (widget-field-find to)))
1271       (cond ((not (eq from-field to-field))
1272              (add-hook 'post-command-hook 'widget-add-change nil t)
1273              (signal 'text-read-only
1274                      '("Change should be restricted to a single field")))
1275             ((null from-field)
1276              (add-hook 'post-command-hook 'widget-add-change nil t)
1277              (signal 'text-read-only
1278                      '("Attempt to change text outside editable field")))
1279             (widget-field-use-before-change
1280              (widget-apply from-field :notify from-field))))))
1281
1282 (defun widget-add-change ()
1283   (remove-hook 'post-command-hook 'widget-add-change t)
1284   (add-hook 'before-change-functions 'widget-before-change nil t)
1285   (add-hook 'after-change-functions 'widget-after-change nil t))
1286
1287 (defun widget-after-change (from to old)
1288   "Adjust field size and text properties."
1289   (let ((field (widget-field-find from))
1290         (other (widget-field-find to)))
1291     (when field
1292       (unless (eq field other)
1293         (error "Change in different fields"))
1294       (let ((size (widget-get field :size)))
1295         (when size
1296           (let ((begin (widget-field-start field))
1297                 (end (widget-field-end field)))
1298             (cond ((< (- end begin) size)
1299                    ;; Field too small.
1300                    (save-excursion
1301                      (goto-char end)
1302                      (insert-char ?\s (- (+ begin size) end))))
1303                   ((> (- end begin) size)
1304                    ;; Field too large and
1305                    (if (or (< (point) (+ begin size))
1306                            (> (point) end))
1307                        ;; Point is outside extra space.
1308                        (setq begin (+ begin size))
1309                      ;; Point is within the extra space.
1310                      (setq begin (point)))
1311                    (save-excursion
1312                      (goto-char end)
1313                      (while (and (eq (preceding-char) ?\s)
1314                                  (> (point) begin))
1315                        (delete-backward-char 1)))))))
1316         (widget-specify-secret field))
1317       (widget-apply field :notify field))))
1318
1319 ;;; Widget Functions
1320 ;;
1321 ;; These functions are used in the definition of multiple widgets.
1322
1323 (defun widget-parent-action (widget &optional event)
1324   "Tell :parent of WIDGET to handle the :action.
1325 Optional EVENT is the event that triggered the action."
1326   (widget-apply (widget-get widget :parent) :action event))
1327
1328 (defun widget-children-value-delete (widget)
1329   "Delete all :children and :buttons in WIDGET."
1330   (mapc 'widget-delete (widget-get widget :children))
1331   (widget-put widget :children nil)
1332   (mapc 'widget-delete (widget-get widget :buttons))
1333   (widget-put widget :buttons nil))
1334
1335 (defun widget-children-validate (widget)
1336   "All the :children must be valid."
1337   (let ((children (widget-get widget :children))
1338         child found)
1339     (while (and children (not found))
1340       (setq child (car children)
1341             children (cdr children)
1342             found (widget-apply child :validate)))
1343     found))
1344
1345 (defun widget-child-value-get (widget)
1346   "Get the value of the first member of :children in WIDGET."
1347   (widget-value (car (widget-get widget :children))))
1348
1349 (defun widget-child-value-inline (widget)
1350   "Get the inline value of the first member of :children in WIDGET."
1351   (widget-apply (car (widget-get widget :children)) :value-inline))
1352
1353 (defun widget-child-validate (widget)
1354   "The result of validating the first member of :children in WIDGET."
1355   (widget-apply (car (widget-get widget :children)) :validate))
1356
1357 (defun widget-type-value-create (widget)
1358   "Convert and instantiate the value of the :type attribute of WIDGET.
1359 Store the newly created widget in the :children attribute.
1360
1361 The value of the :type attribute should be an unconverted widget type."
1362   (let ((value (widget-get widget :value))
1363         (type (widget-get widget :type)))
1364     (widget-put widget :children
1365                 (list (widget-create-child-value widget
1366                                                  (widget-convert type)
1367                                                  value)))))
1368
1369 (defun widget-type-default-get (widget)
1370   "Get default value from the :type attribute of WIDGET.
1371
1372 The value of the :type attribute should be an unconverted widget type."
1373   (widget-default-get (widget-convert (widget-get widget :type))))
1374
1375 (defun widget-type-match (widget value)
1376   "Non-nil if the :type value of WIDGET matches VALUE.
1377
1378 The value of the :type attribute should be an unconverted widget type."
1379   (widget-apply (widget-convert (widget-get widget :type)) :match value))
1380
1381 (defun widget-types-copy (widget)
1382   "Copy :args as widget types in WIDGET."
1383   (widget-put widget :args (mapcar 'widget-copy (widget-get widget :args)))
1384   widget)
1385
1386 ;; Made defsubst to speed up face editor creation.
1387 (defsubst widget-types-convert-widget (widget)
1388   "Convert :args as widget types in WIDGET."
1389   (widget-put widget :args (mapcar 'widget-convert (widget-get widget :args)))
1390   widget)
1391
1392 (defun widget-value-convert-widget (widget)
1393   "Initialize :value from :args in WIDGET."
1394   (let ((args (widget-get widget :args)))
1395     (when args
1396       (widget-put widget :value (car args))
1397       ;; Don't convert :value here, as this is done in `widget-convert'.
1398       ;; (widget-put widget :value (widget-apply widget
1399       ;;                                      :value-to-internal (car args)))
1400       (widget-put widget :args nil)))
1401   widget)
1402
1403 (defun widget-value-value-get (widget)
1404   "Return the :value property of WIDGET."
1405   (widget-get widget :value))
1406
1407 ;;; The `default' Widget.
1408
1409 (define-widget 'default nil
1410   "Basic widget other widgets are derived from."
1411   :value-to-internal (lambda (widget value) value)
1412   :value-to-external (lambda (widget value) value)
1413   :button-prefix 'widget-button-prefix
1414   :button-suffix 'widget-button-suffix
1415   :complete 'widget-default-complete
1416   :create 'widget-default-create
1417   :indent nil
1418   :offset 0
1419   :format-handler 'widget-default-format-handler
1420   :button-face-get 'widget-default-button-face-get
1421   :mouse-face-get 'widget-default-mouse-face-get
1422   :sample-face-get 'widget-default-sample-face-get
1423   :delete 'widget-default-delete
1424   :copy 'identity
1425   :value-set 'widget-default-value-set
1426   :value-inline 'widget-default-value-inline
1427   :value-delete 'ignore
1428   :default-get 'widget-default-default-get
1429   :menu-tag-get 'widget-default-menu-tag-get
1430   :validate #'ignore
1431   :active 'widget-default-active
1432   :activate 'widget-specify-active
1433   :deactivate 'widget-default-deactivate
1434   :mouse-down-action #'ignore
1435   :action 'widget-default-action
1436   :notify 'widget-default-notify
1437   :prompt-value 'widget-default-prompt-value)
1438
1439 (defun widget-default-complete (widget)
1440   "Call the value of the :complete-function property of WIDGET.
1441 If that does not exists, call the value of `widget-complete-field'."
1442   (call-interactively (or (widget-get widget :complete-function)
1443                           widget-complete-field)))
1444
1445 (defun widget-default-create (widget)
1446   "Create WIDGET at point in the current buffer."
1447   (widget-specify-insert
1448    (let ((from (point))
1449          button-begin button-end
1450          sample-begin sample-end
1451          doc-begin doc-end
1452          value-pos)
1453      (insert (widget-get widget :format))
1454      (goto-char from)
1455      ;; Parse escapes in format.
1456      (while (re-search-forward "%\\(.\\)" nil t)
1457        (let ((escape (char-after (match-beginning 1))))
1458          (delete-backward-char 2)
1459          (cond ((eq escape ?%)
1460                 (insert ?%))
1461                ((eq escape ?\[)
1462                 (setq button-begin (point))
1463                 (insert (widget-get-indirect widget :button-prefix)))
1464                ((eq escape ?\])
1465                 (insert (widget-get-indirect widget :button-suffix))
1466                 (setq button-end (point)))
1467                ((eq escape ?\{)
1468                 (setq sample-begin (point)))
1469                ((eq escape ?\})
1470                 (setq sample-end (point)))
1471                ((eq escape ?n)
1472                 (when (widget-get widget :indent)
1473                   (insert ?\n)
1474                   (insert-char ?\s (widget-get widget :indent))))
1475                ((eq escape ?t)
1476                 (let ((image (widget-get widget :tag-glyph))
1477                       (tag (widget-get widget :tag)))
1478                   (cond (image
1479                          (widget-image-insert widget (or tag "image") image))
1480                         (tag
1481                          (insert tag))
1482                         (t
1483                          (princ (widget-get widget :value)
1484                                 (current-buffer))))))
1485                ((eq escape ?d)
1486                 (let ((doc (widget-get widget :doc)))
1487                   (when doc
1488                     (setq doc-begin (point))
1489                     (insert doc)
1490                     (while (eq (preceding-char) ?\n)
1491                       (delete-backward-char 1))
1492                     (insert ?\n)
1493                     (setq doc-end (point)))))
1494                ((eq escape ?h)
1495                 (widget-add-documentation-string-button widget))
1496                ((eq escape ?v)
1497                 (if (and button-begin (not button-end))
1498                     (widget-apply widget :value-create)
1499                   (setq value-pos (point))))
1500                (t
1501                 (widget-apply widget :format-handler escape)))))
1502      ;; Specify button, sample, and doc, and insert value.
1503      (and button-begin button-end
1504           (widget-specify-button widget button-begin button-end))
1505      (and sample-begin sample-end
1506           (widget-specify-sample widget sample-begin sample-end))
1507      (and doc-begin doc-end
1508           (widget-specify-doc widget doc-begin doc-end))
1509      (when value-pos
1510        (goto-char value-pos)
1511        (widget-apply widget :value-create)))
1512    (let ((from (point-min-marker))
1513          (to (point-max-marker)))
1514      (set-marker-insertion-type from t)
1515      (set-marker-insertion-type to nil)
1516      (widget-put widget :from from)
1517      (widget-put widget :to to)))
1518   (widget-clear-undo))
1519
1520 (defun widget-default-format-handler (widget escape)
1521   (error "Unknown escape `%c'" escape))
1522
1523 (defun widget-default-button-face-get (widget)
1524   ;; Use :button-face or widget-button-face
1525   (or (widget-get widget :button-face)
1526       (let ((parent (widget-get widget :parent)))
1527         (if parent
1528             (widget-apply parent :button-face-get)
1529           widget-button-face))))
1530
1531 (defun widget-default-mouse-face-get (widget)
1532   ;; Use :mouse-face or widget-mouse-face
1533   (or (widget-get widget :mouse-face)
1534       (let ((parent (widget-get widget :parent)))
1535         (if parent
1536             (widget-apply parent :mouse-face-get)
1537           widget-mouse-face))))
1538
1539 (defun widget-default-sample-face-get (widget)
1540   ;; Use :sample-face.
1541   (widget-get widget :sample-face))
1542
1543 (defun widget-default-delete (widget)
1544   "Remove widget from the buffer."
1545   (let ((from (widget-get widget :from))
1546         (to (widget-get widget :to))
1547         (inactive-overlay (widget-get widget :inactive))
1548         (button-overlay (widget-get widget :button-overlay))
1549         (sample-overlay (widget-get widget :sample-overlay))
1550         (doc-overlay (widget-get widget :doc-overlay))
1551         (inhibit-modification-hooks t)
1552         (inhibit-read-only t))
1553     (widget-apply widget :value-delete)
1554     (widget-children-value-delete widget)
1555     (when inactive-overlay
1556       (delete-overlay inactive-overlay))
1557     (when button-overlay
1558       (delete-overlay button-overlay))
1559     (when sample-overlay
1560       (delete-overlay sample-overlay))
1561     (when doc-overlay
1562       (delete-overlay doc-overlay))
1563     (when (< from to)
1564       ;; Kludge: this doesn't need to be true for empty formats.
1565       (delete-region from to))
1566     (set-marker from nil)
1567     (set-marker to nil))
1568   (widget-clear-undo))
1569
1570 (defun widget-default-value-set (widget value)
1571   "Recreate widget with new value."
1572   (let* ((old-pos (point))
1573          (from (copy-marker (widget-get widget :from)))
1574          (to (copy-marker (widget-get widget :to)))
1575          (offset (if (and (<= from old-pos) (<= old-pos to))
1576                      (if (>= old-pos (1- to))
1577                          (- old-pos to 1)
1578                        (- old-pos from)))))
1579     ;;??? Bug: this ought to insert the new value before deleting the old one,
1580     ;; so that markers on either side of the value automatically
1581     ;; stay on the same side.  -- rms.
1582     (save-excursion
1583       (goto-char (widget-get widget :from))
1584       (widget-apply widget :delete)
1585       (widget-put widget :value value)
1586       (widget-apply widget :create))
1587     (if offset
1588         (if (< offset 0)
1589             (goto-char (+ (widget-get widget :to) offset 1))
1590           (goto-char (min (+ from offset) (1- (widget-get widget :to))))))))
1591
1592 (defun widget-default-value-inline (widget)
1593   "Wrap value in a list unless it is inline."
1594   (if (widget-get widget :inline)
1595       (widget-value widget)
1596     (list (widget-value widget))))
1597
1598 (defun widget-default-default-get (widget)
1599   "Get `:value'."
1600   (widget-get widget :value))
1601
1602 (defun widget-default-menu-tag-get (widget)
1603   "Use tag or value for menus."
1604   (or (widget-get widget :menu-tag)
1605       (widget-get widget :tag)
1606       (widget-princ-to-string (widget-get widget :value))))
1607
1608 (defun widget-default-active (widget)
1609   "Return t if this widget is active (user modifiable)."
1610   (or (widget-get widget :always-active)
1611       (and (not (widget-get widget :inactive))
1612            (let ((parent (widget-get widget :parent)))
1613              (or (null parent)
1614                  (widget-apply parent :active))))))
1615
1616 (defun widget-default-deactivate (widget)
1617   "Make WIDGET inactive for user modifications."
1618   (widget-specify-inactive widget
1619                            (widget-get widget :from)
1620                            (widget-get widget :to)))
1621
1622 (defun widget-default-action (widget &optional event)
1623   "Notify the parent when a widget changes."
1624   (let ((parent (widget-get widget :parent)))
1625     (when parent
1626       (widget-apply parent :notify widget event))))
1627
1628 (defun widget-default-notify (widget child &optional event)
1629   "Pass notification to parent."
1630   (widget-default-action widget event))
1631
1632 (defun widget-default-prompt-value (widget prompt value unbound)
1633   "Read an arbitrary value."
1634   (eval-minibuffer prompt))
1635
1636 (defun widget-docstring (widget)
1637   "Return the documentation string specificied by WIDGET, or nil if none.
1638 If WIDGET has a `:doc' property, that specifies the documentation string.
1639 Otherwise, try the `:documentation-property' property.  If this
1640 is a function, call it with the widget's value as an argument; if
1641 it is a symbol, use this symbol together with the widget's value
1642 as the argument to `documentation-property'."
1643   (let ((doc (or (widget-get widget :doc)
1644                  (let ((doc-prop (widget-get widget :documentation-property))
1645                        (value (widget-get widget :value)))
1646                    (cond ((functionp doc-prop)
1647                           (funcall doc-prop value))
1648                          ((symbolp doc-prop)
1649                           (documentation-property value doc-prop)))))))
1650     (when (and (stringp doc) (> (length doc) 0))
1651       ;; Remove any redundant `*' in the beginning.
1652       (when (eq (aref doc 0) ?*)
1653         (setq doc (substring doc 1)))
1654       ;; Remove trailing newlines.
1655       (when (string-match "\n+\\'" doc)
1656         (setq doc (substring doc 0 (match-beginning 0))))
1657       doc)))
1658
1659 ;;; The `item' Widget.
1660
1661 (define-widget 'item 'default
1662   "Constant items for inclusion in other widgets."
1663   :convert-widget 'widget-value-convert-widget
1664   :value-create 'widget-item-value-create
1665   :value-delete 'ignore
1666   :value-get 'widget-value-value-get
1667   :match 'widget-item-match
1668   :match-inline 'widget-item-match-inline
1669   :action 'widget-item-action
1670   :format "%t\n")
1671
1672 (defun widget-item-value-create (widget)
1673   "Insert the printed representation of the value."
1674   (princ (widget-get widget :value) (current-buffer)))
1675
1676 (defun widget-item-match (widget value)
1677   ;; Match if the value is the same.
1678   (equal (widget-get widget :value) value))
1679
1680 (defun widget-item-match-inline (widget values)
1681   ;; Match if the value is the same.
1682   (let ((value (widget-get widget :value)))
1683     (and (listp value)
1684          (<= (length value) (length values))
1685          (let ((head (widget-sublist values 0 (length value))))
1686            (and (equal head value)
1687                 (cons head (widget-sublist values (length value))))))))
1688
1689 (defun widget-sublist (list start &optional end)
1690   "Return the sublist of LIST from START to END.
1691 If END is omitted, it defaults to the length of LIST."
1692   (if (> start 0) (setq list (nthcdr start list)))
1693   (if end
1694       (unless (<= end start)
1695         (setq list (copy-sequence list))
1696         (setcdr (nthcdr (- end start 1) list) nil)
1697         list)
1698     (copy-sequence list)))
1699
1700 (defun widget-item-action (widget &optional event)
1701   ;; Just notify itself.
1702   (widget-apply widget :notify widget event))
1703
1704 ;;; The `push-button' Widget.
1705
1706 ;; (defcustom widget-push-button-gui t
1707 ;;   "If non-nil, use GUI push buttons when available."
1708 ;;   :group 'widgets
1709 ;;   :type 'boolean)
1710
1711 ;; Cache already created GUI objects.
1712 ;; (defvar widget-push-button-cache nil)
1713
1714 (defcustom widget-push-button-prefix "["
1715   "String used as prefix for buttons."
1716   :type 'string
1717   :group 'widget-button)
1718
1719 (defcustom widget-push-button-suffix "]"
1720   "String used as suffix for buttons."
1721   :type 'string
1722   :group 'widget-button)
1723
1724 (define-widget 'push-button 'item
1725   "A pushable button."
1726   :button-prefix ""
1727   :button-suffix ""
1728   :value-create 'widget-push-button-value-create
1729   :format "%[%v%]")
1730
1731 (defun widget-push-button-value-create (widget)
1732   "Insert text representing the `on' and `off' states."
1733   (let* ((tag (or (widget-get widget :tag)
1734                   (widget-get widget :value)))
1735          (tag-glyph (widget-get widget :tag-glyph))
1736          (text (concat widget-push-button-prefix
1737                        tag widget-push-button-suffix)))
1738     (if tag-glyph
1739         (widget-image-insert widget text tag-glyph)
1740       (insert text))))
1741
1742 ;; (defun widget-gui-action (widget)
1743 ;;   "Apply :action for WIDGET."
1744 ;;   (widget-apply-action widget (this-command-keys)))
1745
1746 ;;; The `link' Widget.
1747
1748 (defcustom widget-link-prefix "["
1749   "String used as prefix for links."
1750   :type 'string
1751   :group 'widget-button)
1752
1753 (defcustom widget-link-suffix "]"
1754   "String used as suffix for links."
1755   :type 'string
1756   :group 'widget-button)
1757
1758 (define-widget 'link 'item
1759   "An embedded link."
1760   :button-prefix 'widget-link-prefix
1761   :button-suffix 'widget-link-suffix
1762   :follow-link "\C-m"
1763   :help-echo "Follow the link."
1764   :format "%[%t%]")
1765
1766 ;;; The `info-link' Widget.
1767
1768 (define-widget 'info-link 'link
1769   "A link to an info file."
1770   :action 'widget-info-link-action)
1771
1772 (defun widget-info-link-action (widget &optional event)
1773   "Open the info node specified by WIDGET."
1774   (info (widget-value widget)))
1775
1776 ;;; The `url-link' Widget.
1777
1778 (define-widget 'url-link 'link
1779   "A link to an www page."
1780   :action 'widget-url-link-action)
1781
1782 (defun widget-url-link-action (widget &optional event)
1783   "Open the URL specified by WIDGET."
1784   (browse-url (widget-value widget)))
1785
1786 ;;; The `function-link' Widget.
1787
1788 (define-widget 'function-link 'link
1789   "A link to an Emacs function."
1790   :action 'widget-function-link-action)
1791
1792 (defun widget-function-link-action (widget &optional event)
1793   "Show the function specified by WIDGET."
1794   (describe-function (widget-value widget)))
1795
1796 ;;; The `variable-link' Widget.
1797
1798 (define-widget 'variable-link 'link
1799   "A link to an Emacs variable."
1800   :action 'widget-variable-link-action)
1801
1802 (defun widget-variable-link-action (widget &optional event)
1803   "Show the variable specified by WIDGET."
1804   (describe-variable (widget-value widget)))
1805
1806 ;;; The `file-link' Widget.
1807
1808 (define-widget 'file-link 'link
1809   "A link to a file."
1810   :action 'widget-file-link-action)
1811
1812 (defun widget-file-link-action (widget &optional event)
1813   "Find the file specified by WIDGET."
1814   (find-file (widget-value widget)))
1815
1816 ;;; The `emacs-library-link' Widget.
1817
1818 (define-widget 'emacs-library-link 'link
1819   "A link to an Emacs Lisp library file."
1820   :action 'widget-emacs-library-link-action)
1821
1822 (defun widget-emacs-library-link-action (widget &optional event)
1823   "Find the Emacs library file specified by WIDGET."
1824   (find-file (locate-library (widget-value widget))))
1825
1826 ;;; The `emacs-commentary-link' Widget.
1827
1828 (define-widget 'emacs-commentary-link 'link
1829   "A link to Commentary in an Emacs Lisp library file."
1830   :action 'widget-emacs-commentary-link-action)
1831
1832 (defun widget-emacs-commentary-link-action (widget &optional event)
1833   "Find the Commentary section of the Emacs file specified by WIDGET."
1834   (finder-commentary (widget-value widget)))
1835
1836 ;;; The `editable-field' Widget.
1837
1838 (define-widget 'editable-field 'default
1839   "An editable text field.
1840 Note: In an `editable-field' widget, the `%v' escape must be preceded
1841 by some other text in the `:format' string (if specified)."
1842   :convert-widget 'widget-value-convert-widget
1843   :keymap widget-field-keymap
1844   :format "%v"
1845   :help-echo "M-TAB: complete field; RET: enter value"
1846   :value ""
1847   :prompt-internal 'widget-field-prompt-internal
1848   :prompt-history 'widget-field-history
1849   :prompt-value 'widget-field-prompt-value
1850   :action 'widget-field-action
1851   :validate 'widget-field-validate
1852   :valid-regexp ""
1853   :error "Field's value doesn't match allowed forms"
1854   :value-create 'widget-field-value-create
1855   :value-delete 'widget-field-value-delete
1856   :value-get 'widget-field-value-get
1857   :match 'widget-field-match)
1858
1859 (defvar widget-field-history nil
1860   "History of field minibuffer edits.")
1861
1862 (defun widget-field-prompt-internal (widget prompt initial history)
1863   "Read string for WIDGET prompting with PROMPT.
1864 INITIAL is the initial input and HISTORY is a symbol containing
1865 the earlier input."
1866   (read-string prompt initial history))
1867
1868 (defun widget-field-prompt-value (widget prompt value unbound)
1869   "Prompt for a string."
1870   (widget-apply widget
1871                 :value-to-external
1872                 (widget-apply widget
1873                               :prompt-internal prompt
1874                               (unless unbound
1875                                 (cons (widget-apply widget
1876                                                     :value-to-internal value)
1877                                       0))
1878                               (widget-get widget :prompt-history))))
1879
1880 (defvar widget-edit-functions nil)
1881
1882 (defun widget-field-action (widget &optional event)
1883   "Move to next field."
1884   (widget-forward 1)
1885   (run-hook-with-args 'widget-edit-functions widget))
1886
1887 (defun widget-field-validate (widget)
1888   "Valid if the content matches `:valid-regexp'."
1889   (unless (string-match (widget-get widget :valid-regexp)
1890                         (widget-apply widget :value-get))
1891     widget))
1892
1893 (defun widget-field-value-create (widget)
1894   "Create an editable text field."
1895   (let ((size (widget-get widget :size))
1896         (value (widget-get widget :value))
1897         (from (point))
1898         ;; This is changed to a real overlay in `widget-setup'.  We
1899         ;; need the end points to behave differently until
1900         ;; `widget-setup' is called.
1901         (overlay (cons (make-marker) (make-marker))))
1902     (widget-put widget :field-overlay overlay)
1903     (insert value)
1904     (and size
1905          (< (length value) size)
1906          (insert-char ?\s (- size (length value))))
1907     (unless (memq widget widget-field-list)
1908       (setq widget-field-new (cons widget widget-field-new)))
1909     (move-marker (cdr overlay) (point))
1910     (set-marker-insertion-type (cdr overlay) nil)
1911     (when (null size)
1912       (insert ?\n))
1913     (move-marker (car overlay) from)
1914     (set-marker-insertion-type (car overlay) t)))
1915
1916 (defun widget-field-value-delete (widget)
1917   "Remove the widget from the list of active editing fields."
1918   (setq widget-field-list (delq widget widget-field-list))
1919   (setq widget-field-new (delq widget widget-field-new))
1920   ;; These are nil if the :format string doesn't contain `%v'.
1921   (let ((overlay (widget-get widget :field-overlay)))
1922     (when (overlayp overlay)
1923       (delete-overlay overlay))))
1924
1925 (defun widget-field-value-get (widget)
1926   "Return current text in editing field."
1927   (let ((from (widget-field-start widget))
1928         (to (widget-field-end widget))
1929         (buffer (widget-field-buffer widget))
1930         (size (widget-get widget :size))
1931         (secret (widget-get widget :secret))
1932         (old (current-buffer)))
1933     (if (and from to)
1934         (progn
1935           (set-buffer buffer)
1936           (while (and size
1937                       (not (zerop size))
1938                       (> to from)
1939                       (eq (char-after (1- to)) ?\s))
1940             (setq to (1- to)))
1941           (let ((result (buffer-substring-no-properties from to)))
1942             (when secret
1943               (let ((index 0))
1944                 (while (< (+ from index) to)
1945                   (aset result index
1946                         (get-char-property (+ from index) 'secret))
1947                   (setq index (1+ index)))))
1948             (set-buffer old)
1949             result))
1950       (widget-get widget :value))))
1951
1952 (defun widget-field-match (widget value)
1953   ;; Match any string.
1954   (stringp value))
1955
1956 ;;; The `text' Widget.
1957
1958 (define-widget 'text 'editable-field
1959   "A multiline text area."
1960   :keymap widget-text-keymap)
1961
1962 ;;; The `menu-choice' Widget.
1963
1964 (define-widget 'menu-choice 'default
1965   "A menu of options."
1966   :convert-widget  'widget-types-convert-widget
1967   :copy 'widget-types-copy
1968   :format "%[%t%]: %v"
1969   :case-fold t
1970   :tag "choice"
1971   :void '(item :format "invalid (%t)\n")
1972   :value-create 'widget-choice-value-create
1973   :value-get 'widget-child-value-get
1974   :value-inline 'widget-child-value-inline
1975   :default-get 'widget-choice-default-get
1976   :mouse-down-action 'widget-choice-mouse-down-action
1977   :action 'widget-choice-action
1978   :error "Make a choice"
1979   :validate 'widget-choice-validate
1980   :match 'widget-choice-match
1981   :match-inline 'widget-choice-match-inline)
1982
1983 (defun widget-choice-value-create (widget)
1984   "Insert the first choice that matches the value."
1985   (let ((value (widget-get widget :value))
1986         (args (widget-get widget :args))
1987         (explicit (widget-get widget :explicit-choice))
1988         current)
1989     (if explicit
1990         (progn
1991           ;; If the user specified the choice for this value,
1992           ;; respect that choice.
1993           (widget-put widget :children (list (widget-create-child-value
1994                                               widget explicit value)))
1995           (widget-put widget :choice explicit)
1996           (widget-put widget :explicit-choice nil))
1997       (while args
1998         (setq current (car args)
1999               args (cdr args))
2000         (when (widget-apply current :match value)
2001           (widget-put widget :children (list (widget-create-child-value
2002                                               widget current value)))
2003           (widget-put widget :choice current)
2004           (setq args nil
2005                 current nil)))
2006       (when current
2007         (let ((void (widget-get widget :void)))
2008           (widget-put widget :children (list (widget-create-child-and-convert
2009                                               widget void :value value)))
2010           (widget-put widget :choice void))))))
2011
2012 (defun widget-choice-default-get (widget)
2013   ;; Get default for the first choice.
2014   (widget-default-get (car (widget-get widget :args))))
2015
2016 (defcustom widget-choice-toggle nil
2017   "If non-nil, a binary choice will just toggle between the values.
2018 Otherwise, the user will explicitly have to choose between the values
2019 when he invoked the menu."
2020   :type 'boolean
2021   :group 'widgets)
2022
2023 (defun widget-choice-mouse-down-action (widget &optional event)
2024   ;; Return non-nil if we need a menu.
2025   (let ((args (widget-get widget :args))
2026         (old (widget-get widget :choice)))
2027     (cond ((not (display-popup-menus-p))
2028            ;; No place to pop up a menu.
2029            nil)
2030           ((< (length args) 2)
2031            ;; Empty or singleton list, just return the value.
2032            nil)
2033           ((> (length args) widget-menu-max-size)
2034            ;; Too long, prompt.
2035            nil)
2036           ((> (length args) 2)
2037            ;; Reasonable sized list, use menu.
2038            t)
2039           ((and widget-choice-toggle (memq old args))
2040            ;; We toggle.
2041            nil)
2042           (t
2043            ;; Ask which of the two.
2044            t))))
2045
2046 (defun widget-choice-action (widget &optional event)
2047   ;; Make a choice.
2048   (let ((args (widget-get widget :args))
2049         (old (widget-get widget :choice))
2050         (tag (widget-apply widget :menu-tag-get))
2051         (completion-ignore-case (widget-get widget :case-fold))
2052         this-explicit
2053         current choices)
2054     ;; Remember old value.
2055     (if (and old (not (widget-apply widget :validate)))
2056         (let* ((external (widget-value widget))
2057                (internal (widget-apply old :value-to-internal external)))
2058           (widget-put old :value internal)))
2059     ;; Find new choice.
2060     (setq current
2061           (cond ((= (length args) 0)
2062                  nil)
2063                 ((= (length args) 1)
2064                  (nth 0 args))
2065                 ((and widget-choice-toggle
2066                       (= (length args) 2)
2067                       (memq old args))
2068                  (if (eq old (nth 0 args))
2069                      (nth 1 args)
2070                    (nth 0 args)))
2071                 (t
2072                  (while args
2073                    (setq current (car args)
2074                          args (cdr args))
2075                    (setq choices
2076                          (cons (cons (widget-apply current :menu-tag-get)
2077                                      current)
2078                                choices)))
2079                  (setq this-explicit t)
2080                  (widget-choose tag (reverse choices) event))))
2081     (when current
2082       ;; If this was an explicit user choice, record the choice,
2083       ;; so that widget-choice-value-create will respect it.
2084       (when this-explicit
2085         (widget-put widget :explicit-choice current))
2086       (widget-value-set widget (widget-default-get current))
2087       (widget-setup)
2088       (widget-apply widget :notify widget event)))
2089   (run-hook-with-args 'widget-edit-functions widget))
2090
2091 (defun widget-choice-validate (widget)
2092   ;; Valid if we have made a valid choice.
2093   (if (eq (widget-get widget :void) (widget-get widget :choice))
2094       widget
2095     (widget-apply (car (widget-get widget :children)) :validate)))
2096
2097 (defun widget-choice-match (widget value)
2098   ;; Matches if one of the choices matches.
2099   (let ((args (widget-get widget :args))
2100         current found)
2101     (while (and args (not found))
2102       (setq current (car args)
2103             args (cdr args)
2104             found (widget-apply current :match value)))
2105     found))
2106
2107 (defun widget-choice-match-inline (widget values)
2108   ;; Matches if one of the choices matches.
2109   (let ((args (widget-get widget :args))
2110         current found)
2111     (while (and args (null found))
2112       (setq current (car args)
2113             args (cdr args)
2114             found (widget-match-inline current values)))
2115     found))
2116
2117 ;;; The `toggle' Widget.
2118
2119 (define-widget 'toggle 'item
2120   "Toggle between two states."
2121   :format "%[%v%]\n"
2122   :value-create 'widget-toggle-value-create
2123   :action 'widget-toggle-action
2124   :match (lambda (widget value) t)
2125   :on "on"
2126   :off "off")
2127
2128 (defun widget-toggle-value-create (widget)
2129   "Insert text representing the `on' and `off' states."
2130   (if (widget-value widget)
2131       (let ((image (widget-get widget :on-glyph)))
2132         (and (display-graphic-p)
2133              (listp image)
2134              (not (eq (car image) 'image))
2135              (widget-put widget :on-glyph (setq image (eval image))))
2136         (widget-image-insert widget
2137                              (widget-get widget :on)
2138                              image))
2139     (let ((image (widget-get widget :off-glyph)))
2140       (and (display-graphic-p)
2141            (listp image)
2142            (not (eq (car image) 'image))
2143            (widget-put widget :off-glyph (setq image (eval image))))
2144       (widget-image-insert widget (widget-get widget :off) image))))
2145
2146 (defun widget-toggle-action (widget &optional event)
2147   ;; Toggle value.
2148   (widget-value-set widget (not (widget-value widget)))
2149   (widget-apply widget :notify widget event)
2150   (run-hook-with-args 'widget-edit-functions widget))
2151
2152 ;;; The `checkbox' Widget.
2153
2154 (define-widget 'checkbox 'toggle
2155   "A checkbox toggle."
2156   :button-suffix ""
2157   :button-prefix ""
2158   :format "%[%v%]"
2159   :on "[X]"
2160   ;; We could probably do the same job as the images using single
2161   ;; space characters in a boxed face with a stretch specification to
2162   ;; make them square.
2163   :on-glyph '(create-image "\300\300\141\143\067\076\034\030"
2164                            'xbm t :width 8 :height 8
2165                            :background "grey75" ; like default mode line
2166                            :foreground "black"
2167                            :relief -2
2168                            :ascent 'center)
2169   :off "[ ]"
2170   :off-glyph '(create-image (make-string 8 0)
2171                             'xbm t :width 8 :height 8
2172                             :background "grey75"
2173                             :foreground "black"
2174                             :relief -2
2175                             :ascent 'center)
2176   :help-echo "Toggle this item."
2177   :action 'widget-checkbox-action)
2178
2179 (defun widget-checkbox-action (widget &optional event)
2180   "Toggle checkbox, notify parent, and set active state of sibling."
2181   (widget-toggle-action widget event)
2182   (let ((sibling (widget-get-sibling widget)))
2183     (when sibling
2184       (if (widget-value widget)
2185           (widget-apply sibling :activate)
2186         (widget-apply sibling :deactivate))
2187       (widget-clear-undo))))
2188
2189 ;;; The `checklist' Widget.
2190
2191 (define-widget 'checklist 'default
2192   "A multiple choice widget."
2193   :convert-widget 'widget-types-convert-widget
2194   :copy 'widget-types-copy
2195   :format "%v"
2196   :offset 4
2197   :entry-format "%b %v"
2198   :greedy nil
2199   :value-create 'widget-checklist-value-create
2200   :value-get 'widget-checklist-value-get
2201   :validate 'widget-checklist-validate
2202   :match 'widget-checklist-match
2203   :match-inline 'widget-checklist-match-inline)
2204
2205 (defun widget-checklist-value-create (widget)
2206   ;; Insert all values
2207   (let ((alist (widget-checklist-match-find widget (widget-get widget :value)))
2208         (args (widget-get widget :args)))
2209     (while args
2210       (widget-checklist-add-item widget (car args) (assq (car args) alist))
2211       (setq args (cdr args)))
2212     (widget-put widget :children (nreverse (widget-get widget :children)))))
2213
2214 (defun widget-checklist-add-item (widget type chosen)
2215   "Create checklist item in WIDGET of type TYPE.
2216 If the item is checked, CHOSEN is a cons whose cdr is the value."
2217   (and (eq (preceding-char) ?\n)
2218        (widget-get widget :indent)
2219        (insert-char ?\s (widget-get widget :indent)))
2220   (widget-specify-insert
2221    (let* ((children (widget-get widget :children))
2222           (buttons (widget-get widget :buttons))
2223           (button-args (or (widget-get type :sibling-args)
2224                            (widget-get widget :button-args)))
2225           (from (point))
2226           child button)
2227      (insert (widget-get widget :entry-format))
2228      (goto-char from)
2229      ;; Parse % escapes in format.
2230      (while (re-search-forward "%\\([bv%]\\)" nil t)
2231        (let ((escape (char-after (match-beginning 1))))
2232          (delete-backward-char 2)
2233          (cond ((eq escape ?%)
2234                 (insert ?%))
2235                ((eq escape ?b)
2236                 (setq button (apply 'widget-create-child-and-convert
2237                                     widget 'checkbox
2238                                     :value (not (null chosen))
2239                                     button-args)))
2240                ((eq escape ?v)
2241                 (setq child
2242                       (cond ((not chosen)
2243                              (let ((child (widget-create-child widget type)))
2244                                (widget-apply child :deactivate)
2245                                child))
2246                             ((widget-get type :inline)
2247                              (widget-create-child-value
2248                               widget type (cdr chosen)))
2249                             (t
2250                              (widget-create-child-value
2251                               widget type (car (cdr chosen)))))))
2252                (t
2253                 (error "Unknown escape `%c'" escape)))))
2254      ;; Update properties.
2255      (and button child (widget-put child :button button))
2256      (and button (widget-put widget :buttons (cons button buttons)))
2257      (and child (widget-put widget :children (cons child children))))))
2258
2259 (defun widget-checklist-match (widget values)
2260   ;; All values must match a type in the checklist.
2261   (and (listp values)
2262        (null (cdr (widget-checklist-match-inline widget values)))))
2263
2264 (defun widget-checklist-match-inline (widget values)
2265   ;; Find the values which match a type in the checklist.
2266   (let ((greedy (widget-get widget :greedy))
2267         (args (copy-sequence (widget-get widget :args)))
2268         found rest)
2269     (while values
2270       (let ((answer (widget-checklist-match-up args values)))
2271         (cond (answer
2272                (let ((vals (widget-match-inline answer values)))
2273                  (setq found (append found (car vals))
2274                        values (cdr vals)
2275                        args (delq answer args))))
2276               (greedy
2277                (setq rest (append rest (list (car values)))
2278                      values (cdr values)))
2279               (t
2280                (setq rest (append rest values)
2281                      values nil)))))
2282     (cons found rest)))
2283
2284 (defun widget-checklist-match-find (widget vals)
2285   "Find the vals which match a type in the checklist.
2286 Return an alist of (TYPE MATCH)."
2287   (let ((greedy (widget-get widget :greedy))
2288         (args (copy-sequence (widget-get widget :args)))
2289         found)
2290     (while vals
2291       (let ((answer (widget-checklist-match-up args vals)))
2292         (cond (answer
2293                (let ((match (widget-match-inline answer vals)))
2294                  (setq found (cons (cons answer (car match)) found)
2295                        vals (cdr match)
2296                        args (delq answer args))))
2297               (greedy
2298                (setq vals (cdr vals)))
2299               (t
2300                (setq vals nil)))))
2301     found))
2302
2303 (defun widget-checklist-match-up (args vals)
2304   "Return the first type from ARGS that matches VALS."
2305   (let (current found)
2306     (while (and args (null found))
2307       (setq current (car args)
2308             args (cdr args)
2309             found (widget-match-inline current vals)))
2310     (if found
2311         current)))
2312
2313 (defun widget-checklist-value-get (widget)
2314   ;; The values of all selected items.
2315   (let ((children (widget-get widget :children))
2316         child result)
2317     (while children
2318       (setq child (car children)
2319             children (cdr children))
2320       (if (widget-value (widget-get child :button))
2321           (setq result (append result (widget-apply child :value-inline)))))
2322     result))
2323
2324 (defun widget-checklist-validate (widget)
2325   ;; Ticked chilren must be valid.
2326   (let ((children (widget-get widget :children))
2327         child button found)
2328     (while (and children (not found))
2329       (setq child (car children)
2330             children (cdr children)
2331             button (widget-get child :button)
2332             found (and (widget-value button)
2333                        (widget-apply child :validate))))
2334     found))
2335
2336 ;;; The `option' Widget
2337
2338 (define-widget 'option 'checklist
2339   "An widget with an optional item."
2340   :inline t)
2341
2342 ;;; The `choice-item' Widget.
2343
2344 (define-widget 'choice-item 'item
2345   "Button items that delegate action events to their parents."
2346   :action 'widget-parent-action
2347   :format "%[%t%] \n")
2348
2349 ;;; The `radio-button' Widget.
2350
2351 (define-widget 'radio-button 'toggle
2352   "A radio button for use in the `radio' widget."
2353   :notify 'widget-radio-button-notify
2354   :format "%[%v%]"
2355   :button-suffix ""
2356   :button-prefix ""
2357   :on "(*)"
2358   :on-glyph "radio1"
2359   :off "( )"
2360   :off-glyph "radio0")
2361
2362 (defun widget-radio-button-notify (widget child &optional event)
2363   ;; Tell daddy.
2364   (widget-apply (widget-get widget :parent) :action widget event))
2365
2366 ;;; The `radio-button-choice' Widget.
2367
2368 (define-widget 'radio-button-choice 'default
2369   "Select one of multiple options."
2370   :convert-widget 'widget-types-convert-widget
2371   :copy 'widget-types-copy
2372   :offset 4
2373   :format "%v"
2374   :entry-format "%b %v"
2375   :value-create 'widget-radio-value-create
2376   :value-get 'widget-radio-value-get
2377   :value-inline 'widget-radio-value-inline
2378   :value-set 'widget-radio-value-set
2379   :error "You must push one of the buttons"
2380   :validate 'widget-radio-validate
2381   :match 'widget-choice-match
2382   :match-inline 'widget-choice-match-inline
2383   :action 'widget-radio-action)
2384
2385 (defun widget-radio-value-create (widget)
2386   ;; Insert all values
2387   (let ((args (widget-get widget :args))
2388         arg)
2389     (while args
2390       (setq arg (car args)
2391             args (cdr args))
2392       (widget-radio-add-item widget arg))))
2393
2394 (defun widget-radio-add-item (widget type)
2395   "Add to radio widget WIDGET a new radio button item of type TYPE."
2396   ;; (setq type (widget-convert type))
2397   (and (eq (preceding-char) ?\n)
2398        (widget-get widget :indent)
2399        (insert-char ?\s (widget-get widget :indent)))
2400   (widget-specify-insert
2401    (let* ((value (widget-get widget :value))
2402           (children (widget-get widget :children))
2403           (buttons (widget-get widget :buttons))
2404           (button-args (or (widget-get type :sibling-args)
2405                            (widget-get widget :button-args)))
2406           (from (point))
2407           (chosen (and (null (widget-get widget :choice))
2408                        (widget-apply type :match value)))
2409           child button)
2410      (insert (widget-get widget :entry-format))
2411      (goto-char from)
2412      ;; Parse % escapes in format.
2413      (while (re-search-forward "%\\([bv%]\\)" nil t)
2414        (let ((escape (char-after (match-beginning 1))))
2415          (delete-backward-char 2)
2416          (cond ((eq escape ?%)
2417                 (insert ?%))
2418                ((eq escape ?b)
2419                 (setq button (apply 'widget-create-child-and-convert
2420                                     widget 'radio-button
2421                                     :value (not (null chosen))
2422                                     button-args)))
2423                ((eq escape ?v)
2424                 (setq child (if chosen
2425                                 (widget-create-child-value
2426                                  widget type value)
2427                               (widget-create-child widget type)))
2428                 (unless chosen
2429                   (widget-apply child :deactivate)))
2430                (t
2431                 (error "Unknown escape `%c'" escape)))))
2432      ;; Update properties.
2433      (when chosen
2434        (widget-put widget :choice type))
2435      (when button
2436        (widget-put child :button button)
2437        (widget-put widget :buttons (nconc buttons (list button))))
2438      (when child
2439        (widget-put widget :children (nconc children (list child))))
2440      child)))
2441
2442 (defun widget-radio-value-get (widget)
2443   ;; Get value of the child widget.
2444   (let ((chosen (widget-radio-chosen widget)))
2445     (and chosen (widget-value chosen))))
2446
2447 (defun widget-radio-chosen (widget)
2448   "Return the widget representing the chosen radio button."
2449   (let ((children (widget-get widget :children))
2450         current found)
2451     (while children
2452       (setq current (car children)
2453             children (cdr children))
2454       (when (widget-apply (widget-get current :button) :value-get)
2455         (setq found current
2456               children nil)))
2457     found))
2458
2459 (defun widget-radio-value-inline (widget)
2460   ;; Get value of the child widget.
2461   (let ((children (widget-get widget :children))
2462         current found)
2463     (while children
2464       (setq current (car children)
2465             children (cdr children))
2466       (when (widget-apply (widget-get current :button) :value-get)
2467         (setq found (widget-apply current :value-inline)
2468               children nil)))
2469     found))
2470
2471 (defun widget-radio-value-set (widget value)
2472   ;; We can't just delete and recreate a radio widget, since children
2473   ;; can be added after the original creation and won't be recreated
2474   ;; by `:create'.
2475   (let ((children (widget-get widget :children))
2476         current found)
2477     (while children
2478       (setq current (car children)
2479             children (cdr children))
2480       (let* ((button (widget-get current :button))
2481              (match (and (not found)
2482                          (widget-apply current :match value))))
2483         (widget-value-set button match)
2484         (if match
2485             (progn
2486               (widget-value-set current value)
2487               (widget-apply current :activate))
2488           (widget-apply current :deactivate))
2489         (setq found (or found match))))))
2490
2491 (defun widget-radio-validate (widget)
2492   ;; Valid if we have made a valid choice.
2493   (let ((children (widget-get widget :children))
2494         current found button)
2495     (while (and children (not found))
2496       (setq current (car children)
2497             children (cdr children)
2498             button (widget-get current :button)
2499             found (widget-apply button :value-get)))
2500     (if found
2501         (widget-apply current :validate)
2502       widget)))
2503
2504 (defun widget-radio-action (widget child event)
2505   ;; Check if a radio button was pressed.
2506   (let ((children (widget-get widget :children))
2507         (buttons (widget-get widget :buttons))
2508         current)
2509     (when (memq child buttons)
2510       (while children
2511         (setq current (car children)
2512               children (cdr children))
2513         (let* ((button (widget-get current :button)))
2514           (cond ((eq child button)
2515                  (widget-value-set button t)
2516                  (widget-apply current :activate))
2517                 ((widget-value button)
2518                  (widget-value-set button nil)
2519                  (widget-apply current :deactivate)))))))
2520   ;; Pass notification to parent.
2521   (widget-apply widget :notify child event))
2522
2523 ;;; The `insert-button' Widget.
2524
2525 (define-widget 'insert-button 'push-button
2526   "An insert button for the `editable-list' widget."
2527   :tag "INS"
2528   :help-echo "Insert a new item into the list at this position."
2529   :action 'widget-insert-button-action)
2530
2531 (defun widget-insert-button-action (widget &optional event)
2532   ;; Ask the parent to insert a new item.
2533   (widget-apply (widget-get widget :parent)
2534                 :insert-before (widget-get widget :widget)))
2535
2536 ;;; The `delete-button' Widget.
2537
2538 (define-widget 'delete-button 'push-button
2539   "A delete button for the `editable-list' widget."
2540   :tag "DEL"
2541   :help-echo "Delete this item from the list."
2542   :action 'widget-delete-button-action)
2543
2544 (defun widget-delete-button-action (widget &optional event)
2545   ;; Ask the parent to insert a new item.
2546   (widget-apply (widget-get widget :parent)
2547                 :delete-at (widget-get widget :widget)))
2548
2549 ;;; The `editable-list' Widget.
2550
2551 ;; (defcustom widget-editable-list-gui nil
2552 ;;   "If non-nil, use GUI push-buttons in editable list when available."
2553 ;;   :type 'boolean
2554 ;;   :group 'widgets)
2555
2556 (define-widget 'editable-list 'default
2557   "A variable list of widgets of the same type."
2558   :convert-widget 'widget-types-convert-widget
2559   :copy 'widget-types-copy
2560   :offset 12
2561   :format "%v%i\n"
2562   :format-handler 'widget-editable-list-format-handler
2563   :entry-format "%i %d %v"
2564   :value-create 'widget-editable-list-value-create
2565   :value-get 'widget-editable-list-value-get
2566   :validate 'widget-children-validate
2567   :match 'widget-editable-list-match
2568   :match-inline 'widget-editable-list-match-inline
2569   :insert-before 'widget-editable-list-insert-before
2570   :delete-at 'widget-editable-list-delete-at)
2571
2572 (defun widget-editable-list-format-handler (widget escape)
2573   ;; We recognize the insert button.
2574     ;; (let ((widget-push-button-gui widget-editable-list-gui))
2575     (cond ((eq escape ?i)
2576            (and (widget-get widget :indent)
2577                 (insert-char ?\s (widget-get widget :indent)))
2578            (apply 'widget-create-child-and-convert
2579                   widget 'insert-button
2580                   (widget-get widget :append-button-args)))
2581           (t
2582            (widget-default-format-handler widget escape)))
2583     ;; )
2584   )
2585
2586 (defun widget-editable-list-value-create (widget)
2587   ;; Insert all values
2588   (let* ((value (widget-get widget :value))
2589          (type (nth 0 (widget-get widget :args)))
2590          children)
2591     (widget-put widget :value-pos (copy-marker (point)))
2592     (set-marker-insertion-type (widget-get widget :value-pos) t)
2593     (while value
2594       (let ((answer (widget-match-inline type value)))
2595         (if answer
2596             (setq children (cons (widget-editable-list-entry-create
2597                                   widget
2598                                   (if (widget-get type :inline)
2599                                       (car answer)
2600                                     (car (car answer)))
2601                                   t)
2602                                  children)
2603                   value (cdr answer))
2604           (setq value nil))))
2605     (widget-put widget :children (nreverse children))))
2606
2607 (defun widget-editable-list-value-get (widget)
2608   ;; Get value of the child widget.
2609   (apply 'append (mapcar (lambda (child) (widget-apply child :value-inline))
2610                          (widget-get widget :children))))
2611
2612 (defun widget-editable-list-match (widget value)
2613   ;; Value must be a list and all the members must match the type.
2614   (and (listp value)
2615        (null (cdr (widget-editable-list-match-inline widget value)))))
2616
2617 (defun widget-editable-list-match-inline (widget value)
2618   (let ((type (nth 0 (widget-get widget :args)))
2619         (ok t)
2620         found)
2621     (while (and value ok)
2622       (let ((answer (widget-match-inline type value)))
2623         (if answer
2624             (setq found (append found (car answer))
2625                   value (cdr answer))
2626           (setq ok nil))))
2627     (cons found value)))
2628
2629 (defun widget-editable-list-insert-before (widget before)
2630   ;; Insert a new child in the list of children.
2631   (save-excursion
2632     (let ((children (widget-get widget :children))
2633           (inhibit-read-only t)
2634           before-change-functions
2635           after-change-functions)
2636       (cond (before
2637              (goto-char (widget-get before :entry-from)))
2638             (t
2639              (goto-char (widget-get widget :value-pos))))
2640       (let ((child (widget-editable-list-entry-create
2641                     widget nil nil)))
2642         (when (< (widget-get child :entry-from) (widget-get widget :from))
2643           (set-marker (widget-get widget :from)
2644                       (widget-get child :entry-from)))
2645         (if (eq (car children) before)
2646             (widget-put widget :children (cons child children))
2647           (while (not (eq (car (cdr children)) before))
2648             (setq children (cdr children)))
2649           (setcdr children (cons child (cdr children)))))))
2650   (widget-setup)
2651   (widget-apply widget :notify widget))
2652
2653 (defun widget-editable-list-delete-at (widget child)
2654   ;; Delete child from list of children.
2655   (save-excursion
2656     (let ((buttons (copy-sequence (widget-get widget :buttons)))
2657           button
2658           (inhibit-read-only t)
2659           before-change-functions
2660           after-change-functions)
2661       (while buttons
2662         (setq button (car buttons)
2663               buttons (cdr buttons))
2664         (when (eq (widget-get button :widget) child)
2665           (widget-put widget
2666                       :buttons (delq button (widget-get widget :buttons)))
2667           (widget-delete button))))
2668     (let ((entry-from (widget-get child :entry-from))
2669           (entry-to (widget-get child :entry-to))
2670           (inhibit-read-only t)
2671           before-change-functions
2672           after-change-functions)
2673       (widget-delete child)
2674       (delete-region entry-from entry-to)
2675       (set-marker entry-from nil)
2676       (set-marker entry-to nil))
2677     (widget-put widget :children (delq child (widget-get widget :children))))
2678   (widget-setup)
2679   (widget-apply widget :notify widget))
2680
2681 (defun widget-editable-list-entry-create (widget value conv)
2682   ;; Create a new entry to the list.
2683   (let ((type (nth 0 (widget-get widget :args)))
2684         ;; (widget-push-button-gui widget-editable-list-gui)
2685         child delete insert)
2686     (widget-specify-insert
2687      (save-excursion
2688        (and (widget-get widget :indent)
2689             (insert-char ?\s (widget-get widget :indent)))
2690        (insert (widget-get widget :entry-format)))
2691      ;; Parse % escapes in format.
2692      (while (re-search-forward "%\\(.\\)" nil t)
2693        (let ((escape (char-after (match-beginning 1))))
2694          (delete-backward-char 2)
2695          (cond ((eq escape ?%)
2696                 (insert ?%))
2697                ((eq escape ?i)
2698                 (setq insert (apply 'widget-create-child-and-convert
2699                                     widget 'insert-button
2700                                     (widget-get widget :insert-button-args))))
2701                ((eq escape ?d)
2702                 (setq delete (apply 'widget-create-child-and-convert
2703                                     widget 'delete-button
2704                                     (widget-get widget :delete-button-args))))
2705                ((eq escape ?v)
2706                 (if conv
2707                     (setq child (widget-create-child-value
2708                                  widget type value))
2709                   (setq child (widget-create-child-value
2710                                widget type (widget-default-get type)))))
2711                (t
2712                 (error "Unknown escape `%c'" escape)))))
2713      (let ((buttons (widget-get widget :buttons)))
2714        (if insert (push insert buttons))
2715        (if delete (push delete buttons))
2716        (widget-put widget :buttons buttons))
2717      (let ((entry-from (point-min-marker))
2718            (entry-to (point-max-marker)))
2719        (set-marker-insertion-type entry-from t)
2720        (set-marker-insertion-type entry-to nil)
2721        (widget-put child :entry-from entry-from)
2722        (widget-put child :entry-to entry-to)))
2723     (if insert (widget-put insert :widget child))
2724     (if delete (widget-put delete :widget child))
2725     child))
2726
2727 ;;; The `group' Widget.
2728
2729 (define-widget 'group 'default
2730   "A widget which groups other widgets inside."
2731   :convert-widget 'widget-types-convert-widget
2732   :copy 'widget-types-copy
2733   :format "%v"
2734   :value-create 'widget-group-value-create
2735   :value-get 'widget-editable-list-value-get
2736   :default-get 'widget-group-default-get
2737   :validate 'widget-children-validate
2738   :match 'widget-group-match
2739   :match-inline 'widget-group-match-inline)
2740
2741 (defun widget-group-value-create (widget)
2742   ;; Create each component.
2743   (let ((args (widget-get widget :args))
2744         (value (widget-get widget :value))
2745         arg answer children)
2746     (while args
2747       (setq arg (car args)
2748             args (cdr args)
2749             answer (widget-match-inline arg value)
2750             value (cdr answer))
2751       (and (eq (preceding-char) ?\n)
2752            (widget-get widget :indent)
2753            (insert-char ?\s (widget-get widget :indent)))
2754       (push (cond ((null answer)
2755                    (widget-create-child widget arg))
2756                   ((widget-get arg :inline)
2757                    (widget-create-child-value widget arg (car answer)))
2758                   (t
2759                    (widget-create-child-value widget arg (car (car answer)))))
2760             children))
2761     (widget-put widget :children (nreverse children))))
2762
2763 (defun widget-group-default-get (widget)
2764   ;; Get the default of the components.
2765   (mapcar 'widget-default-get (widget-get widget :args)))
2766
2767 (defun widget-group-match (widget values)
2768   ;; Match if the components match.
2769   (and (listp values)
2770        (let ((match (widget-group-match-inline widget values)))
2771          (and match (null (cdr match))))))
2772
2773 (defun widget-group-match-inline (widget vals)
2774   ;; Match if the components match.
2775   (let ((args (widget-get widget :args))
2776         argument answer found)
2777     (while args
2778       (setq argument (car args)
2779             args (cdr args)
2780             answer (widget-match-inline argument vals))
2781       (if answer
2782           (setq vals (cdr answer)
2783                 found (append found (car answer)))
2784         (setq vals nil
2785               args nil)))
2786     (if answer
2787         (cons found vals))))
2788
2789 ;;; The `visibility' Widget.
2790
2791 (define-widget 'visibility 'item
2792   "An indicator and manipulator for hidden items."
2793   :format "%[%v%]"
2794   :button-prefix ""
2795   :button-suffix ""
2796   :on "Hide"
2797   :off "Show"
2798   :value-create 'widget-visibility-value-create
2799   :action 'widget-toggle-action
2800   :match (lambda (widget value) t))
2801
2802 (defun widget-visibility-value-create (widget)
2803   ;; Insert text representing the `on' and `off' states.
2804   (let ((on (widget-get widget :on))
2805         (off (widget-get widget :off)))
2806     (if on
2807         (setq on (concat widget-push-button-prefix
2808                          on
2809                          widget-push-button-suffix))
2810       (setq on ""))
2811     (if off
2812         (setq off (concat widget-push-button-prefix
2813                           off
2814                           widget-push-button-suffix))
2815       (setq off ""))
2816     (if (widget-value widget)
2817         (widget-image-insert widget on "down" "down-pushed")
2818       (widget-image-insert widget off "right" "right-pushed"))))
2819
2820 ;;; The `documentation-link' Widget.
2821 ;;
2822 ;; This is a helper widget for `documentation-string'.
2823
2824 (define-widget 'documentation-link 'link
2825   "Link type used in documentation strings."
2826   :tab-order -1
2827   :help-echo "Describe this symbol"
2828   :action 'widget-documentation-link-action)
2829
2830 (defun widget-documentation-link-action (widget &optional event)
2831   "Display documentation for WIDGET's value.  Ignore optional argument EVENT."
2832   (let* ((string (widget-get widget :value))
2833          (symbol (intern string)))
2834     (if (and (fboundp symbol) (boundp symbol))
2835         ;; If there are two doc strings, give the user a way to pick one.
2836         (apropos (concat "\\`" (regexp-quote string) "\\'"))
2837       (if (fboundp symbol)
2838           (describe-function symbol)
2839         (describe-variable symbol)))))
2840
2841 (defcustom widget-documentation-links t
2842   "Add hyperlinks to documentation strings when non-nil."
2843   :type 'boolean
2844   :group 'widget-documentation)
2845
2846 (defcustom widget-documentation-link-regexp "`\\([^\n`' ]+\\)'"
2847   "Regexp for matching potential links in documentation strings.
2848 The first group should be the link itself."
2849   :type 'regexp
2850   :group 'widget-documentation)
2851
2852 (defcustom widget-documentation-link-p 'intern-soft
2853   "Predicate used to test if a string is useful as a link.
2854 The value should be a function.  The function will be called with one
2855 argument, a string, and should return non-nil if there should be a
2856 link for that string."
2857   :type 'function
2858   :options '(widget-documentation-link-p)
2859   :group 'widget-documentation)
2860
2861 (defcustom widget-documentation-link-type 'documentation-link
2862   "Widget type used for links in documentation strings."
2863   :type 'symbol
2864   :group 'widget-documentation)
2865
2866 (defun widget-documentation-link-add (widget from to)
2867   (widget-specify-doc widget from to)
2868   (when widget-documentation-links
2869     (let ((regexp widget-documentation-link-regexp)
2870           (buttons (widget-get widget :buttons))
2871           (widget-mouse-face (default-value 'widget-mouse-face))
2872           (widget-button-face widget-documentation-face)
2873           (widget-button-pressed-face widget-documentation-face))
2874       (save-excursion
2875         (goto-char from)
2876         (while (re-search-forward regexp to t)
2877           (let ((name (match-string 1))
2878                 (begin (match-beginning 1))
2879                 (end (match-end 1)))
2880             (when (funcall widget-documentation-link-p name)
2881               (push (widget-convert-button widget-documentation-link-type
2882                                            begin end :value name)
2883                     buttons)))))
2884       (widget-put widget :buttons buttons)))
2885   (let ((indent (widget-get widget :indent)))
2886     (when (and indent (not (zerop indent)))
2887       (save-excursion
2888         (save-restriction
2889           (narrow-to-region from to)
2890           (goto-char (point-min))
2891           (while (search-forward "\n" nil t)
2892             (insert-char ?\s indent)))))))
2893
2894 ;;; The `documentation-string' Widget.
2895
2896 (define-widget 'documentation-string 'item
2897   "A documentation string."
2898   :format "%v"
2899   :action 'widget-documentation-string-action
2900   :value-create 'widget-documentation-string-value-create
2901   :visibility-widget 'visibility)
2902
2903 (defun widget-documentation-string-value-create (widget)
2904   ;; Insert documentation string.
2905   (let ((doc (widget-value widget))
2906         (indent (widget-get widget :indent))
2907         (shown (widget-get (widget-get widget :parent) :documentation-shown))
2908         (start (point)))
2909     (if (string-match "\n" doc)
2910         (let ((before (substring doc 0 (match-beginning 0)))
2911               (after (substring doc (match-beginning 0)))
2912               button)
2913           (when (and indent (not (zerop indent)))
2914             (insert-char ?\s indent))
2915           (insert before ?\s)
2916           (widget-documentation-link-add widget start (point))
2917           (setq button
2918                 (widget-create-child-and-convert
2919                  widget (widget-get widget :visibility-widget)
2920                  :help-echo "Show or hide rest of the documentation."
2921                  :on "Hide Rest"
2922                  :off "More"
2923                  :always-active t
2924                  :action 'widget-parent-action
2925                  shown))
2926           (when shown
2927             (setq start (point))
2928             (when (and indent (not (zerop indent)))
2929               (insert-char ?\s indent))
2930             (insert after)
2931             (widget-documentation-link-add widget start (point)))
2932           (widget-put widget :buttons (list button)))
2933       (when (and indent (not (zerop indent)))
2934         (insert-char ?\s indent))
2935       (insert doc)
2936       (widget-documentation-link-add widget start (point))))
2937   (insert ?\n))
2938
2939 (defun widget-documentation-string-action (widget &rest ignore)
2940   ;; Toggle documentation.
2941   (let ((parent (widget-get widget :parent)))
2942     (widget-put parent :documentation-shown
2943                 (not (widget-get parent :documentation-shown))))
2944   ;; Redraw.
2945   (widget-value-set widget (widget-value widget)))
2946
2947 (defun widget-add-documentation-string-button (widget &rest args)
2948   "Insert a new `documentation-string' widget based on WIDGET.
2949 The new widget becomes a child of WIDGET, and is also added to
2950 its `:buttons' list.  The documentation string is found from
2951 WIDGET using the function `widget-docstring'.
2952 Optional ARGS specifies additional keyword arguments for the
2953 `documentation-string' widget."
2954   (let ((doc (widget-docstring widget))
2955         (indent (widget-get widget :indent))
2956         (doc-indent (widget-get widget :documentation-indent)))
2957     (when doc
2958       (and (eq (preceding-char) ?\n)
2959            indent
2960            (insert-char ?\s indent))
2961       (unless (or (numberp doc-indent) (null doc-indent))
2962         (setq doc-indent 0))
2963       (widget-put widget :buttons
2964                   (cons (apply 'widget-create-child-and-convert
2965                                widget 'documentation-string
2966                                :indent doc-indent
2967                                (nconc args (list doc)))
2968                         (widget-get widget :buttons))))))
2969 \f
2970 ;;; The Sexp Widgets.
2971
2972 (define-widget 'const 'item
2973   "An immutable sexp."
2974   :prompt-value 'widget-const-prompt-value
2975   :format "%t\n%d")
2976
2977 (defun widget-const-prompt-value (widget prompt value unbound)
2978   ;; Return the value of the const.
2979   (widget-value widget))
2980
2981 (define-widget 'function-item 'const
2982   "An immutable function name."
2983   :format "%v\n%h"
2984   :documentation-property (lambda (symbol)
2985                             (condition-case nil
2986                                 (documentation symbol t)
2987                               (error nil))))
2988
2989 (define-widget 'variable-item 'const
2990   "An immutable variable name."
2991   :format "%v\n%h"
2992   :documentation-property 'variable-documentation)
2993
2994 (define-widget 'other 'sexp
2995   "Matches any value, but doesn't let the user edit the value.
2996 This is useful as last item in a `choice' widget.
2997 You should use this widget type with a default value,
2998 as in (other DEFAULT) or (other :tag \"NAME\" DEFAULT).
2999 If the user selects this alternative, that specifies DEFAULT
3000 as the value."
3001   :tag "Other"
3002   :format "%t%n"
3003   :value 'other)
3004
3005 (defvar widget-string-prompt-value-history nil
3006   "History of input to `widget-string-prompt-value'.")
3007
3008 (define-widget 'string 'editable-field
3009   "A string"
3010   :tag "String"
3011   :format "%{%t%}: %v"
3012   :complete-function 'ispell-complete-word
3013   :prompt-history 'widget-string-prompt-value-history)
3014
3015 (define-widget 'regexp 'string
3016   "A regular expression."
3017   :match 'widget-regexp-match
3018   :validate 'widget-regexp-validate
3019   ;; Doesn't work well with terminating newline.
3020   ;; :value-face 'widget-single-line-field
3021   :tag "Regexp")
3022
3023 (defun widget-regexp-match (widget value)
3024   ;; Match valid regexps.
3025   (and (stringp value)
3026        (condition-case nil
3027            (prog1 t
3028              (string-match value ""))
3029          (error nil))))
3030
3031 (defun widget-regexp-validate (widget)
3032   "Check that the value of WIDGET is a valid regexp."
3033   (condition-case data
3034       (prog1 nil
3035         (string-match (widget-value widget) ""))
3036     (error (widget-put widget :error (error-message-string data))
3037            widget)))
3038
3039 (define-widget 'file 'string
3040   "A file widget.
3041 It reads a file name from an editable text field."
3042   :complete-function 'widget-file-complete
3043   :prompt-value 'widget-file-prompt-value
3044   :format "%{%t%}: %v"
3045   ;; Doesn't work well with terminating newline.
3046   ;; :value-face 'widget-single-line-field
3047   :tag "File")
3048
3049 (defun widget-file-complete ()
3050   "Perform completion on file name preceding point."
3051   (interactive)
3052   (let* ((end (point))
3053          (beg (widget-field-start widget))
3054          (pattern (buffer-substring beg end))
3055          (name-part (file-name-nondirectory pattern))
3056          ;; I think defaulting to root is right
3057          ;; because these really should be absolute file names.
3058          (directory (or (file-name-directory pattern) "/"))
3059          (completion (file-name-completion name-part directory)))
3060     (cond ((eq completion t))
3061           ((null completion)
3062            (message "Can't find completion for \"%s\"" pattern)
3063            (ding))
3064           ((not (string= name-part completion))
3065            (delete-region beg end)
3066            (insert (expand-file-name completion directory)))
3067           (t
3068            (message "Making completion list...")
3069            (with-output-to-temp-buffer "*Completions*"
3070              (display-completion-list
3071               (sort (file-name-all-completions name-part directory)
3072                     'string<)
3073               name-part))
3074            (message "Making completion list...%s" "done")))))
3075
3076 (defun widget-file-prompt-value (widget prompt value unbound)
3077   ;; Read file from minibuffer.
3078   (abbreviate-file-name
3079    (if unbound
3080        (read-file-name prompt)
3081      (let ((prompt2 (format "%s (default %s): " prompt value))
3082            (dir (file-name-directory value))
3083            (file (file-name-nondirectory value))
3084            (must-match (widget-get widget :must-match)))
3085        (read-file-name prompt2 dir nil must-match file)))))
3086
3087 ;;;(defun widget-file-action (widget &optional event)
3088 ;;;  ;; Read a file name from the minibuffer.
3089 ;;;  (let* ((value (widget-value widget))
3090 ;;;      (dir (file-name-directory value))
3091 ;;;      (file (file-name-nondirectory value))
3092 ;;;      (menu-tag (widget-apply widget :menu-tag-get))
3093 ;;;      (must-match (widget-get widget :must-match))
3094 ;;;      (answer (read-file-name (concat menu-tag " (default " value "): ")
3095 ;;;                              dir nil must-match file)))
3096 ;;;    (widget-value-set widget (abbreviate-file-name answer))
3097 ;;;    (widget-setup)
3098 ;;;    (widget-apply widget :notify widget event)))
3099
3100 ;; Fixme: use file-name-as-directory.
3101 (define-widget 'directory 'file
3102   "A directory widget.
3103 It reads a directory name from an editable text field."
3104   :tag "Directory")
3105
3106 (defvar widget-symbol-prompt-value-history nil
3107   "History of input to `widget-symbol-prompt-value'.")
3108
3109 (define-widget 'symbol 'editable-field
3110   "A Lisp symbol."
3111   :value nil
3112   :tag "Symbol"
3113   :format "%{%t%}: %v"
3114   :match (lambda (widget value) (symbolp value))
3115   :complete-function 'lisp-complete-symbol
3116   :prompt-internal 'widget-symbol-prompt-internal
3117   :prompt-match 'symbolp
3118   :prompt-history 'widget-symbol-prompt-value-history
3119   :value-to-internal (lambda (widget value)
3120                        (if (symbolp value)
3121                            (symbol-name value)
3122                          value))
3123   :value-to-external (lambda (widget value)
3124                        (if (stringp value)
3125                            (intern value)
3126                          value)))
3127
3128 (defun widget-symbol-prompt-internal (widget prompt initial history)
3129   ;; Read file from minibuffer.
3130   (let ((answer (completing-read prompt obarray
3131                                  (widget-get widget :prompt-match)
3132                                  nil initial history)))
3133     (if (and (stringp answer)
3134              (not (zerop (length answer))))
3135         answer
3136       (error "No value"))))
3137
3138 (defvar widget-function-prompt-value-history nil
3139   "History of input to `widget-function-prompt-value'.")
3140
3141 (define-widget 'function 'restricted-sexp
3142   "A Lisp function."
3143   :complete-function (lambda ()
3144                        (interactive)
3145                        (lisp-complete-symbol 'fboundp))
3146   :prompt-value 'widget-field-prompt-value
3147   :prompt-internal 'widget-symbol-prompt-internal
3148   :prompt-match 'fboundp
3149   :prompt-history 'widget-function-prompt-value-history
3150   :action 'widget-field-action
3151   :match-alternatives '(functionp)
3152   :validate (lambda (widget)
3153               (unless (functionp (widget-value widget))
3154                 (widget-put widget :error (format "Invalid function: %S"
3155                                                   (widget-value widget)))
3156                 widget))
3157   :value 'ignore
3158   :tag "Function")
3159
3160 (defvar widget-variable-prompt-value-history nil
3161   "History of input to `widget-variable-prompt-value'.")
3162
3163 (define-widget 'variable 'symbol
3164   "A Lisp variable."
3165   :prompt-match 'boundp
3166   :prompt-history 'widget-variable-prompt-value-history
3167   :complete-function (lambda ()
3168                        (interactive)
3169                        (lisp-complete-symbol 'boundp))
3170   :tag "Variable")
3171 \f
3172 (defvar widget-coding-system-prompt-value-history nil
3173   "History of input to `widget-coding-system-prompt-value'.")
3174
3175 (define-widget 'coding-system 'symbol
3176   "A MULE coding-system."
3177   :format "%{%t%}: %v"
3178   :tag "Coding system"
3179   :base-only nil
3180   :prompt-history 'widget-coding-system-prompt-value-history
3181   :prompt-value 'widget-coding-system-prompt-value
3182   :action 'widget-coding-system-action
3183   :complete-function (lambda ()
3184                        (interactive)
3185                        (lisp-complete-symbol 'coding-system-p))
3186   :validate (lambda (widget)
3187               (unless (coding-system-p (widget-value widget))
3188                 (widget-put widget :error (format "Invalid coding system: %S"
3189                                                   (widget-value widget)))
3190                 widget))
3191   :value 'undecided
3192   :prompt-match 'coding-system-p)
3193
3194 (defun widget-coding-system-prompt-value (widget prompt value unbound)
3195   "Read coding-system from minibuffer."
3196   (if (widget-get widget :base-only)
3197       (intern
3198        (completing-read (format "%s (default %s): " prompt value)
3199                         (mapcar #'list (coding-system-list t)) nil nil nil
3200                         coding-system-history))
3201       (read-coding-system (format "%s (default %s): " prompt value) value)))
3202
3203 (defun widget-coding-system-action (widget &optional event)
3204   (let ((answer
3205          (widget-coding-system-prompt-value
3206           widget
3207           (widget-apply widget :menu-tag-get)
3208           (widget-value widget)
3209           t)))
3210     (widget-value-set widget answer)
3211     (widget-apply widget :notify widget event)
3212     (widget-setup)))
3213 \f
3214 ;;; I'm not sure about what this is good for?  KFS.
3215 (defvar widget-key-sequence-prompt-value-history nil
3216   "History of input to `widget-key-sequence-prompt-value'.")
3217
3218 (defvar widget-key-sequence-default-value [ignore]
3219   "Default value for an empty key sequence.")
3220
3221 (defvar widget-key-sequence-map
3222   (let ((map (make-sparse-keymap)))
3223     (set-keymap-parent map widget-field-keymap)
3224     (define-key map [(control ?q)] 'widget-key-sequence-read-event)
3225     map))
3226
3227 (define-widget 'key-sequence 'restricted-sexp
3228   "A key sequence."
3229   :prompt-value 'widget-field-prompt-value
3230   :prompt-internal 'widget-symbol-prompt-internal
3231 ; :prompt-match 'fboundp   ;; What was this good for?  KFS
3232   :prompt-history 'widget-key-sequence-prompt-value-history
3233   :action 'widget-field-action
3234   :match-alternatives '(stringp vectorp)
3235   :format "%{%t%}: %v"
3236   :validate 'widget-key-sequence-validate
3237   :value-to-internal 'widget-key-sequence-value-to-internal
3238   :value-to-external 'widget-key-sequence-value-to-external
3239   :value widget-key-sequence-default-value
3240   :keymap widget-key-sequence-map
3241   :help-echo "C-q: insert KEY, EVENT, or CODE; RET: enter value"
3242   :tag "Key sequence")
3243
3244 (defun widget-key-sequence-read-event (ev)
3245   (interactive (list
3246                 (let ((inhibit-quit t) quit-flag)
3247                   (read-event "Insert KEY, EVENT, or CODE: "))))
3248   (let ((ev2 (and (memq 'down (event-modifiers ev))
3249                   (read-event)))
3250         (tr (and (keymapp function-key-map)
3251                  (lookup-key function-key-map (vector ev)))))
3252     (when (and (integerp ev)
3253                (or (and (<= ?0 ev) (< ev (+ ?0 (min 10 read-quoted-char-radix))))
3254                    (and (<= ?a (downcase ev))
3255                         (< (downcase ev) (+ ?a -10 (min 36 read-quoted-char-radix))))))
3256       (setq unread-command-events (cons ev unread-command-events)
3257             ev (read-quoted-char (format "Enter code (radix %d)" read-quoted-char-radix))
3258             tr nil)
3259       (if (and (integerp ev) (not (char-valid-p ev)))
3260           (insert (char-to-string ev))))  ;; throw invalid char error
3261     (setq ev (key-description (list ev)))
3262     (when (arrayp tr)
3263       (setq tr (key-description (list (aref tr 0))))
3264       (if (y-or-n-p (format "Key %s is translated to %s -- use %s? " ev tr tr))
3265           (setq ev tr ev2 nil)))
3266     (insert (if (= (char-before) ?\s)  "" " ") ev " ")
3267     (if ev2
3268         (insert (key-description (list ev2)) " "))))
3269
3270 (defun widget-key-sequence-validate (widget)
3271   (unless (or (stringp (widget-value widget))
3272               (vectorp (widget-value widget)))
3273     (widget-put widget :error (format "Invalid key sequence: %S"
3274                                       (widget-value widget)))
3275     widget))
3276
3277 (defun widget-key-sequence-value-to-internal (widget value)
3278   (if (widget-apply widget :match value)
3279       (if (equal value widget-key-sequence-default-value)
3280           ""
3281         (key-description value))
3282     value))
3283
3284 (defun widget-key-sequence-value-to-external (widget value)
3285   (if (stringp value)
3286       (if (string-match "\\`[[:space:]]*\\'" value)
3287           widget-key-sequence-default-value
3288         (read-kbd-macro value))
3289     value))
3290
3291 \f
3292 (define-widget 'sexp 'editable-field
3293   "An arbitrary Lisp expression."
3294   :tag "Lisp expression"
3295   :format "%{%t%}: %v"
3296   :value nil
3297   :validate 'widget-sexp-validate
3298   :match (lambda (widget value) t)
3299   :value-to-internal 'widget-sexp-value-to-internal
3300   :value-to-external (lambda (widget value) (read value))
3301   :prompt-history 'widget-sexp-prompt-value-history
3302   :prompt-value 'widget-sexp-prompt-value)
3303
3304 (defun widget-sexp-value-to-internal (widget value)
3305   ;; Use pp for printer representation.
3306   (let ((pp (if (symbolp value)
3307                 (prin1-to-string value)
3308               (pp-to-string value))))
3309     (while (string-match "\n\\'" pp)
3310       (setq pp (substring pp 0 -1)))
3311     (if (or (string-match "\n\\'" pp)
3312             (> (length pp) 40))
3313         (concat "\n" pp)
3314       pp)))
3315
3316 (defun widget-sexp-validate (widget)
3317   ;; Valid if we can read the string and there is no junk left after it.
3318   (with-temp-buffer
3319     (insert (widget-apply widget :value-get))
3320     (goto-char (point-min))
3321     (let (err)
3322       (condition-case data
3323           (progn
3324             ;; Avoid a confusing end-of-file error.
3325             (skip-syntax-forward "\\s-")
3326             (if (eobp)
3327                 (setq err "Empty sexp -- use `nil'?")
3328               (unless (widget-apply widget :match (read (current-buffer)))
3329                 (setq err (widget-get widget :type-error))))
3330             ;; Allow whitespace after expression.
3331             (skip-syntax-forward "\\s-")
3332             (if (and (not (eobp))
3333                      (not err))
3334                 (setq err (format "Junk at end of expression: %s"
3335                                   (buffer-substring (point)
3336                                                     (point-max))))))
3337         (end-of-file                    ; Avoid confusing error message.
3338          (setq err "Unbalanced sexp"))
3339         (error (setq err (error-message-string data))))
3340       (if (not err)
3341           nil
3342         (widget-put widget :error err)
3343         widget))))
3344
3345 (defvar widget-sexp-prompt-value-history nil
3346   "History of input to `widget-sexp-prompt-value'.")
3347
3348 (defun widget-sexp-prompt-value (widget prompt value unbound)
3349   ;; Read an arbitrary sexp.
3350   (let ((found (read-string prompt
3351                             (if unbound nil (cons (prin1-to-string value) 0))
3352                             (widget-get widget :prompt-history))))
3353     (let ((answer (read-from-string found)))
3354       (unless (= (cdr answer) (length found))
3355         (error "Junk at end of expression: %s"
3356                (substring found (cdr answer))))
3357       (car answer))))
3358
3359 (define-widget 'restricted-sexp 'sexp
3360   "A Lisp expression restricted to values that match.
3361 To use this type, you must define :match or :match-alternatives."
3362   :type-error "The specified value is not valid"
3363   :match 'widget-restricted-sexp-match
3364   :value-to-internal (lambda (widget value)
3365                        (if (widget-apply widget :match value)
3366                            (prin1-to-string value)
3367                          value)))
3368
3369 (defun widget-restricted-sexp-match (widget value)
3370   (let ((alternatives (widget-get widget :match-alternatives))
3371         matched)
3372     (while (and alternatives (not matched))
3373       (if (cond ((functionp (car alternatives))
3374                  (funcall (car alternatives) value))
3375                 ((and (consp (car alternatives))
3376                       (eq (car (car alternatives)) 'quote))
3377                  (eq value (nth 1 (car alternatives)))))
3378           (setq matched t))
3379       (setq alternatives (cdr alternatives)))
3380     matched))
3381 \f
3382 (define-widget 'integer 'restricted-sexp
3383   "An integer."
3384   :tag "Integer"
3385   :value 0
3386   :type-error "This field should contain an integer"
3387   :match-alternatives '(integerp))
3388
3389 (define-widget 'number 'restricted-sexp
3390   "A number (floating point or integer)."
3391   :tag "Number"
3392   :value 0.0
3393   :type-error "This field should contain a number (floating point or integer)"
3394   :match-alternatives '(numberp))
3395
3396 (define-widget 'float 'restricted-sexp
3397   "A floating point number."
3398   :tag "Floating point number"
3399   :value 0.0
3400   :type-error "This field should contain a floating point number"
3401   :match-alternatives '(floatp))
3402
3403 (define-widget 'character 'editable-field
3404   "A character."
3405   :tag "Character"
3406   :value 0
3407   :size 1
3408   :format "%{%t%}: %v\n"
3409   :valid-regexp "\\`.\\'"
3410   :error "This field should contain a single character"
3411   :value-to-internal (lambda (widget value)
3412                        (if (stringp value)
3413                            value
3414                          (char-to-string value)))
3415   :value-to-external (lambda (widget value)
3416                        (if (stringp value)
3417                            (aref value 0)
3418                          value))
3419   :match (lambda (widget value)
3420            (char-valid-p value)))
3421
3422 (define-widget 'list 'group
3423   "A Lisp list."
3424   :tag "List"
3425   :format "%{%t%}:\n%v")
3426
3427 (define-widget 'vector 'group
3428   "A Lisp vector."
3429   :tag "Vector"
3430   :format "%{%t%}:\n%v"
3431   :match 'widget-vector-match
3432   :value-to-internal (lambda (widget value) (append value nil))
3433   :value-to-external (lambda (widget value) (apply 'vector value)))
3434
3435 (defun widget-vector-match (widget value)
3436   (and (vectorp value)
3437        (widget-group-match widget
3438                            (widget-apply widget :value-to-internal value))))
3439
3440 (define-widget 'cons 'group
3441   "A cons-cell."
3442   :tag "Cons-cell"
3443   :format "%{%t%}:\n%v"
3444   :match 'widget-cons-match
3445   :value-to-internal (lambda (widget value)
3446                        (list (car value) (cdr value)))
3447   :value-to-external (lambda (widget value)
3448                        (apply 'cons value)))
3449
3450 (defun widget-cons-match (widget value)
3451   (and (consp value)
3452        (widget-group-match widget
3453                            (widget-apply widget :value-to-internal value))))
3454 \f
3455 ;;; The `lazy' Widget.
3456 ;;
3457 ;; Recursive datatypes.
3458
3459 (define-widget 'lazy 'default
3460   "Base widget for recursive datastructures.
3461
3462 The `lazy' widget will, when instantiated, contain a single inferior
3463 widget, of the widget type specified by the :type parameter.  The
3464 value of the `lazy' widget is the same as the value of the inferior
3465 widget.  When deriving a new widget from the 'lazy' widget, the :type
3466 parameter is allowed to refer to the widget currently being defined,
3467 thus allowing recursive datastructures to be described.
3468
3469 The :type parameter takes the same arguments as the defcustom
3470 parameter with the same name.
3471
3472 Most composite widgets, i.e. widgets containing other widgets, does
3473 not allow recursion.  That is, when you define a new widget type, none
3474 of the inferior widgets may be of the same type you are currently
3475 defining.
3476
3477 In Lisp, however, it is custom to define datastructures in terms of
3478 themselves.  A list, for example, is defined as either nil, or a cons
3479 cell whose cdr itself is a list.  The obvious way to translate this
3480 into a widget type would be
3481
3482   (define-widget 'my-list 'choice
3483     \"A list of sexps.\"
3484     :tag \"Sexp list\"
3485     :args '((const nil) (cons :value (nil) sexp my-list)))
3486
3487 Here we attempt to define my-list as a choice of either the constant
3488 nil, or a cons-cell containing a sexp and my-lisp.  This will not work
3489 because the `choice' widget does not allow recursion.
3490
3491 Using the `lazy' widget you can overcome this problem, as in this
3492 example:
3493
3494   (define-widget 'sexp-list 'lazy
3495     \"A list of sexps.\"
3496     :tag \"Sexp list\"
3497     :type '(choice (const nil) (cons :value (nil) sexp sexp-list)))"
3498   :format "%{%t%}: %v"
3499   ;; We don't convert :type because we want to allow recursive
3500   ;; datastructures.  This is slow, so we should not create speed
3501   ;; critical widgets by deriving from this.
3502   :convert-widget 'widget-value-convert-widget
3503   :value-create 'widget-type-value-create
3504   :value-get 'widget-child-value-get
3505   :value-inline 'widget-child-value-inline
3506   :default-get 'widget-type-default-get
3507   :match 'widget-type-match
3508   :validate 'widget-child-validate)
3509
3510 \f
3511 ;;; The `plist' Widget.
3512 ;;
3513 ;; Property lists.
3514
3515 (define-widget 'plist 'list
3516   "A property list."
3517   :key-type '(symbol :tag "Key")
3518   :value-type '(sexp :tag "Value")
3519   :convert-widget 'widget-plist-convert-widget
3520   :tag "Plist")
3521
3522 (defvar widget-plist-value-type)        ;Dynamic variable
3523
3524 (defun widget-plist-convert-widget (widget)
3525   ;; Handle `:options'.
3526   (let* ((options (widget-get widget :options))
3527          (widget-plist-value-type (widget-get widget :value-type))
3528          (other `(editable-list :inline t
3529                                 (group :inline t
3530                                        ,(widget-get widget :key-type)
3531                                        ,widget-plist-value-type)))
3532          (args (if options
3533                    (list `(checklist :inline t
3534                                      :greedy t
3535                                      ,@(mapcar 'widget-plist-convert-option
3536                                                options))
3537                          other)
3538                  (list other))))
3539     (widget-put widget :args args)
3540     widget))
3541
3542 (defun widget-plist-convert-option (option)
3543   ;; Convert a single plist option.
3544   (let (key-type value-type)
3545     (if (listp option)
3546         (let ((key (nth 0 option)))
3547           (setq value-type (nth 1 option))
3548           (if (listp key)
3549               (setq key-type key)
3550             (setq key-type `(const ,key))))
3551       (setq key-type `(const ,option)
3552             value-type widget-plist-value-type))
3553     `(group :format "Key: %v" :inline t ,key-type ,value-type)))
3554
3555
3556 ;;; The `alist' Widget.
3557 ;;
3558 ;; Association lists.
3559
3560 (define-widget 'alist 'list
3561   "An association list."
3562   :key-type '(sexp :tag "Key")
3563   :value-type '(sexp :tag "Value")
3564   :convert-widget 'widget-alist-convert-widget
3565   :tag "Alist")
3566
3567 (defvar widget-alist-value-type)        ;Dynamic variable
3568
3569 (defun widget-alist-convert-widget (widget)
3570   ;; Handle `:options'.
3571   (let* ((options (widget-get widget :options))
3572          (widget-alist-value-type (widget-get widget :value-type))
3573          (other `(editable-list :inline t
3574                                 (cons :format "%v"
3575                                       ,(widget-get widget :key-type)
3576                                       ,widget-alist-value-type)))
3577          (args (if options
3578                    (list `(checklist :inline t
3579                                      :greedy t
3580                                      ,@(mapcar 'widget-alist-convert-option
3581                                                options))
3582                          other)
3583                  (list other))))
3584     (widget-put widget :args args)
3585     widget))
3586
3587 (defun widget-alist-convert-option (option)
3588   ;; Convert a single alist option.
3589   (let (key-type value-type)
3590     (if (listp option)
3591         (let ((key (nth 0 option)))
3592           (setq value-type (nth 1 option))
3593           (if (listp key)
3594               (setq key-type key)
3595             (setq key-type `(const ,key))))
3596       (setq key-type `(const ,option)
3597             value-type widget-alist-value-type))
3598     `(cons :format "Key: %v" ,key-type ,value-type)))
3599 \f
3600 (define-widget 'choice 'menu-choice
3601   "A union of several sexp types."
3602   :tag "Choice"
3603   :format "%{%t%}: %[Value Menu%] %v"
3604   :button-prefix 'widget-push-button-prefix
3605   :button-suffix 'widget-push-button-suffix
3606   :prompt-value 'widget-choice-prompt-value)
3607
3608 (defun widget-choice-prompt-value (widget prompt value unbound)
3609   "Make a choice."
3610   (let ((args (widget-get widget :args))
3611         (completion-ignore-case (widget-get widget :case-fold))
3612         current choices old)
3613     ;; Find the first arg that matches VALUE.
3614     (let ((look args))
3615       (while look
3616         (if (widget-apply (car look) :match value)
3617             (setq old (car look)
3618                   look nil)
3619           (setq look (cdr look)))))
3620     ;; Find new choice.
3621     (setq current
3622           (cond ((= (length args) 0)
3623                  nil)
3624                 ((= (length args) 1)
3625                  (nth 0 args))
3626                 ((and (= (length args) 2)
3627                       (memq old args))
3628                  (if (eq old (nth 0 args))
3629                      (nth 1 args)
3630                    (nth 0 args)))
3631                 (t
3632                  (while args
3633                    (setq current (car args)
3634                          args (cdr args))
3635                    (setq choices
3636                          (cons (cons (widget-apply current :menu-tag-get)
3637                                      current)
3638                                choices)))
3639                  (let ((val (completing-read prompt choices nil t)))
3640                    (if (stringp val)
3641                        (let ((try (try-completion val choices)))
3642                          (when (stringp try)
3643                            (setq val try))
3644                          (cdr (assoc val choices)))
3645                      nil)))))
3646     (if current
3647         (widget-prompt-value current prompt nil t)
3648       value)))
3649 \f
3650 (define-widget 'radio 'radio-button-choice
3651   "A union of several sexp types."
3652   :tag "Choice"
3653   :format "%{%t%}:\n%v"
3654   :prompt-value 'widget-choice-prompt-value)
3655
3656 (define-widget 'repeat 'editable-list
3657   "A variable length homogeneous list."
3658   :tag "Repeat"
3659   :format "%{%t%}:\n%v%i\n")
3660
3661 (define-widget 'set 'checklist
3662   "A list of members from a fixed set."
3663   :tag "Set"
3664   :format "%{%t%}:\n%v")
3665
3666 (define-widget 'boolean 'toggle
3667   "To be nil or non-nil, that is the question."
3668   :tag "Boolean"
3669   :prompt-value 'widget-boolean-prompt-value
3670   :button-prefix 'widget-push-button-prefix
3671   :button-suffix 'widget-push-button-suffix
3672   :format "%{%t%}: %[Toggle%]  %v\n"
3673   :on "on (non-nil)"
3674   :off "off (nil)")
3675
3676 (defun widget-boolean-prompt-value (widget prompt value unbound)
3677   ;; Toggle a boolean.
3678   (y-or-n-p prompt))
3679 \f
3680 ;;; The `color' Widget.
3681
3682 ;; Fixme: match
3683 (define-widget 'color 'editable-field
3684   "Choose a color name (with sample)."
3685   :format "%{%t%}: %v (%{sample%})\n"
3686   :size 10
3687   :tag "Color"
3688   :value "black"
3689   :complete 'widget-color-complete
3690   :sample-face-get 'widget-color-sample-face-get
3691   :notify 'widget-color-notify
3692   :action 'widget-color-action)
3693
3694 (defun widget-color-complete (widget)
3695   "Complete the color in WIDGET."
3696   (require 'facemenu)                   ; for facemenu-color-alist
3697   (let* ((prefix (buffer-substring-no-properties (widget-field-start widget)
3698                                                  (point)))
3699          (list (or facemenu-color-alist (defined-colors)))
3700          (completion (try-completion prefix list)))
3701     (cond ((eq completion t)
3702            (message "Exact match."))
3703           ((null completion)
3704            (error "Can't find completion for \"%s\"" prefix))
3705           ((not (string-equal prefix completion))
3706            (insert-and-inherit (substring completion (length prefix))))
3707           (t
3708            (message "Making completion list...")
3709            (with-output-to-temp-buffer "*Completions*"
3710              (display-completion-list (all-completions prefix list nil)
3711                                       prefix))
3712            (message "Making completion list...done")))))
3713
3714 (defun widget-color-sample-face-get (widget)
3715   (let* ((value (condition-case nil
3716                     (widget-value widget)
3717                   (error (widget-get widget :value)))))
3718     (if (color-defined-p value)
3719         (list (cons 'foreground-color value))
3720       'default)))
3721
3722 (defun widget-color-action (widget &optional event)
3723   "Prompt for a color."
3724   (let* ((tag (widget-apply widget :menu-tag-get))
3725          (prompt (concat tag ": "))
3726          (value (widget-value widget))
3727          (start (widget-field-start widget))
3728          (answer (facemenu-read-color prompt)))
3729     (unless (zerop (length answer))
3730       (widget-value-set widget answer)
3731       (widget-setup)
3732       (widget-apply widget :notify widget event))))
3733
3734 (defun widget-color-notify (widget child &optional event)
3735   "Update the sample, and notify the parent."
3736   (overlay-put (widget-get widget :sample-overlay)
3737                'face (widget-apply widget :sample-face-get))
3738   (widget-default-notify widget child event))
3739 \f
3740 ;;; The Help Echo
3741
3742 (defun widget-echo-help (pos)
3743   "Display help-echo text for widget at POS."
3744   (let* ((widget (widget-at pos))
3745          (help-echo (and widget (widget-get widget :help-echo))))
3746     (if (functionp help-echo)
3747         (setq help-echo (funcall help-echo widget)))
3748     (if help-echo (message "%s" (eval help-echo)))))
3749
3750 ;;; The End:
3751
3752 (provide 'wid-edit)
3753
3754 ;;; arch-tag: a076e75e-18a1-4b46-8be5-3f317bcbc707
3755 ;;; wid-edit.el ends here