lisp/cus-dep.el

   1 ;;; cus-dep.el --- find customization dependencies
   2 ;;
   3 ;; Copyright (C) 1997, 2001-2014 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   6 ;; Keywords: internal
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'widget)
  29 (require 'cus-face)
  30
  31 (defvar generated-custom-dependencies-file "cus-load.el"
  32   "Output file for `custom-make-dependencies'.")
  33
  34 ;; See finder-no-scan-regexp in finder.el.
  35 (defvar custom-dependencies-no-scan-regexp "\\(^\\.#\\|\\(loaddefs\\|\
  36 ldefs-boot\\|cus-load\\|finder-inf\\|esh-groups\\|subdirs\\)\\.el$\\)"
  37   "Regexp matching file names not to scan for `custom-make-dependencies'.")
  38
  39 (require 'autoload)
  40
  41 ;; Hack workaround for bug#14384.
  42 ;; Define defcustom-mh as an alias for defcustom, etc.
  43 ;; Only do this in batch mode to avoid messing up a normal Emacs session.
  44 ;; Alternative would be to load mh-e when making cus-load.
  45 ;; (Would be better to split just the necessary parts of mh-e into a
  46 ;; separate file and only load that.)
  47 (when (and noninteractive)
  48   (mapc (lambda (e) (let ((sym (intern (format "%s-mh" e))))
  49                       (or (fboundp sym)
  50                           (defalias sym e))))
  51         '(defcustom defface defgroup)))
  52
  53 (defun custom-make-dependencies ()
  54   "Batch function to extract custom dependencies from .el files.
  55 Usage: emacs -batch -l ./cus-dep.el -f custom-make-dependencies DIRS"
  56   (let ((enable-local-eval nil)
  57         (enable-local-variables :safe)
  58         subdir)
  59     (with-temp-buffer
  60       ;; Use up command-line-args-left else Emacs can try to open
  61       ;; the args as directories after we are done.
  62       (while (setq subdir (pop command-line-args-left))
  63         (message "Directory %s" subdir)
  64         (let ((files (directory-files subdir nil "\\`[^=.].*\\.el\\'"))
  65               (default-directory (expand-file-name subdir))
  66               (preloaded (concat "\\`\\(\\./+\\)?"
  67                                  (regexp-opt preloaded-file-list t)
  68                                  "\\.el\\'")))
  69           (dolist (file files)
  70             (unless (or (string-match custom-dependencies-no-scan-regexp file)
  71                         (string-match preloaded (format "%s/%s" subdir file))
  72                         (not (file-exists-p file)))
  73               (erase-buffer)
  74               (kill-all-local-variables)
  75               (insert-file-contents file)
  76               (hack-local-variables)
  77               (goto-char (point-min))
  78               (string-match "\\`\\(.*\\)\\.el\\'" file)
  79               (let ((name (or generated-autoload-load-name ; see bug#5277
  80                               (file-name-nondirectory (match-string 1 file))))
  81                     (load-file-name file))
  82                 (if (save-excursion
  83                       (re-search-forward
  84                      (concat "(\\(cc-\\)?provide[ \t\n]+\\('\\|(quote[ \t\n]\\)[ \t\n]*"
  85                              (regexp-quote name) "[ \t\n)]")
  86                      nil t))
  87                     (setq name (intern name)))
  88                 (condition-case nil
  89                     (while (re-search-forward
  90                             "^(def\\(custom\\|face\\|group\\)" nil t)
  91                       (beginning-of-line)
  92                       (let ((type (match-string 1))
  93                             (expr (read (current-buffer))))
  94                         (condition-case nil
  95                             (let ((custom-dont-initialize t))
  96                               ;; Eval to get the 'custom-group, -tag,
  97                               ;; -version, group-documentation etc properties.
  98                               (put (nth 1 expr) 'custom-where name)
  99                               (eval expr))
 100                           ;; Eval failed for some reason.  Eg maybe the
 101                           ;; defcustom uses something defined earlier
 102                           ;; in the file (we haven't loaded the file).
 103                           ;; In most cases, we can still get the :group.
 104                           (error
 105                            (ignore-errors
 106                              (let ((group (cadr (memq :group expr))))
 107                                (and group
 108                                     (eq (car group) 'quote)
 109                                     (custom-add-to-group
 110                                      (cadr group)
 111                                      (nth 1 expr)
 112                                      (intern (format "custom-%s"
 113                                                      (if (equal type "custom")
 114                                                          "variable"
 115                                                        type)))))))))))
 116                   (error nil)))))))))
 117   (message "Generating %s..." generated-custom-dependencies-file)
 118   (set-buffer (find-file-noselect generated-custom-dependencies-file))
 119   (setq buffer-undo-list t)
 120   (erase-buffer)
 121   (insert (autoload-rubric generated-custom-dependencies-file
 122                            "custom dependencies" t))
 123   (search-backward "\f")
 124   (let (alist)
 125     (mapatoms (lambda (symbol)
 126                 (let ((members (get symbol 'custom-group))
 127                       where found)
 128                   (when members
 129                     (dolist (member (mapcar 'car members))
 130                       (setq where (get member 'custom-where))
 131                       (unless (or (null where)
 132                                   (member where found))
 133                         (push where found)))
 134                     (when found
 135                       (push (cons (symbol-name symbol)
 136                                   (with-output-to-string
 137                                     (prin1 (sort found 'string<)))) alist))))))
 138     (dolist (e (sort alist (lambda (e1 e2) (string< (car e1) (car e2)))))
 139       (insert "(put '" (car e) " 'custom-loads '" (cdr e) ")\n")))
 140   (insert "\
 141
 142 ;; The remainder of this file is for handling :version.
 143 ;; We provide a minimum of information so that `customize-changed-options'
 144 ;; can do its job.
 145
 146 ;; For groups we set `custom-version', `group-documentation' and
 147 ;; `custom-tag' (which are shown in the customize buffer), so we
 148 ;; don't have to load the file containing the group.
 149
 150 ;; This macro is used so we don't modify the information about
 151 ;; variables and groups if it's already set. (We don't know when
 152 ;; " (file-name-nondirectory generated-custom-dependencies-file)
 153       " is going to be loaded and at that time some of the
 154 ;; files might be loaded and some others might not).
 155 \(defmacro custom-put-if-not (symbol propname value)
 156   `(unless (get ,symbol ,propname)
 157      (put ,symbol ,propname ,value)))
 158
 159 ")
 160   (let ((version-alist nil)
 161         groups)
 162     (mapatoms (lambda (symbol)
 163                 (let ((version (get symbol 'custom-version))
 164                       where)
 165                   (when version
 166                     (setq where (get symbol 'custom-where))
 167                     (when where
 168                       (if (or (custom-variable-p symbol)
 169                               (custom-facep symbol))
 170                           ;; This means it's a variable or a face.
 171                           (progn
 172                             (if (assoc version version-alist)
 173                                 (unless
 174                                     (member where
 175                                             (cdr (assoc version version-alist)))
 176                                   (push where (cdr (assoc version version-alist))))
 177                               (push (list version where) version-alist)))
 178                         ;; This is a group
 179                         (push (list (symbol-name symbol)
 180                                     (with-output-to-string (prin1 version))
 181                                     (with-output-to-string
 182                                       (prin1 (get symbol 'group-documentation)))
 183                                     (if (get symbol 'custom-tag)
 184                                         (with-output-to-string
 185                                           (prin1 (get symbol 'custom-tag)))))
 186                               groups)))))))
 187     (dolist (e (sort groups (lambda (e1 e2) (string< (car e1) (car e2)))))
 188       (insert "(custom-put-if-not '" (car e) " 'custom-version '"
 189               (nth 1 e) ")\n")
 190       (insert "(custom-put-if-not '" (car e) " 'group-documentation "
 191               (nth 2 e) ")\n")
 192       (if (nth 3 e)
 193           (insert "(custom-put-if-not '" (car e) " 'custom-tag "
 194                   (nth 3 e) ")\n")))
 195
 196     (insert "\n(defvar custom-versions-load-alist "
 197             (if version-alist "'" ""))
 198     (prin1 (sort version-alist (lambda (e1 e2) (version< (car e1) (car e2))))
 199            (current-buffer))
 200     (insert "\n  \"For internal use by custom.
 201 This is an alist whose members have as car a version string, and as
 202 elements the files that have variables or faces that contain that
 203 version.  These files should be loaded before showing the customization
 204 buffer that `customize-changed-options' generates.\")\n\n"))
 205   (save-buffer)
 206   (message "Generating %s...done" generated-custom-dependencies-file))
 207
 208 \f
 209 (provide 'cus-dep)
 210
 211 ;;; cus-dep.el ends here