lisp/gnus/gnus-int.el

   1 ;;; gnus-int.el --- backend interface functions for Gnus
   2
   3 ;; Copyright (C) 1996-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl))
  28
  29 (require 'gnus)
  30 (require 'message)
  31 (require 'gnus-range)
  32
  33 (autoload 'gnus-run-hook-with-args "gnus-util")
  34 (autoload 'gnus-agent-expire "gnus-agent")
  35 (autoload 'gnus-agent-regenerate-group "gnus-agent")
  36 (autoload 'gnus-agent-read-servers-validate-native "gnus-agent")
  37 (autoload 'gnus-agent-possibly-synchronize-flags-server "gnus-agent")
  38
  39 (defcustom gnus-open-server-hook nil
  40   "Hook called just before opening connection to the news server."
  41   :group 'gnus-start
  42   :type 'hook)
  43
  44 (defcustom gnus-after-set-mark-hook nil
  45   "Hook called just after marks are set in a group."
  46   :version "24.1"
  47   :group 'gnus-start
  48   :type 'hook)
  49
  50 (defcustom gnus-before-update-mark-hook nil
  51   "Hook called just before marks are updated in a group."
  52   :version "24.1"
  53   :group 'gnus-start
  54   :type 'hook)
  55
  56 (defcustom gnus-server-unopen-status nil
  57   "The default status if the server is not able to open.
  58 If the server is covered by Gnus agent, the possible values are
  59 `denied', set the server denied; `offline', set the server offline;
  60 nil, ask user.  If the server is not covered by Gnus agent, set the
  61 server denied."
  62   :version "22.1"
  63   :group 'gnus-start
  64   :type '(choice (const :tag "Ask" nil)
  65                  (const :tag "Deny server" denied)
  66                  (const :tag "Unplug Agent" offline)))
  67
  68 (defcustom gnus-nntp-server nil
  69   "The name of the host running the NNTP server."
  70   :group 'gnus-server
  71   :type '(choice (const :tag "disable" nil)
  72                  string))
  73 (make-obsolete-variable 'gnus-nntp-server 'gnus-select-method "24.1")
  74
  75 (defvar gnus-internal-registry-spool-current-method nil
  76   "The current method, for the registry.")
  77
  78
  79 (defun gnus-server-opened (gnus-command-method)
  80   "Check whether a connection to GNUS-COMMAND-METHOD has been opened."
  81   (unless (eq (gnus-server-status gnus-command-method)
  82               'denied)
  83     (when (stringp gnus-command-method)
  84       (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
  85     (funcall (inline (gnus-get-function gnus-command-method 'server-opened))
  86              (nth 1 gnus-command-method))))
  87
  88 (defun gnus-status-message (gnus-command-method)
  89   "Return the status message from GNUS-COMMAND-METHOD.
  90 If GNUS-COMMAND-METHOD is a string, it is interpreted as a group
  91 name.  The method this group uses will be queried."
  92   (let ((gnus-command-method
  93          (if (stringp gnus-command-method)
  94              (gnus-find-method-for-group gnus-command-method)
  95            gnus-command-method)))
  96     (funcall (gnus-get-function gnus-command-method 'status-message)
  97              (nth 1 gnus-command-method))))
  98
  99 ;;;
 100 ;;; Server Communication
 101 ;;;
 102
 103 (defun gnus-start-news-server (&optional confirm)
 104   "Open a method for getting news.
 105 If CONFIRM is non-nil, the user will be asked for an NNTP server."
 106   (let (how)
 107     (if gnus-current-select-method
 108         ;; Stream is already opened.
 109         nil
 110       ;; Open NNTP server.
 111       (when confirm
 112         ;; Read server name with completion.
 113         (setq gnus-nntp-server
 114               (gnus-completing-read "NNTP server"
 115                                     (cons gnus-nntp-server
 116                                           gnus-secondary-servers)
 117                                     nil gnus-nntp-server)))
 118
 119       (when (and gnus-nntp-server
 120                  (stringp gnus-nntp-server)
 121                  (not (string= gnus-nntp-server "")))
 122         (setq gnus-select-method
 123               (cond ((or (string= gnus-nntp-server "")
 124                          (string= gnus-nntp-server "::"))
 125                      (list 'nnspool (system-name)))
 126                     ((string-match "^:" gnus-nntp-server)
 127                      (list 'nnmh gnus-nntp-server
 128                            (list 'nnmh-directory
 129                                  (file-name-as-directory
 130                                   (expand-file-name
 131                                    (substring gnus-nntp-server 1) "~/")))
 132                            (list 'nnmh-get-new-mail nil)))
 133                     (t
 134                      (list 'nntp gnus-nntp-server)))))
 135
 136       (setq how (car gnus-select-method))
 137       (cond
 138        ((eq how 'nnspool)
 139         (require 'nnspool)
 140         (gnus-message 5 "Looking up local news spool..."))
 141        ((eq how 'nnmh)
 142         (require 'nnmh)
 143         (gnus-message 5 "Looking up mh spool..."))
 144        (t
 145         (require 'nntp)))
 146       (setq gnus-current-select-method gnus-select-method)
 147       (gnus-run-hooks 'gnus-open-server-hook)
 148
 149       ;; Partially validate agent covered methods now that the
 150       ;; gnus-select-method is known.
 151
 152       (if gnus-agent
 153           ;; NOTE: This is here for one purpose only.  By validating
 154           ;; the current select method, it converts the old 5.10.3,
 155           ;; and earlier, format to the current format.  That enables
 156           ;; the agent code within gnus-open-server to function
 157           ;; correctly.
 158           (gnus-agent-read-servers-validate-native gnus-select-method))
 159
 160       (or
 161        ;; gnus-open-server-hook might have opened it
 162        (gnus-server-opened gnus-select-method)
 163        (gnus-open-server gnus-select-method)
 164        gnus-batch-mode
 165        (gnus-y-or-n-p
 166         (format
 167          "%s (%s) open error: '%s'.  Continue? "
 168          (car gnus-select-method) (cadr gnus-select-method)
 169          (gnus-status-message gnus-select-method)))
 170        (gnus-error 1 "Couldn't open server on %s"
 171                    (nth 1 gnus-select-method))))))
 172
 173 (defun gnus-check-group (group)
 174   "Try to make sure that the server where GROUP exists is alive."
 175   (let ((method (gnus-find-method-for-group group)))
 176     (or (gnus-server-opened method)
 177         (gnus-open-server method))))
 178
 179 (defun gnus-check-server (&optional method silent)
 180   "Check whether the connection to METHOD is down.
 181 If METHOD is nil, use `gnus-select-method'.
 182 If it is down, start it up (again)."
 183   (let ((method (or method gnus-select-method))
 184         result)
 185     ;; Transform virtual server names into select methods.
 186     (when (stringp method)
 187       (setq method (gnus-server-to-method method)))
 188     (if (gnus-server-opened method)
 189         ;; The stream is already opened.
 190         t
 191       ;; Open the server.
 192       (unless silent
 193         (gnus-message 5 "Opening %s server%s..." (car method)
 194                       (if (equal (nth 1 method) "") ""
 195                         (format " on %s" (nth 1 method)))))
 196       (gnus-run-hooks 'gnus-open-server-hook)
 197       (prog1
 198           (setq result (gnus-open-server method))
 199         (unless silent
 200           (gnus-message
 201            (if result 5 3)
 202            "Opening %s server%s...%s" (car method)
 203            (if (equal (nth 1 method) "") ""
 204              (format " on %s" (nth 1 method)))
 205            (if result
 206                "done"
 207              (format "failed: %s"
 208                      (nnheader-get-report-string (car method))))))))))
 209
 210 (defun gnus-get-function (method function &optional noerror)
 211   "Return a function symbol based on METHOD and FUNCTION."
 212   ;; Translate server names into methods.
 213   (unless method
 214     (error "Attempted use of a nil select method"))
 215   (when (stringp method)
 216     (setq method (gnus-server-to-method method)))
 217   ;; Check cache of constructed names.
 218   (let* ((method-sym (if gnus-agent
 219                          (inline (gnus-agent-get-function method))
 220                        (car method)))
 221          (method-fns (get method-sym 'gnus-method-functions))
 222          (func (let ((method-fnlist-elt (assq function method-fns)))
 223                  (unless method-fnlist-elt
 224                    (setq method-fnlist-elt
 225                          (cons function
 226                                (intern (format "%s-%s" method-sym function))))
 227                    (put method-sym 'gnus-method-functions
 228                         (cons method-fnlist-elt method-fns)))
 229                  (cdr method-fnlist-elt))))
 230     ;; Maybe complain if there is no function.
 231     (unless (fboundp func)
 232       (unless (car method)
 233         (error "Trying to require a method that doesn't exist"))
 234       (require (car method))
 235       (when (not (fboundp func))
 236         (if noerror
 237             (setq func nil)
 238           (error "No such function: %s" func))))
 239     func))
 240
 241 \f
 242 ;;;
 243 ;;; Interface functions to the backends.
 244 ;;;
 245
 246 (defun gnus-method-denied-p (method)
 247   (eq (nth 1 (assoc method gnus-opened-servers))
 248       'denied))
 249
 250 (defvar gnus-backend-trace nil)
 251
 252 (defun gnus-open-server (gnus-command-method)
 253   "Open a connection to GNUS-COMMAND-METHOD."
 254   (when (stringp gnus-command-method)
 255     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 256   (when gnus-backend-trace
 257     (with-current-buffer (get-buffer-create "*gnus trace*")
 258       (buffer-disable-undo)
 259       (goto-char (point-max))
 260       (insert (format-time-string "%H:%M:%S")
 261               (format " %S\n" gnus-command-method))))
 262   (let ((elem (assoc gnus-command-method gnus-opened-servers))
 263         (server (gnus-method-to-server-name gnus-command-method)))
 264     ;; If this method was previously denied, we just return nil.
 265     (if (eq (nth 1 elem) 'denied)
 266         (progn
 267           (gnus-message
 268            1 "Server %s previously determined to be down; not retrying" server)
 269           nil)
 270       ;; Open the server.
 271       (let* ((open-server-function
 272               (gnus-get-function gnus-command-method 'open-server))
 273              (result
 274               (condition-case err
 275                   (funcall open-server-function
 276                            (nth 1 gnus-command-method)
 277                            (nthcdr 2 gnus-command-method))
 278                 (error
 279                  (gnus-message 1 "Unable to open server %s due to: %s"
 280                                server (error-message-string err))
 281                  nil)
 282                 (quit
 283                  (if debug-on-quit
 284                      (debug "Quit")
 285                    (gnus-message 1 "Quit trying to open server %s" server))
 286                  nil)))
 287              open-offline)
 288         ;; If this hasn't been opened before, we add it to the list.
 289         (unless elem
 290           (setq elem (list gnus-command-method nil)
 291                 gnus-opened-servers (cons elem gnus-opened-servers)))
 292         ;; Set the status of this server.
 293         (setcar
 294          (cdr elem)
 295          (cond (result
 296                 (if (eq open-server-function #'nnagent-open-server)
 297                     ;; The agent's backend has a "special" status
 298                     'offline
 299                   'ok))
 300                ((and gnus-agent
 301                      (gnus-agent-method-p gnus-command-method))
 302                 (cond
 303                  (gnus-server-unopen-status
 304                   ;; Set the server's status to the unopen
 305                   ;; status.  If that status is offline,
 306                   ;; recurse to open the agent's backend.
 307                   (setq open-offline (eq gnus-server-unopen-status 'offline))
 308                   gnus-server-unopen-status)
 309                  ((not gnus-batch-mode)
 310                   (setq open-offline t)
 311                   'offline)
 312                  (t
 313                   ;; This agentized server was still denied
 314                   'denied)))
 315                (t
 316                 ;; This unagentized server must be denied
 317                 'denied)))
 318
 319         ;; NOTE: I MUST set the server's status to offline before this
 320         ;; recursive call as this status will drive the
 321         ;; gnus-get-function (called above) to return the agent's
 322         ;; backend.
 323         (if open-offline
 324             ;; Recursively open this offline server to perform the
 325             ;; open-server function of the agent's backend.
 326             (let ((gnus-server-unopen-status 'denied))
 327               ;; Bind gnus-server-unopen-status to avoid recursively
 328               ;; prompting with "go offline?".  This is only a concern
 329               ;; when the agent's backend fails to open the server.
 330               (gnus-open-server gnus-command-method))
 331           (when (and (eq (cadr elem) 'ok) gnus-agent
 332                      (gnus-agent-method-p gnus-command-method))
 333             (save-excursion
 334               (gnus-agent-possibly-synchronize-flags-server
 335                gnus-command-method)))
 336           result)))))
 337
 338 (defun gnus-close-server (gnus-command-method)
 339   "Close the connection to GNUS-COMMAND-METHOD."
 340   (when (stringp gnus-command-method)
 341     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 342   (funcall (gnus-get-function gnus-command-method 'close-server)
 343            (nth 1 gnus-command-method)))
 344
 345 (defun gnus-request-list (gnus-command-method)
 346   "Request the active file from GNUS-COMMAND-METHOD."
 347   (when (stringp gnus-command-method)
 348     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 349   (funcall (gnus-get-function gnus-command-method 'request-list)
 350            (nth 1 gnus-command-method)))
 351
 352 (defun gnus-finish-retrieve-group-infos (gnus-command-method infos data)
 353   "Read and update infos from GNUS-COMMAND-METHOD."
 354   (when (stringp gnus-command-method)
 355     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 356   (funcall (gnus-get-function gnus-command-method 'finish-retrieve-group-infos)
 357            (nth 1 gnus-command-method)
 358            infos data))
 359
 360 (defun gnus-retrieve-group-data-early (gnus-command-method infos)
 361   "Start early async retrieval of data from GNUS-COMMAND-METHOD."
 362   (when (stringp gnus-command-method)
 363     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 364   (funcall (gnus-get-function gnus-command-method 'retrieve-group-data-early)
 365            (nth 1 gnus-command-method)
 366            infos))
 367
 368 (defun gnus-request-list-newsgroups (gnus-command-method)
 369   "Request the newsgroups file from GNUS-COMMAND-METHOD."
 370   (when (stringp gnus-command-method)
 371     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 372   (funcall (gnus-get-function gnus-command-method 'request-list-newsgroups)
 373            (nth 1 gnus-command-method)))
 374
 375 (defun gnus-request-newgroups (date gnus-command-method)
 376   "Request all new groups since DATE from GNUS-COMMAND-METHOD."
 377   (when (stringp gnus-command-method)
 378     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 379   (let ((func (gnus-get-function gnus-command-method 'request-newgroups t)))
 380     (when func
 381       (funcall func date (nth 1 gnus-command-method)))))
 382
 383 (defun gnus-request-regenerate (gnus-command-method)
 384   "Request a data generation from GNUS-COMMAND-METHOD."
 385   (when (stringp gnus-command-method)
 386     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 387   (funcall (gnus-get-function gnus-command-method 'request-regenerate)
 388            (nth 1 gnus-command-method)))
 389
 390 (defun gnus-request-compact-group (group)
 391   (let* ((method (gnus-find-method-for-group group))
 392          (gnus-command-method method)
 393          (result
 394           (funcall (gnus-get-function gnus-command-method
 395                                       'request-compact-group)
 396                    (gnus-group-real-name group)
 397                    (nth 1 gnus-command-method) t)))
 398     result))
 399
 400 (defun gnus-request-compact (gnus-command-method)
 401   "Request groups compaction from GNUS-COMMAND-METHOD."
 402   (when (stringp gnus-command-method)
 403     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 404   (funcall (gnus-get-function gnus-command-method 'request-compact)
 405            (nth 1 gnus-command-method)))
 406
 407 (defun gnus-request-group (group &optional dont-check gnus-command-method info)
 408   "Request GROUP.  If DONT-CHECK, no information is required."
 409   (let ((gnus-command-method
 410          (or gnus-command-method (inline (gnus-find-method-for-group group)))))
 411     (when (stringp gnus-command-method)
 412       (setq gnus-command-method
 413             (inline (gnus-server-to-method gnus-command-method))))
 414     (funcall (inline (gnus-get-function gnus-command-method 'request-group))
 415              (gnus-group-real-name group) (nth 1 gnus-command-method)
 416              dont-check
 417              info)))
 418
 419 (defun gnus-list-active-group (group)
 420   "Request active information on GROUP."
 421   (let ((gnus-command-method (gnus-find-method-for-group group))
 422         (func 'list-active-group))
 423     (when (gnus-check-backend-function func group)
 424       (funcall (gnus-get-function gnus-command-method func)
 425                (gnus-group-real-name group) (nth 1 gnus-command-method)))))
 426
 427 (defun gnus-request-group-description (group)
 428   "Request a description of GROUP."
 429   (let ((gnus-command-method (gnus-find-method-for-group group))
 430         (func 'request-group-description))
 431     (when (gnus-check-backend-function func group)
 432       (funcall (gnus-get-function gnus-command-method func)
 433                (gnus-group-real-name group) (nth 1 gnus-command-method)))))
 434
 435 (defun gnus-request-group-articles (group)
 436   "Request a list of existing articles in GROUP."
 437   (let ((gnus-command-method (gnus-find-method-for-group group))
 438         (func 'request-group-articles))
 439     (when (gnus-check-backend-function func group)
 440       (funcall (gnus-get-function gnus-command-method func)
 441                (gnus-group-real-name group) (nth 1 gnus-command-method)))))
 442
 443 (defun gnus-close-group (group)
 444   "Request the GROUP be closed."
 445   (let ((gnus-command-method (inline (gnus-find-method-for-group group))))
 446     (funcall (gnus-get-function gnus-command-method 'close-group)
 447              (gnus-group-real-name group) (nth 1 gnus-command-method))))
 448
 449 (defun gnus-retrieve-headers (articles group &optional fetch-old)
 450   "Request headers for ARTICLES in GROUP.
 451 If FETCH-OLD, retrieve all headers (or some subset thereof) in the group."
 452   (let ((gnus-command-method (gnus-find-method-for-group group)))
 453     (cond
 454      ((and gnus-use-cache (numberp (car articles)))
 455       (gnus-cache-retrieve-headers articles group fetch-old))
 456      ((and gnus-agent (gnus-online gnus-command-method)
 457            (gnus-agent-method-p gnus-command-method))
 458       (gnus-agent-retrieve-headers articles group fetch-old))
 459      (t
 460       (funcall (gnus-get-function gnus-command-method 'retrieve-headers)
 461                articles (gnus-group-real-name group)
 462                (nth 1 gnus-command-method) fetch-old)))))
 463
 464 (defun gnus-retrieve-articles (articles group)
 465   "Request ARTICLES in GROUP."
 466   (let ((gnus-command-method (gnus-find-method-for-group group)))
 467     (funcall (gnus-get-function gnus-command-method 'retrieve-articles)
 468              articles (gnus-group-real-name group)
 469              (nth 1 gnus-command-method))))
 470
 471 (defun gnus-retrieve-groups (groups gnus-command-method)
 472   "Request active information on GROUPS from GNUS-COMMAND-METHOD."
 473   (when (stringp gnus-command-method)
 474     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 475   (funcall (gnus-get-function gnus-command-method 'retrieve-groups)
 476            groups (nth 1 gnus-command-method)))
 477
 478 (defun gnus-request-type (group &optional article)
 479   "Return the type (`post' or `mail') of GROUP (and ARTICLE)."
 480   (let ((gnus-command-method (gnus-find-method-for-group group)))
 481     (if (not (gnus-check-backend-function
 482               'request-type (car gnus-command-method)))
 483         'unknown
 484       (funcall (gnus-get-function gnus-command-method 'request-type)
 485                (gnus-group-real-name group) article))))
 486
 487 (defun gnus-request-update-group-status (group status)
 488   "Change the status of a group.
 489 Valid statuses include `subscribe' and `unsubscribe'."
 490   (let ((gnus-command-method (gnus-find-method-for-group group)))
 491     (if (not (gnus-check-backend-function
 492               'request-update-group-status (car gnus-command-method)))
 493         nil
 494       (funcall
 495        (gnus-get-function gnus-command-method 'request-update-group-status)
 496        (gnus-group-real-name group) status
 497        (nth 1 gnus-command-method)))))
 498
 499 (defun gnus-request-set-mark (group action)
 500   "Set marks on articles in the back end."
 501   (let ((gnus-command-method (gnus-find-method-for-group group)))
 502     (if (not (gnus-check-backend-function
 503               'request-set-mark (car gnus-command-method)))
 504         action
 505       (funcall (gnus-get-function gnus-command-method 'request-set-mark)
 506                (gnus-group-real-name group) action
 507                (nth 1 gnus-command-method))
 508       (gnus-run-hook-with-args gnus-after-set-mark-hook group action))))
 509
 510 (defun gnus-request-update-mark (group article mark)
 511   "Allow the back end to change the mark the user tries to put on an article."
 512   (let ((gnus-command-method (gnus-find-method-for-group group)))
 513     (if (not (gnus-check-backend-function
 514               'request-update-mark (car gnus-command-method)))
 515         mark
 516       (gnus-run-hook-with-args gnus-before-update-mark-hook group article mark)
 517       (funcall (gnus-get-function gnus-command-method 'request-update-mark)
 518                (gnus-group-real-name group) article mark))))
 519
 520 (defun gnus-request-article (article group &optional buffer)
 521   "Request the ARTICLE in GROUP.
 522 ARTICLE can either be an article number or an article Message-ID.
 523 If BUFFER, insert the article in that group."
 524   (let ((gnus-command-method (gnus-find-method-for-group group)))
 525     (funcall (gnus-get-function gnus-command-method 'request-article)
 526              article (gnus-group-real-name group)
 527              (nth 1 gnus-command-method) buffer)))
 528
 529 (defun gnus-request-thread (header group)
 530   "Request the headers in the thread containing the article specified by HEADER."
 531   (let ((gnus-command-method (gnus-find-method-for-group group)))
 532     (funcall (gnus-get-function gnus-command-method 'request-thread)
 533              header
 534              (gnus-group-real-name group))))
 535
 536 (defun gnus-warp-to-article ()
 537   "Warps from an article in a virtual group to the article in its
 538 real group. Does nothing on a real group."
 539   (interactive)
 540   (when (gnus-virtual-group-p gnus-newsgroup-name)
 541     (let ((gnus-command-method
 542            (gnus-find-method-for-group gnus-newsgroup-name)))
 543       (when (gnus-check-backend-function
 544              'warp-to-article (car gnus-command-method))
 545         (funcall (gnus-get-function gnus-command-method 'warp-to-article))))))
 546
 547 (defun gnus-request-head (article group)
 548   "Request the head of ARTICLE in GROUP."
 549   (let* ((gnus-command-method (gnus-find-method-for-group group))
 550          (head (gnus-get-function gnus-command-method 'request-head t))
 551          res clean-up)
 552     (cond
 553      ;; Check the cache.
 554      ((and gnus-use-cache
 555            (numberp article)
 556            (gnus-cache-request-article article group))
 557       (setq res (cons group article)
 558             clean-up t))
 559      ;; Check the agent cache.
 560      ((gnus-agent-request-article article group)
 561       (setq res (cons group article)
 562             clean-up t))
 563      ;; Use `head' function.
 564      ((fboundp head)
 565       (setq res (funcall head article (gnus-group-real-name group)
 566                          (nth 1 gnus-command-method))))
 567      ;; Use `article' function.
 568      (t
 569       (setq res (gnus-request-article article group)
 570             clean-up t)))
 571     (when clean-up
 572       (with-current-buffer nntp-server-buffer
 573         (goto-char (point-min))
 574         (when (search-forward "\n\n" nil t)
 575           (delete-region (1- (point)) (point-max)))
 576         (nnheader-fold-continuation-lines)))
 577     res))
 578
 579 (defun gnus-request-body (article group)
 580   "Request the body of ARTICLE in GROUP."
 581   (let* ((gnus-command-method (gnus-find-method-for-group group))
 582          (head (gnus-get-function gnus-command-method 'request-body t))
 583          res clean-up)
 584     (cond
 585      ;; Check the cache.
 586      ((and gnus-use-cache
 587            (numberp article)
 588            (gnus-cache-request-article article group))
 589       (setq res (cons group article)
 590             clean-up t))
 591      ;; Check the agent cache.
 592      ((gnus-agent-request-article article group)
 593       (setq res (cons group article)
 594             clean-up t))
 595      ;; Use `head' function.
 596      ((fboundp head)
 597       (setq res (funcall head article (gnus-group-real-name group)
 598                          (nth 1 gnus-command-method))))
 599      ;; Use `article' function.
 600      (t
 601       (setq res (gnus-request-article article group)
 602             clean-up t)))
 603     (when clean-up
 604       (with-current-buffer nntp-server-buffer
 605         (goto-char (point-min))
 606         (when (search-forward "\n\n" nil t)
 607           (delete-region (point-min) (1- (point))))))
 608     res))
 609
 610 (defun gnus-request-post (gnus-command-method)
 611   "Post the current buffer using GNUS-COMMAND-METHOD."
 612   (when (stringp gnus-command-method)
 613     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 614   (funcall (gnus-get-function gnus-command-method 'request-post)
 615            (nth 1 gnus-command-method)))
 616
 617 (defun gnus-request-expunge-group (group gnus-command-method)
 618   "Expunge GROUP, which is removing articles that have been marked as deleted."
 619   (when (stringp gnus-command-method)
 620     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 621   (funcall (gnus-get-function gnus-command-method 'request-expunge-group)
 622            (gnus-group-real-name group)
 623            (nth 1 gnus-command-method)))
 624
 625 (defun gnus-request-scan (group gnus-command-method)
 626   "Request a SCAN being performed in GROUP from GNUS-COMMAND-METHOD.
 627 If GROUP is nil, all groups on GNUS-COMMAND-METHOD are scanned."
 628   (let ((gnus-command-method
 629          (if group (gnus-find-method-for-group group) gnus-command-method))
 630         (gnus-inhibit-demon t)
 631         (mail-source-plugged gnus-plugged))
 632     (when (or gnus-plugged
 633               (not (gnus-agent-method-p gnus-command-method)))
 634       (setq gnus-internal-registry-spool-current-method gnus-command-method)
 635       (funcall (gnus-get-function gnus-command-method 'request-scan)
 636                (and group (gnus-group-real-name group))
 637                (nth 1 gnus-command-method)))))
 638
 639 (defun gnus-request-update-info (info gnus-command-method)
 640   (when (gnus-check-backend-function
 641          'request-update-info (car gnus-command-method))
 642     (when (stringp gnus-command-method)
 643       (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 644     (funcall (gnus-get-function gnus-command-method 'request-update-info)
 645              (gnus-group-real-name (gnus-info-group info)) info
 646              (nth 1 gnus-command-method))))
 647
 648 (defsubst gnus-request-marks (info gnus-command-method)
 649   "Request that GNUS-COMMAND-METHOD update INFO."
 650   (when (stringp gnus-command-method)
 651     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 652   (when (gnus-check-backend-function
 653          'request-marks (car gnus-command-method))
 654     (let ((group (gnus-info-group info)))
 655       (and (funcall (gnus-get-function gnus-command-method 'request-marks)
 656                     (gnus-group-real-name group)
 657                     info (nth 1 gnus-command-method))
 658            ;; If the minimum article number is greater than 1, then all
 659            ;; smaller article numbers are known not to exist; we'll
 660            ;; artificially add those to the 'read range.
 661            (let* ((active (gnus-active group))
 662                   (min (car active)))
 663              (when (> min 1)
 664                (let* ((range (if (= min 2) 1 (cons 1 (1- min))))
 665                       (read (gnus-info-read info))
 666                       (new-read (gnus-range-add read (list range))))
 667                  (gnus-info-set-read info new-read)))
 668              info)))))
 669
 670 (defun gnus-request-expire-articles (articles group &optional force)
 671   (let* ((gnus-command-method (gnus-find-method-for-group group))
 672          (gnus-inhibit-demon t)
 673          (not-deleted
 674           (funcall
 675            (gnus-get-function gnus-command-method 'request-expire-articles)
 676            articles (gnus-group-real-name group) (nth 1 gnus-command-method)
 677            force)))
 678     (when (and gnus-agent
 679                (gnus-agent-method-p gnus-command-method))
 680       (let ((expired-articles (gnus-sorted-difference articles not-deleted)))
 681         (when expired-articles
 682           (gnus-agent-expire expired-articles group 'force))))
 683     not-deleted))
 684
 685 (defun gnus-request-move-article (article group server accept-function
 686                                           &optional last move-is-internal)
 687   (let* ((gnus-command-method (gnus-find-method-for-group group))
 688          (result (funcall (gnus-get-function gnus-command-method
 689                                              'request-move-article)
 690                           article (gnus-group-real-name group)
 691                           (nth 1 gnus-command-method) accept-function
 692                           last move-is-internal)))
 693     (when (and result gnus-agent
 694                (gnus-agent-method-p gnus-command-method))
 695       (gnus-agent-unfetch-articles group (list article)))
 696     result))
 697
 698 (defun gnus-request-accept-article (group &optional gnus-command-method last
 699                                           no-encode)
 700   ;; Make sure there's a newline at the end of the article.
 701   (when (stringp gnus-command-method)
 702     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 703   (when (and (not gnus-command-method)
 704              (stringp group))
 705     (setq gnus-command-method (or (gnus-find-method-for-group group)
 706                                   (gnus-group-name-to-method group))))
 707   (goto-char (point-max))
 708   (unless (bolp)
 709     (insert "\n"))
 710   (unless no-encode
 711     (let ((message-options message-options))
 712       (message-options-set-recipient)
 713       (save-restriction
 714         (message-narrow-to-head)
 715         (let ((mail-parse-charset message-default-charset))
 716           (mail-encode-encoded-word-buffer)))
 717       (message-encode-message-body)))
 718   (let ((gnus-command-method (or gnus-command-method
 719                                  (gnus-find-method-for-group group)))
 720         (result
 721          (funcall
 722           (gnus-get-function gnus-command-method 'request-accept-article)
 723           (if (stringp group) (gnus-group-real-name group) group)
 724           (cadr gnus-command-method)
 725           last)))
 726     (when (and gnus-agent
 727                (gnus-agent-method-p gnus-command-method)
 728                (cdr result))
 729       (gnus-agent-regenerate-group group (list (cdr result))))
 730     result))
 731
 732 (defun gnus-request-replace-article (article group buffer &optional no-encode)
 733   (unless no-encode
 734     (let ((message-options message-options))
 735       (message-options-set-recipient)
 736       (save-restriction
 737         (message-narrow-to-head)
 738         (let ((mail-parse-charset message-default-charset))
 739           (mail-encode-encoded-word-buffer)))
 740       (message-encode-message-body)))
 741   (let* ((func (car (gnus-group-name-to-method group)))
 742          (result (funcall (intern (format "%s-request-replace-article" func))
 743                           article (gnus-group-real-name group) buffer)))
 744     (when (and gnus-agent (gnus-agent-method-p gnus-command-method))
 745       (gnus-agent-regenerate-group group (list article)))
 746     result))
 747
 748 (defun gnus-request-associate-buffer (group)
 749   (let ((gnus-command-method (gnus-find-method-for-group group)))
 750     (funcall (gnus-get-function gnus-command-method 'request-associate-buffer)
 751              (gnus-group-real-name group))))
 752
 753 (defun gnus-request-restore-buffer (article group)
 754   "Request a new buffer restored to the state of ARTICLE."
 755   (let ((gnus-command-method (gnus-find-method-for-group group)))
 756     (funcall (gnus-get-function gnus-command-method 'request-restore-buffer)
 757              article (gnus-group-real-name group)
 758              (nth 1 gnus-command-method))))
 759
 760 (defun gnus-request-create-group (group &optional gnus-command-method args)
 761   (when (stringp gnus-command-method)
 762     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 763   (let ((gnus-command-method
 764          (or gnus-command-method (gnus-find-method-for-group group))))
 765     (funcall (gnus-get-function gnus-command-method 'request-create-group)
 766              (gnus-group-real-name group) (nth 1 gnus-command-method) args)))
 767
 768 (defun gnus-request-delete-group (group &optional force)
 769   (let* ((gnus-command-method (gnus-find-method-for-group group))
 770          (result
 771           (funcall (gnus-get-function gnus-command-method 'request-delete-group)
 772                    (gnus-group-real-name group) force (nth 1 gnus-command-method))))
 773     (when result
 774       (gnus-cache-delete-group group)
 775       (gnus-agent-delete-group group))
 776     result))
 777
 778 (defun gnus-request-rename-group (group new-name)
 779   (let* ((gnus-command-method (gnus-find-method-for-group group))
 780          (result
 781           (funcall (gnus-get-function gnus-command-method 'request-rename-group)
 782                    (gnus-group-real-name group)
 783                    (gnus-group-real-name new-name) (nth 1 gnus-command-method))))
 784     (when result
 785       (gnus-cache-rename-group group new-name)
 786       (gnus-agent-rename-group group new-name))
 787     result))
 788
 789 (defun gnus-close-backends ()
 790   ;; Send a close request to all backends that support such a request.
 791   (let ((methods gnus-valid-select-methods)
 792         (gnus-inhibit-demon t)
 793         func gnus-command-method)
 794     (while (setq gnus-command-method (pop methods))
 795       (when (fboundp (setq func (intern
 796                                  (concat (car gnus-command-method)
 797                                          "-request-close"))))
 798         (funcall func)))))
 799
 800 (defun gnus-asynchronous-p (gnus-command-method)
 801   (let ((func (gnus-get-function gnus-command-method 'asynchronous-p t)))
 802     (when (fboundp func)
 803       (funcall func))))
 804
 805 (defun gnus-remove-denial (gnus-command-method)
 806   (when (stringp gnus-command-method)
 807     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 808   (let* ((elem (assoc gnus-command-method gnus-opened-servers))
 809          (status (cadr elem)))
 810     ;; If this hasn't been opened before, we add it to the list.
 811     (when (eq status 'denied)
 812       ;; Set the status of this server.
 813       (setcar (cdr elem) 'closed))))
 814
 815 (provide 'gnus-int)
 816
 817 ;;; gnus-int.el ends here