lisp/userlock.el

   1 ;;; userlock.el --- handle file access contention between multiple users
   2
   3 ;; Copyright (C) 1985, 1986 Free Software Foundation, inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This file is autoloaded to handle certain conditions
  28 ;; detected by the file-locking code within Emacs.
  29 ;; The two entry points are `ask-user-about-lock' and
  30 ;; `ask-user-about-supersession-threat'.
  31
  32 ;;; Code:
  33
  34 (put 'file-locked 'error-conditions '(file-locked file-error error))
  35 (put 'file-locked 'error-message "File is locked")
  36
  37 ;;;###autoload
  38 (defun ask-user-about-lock (file opponent)
  39   "Ask user what to do when he wants to edit FILE but it is locked by OPPONENT.
  40 This function has a choice of three things to do:
  41   do (signal 'file-locked (list FILE OPPONENT))
  42     to refrain from editing the file
  43   return t (grab the lock on the file)
  44   return nil (edit the file even though it is locked).
  45 You can redefine this function to choose among those three alternatives
  46 in any way you like."
  47   (discard-input)
  48   (save-window-excursion
  49     (let (answer short-opponent short-file)
  50       (setq short-file
  51             (if (> (length file) 22)
  52                 (concat "..." (substring file (- (length file) 22)))
  53               file))
  54       (setq short-opponent
  55             (if (> (length opponent) 25)
  56                 (save-match-data
  57                   (string-match " (pid [0-9]+)" opponent)
  58                   (concat (substring opponent 0 13) "..."
  59                           (match-string 0 opponent)))
  60               opponent))
  61       (while (null answer)
  62         (message "%s locked by %s: (s, q, p, ?)? "
  63                  short-file short-opponent)
  64         (let ((tem (let ((inhibit-quit t)
  65                          (cursor-in-echo-area t))
  66                      (prog1 (downcase (read-char))
  67                             (setq quit-flag nil)))))
  68           (if (= tem help-char)
  69               (ask-user-about-lock-help)
  70             (setq answer (assoc tem '((?s . t)
  71                                       (?q . yield)
  72                                       (?\C-g . yield)
  73                                       (?p . nil)
  74                                       (?? . help))))
  75             (cond ((null answer)
  76                    (beep)
  77                    (message "Please type q, s, or p; or ? for help")
  78                    (sit-for 3))
  79                   ((eq (cdr answer) 'help)
  80                    (ask-user-about-lock-help)
  81                    (setq answer nil))
  82                   ((eq (cdr answer) 'yield)
  83                    (signal 'file-locked (list file opponent)))))))
  84       (cdr answer))))
  85
  86 (defun ask-user-about-lock-help ()
  87   (with-output-to-temp-buffer "*Help*"
  88     (princ "It has been detected that you want to modify a file that someone else has
  89 already started modifying in EMACS.
  90
  91 You can <s>teal the file; The other user becomes the
  92   intruder if (s)he ever unmodifies the file and then changes it again.
  93 You can <p>roceed; you edit at your own (and the other user's) risk.
  94 You can <q>uit; don't modify this file.")
  95     (save-excursion
  96       (set-buffer standard-output)
  97       (help-mode))))
  98
  99 (put
 100  'file-supersession 'error-conditions '(file-supersession file-error error))
 101
 102 ;;;###autoload
 103 (defun ask-user-about-supersession-threat (fn)
 104   "Ask a user who is about to modify an obsolete buffer what to do.
 105 This function has two choices: it can return, in which case the modification
 106 of the buffer will proceed, or it can (signal 'file-supersession (file)),
 107 in which case the proposed buffer modification will not be made.
 108
 109 You can rewrite this to use any criterion you like to choose which one to do.
 110 The buffer in question is current when this function is called."
 111   (discard-input)
 112   (save-window-excursion
 113     (let (answer)
 114       (while (null answer)
 115         (message "%s changed on disk; really edit the buffer? (y, n, r or C-h) "
 116                  (file-name-nondirectory fn))
 117         (let ((tem (downcase (let ((cursor-in-echo-area t))
 118                                (read-char-exclusive)))))
 119           (setq answer
 120                 (if (= tem help-char)
 121                     'help
 122                   (cdr (assoc tem '((?n . yield)
 123                                     (?\C-g . yield)
 124                                     (?y . proceed)
 125                                     (?r . revert)
 126                                     (?? . help))))))
 127           (cond ((null answer)
 128                  (beep)
 129                  (message "Please type y, n or r; or ? for help")
 130                  (sit-for 3))
 131                 ((eq answer 'help)
 132                  (ask-user-about-supersession-help)
 133                  (setq answer nil))
 134                 ((eq answer 'revert)
 135                  (revert-buffer nil (not (buffer-modified-p)))
 136                                         ; ask confirmation iff buffer modified
 137                  (signal 'file-supersession
 138                          (list "File reverted" fn)))
 139                 ((eq answer 'yield)
 140                  (signal 'file-supersession
 141                          (list "File changed on disk" fn))))))
 142       (message
 143         "File on disk now will become a backup file if you save these changes.")
 144       (setq buffer-backed-up nil))))
 145
 146 (defun ask-user-about-supersession-help ()
 147   (with-output-to-temp-buffer "*Help*"
 148     (princ "You want to modify a buffer whose disk file has changed
 149 since you last read it in or saved it with this buffer.
 150
 151 If you say `y' to go ahead and modify this buffer,
 152 you risk ruining the work of whoever rewrote the file.
 153 If you say `r' to revert, the contents of the buffer are refreshed
 154 from the file on disk.
 155 If you say `n', the change you started to make will be aborted.
 156
 157 Usually, you should type `n' and then `M-x revert-buffer',
 158 to get the latest version of the file, then make the change again.")
 159     (save-excursion
 160       (set-buffer standard-output)
 161       (help-mode))))
 162
 163 ;;; arch-tag: a61c5b60-e1c8-44fd-894a-c617f4dfc639
 164 ;;; userlock.el ends here