lisp/vc/vc-hg.el

   1 ;;; vc-hg.el --- VC backend for the mercurial version control system  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2006-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Ivan Kanis
   6 ;; Maintainer: FSF
   7 ;; Keywords: vc tools
   8 ;; Package: vc
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This is a mercurial version control backend
  28
  29 ;;; Thanks:
  30
  31 ;;; Bugs:
  32
  33 ;;; Installation:
  34
  35 ;;; Todo:
  36
  37 ;; 1) Implement the rest of the vc interface. See the comment at the
  38 ;; beginning of vc.el. The current status is:
  39
  40 ;; FUNCTION NAME                               STATUS
  41 ;; BACKEND PROPERTIES
  42 ;; * revision-granularity                      OK
  43 ;; STATE-QUERYING FUNCTIONS
  44 ;; * registered (file)                         OK
  45 ;; * state (file)                              OK
  46 ;; - state-heuristic (file)                    NOT NEEDED
  47 ;; - dir-status (dir update-function)          OK
  48 ;; - dir-status-files (dir files ds uf)        OK
  49 ;; - dir-extra-headers (dir)                   OK
  50 ;; - dir-printer (fileinfo)                    OK
  51 ;; * working-revision (file)                   OK
  52 ;; - latest-on-branch-p (file)                 ??
  53 ;; * checkout-model (files)                    OK
  54 ;; - workfile-unchanged-p (file)               OK
  55 ;; - mode-line-string (file)                   NOT NEEDED
  56 ;; STATE-CHANGING FUNCTIONS
  57 ;; * register (files &optional rev comment)    OK
  58 ;; * create-repo ()                            OK
  59 ;; - init-revision ()                          NOT NEEDED
  60 ;; - responsible-p (file)                      OK
  61 ;; - could-register (file)                     OK
  62 ;; - receive-file (file rev)                   ?? PROBABLY NOT NEEDED
  63 ;; - unregister (file)                         COMMENTED OUT, MAY BE INCORRECT
  64 ;; * checkin (files rev comment)               OK
  65 ;; * find-revision (file rev buffer)           OK
  66 ;; * checkout (file &optional editable rev)    OK
  67 ;; * revert (file &optional contents-done)     OK
  68 ;; - rollback (files)                          ?? PROBABLY NOT NEEDED
  69 ;; - merge (file rev1 rev2)                    NEEDED
  70 ;; - merge-news (file)                         NEEDED
  71 ;; - steal-lock (file &optional revision)      NOT NEEDED
  72 ;; HISTORY FUNCTIONS
  73 ;; * print-log (files buffer &optional shortlog start-revision limit) OK
  74 ;; - log-view-mode ()                          OK
  75 ;; - show-log-entry (revision)                 NOT NEEDED, DEFAULT IS GOOD
  76 ;; - comment-history (file)                    NOT NEEDED
  77 ;; - update-changelog (files)                  NOT NEEDED
  78 ;; * diff (files &optional rev1 rev2 buffer)   OK
  79 ;; - revision-completion-table (files)         OK?
  80 ;; - annotate-command (file buf &optional rev) OK
  81 ;; - annotate-time ()                          OK
  82 ;; - annotate-current-time ()                  NOT NEEDED
  83 ;; - annotate-extract-revision-at-line ()      OK
  84 ;; TAG SYSTEM
  85 ;; - create-tag (dir name branchp)             NEEDED
  86 ;; - retrieve-tag (dir name update)            NEEDED
  87 ;; MISCELLANEOUS
  88 ;; - make-version-backups-p (file)             ??
  89 ;; - repository-hostname (dirname)             ??
  90 ;; - previous-revision (file rev)              OK
  91 ;; - next-revision (file rev)                  OK
  92 ;; - check-headers ()                          ??
  93 ;; - clear-headers ()                          ??
  94 ;; - delete-file (file)                        TEST IT
  95 ;; - rename-file (old new)                     OK
  96 ;; - find-file-hook ()                         added for bug#10709
  97
  98 ;; 2) Implement Stefan Monnier's advice:
  99 ;; vc-hg-registered and vc-hg-state
 100 ;; Both of those functions should be super extra careful to fail gracefully in
 101 ;; unexpected circumstances. The reason this is important is that any error
 102 ;; there will prevent the user from even looking at the file :-(
 103 ;; Ideally, just like in vc-arch and vc-cvs, checking that the file is under
 104 ;; mercurial's control and extracting the current revision should be done
 105 ;; without even using `hg' (this way even if you don't have `hg' installed,
 106 ;; Emacs is able to tell you this file is under mercurial's control).
 107
 108 ;;; History:
 109 ;;
 110
 111 ;;; Code:
 112
 113 (eval-when-compile
 114   (require 'cl-lib)
 115   (require 'vc)
 116   (require 'vc-dir))
 117
 118 ;;; Customization options
 119
 120 (defgroup vc-hg nil
 121   "VC Mercurial (hg) backend."
 122   :version "24.1"
 123   :group 'vc)
 124
 125 (defcustom vc-hg-global-switches nil
 126   "Global switches to pass to any Hg command."
 127   :type '(choice (const :tag "None" nil)
 128          (string :tag "Argument String")
 129          (repeat :tag "Argument List" :value ("") string))
 130   :version "22.2"
 131   :group 'vc-hg)
 132
 133 (defcustom vc-hg-diff-switches t ; Hg doesn't support common args like -u
 134   "String or list of strings specifying switches for Hg diff under VC.
 135 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
 136   :type '(choice (const :tag "Unspecified" nil)
 137                  (const :tag "None" t)
 138                  (string :tag "Argument String")
 139                  (repeat :tag "Argument List" :value ("") string))
 140   :version "23.1"
 141   :group 'vc-hg)
 142
 143 (defcustom vc-hg-program "hg"
 144   "Name of the Mercurial executable (excluding any arguments)."
 145   :type 'string
 146   :group 'vc-hg)
 147
 148 (defcustom vc-hg-root-log-format
 149   '("{rev}:{tags}: {author|person} {date|shortdate} {desc|firstline}\\n"
 150     "^\\([0-9]+\\):\\([^:]*\\): \\(.*?\\)[ \t]+\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}\\)"
 151     ((1 'log-view-message-face)
 152      (2 'change-log-list)
 153      (3 'change-log-name)
 154      (4 'change-log-date)))
 155   "Mercurial log template for `vc-hg-print-log' short format.
 156 This should be a list (TEMPLATE REGEXP KEYWORDS), where TEMPLATE
 157 is the \"--template\" argument string to pass to Mercurial,
 158 REGEXP is a regular expression matching the resulting Mercurial
 159 output, and KEYWORDS is a list of `font-lock-keywords' for
 160 highlighting the Log View buffer."
 161   :type '(list string string (repeat sexp))
 162   :group 'vc-hg
 163   :version "24.1")
 164
 165 \f
 166 ;;; Properties of the backend
 167
 168 (defvar vc-hg-history nil)
 169
 170 (defun vc-hg-revision-granularity () 'repository)
 171 (defun vc-hg-checkout-model (_files) 'implicit)
 172
 173 ;;; State querying functions
 174
 175 ;;;###autoload (defun vc-hg-registered (file)
 176 ;;;###autoload   "Return non-nil if FILE is registered with hg."
 177 ;;;###autoload   (if (vc-find-root file ".hg")       ; short cut
 178 ;;;###autoload       (progn
 179 ;;;###autoload         (load "vc-hg" nil t)
 180 ;;;###autoload         (vc-hg-registered file))))
 181
 182 ;; Modeled after the similar function in vc-bzr.el
 183 (defun vc-hg-registered (file)
 184   "Return non-nil if FILE is registered with hg."
 185   (when (vc-hg-root file)           ; short cut
 186     (let ((state (vc-hg-state file)))  ; expensive
 187       (and state (not (memq state '(ignored unregistered)))))))
 188
 189 (defun vc-hg-state (file)
 190   "Hg-specific version of `vc-state'."
 191   (let*
 192       ((status nil)
 193        (default-directory (file-name-directory file))
 194        (out
 195         (with-output-to-string
 196           (with-current-buffer
 197               standard-output
 198             (setq status
 199                   (condition-case nil
 200                       ;; Ignore all errors.
 201                       (let ((process-environment
 202                              ;; Avoid localization of messages so we
 203                              ;; can parse the output.
 204                              (append (list "TERM=dumb" "LANGUAGE=C")
 205                                      process-environment)))
 206                         (process-file
 207                          vc-hg-program nil t nil
 208                          "--config" "alias.status=status"
 209                          "--config" "defaults.status="
 210                          "status" "-A" (file-relative-name file)))
 211                     ;; Some problem happened.  E.g. We can't find an `hg'
 212                     ;; executable.
 213                     (error nil)))))))
 214     (when (eq 0 status)
 215         (when (null (string-match ".*: No such file or directory$" out))
 216           (let ((state (aref out 0)))
 217             (cond
 218              ((eq state ?=) 'up-to-date)
 219              ((eq state ?A) 'added)
 220              ((eq state ?M) 'edited)
 221              ((eq state ?I) 'ignored)
 222              ((eq state ?R) 'removed)
 223              ((eq state ?!) 'missing)
 224              ((eq state ??) 'unregistered)
 225              ((eq state ?C) 'up-to-date) ;; Older mercurial versions use this.
 226              (t 'up-to-date)))))))
 227
 228 (defun vc-hg-working-revision (file)
 229   "Hg-specific version of `vc-working-revision'."
 230   (let ((default-directory (if (file-directory-p file)
 231                                (file-name-as-directory file)
 232                              (file-name-directory file))))
 233     (ignore-errors
 234       (with-output-to-string
 235         (process-file vc-hg-program nil standard-output nil
 236                       "log" "-l" "1" "--template" "{rev}"
 237                       (file-relative-name file))))))
 238
 239 ;;; History functions
 240
 241 (defcustom vc-hg-log-switches nil
 242   "String or list of strings specifying switches for hg log under VC."
 243   :type '(choice (const :tag "None" nil)
 244                  (string :tag "Argument String")
 245                  (repeat :tag "Argument List" :value ("") string))
 246   :group 'vc-hg)
 247
 248 (defun vc-hg-print-log (files buffer &optional shortlog start-revision limit)
 249   "Print commit log associated with FILES into specified BUFFER.
 250 If SHORTLOG is non-nil, use a short format based on `vc-hg-root-log-format'.
 251 If START-REVISION is non-nil, it is the newest revision to show.
 252 If LIMIT is non-nil, show no more than this many entries."
 253   ;; `vc-do-command' creates the buffer, but we need it before running
 254   ;; the command.
 255   (vc-setup-buffer buffer)
 256   ;; If the buffer exists from a previous invocation it might be
 257   ;; read-only.
 258   (let ((inhibit-read-only t))
 259     (with-current-buffer
 260         buffer
 261       (apply 'vc-hg-command buffer 0 files "log"
 262              (nconc
 263               (when start-revision (list (format "-r%s:0" start-revision)))
 264               (when limit (list "-l" (format "%s" limit)))
 265               (when shortlog (list "--template" (car vc-hg-root-log-format)))
 266               vc-hg-log-switches)))))
 267
 268 (defvar log-view-message-re)
 269 (defvar log-view-file-re)
 270 (defvar log-view-font-lock-keywords)
 271 (defvar log-view-per-file-logs)
 272 (defvar log-view-expanded-log-entry-function)
 273
 274 (define-derived-mode vc-hg-log-view-mode log-view-mode "Hg-Log-View"
 275   (require 'add-log) ;; we need the add-log faces
 276   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 277   (set (make-local-variable 'log-view-per-file-logs) nil)
 278   (set (make-local-variable 'log-view-message-re)
 279        (if (eq vc-log-view-type 'short)
 280            (cadr vc-hg-root-log-format)
 281          "^changeset:[ \t]*\\([0-9]+\\):\\(.+\\)"))
 282   ;; Allow expanding short log entries
 283   (when (eq vc-log-view-type 'short)
 284     (setq truncate-lines t)
 285     (set (make-local-variable 'log-view-expanded-log-entry-function)
 286          'vc-hg-expanded-log-entry))
 287   (set (make-local-variable 'log-view-font-lock-keywords)
 288        (if (eq vc-log-view-type 'short)
 289            (list (cons (nth 1 vc-hg-root-log-format)
 290                        (nth 2 vc-hg-root-log-format)))
 291          (append
 292           log-view-font-lock-keywords
 293           '(
 294             ;; Handle the case:
 295             ;; user: FirstName LastName <foo@bar>
 296             ("^user:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 297              (1 'change-log-name)
 298              (2 'change-log-email))
 299             ;; Handle the cases:
 300             ;; user: foo@bar
 301             ;; and
 302             ;; user: foo
 303             ("^user:[ \t]+\\([A-Za-z0-9_.+-]+\\(?:@[A-Za-z0-9_.-]+\\)?\\)"
 304              (1 'change-log-email))
 305             ("^date: \\(.+\\)" (1 'change-log-date))
 306             ("^tag: +\\([^ ]+\\)$" (1 'highlight))
 307             ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message)))))))
 308
 309 (defun vc-hg-diff (files &optional oldvers newvers buffer)
 310   "Get a difference report using hg between two revisions of FILES."
 311   (let* ((firstfile (car files))
 312          (working (and firstfile (vc-working-revision firstfile))))
 313     (when (and (equal oldvers working) (not newvers))
 314       (setq oldvers nil))
 315     (when (and (not oldvers) newvers)
 316       (setq oldvers working))
 317     (apply #'vc-hg-command (or buffer "*vc-diff*") nil files "diff"
 318            (append
 319             (vc-switches 'hg 'diff)
 320             (when oldvers
 321               (if newvers
 322                   (list "-r" oldvers "-r" newvers)
 323                 (list "-r" oldvers)))))))
 324
 325 (defun vc-hg-expanded-log-entry (revision)
 326   (with-temp-buffer
 327     (vc-hg-command t nil nil "log" "-r" revision)
 328     (goto-char (point-min))
 329     (unless (eobp)
 330       ;; Indent the expanded log entry.
 331       (indent-region (point-min) (point-max) 2)
 332       (goto-char (point-max))
 333       (buffer-string))))
 334
 335 (defun vc-hg-revision-table (files)
 336   (let ((default-directory (file-name-directory (car files))))
 337     (with-temp-buffer
 338       (vc-hg-command t nil files "log" "--template" "{rev} ")
 339       (split-string
 340        (buffer-substring-no-properties (point-min) (point-max))))))
 341
 342 ;; Modeled after the similar function in vc-cvs.el
 343 (defun vc-hg-revision-completion-table (files)
 344   (letrec ((table (lazy-completion-table
 345                    table (lambda () (vc-hg-revision-table files)))))
 346     table))
 347
 348 (defun vc-hg-annotate-command (file buffer &optional revision)
 349   "Execute \"hg annotate\" on FILE, inserting the contents in BUFFER.
 350 Optional arg REVISION is a revision to annotate from."
 351   (vc-hg-command buffer 0 file "annotate" "-d" "-n" "--follow"
 352                  (when revision (concat "-r" revision))))
 353
 354 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 355
 356 ;; The format for one line output by "hg annotate -d -n" looks like this:
 357 ;;215 Wed Jun 20 21:22:58 2007 -0700: CONTENTS
 358 ;; i.e: VERSION_NUMBER DATE: CONTENTS
 359 ;; If the user has set the "--follow" option, the output looks like:
 360 ;;215 Wed Jun 20 21:22:58 2007 -0700 foo.c: CONTENTS
 361 ;; i.e. VERSION_NUMBER DATE FILENAME: CONTENTS
 362 (defconst vc-hg-annotate-re
 363   "^[ \t]*\\([0-9]+\\) \\(.\\{30\\}\\)\\(?:\\(: \\)\\|\\(?: +\\([^:\n]+\\(?::\\(?:[^: \n][^:\n]*\\)?\\)*\\): \\)\\)")
 364
 365 (defun vc-hg-annotate-time ()
 366   (when (looking-at vc-hg-annotate-re)
 367     (goto-char (match-end 0))
 368     (vc-annotate-convert-time
 369      (date-to-time (match-string-no-properties 2)))))
 370
 371 (defun vc-hg-annotate-extract-revision-at-line ()
 372   (save-excursion
 373     (beginning-of-line)
 374     (when (looking-at vc-hg-annotate-re)
 375       (if (match-beginning 3)
 376           (match-string-no-properties 1)
 377         (cons (match-string-no-properties 1)
 378               (expand-file-name (match-string-no-properties 4)
 379                                 (vc-hg-root default-directory)))))))
 380
 381 (defun vc-hg-previous-revision (_file rev)
 382   (let ((newrev (1- (string-to-number rev))))
 383     (when (>= newrev 0)
 384       (number-to-string newrev))))
 385
 386 (defun vc-hg-next-revision (_file rev)
 387   (let ((newrev (1+ (string-to-number rev)))
 388         (tip-revision
 389          (with-temp-buffer
 390            (vc-hg-command t 0 nil "tip" "--style=default")
 391            (goto-char (point-min))
 392            (re-search-forward "^changeset:[ \t]*\\([0-9]+\\):")
 393            (string-to-number (match-string-no-properties 1)))))
 394     ;; We don't want to exceed the maximum possible revision number, ie
 395     ;; the tip revision.
 396     (when (<= newrev tip-revision)
 397       (number-to-string newrev))))
 398
 399 ;; Modeled after the similar function in vc-bzr.el
 400 (defun vc-hg-delete-file (file)
 401   "Delete FILE and delete it in the hg repository."
 402   (condition-case ()
 403       (delete-file file)
 404     (file-error nil))
 405   (vc-hg-command nil 0 file "remove" "--after" "--force"))
 406
 407 ;; Modeled after the similar function in vc-bzr.el
 408 (defun vc-hg-rename-file (old new)
 409   "Rename file from OLD to NEW using `hg mv'."
 410   (vc-hg-command nil 0 new "mv" old))
 411
 412 (defun vc-hg-register (files &optional _rev _comment)
 413   "Register FILES under hg.
 414 REV is ignored.
 415 COMMENT is ignored."
 416   (vc-hg-command nil 0 files "add"))
 417
 418 (defun vc-hg-create-repo ()
 419   "Create a new Mercurial repository."
 420   (vc-hg-command nil 0 nil "init"))
 421
 422 (defalias 'vc-hg-responsible-p 'vc-hg-root)
 423
 424 ;; Modeled after the similar function in vc-bzr.el
 425 (defun vc-hg-could-register (file)
 426   "Return non-nil if FILE could be registered under hg."
 427   (and (vc-hg-responsible-p file)      ; shortcut
 428        (condition-case ()
 429            (with-temp-buffer
 430              (vc-hg-command t nil file "add" "--dry-run"))
 431              ;; The command succeeds with no output if file is
 432              ;; registered.
 433          (error))))
 434
 435 ;; FIXME: This would remove the file. Is that correct?
 436 ;; (defun vc-hg-unregister (file)
 437 ;;   "Unregister FILE from hg."
 438 ;;   (vc-hg-command nil nil file "remove"))
 439
 440 (declare-function log-edit-extract-headers "log-edit" (headers string))
 441
 442 (defun vc-hg-checkin (files _rev comment)
 443   "Hg-specific version of `vc-backend-checkin'.
 444 REV is ignored."
 445   (apply 'vc-hg-command nil 0 files
 446          (nconc (list "commit" "-m")
 447                 (log-edit-extract-headers '(("Author" . "--user")
 448                                             ("Date" . "--date"))
 449                                           comment))))
 450
 451 (defun vc-hg-find-revision (file rev buffer)
 452   (let ((coding-system-for-read 'binary)
 453         (coding-system-for-write 'binary))
 454     (if rev
 455         (vc-hg-command buffer 0 file "cat" "-r" rev)
 456       (vc-hg-command buffer 0 file "cat"))))
 457
 458 ;; Modeled after the similar function in vc-bzr.el
 459 (defun vc-hg-checkout (file &optional _editable rev)
 460   "Retrieve a revision of FILE.
 461 EDITABLE is ignored.
 462 REV is the revision to check out into WORKFILE."
 463   (let ((coding-system-for-read 'binary)
 464         (coding-system-for-write 'binary))
 465   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 466     (if rev
 467         (vc-hg-command t 0 file "cat" "-r" rev)
 468       (vc-hg-command t 0 file "cat")))))
 469
 470 (defun vc-hg-resolve-when-done ()
 471   "Call \"hg resolve -m\" if the conflict markers have been removed."
 472   (save-excursion
 473     (goto-char (point-min))
 474     (unless (re-search-forward "^<<<<<<< " nil t)
 475       (vc-hg-command nil 0 buffer-file-name "resolve" "-m")
 476       ;; Remove the hook so that it is not called multiple times.
 477       (remove-hook 'after-save-hook 'vc-hg-resolve-when-done t))))
 478
 479 (defun vc-hg-find-file-hook ()
 480   (when (and buffer-file-name
 481              (file-exists-p (concat buffer-file-name ".orig"))
 482              ;; Hg does not seem to have a "conflict" status, eg
 483              ;; hg http://bz.selenic.com/show_bug.cgi?id=2724
 484              (memq (vc-file-getprop buffer-file-name 'vc-state)
 485                    '(edited conflict))
 486              ;; Maybe go on to check that "hg resolve -l" says "U"?
 487              ;; If "hg resolve -l" says there's a conflict but there are no
 488              ;; conflict markers, it's not clear what we should do.
 489              (save-excursion
 490                (goto-char (point-min))
 491                (re-search-forward "^<<<<<<< " nil t)))
 492     ;; Hg may not recognize "conflict" as a state, but we can do better.
 493     (vc-file-setprop buffer-file-name 'vc-state 'conflict)
 494     (smerge-start-session)
 495     (add-hook 'after-save-hook 'vc-hg-resolve-when-done nil t)
 496     (message "There are unresolved conflicts in this file")))
 497
 498
 499 ;; Modeled after the similar function in vc-bzr.el
 500 (defun vc-hg-workfile-unchanged-p (file)
 501   (eq 'up-to-date (vc-hg-state file)))
 502
 503 ;; Modeled after the similar function in vc-bzr.el
 504 (defun vc-hg-revert (file &optional contents-done)
 505   (unless contents-done
 506     (with-temp-buffer (vc-hg-command t 0 file "revert"))))
 507
 508 ;;; Hg specific functionality.
 509
 510 (defvar vc-hg-extra-menu-map
 511   (let ((map (make-sparse-keymap)))
 512     map))
 513
 514 (defun vc-hg-extra-menu () vc-hg-extra-menu-map)
 515
 516 (defun vc-hg-extra-status-menu () vc-hg-extra-menu-map)
 517
 518 (defvar log-view-vc-backend)
 519
 520 (cl-defstruct (vc-hg-extra-fileinfo
 521             (:copier nil)
 522             (:constructor vc-hg-create-extra-fileinfo (rename-state extra-name))
 523             (:conc-name vc-hg-extra-fileinfo->))
 524   rename-state        ;; rename or copy state
 525   extra-name)         ;; original name for copies and rename targets, new name for
 526
 527 (declare-function vc-default-dir-printer "vc-dir" (backend fileentry))
 528
 529 (defun vc-hg-dir-printer (info)
 530   "Pretty-printer for the vc-dir-fileinfo structure."
 531   (let ((extra (vc-dir-fileinfo->extra info)))
 532     (vc-default-dir-printer 'Hg info)
 533     (when extra
 534       (insert (propertize
 535                (format "   (%s %s)"
 536                        (pcase (vc-hg-extra-fileinfo->rename-state extra)
 537                          (`copied "copied from")
 538                          (`renamed-from "renamed from")
 539                          (`renamed-to "renamed to"))
 540                        (vc-hg-extra-fileinfo->extra-name extra))
 541                'face 'font-lock-comment-face)))))
 542
 543 (defun vc-hg-after-dir-status (update-function)
 544   (let ((file nil)
 545         (translation '((?= . up-to-date)
 546                        (?C . up-to-date)
 547                        (?A . added)
 548                        (?R . removed)
 549                        (?M . edited)
 550                        (?I . ignored)
 551                        (?! . missing)
 552                        (?  . copy-rename-line)
 553                        (?? . unregistered)))
 554         (translated nil)
 555         (result nil)
 556         (last-added nil)
 557         (last-line-copy nil))
 558       (goto-char (point-min))
 559       (while (not (eobp))
 560         (setq translated (cdr (assoc (char-after) translation)))
 561         (setq file
 562               (buffer-substring-no-properties (+ (point) 2)
 563                                               (line-end-position)))
 564         (cond ((not translated)
 565                (setq last-line-copy nil))
 566               ((eq translated 'up-to-date)
 567                (setq last-line-copy nil))
 568               ((eq translated 'copy-rename-line)
 569                ;; For copied files the output looks like this:
 570                ;; A COPIED_FILE_NAME
 571                ;;   ORIGINAL_FILE_NAME
 572                (setf (nth 2 last-added)
 573                      (vc-hg-create-extra-fileinfo 'copied file))
 574                (setq last-line-copy t))
 575               ((and last-line-copy (eq translated 'removed))
 576                ;; For renamed files the output looks like this:
 577                ;; A NEW_FILE_NAME
 578                ;;   ORIGINAL_FILE_NAME
 579                ;; R ORIGINAL_FILE_NAME
 580                ;; We need to adjust the previous entry to not think it is a copy.
 581                (setf (vc-hg-extra-fileinfo->rename-state (nth 2 last-added))
 582                      'renamed-from)
 583                (push (list file translated
 584                            (vc-hg-create-extra-fileinfo
 585                             'renamed-to (nth 0 last-added))) result)
 586                (setq last-line-copy nil))
 587               (t
 588                (setq last-added (list file translated nil))
 589                (push last-added result)
 590                (setq last-line-copy nil)))
 591         (forward-line))
 592       (funcall update-function result)))
 593
 594 (defun vc-hg-dir-status (dir update-function)
 595   (vc-hg-command (current-buffer) 'async dir "status" "-C")
 596   (vc-exec-after
 597    `(vc-hg-after-dir-status (quote ,update-function))))
 598
 599 (defun vc-hg-dir-status-files (dir files _default-state update-function)
 600   (apply 'vc-hg-command (current-buffer) 'async dir "status" "-C" files)
 601   (vc-exec-after
 602    `(vc-hg-after-dir-status (quote ,update-function))))
 603
 604 (defun vc-hg-dir-extra-header (name &rest commands)
 605   (concat (propertize name 'face 'font-lock-type-face)
 606           (propertize
 607            (with-temp-buffer
 608              (apply 'vc-hg-command (current-buffer) 0 nil commands)
 609              (buffer-substring-no-properties (point-min) (1- (point-max))))
 610            'face 'font-lock-variable-name-face)))
 611
 612 (defun vc-hg-dir-extra-headers (dir)
 613   "Generate extra status headers for a Mercurial tree."
 614   (let ((default-directory dir))
 615     (concat
 616      (vc-hg-dir-extra-header "Root       : " "root") "\n"
 617      (vc-hg-dir-extra-header "Branch     : " "id" "-b") "\n"
 618      (vc-hg-dir-extra-header "Tags       : " "id" "-t") ; "\n"
 619      ;; these change after each commit
 620      ;; (vc-hg-dir-extra-header "Local num  : " "id" "-n") "\n"
 621      ;; (vc-hg-dir-extra-header "Global id  : " "id" "-i")
 622      )))
 623
 624 (defun vc-hg-log-incoming (buffer remote-location)
 625   (vc-hg-command buffer 1 nil "incoming" "-n" (unless (string= remote-location "")
 626                                                 remote-location)))
 627
 628 (defun vc-hg-log-outgoing (buffer remote-location)
 629   (vc-hg-command buffer 1 nil "outgoing" "-n" (unless (string= remote-location "")
 630                                                 remote-location)))
 631
 632 (declare-function log-view-get-marked "log-view" ())
 633
 634 ;; XXX maybe also add key bindings for these functions.
 635 (defun vc-hg-push ()
 636   (interactive)
 637   (let ((marked-list (log-view-get-marked)))
 638     (if marked-list
 639         (apply #'vc-hg-command
 640                nil 0 nil
 641                "push"
 642                (apply 'nconc
 643                       (mapcar (lambda (arg) (list "-r" arg)) marked-list)))
 644       (error "No log entries selected for push"))))
 645
 646 (defvar vc-hg-error-regexp-alist nil
 647   ;; 'hg pull' does not list modified files, so, for now, the only
 648   ;; benefit of `vc-compilation-mode' is that one can get rid of
 649   ;; *vc-hg* buffer with 'q' or 'z'.
 650   ;; TODO: call 'hg incoming' before pull/merge to get the list of
 651   ;;       modified files
 652   "Value of `compilation-error-regexp-alist' in *vc-hg* buffers.")
 653
 654 (defun vc-hg-pull (prompt)
 655   "Issue a Mercurial pull command.
 656 If called interactively with a set of marked Log View buffers,
 657 call \"hg pull -r REVS\" to pull in the specified revisions REVS.
 658
 659 With a prefix argument or if PROMPT is non-nil, prompt for a
 660 specific Mercurial pull command.  The default is \"hg pull -u\",
 661 which fetches changesets from the default remote repository and
 662 then attempts to update the working directory."
 663   (interactive "P")
 664   (let (marked-list)
 665     ;; The `vc-hg-pull' command existed before the `pull' VC action
 666     ;; was implemented.  Keep it for backward compatibility.
 667     (if (and (called-interactively-p 'interactive)
 668              (setq marked-list (log-view-get-marked)))
 669         (apply #'vc-hg-command
 670                nil 0 nil
 671                "pull"
 672                (apply 'nconc
 673                       (mapcar (lambda (arg) (list "-r" arg))
 674                               marked-list)))
 675       (let* ((root (vc-hg-root default-directory))
 676              (buffer (format "*vc-hg : %s*" (expand-file-name root)))
 677              (command "pull")
 678              (hg-program vc-hg-program)
 679              ;; Fixme: before updating the working copy to the latest
 680              ;; state, should check if it's visiting an old revision.
 681              (args '("-u")))
 682         ;; If necessary, prompt for the exact command.
 683         (when prompt
 684           (setq args (split-string
 685                       (read-shell-command "Run Hg (like this): "
 686                                           (format "%s pull -u" hg-program)
 687                                           'vc-hg-history)
 688                       " " t))
 689           (setq hg-program (car  args)
 690                 command    (cadr args)
 691                 args       (cddr args)))
 692         (apply 'vc-do-async-command buffer root hg-program
 693                command args)
 694         (with-current-buffer buffer (vc-exec-after '(vc-compilation-mode 'hg)))
 695         (vc-set-async-update buffer)))))
 696
 697 (defun vc-hg-merge-branch ()
 698   "Merge incoming changes into the current working directory.
 699 This runs the command \"hg merge\"."
 700   (let* ((root (vc-hg-root default-directory))
 701          (buffer (format "*vc-hg : %s*" (expand-file-name root))))
 702     (apply 'vc-do-async-command buffer root vc-hg-program '("merge"))
 703     (with-current-buffer buffer (vc-exec-after '(vc-compilation-mode 'hg)))
 704     (vc-set-async-update buffer)))
 705
 706 ;;; Internal functions
 707
 708 (defun vc-hg-command (buffer okstatus file-or-list &rest flags)
 709   "A wrapper around `vc-do-command' for use in vc-hg.el.
 710 This function differs from vc-do-command in that it invokes
 711 `vc-hg-program', and passes `vc-hg-global-switches' to it before FLAGS."
 712   (apply 'vc-do-command (or buffer "*vc*") okstatus vc-hg-program file-or-list
 713          (if (stringp vc-hg-global-switches)
 714              (cons vc-hg-global-switches flags)
 715            (append vc-hg-global-switches
 716                    flags))))
 717
 718 (defun vc-hg-root (file)
 719   (vc-find-root file ".hg"))
 720
 721 (provide 'vc-hg)
 722
 723 ;;; vc-hg.el ends here