lisp/cmuscheme.el

   1 ;;; cmuscheme.el --- Scheme process in a buffer. Adapted from tea.el.
   2
   3 ;; Copyright (C) 1988, 1994, 1997 Free Software Foundation, Inc.
   4
   5 ;; Author: Olin Shivers <olin.shivers@cs.cmu.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: processes, lisp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;    This is a customisation of comint-mode (see comint.el)
  29 ;;
  30 ;; Written by Olin Shivers (olin.shivers@cs.cmu.edu). With bits and pieces
  31 ;; lifted from scheme.el, shell.el, clisp.el, newclisp.el, cobol.el, et al..
  32 ;; 8/88
  33 ;;
  34 ;; Please send me bug reports, bug fixes, and extensions, so that I can
  35 ;; merge them into the master source.
  36 ;;
  37 ;; The changelog is at the end of this file.
  38 ;;
  39 ;; NOTE: MIT Cscheme, when invoked with the -emacs flag, has a special user
  40 ;; interface that communicates process state back to the superior emacs by
  41 ;; outputting special control sequences. The gnumacs package, xscheme.el, has
  42 ;; lots and lots of special purpose code to read these control sequences, and
  43 ;; so is very tightly integrated with the cscheme process. The cscheme
  44 ;; interrupt handler and debugger read single character commands in cbreak
  45 ;; mode; when this happens, xscheme.el switches to special keymaps that bind
  46 ;; the single letter command keys to emacs functions that directly send the
  47 ;; character to the scheme process.  Cmuscheme mode does *not* provide this
  48 ;; functionality. If you are a cscheme user, you may prefer to use the
  49 ;; xscheme.el/cscheme -emacs interaction.
  50 ;;
  51 ;; Here's a summary of the pros and cons, as I see them.
  52 ;; xscheme: Tightly integrated with inferior cscheme process!  A few commands
  53 ;;           not in cmuscheme. But. Integration is a bit of a hack.  Input
  54 ;;           history only keeps the immediately prior input. Bizarre
  55 ;;           keybindings.
  56 ;;
  57 ;; cmuscheme: Not tightly integrated with inferior cscheme process.  But.
  58 ;;            Carefully integrated functionality with the entire suite of
  59 ;;            comint-derived CMU process modes. Keybindings reminiscent of
  60 ;;            Zwei and Hemlock. Good input history. A few commands not in
  61 ;;            xscheme.
  62 ;;
  63 ;; It's a tradeoff. Pay your money; take your choice. If you use a Scheme
  64 ;; that isn't Cscheme, of course, there isn't a choice. Xscheme.el is *very*
  65 ;; Cscheme-specific; you must use cmuscheme.el.  Interested parties are
  66 ;; invited to port xscheme functionality on top of comint mode...
  67
  68 ;;; CHANGE LOG
  69 ;;; ===========================================================================
  70 ;;; 8/88 Olin
  71 ;;; Created.
  72 ;;;
  73 ;;; 2/15/89 Olin
  74 ;;; Removed -emacs flag from process invocation. It's only useful for
  75 ;;; cscheme, and makes cscheme assume it's running under xscheme.el,
  76 ;;; which messes things up royally. A bug.
  77 ;;;
  78 ;;; 5/22/90 Olin
  79 ;;; - Upgraded to use comint-send-string and comint-send-region.
  80 ;;; - run-scheme now offers to let you edit the command line if
  81 ;;;   you invoke it with a prefix-arg. M-x scheme is redundant, and
  82 ;;;   has been removed.
  83 ;;; - Explicit references to process "scheme" have been replaced with
  84 ;;;   (scheme-proc). This allows better handling of multiple process bufs.
  85 ;;; - Added scheme-send-last-sexp, bound to C-x C-e. A gnu convention.
  86 ;;; - Have not added process query facility a la cmulisp.el's lisp-show-arglist
  87 ;;;   and friends, but interested hackers might find a useful application
  88 ;;;   of this facility.
  89 ;;;
  90 ;;; 3/12/90 Olin
  91 ;;; - scheme-load-file and scheme-compile-file no longer switch-to-scheme.
  92 ;;;   Tale suggested this.
  93
  94 ;;; Code:
  95
  96 (require 'scheme)
  97 (require 'comint)
  98
  99
 100 (defgroup cmuscheme nil
 101   "Run a scheme process in a buffer."
 102   :group 'lisp)
 103
 104 ;;; INFERIOR SCHEME MODE STUFF
 105 ;;;============================================================================
 106
 107 (defcustom inferior-scheme-mode-hook nil
 108   "*Hook for customising inferior-scheme mode."
 109   :type 'hook
 110   :group 'cmuscheme)
 111
 112 (defvar inferior-scheme-mode-map nil)
 113
 114 (cond ((not inferior-scheme-mode-map)
 115        (setq inferior-scheme-mode-map
 116              (copy-keymap comint-mode-map))
 117        (define-key inferior-scheme-mode-map "\M-\C-x" ;gnu convention
 118                    'scheme-send-definition)
 119        (define-key inferior-scheme-mode-map "\C-x\C-e" 'scheme-send-last-sexp)
 120        (define-key inferior-scheme-mode-map "\C-c\C-l" 'scheme-load-file)
 121        (define-key inferior-scheme-mode-map "\C-c\C-k" 'scheme-compile-file)
 122        (scheme-mode-commands inferior-scheme-mode-map)))
 123
 124 ;; Install the process communication commands in the scheme-mode keymap.
 125 (define-key scheme-mode-map "\M-\C-x" 'scheme-send-definition);gnu convention
 126 (define-key scheme-mode-map "\C-x\C-e" 'scheme-send-last-sexp);gnu convention
 127 (define-key scheme-mode-map "\C-c\C-e" 'scheme-send-definition)
 128 (define-key scheme-mode-map "\C-c\M-e" 'scheme-send-definition-and-go)
 129 (define-key scheme-mode-map "\C-c\C-r" 'scheme-send-region)
 130 (define-key scheme-mode-map "\C-c\M-r" 'scheme-send-region-and-go)
 131 (define-key scheme-mode-map "\C-c\M-c" 'scheme-compile-definition)
 132 (define-key scheme-mode-map "\C-c\C-c" 'scheme-compile-definition-and-go)
 133 (define-key scheme-mode-map "\C-c\C-z" 'switch-to-scheme)
 134 (define-key scheme-mode-map "\C-c\C-l" 'scheme-load-file)
 135 (define-key scheme-mode-map "\C-c\C-k" 'scheme-compile-file) ;k for "kompile"
 136
 137 (let ((map (lookup-key scheme-mode-map [menu-bar scheme])))
 138   (define-key map [separator-eval] '("--"))
 139   (define-key map [compile-file]
 140     '("Compile Scheme File" . scheme-compile-file))
 141   (define-key map [load-file]
 142     '("Load Scheme File" . scheme-load-file))
 143   (define-key map [switch]
 144     '("Switch to Scheme" . switch-to-scheme))
 145   (define-key map [com-def-go]
 146     '("Compile Definitiion & Go" . scheme-compile-definition-and-go))
 147   (define-key map [com-def]
 148     '("Compile Definitiion" . scheme-compile-definition))
 149   (define-key map [send-def-go]
 150     '("Evaluate Last Definition & Go" . scheme-send-definition-and-go))
 151   (define-key map [send-def]
 152     '("Evaluate Last Definition" . scheme-send-definition))
 153   (define-key map [send-region-go]
 154     '("Evaluate Region & Go" . scheme-send-region-and-go))
 155   (define-key map [send-region]
 156     '("Evaluate Region" . scheme-send-region))
 157   (define-key map [send-sexp]
 158     '("Evaluate Last S-expression" . scheme-send-last-sexp))
 159 )
 160
 161 (defvar scheme-buffer)
 162
 163 (defun inferior-scheme-mode ()
 164   "Major mode for interacting with an inferior Scheme process.
 165
 166 The following commands are available:
 167 \\{inferior-scheme-mode-map}
 168
 169 A Scheme process can be fired up with M-x run-scheme.
 170
 171 Customisation: Entry to this mode runs the hooks on comint-mode-hook and
 172 inferior-scheme-mode-hook (in that order).
 173
 174 You can send text to the inferior Scheme process from other buffers containing
 175 Scheme source.
 176     switch-to-scheme switches the current buffer to the Scheme process buffer.
 177     scheme-send-definition sends the current definition to the Scheme process.
 178     scheme-compile-definition compiles the current definition.
 179     scheme-send-region sends the current region to the Scheme process.
 180     scheme-compile-region compiles the current region.
 181
 182     scheme-send-definition-and-go, scheme-compile-definition-and-go,
 183         scheme-send-region-and-go, and scheme-compile-region-and-go
 184         switch to the Scheme process buffer after sending their text.
 185 For information on running multiple processes in multiple buffers, see
 186 documentation for variable scheme-buffer.
 187
 188 Commands:
 189 Return after the end of the process' output sends the text from the
 190     end of process to point.
 191 Return before the end of the process' output copies the sexp ending at point
 192     to the end of the process' output, and sends it.
 193 Delete converts tabs to spaces as it moves back.
 194 Tab indents for Scheme; with argument, shifts rest
 195     of expression rigidly with the current line.
 196 C-M-q does Tab on each line starting within following expression.
 197 Paragraphs are separated only by blank lines.  Semicolons start comments.
 198 If you accidentally suspend your process, use \\[comint-continue-subjob]
 199 to continue it."
 200   (interactive)
 201   (comint-mode)
 202   ;; Customise in inferior-scheme-mode-hook
 203   (setq comint-prompt-regexp "^[^>\n]*>+ *") ; OK for cscheme, oaklisp, T,...
 204   (scheme-mode-variables)
 205   (setq major-mode 'inferior-scheme-mode)
 206   (setq mode-name "Inferior Scheme")
 207   (setq mode-line-process '(":%s"))
 208   (use-local-map inferior-scheme-mode-map)
 209   (setq comint-input-filter (function scheme-input-filter))
 210   (setq comint-get-old-input (function scheme-get-old-input))
 211   (run-hooks 'inferior-scheme-mode-hook))
 212
 213 (defcustom inferior-scheme-filter-regexp "\\`\\s *\\S ?\\S ?\\s *\\'"
 214   "*Input matching this regexp are not saved on the history list.
 215 Defaults to a regexp ignoring all inputs of 0, 1, or 2 letters."
 216   :type 'regexp
 217   :group 'cmuscheme)
 218
 219 (defun scheme-input-filter (str)
 220   "Don't save anything matching inferior-scheme-filter-regexp"
 221   (not (string-match inferior-scheme-filter-regexp str)))
 222
 223 (defun scheme-get-old-input ()
 224   "Snarf the sexp ending at point"
 225   (save-excursion
 226     (let ((end (point)))
 227       (backward-sexp)
 228       (buffer-substring (point) end))))
 229
 230 (defun scheme-args-to-list (string)
 231   (let ((where (string-match "[ \t]" string)))
 232     (cond ((null where) (list string))
 233           ((not (= where 0))
 234            (cons (substring string 0 where)
 235                  (scheme-args-to-list (substring string (+ 1 where)
 236                                                  (length string)))))
 237           (t (let ((pos (string-match "[^ \t]" string)))
 238                (if (null pos)
 239                    nil
 240                  (scheme-args-to-list (substring string pos
 241                                                  (length string)))))))))
 242
 243 (defcustom scheme-program-name "scheme"
 244   "*Program invoked by the run-scheme command"
 245   :type 'string
 246   :group 'cmuscheme)
 247
 248 ;;;###autoload
 249 (defun run-scheme (cmd)
 250   "Run an inferior Scheme process, input and output via buffer *scheme*.
 251 If there is a process already running in `*scheme*', switch to that buffer.
 252 With argument, allows you to edit the command line (default is value
 253 of `scheme-program-name').  Runs the hooks `inferior-scheme-mode-hook'
 254 \(after the `comint-mode-hook' is run).
 255 \(Type \\[describe-mode] in the process buffer for a list of commands.)"
 256
 257   (interactive (list (if current-prefix-arg
 258                          (read-string "Run Scheme: " scheme-program-name)
 259                          scheme-program-name)))
 260   (if (not (comint-check-proc "*scheme*"))
 261       (let ((cmdlist (scheme-args-to-list cmd)))
 262         (set-buffer (apply 'make-comint "scheme" (car cmdlist)
 263                            nil (cdr cmdlist)))
 264         (inferior-scheme-mode)))
 265   (setq scheme-program-name cmd)
 266   (setq scheme-buffer "*scheme*")
 267   (pop-to-buffer "*scheme*"))
 268 ;;;###autoload (add-hook 'same-window-buffer-names "*scheme*")
 269
 270 (defun scheme-send-region (start end)
 271   "Send the current region to the inferior Scheme process."
 272   (interactive "r")
 273   (comint-send-region (scheme-proc) start end)
 274   (comint-send-string (scheme-proc) "\n"))
 275
 276 (defun scheme-send-definition ()
 277   "Send the current definition to the inferior Scheme process."
 278   (interactive)
 279   (save-excursion
 280    (end-of-defun)
 281    (let ((end (point)))
 282      (beginning-of-defun)
 283      (scheme-send-region (point) end))))
 284
 285 (defun scheme-send-last-sexp ()
 286   "Send the previous sexp to the inferior Scheme process."
 287   (interactive)
 288   (scheme-send-region (save-excursion (backward-sexp) (point)) (point)))
 289
 290 (defcustom scheme-compile-exp-command "(compile '%s)"
 291   "*Template for issuing commands to compile arbitrary Scheme expressions."
 292   :type 'string
 293   :group 'cmuscheme)
 294
 295 (defun scheme-compile-region (start end)
 296   "Compile the current region in the inferior Scheme process.
 297 \(A BEGIN is wrapped around the region: (BEGIN <region>))"
 298   (interactive "r")
 299   (comint-send-string (scheme-proc) (format scheme-compile-exp-command
 300                                             (format "(begin %s)"
 301                                                     (buffer-substring start end))))
 302   (comint-send-string (scheme-proc) "\n"))
 303
 304 (defun scheme-compile-definition ()
 305   "Compile the current definition in the inferior Scheme process."
 306   (interactive)
 307   (save-excursion
 308    (end-of-defun)
 309    (let ((end (point)))
 310      (beginning-of-defun)
 311      (scheme-compile-region (point) end))))
 312
 313 (defun switch-to-scheme (eob-p)
 314   "Switch to the scheme process buffer.
 315 With argument, positions cursor at end of buffer."
 316   (interactive "P")
 317   (if (get-buffer scheme-buffer)
 318       (pop-to-buffer scheme-buffer)
 319       (error "No current process buffer. See variable scheme-buffer."))
 320   (cond (eob-p
 321          (push-mark)
 322          (goto-char (point-max)))))
 323
 324 (defun scheme-send-region-and-go (start end)
 325   "Send the current region to the inferior Scheme process.
 326 Then switch to the process buffer."
 327   (interactive "r")
 328   (scheme-send-region start end)
 329   (switch-to-scheme t))
 330
 331 (defun scheme-send-definition-and-go ()
 332   "Send the current definition to the inferior Scheme.
 333 Then switch to the process buffer."
 334   (interactive)
 335   (scheme-send-definition)
 336   (switch-to-scheme t))
 337
 338 (defun scheme-compile-definition-and-go ()
 339   "Compile the current definition in the inferior Scheme.
 340 Then switch to the process buffer."
 341   (interactive)
 342   (scheme-compile-definition)
 343   (switch-to-scheme t))
 344
 345 (defun scheme-compile-region-and-go (start end)
 346   "Compile the current region in the inferior Scheme.
 347 Then switch to the process buffer."
 348   (interactive "r")
 349   (scheme-compile-region start end)
 350   (switch-to-scheme t))
 351
 352 (defcustom scheme-source-modes '(scheme-mode)
 353   "*Used to determine if a buffer contains Scheme source code.
 354 If it's loaded into a buffer that is in one of these major modes, it's
 355 considered a scheme source file by scheme-load-file and scheme-compile-file.
 356 Used by these commands to determine defaults."
 357   :type '(repeat function)
 358   :group 'cmuscheme)
 359
 360 (defvar scheme-prev-l/c-dir/file nil
 361   "Caches the last (directory . file) pair.
 362 Caches the last pair used in the last scheme-load-file or
 363 scheme-compile-file command. Used for determining the default in the
 364 next one.")
 365
 366 (defun scheme-load-file (file-name)
 367   "Load a Scheme file into the inferior Scheme process."
 368   (interactive (comint-get-source "Load Scheme file: " scheme-prev-l/c-dir/file
 369                                   scheme-source-modes t)) ; T because LOAD
 370                                                           ; needs an exact name
 371   (comint-check-source file-name) ; Check to see if buffer needs saved.
 372   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 373                                        (file-name-nondirectory file-name)))
 374   (comint-send-string (scheme-proc) (concat "(load \""
 375                                             file-name
 376                                             "\"\)\n")))
 377
 378 (defun scheme-compile-file (file-name)
 379   "Compile a Scheme file in the inferior Scheme process."
 380   (interactive (comint-get-source "Compile Scheme file: "
 381                                   scheme-prev-l/c-dir/file
 382                                   scheme-source-modes
 383                                   nil)) ; NIL because COMPILE doesn't
 384                                         ; need an exact name.
 385   (comint-check-source file-name) ; Check to see if buffer needs saved.
 386   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 387                                        (file-name-nondirectory file-name)))
 388   (comint-send-string (scheme-proc) (concat "(compile-file \""
 389                                             file-name
 390                                             "\"\)\n")))
 391
 392 \f
 393 (defvar scheme-buffer nil "*The current scheme process buffer.
 394
 395 MULTIPLE PROCESS SUPPORT
 396 ===========================================================================
 397 Cmuscheme.el supports, in a fairly simple fashion, running multiple Scheme
 398 processes. To run multiple Scheme processes, you start the first up with
 399 \\[run-scheme]. It will be in a buffer named *scheme*. Rename this buffer
 400 with \\[rename-buffer]. You may now start up a new process with another
 401 \\[run-scheme]. It will be in a new buffer, named *scheme*. You can
 402 switch between the different process buffers with \\[switch-to-buffer].
 403
 404 Commands that send text from source buffers to Scheme processes --
 405 like scheme-send-definition or scheme-compile-region -- have to choose a
 406 process to send to, when you have more than one Scheme process around. This
 407 is determined by the global variable scheme-buffer. Suppose you
 408 have three inferior Schemes running:
 409     Buffer      Process
 410     foo         scheme
 411     bar         scheme<2>
 412     *scheme*    scheme<3>
 413 If you do a \\[scheme-send-definition-and-go] command on some Scheme source
 414 code, what process do you send it to?
 415
 416 - If you're in a process buffer (foo, bar, or *scheme*),
 417   you send it to that process.
 418 - If you're in some other buffer (e.g., a source file), you
 419   send it to the process attached to buffer scheme-buffer.
 420 This process selection is performed by function scheme-proc.
 421
 422 Whenever \\[run-scheme] fires up a new process, it resets scheme-buffer
 423 to be the new process's buffer. If you only run one process, this will
 424 do the right thing. If you run multiple processes, you can change
 425 scheme-buffer to another process buffer with \\[set-variable].
 426
 427 More sophisticated approaches are, of course, possible. If you find yourself
 428 needing to switch back and forth between multiple processes frequently,
 429 you may wish to consider ilisp.el, a larger, more sophisticated package
 430 for running inferior Lisp and Scheme processes. The approach taken here is
 431 for a minimal, simple implementation. Feel free to extend it.")
 432
 433 (defun scheme-proc ()
 434   "Returns the current scheme process. See variable scheme-buffer."
 435   (let ((proc (get-buffer-process (if (eq major-mode 'inferior-scheme-mode)
 436                                       (current-buffer)
 437                                       scheme-buffer))))
 438     (or proc
 439         (error "No current process. See variable scheme-buffer"))))
 440
 441
 442 ;;; Do the user's customisation...
 443
 444 (defcustom cmuscheme-load-hook nil
 445   "This hook is run when cmuscheme is loaded in.
 446 This is a good place to put keybindings."
 447   :type 'hook
 448   :group 'cmuscheme)
 449
 450 (run-hooks 'cmuscheme-load-hook)
 451
 452 (provide 'cmuscheme)
 453
 454 ;;; cmuscheme.el ends here