lisp/emacs-lisp/debug.el

   1 ;;; debug.el --- debuggers and related commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1994, 2001 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: lisp, tools, maint
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This is a major mode documented in the Emacs manual.
  28
  29 ;;; Code:
  30
  31 (require 'button)
  32
  33 (defgroup debugger nil
  34   "Debuggers and related commands for Emacs."
  35   :prefix "debugger-"
  36   :group 'debug)
  37
  38 (defcustom debugger-mode-hook nil
  39   "*Hooks run when `debugger-mode' is turned on."
  40   :type 'hook
  41   :group 'debugger
  42   :version "20.3")
  43
  44 (defcustom debugger-batch-max-lines 40
  45   "*Maximum lines to show in debugger buffer in a noninteractive Emacs.
  46 When the debugger is entered and Emacs is running in batch mode,
  47 if the backtrace text has more than this many lines,
  48 the middle is discarded, and just the beginning and end are displayed."
  49   :type 'integer
  50   :group 'debugger
  51   :version "21.1")
  52
  53 (defcustom debug-function-list nil
  54   "List of functions currently set for debug on entry."
  55   :type '(repeat function)
  56   :group 'debugger)
  57
  58 (defcustom debugger-step-after-exit nil
  59   "Non-nil means \"single-step\" after the debugger exits."
  60   :type 'boolean
  61   :group 'debugger)
  62
  63 (defvar debugger-value nil
  64   "This is the value for the debugger to return, when it returns.")
  65
  66 (defvar debugger-old-buffer nil
  67   "This is the buffer that was current when the debugger was entered.")
  68
  69 (defvar debugger-previous-backtrace nil
  70   "The contents of the previous backtrace (including text properties).
  71 This is to optimize `debugger-make-xrefs'.")
  72
  73 (defvar debugger-outer-match-data)
  74 (defvar debugger-outer-load-read-function)
  75 (defvar debugger-outer-overriding-local-map)
  76 (defvar debugger-outer-overriding-terminal-local-map)
  77 (defvar debugger-outer-track-mouse)
  78 (defvar debugger-outer-last-command)
  79 (defvar debugger-outer-this-command)
  80 (defvar debugger-outer-unread-command-char)
  81 (defvar debugger-outer-unread-command-events)
  82 (defvar debugger-outer-unread-post-input-method-events)
  83 (defvar debugger-outer-last-input-event)
  84 (defvar debugger-outer-last-command-event)
  85 (defvar debugger-outer-last-nonmenu-event)
  86 (defvar debugger-outer-last-event-frame)
  87 (defvar debugger-outer-standard-input)
  88 (defvar debugger-outer-standard-output)
  89 (defvar debugger-outer-inhibit-redisplay)
  90 (defvar debugger-outer-cursor-in-echo-area)
  91
  92 ;;;###autoload
  93 (setq debugger 'debug)
  94 ;;;###autoload
  95 (defun debug (&rest debugger-args)
  96   "Enter debugger.  To return, type \\<debugger-mode-map>`\\[debugger-continue]'.
  97 Arguments are mainly for use when this is called from the internals
  98 of the evaluator.
  99
 100 You may call with no args, or you may pass nil as the first arg and
 101 any other args you like.  In that case, the list of args after the
 102 first will be printed into the backtrace buffer."
 103   (interactive)
 104   (unless noninteractive
 105     (message "Entering debugger..."))
 106   (let (debugger-value
 107         (debug-on-error nil)
 108         (debug-on-quit nil)
 109         (debugger-buffer (let ((default-major-mode 'fundamental-mode))
 110                            (get-buffer-create "*Backtrace*")))
 111         (debugger-old-buffer (current-buffer))
 112         (debugger-step-after-exit nil)
 113         ;; Don't keep reading from an executing kbd macro!
 114         (executing-kbd-macro nil)
 115         ;; Save the outer values of these vars for the `e' command
 116         ;; before we replace the values.
 117         (debugger-outer-match-data (match-data))
 118         (debugger-outer-load-read-function load-read-function)
 119         (debugger-outer-overriding-local-map overriding-local-map)
 120         (debugger-outer-overriding-terminal-local-map
 121          overriding-terminal-local-map)
 122         (debugger-outer-track-mouse track-mouse)
 123         (debugger-outer-last-command last-command)
 124         (debugger-outer-this-command this-command)
 125         (debugger-outer-unread-command-char unread-command-char)
 126         (debugger-outer-unread-command-events unread-command-events)
 127         (debugger-outer-unread-post-input-method-events
 128          unread-post-input-method-events)
 129         (debugger-outer-last-input-event last-input-event)
 130         (debugger-outer-last-command-event last-command-event)
 131         (debugger-outer-last-nonmenu-event last-nonmenu-event)
 132         (debugger-outer-last-event-frame last-event-frame)
 133         (debugger-outer-standard-input standard-input)
 134         (debugger-outer-standard-output standard-output)
 135         (debugger-outer-inhibit-redisplay inhibit-redisplay)
 136         (debugger-outer-cursor-in-echo-area cursor-in-echo-area))
 137     ;; Set this instead of binding it, so that `q'
 138     ;; will not restore it.
 139     (setq overriding-terminal-local-map nil)
 140     ;; Don't let these magic variables affect the debugger itself.
 141     (let ((last-command nil) this-command track-mouse
 142           (unread-command-char -1) unread-command-events
 143           unread-post-input-method-events
 144           last-input-event last-command-event last-nonmenu-event
 145           last-event-frame
 146           overriding-local-map
 147           load-read-function
 148           ;; If we are inside a minibuffer, allow nesting
 149           ;; so that we don't get an error from the `e' command.
 150           (enable-recursive-minibuffers
 151            (or enable-recursive-minibuffers (> (minibuffer-depth) 0)))
 152           (standard-input t) (standard-output t)
 153           inhibit-redisplay
 154           (cursor-in-echo-area nil))
 155       (unwind-protect
 156           (save-excursion
 157             (save-window-excursion
 158               (pop-to-buffer debugger-buffer)
 159               (debugger-mode)
 160               (debugger-setup-buffer debugger-args)
 161               (when noninteractive
 162                 ;; If the backtrace is long, save the beginning
 163                 ;; and the end, but discard the middle.
 164                 (when (> (count-lines (point-min) (point-max))
 165                          debugger-batch-max-lines)
 166                   (goto-char (point-min))
 167                   (forward-line (/ 2 debugger-batch-max-lines))
 168                   (let ((middlestart (point)))
 169                     (goto-char (point-max))
 170                     (forward-line (- (/ 2 debugger-batch-max-lines)
 171                                      debugger-batch-max-lines))
 172                     (delete-region middlestart (point)))
 173                   (insert "...\n"))
 174                 (goto-char (point-min))
 175                 (message (buffer-string))
 176                 (kill-emacs))
 177               (if (eq (car debugger-args) 'debug)
 178                   ;; Skip the frames for backtrace-debug, byte-code, and debug.
 179                   (backtrace-debug 3 t))
 180               (debugger-reenable)
 181               (message "")
 182               (let ((inhibit-trace t)
 183                     (standard-output nil)
 184                     (buffer-read-only t))
 185                 (message "")
 186                 ;; Make sure we unbind buffer-read-only in the right buffer.
 187                 (save-excursion
 188                   (recursive-edit)))))
 189         ;; Kill or at least neuter the backtrace buffer, so that users
 190         ;; don't try to execute debugger commands in an invalid context.
 191         (if (get-buffer-window debugger-buffer 'visible)
 192             ;; Still visible despite the save-window-excursion?  Maybe it
 193             ;; it's in a pop-up frame.  It would be annoying to delete and
 194             ;; recreate it every time the debugger stops, so instead we'll
 195             ;; erase it but leave it visible.
 196             (save-excursion
 197               (set-buffer debugger-buffer)
 198               (erase-buffer)
 199               (fundamental-mode))
 200           (kill-buffer debugger-buffer))
 201         (set-match-data debugger-outer-match-data)))
 202     ;; Put into effect the modified values of these variables
 203     ;; in case the user set them with the `e' command.
 204     (setq load-read-function debugger-outer-load-read-function)
 205     (setq overriding-local-map debugger-outer-overriding-local-map)
 206     (setq overriding-terminal-local-map
 207           debugger-outer-overriding-terminal-local-map)
 208     (setq track-mouse debugger-outer-track-mouse)
 209     (setq last-command debugger-outer-last-command)
 210     (setq this-command debugger-outer-this-command)
 211     (setq unread-command-char debugger-outer-unread-command-char)
 212     (setq unread-command-events debugger-outer-unread-command-events)
 213     (setq unread-post-input-method-events
 214           debugger-outer-unread-post-input-method-events)
 215     (setq last-input-event debugger-outer-last-input-event)
 216     (setq last-command-event debugger-outer-last-command-event)
 217     (setq last-nonmenu-event debugger-outer-last-nonmenu-event)
 218     (setq last-event-frame debugger-outer-last-event-frame)
 219     (setq standard-input debugger-outer-standard-input)
 220     (setq standard-output debugger-outer-standard-output)
 221     (setq inhibit-redisplay debugger-outer-inhibit-redisplay)
 222     (setq cursor-in-echo-area debugger-outer-cursor-in-echo-area)
 223     (setq debug-on-next-call debugger-step-after-exit)
 224     debugger-value))
 225 \f
 226 (defun debugger-setup-buffer (debugger-args)
 227   "Initialize the `*Backtrace*' buffer for entry to the debugger.
 228 That buffer should be current already."
 229   (setq buffer-read-only nil)
 230   (erase-buffer)
 231   (set-buffer-multibyte nil)
 232   (let ((standard-output (current-buffer))
 233         (print-escape-newlines t)
 234         (print-level 8)
 235         (print-length 50))
 236     (backtrace))
 237   (goto-char (point-min))
 238   (delete-region (point)
 239                  (progn
 240                    (search-forward "\n  debug(")
 241                    (forward-line 1)
 242                    (point)))
 243   (insert "Debugger entered")
 244   ;; lambda is for debug-on-call when a function call is next.
 245   ;; debug is for debug-on-entry function called.
 246   (cond ((memq (car debugger-args) '(lambda debug))
 247          (insert "--entering a function:\n")
 248          (if (eq (car debugger-args) 'debug)
 249              (progn
 250                (delete-char 1)
 251                (insert ?*)
 252                (beginning-of-line))))
 253         ;; Exiting a function.
 254         ((eq (car debugger-args) 'exit)
 255          (insert "--returning value: ")
 256          (setq debugger-value (nth 1 debugger-args))
 257          (prin1 debugger-value (current-buffer))
 258          (insert ?\n)
 259          (delete-char 1)
 260          (insert ? )
 261          (beginning-of-line))
 262         ;; Debugger entered for an error.
 263         ((eq (car debugger-args) 'error)
 264          (insert "--Lisp error: ")
 265          (prin1 (nth 1 debugger-args) (current-buffer))
 266          (insert ?\n))
 267         ;; debug-on-call, when the next thing is an eval.
 268         ((eq (car debugger-args) t)
 269          (insert "--beginning evaluation of function call form:\n"))
 270         ;; User calls debug directly.
 271         (t
 272          (insert ": ")
 273          (prin1 (if (eq (car debugger-args) 'nil)
 274                     (cdr debugger-args) debugger-args)
 275                 (current-buffer))
 276          (insert ?\n)))
 277   ;; After any frame that uses eval-buffer,
 278   ;; insert a line that states the buffer position it's reading at.
 279   (save-excursion
 280     (while (re-search-forward "^  eval-buffer(" nil t)
 281       (end-of-line)
 282       (insert (format "\n  ;;; Reading at buffer position %d"
 283                       (with-current-buffer (nth 2 (backtrace-frame (debugger-frame-number)))
 284                         (point))))))
 285   (debugger-make-xrefs))
 286
 287 (defun debugger-make-xrefs (&optional buffer)
 288   "Attach cross-references to symbol names in the `*Backtrace*' buffer."
 289   (interactive "b")
 290   (save-excursion
 291     (set-buffer (or buffer (current-buffer)))
 292     (setq buffer (current-buffer))
 293     (let ((buffer-read-only nil)
 294           (old-end (point-min)) (new-end (point-min)))
 295       ;; If we saved an old backtrace, find the common part
 296       ;; between the new and the old.
 297       ;; Compare line by line, starting from the end,
 298       ;; because that's the part that is likely to be unchanged.
 299       (if debugger-previous-backtrace
 300           (let (old-start new-start (all-match t))
 301             (goto-char (point-max))
 302             (with-temp-buffer
 303               (insert debugger-previous-backtrace)
 304               (while (and all-match (not (bobp)))
 305                 (setq old-end (point))
 306                 (forward-line -1)
 307                 (setq old-start (point))
 308                 (with-current-buffer buffer
 309                   (setq new-end (point))
 310                   (forward-line -1)
 311                   (setq new-start (point)))
 312                 (if (not (zerop
 313                           (compare-buffer-substrings
 314                            (current-buffer) old-start old-end
 315                            buffer new-start new-end)))
 316                     (setq all-match nil))))
 317             ;; Now new-end is the position of the start of the
 318             ;; unchanged part in the current buffer, and old-end is
 319             ;; the position of that same text in the saved old
 320             ;; backtrace.  But we must subtract (point-min) since strings are
 321             ;; indexed in origin 0.
 322
 323             ;; Replace the unchanged part of the backtrace
 324             ;; with the text from debugger-previous-backtrace,
 325             ;; since that already has the proper xrefs.
 326             ;; With this optimization, we only need to scan
 327             ;; the changed part of the backtrace.
 328             (delete-region new-end (point-max))
 329             (goto-char (point-max))
 330             (insert (substring debugger-previous-backtrace
 331                                (- old-end (point-min))))
 332             ;; Make the unchanged part of the backtrace inaccessible
 333             ;; so it won't be scanned.
 334             (narrow-to-region (point-min) new-end)))
 335
 336       ;; Scan the new part of the backtrace, inserting xrefs.
 337       (goto-char (point-min))
 338       (while (progn
 339                (skip-syntax-forward "^w_")
 340                (not (eobp)))
 341         (let* ((beg (point))
 342                (end (progn (skip-syntax-forward "w_") (point)))
 343                (sym (intern-soft (buffer-substring-no-properties
 344                                   beg end)))
 345                (file (and sym (symbol-file sym))))
 346           (when file
 347             (goto-char beg)
 348             ;; help-xref-button needs to operate on something matched
 349             ;; by a regexp, so set that up for it.
 350             (re-search-forward "\\(\\(\\sw\\|\\s_\\)+\\)")
 351             (help-xref-button 1 'help-function-def sym file)))
 352         (forward-line 1))
 353       (widen))
 354     (setq debugger-previous-backtrace (buffer-string))))
 355 \f
 356 (defun debugger-step-through ()
 357   "Proceed, stepping through subexpressions of this expression.
 358 Enter another debugger on next entry to eval, apply or funcall."
 359   (interactive)
 360   (setq debugger-step-after-exit t)
 361   (message "Proceeding, will debug on next eval or call.")
 362   (exit-recursive-edit))
 363
 364 (defun debugger-continue ()
 365   "Continue, evaluating this expression without stopping."
 366   (interactive)
 367   (unless debugger-may-continue
 368     (error "Cannot continue"))
 369   (message "Continuing.")
 370   (exit-recursive-edit))
 371
 372 (defun debugger-return-value (val)
 373   "Continue, specifying value to return.
 374 This is only useful when the value returned from the debugger
 375 will be used, such as in a debug on exit from a frame."
 376   (interactive "XReturn value (evaluated): ")
 377   (setq debugger-value val)
 378   (princ "Returning " t)
 379   (prin1 debugger-value)
 380   (exit-recursive-edit))
 381
 382 (defun debugger-jump ()
 383   "Continue to exit from this frame, with all debug-on-entry suspended."
 384   (interactive)
 385   (debugger-frame)
 386   ;; Turn off all debug-on-entry functions
 387   ;; but leave them in the list.
 388   (let ((list debug-function-list))
 389     (while list
 390       (fset (car list)
 391             (debug-on-entry-1 (car list) (symbol-function (car list)) nil))
 392       (setq list (cdr list))))
 393   (message "Continuing through this frame")
 394   (exit-recursive-edit))
 395
 396 (defun debugger-reenable ()
 397   "Turn all debug-on-entry functions back on."
 398   (let ((list debug-function-list))
 399     (while list
 400       (or (consp (symbol-function (car list)))
 401           (debug-convert-byte-code (car list)))
 402       (fset (car list)
 403             (debug-on-entry-1 (car list) (symbol-function (car list)) t))
 404       (setq list (cdr list)))))
 405
 406 (defun debugger-frame-number ()
 407   "Return number of frames in backtrace before the one point points at."
 408   (save-excursion
 409     (beginning-of-line)
 410     (let ((opoint (point))
 411           (count 0))
 412       (while (not (eq (cadr (backtrace-frame count)) 'debug))
 413         (setq count (1+ count)))
 414       (goto-char (point-min))
 415       (if (or (equal (buffer-substring (point) (+ (point) 6))
 416                      "Signal")
 417               (equal (buffer-substring (point) (+ (point) 6))
 418                      "Return"))
 419           (progn
 420             (search-forward ":")
 421             (forward-sexp 1)))
 422       (forward-line 1)
 423       (while (progn
 424                (forward-char 2)
 425                (if (= (following-char) ?\()
 426                    (forward-sexp 1)
 427                  (forward-sexp 2))
 428                (forward-line 1)
 429                (<= (point) opoint))
 430         (if (looking-at " *;;;")
 431             (forward-line 1))
 432         (setq count (1+ count)))
 433       count)))
 434
 435 (defun debugger-frame ()
 436   "Request entry to debugger when this frame exits.
 437 Applies to the frame whose line point is on in the backtrace."
 438   (interactive)
 439   (save-excursion
 440     (beginning-of-line)
 441     (if (looking-at " *;;;\\|[a-z]")
 442         (error "This line is not a function call")))
 443   (beginning-of-line)
 444   (backtrace-debug (debugger-frame-number) t)
 445   (if (= (following-char) ? )
 446       (let ((buffer-read-only nil))
 447         (delete-char 1)
 448         (insert ?*)))
 449   (beginning-of-line))
 450
 451 (defun debugger-frame-clear ()
 452   "Do not enter debugger when this frame exits.
 453 Applies to the frame whose line point is on in the backtrace."
 454   (interactive)
 455   (save-excursion
 456     (beginning-of-line)
 457     (if (looking-at " *;;;\\|[a-z]")
 458         (error "This line is not a function call")))
 459   (beginning-of-line)
 460   (backtrace-debug (debugger-frame-number) nil)
 461   (if (= (following-char) ?*)
 462       (let ((buffer-read-only nil))
 463         (delete-char 1)
 464         (insert ? )))
 465   (beginning-of-line))
 466
 467
 468
 469 (put 'debugger-env-macro 'lisp-indent-function 0)
 470 (defmacro debugger-env-macro (&rest body)
 471   "Run BODY in original environment."
 472   `(save-excursion
 473     (if (null (buffer-name debugger-old-buffer))
 474         ;; old buffer deleted
 475         (setq debugger-old-buffer (current-buffer)))
 476     (set-buffer debugger-old-buffer)
 477     (let ((load-read-function debugger-outer-load-read-function)
 478           (overriding-terminal-local-map
 479            debugger-outer-overriding-terminal-local-map)
 480           (overriding-local-map debugger-outer-overriding-local-map)
 481           (track-mouse debugger-outer-track-mouse)
 482           (last-command debugger-outer-last-command)
 483           (this-command debugger-outer-this-command)
 484           (unread-command-char debugger-outer-unread-command-char)
 485           (unread-command-events debugger-outer-unread-command-events)
 486           (unread-post-input-method-events
 487            debugger-outer-unread-post-input-method-events)
 488           (last-input-event debugger-outer-last-input-event)
 489           (last-command-event debugger-outer-last-command-event)
 490           (last-nonmenu-event debugger-outer-last-nonmenu-event)
 491           (last-event-frame debugger-outer-last-event-frame)
 492           (standard-input debugger-outer-standard-input)
 493           (standard-output debugger-outer-standard-output)
 494           (inhibit-redisplay debugger-outer-inhibit-redisplay)
 495           (cursor-in-echo-area debugger-outer-cursor-in-echo-area))
 496       (set-match-data debugger-outer-match-data)
 497       (prog1 (progn ,@body)
 498         (setq debugger-outer-match-data (match-data))
 499         (setq debugger-outer-load-read-function load-read-function)
 500         (setq debugger-outer-overriding-terminal-local-map
 501               overriding-terminal-local-map)
 502         (setq debugger-outer-overriding-local-map overriding-local-map)
 503         (setq debugger-outer-track-mouse track-mouse)
 504         (setq debugger-outer-last-command last-command)
 505         (setq debugger-outer-this-command this-command)
 506         (setq debugger-outer-unread-command-char unread-command-char)
 507         (setq debugger-outer-unread-command-events unread-command-events)
 508         (setq debugger-outer-unread-post-input-method-events
 509               unread-post-input-method-events)
 510         (setq debugger-outer-last-input-event last-input-event)
 511         (setq debugger-outer-last-command-event last-command-event)
 512         (setq debugger-outer-last-nonmenu-event last-nonmenu-event)
 513         (setq debugger-outer-last-event-frame last-event-frame)
 514         (setq debugger-outer-standard-input standard-input)
 515         (setq debugger-outer-standard-output standard-output)
 516         (setq debugger-outer-inhibit-redisplay inhibit-redisplay)
 517         (setq debugger-outer-cursor-in-echo-area cursor-in-echo-area)
 518         ))))
 519
 520 (defun debugger-eval-expression (exp)
 521   "Eval an expression, in an environment like that outside the debugger."
 522   (interactive
 523    (list (read-from-minibuffer "Eval: "
 524                                nil read-expression-map t
 525                                'read-expression-history)))
 526   (debugger-env-macro (eval-expression exp)))
 527 \f
 528 (defvar debugger-mode-map nil)
 529 (unless debugger-mode-map
 530   (let ((loop ? ))
 531     (setq debugger-mode-map (make-keymap))
 532     (set-keymap-parent debugger-mode-map button-buffer-map)
 533     (suppress-keymap debugger-mode-map)
 534     (define-key debugger-mode-map "-" 'negative-argument)
 535     (define-key debugger-mode-map "b" 'debugger-frame)
 536     (define-key debugger-mode-map "c" 'debugger-continue)
 537     (define-key debugger-mode-map "j" 'debugger-jump)
 538     (define-key debugger-mode-map "r" 'debugger-return-value)
 539     (define-key debugger-mode-map "u" 'debugger-frame-clear)
 540     (define-key debugger-mode-map "d" 'debugger-step-through)
 541     (define-key debugger-mode-map "l" 'debugger-list-functions)
 542     (define-key debugger-mode-map "h" 'describe-mode)
 543     (define-key debugger-mode-map "q" 'top-level)
 544     (define-key debugger-mode-map "e" 'debugger-eval-expression)
 545     (define-key debugger-mode-map " " 'next-line)
 546     (define-key debugger-mode-map "R" 'debugger-record-expression)
 547     (define-key debugger-mode-map "\C-m" 'help-follow)
 548     (define-key debugger-mode-map [mouse-2] 'push-button)
 549     ))
 550
 551
 552 (defcustom debugger-record-buffer "*Debugger-record*"
 553   "*Buffer name for expression values, for \\[debugger-record-expression]."
 554   :type 'string
 555   :group 'debugger
 556   :version "20.3")
 557
 558 (defun debugger-record-expression  (exp)
 559   "Display a variable's value and record it in `*Backtrace-record*' buffer."
 560   (interactive
 561    (list (read-from-minibuffer
 562           "Record Eval: "
 563           nil
 564           read-expression-map t
 565           'read-expression-history)))
 566   (let* ((buffer (get-buffer-create debugger-record-buffer))
 567          (standard-output buffer))
 568     (princ (format "Debugger Eval (%s): " exp))
 569     (princ (debugger-eval-expression exp))
 570     (terpri))
 571
 572   (with-current-buffer (get-buffer debugger-record-buffer)
 573     (save-excursion
 574       (forward-line -1)
 575       (message
 576        (buffer-substring (point) (progn (end-of-line) (point)))))))
 577
 578 (put 'debugger-mode 'mode-class 'special)
 579
 580 (defun debugger-mode ()
 581   "Mode for backtrace buffers, selected in debugger.
 582 \\<debugger-mode-map>
 583 A line starts with `*' if exiting that frame will call the debugger.
 584 Type \\[debugger-frame] or \\[debugger-frame-clear] to set or remove the `*'.
 585
 586 When in debugger due to frame being exited,
 587 use the \\[debugger-return-value] command to override the value
 588 being returned from that frame.
 589
 590 Use \\[debug-on-entry] and \\[cancel-debug-on-entry] to control
 591 which functions will enter the debugger when called.
 592
 593 Complete list of commands:
 594 \\{debugger-mode-map}"
 595   (kill-all-local-variables)
 596   (setq major-mode 'debugger-mode)
 597   (setq mode-name "Debugger")
 598   (setq truncate-lines t)
 599   (set-syntax-table emacs-lisp-mode-syntax-table)
 600   (use-local-map debugger-mode-map)
 601   (run-hooks 'debugger-mode-hook))
 602 \f
 603 ;;;###autoload
 604 (defun debug-on-entry (function)
 605   "Request FUNCTION to invoke debugger each time it is called.
 606 If you tell the debugger to continue, FUNCTION's execution proceeds.
 607 This works by modifying the definition of FUNCTION,
 608 which must be written in Lisp, not predefined.
 609 Use \\[cancel-debug-on-entry] to cancel the effect of this command.
 610 Redefining FUNCTION also cancels it."
 611   (interactive "aDebug on entry (to function): ")
 612   (debugger-reenable)
 613   ;; Handle a function that has been aliased to some other function.
 614   (if (symbolp (symbol-function function))
 615       (fset function `(lambda (&rest debug-on-entry-args)
 616                         (apply ',(symbol-function function)
 617                                debug-on-entry-args))))
 618   (if (subrp (symbol-function function))
 619       (error "Function %s is a primitive" function))
 620   (or (consp (symbol-function function))
 621       (debug-convert-byte-code function))
 622   (or (consp (symbol-function function))
 623       (error "Definition of %s is not a list" function))
 624   (fset function (debug-on-entry-1 function (symbol-function function) t))
 625   (or (memq function debug-function-list)
 626       (push function debug-function-list))
 627   function)
 628
 629 ;;;###autoload
 630 (defun cancel-debug-on-entry (&optional function)
 631   "Undo effect of \\[debug-on-entry] on FUNCTION.
 632 If argument is nil or an empty string, cancel for all functions."
 633   (interactive
 634    (list (let ((name
 635                 (completing-read "Cancel debug on entry (to function): "
 636                                  (mapcar 'symbol-name debug-function-list)
 637                                  nil t nil)))
 638            (if name (intern name)))))
 639   (debugger-reenable)
 640   (if (and function (not (string= function "")))
 641       (progn
 642         (fset function
 643               (debug-on-entry-1 function (symbol-function function) nil))
 644         (setq debug-function-list (delq function debug-function-list))
 645         function)
 646     (message "Cancelling debug-on-entry for all functions")
 647     (mapcar 'cancel-debug-on-entry debug-function-list)))
 648
 649 (defun debug-convert-byte-code (function)
 650   (let ((defn (symbol-function function)))
 651     (if (not (consp defn))
 652         ;; Assume a compiled code object.
 653         (let* ((contents (append defn nil))
 654                (body
 655                 (list (list 'byte-code (nth 1 contents)
 656                             (nth 2 contents) (nth 3 contents)))))
 657           (if (nthcdr 5 contents)
 658               (setq body (cons (list 'interactive (nth 5 contents)) body)))
 659           (if (nth 4 contents)
 660               ;; Use `documentation' here, to get the actual string,
 661               ;; in case the compiled function has a reference
 662               ;; to the .elc file.
 663               (setq body (cons (documentation function) body)))
 664           (fset function (cons 'lambda (cons (car contents) body)))))))
 665
 666 (defun debug-on-entry-1 (function defn flag)
 667   (if (subrp defn)
 668       (error "%s is a built-in function" function)
 669     (if (eq (car defn) 'macro)
 670         (debug-on-entry-1 function (cdr defn) flag)
 671       (or (eq (car defn) 'lambda)
 672           (error "%s not user-defined Lisp function" function))
 673       (let (tail prec)
 674         (if (stringp (car (nthcdr 2 defn)))
 675             (setq tail (nthcdr 3 defn)
 676                   prec (list (car defn) (car (cdr defn))
 677                              (car (cdr (cdr defn)))))
 678           (setq tail (nthcdr 2 defn)
 679                 prec (list (car defn) (car (cdr defn)))))
 680         (if (eq flag (equal (car tail) '(debug 'debug)))
 681             defn
 682           (if flag
 683               (nconc prec (cons '(debug 'debug) tail))
 684             (nconc prec (cdr tail))))))))
 685
 686 (defun debugger-list-functions ()
 687   "Display a list of all the functions now set to debug on entry."
 688   (interactive)
 689   (with-output-to-temp-buffer "*Help*"
 690     (if (null debug-function-list)
 691         (princ "No debug-on-entry functions now\n")
 692       (princ "Functions set to debug on entry:\n\n")
 693       (let ((list debug-function-list))
 694         (while list
 695           (prin1 (car list))
 696           (terpri)
 697           (setq list (cdr list))))
 698       (princ "Note: if you have redefined a function, then it may no longer\n")
 699       (princ "be set to debug on entry, even if it is in the list."))
 700     (save-excursion
 701       (set-buffer standard-output)
 702       (help-mode))))
 703
 704 (provide 'debug)
 705
 706 ;;; debug.el ends here