lisp/ls-lisp.el

   1 ;;; ls-lisp.el --- emulate insert-directory completely in Emacs Lisp
   2
   3 ;; Copyright (C) 1992, 1994, 2000-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   6 ;; Modified by: Francis J. Wright <F.J.Wright@maths.qmw.ac.uk>
   7 ;; Maintainer: FSF
   8 ;; Keywords: unix, dired
   9 ;; Package: emacs
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; OVERVIEW ==========================================================
  29
  30 ;; This file redefines the function `insert-directory' to implement it
  31 ;; directly from Emacs lisp, without running ls in a subprocess.  It
  32 ;; is useful if you cannot afford to fork Emacs on a real memory UNIX,
  33 ;; or other non-UNIX platforms if you don't have the ls
  34 ;; program, or if you want a different format from what ls offers.
  35
  36 ;; This function can use regexps instead of shell wildcards.  If you
  37 ;; enter regexps remember to double each $ sign.  For example, to
  38 ;; include files *.el, enter `.*\.el$$', resulting in the regexp
  39 ;; `.*\.el$'.
  40
  41 ;; RESTRICTIONS ======================================================
  42
  43 ;; * A few obscure ls switches are still ignored: see the docstring of
  44 ;; `insert-directory'.
  45
  46 ;; TO DO =============================================================
  47
  48 ;; Complete handling of F switch (if/when possible).
  49
  50 ;; FJW: May be able to sort much faster by consing the sort key onto
  51 ;; the front of each list element, sorting and then stripping the key
  52 ;; off again!
  53
  54 ;;; History:
  55
  56 ;; Written originally by Sebastian Kremer <sk@thp.uni-koeln.de>
  57 ;; Revised by Andrew Innes and Geoff Volker (and maybe others).
  58
  59 ;; Modified by Francis J. Wright <F.J.Wright@maths.qmw.ac.uk>, mainly
  60 ;; to support many more ls options, "platform emulation" and more
  61 ;; robust sorting.
  62
  63 ;;; Code:
  64
  65 (defgroup ls-lisp nil
  66   "Emulate the ls program completely in Emacs Lisp."
  67   :version "21.1"
  68   :group 'dired)
  69
  70 (defun ls-lisp-set-options ()
  71   "Reset the ls-lisp options that depend on `ls-lisp-emulation'."
  72   (mapc 'custom-reevaluate-setting
  73         '(ls-lisp-ignore-case ls-lisp-dirs-first ls-lisp-verbosity)))
  74
  75 (defcustom ls-lisp-emulation
  76   (cond ;; ((eq system-type 'windows-nt) 'MS-Windows)
  77         ((memq system-type '(hpux usg-unix-v irix berkeley-unix))
  78          'UNIX))        ; very similar to GNU
  79   ;; Anything else defaults to nil, meaning GNU.
  80   "Platform to emulate: GNU (default), MacOS, MS-Windows, UNIX.
  81 Corresponding value is one of: nil, `MacOS', `MS-Windows', `UNIX'.
  82 Set this to your preferred value; it need not match the actual platform
  83 you are using.
  84
  85 This variable does not affect the behavior of ls-lisp directly.
  86 Rather, it controls the default values for some variables that do:
  87 `ls-lisp-ignore-case', `ls-lisp-dirs-first', and `ls-lisp-verbosity'.
  88
  89 If you change this variable directly (without using customize)
  90 after loading `ls-lisp', you should use `ls-lisp-set-options' to
  91 update the dependent variables."
  92   :type '(choice (const :tag "GNU" nil)
  93                  (const MacOS)
  94                  (const MS-Windows)
  95                  (const UNIX))
  96   :initialize 'custom-initialize-default
  97   :set (lambda (symbol value)
  98          (unless (equal value (eval symbol))
  99            (custom-set-default symbol value)
 100            (ls-lisp-set-options)))
 101   :group 'ls-lisp)
 102
 103 ;; Only made an obsolete alias in 23.3.  Before that, the initial
 104 ;; value was set according to:
 105 ;;  (or (memq ls-lisp-emulation '(MS-Windows MacOS))
 106 ;;      (and (boundp 'ls-lisp-dired-ignore-case) ls-lisp-dired-ignore-case))
 107 ;; Which isn't the right thing to do.
 108 (define-obsolete-variable-alias 'ls-lisp-dired-ignore-case
 109   'ls-lisp-ignore-case "21.1")
 110
 111 (defcustom ls-lisp-ignore-case
 112   (memq ls-lisp-emulation '(MS-Windows MacOS))
 113   "Non-nil causes ls-lisp alphabetic sorting to ignore case."
 114   :set-after '(ls-lisp-emulation)
 115   :type 'boolean
 116   :group 'ls-lisp)
 117
 118 (defcustom ls-lisp-dirs-first (eq ls-lisp-emulation 'MS-Windows)
 119   "Non-nil causes ls-lisp to sort directories first in any ordering.
 120 \(Or last if it is reversed.)  Follows Microsoft Windows Explorer."
 121   ;; Functionality suggested by Chris McMahan <cmcmahan@one.net>
 122   :set-after '(ls-lisp-emulation)
 123   :type 'boolean
 124   :group 'ls-lisp)
 125
 126 (defcustom ls-lisp-verbosity
 127   (cond ((eq ls-lisp-emulation 'MacOS) nil)
 128         ((eq ls-lisp-emulation 'MS-Windows)
 129          (if (and (fboundp 'w32-using-nt) (w32-using-nt))
 130              '(links)))                 ; distinguish NT/2K from 9x
 131         ((eq ls-lisp-emulation 'UNIX) '(links uid)) ; UNIX ls
 132         (t '(links uid gid)))           ; GNU ls
 133   "A list of optional file attributes that ls-lisp should display.
 134 It should contain none or more of the symbols: links, uid, gid.
 135 A value of nil (or an empty list) means display none of them.
 136
 137 Concepts come from UNIX: `links' means count of names associated with
 138 the file; `uid' means user (owner) identifier; `gid' means group
 139 identifier.
 140
 141 If emulation is MacOS then default is nil;
 142 if emulation is MS-Windows then default is `(links)' if platform is
 143 Windows NT/2K, nil otherwise;
 144 if emulation is UNIX then default is `(links uid)';
 145 if emulation is GNU then default is `(links uid gid)'."
 146   :set-after '(ls-lisp-emulation)
 147   ;; Functionality suggested by Howard Melman <howard@silverstream.com>
 148   :type '(set (const :tag "Show Link Count" links)
 149               (const :tag "Show User" uid)
 150               (const :tag "Show Group" gid))
 151   :group 'ls-lisp)
 152
 153 (defcustom ls-lisp-use-insert-directory-program
 154   (not (memq system-type '(ms-dos windows-nt)))
 155   "Non-nil causes ls-lisp to revert back to using `insert-directory-program'.
 156 This is useful on platforms where ls-lisp is dumped into Emacs, such as
 157 Microsoft Windows, but you would still like to use a program to list
 158 the contents of a directory."
 159   :type 'boolean
 160   :group 'ls-lisp)
 161
 162 ;;; Autoloaded because it is let-bound in `recover-session', `mail-recover-1'.
 163 ;;;###autoload
 164 (defcustom ls-lisp-support-shell-wildcards t
 165   "Non-nil means ls-lisp treats file patterns as shell wildcards.
 166 Otherwise they are treated as Emacs regexps (for backward compatibility)."
 167   :type 'boolean
 168   :group 'ls-lisp)
 169
 170 (defcustom ls-lisp-format-time-list
 171   '("%b %e %H:%M"
 172     "%b %e  %Y")
 173   "List of `format-time-string' specs to display file time stamps.
 174 These specs are used ONLY if a valid locale can not be determined.
 175
 176 If `ls-lisp-use-localized-time-format' is non-nil, these specs are used
 177 regardless of whether the locale can be determined.
 178
 179 Syntax:  (EARLY-TIME-FORMAT OLD-TIME-FORMAT)
 180
 181 The EARLY-TIME-FORMAT is used if file has been modified within the
 182 current year.  The OLD-TIME-FORMAT is used for older files.  To use ISO
 183 8601 dates, you could set:
 184
 185 \(setq ls-lisp-format-time-list
 186        '(\"%Y-%m-%d %H:%M\"
 187          \"%Y-%m-%d      \"))"
 188   :type '(list (string :tag "Early time format")
 189                (string :tag "Old time format"))
 190   :group 'ls-lisp)
 191
 192 (defcustom ls-lisp-use-localized-time-format nil
 193   "Non-nil means to always use `ls-lisp-format-time-list' for time stamps.
 194 This applies even if a valid locale is specified.
 195
 196 WARNING: Using localized date/time format might cause Dired columns
 197 to fail to line up, e.g. if month names are not all of the same length."
 198   :type 'boolean
 199   :group 'ls-lisp)
 200
 201 (defvar original-insert-directory nil
 202   "This holds the original function definition of `insert-directory'.")
 203
 204 (defvar ls-lisp-uid-d-fmt "-%d"
 205   "Format to display integer UIDs.")
 206 (defvar ls-lisp-uid-s-fmt "-%s"
 207   "Format to display user names.")
 208 (defvar ls-lisp-gid-d-fmt "-%d"
 209   "Format to display integer GIDs.")
 210 (defvar ls-lisp-gid-s-fmt "-%s"
 211   "Format to display user group names.")
 212 (defvar ls-lisp-filesize-d-fmt "%d"
 213   "Format to display integer file sizes.")
 214 (defvar ls-lisp-filesize-f-fmt "%.0f"
 215   "Format to display float file sizes.")
 216
 217 ;; Remember the original insert-directory function
 218 (or (featurep 'ls-lisp)  ; FJW: unless this file is being reloaded!
 219     (setq original-insert-directory (symbol-function 'insert-directory)))
 220
 221 \f
 222 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 223
 224 (defun insert-directory (file switches &optional wildcard full-directory-p)
 225   "Insert directory listing for FILE, formatted according to SWITCHES.
 226 Leaves point after the inserted text.
 227 SWITCHES may be a string of options, or a list of strings.
 228 Optional third arg WILDCARD means treat FILE as shell wildcard.
 229 Optional fourth arg FULL-DIRECTORY-P means file is a directory and
 230 switches do not contain `d', so that a full listing is expected.
 231
 232 This version of the function comes from `ls-lisp.el'.
 233 If the value of `ls-lisp-use-insert-directory-program' is non-nil then
 234 it works exactly like the version from `files.el' and runs a directory
 235 listing program whose name is in the variable
 236 `insert-directory-program'; if also WILDCARD is non-nil then it runs
 237 the shell specified by `shell-file-name'.  If the value of
 238 `ls-lisp-use-insert-directory-program' is nil then it runs a Lisp
 239 emulation.
 240
 241 The Lisp emulation does not run any external programs or shells.  It
 242 supports ordinary shell wildcards if `ls-lisp-support-shell-wildcards'
 243 is non-nil; otherwise, it interprets wildcards as regular expressions
 244 to match file names.  It does not support all `ls' switches -- those
 245 that work are: A a B C c F G g h i n R r S s t U u X.  The l switch
 246 is assumed to be always present and cannot be turned off."
 247   (if ls-lisp-use-insert-directory-program
 248       (funcall original-insert-directory
 249                file switches wildcard full-directory-p)
 250     ;; We need the directory in order to find the right handler.
 251     (let ((handler (find-file-name-handler (expand-file-name file)
 252                                            'insert-directory))
 253           (orig-file file)
 254           wildcard-regexp)
 255       (if handler
 256           (funcall handler 'insert-directory file switches
 257                    wildcard full-directory-p)
 258         ;; Remove --dired switch
 259         (if (string-match "--dired " switches)
 260             (setq switches (replace-match "" nil nil switches)))
 261         ;; Convert SWITCHES to a list of characters.
 262         (setq switches (delete ?\  (delete ?- (append switches nil))))
 263         ;; Sometimes we get ".../foo*/" as FILE.  While the shell and
 264         ;; `ls' don't mind, we certainly do, because it makes us think
 265         ;; there is no wildcard, only a directory name.
 266         (if (and ls-lisp-support-shell-wildcards
 267                  (string-match "[[?*]" file)
 268                  ;; Prefer an existing file to wildcards, like
 269                  ;; dired-noselect does.
 270                  (not (file-exists-p file)))
 271             (progn
 272               (or (not (eq (aref file (1- (length file))) ?/))
 273                   (setq file (substring file 0 (1- (length file)))))
 274               (setq wildcard t)))
 275         (if wildcard
 276             (setq wildcard-regexp
 277                   (if ls-lisp-support-shell-wildcards
 278                       (wildcard-to-regexp (file-name-nondirectory file))
 279                     (file-name-nondirectory file))
 280                   file (file-name-directory file))
 281           (if (memq ?B switches) (setq wildcard-regexp "[^~]\\'")))
 282         (condition-case err
 283             (ls-lisp-insert-directory
 284              file switches (ls-lisp-time-index switches)
 285              wildcard-regexp full-directory-p)
 286           (invalid-regexp
 287            ;; Maybe they wanted a literal file that just happens to
 288            ;; use characters special to shell wildcards.
 289            (if (equal (cadr err) "Unmatched [ or [^")
 290                (progn
 291                  (setq wildcard-regexp (if (memq ?B switches) "[^~]\\'")
 292                        file (file-relative-name orig-file))
 293                  (ls-lisp-insert-directory
 294                   file switches (ls-lisp-time-index switches)
 295                   nil full-directory-p))
 296              (signal (car err) (cdr err)))))
 297         ;; Try to insert the amount of free space.
 298         (save-excursion
 299           (goto-char (point-min))
 300           ;; First find the line to put it on.
 301           (when (re-search-forward "^total" nil t)
 302             (let ((available (get-free-disk-space ".")))
 303               (when available
 304                 ;; Replace "total" with "total used", to avoid confusion.
 305                 (replace-match "total used in directory")
 306                 (end-of-line)
 307                 (insert " available " available)))))))))
 308
 309 (defun ls-lisp-insert-directory
 310   (file switches time-index wildcard-regexp full-directory-p)
 311   "Insert directory listing for FILE, formatted according to SWITCHES.
 312 Leaves point after the inserted text.  This is an internal function
 313 optionally called by the `ls-lisp.el' version of `insert-directory'.
 314 It is called recursively if the -R switch is used.
 315 SWITCHES is a *list* of characters.  TIME-INDEX is the time index into
 316 file-attributes according to SWITCHES.  WILDCARD-REGEXP is nil or an *Emacs
 317 regexp*.  FULL-DIRECTORY-P means file is a directory and SWITCHES does
 318 not contain `d', so that a full listing is expected."
 319   (if (or wildcard-regexp full-directory-p)
 320       (let* ((dir (file-name-as-directory file))
 321              (default-directory dir)    ; so that file-attributes works
 322              (file-alist
 323               (directory-files-and-attributes dir nil wildcard-regexp t
 324                                               (if (memq ?n switches)
 325                                                   'integer
 326                                                 'string)))
 327              (sum 0)
 328              (max-uid-len 0)
 329              (max-gid-len 0)
 330              (max-file-size 0)
 331              ;; do all bindings here for speed
 332              total-line files elt short file-size attr
 333              fuid fgid uid-len gid-len)
 334         (cond ((memq ?A switches)
 335                (setq file-alist
 336                      (ls-lisp-delete-matching "^\\.\\.?$" file-alist)))
 337               ((not (memq ?a switches))
 338                ;; if neither -A  nor -a, flush . files
 339                (setq file-alist
 340                      (ls-lisp-delete-matching "^\\." file-alist))))
 341         (setq file-alist
 342               (ls-lisp-handle-switches file-alist switches))
 343         (if (memq ?C switches)          ; column (-C) format
 344             (ls-lisp-column-format file-alist)
 345           (setq total-line (cons (point) (car-safe file-alist)))
 346           ;; Find the appropriate format for displaying uid, gid, and
 347           ;; file size, by finding the longest strings among all the
 348           ;; files we are about to display.
 349           (dolist (elt file-alist)
 350             (setq attr (cdr elt)
 351                   fuid (nth 2 attr)
 352                   uid-len (if (stringp fuid) (string-width fuid)
 353                             (length (format "%d" fuid)))
 354                   fgid (nth 3 attr)
 355                   gid-len (if (stringp fgid) (string-width fgid)
 356                             (length (format "%d" fgid)))
 357                   file-size (nth 7 attr))
 358             (if (> uid-len max-uid-len)
 359                 (setq max-uid-len uid-len))
 360             (if (> gid-len max-gid-len)
 361                 (setq max-gid-len gid-len))
 362             (if (> file-size max-file-size)
 363                 (setq max-file-size file-size)))
 364           (setq ls-lisp-uid-d-fmt (format " %%-%dd" max-uid-len))
 365           (setq ls-lisp-uid-s-fmt (format " %%-%ds" max-uid-len))
 366           (setq ls-lisp-gid-d-fmt (format " %%-%dd" max-gid-len))
 367           (setq ls-lisp-gid-s-fmt (format " %%-%ds" max-gid-len))
 368           (setq ls-lisp-filesize-d-fmt
 369                 (format " %%%dd"
 370                         (if (memq ?s switches)
 371                             (length (format "%.0f"
 372                                             (fceiling (/ max-file-size 1024.0))))
 373                           (length (format "%.0f" max-file-size)))))
 374           (setq ls-lisp-filesize-f-fmt
 375                 (format " %%%d.0f"
 376                         (if (memq ?s switches)
 377                             (length (format "%.0f"
 378                                             (fceiling (/ max-file-size 1024.0))))
 379                           (length (format "%.0f" max-file-size)))))
 380           (setq files file-alist)
 381           (while files                  ; long (-l) format
 382             (setq elt (car files)
 383                   files (cdr files)
 384                   short (car elt)
 385                   attr (cdr elt)
 386                   file-size (nth 7 attr))
 387             (and attr
 388                  (setq sum (+ file-size
 389                               ;; Even if neither SUM nor file's size
 390                               ;; overflow, their sum could.
 391                               (if (or (< sum (- 134217727 file-size))
 392                                       (floatp sum)
 393                                       (floatp file-size))
 394                                   sum
 395                                 (float sum))))
 396                  (insert (ls-lisp-format short attr file-size
 397                                          switches time-index))))
 398           ;; Insert total size of all files:
 399           (save-excursion
 400             (goto-char (car total-line))
 401             (or (cdr total-line)
 402                 ;; Shell says ``No match'' if no files match
 403                 ;; the wildcard; let's say something similar.
 404                 (insert "(No match)\n"))
 405             (insert (format "total %.0f\n" (fceiling (/ sum 1024.0))))))
 406         (if (memq ?R switches)
 407             ;; List the contents of all directories recursively.
 408             ;; cadr of each element of `file-alist' is t for
 409             ;; directory, string (name linked to) for symbolic
 410             ;; link, or nil.
 411             (while file-alist
 412               (setq elt (car file-alist)
 413                     file-alist (cdr file-alist))
 414               (when (and (eq (cadr elt) t) ; directory
 415                          ;; Under -F, we have already decorated all
 416                          ;; directories, including "." and "..", with
 417                          ;; a /, so allow for that as well.
 418                          (not (string-match "\\`\\.\\.?/?\\'" (car elt))))
 419                 (setq elt (expand-file-name (car elt) dir))
 420                 (insert "\n" elt ":\n")
 421                 (ls-lisp-insert-directory
 422                  elt switches time-index wildcard-regexp full-directory-p)))))
 423     ;; If not full-directory-p, FILE *must not* end in /, as
 424     ;; file-attributes will not recognize a symlink to a directory,
 425     ;; so must make it a relative filename as ls does:
 426     (if (file-name-absolute-p file) (setq file (expand-file-name file)))
 427     (if (eq (aref file (1- (length file))) ?/)
 428         (setq file (substring file 0 -1)))
 429     (let ((fattr (file-attributes file 'string)))
 430       (if fattr
 431           (insert (ls-lisp-format
 432                    (if (memq ?F switches)
 433                        (ls-lisp-classify-file file fattr)
 434                      file)
 435                    fattr (nth 7 fattr)
 436                                   switches time-index))
 437         (message "%s: doesn't exist or is inaccessible" file)
 438         (ding) (sit-for 2)))))          ; to show user the message!
 439
 440 (defun ls-lisp-column-format (file-alist)
 441   "Insert the file names (only) in FILE-ALIST into the current buffer.
 442 Format in columns, sorted vertically, following GNU ls -C.
 443 Responds to the window width as ls should but may not!"
 444   (let (files fmt ncols collen (nfiles 0) (colwid 0))
 445     ;; Count number of files as `nfiles', build list of filenames as
 446     ;; `files', and find maximum filename length as `colwid':
 447     (let (file len)
 448       (while file-alist
 449         (setq nfiles (1+ nfiles)
 450               file (caar file-alist)
 451               files (cons file files)
 452               file-alist (cdr file-alist)
 453               len (length file))
 454         (if (> len colwid) (setq colwid len))))
 455     (setq files (nreverse files)
 456           colwid (+ 2 colwid)           ; 2 character column gap
 457           fmt (format "%%-%ds" colwid)  ; print format
 458           ncols (/ (window-width) colwid) ; no of columns
 459           collen (/ nfiles ncols))      ; floor of column length
 460     (if (> nfiles (* collen ncols)) (setq collen (1+ collen)))
 461     ;; Output the file names in columns, sorted vertically:
 462     (let ((i 0) j)
 463       (while (< i collen)
 464         (setq j i)
 465         (while (< j nfiles)
 466           (insert (format fmt (nth j files)))
 467           (setq j (+ j collen)))
 468         ;; FJW: This is completely unnecessary, but I don't like
 469         ;; trailing white space...
 470         (delete-region (point) (progn (skip-chars-backward " \t") (point)))
 471         (insert ?\n)
 472         (setq i (1+ i))))))
 473
 474 (defun ls-lisp-delete-matching (regexp list)
 475   "Delete all elements matching REGEXP from LIST, return new list."
 476   ;; Should perhaps use setcdr for efficiency.
 477   (let (result)
 478     (while list
 479       (or (string-match regexp (caar list))
 480           (setq result (cons (car list) result)))
 481       (setq list (cdr list)))
 482     result))
 483
 484 (defsubst ls-lisp-string-lessp (s1 s2)
 485   "Return t if string S1 is less than string S2 in lexicographic order.
 486 Case is significant if `ls-lisp-ignore-case' is nil.
 487 Unibyte strings are converted to multibyte for comparison."
 488   (let ((u (compare-strings s1 0 nil s2 0 nil ls-lisp-ignore-case)))
 489     (and (numberp u) (< u 0))))
 490
 491 (defun ls-lisp-handle-switches (file-alist switches)
 492   "Return new FILE-ALIST sorted according to SWITCHES.
 493 SWITCHES is a list of characters.  Default sorting is alphabetic."
 494   ;; FILE-ALIST's elements are (FILE . FILE-ATTRIBUTES).
 495   (or (memq ?U switches)                ; unsorted
 496       ;; Catch and ignore unexpected sorting errors
 497       (condition-case err
 498           (setq file-alist
 499                 (let (index)
 500                   ;; Copy file-alist in case of error
 501                   (sort (copy-sequence file-alist) ; modifies its argument!
 502                         (cond ((memq ?S switches)
 503                                (lambda (x y) ; sorted on size
 504                                  ;; 7th file attribute is file size
 505                                  ;; Make largest file come first
 506                                  (< (nth 7 (cdr y))
 507                                     (nth 7 (cdr x)))))
 508                               ((setq index (ls-lisp-time-index switches))
 509                                (lambda (x y) ; sorted on time
 510                                  (time-less-p (nth index (cdr y))
 511                                               (nth index (cdr x)))))
 512                               ((memq ?X switches)
 513                                (lambda (x y) ; sorted on extension
 514                                  (ls-lisp-string-lessp
 515                                   (ls-lisp-extension (car x))
 516                                   (ls-lisp-extension (car y)))))
 517                               (t
 518                                (lambda (x y) ; sorted alphabetically
 519                                  (ls-lisp-string-lessp (car x) (car y))))))))
 520         (error (message "Unsorted (ls-lisp sorting error) - %s"
 521                         (error-message-string err))
 522                (ding) (sit-for 2))))    ; to show user the message!
 523   (if (memq ?F switches)                ; classify switch
 524       (setq file-alist (mapcar 'ls-lisp-classify file-alist)))
 525   (if ls-lisp-dirs-first
 526   ;; Re-sort directories first, without otherwise changing the
 527   ;; ordering, and reverse whole list.  cadr of each element of
 528   ;; `file-alist' is t for directory, string (name linked to) for
 529   ;; symbolic link, or nil.
 530       (let (el dirs files)
 531         (while file-alist
 532           (if (or (eq (cadr (setq el (car file-alist))) t) ; directory
 533                   (and (stringp (cadr el))
 534                        (file-directory-p (cadr el)))) ; symlink to a directory
 535               (setq dirs (cons el dirs))
 536             (setq files (cons el files)))
 537           (setq file-alist (cdr file-alist)))
 538         (setq file-alist
 539               (if (memq ?U switches)    ; unsorted order is reversed
 540                   (nconc dirs files)
 541                 (nconc files dirs)
 542                 ))))
 543   ;; Finally reverse file alist if necessary.
 544   ;; (eq below MUST compare `(not (memq ...))' to force comparison of
 545   ;; `t' or `nil', rather than list tails!)
 546   (if (eq (eq (not (memq ?U switches))  ; unsorted order is reversed
 547               (not (memq ?r switches))) ; reversed sort order requested
 548           ls-lisp-dirs-first)           ; already reversed
 549       (nreverse file-alist)
 550     file-alist))
 551
 552 (defun ls-lisp-classify-file (filename fattr)
 553   "Append a character to FILENAME indicating the file type.
 554
 555 FATTR is the file attributes returned by `file-attributes' for the file.
 556 The file type indicators are `/' for directories, `@' for symbolic
 557 links, `|' for FIFOs, `=' for sockets, `*' for regular files that
 558 are executable, and nothing for other types of files."
 559   (let* ((type (car fattr))
 560          (modestr (nth 8 fattr))
 561          (typestr (substring modestr 0 1)))
 562     (cond
 563      (type
 564       (concat filename (if (eq type t) "/" "@")))
 565      ((string-match "x" modestr)
 566       (concat filename "*"))
 567      ((string= "p" typestr)
 568       (concat filename "|"))
 569      ((string= "s" typestr)
 570       (concat filename "="))
 571      (t filename))))
 572
 573 (defun ls-lisp-classify (filedata)
 574   "Append a character to file name in FILEDATA indicating the file type.
 575
 576 FILEDATA has the form (FILENAME . ATTRIBUTES), where ATTRIBUTES is the
 577 structure returned by `file-attributes' for that file.
 578
 579 The file type indicators are `/' for directories, `@' for symbolic
 580 links, `|' for FIFOs, `=' for sockets, `*' for regular files that
 581 are executable, and nothing for other types of files."
 582   (let ((file-name (car filedata))
 583         (fattr (cdr filedata)))
 584     (setq file-name (propertize file-name 'dired-filename t))
 585     (cons (ls-lisp-classify-file file-name fattr) fattr)))
 586
 587 (defun ls-lisp-extension (filename)
 588   "Return extension of FILENAME (ignoring any version extension)
 589 FOLLOWED by null and full filename, SOLELY for full alpha sort."
 590   ;; Force extension sort order: `no ext' then `null ext' then `ext'
 591   ;; to agree with GNU ls.
 592   (concat
 593    (let* ((i (length filename)) end)
 594      (if (= (aref filename (1- i)) ?.) ; null extension
 595          "\0"
 596        (while (and (>= (setq i (1- i)) 0)
 597                    (/= (aref filename i) ?.)))
 598        (if (< i 0) "\0\0"               ; no extension
 599          (if (/= (aref filename (1+ i)) ?~)
 600              (substring filename (1+ i))
 601            ;; version extension found -- ignore it
 602            (setq end i)
 603            (while (and (>= (setq i (1- i)) 0)
 604                        (/= (aref filename i) ?.)))
 605            (if (< i 0) "\0\0"   ; no extension
 606              (substring filename (1+ i) end))))
 607        )) "\0" filename))
 608
 609 (defun ls-lisp-format (file-name file-attr file-size switches time-index)
 610   "Format one line of long ls output for file FILE-NAME.
 611 FILE-ATTR and FILE-SIZE give the file's attributes and size.
 612 SWITCHES and TIME-INDEX give the full switch list and time data."
 613   (let ((file-type (nth 0 file-attr))
 614         ;; t for directory, string (name linked to)
 615         ;; for symbolic link, or nil.
 616         (drwxrwxrwx (nth 8 file-attr))) ; attribute string ("drwxrwxrwx")
 617     (concat (if (memq ?i switches)      ; inode number
 618                 (let ((inode (nth 10 file-attr)))
 619                   (if (consp inode)
 620                       (if (consp (cdr inode))
 621                           ;; 2^(24+16) = 1099511627776.0, but
 622                           ;; multiplying by it and then adding the
 623                           ;; other members of the cons cell in one go
 624                           ;; loses precision, since a double does not
 625                           ;; have enough significant digits to hold a
 626                           ;; full 64-bit value.  So below we split
 627                           ;; 1099511627776 into high 13 and low 5
 628                           ;; digits and compute in two parts.
 629                           (let ((p1 (* (car inode) 10995116.0))
 630                                 (p2 (+ (* (car inode) 27776.0)
 631                                        (* (cadr inode) 65536.0)
 632                                        (cddr inode))))
 633                             (format " %13.0f%05.0f "
 634                                     ;; Use floor to emulate integer
 635                                     ;; division.
 636                                     (+ p1 (floor p2 100000.0))
 637                                     (mod p2 100000.0)))
 638                         (format " %18.0f "
 639                                 (+ (* (car inode) 65536.0)
 640                                    (cdr inode))))
 641                     (format " %18d " inode))))
 642             ;; nil is treated like "" in concat
 643             (if (memq ?s switches)      ; size in K
 644                 (format ls-lisp-filesize-f-fmt
 645                         (fceiling (/ file-size 1024.0))))
 646             drwxrwxrwx                  ; attribute string
 647             (if (memq 'links ls-lisp-verbosity)
 648                 (format "%3d" (nth 1 file-attr))) ; link count
 649             ;; Numeric uid/gid are more confusing than helpful;
 650             ;; Emacs should be able to make strings of them.
 651             ;; They tend to be bogus on non-UNIX platforms anyway so
 652             ;; optionally hide them.
 653             (if (memq 'uid ls-lisp-verbosity)
 654                 ;; uid can be a string or an integer
 655                 (let ((uid (nth 2 file-attr)))
 656                   (format (if (stringp uid)
 657                               ls-lisp-uid-s-fmt
 658                             ls-lisp-uid-d-fmt)
 659                           uid)))
 660             (if (not (memq ?G switches)) ; GNU ls -- shows group by default
 661                 (if (or (memq ?g switches) ; UNIX ls -- no group by default
 662                         (memq 'gid ls-lisp-verbosity))
 663                     (let ((gid (nth 3 file-attr)))
 664                       (format (if (stringp gid)
 665                                   ls-lisp-gid-s-fmt
 666                                 ls-lisp-gid-d-fmt)
 667                               gid))))
 668             (ls-lisp-format-file-size file-size (memq ?h switches))
 669             " "
 670             (ls-lisp-format-time file-attr time-index)
 671             " "
 672             (if (not (memq ?F switches)) ; ls-lisp-classify already did that
 673                 (propertize file-name 'dired-filename t)
 674               file-name)
 675             (if (stringp file-type)     ; is a symbolic link
 676                 (concat " -> " file-type))
 677             "\n"
 678             )))
 679
 680 (defun ls-lisp-time-index (switches)
 681   "Return time index into file-attributes according to ls SWITCHES list.
 682 Return nil if no time switch found."
 683   ;; FJW: Default of nil is IMPORTANT and used in `ls-lisp-handle-switches'!
 684   (cond ((memq ?c switches) 6)          ; last mode change
 685         ((memq ?t switches) 5)          ; last modtime
 686         ((memq ?u switches) 4)))        ; last access
 687
 688 (defun ls-lisp-format-time (file-attr time-index)
 689   "Format time for file with attributes FILE-ATTR according to TIME-INDEX.
 690 Use the same method as ls to decide whether to show time-of-day or year,
 691 depending on distance between file date and the current time.
 692 All ls time options, namely c, t and u, are handled."
 693   (let* ((time (nth (or time-index 5) file-attr)) ; default is last modtime
 694          (diff (- (float-time time) (float-time)))
 695          ;; Consider a time to be recent if it is within the past six
 696          ;; months.  A Gregorian year has 365.2425 * 24 * 60 * 60 ==
 697          ;; 31556952 seconds on the average, and half of that is 15778476.
 698          ;; Write the constant explicitly to avoid roundoff error.
 699          (past-cutoff -15778476)) ; half a Gregorian year
 700     (condition-case nil
 701         ;; Use traditional time format in the C or POSIX locale,
 702         ;; ISO-style time format otherwise, so columns line up.
 703         (let ((locale system-time-locale))
 704           (if (not locale)
 705               (let ((vars '("LC_ALL" "LC_TIME" "LANG")))
 706                 (while (and vars (not (setq locale (getenv (car vars)))))
 707                   (setq vars (cdr vars)))))
 708           (if (member locale '("C" "POSIX"))
 709               (setq locale nil))
 710           (format-time-string
 711            (if (and (<= past-cutoff diff) (<= diff 0))
 712                (if (and locale (not ls-lisp-use-localized-time-format))
 713                    "%m-%d %H:%M"
 714                  (nth 0 ls-lisp-format-time-list))
 715              (if (and locale (not ls-lisp-use-localized-time-format))
 716                  "%Y-%m-%d "
 717                (nth 1 ls-lisp-format-time-list)))
 718            time))
 719       (error "Unk  0  0000"))))
 720
 721 (defun ls-lisp-format-file-size (file-size human-readable)
 722   (if (not human-readable)
 723       (format (if (floatp file-size)
 724                   ls-lisp-filesize-f-fmt
 725                 ls-lisp-filesize-d-fmt)
 726               file-size)
 727     (format " %7s" (file-size-human-readable file-size))))
 728
 729 (provide 'ls-lisp)
 730
 731 ;;; ls-lisp.el ends here