lisp/cmuscheme.el

   1 ;;; cmuscheme.el --- Scheme process in a buffer. Adapted from tea.el
   2
   3 ;; Copyright (C) 1988, 1994, 1997, 2001-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Olin Shivers <olin.shivers@cs.cmu.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: processes, lisp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;    This is a customization of comint-mode (see comint.el)
  27 ;;
  28 ;; Written by Olin Shivers (olin.shivers@cs.cmu.edu). With bits and pieces
  29 ;; lifted from scheme.el, shell.el, clisp.el, newclisp.el, cobol.el, et al..
  30 ;; 8/88
  31 ;;
  32 ;; Please send me bug reports, bug fixes, and extensions, so that I can
  33 ;; merge them into the master source.
  34 ;;
  35 ;; The changelog is at the end of this file.
  36 ;;
  37 ;; NOTE: MIT Cscheme, when invoked with the -emacs flag, has a special user
  38 ;; interface that communicates process state back to the superior emacs by
  39 ;; outputting special control sequences. The gnumacs package, xscheme.el, has
  40 ;; lots and lots of special purpose code to read these control sequences, and
  41 ;; so is very tightly integrated with the cscheme process. The cscheme
  42 ;; interrupt handler and debugger read single character commands in cbreak
  43 ;; mode; when this happens, xscheme.el switches to special keymaps that bind
  44 ;; the single letter command keys to emacs functions that directly send the
  45 ;; character to the scheme process.  Cmuscheme mode does *not* provide this
  46 ;; functionality. If you are a cscheme user, you may prefer to use the
  47 ;; xscheme.el/cscheme -emacs interaction.
  48 ;;
  49 ;; Here's a summary of the pros and cons, as I see them.
  50 ;; xscheme: Tightly integrated with inferior cscheme process!  A few commands
  51 ;;           not in cmuscheme. But. Integration is a bit of a hack.  Input
  52 ;;           history only keeps the immediately prior input. Bizarre
  53 ;;           keybindings.
  54 ;;
  55 ;; cmuscheme: Not tightly integrated with inferior cscheme process.  But.
  56 ;;            Carefully integrated functionality with the entire suite of
  57 ;;            comint-derived CMU process modes. Keybindings reminiscent of
  58 ;;            Zwei and Hemlock. Good input history. A few commands not in
  59 ;;            xscheme.
  60 ;;
  61 ;; It's a tradeoff. Pay your money; take your choice. If you use a Scheme
  62 ;; that isn't Cscheme, of course, there isn't a choice. Xscheme.el is *very*
  63 ;; Cscheme-specific; you must use cmuscheme.el.  Interested parties are
  64 ;; invited to port xscheme functionality on top of comint mode...
  65
  66 ;;; CHANGE LOG
  67 ;; ===========================================================================
  68 ;; 8/88 Olin
  69 ;; Created.
  70 ;;
  71 ;; 2/15/89 Olin
  72 ;; Removed -emacs flag from process invocation. It's only useful for
  73 ;; cscheme, and makes cscheme assume it's running under xscheme.el,
  74 ;; which messes things up royally. A bug.
  75 ;;
  76 ;; 5/22/90 Olin
  77 ;; - Upgraded to use comint-send-string and comint-send-region.
  78 ;; - run-scheme now offers to let you edit the command line if
  79 ;;   you invoke it with a prefix-arg. M-x scheme is redundant, and
  80 ;;   has been removed.
  81 ;; - Explicit references to process "scheme" have been replaced with
  82 ;;   (scheme-proc). This allows better handling of multiple process bufs.
  83 ;; - Added scheme-send-last-sexp, bound to C-x C-e. A gnu convention.
  84 ;; - Have not added process query facility a la cmulisp.el's lisp-show-arglist
  85 ;;   and friends, but interested hackers might find a useful application
  86 ;;   of this facility.
  87 ;;
  88 ;; 3/12/90 Olin
  89 ;; - scheme-load-file and scheme-compile-file no longer switch-to-scheme.
  90 ;;   Tale suggested this.
  91
  92 ;;; Code:
  93
  94 (require 'scheme)
  95 (require 'comint)
  96
  97
  98 (defgroup cmuscheme nil
  99   "Run a scheme process in a buffer."
 100   :group 'scheme)
 101
 102 ;;; INFERIOR SCHEME MODE STUFF
 103 ;;;============================================================================
 104
 105 (defcustom inferior-scheme-mode-hook nil
 106   "Hook for customizing inferior-scheme mode."
 107   :type 'hook
 108   :group 'cmuscheme)
 109
 110 (defvar inferior-scheme-mode-map
 111   (let ((m (make-sparse-keymap)))
 112     (define-key m "\M-\C-x" 'scheme-send-definition) ;gnu convention
 113     (define-key m "\C-x\C-e" 'scheme-send-last-sexp)
 114     (define-key m "\C-c\C-l" 'scheme-load-file)
 115     (define-key m "\C-c\C-k" 'scheme-compile-file)
 116     (scheme-mode-commands m)
 117     m))
 118
 119 ;; Install the process communication commands in the scheme-mode keymap.
 120 (define-key scheme-mode-map "\M-\C-x" 'scheme-send-definition);gnu convention
 121 (define-key scheme-mode-map "\C-x\C-e" 'scheme-send-last-sexp);gnu convention
 122 (define-key scheme-mode-map "\C-c\C-e" 'scheme-send-definition)
 123 (define-key scheme-mode-map "\C-c\M-e" 'scheme-send-definition-and-go)
 124 (define-key scheme-mode-map "\C-c\C-r" 'scheme-send-region)
 125 (define-key scheme-mode-map "\C-c\M-r" 'scheme-send-region-and-go)
 126 (define-key scheme-mode-map "\C-c\M-c" 'scheme-compile-definition)
 127 (define-key scheme-mode-map "\C-c\C-c" 'scheme-compile-definition-and-go)
 128 (define-key scheme-mode-map "\C-c\C-t" 'scheme-trace-procedure)
 129 (define-key scheme-mode-map "\C-c\C-x" 'scheme-expand-current-form)
 130 (define-key scheme-mode-map "\C-c\C-z" 'switch-to-scheme)
 131 (define-key scheme-mode-map "\C-c\C-l" 'scheme-load-file)
 132 (define-key scheme-mode-map "\C-c\C-k" 'scheme-compile-file) ;k for "kompile"
 133
 134 (let ((map (lookup-key scheme-mode-map [menu-bar scheme])))
 135   (define-key map [separator-eval] '("--"))
 136   (define-key map [compile-file]
 137     '("Compile Scheme File" . scheme-compile-file))
 138   (define-key map [load-file]
 139     '("Load Scheme File" . scheme-load-file))
 140   (define-key map [switch]
 141     '("Switch to Scheme" . switch-to-scheme))
 142   (define-key map [com-def-go]
 143     '("Compile Definition & Go" . scheme-compile-definition-and-go))
 144   (define-key map [com-def]
 145     '("Compile Definition" . scheme-compile-definition))
 146   (define-key map [exp-form]
 147     '("Expand current form" . scheme-expand-current-form))
 148   (define-key map [trace-proc]
 149     '("Trace procedure" . scheme-trace-procedure))
 150   (define-key map [send-def-go]
 151     '("Evaluate Last Definition & Go" . scheme-send-definition-and-go))
 152   (define-key map [send-def]
 153     '("Evaluate Last Definition" . scheme-send-definition))
 154   (define-key map [send-region-go]
 155     '("Evaluate Region & Go" . scheme-send-region-and-go))
 156   (define-key map [send-region]
 157     '("Evaluate Region" . scheme-send-region))
 158   (define-key map [send-sexp]
 159     '("Evaluate Last S-expression" . scheme-send-last-sexp))
 160   )
 161
 162 (defvar scheme-buffer)
 163
 164 (define-derived-mode inferior-scheme-mode comint-mode "Inferior Scheme"
 165   "Major mode for interacting with an inferior Scheme process.
 166
 167 The following commands are available:
 168 \\{inferior-scheme-mode-map}
 169
 170 A Scheme process can be fired up with M-x run-scheme.
 171
 172 Customization: Entry to this mode runs the hooks on comint-mode-hook and
 173 inferior-scheme-mode-hook (in that order).
 174
 175 You can send text to the inferior Scheme process from other buffers containing
 176 Scheme source.
 177     switch-to-scheme switches the current buffer to the Scheme process buffer.
 178     scheme-send-definition sends the current definition to the Scheme process.
 179     scheme-compile-definition compiles the current definition.
 180     scheme-send-region sends the current region to the Scheme process.
 181     scheme-compile-region compiles the current region.
 182
 183     scheme-send-definition-and-go, scheme-compile-definition-and-go,
 184         scheme-send-region-and-go, and scheme-compile-region-and-go
 185         switch to the Scheme process buffer after sending their text.
 186 For information on running multiple processes in multiple buffers, see
 187 documentation for variable scheme-buffer.
 188
 189 Commands:
 190 Return after the end of the process' output sends the text from the
 191     end of process to point.
 192 Return before the end of the process' output copies the sexp ending at point
 193     to the end of the process' output, and sends it.
 194 Delete converts tabs to spaces as it moves back.
 195 Tab indents for Scheme; with argument, shifts rest
 196     of expression rigidly with the current line.
 197 C-M-q does Tab on each line starting within following expression.
 198 Paragraphs are separated only by blank lines.  Semicolons start comments.
 199 If you accidentally suspend your process, use \\[comint-continue-subjob]
 200 to continue it."
 201   ;; Customize in inferior-scheme-mode-hook
 202   (setq comint-prompt-regexp "^[^>\n]*>+ *") ; OK for cscheme, oaklisp, T,...
 203   (scheme-mode-variables)
 204   (setq mode-line-process '(":%s"))
 205   (setq comint-input-filter (function scheme-input-filter))
 206   (setq comint-get-old-input (function scheme-get-old-input)))
 207
 208 (defcustom inferior-scheme-filter-regexp "\\`\\s *\\S ?\\S ?\\s *\\'"
 209   "Input matching this regexp are not saved on the history list.
 210 Defaults to a regexp ignoring all inputs of 0, 1, or 2 letters."
 211   :type 'regexp
 212   :group 'cmuscheme)
 213
 214 (defun scheme-input-filter (str)
 215   "Don't save anything matching `inferior-scheme-filter-regexp'."
 216   (not (string-match inferior-scheme-filter-regexp str)))
 217
 218 (defun scheme-get-old-input ()
 219   "Snarf the sexp ending at point."
 220   (save-excursion
 221     (let ((end (point)))
 222       (backward-sexp)
 223       (buffer-substring (point) end))))
 224
 225 ;;;###autoload
 226 (defun run-scheme (cmd)
 227   "Run an inferior Scheme process, input and output via buffer `*scheme*'.
 228 If there is a process already running in `*scheme*', switch to that buffer.
 229 With argument, allows you to edit the command line (default is value
 230 of `scheme-program-name').
 231 If the file `~/.emacs_SCHEMENAME' or `~/.emacs.d/init_SCHEMENAME.scm' exists,
 232 it is given as initial input.
 233 Note that this may lose due to a timing error if the Scheme processor
 234 discards input when it starts up.
 235 Runs the hook `inferior-scheme-mode-hook' \(after the `comint-mode-hook'
 236 is run).
 237 \(Type \\[describe-mode] in the process buffer for a list of commands.)"
 238
 239   (interactive (list (if current-prefix-arg
 240                          (read-string "Run Scheme: " scheme-program-name)
 241                          scheme-program-name)))
 242   (if (not (comint-check-proc "*scheme*"))
 243       (let ((cmdlist (split-string-and-unquote cmd)))
 244         (set-buffer (apply 'make-comint "scheme" (car cmdlist)
 245                            (scheme-start-file (car cmdlist)) (cdr cmdlist)))
 246         (inferior-scheme-mode)))
 247   (setq scheme-program-name cmd)
 248   (setq scheme-buffer "*scheme*")
 249   (pop-to-buffer "*scheme*"))
 250 ;;;###autoload (add-hook 'same-window-buffer-names (purecopy "*scheme*"))
 251
 252 (defun scheme-start-file (prog)
 253   "Return the name of the start file corresponding to PROG.
 254 Search in the directories \"~\" and \"~/.emacs.d\", in this
 255 order.  Return nil if no start file found."
 256   (let* ((progname (file-name-nondirectory prog))
 257          (start-file (concat "~/.emacs_" progname))
 258          (alt-start-file (concat user-emacs-directory "init_" progname ".scm")))
 259     (if (file-exists-p start-file)
 260         start-file
 261       (and (file-exists-p alt-start-file) alt-start-file))))
 262
 263 (defun scheme-send-region (start end)
 264   "Send the current region to the inferior Scheme process."
 265   (interactive "r")
 266   (comint-send-region (scheme-proc) start end)
 267   (comint-send-string (scheme-proc) "\n"))
 268
 269 (defun scheme-send-definition ()
 270   "Send the current definition to the inferior Scheme process."
 271   (interactive)
 272   (save-excursion
 273    (end-of-defun)
 274    (let ((end (point)))
 275      (beginning-of-defun)
 276      (scheme-send-region (point) end))))
 277
 278 (defun scheme-send-last-sexp ()
 279   "Send the previous sexp to the inferior Scheme process."
 280   (interactive)
 281   (scheme-send-region (save-excursion (backward-sexp) (point)) (point)))
 282
 283 (defcustom scheme-compile-exp-command "(compile '%s)"
 284   "Template for issuing commands to compile arbitrary Scheme expressions."
 285   :type 'string
 286   :group 'cmuscheme)
 287
 288 (defun scheme-compile-region (start end)
 289   "Compile the current region in the inferior Scheme process.
 290 \(A BEGIN is wrapped around the region: (BEGIN <region>))"
 291   (interactive "r")
 292   (comint-send-string (scheme-proc) (format scheme-compile-exp-command
 293                                             (format "(begin %s)"
 294                                                     (buffer-substring start end))))
 295   (comint-send-string (scheme-proc) "\n"))
 296
 297 (defun scheme-compile-definition ()
 298   "Compile the current definition in the inferior Scheme process."
 299   (interactive)
 300   (save-excursion
 301    (end-of-defun)
 302    (let ((end (point)))
 303      (beginning-of-defun)
 304      (scheme-compile-region (point) end))))
 305
 306 (defcustom scheme-trace-command "(trace %s)"
 307   "Template for issuing commands to trace a Scheme procedure.
 308 Some Scheme implementations might require more elaborate commands here.
 309 For PLT-Scheme, e.g., one should use
 310
 311    (setq scheme-trace-command \"(begin (require (lib \\\"trace.ss\\\")) (trace %s))\")
 312
 313 For Scheme 48 and Scsh use \",trace %s\"."
 314   :type 'string
 315   :group 'cmuscheme)
 316
 317 (defcustom scheme-untrace-command "(untrace %s)"
 318   "Template for switching off tracing of a Scheme procedure.
 319 Scheme 48 and Scsh users should set this variable to \",untrace %s\"."
 320
 321   :type 'string
 322   :group 'cmuscheme)
 323
 324 (defun scheme-trace-procedure (proc &optional untrace)
 325   "Trace procedure PROC in the inferior Scheme process.
 326 With a prefix argument switch off tracing of procedure PROC."
 327   (interactive
 328    (list (let ((current (symbol-at-point))
 329                (action (if current-prefix-arg "Untrace" "Trace")))
 330            (if current
 331                (read-string (format "%s procedure [%s]: " action current) nil nil (symbol-name current))
 332              (read-string (format "%s procedure: " action))))
 333          current-prefix-arg))
 334   (when (= (length proc) 0)
 335     (error "Invalid procedure name"))
 336   (comint-send-string (scheme-proc)
 337                       (format
 338                        (if untrace scheme-untrace-command scheme-trace-command)
 339                        proc))
 340   (comint-send-string (scheme-proc) "\n"))
 341
 342 (defcustom scheme-macro-expand-command "(expand %s)"
 343   "Template for macro-expanding a Scheme form.
 344 For Scheme 48 and Scsh use \",expand %s\"."
 345   :type 'string
 346   :group 'cmuscheme)
 347
 348 (defun scheme-expand-current-form ()
 349   "Macro-expand the form at point in the inferior Scheme process."
 350   (interactive)
 351   (let ((current-form (scheme-form-at-point)))
 352     (if current-form
 353         (progn
 354           (comint-send-string (scheme-proc)
 355                               (format
 356                                scheme-macro-expand-command
 357                                current-form))
 358           (comint-send-string (scheme-proc) "\n"))
 359       (error "Not at a form"))))
 360
 361 (defun scheme-form-at-point ()
 362   (let ((next-sexp (thing-at-point 'sexp)))
 363     (if (and next-sexp (string-equal (substring next-sexp 0 1) "("))
 364         next-sexp
 365       (save-excursion
 366         (backward-up-list)
 367         (scheme-form-at-point)))))
 368
 369 (defun switch-to-scheme (eob-p)
 370   "Switch to the scheme process buffer.
 371 With argument, position cursor at end of buffer."
 372   (interactive "P")
 373   (if (or (and scheme-buffer (get-buffer scheme-buffer))
 374           (scheme-interactively-start-process))
 375       (pop-to-buffer scheme-buffer)
 376     (error "No current process buffer.  See variable `scheme-buffer'"))
 377   (when eob-p
 378     (push-mark)
 379     (goto-char (point-max))))
 380
 381 (defun scheme-send-region-and-go (start end)
 382   "Send the current region to the inferior Scheme process.
 383 Then switch to the process buffer."
 384   (interactive "r")
 385   (scheme-send-region start end)
 386   (switch-to-scheme t))
 387
 388 (defun scheme-send-definition-and-go ()
 389   "Send the current definition to the inferior Scheme.
 390 Then switch to the process buffer."
 391   (interactive)
 392   (scheme-send-definition)
 393   (switch-to-scheme t))
 394
 395 (defun scheme-compile-definition-and-go ()
 396   "Compile the current definition in the inferior Scheme.
 397 Then switch to the process buffer."
 398   (interactive)
 399   (scheme-compile-definition)
 400   (switch-to-scheme t))
 401
 402 (defun scheme-compile-region-and-go (start end)
 403   "Compile the current region in the inferior Scheme.
 404 Then switch to the process buffer."
 405   (interactive "r")
 406   (scheme-compile-region start end)
 407   (switch-to-scheme t))
 408
 409 (defcustom scheme-source-modes '(scheme-mode)
 410   "Used to determine if a buffer contains Scheme source code.
 411 If it's loaded into a buffer that is in one of these major modes, it's
 412 considered a scheme source file by `scheme-load-file' and `scheme-compile-file'.
 413 Used by these commands to determine defaults."
 414   :type '(repeat function)
 415   :group 'cmuscheme)
 416
 417 (defvar scheme-prev-l/c-dir/file nil
 418   "Caches the last (directory . file) pair.
 419 Caches the last pair used in the last `scheme-load-file' or
 420 `scheme-compile-file' command.  Used for determining the default
 421 in the next one.")
 422
 423 (defun scheme-load-file (file-name)
 424   "Load a Scheme file FILE-NAME into the inferior Scheme process."
 425   (interactive (comint-get-source "Load Scheme file: " scheme-prev-l/c-dir/file
 426                                   scheme-source-modes t)) ; t because `load'
 427                                                           ; needs an exact name
 428   (comint-check-source file-name) ; Check to see if buffer needs saved.
 429   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 430                                        (file-name-nondirectory file-name)))
 431   (comint-send-string (scheme-proc) (concat "(load \""
 432                                             file-name
 433                                             "\"\)\n")))
 434
 435 (defun scheme-compile-file (file-name)
 436   "Compile a Scheme file FILE-NAME in the inferior Scheme process."
 437   (interactive (comint-get-source "Compile Scheme file: "
 438                                   scheme-prev-l/c-dir/file
 439                                   scheme-source-modes
 440                                   nil)) ; nil because COMPILE doesn't
 441                                         ; need an exact name.
 442   (comint-check-source file-name) ; Check to see if buffer needs saved.
 443   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 444                                        (file-name-nondirectory file-name)))
 445   (comint-send-string (scheme-proc) (concat "(compile-file \""
 446                                             file-name
 447                                             "\"\)\n")))
 448
 449 \f
 450 (defvar scheme-buffer nil "*The current scheme process buffer.
 451
 452 MULTIPLE PROCESS SUPPORT
 453 ===========================================================================
 454 Cmuscheme.el supports, in a fairly simple fashion, running multiple Scheme
 455 processes.  To run multiple Scheme processes, you start the first up with
 456 \\[run-scheme].  It will be in a buffer named *scheme*.  Rename this buffer
 457 with \\[rename-buffer].  You may now start up a new process with another
 458 \\[run-scheme].  It will be in a new buffer, named *scheme*.  You can
 459 switch between the different process buffers with \\[switch-to-buffer].
 460
 461 Commands that send text from source buffers to Scheme processes --
 462 like `scheme-send-definition' or `scheme-compile-region' -- have to choose a
 463 process to send to, when you have more than one Scheme process around.  This
 464 is determined by the global variable `scheme-buffer'.  Suppose you
 465 have three inferior Schemes running:
 466     Buffer      Process
 467     foo         scheme
 468     bar         scheme<2>
 469     *scheme*    scheme<3>
 470 If you do a \\[scheme-send-definition-and-go] command on some Scheme source
 471 code, what process do you send it to?
 472
 473 - If you're in a process buffer (foo, bar, or *scheme*),
 474   you send it to that process.
 475 - If you're in some other buffer (e.g., a source file), you
 476   send it to the process attached to buffer `scheme-buffer'.
 477 This process selection is performed by function `scheme-proc'.
 478
 479 Whenever \\[run-scheme] fires up a new process, it resets `scheme-buffer'
 480 to be the new process's buffer.  If you only run one process, this will
 481 do the right thing.  If you run multiple processes, you can change
 482 `scheme-buffer' to another process buffer with \\[set-variable].
 483
 484 More sophisticated approaches are, of course, possible.  If you find yourself
 485 needing to switch back and forth between multiple processes frequently,
 486 you may wish to consider ilisp.el, a larger, more sophisticated package
 487 for running inferior Lisp and Scheme processes.  The approach taken here is
 488 for a minimal, simple implementation.  Feel free to extend it.")
 489
 490 (defun scheme-proc ()
 491   "Return the current Scheme process, starting one if necessary.
 492 See variable `scheme-buffer'."
 493   (unless (and scheme-buffer
 494                (get-buffer scheme-buffer)
 495                (comint-check-proc scheme-buffer))
 496     (scheme-interactively-start-process))
 497   (or (scheme-get-process)
 498       (error "No current process.  See variable `scheme-buffer'")))
 499
 500 (defun scheme-get-process ()
 501   "Return the current Scheme process or nil if none is running."
 502   (get-buffer-process (if (eq major-mode 'inferior-scheme-mode)
 503                           (current-buffer)
 504                         scheme-buffer)))
 505
 506 (defun scheme-interactively-start-process (&optional _cmd)
 507   "Start an inferior Scheme process.  Return the process started.
 508 Since this command is run implicitly, always ask the user for the
 509 command to run."
 510   (save-window-excursion
 511     (run-scheme (read-string "Run Scheme: " scheme-program-name))))
 512
 513 ;;; Do the user's customization...
 514
 515 (defcustom cmuscheme-load-hook nil
 516   "This hook is run when cmuscheme is loaded in.
 517 This is a good place to put keybindings."
 518   :type 'hook
 519   :group 'cmuscheme)
 520
 521 (run-hooks 'cmuscheme-load-hook)
 522
 523 (provide 'cmuscheme)
 524
 525 ;;; cmuscheme.el ends here