lisp/outline.el

   1 ;;; outline.el --- outline mode commands for Emacs
   2
   3 ;; Copyright (C) 1986, 1993, 1994, 1995, 1997, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: outlines
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package is a major mode for editing outline-format documents.
  29 ;; An outline can be `abstracted' to show headers at any given level,
  30 ;; with all stuff below hidden.  See the Emacs manual for details.
  31
  32 ;;; Todo:
  33
  34 ;; - subtree-terminators
  35 ;; - better handle comments before function bodies (i.e. heading)
  36 ;; - don't bother hiding whitespace
  37
  38 ;;; Code:
  39
  40 (defvar font-lock-warning-face)
  41
  42
  43 (defgroup outlines nil
  44   "Support for hierarchical outlining."
  45   :prefix "outline-"
  46   :group 'editing)
  47
  48 (defcustom outline-regexp "[*\^L]+"
  49   "Regular expression to match the beginning of a heading.
  50 Any line whose beginning matches this regexp is considered to start a heading.
  51 Note that Outline mode only checks this regexp at the start of a line,
  52 so the regexp need not (and usually does not) start with `^'.
  53 The recommended way to set this is with a Local Variables: list
  54 in the file it applies to.  See also `outline-heading-end-regexp'."
  55   :type '(choice regexp (const nil))
  56   :group 'outlines)
  57 ;;;###autoload(put 'outline-regexp 'safe-local-variable 'string-or-null-p)
  58
  59 (defcustom outline-heading-end-regexp "\n"
  60   "Regular expression to match the end of a heading line.
  61 You can assume that point is at the beginning of a heading when this
  62 regexp is searched for.  The heading ends at the end of the match.
  63 The recommended way to set this is with a `Local Variables:' list
  64 in the file it applies to."
  65   :type 'regexp
  66   :group 'outlines)
  67
  68 (defvar outline-mode-prefix-map
  69   (let ((map (make-sparse-keymap)))
  70     (define-key map "@" 'outline-mark-subtree)
  71     (define-key map "\C-n" 'outline-next-visible-heading)
  72     (define-key map "\C-p" 'outline-previous-visible-heading)
  73     (define-key map "\C-i" 'show-children)
  74     (define-key map "\C-s" 'show-subtree)
  75     (define-key map "\C-d" 'hide-subtree)
  76     (define-key map "\C-u" 'outline-up-heading)
  77     (define-key map "\C-f" 'outline-forward-same-level)
  78     (define-key map "\C-b" 'outline-backward-same-level)
  79     (define-key map "\C-t" 'hide-body)
  80     (define-key map "\C-a" 'show-all)
  81     (define-key map "\C-c" 'hide-entry)
  82     (define-key map "\C-e" 'show-entry)
  83     (define-key map "\C-l" 'hide-leaves)
  84     (define-key map "\C-k" 'show-branches)
  85     (define-key map "\C-q" 'hide-sublevels)
  86     (define-key map "\C-o" 'hide-other)
  87     (define-key map "\C-^" 'outline-move-subtree-up)
  88     (define-key map "\C-v" 'outline-move-subtree-down)
  89     (define-key map [(control ?<)] 'outline-promote)
  90     (define-key map [(control ?>)] 'outline-demote)
  91     (define-key map "\C-m" 'outline-insert-heading)
  92     ;; Where to bind outline-cycle ?
  93     map))
  94
  95 (defvar outline-mode-menu-bar-map
  96   (let ((map (make-sparse-keymap)))
  97
  98     (define-key map [hide] (cons "Hide" (make-sparse-keymap "Hide")))
  99
 100     (define-key map [hide hide-other]
 101       '(menu-item "Hide Other" hide-other
 102                   :help "Hide everything except current body and parent and top-level headings"))
 103     (define-key map [hide hide-sublevels]
 104       '(menu-item "Hide Sublevels" hide-sublevels
 105                   :help "Hide everything but the top LEVELS levels of headers, in whole buffer"))
 106     (define-key map [hide hide-subtree]
 107       '(menu-item "Hide Subtree" hide-subtree
 108                   :help "Hide everything after this heading at deeper levels"))
 109     (define-key map [hide hide-entry]
 110       '(menu-item "Hide Entry" hide-entry
 111                   :help "Hide the body directly following this heading"))
 112     (define-key map [hide hide-body]
 113       '(menu-item "Hide Body" hide-body
 114                   :help "Hide all body lines in buffer, leaving all headings visible"))
 115     (define-key map [hide hide-leaves]
 116       '(menu-item "Hide Leaves" hide-leaves
 117                   :help "Hide the body after this heading and at deeper levels"))
 118
 119     (define-key map [show] (cons "Show" (make-sparse-keymap "Show")))
 120
 121     (define-key map [show show-subtree]
 122       '(menu-item "Show Subtree" show-subtree
 123                   :help "Show everything after this heading at deeper levels"))
 124     (define-key map [show show-children]
 125       '(menu-item "Show Children" show-children
 126                   :help "Show all direct subheadings of this heading"))
 127     (define-key map [show show-branches]
 128       '(menu-item "Show Branches" show-branches
 129                   :help "Show all subheadings of this heading, but not their bodies"))
 130     (define-key map [show show-entry]
 131       '(menu-item "Show Entry" show-entry
 132                   :help "Show the body directly following this heading"))
 133     (define-key map [show show-all]
 134       '(menu-item "Show All" show-all
 135                   :help "Show all of the text in the buffer"))
 136
 137     (define-key map [headings]
 138       (cons "Headings" (make-sparse-keymap "Headings")))
 139
 140     (define-key map [headings demote-subtree]
 141       '(menu-item "Demote subtree" outline-demote
 142                   :help "Demote headings lower down the tree"))
 143     (define-key map [headings promote-subtree]
 144       '(menu-item "Promote subtree" outline-promote
 145                   :help "Promote headings higher up the tree"))
 146     (define-key map [headings move-subtree-down]
 147       '(menu-item "Move subtree down" outline-move-subtree-down
 148                   :help "Move the currrent subtree down past arg headlines of the same level"))
 149     (define-key map [headings move-subtree-up]
 150       '(menu-item "Move subtree up" outline-move-subtree-up
 151                   :help "Move the currrent subtree up past arg headlines of the same level"))
 152     (define-key map [headings copy]
 153       '(menu-item "Copy to kill ring" outline-headers-as-kill
 154                   :enable mark-active
 155                   :help "Save the visible outline headers in region at the start of the kill ring"))
 156     (define-key map [headings outline-insert-heading]
 157
 158       '(menu-item "New heading" outline-insert-heading
 159                   :help "Insert a new heading at same depth at point"))
 160     (define-key map [headings outline-backward-same-level]
 161
 162       '(menu-item "Previous Same Level" outline-backward-same-level
 163                   :help "Move backward to the arg'th subheading at same level as this one."))
 164     (define-key map [headings outline-forward-same-level]
 165
 166       '(menu-item "Next Same Level" outline-forward-same-level
 167                   :help "Move forward to the arg'th subheading at same level as this one"))
 168     (define-key map [headings outline-previous-visible-heading]
 169
 170       '(menu-item "Previous" outline-previous-visible-heading
 171                   :help "Move to the previous heading line"))
 172     (define-key map [headings outline-next-visible-heading]
 173
 174       '(menu-item "Next" outline-next-visible-heading
 175                   :help "Move to the next visible heading line"))
 176     (define-key map [headings outline-up-heading]
 177
 178       '(menu-item "Up" outline-up-heading
 179                   :help "Move to the visible heading line of which the present line is a subheading"))
 180     map))
 181
 182 (defvar outline-minor-mode-menu-bar-map
 183   (let ((map (make-sparse-keymap)))
 184     (define-key map [outline]
 185       (cons "Outline"
 186             (nconc (make-sparse-keymap "Outline")
 187                    ;; Remove extra separator
 188                    (cdr
 189                     ;; Flatten the major mode's menus into a single menu.
 190                     (apply 'append
 191                            (mapcar (lambda (x)
 192                                      (if (consp x)
 193                                          ;; Add a separator between each
 194                                          ;; part of the unified menu.
 195                                          (cons '(--- "---") (cdr x))))
 196                                    outline-mode-menu-bar-map))))))
 197     map))
 198
 199
 200 (defvar outline-mode-map
 201   (let ((map (make-sparse-keymap)))
 202     (define-key map "\C-c" outline-mode-prefix-map)
 203     (define-key map [menu-bar] outline-mode-menu-bar-map)
 204     map))
 205
 206 (defvar outline-font-lock-keywords
 207   '(;;
 208     ;; Highlight headings according to the level.
 209     (eval . (list (concat "^\\(?:" outline-regexp "\\).+")
 210                   0 '(outline-font-lock-face) nil t)))
 211   "Additional expressions to highlight in Outline mode.")
 212
 213 (defface outline-1
 214   '((t :inherit font-lock-function-name-face))
 215   "Level 1."
 216   :group 'outlines)
 217
 218 (defface outline-2
 219   '((t :inherit font-lock-variable-name-face))
 220   "Level 2."
 221   :group 'outlines)
 222
 223 (defface outline-3
 224   '((t :inherit font-lock-keyword-face))
 225   "Level 3."
 226   :group 'outlines)
 227
 228 (defface outline-4
 229   '((t :inherit font-lock-comment-face))
 230   "Level 4."
 231   :group 'outlines)
 232
 233 (defface outline-5
 234   '((t :inherit font-lock-type-face))
 235   "Level 5."
 236   :group 'outlines)
 237
 238 (defface outline-6
 239   '((t :inherit font-lock-constant-face))
 240   "Level 6."
 241   :group 'outlines)
 242
 243 (defface outline-7
 244   '((t :inherit font-lock-builtin-face))
 245   "Level 7."
 246   :group 'outlines)
 247
 248 (defface outline-8
 249   '((t :inherit font-lock-string-face))
 250   "Level 8."
 251   :group 'outlines)
 252
 253 (defvar outline-font-lock-faces
 254   [outline-1 outline-2 outline-3 outline-4
 255    outline-5 outline-6 outline-7 outline-8])
 256
 257 ;; (defvar outline-font-lock-levels nil)
 258 ;; (make-variable-buffer-local 'outline-font-lock-levels)
 259
 260 (defun outline-font-lock-face ()
 261   ;; (save-excursion
 262   ;;   (outline-back-to-heading t)
 263   ;;   (let* ((count 0)
 264   ;;       (start-level (funcall outline-level))
 265   ;;       (level start-level)
 266   ;;       face-level)
 267   ;;     (while (not (setq face-level
 268   ;;                    (if (or (bobp) (eq level 1)) 0
 269   ;;                      (cdr (assq level outline-font-lock-levels)))))
 270   ;;    (outline-up-heading 1 t)
 271   ;;    (setq count (1+ count))
 272   ;;    (setq level (funcall outline-level)))
 273   ;;     ;; Remember for later.
 274   ;;     (unless (zerop count)
 275   ;;    (setq face-level (+ face-level count))
 276   ;;    (push (cons start-level face-level) outline-font-lock-levels))
 277   ;;     (condition-case nil
 278   ;;      (aref outline-font-lock-faces face-level)
 279   ;;    (error font-lock-warning-face))))
 280   (save-excursion
 281     (goto-char (match-beginning 0))
 282     (looking-at outline-regexp)
 283     (aref outline-font-lock-faces (% (1- (funcall outline-level)) (length outline-font-lock-faces)))))
 284
 285 (defvar outline-view-change-hook nil
 286   "Normal hook to be run after outline visibility changes.")
 287
 288 (defvar outline-mode-hook nil
 289   "*This hook is run when outline mode starts.")
 290
 291 (defvar outline-blank-line nil
 292   "*Non-nil means to leave unhidden blank line before heading.")
 293
 294 ;;;###autoload
 295 (define-derived-mode outline-mode text-mode "Outline"
 296   "Set major mode for editing outlines with selective display.
 297 Headings are lines which start with asterisks: one for major headings,
 298 two for subheadings, etc.  Lines not starting with asterisks are body lines.
 299
 300 Body text or subheadings under a heading can be made temporarily
 301 invisible, or visible again.  Invisible lines are attached to the end
 302 of the heading, so they move with it, if the line is killed and yanked
 303 back.  A heading with text hidden under it is marked with an ellipsis (...).
 304
 305 Commands:\\<outline-mode-map>
 306 \\[outline-next-visible-heading]   outline-next-visible-heading      move by visible headings
 307 \\[outline-previous-visible-heading]   outline-previous-visible-heading
 308 \\[outline-forward-same-level]   outline-forward-same-level        similar but skip subheadings
 309 \\[outline-backward-same-level]   outline-backward-same-level
 310 \\[outline-up-heading]   outline-up-heading                 move from subheading to heading
 311
 312 \\[hide-body]   make all text invisible (not headings).
 313 \\[show-all]    make everything in buffer visible.
 314 \\[hide-sublevels]  make only the first N levels of headers visible.
 315
 316 The remaining commands are used when point is on a heading line.
 317 They apply to some of the body or subheadings of that heading.
 318 \\[hide-subtree]   hide-subtree make body and subheadings invisible.
 319 \\[show-subtree]   show-subtree make body and subheadings visible.
 320 \\[show-children]   show-children       make direct subheadings visible.
 321                  No effect on body, or subheadings 2 or more levels down.
 322                  With arg N, affects subheadings N levels down.
 323 \\[hide-entry]     make immediately following body invisible.
 324 \\[show-entry]     make it visible.
 325 \\[hide-leaves]    make body under heading and under its subheadings invisible.
 326                      The subheadings remain visible.
 327 \\[show-branches]  make all subheadings at all levels visible.
 328
 329 The variable `outline-regexp' can be changed to control what is a heading.
 330 A line is a heading if `outline-regexp' matches something at the
 331 beginning of the line.  The longer the match, the deeper the level.
 332
 333 Turning on outline mode calls the value of `text-mode-hook' and then of
 334 `outline-mode-hook', if they are non-nil."
 335   (make-local-variable 'line-move-ignore-invisible)
 336   (setq line-move-ignore-invisible t)
 337   ;; Cause use of ellipses for invisible text.
 338   (add-to-invisibility-spec '(outline . t))
 339   (set (make-local-variable 'paragraph-start)
 340        (concat paragraph-start "\\|\\(?:" outline-regexp "\\)"))
 341   ;; Inhibit auto-filling of header lines.
 342   (set (make-local-variable 'auto-fill-inhibit-regexp) outline-regexp)
 343   (set (make-local-variable 'paragraph-separate)
 344        (concat paragraph-separate "\\|\\(?:" outline-regexp "\\)"))
 345   (set (make-local-variable 'font-lock-defaults)
 346        '(outline-font-lock-keywords t nil nil backward-paragraph))
 347   (setq imenu-generic-expression
 348         (list (list nil (concat "^\\(?:" outline-regexp "\\).*$") 0)))
 349   (add-hook 'change-major-mode-hook 'show-all nil t))
 350
 351 (defcustom outline-minor-mode-prefix "\C-c@"
 352   "*Prefix key to use for Outline commands in Outline minor mode.
 353 The value of this variable is checked as part of loading Outline mode.
 354 After that, changing the prefix key requires manipulating keymaps."
 355   :type 'string
 356   :group 'outlines)
 357
 358 ;;;###autoload
 359 (define-minor-mode outline-minor-mode
 360   "Toggle Outline minor mode.
 361 With arg, turn Outline minor mode on if arg is positive, off otherwise.
 362 See the command `outline-mode' for more information on this mode."
 363   nil " Outl" (list (cons [menu-bar] outline-minor-mode-menu-bar-map)
 364                     (cons outline-minor-mode-prefix outline-mode-prefix-map))
 365   :group 'outlines
 366   (if outline-minor-mode
 367       (progn
 368         ;; Turn off this mode if we change major modes.
 369         (add-hook 'change-major-mode-hook
 370                   (lambda () (outline-minor-mode -1))
 371                   nil t)
 372         (set (make-local-variable 'line-move-ignore-invisible) t)
 373         ;; Cause use of ellipses for invisible text.
 374         (add-to-invisibility-spec '(outline . t)))
 375     (setq line-move-ignore-invisible nil)
 376     ;; Cause use of ellipses for invisible text.
 377     (remove-from-invisibility-spec '(outline . t))
 378     ;; When turning off outline mode, get rid of any outline hiding.
 379     (show-all)))
 380 \f
 381 (defvar outline-level 'outline-level
 382   "*Function of no args to compute a header's nesting level in an outline.
 383 It can assume point is at the beginning of a header line and that the match
 384 data reflects the `outline-regexp'.")
 385
 386 (defvar outline-heading-alist ()
 387   "Alist associating a heading for every possible level.
 388 Each entry is of the form (HEADING . LEVEL).
 389 This alist is used two ways: to find the heading corresponding to
 390 a given level and to find the level of a given heading.
 391 If a mode or document needs several sets of outline headings (for example
 392 numbered and unnumbered sections), list them set by set and sorted by level
 393 within each set.  For example in texinfo mode:
 394
 395      (setq outline-heading-alist
 396       '((\"@chapter\" . 2) (\"@section\" . 3) (\"@subsection\" . 4)
 397            (\"@subsubsection\" . 5)
 398         (\"@unnumbered\" . 2) (\"@unnumberedsec\" . 3)
 399            (\"@unnumberedsubsec\" . 4)  (\"@unnumberedsubsubsec\" . 5)
 400         (\"@appendix\" . 2) (\"@appendixsec\" . 3)...
 401            (\"@appendixsubsec\" . 4) (\"@appendixsubsubsec\" . 5) ..))
 402
 403 Instead of sorting the entries in each set, you can also separate the
 404 sets with nil.")
 405 (make-variable-buffer-local 'outline-heading-alist)
 406
 407 ;; This used to count columns rather than characters, but that made ^L
 408 ;; appear to be at level 2 instead of 1.  Columns would be better for
 409 ;; tab handling, but the default regexp doesn't use tabs, and anyone
 410 ;; who changes the regexp can also redefine the outline-level variable
 411 ;; as appropriate.
 412 (defun outline-level ()
 413   "Return the depth to which a statement is nested in the outline.
 414 Point must be at the beginning of a header line.
 415 This is actually either the level specified in `outline-heading-alist'
 416 or else the number of characters matched by `outline-regexp'."
 417   (or (cdr (assoc (match-string 0) outline-heading-alist))
 418       (- (match-end 0) (match-beginning 0))))
 419
 420 (defun outline-next-preface ()
 421   "Skip forward to just before the next heading line.
 422 If there's no following heading line, stop before the newline
 423 at the end of the buffer."
 424   (if (re-search-forward (concat "\n\\(?:" outline-regexp "\\)")
 425                          nil 'move)
 426       (goto-char (match-beginning 0)))
 427   (if (and (bolp) (or outline-blank-line (eobp)) (not (bobp)))
 428       (forward-char -1)))
 429
 430 (defun outline-next-heading ()
 431   "Move to the next (possibly invisible) heading line."
 432   (interactive)
 433   ;; Make sure we don't match the heading we're at.
 434   (if (and (bolp) (not (eobp))) (forward-char 1))
 435   (if (re-search-forward (concat "^\\(?:" outline-regexp "\\)")
 436                          nil 'move)
 437       (goto-char (match-beginning 0))))
 438
 439 (defun outline-previous-heading ()
 440   "Move to the previous (possibly invisible) heading line."
 441   (interactive)
 442   (re-search-backward (concat "^\\(?:" outline-regexp "\\)")
 443                       nil 'move))
 444
 445 (defsubst outline-invisible-p (&optional pos)
 446   "Non-nil if the character after point is invisible."
 447   (get-char-property (or pos (point)) 'invisible))
 448
 449 (defun outline-visible ()
 450   (not (outline-invisible-p)))
 451 (make-obsolete 'outline-visible 'outline-invisible-p)
 452
 453 (defun outline-back-to-heading (&optional invisible-ok)
 454   "Move to previous heading line, or beg of this line if it's a heading.
 455 Only visible heading lines are considered, unless INVISIBLE-OK is non-nil."
 456   (beginning-of-line)
 457   (or (outline-on-heading-p invisible-ok)
 458       (let (found)
 459         (save-excursion
 460           (while (not found)
 461             (or (re-search-backward (concat "^\\(?:" outline-regexp "\\)")
 462                                     nil t)
 463                 (error "before first heading"))
 464             (setq found (and (or invisible-ok (not (outline-invisible-p)))
 465                              (point)))))
 466         (goto-char found)
 467         found)))
 468
 469 (defun outline-on-heading-p (&optional invisible-ok)
 470   "Return t if point is on a (visible) heading line.
 471 If INVISIBLE-OK is non-nil, an invisible heading line is ok too."
 472   (save-excursion
 473     (beginning-of-line)
 474     (and (bolp) (or invisible-ok (not (outline-invisible-p)))
 475          (looking-at outline-regexp))))
 476
 477 (defun outline-insert-heading ()
 478   "Insert a new heading at same depth at point."
 479   (interactive)
 480   (let ((head (save-excursion
 481                 (condition-case nil
 482                     (outline-back-to-heading)
 483                   (error (outline-next-heading)))
 484                 (if (eobp)
 485                     (or (caar outline-heading-alist) "")
 486                   (match-string 0)))))
 487     (unless (or (string-match "[ \t]\\'" head)
 488                 (not (string-match (concat "\\`\\(?:" outline-regexp "\\)")
 489                                    (concat head " "))))
 490       (setq head (concat head " ")))
 491     (unless (bolp) (end-of-line) (newline))
 492     (insert head)
 493     (unless (eolp)
 494       (save-excursion (newline-and-indent)))
 495     (run-hooks 'outline-insert-heading-hook)))
 496
 497 (defun outline-invent-heading (head up)
 498   (save-match-data
 499     ;; Let's try to invent one by repeating or deleting the last char.
 500     (let ((new-head (if up (substring head 0 -1)
 501                       (concat head (substring head -1)))))
 502       (if (string-match (concat "\\`\\(?:" outline-regexp "\\)")
 503                         new-head)
 504           ;; Why bother checking that it is indeed higher/lower level ?
 505           new-head
 506         ;; Didn't work, so ask what to do.
 507         (read-string (format "%s heading for `%s': "
 508                              (if up "Parent" "Demoted") head)
 509                      head nil nil t)))))
 510
 511 (defun outline-promote (&optional which)
 512   "Promote headings higher up the tree.
 513 If transient-mark-mode is on, and mark is active, promote headings in
 514 the region (from a Lisp program, pass `region' for WHICH).  Otherwise:
 515 without prefix argument, promote current heading and all headings in the
 516 subtree (from a Lisp program, pass `subtree' for WHICH); with prefix
 517 argument, promote just the current heading (from a Lisp program, pass
 518 nil for WHICH, or do not pass any argument)."
 519   (interactive
 520    (list (if (and transient-mark-mode mark-active) 'region
 521            (outline-back-to-heading)
 522            (if current-prefix-arg nil 'subtree))))
 523   (cond
 524    ((eq which 'region)
 525     (outline-map-region 'outline-promote (region-beginning) (region-end)))
 526    (which
 527     (outline-map-region 'outline-promote
 528                         (point)
 529                         (save-excursion (outline-get-next-sibling) (point))))
 530    (t
 531     (outline-back-to-heading t)
 532     (let* ((head (match-string-no-properties 0))
 533            (level (save-match-data (funcall outline-level)))
 534            (up-head (or (outline-head-from-level (1- level) head)
 535                         ;; Use the parent heading, if it is really
 536                         ;; one level less.
 537                         (save-excursion
 538                           (save-match-data
 539                             (outline-up-heading 1 t)
 540                             (and (= (1- level) (funcall outline-level))
 541                                  (match-string-no-properties 0))))
 542                         ;; Bummer!! There is no lower level heading.
 543                         (outline-invent-heading head 'up))))
 544
 545       (unless (rassoc level outline-heading-alist)
 546         (push (cons head level) outline-heading-alist))
 547
 548       (replace-match up-head nil t)))))
 549
 550 (defun outline-demote (&optional which)
 551   "Demote headings lower down the tree.
 552 If transient-mark-mode is on, and mark is active, demote headings in
 553 the region (from a Lisp program, pass `region' for WHICH).  Otherwise:
 554 without prefix argument, demote current heading and all headings in the
 555 subtree (from a Lisp program, pass `subtree' for WHICH); with prefix
 556 argument, demote just the current heading (from a Lisp program, pass
 557 nil for WHICH, or do not pass any argument)."
 558   (interactive
 559    (list (if (and transient-mark-mode mark-active) 'region
 560            (outline-back-to-heading)
 561            (if current-prefix-arg nil 'subtree))))
 562   (cond
 563    ((eq which 'region)
 564     (outline-map-region 'outline-demote (region-beginning) (region-end)))
 565    (which
 566     (outline-map-region 'outline-demote
 567                         (point)
 568                         (save-excursion (outline-get-next-sibling) (point))))
 569    (t
 570     (let* ((head (match-string-no-properties 0))
 571            (level (save-match-data (funcall outline-level)))
 572            (down-head
 573             (or (outline-head-from-level (1+ level) head)
 574                 (save-excursion
 575                   (save-match-data
 576                     (while (and (progn (outline-next-heading) (not (eobp)))
 577                                 (<= (funcall outline-level) level)))
 578                     (when (eobp)
 579                       ;; Try again from the beginning of the buffer.
 580                       (goto-char (point-min))
 581                       (while (and (progn (outline-next-heading) (not (eobp)))
 582                                   (<= (funcall outline-level) level))))
 583                     (unless (eobp)
 584                       (looking-at outline-regexp)
 585                       (match-string-no-properties 0))))
 586                 ;; Bummer!! There is no higher-level heading in the buffer.
 587                 (outline-invent-heading head nil))))
 588
 589       (unless (rassoc level outline-heading-alist)
 590         (push (cons head level) outline-heading-alist))
 591       (replace-match down-head nil t)))))
 592
 593 (defun outline-head-from-level (level head &optional alist)
 594   "Get new heading with level LEVEL from ALIST.
 595 If there are no such entries, return nil.
 596 ALIST defaults to `outline-heading-alist'.
 597 Similar to (car (rassoc LEVEL ALIST)).
 598 If there are several different entries with same new level, choose
 599 the one with the smallest distance to the assocation of HEAD in the alist.
 600 This makes it possible for promotion to work in modes with several
 601 independent sets of headings (numbered, unnumbered, appendix...)"
 602   (unless alist (setq alist outline-heading-alist))
 603   (let ((l (rassoc level alist))
 604         ll h hl l2 l2l)
 605     (cond
 606      ((null l) nil)
 607      ;; If there's no HEAD after L, any other entry for LEVEL after L
 608      ;; can't be much better than L.
 609      ((null (setq h (assoc head (setq ll (memq l alist))))) (car l))
 610      ;; If there's no other entry for LEVEL, just keep L.
 611      ((null (setq l2 (rassoc level (cdr ll)))) (car l))
 612      ;; Now we have L, L2, and H: see if L2 seems better than L.
 613      ;; If H is after L2, L2 is better.
 614      ((memq h (setq l2l (memq l2 (cdr ll))))
 615       (outline-head-from-level level head l2l))
 616      ;; Now we have H between L and L2.
 617      ;; If there's a separator between L and H, prefer L2.
 618      ((memq h (memq nil ll))
 619       (outline-head-from-level level head l2l))
 620      ;; If there's a separator between L2 and H, prefer L.
 621      ((memq l2 (memq nil (setq hl (memq h ll)))) (car l))
 622      ;; No separator between L and L2, check the distance.
 623      ((< (* 2 (length hl)) (+ (length ll) (length l2l)))
 624       (outline-head-from-level level head l2l))
 625      ;; If all else fails, just keep L.
 626      (t (car l)))))
 627
 628 (defun outline-map-region (fun beg end)
 629   "Call FUN for every heading between BEG and END.
 630 When FUN is called, point is at the beginning of the heading and
 631 the match data is set appropriately."
 632   (save-excursion
 633     (setq end (copy-marker end))
 634     (goto-char beg)
 635     (when (re-search-forward (concat "^\\(?:" outline-regexp "\\)") end t)
 636       (goto-char (match-beginning 0))
 637       (funcall fun)
 638       (while (and (progn
 639                     (outline-next-heading)
 640                     (< (point) end))
 641                   (not (eobp)))
 642         (funcall fun)))))
 643
 644 ;; Vertical tree motion
 645
 646 (defun outline-move-subtree-up (&optional arg)
 647   "Move the currrent subtree up past ARG headlines of the same level."
 648   (interactive "p")
 649   (outline-move-subtree-down (- arg)))
 650
 651 (defun outline-move-subtree-down (&optional arg)
 652   "Move the currrent subtree down past ARG headlines of the same level."
 653   (interactive "p")
 654   (let ((movfunc (if (> arg 0) 'outline-get-next-sibling
 655                    'outline-get-last-sibling))
 656         (ins-point (make-marker))
 657         (cnt (abs arg))
 658         beg end folded)
 659     ;; Select the tree
 660     (outline-back-to-heading)
 661     (setq beg (point))
 662     (save-match-data
 663       (save-excursion (outline-end-of-heading)
 664                       (setq folded (outline-invisible-p)))
 665       (outline-end-of-subtree))
 666     (if (= (char-after) ?\n) (forward-char 1))
 667     (setq end (point))
 668     ;; Find insertion point, with error handling
 669     (goto-char beg)
 670     (while (> cnt 0)
 671       (or (funcall movfunc)
 672           (progn (goto-char beg)
 673                  (error "Cannot move past superior level")))
 674       (setq cnt (1- cnt)))
 675     (if (> arg 0)
 676         ;; Moving forward - still need to move over subtree
 677         (progn (outline-end-of-subtree)
 678                (if (= (char-after) ?\n) (forward-char 1))))
 679     (move-marker ins-point (point))
 680     (insert (delete-and-extract-region beg end))
 681     (goto-char ins-point)
 682     (if folded (hide-subtree))
 683     (move-marker ins-point nil)))
 684
 685 (defun outline-end-of-heading ()
 686   (if (re-search-forward outline-heading-end-regexp nil 'move)
 687       (forward-char -1)))
 688
 689 (defun outline-next-visible-heading (arg)
 690   "Move to the next visible heading line.
 691 With argument, repeats or can move backward if negative.
 692 A heading line is one that starts with a `*' (or that
 693 `outline-regexp' matches)."
 694   (interactive "p")
 695   (if (< arg 0)
 696       (beginning-of-line)
 697     (end-of-line))
 698   (let (found-heading-p)
 699     (while (and (not (bobp)) (< arg 0))
 700       (while (and (not (bobp))
 701                   (setq found-heading-p
 702                         (re-search-backward
 703                          (concat "^\\(?:" outline-regexp "\\)")
 704                          nil 'move))
 705                   (outline-invisible-p)))
 706       (setq arg (1+ arg)))
 707     (while (and (not (eobp)) (> arg 0))
 708       (while (and (not (eobp))
 709                   (setq found-heading-p
 710                         (re-search-forward
 711                          (concat "^\\(?:" outline-regexp "\\)")
 712                          nil 'move))
 713                   (outline-invisible-p (match-beginning 0))))
 714       (setq arg (1- arg)))
 715     (if found-heading-p (beginning-of-line))))
 716
 717 (defun outline-previous-visible-heading (arg)
 718   "Move to the previous heading line.
 719 With argument, repeats or can move forward if negative.
 720 A heading line is one that starts with a `*' (or that
 721 `outline-regexp' matches)."
 722   (interactive "p")
 723   (outline-next-visible-heading (- arg)))
 724
 725 (defun outline-mark-subtree ()
 726   "Mark the current subtree in an outlined document.
 727 This puts point at the start of the current subtree, and mark at the end."
 728   (interactive)
 729   (let ((beg))
 730     (if (outline-on-heading-p)
 731         ;; we are already looking at a heading
 732         (beginning-of-line)
 733       ;; else go back to previous heading
 734       (outline-previous-visible-heading 1))
 735     (setq beg (point))
 736     (outline-end-of-subtree)
 737     (push-mark (point) nil t)
 738     (goto-char beg)))
 739 \f
 740
 741 (defvar outline-isearch-open-invisible-function nil
 742   "Function called if `isearch' finishes in an invisible overlay.
 743 The function is called with the overlay as its only argument.
 744 If nil, `show-entry' is called to reveal the invisible text.")
 745
 746 (put 'outline 'reveal-toggle-invisible 'outline-reveal-toggle-invisible)
 747 (defun outline-flag-region (from to flag)
 748   "Hide or show lines from FROM to TO, according to FLAG.
 749 If FLAG is nil then text is shown, while if FLAG is t the text is hidden."
 750   (remove-overlays from to 'invisible 'outline)
 751   (when flag
 752     ;; We use `front-advance' here because the invisible text begins at the
 753     ;; very end of the heading, before the newline, so text inserted at FROM
 754     ;; belongs to the heading rather than to the entry.
 755     (let ((o (make-overlay from to nil 'front-advance)))
 756       (overlay-put o 'invisible 'outline)
 757       (overlay-put o 'isearch-open-invisible
 758                    (or outline-isearch-open-invisible-function
 759                        'outline-isearch-open-invisible))))
 760   ;; Seems only used by lazy-lock.  I.e. obsolete.
 761   (run-hooks 'outline-view-change-hook))
 762
 763 (defun outline-reveal-toggle-invisible (o hidep)
 764   (save-excursion
 765     (goto-char (overlay-start o))
 766     (if hidep
 767         ;; When hiding the area again, we could just clean it up and let
 768         ;; reveal do the rest, by simply doing:
 769         ;; (remove-overlays (overlay-start o) (overlay-end o)
 770         ;;                  'invisible 'outline)
 771         ;;
 772         ;; That works fine as long as everything is in sync, but if the
 773         ;; structure of the document is changed while revealing parts of it,
 774         ;; the resulting behavior can be ugly.  I.e. we need to make
 775         ;; sure that we hide exactly a subtree.
 776         (progn
 777           (let ((end (overlay-end o)))
 778             (delete-overlay o)
 779             (while (progn
 780                      (hide-subtree)
 781                      (outline-next-visible-heading 1)
 782                      (and (not (eobp)) (< (point) end))))))
 783
 784       ;; When revealing, we just need to reveal sublevels.  If point is
 785       ;; inside one of the sublevels, reveal will call us again.
 786       ;; But we need to preserve the original overlay.
 787       (let ((o1 (copy-overlay o)))
 788         (overlay-put o 'invisible nil)  ;Show (most of) the text.
 789         (while (progn
 790                  (show-entry)
 791                  (show-children)
 792                  ;; Normally just the above is needed.
 793                  ;; But in odd cases, the above might fail to show anything.
 794                  ;; To avoid an infinite loop, we have to make sure that
 795                  ;; *something* gets shown.
 796                  (and (equal (overlay-start o) (overlay-start o1))
 797                       (< (point) (overlay-end o))
 798                       (= 0 (forward-line 1)))))
 799         ;; If still nothing was shown, just kill the damn thing.
 800         (when (equal (overlay-start o) (overlay-start o1))
 801           ;; I've seen it happen at the end of buffer.
 802           (delete-overlay o1))))))
 803
 804 ;; Function to be set as an outline-isearch-open-invisible' property
 805 ;; to the overlay that makes the outline invisible (see
 806 ;; `outline-flag-region').
 807 (defun outline-isearch-open-invisible (overlay)
 808   ;; We rely on the fact that isearch places point on the matched text.
 809   (show-entry))
 810 \f
 811 (defun hide-entry ()
 812   "Hide the body directly following this heading."
 813   (interactive)
 814   (save-excursion
 815     (outline-back-to-heading)
 816     (outline-end-of-heading)
 817     (outline-flag-region (point) (progn (outline-next-preface) (point)) t)))
 818
 819 (defun show-entry ()
 820   "Show the body directly following this heading.
 821 Show the heading too, if it is currently invisible."
 822   (interactive)
 823   (save-excursion
 824     (outline-back-to-heading t)
 825     (outline-flag-region (1- (point))
 826                          (progn (outline-next-preface) (point)) nil)))
 827
 828 (defun hide-body ()
 829   "Hide all body lines in buffer, leaving all headings visible."
 830   (interactive)
 831   (hide-region-body (point-min) (point-max)))
 832
 833 (defun hide-region-body (start end)
 834   "Hide all body lines in the region, but not headings."
 835   ;; Nullify the hook to avoid repeated calls to `outline-flag-region'
 836   ;; wasting lots of time running `lazy-lock-fontify-after-outline'
 837   ;; and run the hook finally.
 838   (let (outline-view-change-hook)
 839     (save-excursion
 840       (save-restriction
 841         (narrow-to-region start end)
 842         (goto-char (point-min))
 843         (if (outline-on-heading-p)
 844             (outline-end-of-heading)
 845           (outline-next-preface))
 846         (while (not (eobp))
 847           (outline-flag-region (point)
 848                                (progn (outline-next-preface) (point)) t)
 849           (unless (eobp)
 850             (forward-char (if (looking-at "\n\n") 2 1))
 851             (outline-end-of-heading))))))
 852   (run-hooks 'outline-view-change-hook))
 853
 854 (defun show-all ()
 855   "Show all of the text in the buffer."
 856   (interactive)
 857   (outline-flag-region (point-min) (point-max) nil))
 858
 859 (defun hide-subtree ()
 860   "Hide everything after this heading at deeper levels."
 861   (interactive)
 862   (outline-flag-subtree t))
 863
 864 (defun hide-leaves ()
 865   "Hide the body after this heading and at deeper levels."
 866   (interactive)
 867   (save-excursion
 868     (outline-back-to-heading)
 869 ;; Turned off to fix bug reported by Otto Maddox on 22 Nov 2005.
 870 ;;    (outline-end-of-heading)
 871     (hide-region-body (point) (progn (outline-end-of-subtree) (point)))))
 872
 873 (defun show-subtree ()
 874   "Show everything after this heading at deeper levels."
 875   (interactive)
 876   (outline-flag-subtree nil))
 877
 878 (defun outline-show-heading ()
 879   "Show the current heading and move to its end."
 880   (outline-flag-region (- (point)
 881                           (if (bobp) 0
 882                             (if (and outline-blank-line
 883                                      (eq (char-before (1- (point))) ?\n))
 884                                 2 1)))
 885                        (progn (outline-end-of-heading) (point))
 886                        nil))
 887
 888 (defun hide-sublevels (levels)
 889   "Hide everything but the top LEVELS levels of headers, in whole buffer."
 890   (interactive (list
 891                 (cond
 892                  (current-prefix-arg (prefix-numeric-value current-prefix-arg))
 893                  ((save-excursion (beginning-of-line)
 894                                   (looking-at outline-regexp))
 895                   (funcall outline-level))
 896                  (t 1))))
 897   (if (< levels 1)
 898       (error "Must keep at least one level of headers"))
 899   (save-excursion
 900     (let* (outline-view-change-hook
 901            (beg (progn
 902                   (goto-char (point-min))
 903                   ;; Skip the prelude, if any.
 904                   (unless (outline-on-heading-p t) (outline-next-heading))
 905                   (point)))
 906            (end (progn
 907                   (goto-char (point-max))
 908                   ;; Keep empty last line, if available.
 909                   (if (bolp) (1- (point)) (point)))))
 910       ;; First hide everything.
 911       (outline-flag-region beg end t)
 912       ;; Then unhide the top level headers.
 913       (outline-map-region
 914        (lambda ()
 915          (if (<= (funcall outline-level) levels)
 916              (outline-show-heading)))
 917        beg end)))
 918   (run-hooks 'outline-view-change-hook))
 919
 920 (defun hide-other ()
 921   "Hide everything except current body and parent and top-level headings."
 922   (interactive)
 923   (hide-sublevels 1)
 924   (let (outline-view-change-hook)
 925     (save-excursion
 926       (outline-back-to-heading t)
 927       (show-entry)
 928       (while (condition-case nil (progn (outline-up-heading 1 t) (not (bobp)))
 929                (error nil))
 930         (outline-flag-region (1- (point))
 931                              (save-excursion (forward-line 1) (point))
 932                              nil))))
 933   (run-hooks 'outline-view-change-hook))
 934
 935 (defun outline-toggle-children ()
 936   "Show or hide the current subtree depending on its current state."
 937   (interactive)
 938   (save-excursion
 939     (outline-back-to-heading)
 940     (if (not (outline-invisible-p (line-end-position)))
 941         (hide-subtree)
 942       (show-children)
 943       (show-entry))))
 944
 945 (defun outline-flag-subtree (flag)
 946   (save-excursion
 947     (outline-back-to-heading)
 948     (outline-end-of-heading)
 949     (outline-flag-region (point)
 950                           (progn (outline-end-of-subtree) (point))
 951                           flag)))
 952
 953 (defun outline-end-of-subtree ()
 954   (outline-back-to-heading)
 955   (let ((first t)
 956         (level (funcall outline-level)))
 957     (while (and (not (eobp))
 958                 (or first (> (funcall outline-level) level)))
 959       (setq first nil)
 960       (outline-next-heading))
 961     (if (and (bolp) (not (eolp)))
 962         ;; We stopped at a nonempty line (the next heading).
 963         (progn
 964           ;; Go to end of line before heading
 965           (forward-char -1)
 966           (if (and outline-blank-line (bolp))
 967               ;; leave blank line before heading
 968               (forward-char -1))))))
 969 \f
 970 (defun show-branches ()
 971   "Show all subheadings of this heading, but not their bodies."
 972   (interactive)
 973   (show-children 1000))
 974
 975 (defun show-children (&optional level)
 976   "Show all direct subheadings of this heading.
 977 Prefix arg LEVEL is how many levels below the current level should be shown.
 978 Default is enough to cause the following heading to appear."
 979   (interactive "P")
 980   (setq level
 981         (if level (prefix-numeric-value level)
 982           (save-excursion
 983             (outline-back-to-heading)
 984             (let ((start-level (funcall outline-level)))
 985               (outline-next-heading)
 986               (if (eobp)
 987                   1
 988                 (max 1 (- (funcall outline-level) start-level)))))))
 989   (let (outline-view-change-hook)
 990     (save-excursion
 991       (outline-back-to-heading)
 992       (setq level (+ level (funcall outline-level)))
 993       (outline-map-region
 994        (lambda ()
 995          (if (<= (funcall outline-level) level)
 996              (outline-show-heading)))
 997        (point)
 998        (progn (outline-end-of-subtree)
 999               (if (eobp) (point-max) (1+ (point)))))))
1000   (run-hooks 'outline-view-change-hook))
1001
1002 \f
1003
1004 (defun outline-up-heading (arg &optional invisible-ok)
1005   "Move to the visible heading line of which the present line is a subheading.
1006 With argument, move up ARG levels.
1007 If INVISIBLE-OK is non-nil, also consider invisible lines."
1008   (interactive "p")
1009   (and (eq this-command 'outline-up-heading)
1010        (or (eq last-command 'outline-up-heading) (push-mark)))
1011   (outline-back-to-heading invisible-ok)
1012   (let ((start-level (funcall outline-level)))
1013     (when (<= start-level 1)
1014       (error "Already at top level of the outline"))
1015     (while (and (> start-level 1) (> arg 0) (not (bobp)))
1016       (let ((level start-level))
1017         (while (not (or (< level start-level) (bobp)))
1018           (if invisible-ok
1019               (outline-previous-heading)
1020             (outline-previous-visible-heading 1))
1021           (setq level (funcall outline-level)))
1022         (setq start-level level))
1023       (setq arg (- arg 1))))
1024   (looking-at outline-regexp))
1025
1026 (defun outline-forward-same-level (arg)
1027   "Move forward to the ARG'th subheading at same level as this one.
1028 Stop at the first and last subheadings of a superior heading."
1029   (interactive "p")
1030   (outline-back-to-heading)
1031   (while (> arg 0)
1032     (let ((point-to-move-to (save-excursion
1033                               (outline-get-next-sibling))))
1034       (if point-to-move-to
1035           (progn
1036             (goto-char point-to-move-to)
1037             (setq arg (1- arg)))
1038         (progn
1039           (setq arg 0)
1040           (error "No following same-level heading"))))))
1041
1042 (defun outline-get-next-sibling ()
1043   "Move to next heading of the same level, and return point.
1044 If there is no such heading, return nil."
1045   (let ((level (funcall outline-level)))
1046     (outline-next-visible-heading 1)
1047     (while (and (not (eobp)) (> (funcall outline-level) level))
1048       (outline-next-visible-heading 1))
1049     (if (or (eobp) (< (funcall outline-level) level))
1050         nil
1051       (point))))
1052
1053 (defun outline-backward-same-level (arg)
1054   "Move backward to the ARG'th subheading at same level as this one.
1055 Stop at the first and last subheadings of a superior heading."
1056   (interactive "p")
1057   (outline-back-to-heading)
1058   (while (> arg 0)
1059     (let ((point-to-move-to (save-excursion
1060                               (outline-get-last-sibling))))
1061       (if point-to-move-to
1062           (progn
1063             (goto-char point-to-move-to)
1064             (setq arg (1- arg)))
1065         (progn
1066           (setq arg 0)
1067           (error "No previous same-level heading"))))))
1068
1069 (defun outline-get-last-sibling ()
1070   "Move to previous heading of the same level, and return point.
1071 If there is no such heading, return nil."
1072   (let ((opoint (point))
1073         (level (funcall outline-level)))
1074     (outline-previous-visible-heading 1)
1075     (when (and (/= (point) opoint) (outline-on-heading-p))
1076       (while (and (> (funcall outline-level) level)
1077                   (not (bobp)))
1078         (outline-previous-visible-heading 1))
1079       (if (< (funcall outline-level) level)
1080           nil
1081         (point)))))
1082 \f
1083 (defun outline-headers-as-kill (beg end)
1084   "Save the visible outline headers in region at the start of the kill ring.
1085
1086 Text shown between the headers isn't copied.  Two newlines are
1087 inserted between saved headers.  Yanking the result may be a
1088 convenient way to make a table of contents of the buffer."
1089   (interactive "r")
1090   (save-excursion
1091     (save-restriction
1092       (narrow-to-region beg end)
1093       (goto-char (point-min))
1094       (let ((buffer (current-buffer))
1095             start end)
1096         (with-temp-buffer
1097           (with-current-buffer buffer
1098             ;; Boundary condition: starting on heading:
1099             (when (outline-on-heading-p)
1100               (outline-back-to-heading)
1101               (setq start (point)
1102                     end (progn (outline-end-of-heading)
1103                                (point)))
1104               (insert-buffer-substring buffer start end)
1105               (insert "\n\n")))
1106           (let ((temp-buffer (current-buffer)))
1107             (with-current-buffer buffer
1108               (while (outline-next-heading)
1109                 (unless (outline-invisible-p)
1110                   (setq start (point)
1111                         end (progn (outline-end-of-heading) (point)))
1112                   (with-current-buffer temp-buffer
1113                     (insert-buffer-substring buffer start end)
1114                     (insert "\n\n"))))))
1115           (kill-new (buffer-string)))))))
1116
1117 (provide 'outline)
1118 (provide 'noutline)
1119
1120 ;; arch-tag: 1724410e-7d4d-4f46-b801-49e18171e874
1121 ;;; outline.el ends here