configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.62)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 dnl FIXME hesiod support may not be present, so it seems like an error
  95 dnl to define, or at least use, this unconditionally.
  96 if test "$with_hesiod" != no; then
  97   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  98 fi
  99
 100 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 101 if test "$with_mmdf" != no; then
 102    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 106 if test "$with_mail_unlink" != no; then
 107    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 108 fi
 109
 110 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 111     [string giving default POP mail host])],
 112     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 113
 114 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 115
 116 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 117 if test "$with_sync_input" = yes; then
 118    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 119 fi
 120
 121 dnl FIXME currently it is not the last.
 122 dnl This should be the last --with option, because --with-x is
 123 dnl added later on when we find the path of X, and it's best to
 124 dnl keep them together visually.
 125 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 126  [use an X toolkit (KIT one of: yes or gtk, lucid or athena, motif, no)])],
 127 [         case "${withval}" in
 128             y | ye | yes )      val=gtk ;;
 129             n | no )            val=no  ;;
 130             l | lu | luc | luci | lucid )       val=lucid ;;
 131             a | at | ath | athe | athen | athena )      val=athena ;;
 132             m | mo | mot | moti | motif )       val=motif ;;
 133             g | gt | gtk  )     val=gtk ;;
 134             * )
 135 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 136 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 137 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 138             ;;
 139           esac
 140           with_x_toolkit=$val
 141 ])
 142
 143 dnl _ON results in a '--without' option in the --help output, so
 144 dnl the help text should refer to "don't compile", etc.
 145 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 146 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 147 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 148 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 149 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 150 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 151
 152 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 153 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 154 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 155
 156 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 157 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 158 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 159 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 160
 161 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 162 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 163 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 164 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 165
 166 ## For the times when you want to build Emacs but don't have
 167 ## a suitable makeinfo, and can live without the manuals.
 168 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 169 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 170
 171 dnl Can remove these in Emacs 24.
 172 AC_ARG_WITH([gtk],,
 173   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 174 specify a toolkit.])],,)
 175
 176 AC_ARG_WITH([gcc],,
 177   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 178 variable to specify a compiler.])],,)
 179
 180 AC_ARG_WITH([pkg-config-prog],dnl
 181 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 182                   [path to pkg-config for finding GTK and librsvg])])
 183 if test "X${with_pkg_config_prog}" != X; then
 184    if test "${with_pkg_config_prog}" != yes; then
 185       PKG_CONFIG="${with_pkg_config_prog}"
 186    fi
 187 fi
 188
 189 CRT_DIR=
 190 AC_ARG_WITH([crt-dir],dnl
 191 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 192 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 193 CRT_DIR="${with_crt_dir}"
 194
 195 AC_ARG_WITH([gnustep-conf],dnl
 196 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 197 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 198   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 199 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 200      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 201
 202 AC_ARG_ENABLE(ns-self-contained,
 203 [AS_HELP_STRING([--disable-ns-self-contained],
 204                 [disable self contained build under NeXTstep])],
 205    EN_NS_SELF_CONTAINED=$enableval,
 206    EN_NS_SELF_CONTAINED=yes)
 207
 208 AC_ARG_ENABLE(asserts,
 209 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 210       USE_XASSERTS=$enableval,
 211       USE_XASSERTS=no)
 212
 213 AC_ARG_ENABLE(maintainer-mode,
 214 [AS_HELP_STRING([--enable-maintainer-mode],
 215                 [enable make rules and dependencies not useful (and sometimes
 216                  confusing) to the casual installer])],
 217       USE_MAINTAINER_MODE=$enableval,
 218       USE_MAINTAINER_MODE=no)
 219 if test $USE_MAINTAINER_MODE = yes; then
 220   MAINT=
 221 else
 222   MAINT=#
 223 fi
 224 AC_SUBST(MAINT)
 225
 226 AC_ARG_ENABLE(locallisppath,
 227 [AS_HELP_STRING([--enable-locallisppath=PATH],
 228                 [directories Emacs should search for lisp files specific
 229                  to this site])],
 230 if test "${enableval}" = "no"; then
 231   locallisppath=
 232 elif test "${enableval}" != "yes"; then
 233   locallisppath=${enableval}
 234 fi)
 235
 236 AC_ARG_ENABLE(checking,
 237 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 238                 [enable expensive run-time checks.  With LIST,
 239                  enable only specific categories of checks.
 240                  Categories are: all,yes,no.
 241                  Flags are: stringbytes, stringoverrun, stringfreelist,
 242                  xmallocoverrun, conslist])],
 243 [ac_checking_flags="${enableval}"],[])
 244 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 245 for check in $ac_checking_flags
 246 do
 247         case $check in
 248         # these set all the flags to specific states
 249         yes)            ac_enable_checking=1 ;;
 250         no)             ac_enable_checking= ;
 251                         ac_gc_check_stringbytes= ;
 252                         ac_gc_check_string_overrun= ;
 253                         ac_gc_check_string_free_list= ;
 254                         ac_xmalloc_overrun= ;
 255                         ac_gc_check_cons_list= ;;
 256         all)            ac_enable_checking=1 ;
 257                         ac_gc_check_stringbytes=1 ;
 258                         ac_gc_check_string_overrun=1 ;
 259                         ac_gc_check_string_free_list=1 ;
 260                         ac_xmalloc_overrun=1 ;
 261                         ac_gc_check_cons_list=1 ;;
 262         # these enable particular checks
 263         stringbytes)    ac_gc_check_stringbytes=1 ;;
 264         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 265         stringfreelist) ac_gc_check_string_free_list=1 ;;
 266         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 267         conslist)       ac_gc_check_cons_list=1 ;;
 268         *)      AC_MSG_ERROR(unknown check category $check) ;;
 269         esac
 270 done
 271 IFS="$ac_save_IFS"
 272
 273 if test x$ac_enable_checking != x ; then
 274   AC_DEFINE(ENABLE_CHECKING, 1,
 275 [Enable expensive run-time checking of data types?])
 276 fi
 277 if test x$ac_gc_check_stringbytes != x ; then
 278   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 279 [Define this temporarily to hunt a bug.  If defined, the size of
 280    strings is redundantly recorded in sdata structures so that it can
 281    be compared to the sizes recorded in Lisp strings.])
 282 fi
 283 if test x$ac_gc_check_stringoverrun != x ; then
 284   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 285 [Define this to check for short string overrun.])
 286 fi
 287 if test x$ac_gc_check_string_free_list != x ; then
 288   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 289 [Define this to check the string free list.])
 290 fi
 291 if test x$ac_xmalloc_overrun != x ; then
 292   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 293 [Define this to check for malloc buffer overrun.])
 294 fi
 295 if test x$ac_gc_check_cons_list != x ; then
 296   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 297 [Define this to check for errors in cons list.])
 298 fi
 299
 300 AC_ARG_ENABLE(profiling,
 301 [AS_HELP_STRING([--enable-profiling],
 302                 [build emacs with profiling support.
 303                  This might not work on all platforms])],
 304 [ac_enable_profiling="${enableval}"],[])
 305 if test x$ac_enable_profiling != x ; then
 306    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 307    PROFILING_LDFLAGS="-pg"
 308 else
 309    PROFILING_CFLAGS=
 310    PROFILING_LDFLAGS=
 311 fi
 312
 313 AC_ARG_ENABLE(autodepend,
 314 [AS_HELP_STRING([--enable-autodepend],
 315                 [automatically generate dependencies to .h-files.
 316                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 317                  found])],
 318 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 319
 320 #### Make srcdir absolute, if it isn't already.  It's important to
 321 #### avoid running the path through pwd unnecessarily, since pwd can
 322 #### give you automounter prefixes, which can go away.  We do all this
 323 #### so Emacs can find its files when run uninstalled.
 324 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 325 unset CDPATH
 326 case "${srcdir}" in
 327   /* ) ;;
 328   . )
 329     ## We may be able to use the $PWD environment variable to make this
 330     ## absolute.  But sometimes PWD is inaccurate.
 331     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 332     ## but that tested only for a well-formed and valid PWD,
 333     ## it did not object when PWD was well-formed and valid but just wrong.
 334     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 335     then
 336       srcdir="$PWD"
 337     else
 338       srcdir="`(cd ${srcdir}; pwd)`"
 339     fi
 340   ;;
 341   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 342 esac
 343
 344 #### Check if the source directory already has a configured system in it.
 345 if test `pwd` != `(cd ${srcdir} && pwd)` \
 346    && test -f "${srcdir}/src/config.h" ; then
 347   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 348    as a build directory right now; it has been configured in its own
 349    right.  To configure in another directory as well, you MUST
 350    use GNU make.  If you do not have GNU make, then you must
 351    now do `make distclean' in ${srcdir},
 352    and then run $0 again.]])
 353 fi
 354
 355 #### Given the configuration name, set machfile and opsysfile to the
 356 #### names of the m/*.h and s/*.h files we should use.
 357
 358 ### Canonicalize the configuration name.
 359
 360 AC_CANONICAL_HOST
 361 canonical=$host
 362 configuration=${host_alias-${build_alias-$host}}
 363
 364 dnl This used to use changequote, but, apart from `changequote is evil'
 365 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 366 dnl the great gob of text.  Thus it's not processed for possible expansion.
 367 dnl Just make sure the brackets remain balanced.
 368 dnl
 369 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 370 dnl indicated by comments.
 371 dnl quotation begins
 372 [
 373
 374 ### If you add support for a new configuration, add code to this
 375 ### switch statement to recognize your configuration name and select
 376 ### the appropriate operating system and machine description files.
 377
 378 ### You would hope that you could choose an m/*.h file pretty much
 379 ### based on the machine portion of the configuration name, and an s-
 380 ### file based on the operating system portion.  However, it turns out
 381 ### that each m/*.h file is pretty manufacturer-specific - for
 382 ### example mips.h is MIPS
 383 ### So we basically have to have a special case for each
 384 ### configuration name.
 385 ###
 386 ### As far as handling version numbers on operating systems is
 387 ### concerned, make sure things will fail in a fixable way.  If
 388 ### /etc/MACHINES doesn't say anything about version numbers, be
 389 ### prepared to handle anything reasonably.  If version numbers
 390 ### matter, be sure /etc/MACHINES says something about it.
 391 ###
 392 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 393 ### "System V Release 4"; he writes, "The old convention encouraged
 394 ### confusion between `system' and `release' levels'."
 395
 396 machine='' opsys='' unported=no
 397 case "${canonical}" in
 398
 399   ## FreeBSD ports
 400   *-*-freebsd* )
 401     opsys=freebsd
 402     case "${canonical}" in
 403       alpha*-*-freebsd*)        machine=alpha ;;
 404       arm*-*-freebsd*)          machine=arm ;;
 405       ia64-*-freebsd*)          machine=ia64 ;;
 406       sparc-*-freebsd*)         machine=sparc ;;
 407       sparc64-*-freebsd*)       machine=sparc ;;
 408       powerpc-*-freebsd*)       machine=macppc ;;
 409       i[3456]86-*-freebsd*)     machine=intel386 ;;
 410       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 411     esac
 412   ;;
 413
 414   ## FreeBSD kernel + glibc based userland
 415   *-*-kfreebsd*gnu* )
 416     opsys=gnu-kfreebsd
 417     case "${canonical}" in
 418       alpha*-*-kfreebsd*)       machine=alpha ;;
 419       ia64-*-kfreebsd*)         machine=ia64 ;;
 420       sparc-*-kfreebsd*)        machine=sparc ;;
 421       sparc64-*-kfreebsd*)      machine=sparc ;;
 422       powerpc-*-kfreebsd*)      machine=macppc ;;
 423       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 424       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 425     esac
 426   ;;
 427
 428   ## NetBSD ports
 429   *-*-netbsd* )
 430     opsys=netbsd
 431     case "${canonical}" in
 432       alpha*-*-netbsd*) machine=alpha ;;
 433       i[3456]86-*-netbsd*) machine=intel386 ;;
 434       mips-*-netbsd*)   machine=mips ;;
 435       mipsel-*-netbsd*) machine=mips ;;
 436       mipseb-*-netbsd*) machine=mips ;;
 437       powerpc-*-netbsd*) machine=macppc ;;
 438       sparc*-*-netbsd*) machine=sparc ;;
 439       vax-*-netbsd*)    machine=vax ;;
 440       arm-*-netbsd*)    machine=arm ;;
 441       x86_64-*-netbsd*) machine=amdx86-64 ;;
 442       hppa-*-netbsd*)   machine=hp800 ;;
 443       m68k-*-netbsd*)   machine=m68k ;;
 444     esac
 445   ;;
 446
 447   ## OpenBSD ports
 448   *-*-openbsd* )
 449     opsys=openbsd
 450     case "${canonical}" in
 451       alpha*-*-openbsd*)        machine=alpha ;;
 452       arm-*-openbsd*)          machine=arm ;;
 453       i386-*-openbsd*)         machine=intel386 ;;
 454       powerpc-*-openbsd*)      machine=macppc ;;
 455       sparc*-*-openbsd*)       machine=sparc ;;
 456       vax-*-openbsd*)          machine=vax ;;
 457       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 458       hppa-*-openbsd*)         machine=hp800 ;;
 459     esac
 460   ;;
 461
 462   alpha*-*-linux-gnu* )
 463     machine=alpha opsys=gnu-linux
 464   ;;
 465
 466   arm*-*-linux-gnu* )
 467     machine=arm opsys=gnu-linux
 468   ;;
 469
 470   ## Apple Darwin / Mac OS X
 471   *-apple-darwin* )
 472     case "${canonical}" in
 473       i[3456]86-* )  machine=intel386 ;;
 474       powerpc-* )    machine=macppc ;;
 475       x86_64-* )     machine=amdx86-64 ;;
 476       * )            unported=yes ;;
 477     esac
 478     opsys=darwin
 479     # Define CPP as follows to make autoconf work correctly.
 480     CPP="${CC-cc} -E -no-cpp-precomp"
 481     # Use fink packages if available.
 482     if test -d /sw/include && test -d /sw/lib; then
 483       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 484       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 485       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 486     fi
 487   ;;
 488
 489   ## HP 9000 series 700 and 800, running HP/UX
 490   hppa*-hp-hpux10.2* )
 491     machine=hp800 opsys=hpux10-20
 492   ;;
 493   hppa*-hp-hpux1[1-9]* )
 494     machine=hp800 opsys=hpux11
 495     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 496   ;;
 497
 498   hppa*-*-linux-gnu* )
 499     machine=hp800 opsys=gnu-linux
 500   ;;
 501
 502   ## IBM machines
 503   s390-*-linux-gnu* )
 504     machine=ibms390 opsys=gnu-linux
 505   ;;
 506   s390x-*-linux-gnu* )
 507     machine=ibms390x opsys=gnu-linux
 508   ;;
 509   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 510     machine=ibmrs6000 opsys=aix4-2
 511   ;;
 512   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 513     machine=ibmrs6000 opsys=aix4-2
 514   ;;
 515   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 516     machine=ibmrs6000 opsys=aix4-2
 517   ;;
 518   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 519     machine=ibmrs6000 opsys=aix4-2
 520   ;;
 521
 522   ## Macintosh PowerPC
 523   powerpc*-*-linux-gnu* )
 524     machine=macppc opsys=gnu-linux
 525   ;;
 526
 527   ## Silicon Graphics machines
 528   ## Iris 4D
 529   mips-sgi-irix6.5 )
 530     machine=iris4d opsys=irix6-5
 531     # Without defining _LANGUAGE_C, things get masked out in the headers
 532     # so that, for instance, grepping for `free' in stdlib.h fails and
 533     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 534     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 535     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 536   ;;
 537
 538   ## Suns
 539   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 540     machine=sparc opsys=gnu-linux
 541   ;;
 542
 543   *-sun-solaris* \
 544     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 545     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 546     case "${canonical}" in
 547       i[3456]86-*-* )     machine=intel386 ;;
 548       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 549       sparc* )          machine=sparc ;;
 550       * )               unported=yes ;;
 551     esac
 552     case "${canonical}" in
 553       *-sunos5.6* | *-solaris2.6* )
 554                 opsys=sol2-6
 555                 NON_GNU_CPP=/usr/ccs/lib/cpp
 556                 RANLIB="ar -ts"
 557                 ;;
 558       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 559                 opsys=sol2-6
 560                 emacs_check_sunpro_c=yes
 561                 NON_GNU_CPP=/usr/ccs/lib/cpp
 562                 ;;
 563       *-sunos5* | *-solaris* )
 564                 opsys=sol2-10
 565                 emacs_check_sunpro_c=yes
 566                 NON_GNU_CPP=/usr/ccs/lib/cpp
 567                 ;;
 568     esac
 569     ## Watch out for a compiler that we know will not work.
 570     case "${canonical}" in
 571      *-solaris* | *-sunos5* )
 572                 if [ "x$CC" = x/usr/ucb/cc ]; then
 573                   ## /usr/ucb/cc doesn't work;
 574                   ## we should find some other compiler that does work.
 575                   unset CC
 576                 fi
 577                 ;;
 578       *) ;;
 579     esac
 580   ;;
 581
 582   ## IA-64
 583   ia64*-*-linux* )
 584     machine=ia64 opsys=gnu-linux
 585   ;;
 586
 587   ## Intel 386 machines where we don't care about the manufacturer
 588   i[3456]86-*-* )
 589     machine=intel386
 590     case "${canonical}" in
 591       *-cygwin )                opsys=cygwin ;;
 592       *-darwin* )               opsys=darwin
 593                                 CPP="${CC-cc} -E -no-cpp-precomp"
 594                                 ;;
 595       *-linux-gnu* )            opsys=gnu-linux ;;
 596       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 597       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 598       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 599       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 600     esac
 601   ;;
 602
 603   ## m68k Linux-based GNU system
 604   m68k-*-linux-gnu* )
 605     machine=m68k opsys=gnu-linux
 606   ;;
 607
 608   ## Mips Linux-based GNU system
 609   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 610     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 611     machine=mips opsys=gnu-linux
 612   ;;
 613
 614   ## AMD x86-64 Linux-based GNU system
 615   x86_64-*-linux-gnu* )
 616     machine=amdx86-64 opsys=gnu-linux
 617   ;;
 618
 619   ## Tensilica Xtensa Linux-based GNU system
 620   xtensa*-*-linux-gnu* )
 621     machine=xtensa opsys=gnu-linux
 622     ;;
 623
 624   ## SuperH Linux-based GNU system
 625   sh[34]*-*-linux-gnu* )
 626     machine=sh3 opsys=gnu-linux
 627   ;;
 628
 629   * )
 630     unported=yes
 631   ;;
 632 esac
 633
 634 ### If the code above didn't choose an operating system, just choose
 635 ### an operating system based on the configuration name.  You really
 636 ### only want to use this when you have no idea what the right
 637 ### operating system is; if you know what operating systems a machine
 638 ### runs, it's cleaner to make it explicit in the case statement
 639 ### above.
 640 if test x"${opsys}" = x; then
 641   case "${canonical}" in
 642     *-gnu* )                            opsys=gnu ;;
 643     * )
 644       unported=yes
 645     ;;
 646   esac
 647 fi
 648
 649 ]
 650 dnl quotation ends
 651
 652 if test $unported = yes; then
 653   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 654 Check `etc/MACHINES' for recognized configuration names.])
 655 fi
 656
 657 machfile="m/${machine}.h"
 658 opsysfile="s/${opsys}.h"
 659
 660
 661 #### Choose a compiler.
 662 test -n "$CC" && cc_specified=yes
 663
 664 # Save the value of CFLAGS that the user specified.
 665 SPECIFIED_CFLAGS="$CFLAGS"
 666
 667 dnl Sets GCC=yes if using gcc.
 668 AC_PROG_CC
 669
 670 # On Suns, sometimes $CPP names a directory.
 671 if test -n "$CPP" && test -d "$CPP"; then
 672   CPP=
 673 fi
 674
 675 ## If not using gcc, and on Solaris, and no CPP specified, see if
 676 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 677 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 678  test x"$CPP" = x; then
 679   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 680   AC_CACHE_VAL(emacs_cv_sunpro_c,
 681   [AC_TRY_LINK([],
 682 [#ifndef __SUNPRO_C
 683 fail;
 684 #endif
 685 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 686   AC_MSG_RESULT($emacs_cv_sunpro_c)
 687
 688   if test x"$emacs_cv_sunpro_c" = xyes; then
 689     NON_GNU_CPP="$CC -E -Xs"
 690   fi
 691 fi
 692
 693 #### Some systems specify a CPP to use unless we are using GCC.
 694 #### Now that we know whether we are using GCC, we can decide whether
 695 #### to use that one.
 696 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 697 then
 698   CPP="$NON_GNU_CPP"
 699 fi
 700
 701 #### Some systems specify a CC to use unless we are using GCC.
 702 #### Now that we know whether we are using GCC, we can decide whether
 703 #### to use that one.
 704 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 705   test x$cc_specified != xyes
 706 then
 707   CC="$NON_GNU_CC"
 708 fi
 709
 710 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 711 then
 712   CC="$CC $GCC_TEST_OPTIONS"
 713 fi
 714
 715 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 716 then
 717   CC="$CC $NON_GCC_TEST_OPTIONS"
 718 fi
 719
 720 dnl checks for Unix variants
 721 AC_USE_SYSTEM_EXTENSIONS
 722
 723 ### Use -Wno-pointer-sign if the compiler supports it
 724 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 725 SAVE_CFLAGS="$CFLAGS"
 726 CFLAGS="$CFLAGS -Wno-pointer-sign"
 727 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 728 if test $has_option = yes; then
 729    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 730 fi
 731 AC_MSG_RESULT($has_option)
 732 CFLAGS="$SAVE_CFLAGS"
 733 unset has_option
 734 unset SAVE_CFLAGS
 735
 736 ### Use -Wdeclaration-after-statement if the compiler supports it
 737 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 738 SAVE_CFLAGS="$CFLAGS"
 739 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 740 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 741 if test $has_option = yes; then
 742    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 743 fi
 744 AC_MSG_RESULT($has_option)
 745 CFLAGS="$SAVE_CFLAGS"
 746 unset has_option
 747 unset SAVE_CFLAGS
 748
 749 #### Some other nice autoconf tests.
 750
 751 dnl checks for programs
 752 AC_PROG_CPP
 753 AC_PROG_INSTALL
 754 if test "x$RANLIB" = x; then
 755   AC_PROG_RANLIB
 756 fi
 757
 758 ## Although we're running on an amd64 kernel, we're actually compiling for
 759 ## the x86 architecture.  The user should probably have provided an
 760 ## explicit --build to `configure', but if everything else than the kernel
 761 ## is running in i386 mode, we can help them out.
 762 if test "$machine" = "amdx86-64"; then
 763   AC_CHECK_DECL([i386])
 764   if test "$ac_cv_have_decl_i386" = "yes"; then
 765     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 766     machine=intel386
 767     machfile="m/${machine}.h"
 768   fi
 769 fi
 770
 771 AC_PATH_PROG(INSTALL_INFO, install-info)
 772 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 773 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 774 dnl Don't use GZIP, which is used by gzip for additional parameters.
 775 AC_PATH_PROG(GZIP_PROG, gzip)
 776
 777
 778 ## Need makeinfo >= 4.6 (?) to build the manuals.
 779 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 780 dnl By this stage, configure has already checked for egrep and set EGREP,
 781 dnl or exited with an error if no egrep was found.
 782 if test "$MAKEINFO" != "no" && \
 783   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 784    MAKEINFO=no
 785 fi
 786
 787 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 788 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 789 ## therefore in the category of "special tools" not normally required, which
 790 ## configure does not have to check for (eg autoconf itself).
 791 ## In a Bazaar checkout on the other hand, the manuals are not included.
 792 ## So makeinfo is a requirement to build from Bazaar, and configure
 793 ## should test for it as it does for any other build requirement.
 794 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 795 ## with pre-built manuals, from a Bazaar checkout.
 796 if test "$MAKEINFO" = "no"; then
 797   if test "x${with_makeinfo}" = "xno"; then
 798     MAKEINFO=off
 799   elif test ! -e $srcdir/info/emacs; then
 800     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 801 source tree does not seem to have pre-built manuals in the `info' directory.
 802 Either install a suitable version of makeinfo, or re-run configure
 803 with the `--without-makeinfo' option to build without the manuals.] )
 804   fi
 805 fi
 806
 807 dnl Add our options to ac_link now, after it is set up.
 808
 809 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 810 then
 811   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 812 fi
 813
 814 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 815 then
 816   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 817 fi
 818
 819 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 820 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 821 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 822 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 823 dnl if not built to support GNU ld.
 824
 825 late_LDFLAGS=$LDFLAGS
 826 if test "$GCC" = yes; then
 827   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 828 else
 829   LDFLAGS="$LDFLAGS -znocombreloc"
 830 fi
 831
 832 AC_MSG_CHECKING([for -znocombreloc])
 833 AC_LINK_IFELSE([main(){return 0;}],
 834   [AC_MSG_RESULT(yes)],
 835   LDFLAGS=$late_LDFLAGS
 836   [AC_MSG_RESULT(no)])
 837
 838 #### Extract some information from the operating system and machine files.
 839
 840 AC_CHECKING([the machine- and system-dependent files to find out
 841  - which libraries the lib-src programs will want, and
 842  - whether the GNU malloc routines are usable])
 843
 844 ### First figure out CFLAGS (which we use for running the compiler here)
 845 ### and REAL_CFLAGS (which we use for real compilation).
 846 ### The two are the same except on a few systems, where they are made
 847 ### different to work around various lossages.  For example,
 848 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 849 ### as implying static linking.
 850
 851 ### If the CFLAGS env var is specified, we use that value
 852 ### instead of the default.
 853
 854 ### It's not important that this name contain the PID; you can't run
 855 ### two configures in the same directory and have anything work
 856 ### anyway.
 857 tempcname="conftest.c"
 858
 859 echo '
 860 #include "'${srcdir}'/src/'${opsysfile}'"
 861 #include "'${srcdir}'/src/'${machfile}'"
 862 #ifndef LIBS_SYSTEM
 863 #define LIBS_SYSTEM
 864 #endif
 865 configure___ libsrc_libs=LIBS_SYSTEM
 866
 867 configure___ LIBX=-lX11
 868
 869 configure___ unexec=UNEXEC
 870
 871 #ifdef SYSTEM_MALLOC
 872 configure___ system_malloc=yes
 873 #else
 874 configure___ system_malloc=no
 875 #endif
 876
 877 #ifdef USE_MMAP_FOR_BUFFERS
 878 configure___ use_mmap_for_buffers=yes
 879 #else
 880 configure___ use_mmap_for_buffers=no
 881 #endif
 882
 883 #ifndef C_OPTIMIZE_SWITCH
 884 #ifdef __GNUC__
 885 #define C_OPTIMIZE_SWITCH -O2
 886 #else
 887 #define C_OPTIMIZE_SWITCH -O
 888 #endif
 889 #endif
 890
 891 #ifndef C_WARNINGS_SWITCH
 892 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 893 #endif
 894
 895 #ifndef LD_SWITCH_SYSTEM
 896 #define LD_SWITCH_SYSTEM
 897 #endif
 898
 899 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 900
 901 #ifdef THIS_IS_CONFIGURE
 902
 903 /* Get the CFLAGS for tests in configure.  */
 904 #ifdef __GNUC__
 905 configure___ CFLAGS=-g C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 906 #else
 907 configure___ CFLAGS='${SPECIFIED_CFLAGS}'
 908 #endif
 909
 910 #else /* not THIS_IS_CONFIGURE */
 911
 912 /* Get the CFLAGS for real compilation.  */
 913 #ifdef __GNUC__
 914 configure___ REAL_CFLAGS=-g C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 915 #else
 916 configure___ REAL_CFLAGS='${SPECIFIED_CFLAGS}'
 917 #endif
 918
 919 #endif /* not THIS_IS_CONFIGURE */
 920 ' > ${tempcname}
 921
 922 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 923
 924 # The value of CPP is a quoted variable reference, so we need to do this
 925 # to get its actual value...
 926 CPP=`eval "echo $CPP"`
 927 [eval `${CPP} -Isrc ${tempcname} \
 928        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 929 if test "x$SPECIFIED_CFLAGS" = x; then
 930   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 931          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 932 else
 933   REAL_CFLAGS="$CFLAGS"
 934 fi]
 935 rm ${tempcname}
 936
 937 ac_link="$ac_link $ld_switch_system"
 938
 939
 940 C_SWITCH_MACHINE=
 941 if test "$machine" = "alpha"; then
 942   AC_CHECK_DECL([__ELF__])
 943   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 944     ## With ELF, make sure that all common symbols get allocated to in the
 945     ## data section.  Otherwise, the dump of temacs may miss variables in
 946     ## the shared library that have been initialized.  For example, with
 947     ## GNU libc, __malloc_initialized would normally be resolved to the
 948     ## shared library's .bss section, which is fatal.
 949     if test "x$GCC" = "xyes"; then
 950       C_SWITCH_MACHINE="-fno-common"
 951     else
 952       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 953     fi
 954   fi
 955 fi
 956 AC_SUBST(C_SWITCH_MACHINE)
 957
 958
 959 C_SWITCH_SYSTEM=
 960 ## Some programs in src produce warnings saying certain subprograms
 961 ## are too complex and need a MAXMEM value greater than 2000 for
 962 ## additional optimization.  --nils@exp-math.uni-essen.de
 963 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 964   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 965 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 966 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 967 AC_SUBST(C_SWITCH_SYSTEM)
 968
 969
 970 ### Make sure subsequent tests use flags consistent with the build flags.
 971
 972 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 973   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 974 else
 975   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 976 fi
 977
 978 dnl For AC_FUNC_GETLOADAVG, at least:
 979 AC_CONFIG_LIBOBJ_DIR(src)
 980
 981 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 982 AC_SYS_LARGEFILE
 983
 984
 985 ## If user specified a crt-dir, use that unconditionally.
 986 if test "X$CRT_DIR" = "X"; then
 987
 988   case "$canonical" in
 989     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
 990     ## On x86-64 and s390x GNU/Linux distributions, the standard library
 991     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
 992     ## For anything else (eg /usr/lib32), it is up the user to specify
 993     ## the location (bug#5655).
 994     ## Test for crtn.o, not just the directory, because sometimes the
 995     ## directory exists but does not have the relevant files (bug#1287).
 996     ## FIXME better to test for binary compatibility somehow.
 997     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
 998     ;;
 999
1000     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1001   esac
1002
1003   case "$opsys" in
1004     hpux10-20) CRT_DIR=/lib ;;
1005   esac
1006
1007   ## Default is /usr/lib.
1008   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1009
1010 else
1011
1012   ## Some platforms don't use any of these files, so it is not
1013   ## appropriate to put this test outside the if block.
1014   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1015     AC_MSG_ERROR([crt*.o not found in specified location.])
1016
1017 fi
1018
1019 AC_SUBST(CRT_DIR)
1020
1021 LIB_MATH=-lm
1022 LIB_STANDARD=
1023 START_FILES=
1024
1025 case $opsys in
1026   cygwin )
1027     LIB_MATH=
1028     START_FILES='ecrt0.o'
1029     ;;
1030   darwin )
1031     ## Adding -lm confuses the dynamic linker, so omit it.
1032     LIB_MATH=
1033     START_FILES='pre-crt0.o'
1034     ;;
1035   freebsd )
1036     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1037     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1038     ;;
1039   gnu-linux | gnu-kfreebsd )
1040     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1041     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1042     ;;
1043   hpux10-20 | hpux11 )
1044     LIB_STANDARD=-lc
1045     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1046     ;;
1047   netbsd | openbsd )
1048     if test -f $(CRT_DIR)/crti.o; then
1049         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1050         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1051     else
1052         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1053         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1054     fi
1055     ;;
1056 esac
1057
1058 AC_SUBST(LIB_MATH)
1059 AC_SUBST(START_FILES)
1060
1061 dnl This function defintion taken from Gnome 2.0
1062 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1063 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1064 dnl also defines GSTUFF_PKG_ERRORS on error
1065 AC_DEFUN([PKG_CHECK_MODULES], [
1066   succeeded=no
1067
1068   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1069
1070   if test "$PKG_CONFIG" = "no" ; then
1071      ifelse([$4], , [AC_MSG_ERROR([
1072       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1073   else
1074      PKG_CONFIG_MIN_VERSION=0.9.0
1075      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1076         AC_MSG_CHECKING(for $2)
1077
1078         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1079             AC_MSG_RESULT(yes)
1080             succeeded=yes
1081
1082             AC_MSG_CHECKING($1_CFLAGS)
1083             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1084             AC_MSG_RESULT($$1_CFLAGS)
1085
1086             AC_MSG_CHECKING($1_LIBS)
1087             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1088             AC_MSG_RESULT($$1_LIBS)
1089         else
1090             AC_MSG_RESULT(no)
1091             $1_CFLAGS=""
1092             $1_LIBS=""
1093             ## If we have a custom action on failure, don't print errors, but
1094             ## do set a variable so people can do so.
1095             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1096             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1097         fi
1098
1099         AC_SUBST($1_CFLAGS)
1100         AC_SUBST($1_LIBS)
1101      else
1102         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1103         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1104      fi
1105   fi
1106
1107   if test $succeeded = yes; then
1108      ifelse([$3], , :, [$3])
1109   else
1110      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1111   fi
1112 ])
1113
1114
1115 if test "${with_sound}" != "no"; then
1116   # Sound support for GNU/Linux and the free BSDs.
1117   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1118   # Emulation library used on NetBSD.
1119   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1120   AC_SUBST(LIBSOUND)
1121
1122   ALSA_REQUIRED=1.0.0
1123   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1124   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1125   if test $HAVE_ALSA = yes; then
1126     SAVE_CFLAGS="$CFLAGS"
1127     SAVE_LDFLAGS="$LDFLAGS"
1128     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1129     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1130     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1131                     emacs_alsa_normal=yes,
1132                     emacs_alsa_normal=no)
1133     if test "$emacs_alsa_normal" != yes; then
1134       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1135                      [snd_lib_error_set_handler (0);],
1136                      emacs_alsa_subdir=yes,
1137                      emacs_alsa_subdir=no)
1138       if test "$emacs_alsa_subdir" != yes; then
1139         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1140       fi
1141       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1142     fi
1143
1144     CFLAGS="$SAVE_CFLAGS"
1145     LDFLAGS="$SAVE_LDFLAGS"
1146     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1147     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1148     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1149   fi
1150   AC_SUBST(CFLAGS_SOUND)
1151 fi
1152
1153 dnl checks for header files
1154 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1155   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1156   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1157   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1158   sys/utsname.h pwd.h utmp.h)
1159
1160 AC_MSG_CHECKING(if personality LINUX32 can be set)
1161 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1162                emacs_cv_personality_linux32=yes,
1163                emacs_cv_personality_linux32=no)
1164 AC_MSG_RESULT($emacs_cv_personality_linux32)
1165
1166 if test $emacs_cv_personality_linux32 = yes; then
1167   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1168             [Define to 1 if personality LINUX32 can be set.])
1169 fi
1170
1171 dnl On Solaris 8 there's a compilation warning for term.h because
1172 dnl it doesn't define `bool'.
1173 AC_CHECK_HEADERS(term.h, , , -)
1174 AC_HEADER_STDC
1175 AC_HEADER_TIME
1176 AC_CHECK_DECLS([sys_siglist])
1177 if test $ac_cv_have_decl_sys_siglist != yes; then
1178   # For Tru64, at least:
1179   AC_CHECK_DECLS([__sys_siglist])
1180   if test $ac_cv_have_decl___sys_siglist = yes; then
1181     AC_DEFINE(sys_siglist, __sys_siglist,
1182               [Define to any substitute for sys_siglist.])
1183   fi
1184 fi
1185 AC_HEADER_SYS_WAIT
1186
1187 dnl Some systems have utime.h but don't declare the struct anyplace.
1188 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1189 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1190 #include <sys/time.h>
1191 #include <time.h>
1192 #else
1193 #ifdef HAVE_SYS_TIME_H
1194 #include <sys/time.h>
1195 #else
1196 #include <time.h>
1197 #endif
1198 #endif
1199 #ifdef HAVE_UTIME_H
1200 #include <utime.h>
1201 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1202   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1203 if test $emacs_cv_struct_utimbuf = yes; then
1204   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1205 fi
1206
1207 dnl checks for typedefs
1208 AC_TYPE_SIGNAL
1209
1210 dnl Check for speed_t typedef.
1211 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1212   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1213     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1214 if test $emacs_cv_speed_t = yes; then
1215   AC_DEFINE(HAVE_SPEED_T, 1,
1216            [Define to 1 if `speed_t' is declared by <termios.h>.])
1217 fi
1218
1219 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1220 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1221 #include <sys/time.h>
1222 #include <time.h>
1223 #else
1224 #ifdef HAVE_SYS_TIME_H
1225 #include <sys/time.h>
1226 #else
1227 #include <time.h>
1228 #endif
1229 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1230   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1231 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1232 if test $emacs_cv_struct_timeval = yes; then
1233   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1234 fi
1235
1236 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1237 AC_TRY_COMPILE([#include <math.h>],
1238 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1239   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1240 HAVE_EXCEPTION=$emacs_cv_struct_exception
1241 if test $emacs_cv_struct_exception != yes; then
1242   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1243 fi
1244
1245 AC_CHECK_HEADERS(sys/socket.h)
1246 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1247 #if HAVE_SYS_SOCKET_H
1248 #include <sys/socket.h>
1249 #endif])
1250
1251 dnl checks for structure members
1252 AC_STRUCT_TM
1253 AC_STRUCT_TIMEZONE
1254 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1255                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1256                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1257                 [#include <time.h>])
1258 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1259                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1260                   struct ifreq.ifr_addr], , ,
1261                  [AC_INCLUDES_DEFAULT
1262 #if HAVE_SYS_SOCKET_H
1263 #include <sys/socket.h>
1264 #endif
1265 #if HAVE_NET_IF_H
1266 #include <net/if.h>
1267 #endif])
1268
1269 dnl checks for compiler characteristics
1270
1271 dnl Testing __STDC__ to determine prototype support isn't good enough.
1272 dnl DEC C, for instance, doesn't define it with default options, and
1273 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1274 dnl and void *.
1275 AC_C_PROTOTYPES
1276 AC_C_VOLATILE
1277 AC_C_CONST
1278 dnl This isn't useful because we can't turn on use of `inline' unless
1279 dnl the compiler groks `extern inline'.
1280 dnl AC_C_INLINE
1281 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1282   [AC_TRY_COMPILE(, [void * foo;],
1283                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1284 if test $emacs_cv_void_star = yes; then
1285   AC_DEFINE(POINTER_TYPE, void)
1286 else
1287   AC_DEFINE(POINTER_TYPE, char)
1288 fi
1289 AH_TEMPLATE(POINTER_TYPE,
1290             [Define as `void' if your compiler accepts `void *'; otherwise
1291              define as `char'.])dnl
1292
1293
1294
1295 dnl This could be used for targets which can have both byte sexes.
1296 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1297 dnl AC_C_BIGENDIAN
1298
1299 dnl check for Make feature
1300 AC_PROG_MAKE_SET
1301
1302 dnl check for GNU Make if we have GCC and autodepend is on.
1303 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1304    AC_MSG_CHECKING([whether we are using GNU Make])
1305    HAVE_GNU_MAKE=no
1306    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1307    if test "x$testval" != x; then
1308       HAVE_GNU_MAKE=yes
1309    else
1310       ac_enable_autodepend=no
1311    fi
1312    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1313    if test $HAVE_GNU_MAKE = yes; then
1314       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1315       SAVE_CFLAGS="$CFLAGS"
1316       CFLAGS="$CFLAGS -MMD -MF deps.d"
1317       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1318       CFLAGS="$SAVE_CFLAGS"
1319       test -f deps.d || ac_enable_autodepend=no
1320       rm -rf deps.d
1321       AC_MSG_RESULT([$ac_enable_autodepend])
1322    fi
1323    if test $ac_enable_autodepend = yes; then
1324       AC_DEFINE(AUTO_DEPEND, 1, [Generate dependencies with gcc.])
1325    fi
1326 fi
1327
1328 dnl checks for operating system services
1329 AC_SYS_LONG_FILE_NAMES
1330
1331 #### Choose a window system.
1332
1333 AC_PATH_X
1334 if test "$no_x" = yes; then
1335   window_system=none
1336 else
1337   window_system=x11
1338 fi
1339
1340 ## Workaround for bug in autoconf <= 2.62.
1341 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1342 ## No need to do anything special for these standard directories.
1343 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1344
1345    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1346
1347 fi
1348
1349 LD_SWITCH_X_SITE_AUX=
1350 LD_SWITCH_X_SITE_AUX_RPATH=
1351 if test "${x_libraries}" != NONE; then
1352   if test -n "${x_libraries}"; then
1353     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1354     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1355     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1356   fi
1357   x_default_search_path=""
1358   x_search_path=${x_libraries}
1359   if test -z "${x_search_path}"; then
1360     x_search_path=/usr/lib
1361   fi
1362   for x_library in `echo ${x_search_path}: | \
1363                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1364     x_search_path="\
1365 ${x_library}/X11/%L/%T/%N%C%S:\
1366 ${x_library}/X11/%l/%T/%N%C%S:\
1367 ${x_library}/X11/%T/%N%C%S:\
1368 ${x_library}/X11/%L/%T/%N%S:\
1369 ${x_library}/X11/%l/%T/%N%S:\
1370 ${x_library}/X11/%T/%N%S"
1371     if test x"${x_default_search_path}" = x; then
1372       x_default_search_path=${x_search_path}
1373     else
1374       x_default_search_path="${x_search_path}:${x_default_search_path}"
1375     fi
1376   done
1377 fi
1378 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1379 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1380
1381 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1382   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1383 fi
1384
1385 if test x"${x_includes}" = x; then
1386   bitmapdir=/usr/include/X11/bitmaps
1387 else
1388   # accumulate include directories that have X11 bitmap subdirectories
1389   bmd_acc="dummyval"
1390   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1391     if test -d "${bmd}/X11/bitmaps"; then
1392       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1393     fi
1394     if test -d "${bmd}/bitmaps"; then
1395       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1396     fi
1397   done
1398   if test ${bmd_acc} != "dummyval"; then
1399     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1400   fi
1401 fi
1402
1403 HAVE_NS=no
1404 NS_IMPL_COCOA=no
1405 NS_IMPL_GNUSTEP=no
1406 tmp_CPPFLAGS="$CPPFLAGS"
1407 tmp_CFLAGS="$CFLAGS"
1408 CPPFLAGS="$CPPFLAGS -x objective-c"
1409 CFLAGS="$CFLAGS -x objective-c"
1410 if test "${with_ns}" != no; then
1411   if test "${opsys}" = darwin; then
1412      NS_IMPL_COCOA=yes
1413      ns_appdir=`pwd`/nextstep/Emacs.app
1414      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1415      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1416      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1417   elif test -f $GNUSTEP_CONFIG_FILE; then
1418      NS_IMPL_GNUSTEP=yes
1419      ns_appdir=`pwd`/nextstep/Emacs.app
1420      ns_appbindir=`pwd`/nextstep/Emacs.app
1421      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1422      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1423      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1424      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1425      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1426      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1427      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1428      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1429      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1430      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1431      LIB_STANDARD=
1432   fi
1433   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1434                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1435   files are missing or cannot be compiled.])])
1436   NS_HAVE_NSINTEGER=yes
1437   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1438                                      [NSInteger i;])],
1439                     ns_have_nsinteger=yes,
1440                     ns_have_nsinteger=no)
1441   if test $ns_have_nsinteger = no; then
1442     NS_HAVE_NSINTEGER=no
1443   fi
1444 fi
1445
1446 NS_OBJ=
1447 NS_SUPPORT=
1448 if test "${HAVE_NS}" = yes; then
1449   window_system=nextstep
1450   with_xft=no
1451   # set up packaging dirs
1452   exec_prefix=${ns_appbindir}
1453   libexecdir=${ns_appbindir}/libexec
1454   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1455      prefix=${ns_appresdir}
1456   fi
1457   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1458   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1459 fi
1460 CFLAGS="$tmp_CFLAGS"
1461 CPPFLAGS="$tmp_CPPFLAGS"
1462 AC_SUBST(NS_OBJ)
1463 AC_SUBST(NS_SUPPORT)
1464 AC_SUBST(LIB_STANDARD)
1465
1466 case "${window_system}" in
1467   x11 )
1468     HAVE_X_WINDOWS=yes
1469     HAVE_X11=yes
1470     case "${with_x_toolkit}" in
1471       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1472       motif ) USE_X_TOOLKIT=MOTIF ;;
1473       gtk ) with_gtk=yes
1474 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1475 dnl USE_X_TOOLKIT is set.
1476             USE_X_TOOLKIT=none ;;
1477       no ) USE_X_TOOLKIT=none ;;
1478 dnl If user did not say whether to use a toolkit, make this decision later:
1479 dnl use the toolkit if we have gtk, or X11R5 or newer.
1480       * ) USE_X_TOOLKIT=maybe ;;
1481     esac
1482   ;;
1483   nextstep | none )
1484     HAVE_X_WINDOWS=no
1485     HAVE_X11=no
1486     USE_X_TOOLKIT=none
1487   ;;
1488 esac
1489
1490 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1491    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1492    if test "$HAVE_XSERVER" = true ||
1493       test -n "$DISPLAY" ||
1494       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1495         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1496 were found.  You should install the relevant development files for X
1497 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1498 sure you have development files for image handling, i.e.
1499 tiff, gif, jpeg, png and xpm.
1500 If you are sure you want Emacs compiled without X window support, pass
1501   --without-x
1502 to configure.])
1503    fi
1504 fi
1505
1506 ### If we're using X11, we should use the X menu package.
1507 HAVE_MENUS=no
1508 case ${HAVE_X11} in
1509   yes ) HAVE_MENUS=yes ;;
1510 esac
1511
1512 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1513 # Assume not, until told otherwise.
1514 GNU_MALLOC=yes
1515 doug_lea_malloc=yes
1516 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1517 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1518 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1519                emacs_cv_var___after_morecore_hook,
1520 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1521   emacs_cv_var___after_morecore_hook=yes,
1522   emacs_cv_var___after_morecore_hook=no)])
1523 if test $emacs_cv_var___after_morecore_hook = no; then
1524   doug_lea_malloc=no
1525 fi
1526 if test "${system_malloc}" = "yes"; then
1527   GNU_MALLOC=no
1528   GNU_MALLOC_reason="
1529     (The GNU allocators don't work with this system configuration.)"
1530 fi
1531 if test "$doug_lea_malloc" = "yes" ; then
1532   if test "$GNU_MALLOC" = yes ; then
1533     GNU_MALLOC_reason="
1534       (Using Doug Lea's new malloc from the GNU C Library.)"
1535   fi
1536   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1537             [Define to 1 if you are using the GNU C Library.])
1538 fi
1539
1540 if test x"${REL_ALLOC}" = x; then
1541   REL_ALLOC=${GNU_MALLOC}
1542 fi
1543
1544 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1545 dnl the system configuration file (s/*.h) to turn the use of mmap
1546 dnl in the relocating allocator on.
1547
1548 AC_FUNC_MMAP
1549 if test $use_mmap_for_buffers = yes; then
1550   REL_ALLOC=no
1551 fi
1552
1553 LIBS="$libsrc_libs $LIBS"
1554
1555 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1556 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1557 AC_CHECK_LIB(dnet, dnet_ntoa)
1558 dnl This causes -lresolv to get used in subsequent tests,
1559 dnl which causes failures on some systems such as HPUX 9.
1560 dnl AC_CHECK_LIB(resolv, gethostbyname)
1561
1562 dnl FIXME replace main with a function we actually want from this library.
1563 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1564
1565 AC_CHECK_LIB(pthreads, cma_open)
1566
1567 dnl Check for need for bigtoc support on IBM AIX
1568
1569 case ${host_os} in
1570 aix*)
1571   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1572     case $GCC in
1573     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1574     *) gdb_cv_bigtoc=-bbigtoc ;;
1575     esac
1576
1577     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1578     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1579   ])
1580   ;;
1581 esac
1582
1583 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1584 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1585 # REAL_CPPFLAGS later on.
1586
1587 REAL_CPPFLAGS="$CPPFLAGS"
1588
1589 if test "${HAVE_X11}" = "yes"; then
1590   DEFS="$C_SWITCH_X_SITE $DEFS"
1591   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1592   LIBS="$LIBX $LIBS"
1593   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1594   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1595
1596   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1597   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1598   # but it's more convenient here to set LD_RUN_PATH
1599   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1600   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1601     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1602     export LD_RUN_PATH
1603   fi
1604
1605   if test "${opsys}" = "gnu-linux"; then
1606     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1607     AC_TRY_LINK([],
1608      [XOpenDisplay ("foo");],
1609      [xlinux_first_failure=no],
1610      [xlinux_first_failure=yes])
1611     if test "${xlinux_first_failure}" = "yes"; then
1612       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1613       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1614       OLD_CPPFLAGS="$CPPFLAGS"
1615       OLD_LIBS="$LIBS"
1616       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1617       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1618       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1619       LIBS="$LIBS -b i486-linuxaout"
1620       AC_TRY_LINK([],
1621        [XOpenDisplay ("foo");],
1622        [xlinux_second_failure=no],
1623        [xlinux_second_failure=yes])
1624       if test "${xlinux_second_failure}" = "yes"; then
1625         # If we get the same failure with -b, there is no use adding -b.
1626         # So take it out.  This plays safe.
1627         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1628         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1629         CPPFLAGS="$OLD_CPPFLAGS"
1630         LIBS="$OLD_LIBS"
1631         AC_MSG_RESULT(no)
1632       else
1633         AC_MSG_RESULT(yes)
1634       fi
1635     else
1636       AC_MSG_RESULT(no)
1637     fi
1638   fi
1639
1640   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1641   # header files included from there.
1642   AC_MSG_CHECKING(for Xkb)
1643   AC_TRY_LINK([#include <X11/Xlib.h>
1644 #include <X11/XKBlib.h>],
1645         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1646         emacs_xkb=yes, emacs_xkb=no)
1647   AC_MSG_RESULT($emacs_xkb)
1648   if test $emacs_xkb = yes; then
1649     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1650   fi
1651
1652   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1653 XScreenNumberOfScreen XSetWMProtocols)
1654 fi
1655
1656 if test "${window_system}" = "x11"; then
1657   AC_MSG_CHECKING(X11 version 6)
1658   AC_CACHE_VAL(emacs_cv_x11_version_6,
1659   [AC_TRY_LINK([#include <X11/Xlib.h>],
1660 [#if XlibSpecificationRelease < 6
1661 fail;
1662 #endif
1663 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1664   if test $emacs_cv_x11_version_6 = yes; then
1665     AC_MSG_RESULT(6 or newer)
1666     AC_DEFINE(HAVE_X11R6, 1,
1667               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1668   else
1669     AC_MSG_RESULT(before 6)
1670   fi
1671 fi
1672
1673
1674 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1675 HAVE_RSVG=no
1676 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1677   if test "${with_rsvg}" != "no"; then
1678     RSVG_REQUIRED=2.11.0
1679     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1680
1681     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1682     AC_SUBST(RSVG_CFLAGS)
1683     AC_SUBST(RSVG_LIBS)
1684
1685     if test ".${RSVG_CFLAGS}" != "."; then
1686       HAVE_RSVG=yes
1687       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1688       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1689       LIBS="$RSVG_LIBS $LIBS"
1690     fi
1691   fi
1692 fi
1693
1694
1695 HAVE_GTK=no
1696 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1697   GLIB_REQUIRED=2.6
1698   GTK_REQUIRED=2.6
1699   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1700
1701   dnl Checks for libraries.
1702   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1703   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1704      AC_MSG_ERROR($GTK_PKG_ERRORS)
1705   fi
1706 fi
1707
1708
1709 GTK_OBJ=
1710 if test x"$pkg_check_gtk" = xyes; then
1711
1712   AC_SUBST(GTK_CFLAGS)
1713   AC_SUBST(GTK_LIBS)
1714   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1715   CFLAGS="$CFLAGS $GTK_CFLAGS"
1716   LIBS="$GTK_LIBS $LIBS"
1717   dnl Try to compile a simple GTK program.
1718   GTK_COMPILES=no
1719   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1720   if test "${GTK_COMPILES}" != "yes"; then
1721     if test "$USE_X_TOOLKIT" != "maybe"; then
1722       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1723     fi
1724   else
1725     HAVE_GTK=yes
1726     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1727     GTK_OBJ=gtkutil.o
1728     USE_X_TOOLKIT=none
1729     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1730       :
1731     else
1732       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1733        closing open displays.  This is no problem if you just use
1734        one display, but if you use more than one and close one of them
1735        Emacs may crash.]])
1736       sleep 3
1737     fi
1738   fi
1739
1740 fi
1741 AC_SUBST(GTK_OBJ)
1742
1743
1744 if test "${HAVE_GTK}" = "yes"; then
1745
1746   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1747   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1748   if test "$with_toolkit_scroll_bars" != no; then
1749     with_toolkit_scroll_bars=yes
1750   fi
1751
1752   dnl  Check if we can use multiple displays with this GTK version.
1753   dnl  If gdk_display_open exists, assume all others are there also.
1754   HAVE_GTK_MULTIDISPLAY=no
1755   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1756   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1757     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1758               [Define to 1 if GTK can handle more than one display.])
1759   fi
1760
1761   dnl  Check if we have the old file selection dialog declared and
1762   dnl  in the link library.  In 2.x it may be in the library,
1763   dnl  but not declared if deprecated featured has been selected out.
1764   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1765   HAVE_GTK_FILE_SELECTION=no
1766   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1767                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1768 #include <gtk/gtk.h>])
1769   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1770     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1771                    HAVE_GTK_FILE_SELECTION=no)
1772   fi
1773
1774   dnl  Check if we have the new file chooser dialog
1775   HAVE_GTK_FILE_CHOOSER=no
1776   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1777                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1778 #include <gtk/gtk.h>])
1779   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1780     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1781                    HAVE_GTK_FILE_CHOOSER=no)
1782   fi
1783
1784   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1785      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1786     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1787               [Define to 1 if GTK has both file selection and chooser dialog.])
1788   fi
1789
1790   dnl Check if pthreads are available.  Emacs only needs this when using
1791   dnl gtk_file_chooser under Gnome.
1792   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1793     HAVE_GTK_AND_PTHREAD=no
1794     AC_CHECK_HEADERS(pthread.h)
1795     if test "$ac_cv_header_pthread_h"; then
1796       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1797     fi
1798     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1799       case "${canonical}" in
1800         *-hpux*) ;;
1801         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1802       esac
1803       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1804                [Define to 1 if you have GTK and pthread (-lpthread).])
1805     fi
1806   fi
1807 fi
1808
1809 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1810 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1811 dnl also not configured.
1812 HAVE_DBUS=no
1813 DBUS_OBJ=
1814 if test "${with_dbus}" = "yes"; then
1815    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1816    if test "$HAVE_DBUS" = yes; then
1817      LIBS="$LIBS $DBUS_LIBS"
1818      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1819      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1820      DBUS_OBJ=dbusbind.o
1821    fi
1822 fi
1823 AC_SUBST(DBUS_OBJ)
1824
1825 dnl GConf has been tested under GNU/Linux only.
1826 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1827 HAVE_GCONF=no
1828 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1829    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1830    if test "$HAVE_GCONF" = yes; then
1831       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1832    fi
1833 fi
1834
1835 dnl SELinux is available for GNU/Linux only.
1836 HAVE_LIBSELINUX=no
1837 LIBSELINUX_LIBS=
1838 if test "${with_selinux}" = "yes"; then
1839    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1840    if test "$HAVE_LIBSELINUX" = yes; then
1841       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1842       LIBSELINUX_LIBS=-lselinux
1843    fi
1844 fi
1845 AC_SUBST(LIBSELINUX_LIBS)
1846
1847 dnl Do not put whitespace before the #include statements below.
1848 dnl Older compilers (eg sunos4 cc) choke on it.
1849 HAVE_XAW3D=no
1850 LUCID_LIBW=
1851 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1852   if test "$with_xaw3d" != no; then
1853     AC_MSG_CHECKING(for xaw3d)
1854     AC_CACHE_VAL(emacs_cv_xaw3d,
1855     [AC_TRY_LINK([
1856 #include <X11/Intrinsic.h>
1857 #include <X11/Xaw3d/Simple.h>],
1858       [],
1859       emacs_cv_xaw3d=yes,
1860       emacs_cv_xaw3d=no)])
1861   else
1862     emacs_cv_xaw3d=no
1863   fi
1864   if test $emacs_cv_xaw3d = yes; then
1865     AC_MSG_RESULT([yes; using Lucid toolkit])
1866     USE_X_TOOLKIT=LUCID
1867     HAVE_XAW3D=yes
1868     LUCID_LIBW=-lXaw3d
1869     AC_DEFINE(HAVE_XAW3D, 1,
1870               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1871   else
1872     AC_MSG_RESULT(no)
1873     AC_MSG_CHECKING(for libXaw)
1874     AC_CACHE_VAL(emacs_cv_xaw,
1875     [AC_TRY_LINK([
1876 #include <X11/Intrinsic.h>
1877 #include <X11/Xaw/Simple.h>],
1878       [],
1879       emacs_cv_xaw=yes,
1880       emacs_cv_xaw=no)])
1881     if test $emacs_cv_xaw = yes; then
1882       AC_MSG_RESULT([yes; using Lucid toolkit])
1883       USE_X_TOOLKIT=LUCID
1884       LUCID_LIBW=-lXaw
1885     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1886       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1887     else
1888       AC_MSG_RESULT([no; do not use toolkit by default])
1889       USE_X_TOOLKIT=none
1890     fi
1891   fi
1892 fi
1893
1894 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1895
1896 LIBXTR6=
1897 if test "${USE_X_TOOLKIT}" != "none"; then
1898   AC_MSG_CHECKING(X11 toolkit version)
1899   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1900   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1901 [#if XtSpecificationRelease < 6
1902 fail;
1903 #endif
1904 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1905   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1906   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1907     AC_MSG_RESULT(6 or newer)
1908     AC_DEFINE(HAVE_X11XTR6, 1,
1909               [Define to 1 if you have the X11R6 or newer version of Xt.])
1910     LIBXTR6="-lSM -lICE"
1911     case "$opsys" in
1912       ## Use libw.a along with X11R6 Xt.
1913       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
1914     esac
1915   else
1916     AC_MSG_RESULT(before 6)
1917   fi
1918
1919 dnl If using toolkit, check whether libXmu.a exists.
1920 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1921   OLDLIBS="$LIBS"
1922   if test x$HAVE_X11XTR6 = xyes; then
1923     LIBS="-lXt -lSM -lICE $LIBS"
1924   else
1925     LIBS="-lXt $LIBS"
1926   fi
1927   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1928   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1929 fi
1930 AC_SUBST(LIBXTR6)
1931
1932 dnl FIXME the logic here seems weird, but this is what cpp was doing.
1933 dnl Why not just test for libxmu in the normal way?
1934 LIBXMU=-lXmu
1935 case "$machine" in
1936   ## These machines don't supply Xmu.
1937   hpux* | aix4-2 )
1938     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
1939     ;;
1940 esac
1941 AC_SUBST(LIBXMU)
1942
1943 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1944 if test "${HAVE_X11}" = "yes"; then
1945   if test "${USE_X_TOOLKIT}" != "none"; then
1946     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1947   fi
1948 fi
1949
1950 LIBXP=
1951 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1952   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1953   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1954     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1955 int x = 5;
1956 #else
1957 Motif version prior to 2.1.
1958 #endif],
1959     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1960   if test $emacs_cv_motif_version_2_1 = yes; then
1961     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
1962   else
1963     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1964     # We put this in CFLAGS temporarily to precede other -I options
1965     # that might be in CFLAGS temporarily.
1966     # We put this in CPPFLAGS where it precedes the other -I options.
1967     OLD_CPPFLAGS=$CPPFLAGS
1968     OLD_CFLAGS=$CFLAGS
1969     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1970     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1971     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1972       [int x = 5;],
1973       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1974     if test $emacs_cv_lesstif = yes; then
1975       # Make sure this -I option remains in CPPFLAGS after it is set
1976       # back to REAL_CPPFLAGS.
1977       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1978       # have those other -I options anyway.  Ultimately, having this
1979       # directory ultimately in CPPFLAGS will be enough.
1980       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1981       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1982     else
1983       CFLAGS=$OLD_CFLAGS
1984       CPPFLAGS=$OLD_CPPFLAGS
1985     fi
1986   fi
1987 fi
1988
1989 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1990 dnl using Motif or Xaw3d is available, and unless
1991 dnl --with-toolkit-scroll-bars=no was specified.
1992
1993 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1994             [Define to 1 if we should use toolkit scroll bars.])dnl
1995 USE_TOOLKIT_SCROLL_BARS=no
1996 if test "${with_toolkit_scroll_bars}" != "no"; then
1997   if test "${USE_X_TOOLKIT}" != "none"; then
1998     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1999       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2000       HAVE_XAW3D=no
2001       USE_TOOLKIT_SCROLL_BARS=yes
2002     elif test "${HAVE_XAW3D}" = "yes"; then
2003       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2004       USE_TOOLKIT_SCROLL_BARS=yes
2005     fi
2006   elif test "${HAVE_GTK}" = "yes"; then
2007     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2008     USE_TOOLKIT_SCROLL_BARS=yes
2009   elif test "${HAVE_NS}" = "yes"; then
2010     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2011     USE_TOOLKIT_SCROLL_BARS=yes
2012   fi
2013 fi
2014
2015 dnl See if XIM is available.
2016 AC_TRY_COMPILE([
2017           #include <X11/Xlib.h>
2018           #include <X11/Xresource.h>],
2019          [XIMProc  callback;],
2020          [HAVE_XIM=yes
2021          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2022          HAVE_XIM=no)
2023
2024 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2025
2026 if test "${with_xim}" != "no"; then
2027   AC_DEFINE(USE_XIM, 1,
2028             [Define to 1 if we should use XIM, if it is available.])
2029 fi
2030
2031
2032 if test "${HAVE_XIM}" != "no"; then
2033   late_CFLAGS=$CFLAGS
2034   if test "$GCC" = yes; then
2035     CFLAGS="$CFLAGS --pedantic-errors"
2036   fi
2037   AC_TRY_COMPILE([
2038 #include <X11/Xlib.h>
2039 #include <X11/Xresource.h>],
2040 [Display *display;
2041 XrmDatabase db;
2042 char *res_name;
2043 char *res_class;
2044 XIMProc  callback;
2045 XPointer *client_data;
2046 #ifndef __GNUC__
2047 /* If we're not using GCC, it's probably not XFree86, and this is
2048    probably right, but we can't use something like --pedantic-errors.  */
2049 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2050                                            char*, XIMProc, XPointer*);
2051 #endif
2052 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2053    client_data);],
2054     [emacs_cv_arg6_star=yes])
2055   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2056          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2057 either XPointer or XPointer*.])dnl
2058   if test "$emacs_cv_arg6_star" = yes; then
2059     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2060   else
2061     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2062   fi
2063   CFLAGS=$late_CFLAGS
2064 fi
2065
2066 ### Start of font-backend (under any platform) section.
2067 # (nothing here yet -- this is a placeholder)
2068 ### End of font-backend (under any platform) section.
2069
2070 ### Start of font-backend (under X11) section.
2071 if test "${HAVE_X11}" = "yes"; then
2072    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2073
2074    ## Use -lXft if available, unless `--with-xft=no'.
2075    HAVE_XFT=maybe
2076     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2077       with_xft="no";
2078     fi
2079     if test "x${with_xft}" != "xno"; then
2080
2081       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2082       ## Because xftfont.c uses XRenderQueryExtension, we also
2083       ## need to link to -lXrender.
2084       HAVE_XRENDER=no
2085       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2086       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2087         OLD_CPPFLAGS="$CPPFLAGS"
2088         OLD_CFLAGS="$CFLAGS"
2089         OLD_LIBS="$LIBS"
2090         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2091         CFLAGS="$CFLAGS $XFT_CFLAGS"
2092         XFT_LIBS="-lXrender $XFT_LIBS"
2093         LIBS="$XFT_LIBS $LIBS"
2094         AC_CHECK_HEADER(X11/Xft/Xft.h,
2095           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2096
2097         if test "${HAVE_XFT}" = "yes"; then
2098           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2099             AC_SUBST(XFT_LIBS)
2100           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2101         else
2102           CPPFLAGS="$OLD_CPPFLAGS"
2103           CFLAGS="$OLD_CFLAGS"
2104           LIBS="$OLD_LIBS"
2105         fi                        # "${HAVE_XFT}" = "yes"
2106       fi                          # "$HAVE_XFT" != no
2107     fi                            # "x${with_xft}" != "xno"
2108
2109     dnl For the "Does Emacs use" message at the end.
2110     if test "$HAVE_XFT" != "yes"; then
2111        HAVE_XFT=no
2112     fi
2113
2114
2115     HAVE_FREETYPE=no
2116     ## We used to allow building with FreeType and without Xft.
2117     ## However, the ftx font backend driver is not in good shape.
2118     if test "${HAVE_XFT}" = "yes"; then
2119       dnl As we use Xft, we anyway use freetype.
2120       dnl There's no need for additional CFLAGS and LIBS.
2121       HAVE_FREETYPE=yes
2122       FONTCONFIG_CFLAGS=
2123       FONTCONFIG_LIBS=
2124     fi
2125
2126     HAVE_LIBOTF=no
2127     if test "${HAVE_FREETYPE}" = "yes"; then
2128       AC_DEFINE(HAVE_FREETYPE, 1,
2129                 [Define to 1 if using the freetype and fontconfig libraries.])
2130       if test "${with_libotf}" != "no"; then
2131         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2132                           HAVE_LIBOTF=no)
2133         if test "$HAVE_LIBOTF" = "yes"; then
2134           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2135           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2136                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2137                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2138           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2139             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2140                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2141           fi
2142         fi
2143       fi
2144     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2145     dnl Does the new font backend require it, or can it work without it?
2146     fi
2147
2148     HAVE_M17N_FLT=no
2149     if test "${HAVE_LIBOTF}" = yes; then
2150       if test "${with_m17n_flt}" != "no"; then
2151         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2152         if test "$HAVE_M17N_FLT" = "yes"; then
2153           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2154         fi
2155       fi
2156     fi
2157 else
2158     HAVE_XFT=no
2159     HAVE_FREETYPE=no
2160     HAVE_LIBOTF=no
2161     HAVE_M17N_FLT=no
2162 fi
2163
2164 FONT_OBJ=xfont.o
2165 if test "$HAVE_XFT" = "yes"; then
2166   FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
2167 elif test "$HAVE_FREETYPE" = "yes"; then
2168   FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
2169 fi
2170 AC_SUBST(FONT_OBJ)
2171
2172 ### End of font-backend (under X11) section.
2173
2174 AC_SUBST(FREETYPE_CFLAGS)
2175 AC_SUBST(FREETYPE_LIBS)
2176 AC_SUBST(FONTCONFIG_CFLAGS)
2177 AC_SUBST(FONTCONFIG_LIBS)
2178 AC_SUBST(LIBOTF_CFLAGS)
2179 AC_SUBST(LIBOTF_LIBS)
2180 AC_SUBST(M17N_FLT_CFLAGS)
2181 AC_SUBST(M17N_FLT_LIBS)
2182
2183 ### Use -lXpm if available, unless `--with-xpm=no'.
2184 HAVE_XPM=no
2185 LIBXPM=
2186 if test "${HAVE_X11}" = "yes"; then
2187   if test "${with_xpm}" != "no"; then
2188     AC_CHECK_HEADER(X11/xpm.h,
2189       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2190     if test "${HAVE_XPM}" = "yes"; then
2191       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2192       AC_EGREP_CPP(no_return_alloc_pixels,
2193       [#include "X11/xpm.h"
2194 #ifndef XpmReturnAllocPixels
2195 no_return_alloc_pixels
2196 #endif
2197       ], HAVE_XPM=no, HAVE_XPM=yes)
2198
2199       if test "${HAVE_XPM}" = "yes"; then
2200         AC_MSG_RESULT(yes)
2201       else
2202         AC_MSG_RESULT(no)
2203       fi
2204     fi
2205   fi
2206
2207   if test "${HAVE_XPM}" = "yes"; then
2208     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2209     LIBXPM=-lXpm
2210   fi
2211 fi
2212 AC_SUBST(LIBXPM)
2213
2214 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2215 HAVE_JPEG=no
2216 LIBJPEG=
2217 if test "${HAVE_X11}" = "yes"; then
2218   if test "${with_jpeg}" != "no"; then
2219     dnl Checking for jpeglib.h can lose because of a redefinition of
2220     dnl  HAVE_STDLIB_H.
2221     AC_CHECK_HEADER(jerror.h,
2222       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2223   fi
2224
2225   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2226   if test "${HAVE_JPEG}" = "yes"; then
2227     AC_DEFINE(HAVE_JPEG)
2228     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2229         [#include <jpeglib.h>
2230          version=JPEG_LIB_VERSION
2231 ],
2232         [AC_DEFINE(HAVE_JPEG)],
2233         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2234         HAVE_JPEG=no])
2235   fi
2236   if test "${HAVE_JPEG}" = "yes"; then
2237     LIBJPEG=-ljpeg
2238   fi
2239 fi
2240 AC_SUBST(LIBJPEG)
2241
2242 ### Use -lpng if available, unless `--with-png=no'.
2243 HAVE_PNG=no
2244 LIBPNG=
2245 if test "${HAVE_X11}" = "yes"; then
2246   if test "${with_png}" != "no"; then
2247     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2248     # in /usr/include/libpng.
2249     AC_CHECK_HEADERS(png.h libpng/png.h)
2250     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2251       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2252     fi
2253   fi
2254
2255   if test "${HAVE_PNG}" = "yes"; then
2256     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2257     LIBPNG="-lpng -lz -lm"
2258   fi
2259 fi
2260 AC_SUBST(LIBPNG)
2261
2262 ### Use -ltiff if available, unless `--with-tiff=no'.
2263 HAVE_TIFF=no
2264 LIBTIFF=
2265 if test "${HAVE_X11}" = "yes"; then
2266   if test "${with_tiff}" != "no"; then
2267     AC_CHECK_HEADER(tiffio.h,
2268       [tifflibs="-lz -lm"
2269       # At least one tiff package requires the jpeg library.
2270       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2271       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2272   fi
2273
2274   if test "${HAVE_TIFF}" = "yes"; then
2275     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2276     dnl FIXME -lz -lm, as per libpng?
2277     LIBTIFF=-ltiff
2278   fi
2279 fi
2280 AC_SUBST(LIBTIFF)
2281
2282 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2283 HAVE_GIF=no
2284 LIBGIF=
2285 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2286   AC_CHECK_HEADER(gif_lib.h,
2287 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2288 # Earlier versions can crash Emacs.
2289     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2290
2291   if test "$HAVE_GIF" = yes; then
2292     LIBGIF=-lgif
2293   elif test "$HAVE_GIF" = maybe; then
2294 # If gif_lib.h but no libgif, try libungif.
2295     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2296     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2297   fi
2298
2299   if test "${HAVE_GIF}" = "yes"; then
2300     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2301   fi
2302 fi
2303 AC_SUBST(LIBGIF)
2304
2305 dnl Check for required libraries.
2306 if test "${HAVE_X11}" = "yes"; then
2307   MISSING=""
2308   WITH_NO=""
2309   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2310     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2311   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2312     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2313   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2314     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2315   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2316     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2317   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2318     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2319
2320   if test "X${MISSING}" != X; then
2321     AC_MSG_ERROR([The following required libraries were not found:
2322     $MISSING
2323 Maybe some development libraries/packages are missing?
2324 If you don't want to link with them give
2325     $WITH_NO
2326 as options to configure])
2327   fi
2328 fi
2329
2330 ### Use -lgpm if available, unless `--with-gpm=no'.
2331 HAVE_GPM=no
2332 LIBGPM=
2333 GPM_MOUSE_SUPPORT=
2334 if test "${with_gpm}" != "no"; then
2335   AC_CHECK_HEADER(gpm.h,
2336     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2337
2338   if test "${HAVE_GPM}" = "yes"; then
2339     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2340     LIBGPM=-lgpm
2341     GPM_MOUSE_SUPPORT="\${lispsource}mouse.elc"
2342   fi
2343 fi
2344 AC_SUBST(LIBGPM)
2345 AC_SUBST(GPM_MOUSE_SUPPORT)
2346
2347 dnl Check for malloc/malloc.h on darwin
2348 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2349
2350 C_SWITCH_X_SYSTEM=
2351 ### Use NeXTstep API to implement GUI.
2352 if test "${HAVE_NS}" = "yes"; then
2353   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2354   if test "${NS_IMPL_COCOA}" = "yes"; then
2355     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2356     GNU_OBJC_CFLAGS=
2357   fi
2358   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2359     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2360     # See also .m.o rule in Makefile.in */
2361     # FIXME: are all these flags really needed?  Document here why.  */
2362     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2363     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2364   fi
2365   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2366     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2367   fi
2368   # We also have mouse menus.
2369   HAVE_MENUS=yes
2370   OTHER_FILES=ns-app
2371 fi
2372
2373
2374 ### Use session management (-lSM -lICE) if available
2375 HAVE_X_SM=no
2376 LIBXSM=
2377 if test "${HAVE_X11}" = "yes"; then
2378   AC_CHECK_HEADER(X11/SM/SMlib.h,
2379     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2380
2381   if test "${HAVE_X_SM}" = "yes"; then
2382     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2383     LIBXSM="-lSM -lICE"
2384     case "$LIBS" in
2385       *-lSM*) ;;
2386       *)      LIBS="$LIBXSM $LIBS" ;;
2387     esac
2388   fi
2389 fi
2390 AC_SUBST(LIBXSM)
2391
2392 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2393 AC_CACHE_CHECK(whether netdb declares h_errno,
2394                emacs_cv_netdb_declares_h_errno,
2395 [AC_TRY_LINK([#include <netdb.h>],
2396   [return h_errno;],
2397   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2398 if test $emacs_cv_netdb_declares_h_errno = yes; then
2399   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2400 fi
2401
2402 AC_FUNC_ALLOCA
2403
2404 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2405 dnl FIXME is there an autoconf test that does the right thing, without
2406 dnl needing to call A_M_E afterwards?
2407 if test x"$ac_cv_func_alloca_works" != xyes; then
2408    AC_MSG_ERROR( [a system implementation of alloca is required] )
2409 fi
2410
2411 # fmod, logb, and frexp are found in -lm on most systems.
2412 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2413 AC_CHECK_LIB(m, sqrt)
2414
2415 # Check for mail-locking functions in a "mail" library.  Probably this should
2416 # have the same check as for liblockfile below.
2417 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2418 if test $have_mail = yes; then
2419   LIBS_MAIL=-lmail
2420   LIBS="$LIBS_MAIL $LIBS"
2421   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2422 else
2423   LIBS_MAIL=
2424 fi
2425 dnl Debian, at least:
2426 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2427 if test $have_lockfile = yes; then
2428    LIBS_MAIL=-llockfile
2429    LIBS="$LIBS_MAIL $LIBS"
2430    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2431 else
2432 # If we have the shared liblockfile, assume we must use it for mail
2433 # locking (e.g. Debian).  If we couldn't link against liblockfile
2434 # (no liblockfile.a installed), ensure that we don't need to.
2435   dnl This works for files generally, not just executables.
2436   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2437   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2438                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2439   if test $ac_cv_prog_liblockfile = yes; then
2440     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2441 This probably means that movemail could lose mail.
2442 There may be a `development' package to install containing liblockfile.])
2443   fi
2444 fi
2445 AC_CHECK_FUNCS(touchlock)
2446 AC_CHECK_HEADERS(maillock.h)
2447 AC_SUBST(LIBS_MAIL)
2448
2449 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2450 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2451 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2452 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2453 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2454 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2455 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2456 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2457 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2458 cfmakeraw cfsetspeed)
2459
2460 AC_CHECK_HEADERS(sys/un.h)
2461
2462 AC_FUNC_MKTIME
2463 if test "$ac_cv_func_working_mktime" = no; then
2464   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2465 fi
2466
2467 AC_FUNC_GETLOADAVG
2468
2469 AC_FUNC_FSEEKO
2470
2471 # Configure getopt.
2472 m4_include([m4/getopt.m4])
2473 gl_GETOPT_IFELSE([
2474   gl_GETOPT_SUBSTITUTE_HEADER
2475   gl_PREREQ_GETOPT
2476   GETOPTOBJS='getopt.o getopt1.o'
2477 ])
2478 AC_SUBST(GETOPTOBJS)
2479
2480 AC_FUNC_GETPGRP
2481
2482 AC_FUNC_STRFTIME
2483
2484 # UNIX98 PTYs.
2485 AC_CHECK_FUNCS(grantpt)
2486
2487 # PTY-related GNU extensions.
2488 AC_CHECK_FUNCS(getpt)
2489
2490 # Check this now, so that we will NOT find the above functions in ncurses.
2491 # That is because we have not set up to link ncurses in lib-src.
2492 # It's better to believe a function is not available
2493 # than to expect to find it in ncurses.
2494 # Also we need tputs and frieds to be able to build at all.
2495 have_tputs_et_al=true
2496 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2497 if test "$have_tputs_et_al" != true; then
2498   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2499 Maybe some development libraries/packages are missing?  Try installing
2500 libncurses-dev(el), libterminfo-dev(el) or similar.])
2501 fi
2502 # Must define this when any termcap library is found.
2503 AC_DEFINE(HAVE_LIBNCURSES, 1,
2504           [Define to 1 if you have the `ncurses' library (-lncurses).])
2505
2506 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2507
2508 resolv=no
2509 AC_TRY_LINK([#include <netinet/in.h>
2510 #include <arpa/nameser.h>
2511 #include <resolv.h>],
2512     [return res_init();],
2513     have_res_init=yes, have_res_init=no)
2514 if test "$have_res_init" = no; then
2515   OLIBS="$LIBS"
2516   LIBS="$LIBS -lresolv"
2517   AC_MSG_CHECKING(for res_init with -lresolv)
2518   AC_TRY_LINK([#include <netinet/in.h>
2519 #include <arpa/nameser.h>
2520 #include <resolv.h>],
2521     [return res_init();],
2522     have_res_init=yes, have_res_init=no)
2523   AC_MSG_RESULT($have_res_init)
2524   if test "$have_res_init" = yes ; then
2525     resolv=yes
2526   fi
2527   LIBS="$OLIBS"
2528 fi
2529
2530 if test "$have_res_init" = yes; then
2531   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2532 fi
2533
2534 # Do we need the Hesiod library to provide the support routines?
2535 LIBHESIOD=
2536 if test "$with_hesiod" != no ; then
2537   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2538   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2539      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2540                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2541   if test "$resolv" = yes ; then
2542     RESOLVLIB=-lresolv
2543   else
2544     RESOLVLIB=
2545   fi
2546   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2547         hesiod=yes, :, $RESOLVLIB)])
2548
2549   if test x"$hesiod" = xyes; then
2550     AC_DEFINE(HAVE_LIBHESIOD, 1,
2551               [Define to 1 if you have the hesiod library (-lhesiod).])
2552     LIBHESIOD=-lhesiod
2553   fi
2554 fi
2555 AC_SUBST(LIBHESIOD)
2556
2557 # Do we need libresolv (due to res_init or Hesiod)?
2558 if test "$resolv" = yes ; then
2559   AC_DEFINE(HAVE_LIBRESOLV, 1,
2560             [Define to 1 if you have the resolv library (-lresolv).])
2561   LIBRESOLV=-lresolv
2562 else
2563   LIBRESOLV=
2564 fi
2565 AC_SUBST(LIBRESOLV)
2566
2567 # These tell us which Kerberos-related libraries to use.
2568 COM_ERRLIB=
2569 CRYPTOLIB=
2570 KRB5LIB=
2571 DESLIB=
2572 KRB4LIB=
2573
2574 if test "${with_kerberos}" != no; then
2575   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2576   if test $have_com_err = yes; then
2577     COM_ERRLIB=-lcom_err
2578     LIBS="$COM_ERRLIB $LIBS"
2579     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2580   fi
2581   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2582   if test $have_crypto = yes; then
2583     CRYPTOLIB=-lcrypto
2584     LIBS="$CRYPTOLIB $LIBS"
2585     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2586   fi
2587   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2588   if test $have_k5crypto = yes; then
2589     CRYPTOLIB=-lk5crypto
2590     LIBS="$CRYPTOLIB $LIBS"
2591     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2592   fi
2593   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2594   if test $have_krb5=yes; then
2595     KRB5LIB=-lkrb5
2596     LIBS="$KRB5LIB $LIBS"
2597     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2598   fi
2599   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2600   if test "${with_kerberos5}" = no; then
2601     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2602     if test $have_des425 = yes; then
2603       DESLIB=-ldes425
2604       LIBS="$DESLIB $LIBS"
2605       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2606     else
2607       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2608       if test $have_des = yes; then
2609         DESLIB=-ldes
2610         LIBS="$DESLIB $LIBS"
2611         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2612       fi
2613     fi
2614     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2615     if test $have_krb4 = yes; then
2616       KRB4LIB=-lkrb4
2617       LIBS="$KRB4LIB $LIBS"
2618       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2619     else
2620       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2621       if test $have_krb = yes; then
2622         KRB4LIB=-lkrb
2623         LIBS="$KRB4LIB $LIBS"
2624         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2625       fi
2626     fi
2627   fi
2628
2629   if test "${with_kerberos5}" != no; then
2630     AC_CHECK_HEADERS(krb5.h,
2631       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2632                         [#include <krb5.h>])])
2633   else
2634     AC_CHECK_HEADERS(des.h,,
2635                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2636                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2637     AC_CHECK_HEADERS(krb.h,,
2638                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2639                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2640   fi
2641   AC_CHECK_HEADERS(com_err.h)
2642 fi
2643
2644 AC_SUBST(COM_ERRLIB)
2645 AC_SUBST(CRYPTOLIB)
2646 AC_SUBST(KRB5LIB)
2647 AC_SUBST(DESLIB)
2648 AC_SUBST(KRB4LIB)
2649
2650 # Solaris requires -lintl if you want strerror (which calls dgettext)
2651 # to return localized messages.
2652 AC_CHECK_LIB(intl, dgettext)
2653
2654 AC_MSG_CHECKING(whether localtime caches TZ)
2655 AC_CACHE_VAL(emacs_cv_localtime_cache,
2656 [if test x$ac_cv_func_tzset = xyes; then
2657 AC_TRY_RUN([#include <time.h>
2658 extern char **environ;
2659 unset_TZ ()
2660 {
2661   char **from, **to;
2662   for (to = from = environ; (*to = *from); from++)
2663     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2664       to++;
2665 }
2666 char TZ_GMT0[] = "TZ=GMT0";
2667 char TZ_PST8[] = "TZ=PST8";
2668 main()
2669 {
2670   time_t now = time ((time_t *) 0);
2671   int hour_GMT0, hour_unset;
2672   if (putenv (TZ_GMT0) != 0)
2673     exit (1);
2674   hour_GMT0 = localtime (&now)->tm_hour;
2675   unset_TZ ();
2676   hour_unset = localtime (&now)->tm_hour;
2677   if (putenv (TZ_PST8) != 0)
2678     exit (1);
2679   if (localtime (&now)->tm_hour == hour_GMT0)
2680     exit (1);
2681   unset_TZ ();
2682   if (localtime (&now)->tm_hour != hour_unset)
2683     exit (1);
2684   exit (0);
2685 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2686 [# If we have tzset, assume the worst when cross-compiling.
2687 emacs_cv_localtime_cache=yes])
2688 else
2689         # If we lack tzset, report that localtime does not cache TZ,
2690         # since we can't invalidate the cache if we don't have tzset.
2691         emacs_cv_localtime_cache=no
2692 fi])dnl
2693 AC_MSG_RESULT($emacs_cv_localtime_cache)
2694 if test $emacs_cv_localtime_cache = yes; then
2695   AC_DEFINE(LOCALTIME_CACHE, 1,
2696             [Define to 1 if localtime caches TZ.])
2697 fi
2698
2699 if test "x$HAVE_TIMEVAL" = xyes; then
2700   AC_CHECK_FUNCS(gettimeofday)
2701   if test $ac_cv_func_gettimeofday = yes; then
2702     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2703                    emacs_cv_gettimeofday_two_arguments,
2704     [AC_TRY_COMPILE([
2705 #ifdef TIME_WITH_SYS_TIME
2706 #include <sys/time.h>
2707 #include <time.h>
2708 #else
2709 #ifdef HAVE_SYS_TIME_H
2710 #include <sys/time.h>
2711 #else
2712 #include <time.h>
2713 #endif
2714 #endif],
2715       [struct timeval time;
2716        gettimeofday (&time, 0);],
2717       emacs_cv_gettimeofday_two_arguments=yes,
2718       emacs_cv_gettimeofday_two_arguments=no)])
2719     if test $emacs_cv_gettimeofday_two_arguments = no; then
2720       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2721                 [Define to 1 if gettimeofday accepts only one argument.])
2722     fi
2723   fi
2724 fi
2725
2726 ok_so_far=yes
2727 AC_CHECK_FUNC(socket, , ok_so_far=no)
2728 if test $ok_so_far = yes; then
2729   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2730 fi
2731 if test $ok_so_far = yes; then
2732   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2733 fi
2734 if test $ok_so_far = yes; then
2735 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2736   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2737             [Define to 1 if you have inet sockets.])
2738 fi
2739
2740 AC_CHECK_HEADERS(sys/ioctl.h)
2741
2742 if test -f /usr/lpp/X11/bin/smt.exp; then
2743   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2744             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2745 fi
2746
2747 AC_MSG_CHECKING(whether system supports dynamic ptys)
2748 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2749   AC_MSG_RESULT(yes)
2750   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2751 else
2752   AC_MSG_RESULT(no)
2753 fi
2754
2755 AC_FUNC_FORK
2756
2757 dnl Adapted from Haible's version.
2758 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2759   [AC_TRY_LINK([#include <langinfo.h>],
2760     [char* cs = nl_langinfo(CODESET);],
2761     emacs_cv_langinfo_codeset=yes,
2762     emacs_cv_langinfo_codeset=no)
2763   ])
2764 if test $emacs_cv_langinfo_codeset = yes; then
2765   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2766     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2767 fi
2768
2769 AC_CHECK_TYPES(size_t)
2770
2771 AC_TYPE_MBSTATE_T
2772
2773 dnl Restrict could probably be used effectively other than in regex.c.
2774 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2775   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2776                   emacs_cv_c_restrict=yes,
2777                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2778                                   emacs_cv_c_restrict=__restrict,
2779                                   emacs_cv_c_restrict=no)])])
2780 case "$emacs_cv_c_restrict" in
2781   yes) emacs_restrict=restrict;;
2782   no) emacs_restrict="";;
2783   *) emacs_restrict="$emacs_cv_c_restrict";;
2784 esac
2785 if test "$emacs_restrict" != __restrict; then
2786   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2787     [Define to compiler's equivalent of C99 restrict keyword.
2788      Don't define if equivalent is `__restrict'.])
2789 fi
2790
2791 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2792   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2793                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2794 if test "$emacs_cv_c_restrict_arr" = yes; then
2795   AC_DEFINE(__restrict_arr, __restrict,
2796     [Define to compiler's equivalent of C99 restrict keyword in array
2797      declarations.  Define as empty for no equivalent.])
2798 fi
2799
2800 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2801 dnl how the tty code is related to POSIX and/or other versions of termios.
2802 dnl The following looks like a useful start.
2803 dnl
2804 dnl AC_SYS_POSIX_TERMIOS
2805 dnl if test $ac_cv_sys_posix_termios = yes; then
2806 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2807 dnl                                and macros for terminal control.])
2808 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2809 dnl fi
2810
2811 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2812
2813 # Set up the CFLAGS for real compilation, so we can substitute it.
2814 CFLAGS="$REAL_CFLAGS"
2815 CPPFLAGS="$REAL_CPPFLAGS"
2816
2817 #### Find out which version of Emacs this is.
2818 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2819          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2820 if test x"${version}" = x; then
2821   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2822 fi
2823 if test x"${version}" != x"$PACKAGE_VERSION"; then
2824   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/lisp/version.el'.])
2825 fi
2826
2827 ### Specify what sort of things we'll be editing into Makefile and config.h.
2828 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2829 AC_SUBST(version)
2830 AC_SUBST(configuration)
2831 AC_SUBST(canonical)
2832 AC_SUBST(srcdir)
2833 AC_SUBST(prefix)
2834 AC_SUBST(exec_prefix)
2835 AC_SUBST(bindir)
2836 AC_SUBST(datadir)
2837 AC_SUBST(sharedstatedir)
2838 AC_SUBST(libexecdir)
2839 AC_SUBST(mandir)
2840 AC_SUBST(infodir)
2841 AC_SUBST(lispdir)
2842 AC_SUBST(locallisppath)
2843 AC_SUBST(lisppath)
2844 AC_SUBST(x_default_search_path)
2845 AC_SUBST(etcdir)
2846 AC_SUBST(archlibdir)
2847 AC_SUBST(docdir)
2848 AC_SUBST(bitmapdir)
2849 AC_SUBST(gamedir)
2850 AC_SUBST(gameuser)
2851 AC_SUBST(unexec)
2852 AC_SUBST(LD_SWITCH_X_SITE)
2853 AC_SUBST(C_SWITCH_X_SITE)
2854 AC_SUBST(C_SWITCH_X_SYSTEM)
2855 AC_SUBST(CFLAGS)
2856 ## Used in lwlib/Makefile.in.
2857 AC_SUBST(X_TOOLKIT_TYPE)
2858 AC_SUBST(machfile)
2859 AC_SUBST(opsysfile)
2860 AC_SUBST(GETLOADAVG_LIBS)
2861 AC_SUBST(ns_appdir)
2862 AC_SUBST(ns_appbindir)
2863 AC_SUBST(ns_appresdir)
2864 AC_SUBST(ns_appsrc)
2865 AC_SUBST(GNUSTEP_MAKEFILES)
2866 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2867 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2868 AC_SUBST(GNU_OBJC_CFLAGS)
2869 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2870 AC_SUBST(OTHER_FILES)
2871
2872 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2873                    [Define to the canonical Emacs configuration name.])
2874 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2875                    [Define to the options passed to configure.])
2876 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2877                    [Define to the used machine dependent file.])
2878 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2879                    [Define to the used os dependent file.])
2880 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2881 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2882  may need to deal with X Windows.  For instance, if you've defined
2883  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2884  your loader can find on its own, you might want to add "-L/..." or
2885  something similar.])
2886 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2887 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2888  may need to deal with X Windows.  For instance, if you've defined
2889  HAVE_X_WINDOWS above and your X include files aren't in a place
2890  that your compiler can find on its own, you might want to add
2891  "-I/..." or something similar.])
2892
2893 XMENU_OBJ=
2894 XOBJ=
2895 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2896   AC_DEFINE(HAVE_X_WINDOWS, 1,
2897             [Define to 1 if you want to use the X window system.])
2898   XMENU_OBJ=xmenu.o
2899   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
2900 fi
2901 AC_SUBST(XMENU_OBJ)
2902 AC_SUBST(XOBJ)
2903
2904 WIDGET_OBJ=
2905 MOTIF_LIBW=
2906 if test "${USE_X_TOOLKIT}" != "none" ; then
2907   WIDGET_OBJ=widget.o
2908   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2909   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2910     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2911   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2912     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2913     MOTIF_LIBW=-lXm
2914     case "$opsys" in
2915       gnu-linux)
2916         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
2917         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
2918         ;;
2919
2920       unixware)
2921         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
2922         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
2923         MOTIF_LIBW="MOTIF_LIBW -lXimp"
2924         ;;
2925
2926       aix4-2)
2927         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
2928         MOTIF_LIBW="$MOTIF_LIBW -li18n"
2929         ;;
2930     esac
2931     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
2932   fi
2933 fi
2934 AC_SUBST(WIDGET_OBJ)
2935
2936 TOOLKIT_LIBW=
2937 case "$USE_X_TOOLKIT" in
2938   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
2939   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
2940   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
2941 esac
2942 AC_SUBST(TOOLKIT_LIBW)
2943
2944 if test "$USE_X_TOOLKIT" = "none"; then
2945   LIBXT_OTHER="\$(LIBXSM)"
2946 else
2947   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
2948 fi
2949 AC_SUBST(LIBXT_OTHER)
2950
2951 ## The X Menu stuff is present in the X10 distribution, but missing
2952 ## from X11.  If we have X10, just use the installed library;
2953 ## otherwise, use our own copy.
2954 if test "${HAVE_X11}" = "yes" ; then
2955   AC_DEFINE(HAVE_X11, 1,
2956             [Define to 1 if you want to use version 11 of X windows.
2957              Otherwise, Emacs expects to use version 10.])
2958
2959   if test "$USE_X_TOOLKIT" = "none"; then
2960     OLDXMENU="\${oldXMenudir}libXMenu11.a"
2961   else
2962     OLDXMENU="\${lwlibdir}liblw.a"
2963   fi
2964   LIBXMENU="\$(OLDXMENU)"
2965   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
2966 else
2967   OLDXMENU=
2968   LIBXMENU="-lXMenu"
2969   LIBX_OTHER=
2970 fi
2971
2972 if test "$HAVE_GTK" = "yes"; then
2973   OLDXMENU=
2974   LIBXMENU=
2975 fi
2976
2977 AC_SUBST(OLDXMENU)
2978 AC_SUBST(LIBXMENU)
2979 AC_SUBST(LIBX_OTHER)
2980
2981 if test "${HAVE_MENUS}" = "yes" ; then
2982   AC_DEFINE(HAVE_MENUS, 1,
2983             [Define to 1 if you have mouse menus.
2984              (This is automatic if you use X, but the option to specify it remains.)
2985              It is also defined with other window systems that support xmenu.c.])
2986 fi
2987 if test "${GNU_MALLOC}" = "yes" ; then
2988   AC_DEFINE(GNU_MALLOC, 1,
2989             [Define to 1 if you want to use the GNU memory allocator.])
2990 fi
2991 if test "${REL_ALLOC}" = "yes" ; then
2992   AC_DEFINE(REL_ALLOC, 1,
2993             [Define REL_ALLOC if you want to use the relocating allocator for
2994              buffer space.])
2995 fi
2996
2997
2998 if test "$opsys" = "cygwin"; then
2999   CYGWIN_OBJ="sheap.o"
3000   ## Cygwin differs because of its unexec().
3001   PRE_ALLOC_OBJ=
3002   POST_ALLOC_OBJ="lastfile.o vm-limit.o"
3003 else
3004   CYGWIN_OBJ=
3005   PRE_ALLOC_OBJ=lastfile.o
3006   POST_ALLOC_OBJ="\$(vmlimitobj)"
3007 fi
3008 AC_SUBST(CYGWIN_OBJ)
3009 AC_SUBST(PRE_ALLOC_OBJ)
3010 AC_SUBST(POST_ALLOC_OBJ)
3011
3012
3013 case "$opsys" in
3014   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3015
3016   darwin)
3017   ## The -headerpad option tells ld (see man page) to leave room at the
3018   ## end of the header for adding load commands.  Needed for dumping.
3019   ## 0x690 is the total size of 30 segment load commands (at 56
3020   ## each); under Cocoa 31 commands are required.
3021   if test "$HAVE_NS" = "yes"; then
3022     libs_nsgui="-framework AppKit"
3023     headerpad_extra=6C8
3024   else
3025     libs_nsgui=
3026     headerpad_extra=690
3027   fi
3028   LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3029   ;;
3030
3031   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3032 esac
3033 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3034
3035
3036 AH_TOP([/* GNU Emacs site configuration template file.
3037    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3038      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3039
3040 This file is part of GNU Emacs.
3041
3042 GNU Emacs is free software: you can redistribute it and/or modify
3043 it under the terms of the GNU General Public License as published by
3044 the Free Software Foundation, either version 3 of the License, or
3045 (at your option) any later version.
3046
3047 GNU Emacs is distributed in the hope that it will be useful,
3048 but WITHOUT ANY WARRANTY; without even the implied warranty of
3049 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3050 GNU General Public License for more details.
3051
3052 You should have received a copy of the GNU General Public License
3053 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3054
3055
3056 /* No code in Emacs #includes config.h twice, but some bits of code
3057    intended to work with other packages as well (like gmalloc.c)
3058    think they can include it as many times as they like.  */
3059 #ifndef EMACS_CONFIG_H
3060 #define EMACS_CONFIG_H
3061 ])dnl
3062
3063 AH_BOTTOM([
3064 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
3065 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
3066 #define HAVE_WINDOW_SYSTEM
3067 #define HAVE_MOUSE
3068 #endif
3069
3070 /* Define AMPERSAND_FULL_NAME if you use the convention
3071    that & in the full name stands for the login id.  */
3072 /* Turned on June 1996 supposing nobody will mind it.  */
3073 #define AMPERSAND_FULL_NAME
3074
3075 /* Define HAVE_SOUND if we have sound support.  We know it works
3076    and compiles only on the specified platforms.   For others,
3077    it probably doesn't make sense to try.  */
3078
3079 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
3080 #ifdef HAVE_MACHINE_SOUNDCARD_H
3081 #define HAVE_SOUND 1
3082 #endif
3083 #ifdef HAVE_SYS_SOUNDCARD_H
3084 #define HAVE_SOUND 1
3085 #endif
3086 #ifdef HAVE_SOUNDCARD_H
3087 #define HAVE_SOUND 1
3088 #endif
3089 #ifdef HAVE_ALSA
3090 #define HAVE_SOUND 1
3091 #endif
3092 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
3093
3094 /* If using GNU, then support inline function declarations. */
3095 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3096    generally, because even if non-gcc compilers accept `inline', they
3097    may reject `extern inline'.  */
3098 #if defined (__GNUC__) && defined (OPTIMIZE)
3099 #define INLINE __inline__
3100 #else
3101 #define INLINE
3102 #endif
3103
3104 /* `subprocesses' should be defined if you want to
3105    have code for asynchronous subprocesses
3106    (as used in M-x compile and M-x shell).
3107    Only MSDOS does not support this (it overrides
3108    this in its config_opsysfile below).  */
3109
3110 #define subprocesses
3111
3112 /* Include the os and machine dependent files.  */
3113 #include config_opsysfile
3114 #include config_machfile
3115
3116 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
3117   (There is probably a better place to do this, but right now the Cocoa
3118    side does this in s/darwin.h and we cannot
3119    parallel this exactly since GNUstep is multi-OS. */
3120 #ifdef HAVE_NS
3121 # ifdef NS_IMPL_GNUSTEP
3122 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3123 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
3124 #  define SYSTEM_PURESIZE_EXTRA 30000
3125 # endif /* NS_IMPL_GNUSTEP */
3126 #endif /* HAVE_NS */
3127
3128 /* SIGTYPE is the macro we actually use.  */
3129 #ifndef SIGTYPE
3130 #define SIGTYPE RETSIGTYPE
3131 #endif
3132
3133 #ifdef emacs /* Don't do this for lib-src.  */
3134 /* Tell regex.c to use a type compatible with Emacs.  */
3135 #define RE_TRANSLATE_TYPE Lisp_Object
3136 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3137 #ifdef make_number
3138 /* If make_number is a macro, use it.  */
3139 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3140 #else
3141 /* If make_number is a function, avoid it.  */
3142 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3143 #endif
3144 #endif
3145
3146 /* Avoid link-time collision with system mktime if we will use our own.  */
3147 #if ! HAVE_MKTIME || BROKEN_MKTIME
3148 #define mktime emacs_mktime
3149 #endif
3150
3151 #define my_strftime nstrftime   /* for strftime.c */
3152
3153 /* The rest of the code currently tests the CPP symbol BSTRING.
3154    Override any claims made by the system-description files.
3155    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
3156 #undef BSTRING
3157 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
3158 #define BSTRING
3159 #endif
3160
3161 /* Some of the files of Emacs which are intended for use with other
3162    programs assume that if you have a config.h file, you must declare
3163    the type of getenv.
3164
3165    This declaration shouldn't appear when alloca.s or Makefile.in
3166    includes config.h.  */
3167 #ifndef NOT_C_CODE
3168 extern char *getenv ();
3169 #endif
3170
3171 /* These default definitions are good for almost all machines.
3172    The exceptions override them in m/MACHINE.h.  */
3173
3174 #ifndef BITS_PER_CHAR
3175 #define BITS_PER_CHAR 8
3176 #endif
3177
3178 #ifndef BITS_PER_SHORT
3179 #define BITS_PER_SHORT 16
3180 #endif
3181
3182 /* Note that lisp.h uses this in a preprocessor conditional, so it
3183    would not work to use sizeof.  That being so, we do all of them
3184    without sizeof, for uniformity's sake.  */
3185 #ifndef BITS_PER_INT
3186 #define BITS_PER_INT 32
3187 #endif
3188
3189 #ifndef BITS_PER_LONG
3190 #ifdef _LP64
3191 #define BITS_PER_LONG 64
3192 #else
3193 #define BITS_PER_LONG 32
3194 #endif
3195 #endif
3196
3197 /* Define if the compiler supports function prototypes.  It may do so
3198    but not define __STDC__ (e.g. DEC C by default) or may define it as
3199    zero.  */
3200 #undef PROTOTYPES
3201 /* For mktime.c:  */
3202 #ifndef __P
3203 # if defined PROTOTYPES
3204 #  define __P(args) args
3205 # else
3206 #  define __P(args) ()
3207 # endif  /* GCC.  */
3208 #endif /* __P */
3209
3210 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
3211 #ifndef NOT_C_CODE
3212 #ifdef HAVE_STRING_H
3213 #include "string.h"
3214 #endif
3215 #ifdef HAVE_STRINGS_H
3216 #include "strings.h"  /* May be needed for bcopy & al. */
3217 #endif
3218 #ifdef HAVE_STDLIB_H
3219 #include <stdlib.h>
3220 #endif
3221 #ifndef __GNUC__
3222 # ifdef HAVE_ALLOCA_H
3223 #  include <alloca.h>
3224 # else /* AIX files deal with #pragma.  */
3225 #  ifndef alloca /* predefined by HP cc +Olibcalls */
3226 char *alloca ();
3227 #  endif
3228 # endif /* HAVE_ALLOCA_H */
3229 #endif /* __GNUC__ */
3230 #ifndef HAVE_SIZE_T
3231 typedef unsigned size_t;
3232 #endif
3233 #endif /* NOT_C_CODE */
3234
3235 /* Define HAVE_X_I18N if we have usable i18n support.  */
3236
3237 #ifdef HAVE_X11R6
3238 #define HAVE_X_I18N
3239 #elif !defined X11R5_INHIBIT_I18N
3240 #define HAVE_X_I18N
3241 #endif
3242
3243 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
3244
3245 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3246 #define HAVE_X11R6_XIM
3247 #endif
3248
3249 #if defined __GNUC__ && (__GNUC__ > 2 \
3250                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3251 #define NO_RETURN       __attribute__ ((__noreturn__))
3252 #else
3253 #define NO_RETURN       /* nothing */
3254 #endif
3255
3256 /* These won't be used automatically yet.  We also need to know, at least,
3257    that the stack is continuous.  */
3258 #ifdef __GNUC__
3259 #  ifndef GC_SETJMP_WORKS
3260   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
3261      see NON_SAVING_SETJMP in the target descriptions.  */
3262   /* Exceptions (see NON_SAVING_SETJMP in target description) are
3263      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
3264      Fixme: Deal with SVR3.  */
3265 #    define GC_SETJMP_WORKS 1
3266 #  endif
3267 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3268 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3269 #  endif
3270 #endif
3271
3272 #ifndef HAVE_BCOPY
3273 #define bcopy(a,b,s) memcpy (b,a,s)
3274 #endif
3275 #ifndef HAVE_BZERO
3276 #define bzero(a,s) memset (a,0,s)
3277 #endif
3278 #ifndef HAVE_BCMP
3279 #define BCMP memcmp
3280 #endif
3281
3282 #endif /* EMACS_CONFIG_H */
3283
3284 /*
3285 Local Variables:
3286 mode: c
3287 End:
3288 */
3289 ])dnl
3290
3291 #### Report on what we decided to do.
3292 #### Report GTK as a toolkit, even if it doesn't use Xt.
3293 #### It makes printing result more understandable as using GTK sets
3294 #### toolkit_scroll_bars to yes by default.
3295 if test "${HAVE_GTK}" = "yes"; then
3296   USE_X_TOOLKIT=GTK
3297 fi
3298
3299 echo "
3300 Configured for \`${canonical}'.
3301
3302   Where should the build process find the source code?    ${srcdir}
3303   What operating system and machine description files should Emacs use?
3304         \`${opsysfile}' and \`${machfile}'
3305   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3306   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3307   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3308   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3309   What window system should Emacs use?                    ${window_system}
3310   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3311
3312 if test -n "${x_includes}"; then
3313 echo "  Where do we find X Windows header files?                ${x_includes}"
3314 else
3315 echo "  Where do we find X Windows header files?                Standard dirs"
3316 fi
3317 if test -n "${x_libraries}"; then
3318 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3319 else
3320 echo "  Where do we find X Windows libraries?                   Standard dirs"
3321 fi
3322
3323 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3324 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3325 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3326 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3327 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3328 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3329 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3330 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3331 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3332 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3333 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3334
3335 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3336 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3337 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3338 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3339
3340 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3341 echo
3342
3343 if test $USE_XASSERTS = yes; then
3344    echo "  Compiling with asserts turned on."
3345    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3346 fi
3347
3348 echo
3349
3350 if test "$HAVE_NS" = "yes"; then
3351    echo
3352    echo "You must run \"make install\" in order to test the built application.
3353 The installed application will go to nextstep/Emacs.app and can be
3354 run or moved from there."
3355    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3356       echo "The application will be fully self-contained."
3357     else
3358       echo "The lisp resources for the application will be installed under ${prefix}.
3359 You may need to run \"make install\" with sudo.  The application will fail
3360 to run if these resources are not installed."
3361    fi
3362    echo
3363 fi
3364
3365 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3366   echo "D-Bus integration has been tested for GNU/Linux only."
3367   echo
3368 fi
3369
3370
3371 # Remove any trailing slashes in these variables.
3372 [test "${prefix}" != NONE &&
3373   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3374 test "${exec_prefix}" != NONE &&
3375   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3376
3377 # Now get this: Some word that is part of the ${srcdir} directory name
3378 # or the ${configuration} value might, just might, happen to be an
3379 # identifier like `sun4' or `i386' or something, and be predefined by
3380 # the C preprocessor to some helpful value like 1, or maybe the empty
3381 # string.  Needless to say consequent macro substitutions are less
3382 # than conducive to the makefile finding the correct directory.
3383 [cpp_undefs="`echo $srcdir $configuration $canonical unix |
3384   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3385   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3386
3387 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3388 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3389 ## from Makefile.c can correctly provide the arg `-traditional' to the
3390 ## C preprocessor.
3391
3392 AC_EGREP_CPP(yes..yes,
3393         [yes..yes],
3394         CPP_NEED_TRADITIONAL=no,
3395         CPP_NEED_TRADITIONAL=yes)
3396
3397 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3398         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3399         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3400         lwlib/Makefile lisp/Makefile leim/Makefile, [
3401
3402 ### Make the necessary directories, if they don't exist.
3403 for dir in etc lisp ; do
3404   test -d ${dir} || mkdir ${dir}
3405 done
3406
3407 # Build src/Makefile from ${srcdir}/src/Makefile.c
3408 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3409 # This must be done after src/config.h is built, since we rely on that file.
3410
3411 echo creating src/epaths.h
3412 ${MAKE-make} epaths-force
3413
3414 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3415 # `..' to `. .'  unless invoked with -traditional
3416
3417 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3418   CPPFLAGS="$CPPFLAGS -traditional"
3419 fi
3420
3421 echo creating lib-src/Makefile
3422 ( cd lib-src
3423   rm -f junk.c junk1.c junk2.c
3424   sed -e '/start of cpp stuff/q' \
3425       < Makefile.c > junk1.c
3426   sed -e '1,/start of cpp stuff/d'\
3427       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3428       < Makefile.c > junk.c
3429   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3430       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3431   cat junk1.c junk2.c > Makefile.new
3432   rm -f junk.c junk1.c junk2.c
3433   chmod 444 Makefile.new
3434   mv -f Makefile.new Makefile
3435 )
3436
3437 echo creating src/Makefile
3438 ( cd src
3439   rm -f junk.c junk1.c junk2.c
3440   sed -e '/start of cpp stuff/q' \
3441       < Makefile.c > junk1.c
3442   sed -e '1,/start of cpp stuff/d'\
3443       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3444       < Makefile.c > junk.c
3445   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3446       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3447   cat junk1.c junk2.c > Makefile.new
3448   rm -f junk.c junk1.c junk2.c
3449   chmod 444 Makefile.new
3450   mv -f Makefile.new Makefile
3451 )
3452
3453 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3454   echo creating src/.gdbinit
3455   echo source $srcdir/src/.gdbinit > src/.gdbinit
3456 fi
3457
3458 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3459
3460 m4_if(dnl       Do not change this comment
3461    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3462 )dnl