lisp/delsel.el

   1 ;;; delsel.el --- delete selection if you insert
   2
   3 ;;; Copyright (C) 1992 Free Software Foundation, Inc.
   4
   5 ;; Author: Matthieu Devin <devin@lucid.com>
   6 ;; Created: 14 Jul 92
   7 ;; Last change  18-Feb-93, devin.
   8
   9 ;;; This file is part of GNU Emacs.
  10
  11 ;;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;;; it under the terms of the GNU General Public License as published by
  13 ;;; the Free Software Foundation; either version 2, or (at your option)
  14 ;;; any later version.
  15
  16 ;;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;;; GNU General Public License for more details.
  20
  21 ;;; You should have received a copy of the GNU General Public License
  22 ;;; along with GNU Emacs; see the file COPYING.  If not, write to
  23 ;;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; This file makes the active region be pending delete, meaning that
  28 ;;; text inserted while the region is active will replace the region contents.
  29 ;;; This is a popular behavior of personal computers text editors.
  30
  31 ;;; Code:
  32
  33 (defvar delete-selection-mode t
  34   "*Non-nil means Delete Selection mode is enabled.
  35 In Delete Selection mode, when a region is highlighted,
  36 insertion commands first delete the region and then insert.")
  37
  38 (defun delete-active-region (&optional killp)
  39   (if killp
  40       (kill-region (point) (mark))
  41     (delete-region (point) (mark)))
  42   (setq mark-active nil)
  43   (run-hooks 'deactivate-mark-hook)
  44   t)
  45
  46 (defun delete-selection-pre-hook ()
  47   (if (and delete-selection-mode
  48            (not buffer-read-only)
  49            transient-mark-mode mark-active)
  50       (let ((type (and (symbolp this-command)
  51                        (get this-command 'delete-selection))))
  52         (cond ((eq type 'kill)
  53                (delete-active-region t))
  54               ((eq type 'supersede)
  55                (if (delete-active-region nil)
  56                    (setq this-command '(lambda () (interactive)))))
  57               (type
  58                (delete-active-region nil))))))
  59
  60 (add-hook 'pre-command-hook 'delete-selection-pre-hook)
  61
  62 (put 'self-insert-command 'delete-selection t)
  63
  64 (put 'yank 'delete-selection t)
  65 (put 'insert-register 'delete-selection t)
  66
  67 (put 'delete-backward-char 'delete-selection 'supersede)
  68 (put 'backward-delete-char-untabify 'delete-selection 'supersede)
  69 (put 'delete-char 'delete-selection 'supersede)
  70
  71 (put 'newline-and-indent 'delete-selection 't)
  72 (put 'newline 'delete-selection t)
  73 (put 'open-line 'delete-selection t)
  74
  75 ;;;###autoload
  76 (defalias 'pending-delete-mode 'delete-selection-mode)
  77 ;;;###autoload
  78 (defun delete-selection-mode (arg)
  79   "Toggle Delete Selection mode.
  80 When ON, typed text replaces the selection if the selection is active.
  81 When OFF, typed text is just inserted at point."
  82   (interactive "P")
  83   (setq delete-selection-mode
  84         (if (null arg) (not delete-selection-mode)
  85           (> (prefix-numeric-value arg) 0)))
  86   (set-buffer-modified-p (buffer-modified-p))) ;No-op, but updates mode line.
  87
  88 ;; This is very useful for cancelling a selection in the minibuffer without
  89 ;; aborting the minibuffer.
  90 (defun minibuffer-keyboard-quit ()
  91   "Abort recursive edit.
  92 In Delete Selection mode mode, if the mark is active, just deactivate it;
  93 then it takes a second C-g to abort the minibuffer."
  94   (interactive)
  95   (if (and delete-selection-mode transient-mark-mode mark-active)
  96       (setq deactivate-mark t)
  97     (abort-recursive-edit)))
  98
  99 (define-key minibuffer-local-map "\C-g" 'minibuffer-keyboard-quit)
 100 (define-key minibuffer-local-ns-map "\C-g" 'minibuffer-keyboard-quit)
 101 (define-key minibuffer-local-completion-map "\C-g" 'minibuffer-keyboard-quit)
 102 (define-key minibuffer-local-must-match-map "\C-g" 'minibuffer-keyboard-quit)
 103 (define-key minibuffer-local-isearch-map "\C-g" 'minibuffer-keyboard-quit)
 104
 105 (provide 'delsel)
 106
 107 ;;; delsel.el ends here