lisp/gnus/gnus-undo.el

   1 ;;; gnus-undo.el --- minor mode for undoing in Gnus
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This package allows arbitrary undoing in Gnus buffers.  As all the
  27 ;; Gnus buffers aren't very text-oriented (what is in the buffers is
  28 ;; just some arbitrary representation of the actual data), normal Emacs
  29 ;; undoing doesn't work at all for Gnus.
  30 ;;
  31 ;; This package works by letting Gnus register functions for reversing
  32 ;; actions, and then calling these functions when the user pushes the
  33 ;; `undo' key.  As with normal `undo', there it is possible to set
  34 ;; undo boundaries and so on.
  35 ;;
  36 ;; Internally, the undo sequence is represented by the
  37 ;; `gnus-undo-actions' list, where each element is a list of functions
  38 ;; to be called, in sequence, to undo some action.  (An "action" is a
  39 ;; collection of functions.)
  40 ;;
  41 ;; For instance, a function for killing a group will call
  42 ;; `gnus-undo-register' with a function that un-kills the group.  This
  43 ;; package will put that function into an action.
  44
  45 ;;; Code:
  46
  47 (eval-when-compile (require 'cl))
  48
  49 (require 'gnus-util)
  50 (require 'gnus)
  51
  52 (defgroup gnus-undo nil
  53   "Undoing in Gnus buffers."
  54   :group 'gnus)
  55
  56 (defcustom gnus-undo-limit 2000
  57   "The number of undoable actions recorded."
  58   :type 'integer
  59   :group 'gnus-undo)
  60
  61 (defcustom gnus-undo-mode nil
  62   "Minor mode for undoing in Gnus buffers."
  63   :type 'boolean
  64   :group 'gnus-undo)
  65
  66 (defcustom gnus-undo-mode-hook nil
  67   "Hook called in all `gnus-undo-mode' buffers."
  68   :type 'hook
  69   :group 'gnus-undo)
  70
  71 ;;; Internal variables.
  72
  73 (defvar gnus-undo-actions nil)
  74 (defvar gnus-undo-boundary t)
  75 (defvar gnus-undo-last nil)
  76 (defvar gnus-undo-boundary-inhibit nil)
  77
  78 ;;; Minor mode definition.
  79
  80 (defvar gnus-undo-mode-map nil)
  81
  82 (unless gnus-undo-mode-map
  83   (setq gnus-undo-mode-map (make-sparse-keymap))
  84
  85   (gnus-define-keys gnus-undo-mode-map
  86     "\M-\C-_"     gnus-undo
  87     "\C-_"        gnus-undo
  88     "\C-xu"       gnus-undo
  89     ;; many people are used to type `C-/' on X terminals and get `C-_'.
  90     [(control /)] gnus-undo))
  91
  92 (defun gnus-undo-make-menu-bar ()
  93   ;; This is disabled for the time being.
  94   (when nil
  95     (define-key-after (current-local-map) [menu-bar file gnus-undo]
  96       (cons "Undo" 'gnus-undo-actions)
  97       [menu-bar file whatever])))
  98
  99 (defun gnus-undo-mode (&optional arg)
 100   "Minor mode for providing `undo' in Gnus buffers.
 101
 102 \\{gnus-undo-mode-map}"
 103   (interactive "P")
 104   (set (make-local-variable 'gnus-undo-mode)
 105        (if (null arg) (not gnus-undo-mode)
 106          (> (prefix-numeric-value arg) 0)))
 107   (set (make-local-variable 'gnus-undo-actions) nil)
 108   (set (make-local-variable 'gnus-undo-boundary) t)
 109   (when gnus-undo-mode
 110     ;; Set up the menu.
 111     (when (gnus-visual-p 'undo-menu 'menu)
 112       (gnus-undo-make-menu-bar))
 113     (add-minor-mode 'gnus-undo-mode "" gnus-undo-mode-map)
 114     (gnus-make-local-hook 'post-command-hook)
 115     (add-hook 'post-command-hook 'gnus-undo-boundary nil t)
 116     (gnus-run-hooks 'gnus-undo-mode-hook)))
 117
 118 ;;; Interface functions.
 119
 120 (defun gnus-disable-undo (&optional buffer)
 121   "Disable undoing in the current buffer."
 122   (interactive)
 123   (save-excursion
 124     (when buffer
 125       (set-buffer buffer))
 126     (gnus-undo-mode -1)))
 127
 128 (defun gnus-undo-boundary ()
 129   "Set Gnus undo boundary."
 130   (if gnus-undo-boundary-inhibit
 131       (setq gnus-undo-boundary-inhibit nil)
 132     (setq gnus-undo-boundary t)))
 133
 134 (defun gnus-undo-force-boundary ()
 135   "Set Gnus undo boundary."
 136   (setq gnus-undo-boundary-inhibit nil
 137         gnus-undo-boundary t))
 138
 139 (defun gnus-undo-register (form)
 140   "Register FORMS as something to be performed to undo a change.
 141 FORMS may use backtick quote syntax."
 142   (when gnus-undo-mode
 143     (gnus-undo-register-1
 144      `(lambda ()
 145         ,form))))
 146
 147 (put 'gnus-undo-register 'lisp-indent-function 0)
 148 (put 'gnus-undo-register 'edebug-form-spec '(body))
 149
 150 (defun gnus-undo-register-1 (function)
 151   "Register FUNCTION as something to be performed to undo a change."
 152   (when gnus-undo-mode
 153     (cond
 154      ;; We are on a boundary, so we create a new action.
 155      (gnus-undo-boundary
 156       (push (list function) gnus-undo-actions)
 157       (setq gnus-undo-boundary nil))
 158      ;; Prepend the function to an old action.
 159      (gnus-undo-actions
 160       (setcar gnus-undo-actions (cons function (car gnus-undo-actions))))
 161      ;; Initialize list.
 162      (t
 163       (setq gnus-undo-actions (list (list function)))))
 164     ;; Limit the length of the undo list.
 165     (let ((next (nthcdr gnus-undo-limit gnus-undo-actions)))
 166       (when next
 167         (setcdr next nil)))
 168     ;; We are not at a boundary...
 169     (setq gnus-undo-boundary-inhibit t)))
 170
 171 (defun gnus-undo (n)
 172   "Undo some previous changes in Gnus buffers.
 173 Repeat this command to undo more changes.
 174 A numeric argument serves as a repeat count."
 175   (interactive "p")
 176   (unless gnus-undo-mode
 177     (error "Undoing is not enabled in this buffer"))
 178   (message "%s" last-command)
 179   (when (or (not (eq last-command 'gnus-undo))
 180             (not gnus-undo-last))
 181     (setq gnus-undo-last gnus-undo-actions))
 182   (let ((action (pop gnus-undo-last)))
 183     (unless action
 184       (error "Nothing further to undo"))
 185     (setq gnus-undo-actions (delq action gnus-undo-actions))
 186     (setq gnus-undo-boundary t)
 187     (mapc 'funcall action)))
 188
 189 (provide 'gnus-undo)
 190
 191 ;; arch-tag: 0d787bc7-787d-499a-837f-211d2cb07f2e
 192 ;;; gnus-undo.el ends here