lisp/calendar/cal-julian.el

   1 ;;; cal-julian.el --- calendar functions for the Julian calendar
   2
   3 ;; Copyright (C) 1995, 1997, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 ;;   2008  Free Software Foundation, Inc.
   5
   6 ;; Author: Edward M. Reingold <reingold@cs.uiuc.edu>
   7 ;; Maintainer: Glenn Morris <rgm@gnu.org>
   8 ;; Keywords: calendar
   9 ;; Human-Keywords: Julian calendar, Julian day number, calendar, diary
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This collection of functions implements the features of calendar.el and
  31 ;; diary.el that deal with the Julian calendar.
  32
  33 ;; Technical details of all the calendrical calculations can be found in
  34 ;; ``Calendrical Calculations: The Millennium Edition'' by Edward M. Reingold
  35 ;; and Nachum Dershowitz, Cambridge University Press (2001).
  36
  37 ;;; Code:
  38
  39 (defvar displayed-month)
  40 (defvar displayed-year)
  41
  42 (require 'calendar)
  43
  44 ;;;###autoload
  45 (defun calendar-julian-from-absolute (date)
  46   "Compute the Julian (month day year) corresponding to the absolute DATE.
  47 The absolute date is the number of days elapsed since the (imaginary)
  48 Gregorian date Sunday, December 31, 1 BC."
  49   (let* ((approx (/ (+ date 2) 366));; Approximation from below.
  50          (year        ;; Search forward from the approximation.
  51           (+ approx
  52              (calendar-sum y approx
  53                 (>= date (calendar-absolute-from-julian (list 1 1 (1+ y))))
  54                 1)))
  55          (month       ;; Search forward from January.
  56           (1+ (calendar-sum m 1
  57                  (> date
  58                     (calendar-absolute-from-julian
  59                      (list m
  60                            (if (and (= m 2) (= (% year 4) 0))
  61                                29
  62                              (aref [31 28 31 30 31 30 31 31 30 31 30 31]
  63                                    (1- m)))
  64                            year)))
  65                  1)))
  66          (day         ;; Calculate the day by subtraction.
  67           (- date (1- (calendar-absolute-from-julian (list month 1 year))))))
  68     (list month day year)))
  69
  70 (defun calendar-absolute-from-julian (date)
  71   "The number of days elapsed between the Gregorian date 12/31/1 BC and DATE.
  72 The Gregorian date Sunday, December 31, 1 BC is imaginary."
  73   (let ((month (extract-calendar-month date))
  74         (day (extract-calendar-day date))
  75         (year (extract-calendar-year date)))
  76     (+ (calendar-day-number date)
  77        (if (and (zerop (% year 100))
  78                 (/= (% year 400) 0)
  79                 (> month 2))
  80            1 0);; Correct for Julian but not Gregorian leap year.
  81        (* 365 (1- year))
  82        (/ (1- year) 4)
  83        -2)))
  84
  85 ;;;###autoload
  86 (defun calendar-julian-date-string (&optional date)
  87   "String of Julian date of Gregorian DATE.
  88 Defaults to today's date if DATE is not given.
  89 Driven by the variable `calendar-date-display-form'."
  90   (calendar-date-string
  91    (calendar-julian-from-absolute
  92     (calendar-absolute-from-gregorian
  93      (or date (calendar-current-date))))
  94    nil t))
  95
  96 ;;;###autoload
  97 (defun calendar-print-julian-date ()
  98   "Show the Julian calendar equivalent of the date under the cursor."
  99   (interactive)
 100   (message "Julian date: %s"
 101            (calendar-julian-date-string (calendar-cursor-to-date t))))
 102
 103 ;;;###autoload
 104 (defun calendar-goto-julian-date (date &optional noecho)
 105   "Move cursor to Julian DATE; echo Julian date unless NOECHO is t."
 106   (interactive
 107    (let* ((today (calendar-current-date))
 108           (year (calendar-read
 109                  "Julian calendar year (>0): "
 110                  (lambda (x) (> x 0))
 111                  (int-to-string
 112                   (extract-calendar-year
 113                    (calendar-julian-from-absolute
 114                     (calendar-absolute-from-gregorian
 115                      today))))))
 116           (month-array calendar-month-name-array)
 117           (completion-ignore-case t)
 118           (month (cdr (assoc-string
 119                         (completing-read
 120                          "Julian calendar month name: "
 121                          (mapcar 'list (append month-array nil))
 122                          nil t)
 123                        (calendar-make-alist month-array 1) t)))
 124           (last
 125            (if (and (zerop (% year 4)) (= month 2))
 126                29
 127              (aref [31 28 31 30 31 30 31 31 30 31 30 31] (1- month))))
 128           (day (calendar-read
 129                 (format "Julian calendar day (%d-%d): "
 130                         (if (and (= year 1) (= month 1)) 3 1) last)
 131                 (lambda (x)
 132                    (and (< (if (and (= year 1) (= month 1)) 2 0) x)
 133                         (<= x last))))))
 134      (list (list month day year))))
 135   (calendar-goto-date (calendar-gregorian-from-absolute
 136                        (calendar-absolute-from-julian date)))
 137   (or noecho (calendar-print-julian-date)))
 138
 139 (defun holiday-julian (month day string)
 140   "Holiday on MONTH, DAY  (Julian) called STRING.
 141 If MONTH, DAY (Julian) is visible, the value returned is corresponding
 142 Gregorian date in the form of the list (((month day year) STRING)).  Returns
 143 nil if it is not visible in the current calendar window."
 144   (let ((m1 displayed-month)
 145         (y1 displayed-year)
 146         (m2 displayed-month)
 147         (y2 displayed-year)
 148         (year))
 149     (increment-calendar-month m1 y1 -1)
 150     (increment-calendar-month m2 y2 1)
 151     (let* ((start-date (calendar-absolute-from-gregorian
 152                         (list m1 1 y1)))
 153            (end-date (calendar-absolute-from-gregorian
 154                       (list m2 (calendar-last-day-of-month m2 y2) y2)))
 155            (julian-start (calendar-julian-from-absolute start-date))
 156            (julian-end (calendar-julian-from-absolute end-date))
 157            (julian-y1 (extract-calendar-year julian-start))
 158            (julian-y2 (extract-calendar-year julian-end)))
 159       (setq year (if (< 10 month) julian-y1 julian-y2))
 160       (let ((date (calendar-gregorian-from-absolute
 161                    (calendar-absolute-from-julian
 162                     (list month day year)))))
 163         (if (calendar-date-is-visible-p date)
 164             (list (list date string)))))))
 165
 166 (defvar date)
 167
 168 ;; To be called from list-sexp-diary-entries, where DATE is bound.
 169 (defun diary-julian-date ()
 170   "Julian calendar equivalent of date diary entry."
 171   (format "Julian date: %s" (calendar-julian-date-string date)))
 172
 173 ;;;###autoload
 174 (defun calendar-absolute-from-astro (d)
 175   "Absolute date of astronomical (Julian) day number D."
 176   (- d 1721424.5))
 177
 178 ;;;###autoload
 179 (defun calendar-astro-from-absolute (d)
 180   "Astronomical (Julian) day number of absolute date D."
 181   (+ d 1721424.5))
 182
 183 ;;;###autoload
 184 (defun calendar-astro-date-string (&optional date)
 185   "String of astronomical (Julian) day number after noon UTC of Gregorian DATE.
 186 Defaults to today's date if DATE is not given."
 187   (int-to-string
 188    (ceiling
 189     (calendar-astro-from-absolute
 190      (calendar-absolute-from-gregorian
 191       (or date (calendar-current-date)))))))
 192
 193 ;;;###autoload
 194 (defun calendar-print-astro-day-number ()
 195   "Show astronomical (Julian) day number after noon UTC on date shown by cursor."
 196   (interactive)
 197   (message
 198    "Astronomical (Julian) day number (at noon UTC): %s.0"
 199    (calendar-astro-date-string (calendar-cursor-to-date t))))
 200
 201 ;;;###autoload
 202 (defun calendar-goto-astro-day-number (daynumber &optional noecho)
 203   "Move cursor to astronomical (Julian) DAYNUMBER.
 204 Echo astronomical (Julian) day number unless NOECHO is t."
 205   (interactive (list (calendar-read
 206                       "Astronomical (Julian) day number (>1721425): "
 207                       (lambda (x) (> x 1721425)))))
 208   (calendar-goto-date
 209    (calendar-gregorian-from-absolute
 210     (floor
 211      (calendar-absolute-from-astro daynumber))))
 212   (or noecho (calendar-print-astro-day-number)))
 213
 214 ;; To be called from list-sexp-diary-entries, where DATE is bound.
 215 (defun diary-astro-day-number ()
 216   "Astronomical (Julian) day number diary entry."
 217   (format "Astronomical (Julian) day number at noon UTC: %s.0"
 218           (calendar-astro-date-string date)))
 219
 220 (provide 'cal-julian)
 221
 222 ;; Local Variables:
 223 ;; generated-autoload-file: "cal-loaddefs.el"
 224 ;; End:
 225
 226 ;; arch-tag: 0520acdd-1c60-4188-9aa8-9b8c24d856ae
 227 ;;; cal-julian.el ends here