lisp/isearch.el

   1 ;;; isearch.el --- incremental search minor mode.
   2
   3 ;; Copyright (C) 1992, 1993, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Daniel LaLiberte <liberte@cs.uiuc.edu>
   6
   7 ;; |$Date: 1994/08/30 21:20:09 $|$Revision: 1.73 $
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;;====================================================================
  28 ;; Instructions
  29
  30 ;; For programmed use of isearch-mode, e.g. calling (isearch-forward),
  31 ;; isearch-mode behaves modally and does not return until the search
  32 ;; is completed.  It uses a recursive-edit to behave this way.  Note:
  33 ;; gnus does it wrong: (call-interactively 'isearch-forward).
  34
  35 ;; The key bindings active within isearch-mode are defined below in
  36 ;; `isearch-mode-map' which is given bindings close to the default
  37 ;; characters of the original isearch.el.  With `isearch-mode',
  38 ;; however, you can bind multi-character keys and it should be easier
  39 ;; to add new commands.  One bug though: keys with meta-prefix cannot
  40 ;; be longer than two chars.  Also see minibuffer-local-isearch-map
  41 ;; for bindings active during `isearch-edit-string'.
  42
  43 ;; Note to emacs version 19 users: isearch-mode should work even if
  44 ;; you switch windows with the mouse, in which case isearch-mode is
  45 ;; terminated automatically before the switch.  This is true of lemacs
  46 ;; too, with a few more cleanups I've neglected in this release.
  47 ;; No one has supplied patches for epoch yet.
  48
  49 ;; The search ring and completion commands automatically put you in
  50 ;; the minibuffer to edit the string.  This gives you a chance to
  51 ;; modify the search string before executing the search.  There are
  52 ;; three commands to terminate the editing: C-s and C-r exit the
  53 ;; minibuffer and search forward and reverse respectively, while C-m
  54 ;; exits and does a nonincremental search.
  55
  56 ;; Exiting immediately from isearch uses isearch-edit-string instead
  57 ;; of nonincremental-search, if search-nonincremental-instead is non-nil.
  58 ;; The name of this option should probably be changed if we decide to
  59 ;; keep the behavior.  No point in forcing nonincremental search until
  60 ;; the last possible moment.
  61
  62 ;; TODO
  63 ;; - Integrate the emacs 19 generalized command history.
  64 ;; - Think about incorporating query-replace.
  65 ;; - Hooks and options for failed search.
  66
  67 ;;; Change Log:
  68
  69 ;;; Changes before those recorded in ChangeLog:
  70
  71 ;;; Revision 1.4  92/09/14  16:26:02  liberte
  72 ;;; Added prefix args to isearch-forward, etc. to switch between
  73 ;;;    string and regular expression searching.
  74 ;;; Added some support for lemacs.
  75 ;;; Added general isearch-highlight option - but only for lemacs so far.
  76 ;;; Added support for frame switching in emacs 19.
  77 ;;; Added word search option to isearch-edit-string.
  78 ;;; Renamed isearch-quit to isearch-abort.
  79 ;;; Numerous changes to comments and doc strings.
  80 ;;;
  81 ;;; Revision 1.3  92/06/29  13:10:08  liberte
  82 ;;; Moved modal isearch-mode handling into isearch-mode.
  83 ;;; Got rid of buffer-local isearch variables.
  84 ;;; isearch-edit-string used by ring adjustments, completion, and
  85 ;;; nonincremental searching.  C-s and C-r are additional exit commands.
  86 ;;; Renamed all regex to regexp.
  87 ;;; Got rid of found-start and found-point globals.
  88 ;;; Generalized handling of upper-case chars.
  89
  90 ;;; Revision 1.2  92/05/27  11:33:57  liberte
  91 ;;; Emacs version 19 has a search ring, which is supported here.
  92 ;;; Other fixes found in the version 19 isearch are included here.
  93 ;;;
  94 ;;; Also see variables search-caps-disable-folding,
  95 ;;; search-nonincremental-instead, search-whitespace-regexp, and
  96 ;;; commands isearch-toggle-regexp, isearch-edit-string.
  97 ;;;
  98 ;;; semi-modal isearching is supported.
  99
 100 ;;; Changes for 1.1
 101 ;;; 3/18/92 Fixed invalid-regexp.
 102 ;;; 3/18/92 Fixed yanking in regexps.
 103
 104 ;;; Code:
 105
 106 \f
 107 ;;;=========================================================================
 108 ;;; Emacs features
 109
 110 ;; isearch-mode takes advantage of the features provided by several
 111 ;; different versions of emacs.  Rather than testing the version of
 112 ;; emacs, several constants are defined, one for each of the features.
 113 ;; Each of the tests below must work on any version of emacs.
 114 ;; (Perhaps provide and featurep could be used for this purpose.)
 115
 116 (defconst isearch-gnu-emacs-events (fboundp 'set-frame-height)) ;; emacs 19
 117 (defconst isearch-pre-command-hook-exists (boundp 'pre-command-hook)) ;; lemacs
 118 (defconst isearch-event-data-type nil)  ;; lemacs
 119
 120 (defconst search-exit-option t
 121   "*Non-nil means random control characters terminate incremental search.")
 122
 123 (defvar search-slow-window-lines 1
 124   "*Number of lines in slow search display windows.
 125 These are the short windows used during incremental search on slow terminals.
 126 Negative means put the slow search window at the top (normally it's at bottom)
 127 and the value is minus the number of lines.")
 128
 129 (defvar search-slow-speed 1200
 130   "*Highest terminal speed at which to use \"slow\" style incremental search.
 131 This is the style where a one-line window is created to show the line
 132 that the search has reached.")
 133
 134 ;;;========================================================================
 135 ;;; Some additional options and constants.
 136
 137 (defvar search-upper-case 'not-yanks
 138   "*If non-nil, upper case chars disable case fold searching.
 139 That is, upper and lower case chars must match exactly.
 140 This applies no matter where the chars come from, but does not
 141 apply to chars in regexps that are prefixed with `\\'.
 142 If this value is `not-yanks', yanked text is always downcased.")
 143
 144 (defvar search-nonincremental-instead t
 145   "*If non-nil, do a nonincremental search instead if exiting immediately.
 146 Actually, `isearch-edit-string' is called to let you enter the search
 147 string, and RET terminates editing and does a nonincremental search.")
 148
 149 (defconst search-whitespace-regexp "\\s-+"
 150   "*If non-nil, regular expression to match a sequence of whitespace chars.
 151 You might want to use something like \"[ \\t\\r\\n]+\" instead.")
 152
 153 ;; I removed the * from the doc string because highlighting is not
 154 ;; currently a clean thing to do.  Once highlighting is made clean,
 155 ;; this feature can be re-enabled and advertised.
 156 (defvar search-highlight nil
 157   "*Non-nil means incremental search highlights the current match.")
 158
 159 (defvar isearch-mode-hook nil
 160   "Function(s) to call after starting up an incremental search.")
 161
 162 (defvar isearch-mode-end-hook nil
 163   "Function(s) to call after terminating an incremental search.")
 164
 165 ;;;==================================================================
 166 ;;; Search ring.
 167
 168 (defvar search-ring nil
 169   "List of search string sequences.")
 170 (defvar regexp-search-ring nil
 171   "List of regular expression search string sequences.")
 172
 173 (defconst search-ring-max 16
 174   "*Maximum length of search ring before oldest elements are thrown away.")
 175 (defconst regexp-search-ring-max 16
 176   "*Maximum length of regexp search ring before oldest elements are thrown away.")
 177
 178 (defvar search-ring-yank-pointer nil
 179   "Index in `search-ring' of last string reused.
 180 nil if none yet.")
 181 (defvar regexp-search-ring-yank-pointer nil
 182   "Index in `regexp-search-ring' of last string reused.
 183 nil if none yet.")
 184
 185 (defvar search-ring-update nil
 186   "*Non-nil if advancing or retreating in the search ring should cause search.
 187 Default value, nil, means edit the string instead.")
 188
 189 ;;;====================================================
 190 ;;; Define isearch-mode keymap.
 191
 192 (defvar isearch-mode-map nil
 193   "Keymap for isearch-mode.")
 194
 195 (or isearch-mode-map
 196     (let* ((i 0)
 197            (map (make-keymap)))
 198       (or (vectorp (nth 1 map))
 199           (error "The initialization of isearch-mode-map must be updated"))
 200       ;; Give this map a vector 256 long, for dense binding
 201       ;; of a larger range of ordinary characters.
 202       (setcar (cdr map) (make-vector 256 nil))
 203
 204       ;; Make function keys, etc, exit the search.
 205       (define-key map [t] 'isearch-other-control-char)
 206       ;; Control chars, by default, end isearch mode transparently.
 207       ;; We need these explicit definitions because, in a dense keymap,
 208       ;; the binding for t does not affect characters.
 209       ;; We use a dense keymap to save space.
 210       (while (< i ?\ )
 211         (define-key map (make-string 1 i) 'isearch-other-control-char)
 212         (setq i (1+ i)))
 213
 214       ;; Printing chars extend the search string by default.
 215       (setq i ?\ )
 216       (while (< i (length (nth 1 map)))
 217         (define-key map (vector i) 'isearch-printing-char)
 218         (setq i (1+ i)))
 219
 220       ;; Several non-printing chars change the searching behavior.
 221       (define-key map "\C-s" 'isearch-repeat-forward)
 222       (define-key map "\C-r" 'isearch-repeat-backward)
 223       (define-key map "\177" 'isearch-delete-char)
 224       (define-key map "\C-g" 'isearch-abort)
 225
 226       (define-key map "\C-q" 'isearch-quote-char)
 227
 228       (define-key map "\r" 'isearch-exit)
 229       (define-key map "\C-j" 'isearch-printing-char)
 230       (define-key map "\t" 'isearch-printing-char)
 231       (define-key map " " 'isearch-whitespace-chars)
 232
 233       (define-key map "\C-w" 'isearch-yank-word)
 234       (define-key map "\C-y" 'isearch-yank-line)
 235
 236       ;; Bind the ASCII-equivalent "function keys" explicitly to nil
 237       ;; so that the default binding does not apply.
 238       ;; As a result, these keys translate thru function-key-map
 239       ;; as normal, and they have the effect of the equivalent ASCII char.
 240       ;; We bind [escape] below.
 241       (define-key map [tab] 'nil)
 242       (define-key map [kp-0] 'nil)
 243       (define-key map [kp-1] 'nil)
 244       (define-key map [kp-2] 'nil)
 245       (define-key map [kp-3] 'nil)
 246       (define-key map [kp-4] 'nil)
 247       (define-key map [kp-5] 'nil)
 248       (define-key map [kp-6] 'nil)
 249       (define-key map [kp-7] 'nil)
 250       (define-key map [kp-8] 'nil)
 251       (define-key map [kp-9] 'nil)
 252       (define-key map [kp-add] 'nil)
 253       (define-key map [kp-subtract] 'nil)
 254       (define-key map [kp-multiply] 'nil)
 255       (define-key map [kp-divide] 'nil)
 256       (define-key map [kp-decimal] 'nil)
 257       (define-key map [kp-separator] 'nil)
 258       (define-key map [kp-equal] 'nil)
 259       (define-key map [kp-tab] 'nil)
 260       (define-key map [kp-space] 'nil)
 261       (define-key map [kp-enter] 'nil)
 262       (define-key map [delete] 'nil)
 263       (define-key map [backspace] 'nil)
 264       (define-key map [return] 'nil)
 265       (define-key map [newline] 'nil)
 266
 267       ;; Define keys for regexp chars * ? |.
 268       ;; Nothing special for + because it matches at least once.
 269       (define-key map "*" 'isearch-*-char)
 270       (define-key map "?" 'isearch-*-char)
 271       (define-key map "|" 'isearch-|-char)
 272
 273 ;;; Turned off because I find I expect to get the global definition--rms.
 274 ;;;      ;; Instead bind C-h to special help command for isearch-mode.
 275 ;;;      (define-key map "\C-h" 'isearch-mode-help)
 276
 277       ;; To handle local bindings with meta char prefix keys, define
 278       ;; another full keymap.  This must be done for any other prefix
 279       ;; keys as well, one full keymap per char of the prefix key.  It
 280       ;; would be simpler to disable the global keymap, and/or have a
 281       ;; default local key binding for any key not otherwise bound.
 282       (let ((meta-map (make-sparse-keymap)))
 283         (define-key map (char-to-string meta-prefix-char) meta-map)
 284         (define-key map [escape] meta-map))
 285       (define-key map (vector meta-prefix-char t) 'isearch-other-meta-char)
 286
 287       (define-key map "\M-n" 'isearch-ring-advance)
 288       (define-key map "\M-p" 'isearch-ring-retreat)
 289       (define-key map "\M-y" 'isearch-yank-kill)
 290
 291       (define-key map "\M-\t" 'isearch-complete)
 292
 293       ;; For emacs 19, switching frames should terminate isearch-mode
 294       (if isearch-gnu-emacs-events
 295           (define-key map [switch-frame] 'isearch-switch-frame-handler))
 296
 297       (setq isearch-mode-map map)
 298       ))
 299
 300 ;; Some bindings you may want to put in your isearch-mode-hook.
 301 ;; Suggest some alternates...
 302 ;; (define-key isearch-mode-map "\C-t" 'isearch-toggle-case-fold)
 303 ;; (define-key isearch-mode-map "\C-t" 'isearch-toggle-regexp)
 304 ;; (define-key isearch-mode-map "\C-^" 'isearch-edit-string)
 305
 306
 307 (defvar minibuffer-local-isearch-map nil
 308   "Keymap for editing isearch strings in the minibuffer.")
 309
 310 (or minibuffer-local-isearch-map
 311     (let ((map (copy-keymap minibuffer-local-map)))
 312       (define-key map "\r" 'isearch-nonincremental-exit-minibuffer)
 313       (define-key map "\M-n" 'isearch-ring-advance-edit)
 314       (define-key map "\M-p" 'isearch-ring-retreat-edit)
 315       (define-key map "\M-\t" 'isearch-complete-edit)
 316       (define-key map "\C-s" 'isearch-forward-exit-minibuffer)
 317       (define-key map "\C-r" 'isearch-reverse-exit-minibuffer)
 318       (setq minibuffer-local-isearch-map map)
 319       ))
 320
 321 ;;;========================================================
 322 ;; Internal variables declared globally for byte-compiler.
 323 ;; These are all set with setq while isearching
 324 ;; and bound locally while editing the search string.
 325
 326 (defvar isearch-forward nil)    ; Searching in the forward direction.
 327 (defvar isearch-regexp nil)     ; Searching for a regexp.
 328 (defvar isearch-word nil)       ; Searching for words.
 329
 330 (defvar isearch-cmds nil)   ; Stack of search status sets.
 331 (defvar isearch-string "")  ; The current search string.
 332 (defvar isearch-message "") ; text-char-description version of isearch-string
 333
 334 (defvar isearch-success t)              ; Searching is currently successful.
 335 (defvar isearch-invalid-regexp nil)     ; Regexp not well formed.
 336 (defvar isearch-within-brackets nil)    ; Regexp has unclosed [.
 337 (defvar isearch-other-end nil)  ; Start (end) of match if forward (backward).
 338 (defvar isearch-wrapped nil)    ; Searching restarted from the top (bottom).
 339 (defvar isearch-barrier 0)
 340
 341 ; case-fold-search while searching.
 342 ;   either nil, t, or 'yes.  'yes means the same as t except that mixed
 343 ;   case in the search string is ignored.
 344 (defvar isearch-case-fold-search nil)
 345
 346 (defvar isearch-adjusted nil)
 347 (defvar isearch-slow-terminal-mode nil)
 348 ;;; If t, using a small window.
 349 (defvar isearch-small-window nil)
 350 (defvar isearch-opoint 0)
 351 ;;; The window configuration active at the beginning of the search.
 352 (defvar isearch-window-configuration nil)
 353
 354 ;; Flag to indicate a yank occurred, so don't move the cursor.
 355 (defvar isearch-yank-flag nil)
 356
 357 ;;; A function to be called after each input character is processed.
 358 ;;; (It is not called after characters that exit the search.)
 359 ;;; It is only set from an optional argument to `isearch-mode'.
 360 (defvar isearch-op-fun nil)
 361
 362 ;;;  Is isearch-mode in a recursive edit for modal searching.
 363 (defvar isearch-recursive-edit nil)
 364
 365 ;;; Should isearch be terminated after doing one search?
 366 (defvar isearch-nonincremental nil)
 367
 368 ;; New value of isearch-forward after isearch-edit-string.
 369 (defvar isearch-new-forward nil)
 370
 371
 372 ;;;==============================================================
 373 ;; Minor-mode-alist changes - kind of redundant with the
 374 ;; echo area, but if isearching in multiple windows, it can be useful.
 375
 376 (or (assq 'isearch-mode minor-mode-alist)
 377     (nconc minor-mode-alist
 378            (list '(isearch-mode isearch-mode))))
 379
 380 (defvar isearch-mode nil) ;; Name of the minor mode, if non-nil.
 381 (make-variable-buffer-local 'isearch-mode)
 382
 383 (define-key global-map "\C-s" 'isearch-forward)
 384 (define-key esc-map "\C-s" 'isearch-forward-regexp)
 385 (define-key global-map "\C-r" 'isearch-backward)
 386 (define-key esc-map "\C-r" 'isearch-backward-regexp)
 387
 388 ;;;===============================================================
 389 ;;; Entry points to isearch-mode.
 390 ;;; These four functions should replace those in loaddefs.el
 391 ;;; An alternative is to defalias isearch-forward etc to isearch-mode,
 392 ;;; and look at this-command to set the options accordingly.
 393
 394 (defun isearch-forward (&optional regexp-p no-recursive-edit)
 395   "\
 396 Do incremental search forward.
 397 With a prefix argument, do an incremental regular expression search instead.
 398 \\<isearch-mode-map>
 399 As you type characters, they add to the search string and are found.
 400 The following non-printing keys are bound in `isearch-mode-map'.
 401
 402 Type \\[isearch-delete-char] to cancel characters from end of search string.
 403 Type \\[isearch-exit] to exit, leaving point at location found.
 404 Type LFD (C-j) to match end of line.
 405 Type \\[isearch-repeat-forward] to search again forward,\
 406  \\[isearch-repeat-backward] to search again backward.
 407 Type \\[isearch-yank-word] to yank word from buffer onto end of search\
 408  string and search for it.
 409 Type \\[isearch-yank-line] to yank rest of line onto end of search string\
 410  and search for it.
 411 Type \\[isearch-quote-char] to quote control character to search for it.
 412 \\[isearch-abort] while searching or when search has failed cancels input\
 413  back to what has
 414  been found successfully.
 415 \\[isearch-abort] when search is successful aborts and moves point to\
 416  starting point.
 417
 418 Also supported is a search ring of the previous 16 search strings.
 419 Type \\[isearch-ring-advance] to search for the next item in the search ring.
 420 Type \\[isearch-ring-retreat] to search for the previous item in the search\
 421  ring.
 422 Type \\[isearch-complete] to complete the search string using the search ring.
 423
 424 The above keys, bound in `isearch-mode-map', are often controlled by
 425  options; do M-x apropos on search-.* to find them.
 426 Other control and meta characters terminate the search
 427  and are then executed normally (depending on `search-exit-option').
 428
 429 If this function is called non-interactively, it does not return to
 430 the calling function until the search is done."
 431
 432   (interactive "P\np")
 433   (isearch-mode t (not (null regexp-p)) nil (not no-recursive-edit)))
 434
 435 (defun isearch-forward-regexp (&optional not-regexp no-recursive-edit)
 436   "\
 437 Do incremental search forward for regular expression.
 438 With a prefix argument, do a regular string search instead.
 439 Like ordinary incremental search except that your input
 440 is treated as a regexp.  See \\[isearch-forward] for more info."
 441   (interactive "P\np")
 442   (isearch-mode t (null not-regexp) nil (not no-recursive-edit)))
 443
 444 (defun isearch-backward (&optional regexp-p no-recursive-edit)
 445   "\
 446 Do incremental search backward.
 447 With a prefix argument, do a regular expression search instead.
 448 See \\[isearch-forward] for more information."
 449   (interactive "P\np")
 450   (isearch-mode nil (not (null regexp-p)) nil (not no-recursive-edit)))
 451
 452 (defun isearch-backward-regexp (&optional not-regexp no-recursive-edit)
 453   "\
 454 Do incremental search backward for regular expression.
 455 With a prefix argument, do a regular string search instead.
 456 Like ordinary incremental search except that your input
 457 is treated as a regexp.  See \\[isearch-forward] for more info."
 458   (interactive "P\np")
 459   (isearch-mode nil (null not-regexp) nil (not no-recursive-edit)))
 460
 461
 462 (defun isearch-mode-help ()
 463   (interactive)
 464   (describe-function 'isearch-forward)
 465   (isearch-update))
 466
 467 \f
 468 ;;;==================================================================
 469 ;; isearch-mode only sets up incremental search for the minor mode.
 470 ;; All the work is done by the isearch-mode commands.
 471
 472 ;; Not used yet:
 473 ;;(defconst isearch-commands '(isearch-forward isearch-backward
 474 ;;                           isearch-forward-regexp isearch-backward-regexp)
 475 ;;  "List of commands for which isearch-mode does not recursive-edit.")
 476
 477
 478 (defun isearch-mode (forward &optional regexp op-fun recursive-edit word-p)
 479   "Start isearch minor mode.  Called by isearch-forward, etc."
 480
 481   ;; Initialize global vars.
 482   (setq isearch-forward forward
 483         isearch-regexp regexp
 484         isearch-word word-p
 485         isearch-op-fun op-fun
 486         isearch-case-fold-search case-fold-search
 487         isearch-string ""
 488         isearch-message ""
 489         isearch-cmds nil
 490         isearch-success t
 491         isearch-wrapped nil
 492         isearch-barrier (point)
 493         isearch-adjusted nil
 494         isearch-yank-flag nil
 495         isearch-invalid-regexp nil
 496         isearch-within-brackets nil
 497         ;; Use (baud-rate) for now, for sake of other versions.
 498         isearch-slow-terminal-mode (and (<= (baud-rate) search-slow-speed)
 499                                         (> (window-height)
 500                                            (* 4 search-slow-window-lines)))
 501         isearch-other-end nil
 502         isearch-small-window nil
 503
 504         isearch-opoint (point)
 505         search-ring-yank-pointer nil
 506         regexp-search-ring-yank-pointer nil)
 507   (setq isearch-window-configuration
 508         (if isearch-slow-terminal-mode (current-window-configuration) nil))
 509
 510 ;; This was for Lucid Emacs.  But now that we have pre-command-hook,
 511 ;; it causes trouble.
 512 ;;  (if isearch-pre-command-hook-exists
 513 ;;      (add-hook 'pre-command-hook 'isearch-pre-command-hook))
 514   (setq isearch-mode " Isearch")  ;; forward? regexp?
 515   (set-buffer-modified-p (buffer-modified-p)) ; update modeline
 516
 517   (isearch-push-state)
 518
 519   (make-local-variable 'overriding-local-map)
 520   (setq overriding-local-map isearch-mode-map)
 521   (isearch-update)
 522   (run-hooks 'isearch-mode-hook)
 523
 524   ;; isearch-mode can be made modal (in the sense of not returning to
 525   ;; the calling function until searching is completed) by entering
 526   ;; a recursive-edit and exiting it when done isearching.
 527   (if recursive-edit
 528       (let ((isearch-recursive-edit t))
 529         (recursive-edit)))
 530   isearch-success)
 531
 532
 533 ;;;====================================================
 534 ;; Some high level utilities.  Others below.
 535
 536 (defun isearch-update ()
 537   ;; Called after each command to update the display.
 538   (if (if isearch-event-data-type
 539           (null unread-command-event)
 540         (if isearch-gnu-emacs-events
 541             (null unread-command-events)
 542           (< unread-command-char 0)))
 543       (progn
 544         (if (not (input-pending-p))
 545             (isearch-message))
 546         (if (and isearch-slow-terminal-mode
 547                  (not (or isearch-small-window
 548                           (pos-visible-in-window-p))))
 549             (let ((found-point (point)))
 550               (setq isearch-small-window t)
 551               (move-to-window-line 0)
 552               (let ((window-min-height 1))
 553                 (split-window nil (if (< search-slow-window-lines 0)
 554                                       (1+ (- search-slow-window-lines))
 555                                     (- (window-height)
 556                                        (1+ search-slow-window-lines)))))
 557               (if (< search-slow-window-lines 0)
 558                   (progn (vertical-motion (- 1 search-slow-window-lines))
 559                          (set-window-start (next-window) (point))
 560                          (set-window-hscroll (next-window)
 561                                              (window-hscroll))
 562                          (set-window-hscroll (selected-window) 0))
 563                 (other-window 1))
 564               (goto-char found-point)))
 565         (if isearch-other-end
 566             (if (< isearch-other-end (point)) ; isearch-forward?
 567                 (isearch-highlight isearch-other-end (point))
 568               (isearch-highlight (point) isearch-other-end))
 569           (isearch-dehighlight nil))
 570         ))
 571   (setq ;; quit-flag nil  not for isearch-mode
 572    isearch-adjusted nil
 573    isearch-yank-flag nil)
 574   )
 575
 576
 577 (defun isearch-done (&optional nopush edit)
 578   ;; Called by all commands that terminate isearch-mode.
 579   ;; If NOPUSH is non-nil, we don't push the string on the search ring.
 580   (setq overriding-local-map nil)
 581   ;; (setq pre-command-hook isearch-old-pre-command-hook) ; for lemacs
 582   (isearch-dehighlight t)
 583   (let ((found-start (window-start (selected-window)))
 584         (found-point (point)))
 585     (if isearch-window-configuration
 586         (set-window-configuration isearch-window-configuration))
 587
 588     (if isearch-small-window
 589         (goto-char found-point)
 590       ;; Exiting the save-window-excursion clobbers window-start; restore it.
 591       (set-window-start (selected-window) found-start t)))
 592
 593     ;; If there was movement, mark the starting position.
 594     ;; Maybe should test difference between and set mark iff > threshold.
 595     (if (/= (point) isearch-opoint)
 596         (progn
 597           (or (and transient-mark-mode mark-active)
 598               (push-mark isearch-opoint t))
 599           (or executing-macro (> (minibuffer-depth) 0)
 600               (message "Mark saved where search started")))
 601       ;; (message "") why is this needed?
 602       )
 603
 604   (setq isearch-mode nil)
 605   (set-buffer-modified-p (buffer-modified-p))  ;; update modeline
 606
 607   (if (and (> (length isearch-string) 0) (not nopush))
 608       ;; Update the ring data.
 609       (if isearch-regexp
 610           (if (or (null regexp-search-ring)
 611                   (not (string= isearch-string (car regexp-search-ring))))
 612               (progn
 613                 (setq regexp-search-ring
 614                       (cons isearch-string regexp-search-ring))
 615                 (if (> (length regexp-search-ring) regexp-search-ring-max)
 616                     (setcdr (nthcdr (1- search-ring-max) regexp-search-ring)
 617                             nil))))
 618         (if (or (null search-ring)
 619                 (not (string= isearch-string (car search-ring))))
 620             (progn
 621               (setq search-ring (cons isearch-string search-ring))
 622               (if (> (length search-ring) search-ring-max)
 623                   (setcdr (nthcdr (1- search-ring-max) search-ring) nil))))))
 624
 625   (run-hooks 'isearch-mode-end-hook)
 626   (and (not edit) isearch-recursive-edit (exit-recursive-edit)))
 627
 628 ;;;=======================================================
 629 ;;; Switching buffers should first terminate isearch-mode.
 630 ;;; This is done quite differently for each variant of emacs.
 631 ;;; For lemacs, see Exiting in lemacs below
 632
 633 ;; For Emacs 19, the frame switch event is handled.
 634 (defun isearch-switch-frame-handler ()
 635   (interactive) ;; Is this necessary?
 636   ;; First terminate isearch-mode.
 637   (isearch-done)
 638   (handle-switch-frame (car (cdr (isearch-last-command-char)))))
 639
 640 ;;;========================================================
 641
 642 \f
 643 ;;;====================================================
 644 ;; Commands active while inside of the isearch minor mode.
 645
 646 (defun isearch-exit ()
 647   "Exit search normally.
 648 However, if this is the first command after starting incremental
 649 search and `search-nonincremental-instead' is non-nil, do a
 650 nonincremental search instead via `isearch-edit-string'."
 651   (interactive)
 652   (if (and search-nonincremental-instead
 653            (= 0 (length isearch-string)))
 654       (let ((isearch-nonincremental t))
 655         (isearch-edit-string)))
 656   (isearch-done))
 657
 658
 659 (defun isearch-edit-string ()
 660   "Edit the search string in the minibuffer.
 661 The following additional command keys are active while editing.
 662 \\<minibuffer-local-isearch-map>
 663 \\[exit-minibuffer] to resume incremental searching with the edited string.
 664 \\[isearch-nonincremental-exit-minibuffer] to do one nonincremental search.
 665 \\[isearch-forward-exit-minibuffer] to resume isearching forward.
 666 \\[isearch-reverse-exit-minibuffer] to resume isearching backward.
 667 \\[isearch-ring-advance-edit] to replace the search string with the next item in the search ring.
 668 \\[isearch-ring-retreat-edit] to replace the search string with the previous item in the search ring.
 669 \\[isearch-complete-edit] to complete the search string using the search ring.
 670 \\<isearch-mode-map>
 671 If first char entered is \\[isearch-yank-word], then do word search instead."
 672
 673   ;; This code is very hairy for several reasons, explained in the code.
 674   ;; Mainly, isearch-mode must be terminated while editing and then restarted.
 675   ;; If there were a way to catch any change of buffer from the minibuffer,
 676   ;; this could be simplified greatly.
 677   ;; Editing doesn't back up the search point.  Should it?
 678   (interactive)
 679   (condition-case err
 680       (let ((isearch-nonincremental isearch-nonincremental)
 681
 682             ;; Locally bind all isearch global variables to protect them
 683             ;; from recursive isearching.
 684             ;; isearch-string -message and -forward are not bound
 685             ;; so they may be changed.  Instead, save the values.
 686             (isearch-new-string isearch-string)
 687             (isearch-new-message isearch-message)
 688             (isearch-new-forward isearch-forward)
 689             (isearch-new-word isearch-word)
 690
 691             (isearch-regexp isearch-regexp)
 692             (isearch-op-fun isearch-op-fun)
 693             (isearch-cmds isearch-cmds)
 694             (isearch-success isearch-success)
 695             (isearch-wrapped isearch-wrapped)
 696             (isearch-barrier isearch-barrier)
 697             (isearch-adjusted isearch-adjusted)
 698             (isearch-yank-flag isearch-yank-flag)
 699             (isearch-invalid-regexp isearch-invalid-regexp)
 700             (isearch-within-brackets isearch-within-brackets)
 701             (isearch-other-end isearch-other-end)
 702             (isearch-opoint isearch-opoint)
 703             (isearch-slow-terminal-mode isearch-slow-terminal-mode)
 704             (isearch-small-window isearch-small-window)
 705             (isearch-recursive-edit isearch-recursive-edit)
 706             ;; Save current configuration so we can restore it here.
 707             (isearch-window-configuration (current-window-configuration))
 708             )
 709
 710         ;; Actually terminate isearching until editing is done.
 711         ;; This is so that the user can do anything without failure,
 712         ;; like switch buffers and start another isearch, and return.
 713         (condition-case err
 714             (isearch-done t t)
 715           (exit nil))                   ; was recursive editing
 716
 717         (isearch-message) ;; for read-char
 718         (unwind-protect
 719             (let* (;; Why does following read-char echo?
 720                    ;;(echo-keystrokes 0) ;; not needed with above message
 721                    (e (let ((cursor-in-echo-area t))
 722                         (read-event)))
 723                    ;; Binding minibuffer-history-symbol to nil is a work-around
 724                    ;; for some incompatibility with gmhist.
 725                    (minibuffer-history-symbol))
 726               ;; If the first character the user types when we prompt them
 727               ;; for a string is the yank-word character, then go into
 728               ;; word-search mode.  Otherwise unread that character and
 729               ;; read a key the normal way.
 730               ;; Word search does not apply (yet) to regexp searches,
 731               ;; no check is made here.
 732               (message (isearch-message-prefix nil nil t))
 733               (if (eq 'isearch-yank-word
 734                       (lookup-key isearch-mode-map (vector e)))
 735                   (setq isearch-word t  ;; so message-prefix is right
 736                         isearch-new-word t)
 737                 (isearch-unread e))
 738               (setq cursor-in-echo-area nil)
 739               (setq isearch-new-string
 740                     (let (junk-ring)
 741                       (read-from-minibuffer (isearch-message-prefix)
 742                                             isearch-string
 743                                             minibuffer-local-isearch-map nil
 744                                             'junk-ring))
 745                     isearch-new-message
 746                     (mapconcat 'isearch-text-char-description
 747                                isearch-new-string "")))
 748           ;; Always resume isearching by restarting it.
 749           (isearch-mode isearch-forward
 750                         isearch-regexp
 751                         isearch-op-fun
 752                         nil
 753                         isearch-word)
 754
 755           ;; Copy new local values to isearch globals
 756           (setq isearch-string isearch-new-string
 757                 isearch-message isearch-new-message
 758                 isearch-forward isearch-new-forward
 759                 isearch-word isearch-new-word))
 760
 761         ;; Empty isearch-string means use default.
 762         (if (= 0 (length isearch-string))
 763             (setq isearch-string (car (if isearch-regexp regexp-search-ring
 764                                         search-ring)))
 765           ;; This used to set the last search string,
 766           ;; but I think it is not right to do that here.
 767           ;; Only the string actually used should be saved.
 768           )
 769
 770         ;; Reinvoke the pending search.
 771         (isearch-push-state)
 772         (isearch-search)
 773         (isearch-update)
 774         (if isearch-nonincremental
 775             (progn
 776               ;; (sit-for 1) ;; needed if isearch-done does: (message "")
 777               (isearch-done))))
 778
 779     (quit  ; handle abort-recursive-edit
 780      (isearch-abort)  ;; outside of let to restore outside global values
 781      )))
 782
 783 (defun isearch-nonincremental-exit-minibuffer ()
 784   (interactive)
 785   (setq isearch-nonincremental t)
 786   (exit-minibuffer))
 787
 788 (defun isearch-forward-exit-minibuffer ()
 789   (interactive)
 790   (setq isearch-new-forward t)
 791   (exit-minibuffer))
 792
 793 (defun isearch-reverse-exit-minibuffer ()
 794   (interactive)
 795   (setq isearch-new-forward nil)
 796   (exit-minibuffer))
 797
 798
 799 (defun isearch-abort ()
 800   "Abort incremental search mode if searching is successful, signalling quit.
 801 Otherwise, revert to previous successful search and continue searching.
 802 Use `isearch-exit' to quit without signalling."
 803   (interactive)
 804 ;;  (ding)  signal instead below, if quitting
 805   (discard-input)
 806   (if isearch-success
 807       ;; If search is successful, move back to starting point
 808       ;; and really do quit.
 809       (progn (goto-char isearch-opoint)
 810              (isearch-done t)   ; exit isearch
 811              (signal 'quit nil))  ; and pass on quit signal
 812     ;; If search is failing, rub out until it is once more successful.
 813     (while (not isearch-success) (isearch-pop-state))
 814     (isearch-update)))
 815
 816
 817 (defun isearch-repeat (direction)
 818   ;; Utility for isearch-repeat-forward and -backward.
 819   (if (eq isearch-forward (eq direction 'forward))
 820       ;; C-s in forward or C-r in reverse.
 821       (if (equal isearch-string "")
 822           ;; If search string is empty, use last one.
 823           (setq isearch-string
 824                 (or (if isearch-regexp
 825                         (car regexp-search-ring)
 826                       (car search-ring))
 827                     "")
 828                 isearch-message
 829                 (mapconcat 'isearch-text-char-description
 830                            isearch-string ""))
 831         ;; If already have what to search for, repeat it.
 832         (or isearch-success
 833             (progn
 834
 835               (goto-char (if isearch-forward (point-min) (point-max)))
 836               (setq isearch-wrapped t))))
 837     ;; C-s in reverse or C-r in forward, change direction.
 838     (setq isearch-forward (not isearch-forward)))
 839
 840   (setq isearch-barrier (point)) ; For subsequent \| if regexp.
 841
 842   (if (equal isearch-string "")
 843       (setq isearch-success t)
 844     (if (and isearch-success (equal (match-end 0) (match-beginning 0)))
 845         ;; If repeating a search that found
 846         ;; an empty string, ensure we advance.
 847         (if (if isearch-forward (eobp) (bobp))
 848             ;; If there's nowhere to advance to, fail (and wrap next time).
 849             (progn
 850               (setq isearch-success nil)
 851               (ding))
 852           (forward-char (if isearch-forward 1 -1))
 853           (isearch-search))
 854       (isearch-search)))
 855
 856   (isearch-push-state)
 857   (isearch-update))
 858
 859 (defun isearch-repeat-forward ()
 860   "Repeat incremental search forwards."
 861   (interactive)
 862   (isearch-repeat 'forward))
 863
 864 (defun isearch-repeat-backward ()
 865   "Repeat incremental search backwards."
 866   (interactive)
 867   (isearch-repeat 'backward))
 868
 869 (defun isearch-toggle-regexp ()
 870   "Toggle regexp searching on or off."
 871   ;; The status stack is left unchanged.
 872   (interactive)
 873   (setq isearch-regexp (not isearch-regexp))
 874   (if isearch-regexp (setq isearch-word nil))
 875   (isearch-update))
 876
 877 (defun isearch-toggle-case-fold ()
 878   "Toggle case folding in searching on or off."
 879   (interactive)
 880   (setq isearch-case-fold-search
 881         (if isearch-case-fold-search nil 'yes))
 882   (message "%s%s [case %ssensitive]"
 883            (isearch-message-prefix)
 884            isearch-message
 885            (if isearch-case-fold-search "in" ""))
 886   (setq isearch-adjusted t)
 887   (sit-for 1)
 888   (isearch-update))
 889
 890 (defun isearch-delete-char ()
 891   "Discard last input item and move point back.
 892 If no previous match was done, just beep."
 893   (interactive)
 894   (if (null (cdr isearch-cmds))
 895       (ding)
 896     (isearch-pop-state))
 897   (isearch-update))
 898
 899
 900 (defun isearch-yank (chunk)
 901   ;; Helper for isearch-yank-word and isearch-yank-line
 902   ;; CHUNK should be word, line or kill.
 903   (let ((string (cond
 904                  ((eq chunk 'kill)
 905                   (current-kill 0))
 906                  (t
 907                   (save-excursion
 908                     (and (not isearch-forward) isearch-other-end
 909                          (goto-char isearch-other-end))
 910                     (buffer-substring
 911                      (point)
 912                      (save-excursion
 913                        (cond
 914                         ((eq chunk 'word)
 915                          (forward-word 1))
 916                         ((eq chunk 'line)
 917                          (end-of-line)))
 918                        (point))))))))
 919     ;; Downcase the string if not supposed to case-fold yanked strings.
 920     (if (and isearch-case-fold-search
 921              (eq 'not-yanks search-upper-case))
 922         (setq string (downcase string)))
 923     (if isearch-regexp (setq string (regexp-quote string)))
 924     (setq isearch-string (concat isearch-string string)
 925           isearch-message
 926           (concat isearch-message
 927                   (mapconcat 'isearch-text-char-description
 928                              string ""))
 929           ;; Don't move cursor in reverse search.
 930           isearch-yank-flag t))
 931   (isearch-search-and-update))
 932
 933 (defun isearch-yank-kill ()
 934   "Pull string from kill ring into search string."
 935   (interactive)
 936   (isearch-yank 'kill))
 937
 938 (defun isearch-yank-word ()
 939   "Pull next word from buffer into search string."
 940   (interactive)
 941   (isearch-yank 'word))
 942
 943 (defun isearch-yank-line ()
 944   "Pull rest of line from buffer into search string."
 945   (interactive)
 946   (isearch-yank 'line))
 947
 948
 949 (defun isearch-search-and-update ()
 950   ;; Do the search and update the display.
 951   (if (and (not isearch-success)
 952            ;; unsuccessful regexp search may become
 953            ;;  successful by addition of characters which
 954            ;;  make isearch-string valid
 955            (not isearch-regexp))
 956       nil
 957     ;; In reverse search, adding stuff at
 958     ;; the end may cause zero or many more chars to be
 959     ;; matched, in the string following point.
 960     ;; Allow all those possibilities without moving point as
 961     ;; long as the match does not extend past search origin.
 962     (if (and (not isearch-forward) (not isearch-adjusted)
 963              (condition-case ()
 964                  (looking-at (if isearch-regexp isearch-string
 965                                (regexp-quote isearch-string)))
 966                (error nil))
 967                (or isearch-yank-flag
 968                    (<= (match-end 0)
 969                        (min isearch-opoint isearch-barrier))))
 970         (setq isearch-success t
 971               isearch-invalid-regexp nil
 972               isearch-within-brackets nil
 973               isearch-other-end (match-end 0))
 974       ;; Not regexp, not reverse, or no match at point.
 975       (if (and isearch-other-end (not isearch-adjusted))
 976           (goto-char (if isearch-forward isearch-other-end
 977                        (min isearch-opoint
 978                             isearch-barrier
 979                             (1+ isearch-other-end)))))
 980       (isearch-search)
 981       ))
 982   (isearch-push-state)
 983   (if isearch-op-fun (funcall isearch-op-fun))
 984   (isearch-update))
 985
 986
 987 ;; *, ?, and | chars can make a regexp more liberal.
 988 ;; They can make a regexp match sooner or make it succeed instead of failing.
 989 ;; So go back to place last successful search started
 990 ;; or to the last ^S/^R (barrier), whichever is nearer.
 991 ;; + needs no special handling because the string must match at least once.
 992
 993 (defun isearch-*-char ()
 994   "Handle * and ? specially in regexps."
 995   (interactive)
 996   (if isearch-regexp
 997
 998       (progn
 999         (setq isearch-adjusted t)
1000         (let ((cs (nth (if isearch-forward
1001                            5            ; isearch-other-end
1002                          2)             ; saved (point)
1003                        (car (cdr isearch-cmds)))))
1004           ;; (car isearch-cmds) is after last search;
1005           ;; (car (cdr isearch-cmds)) is from before it.
1006           (setq cs (or cs isearch-barrier))
1007           (goto-char
1008            (if isearch-forward
1009                (max cs isearch-barrier)
1010              (min cs isearch-barrier))))))
1011   (isearch-process-search-char (isearch-last-command-char)))
1012
1013
1014 (defun isearch-|-char ()
1015   "If in regexp search, jump to the barrier."
1016   (interactive)
1017   (if isearch-regexp
1018       (progn
1019         (setq isearch-adjusted t)
1020         (goto-char isearch-barrier)))
1021   (isearch-process-search-char (isearch-last-command-char)))
1022
1023
1024 (defalias 'isearch-other-control-char 'isearch-other-meta-char)
1025
1026 (defun isearch-other-meta-char ()
1027   "Exit the search normally and reread this key sequence.
1028 But only if `search-exit-option' is non-nil, the default.
1029 If it is the symbol `edit', the search string is edited in the minibuffer
1030 and the meta character is unread so that it applies to editing the string."
1031   (interactive)
1032   (cond ((eq search-exit-option 'edit)
1033          (let ((key (this-command-keys)))
1034            (apply 'isearch-unread (listify-key-sequence key)))
1035          (isearch-edit-string))
1036         (search-exit-option
1037          (let ((key (this-command-keys))
1038                (index 0)
1039                window)
1040            (apply 'isearch-unread (listify-key-sequence key))
1041            ;; Properly handle scroll-bar and mode-line clicks
1042            ;; for which a dummy prefix event was generated as (aref key 0).
1043            (and (> (length key) 1)
1044                 (symbolp (aref key 0))
1045                 (listp (aref key 1))
1046                 ;; These events now have a symbol; they used to have a list.
1047                 ;; Accept either one.  Other events have a number here.
1048                 (not (numberp (posn-point (event-start (aref key 1)))))
1049                 (setq index 1))
1050            ;; If we got a mouse click, maybe it was read with the buffer
1051            ;; it was clicked on.  If so, that buffer, not the current one,
1052            ;; is in isearch mode.  So end the search in that buffer.
1053            (if (and (listp (aref key index))
1054                     (setq window (posn-window (event-start (aref key index))))
1055                     (windowp window))
1056                (save-excursion
1057                  (set-buffer (window-buffer window))
1058                  (isearch-done))
1059              (isearch-done))))
1060         (t;; otherwise nil
1061          (isearch-process-search-string (this-command-keys)
1062                                         (this-command-keys)))))
1063
1064 (defun isearch-quote-char ()
1065   "Quote special characters for incremental search."
1066   (interactive)
1067   (isearch-process-search-char (read-quoted-char (isearch-message t))))
1068
1069 (defun isearch-return-char ()
1070   "Convert return into newline for incremental search.
1071 Obsolete."
1072   (interactive)
1073   (isearch-process-search-char ?\n))
1074
1075 (defun isearch-printing-char ()
1076   "Add this ordinary printing character to the search string and search."
1077   (interactive)
1078   (isearch-process-search-char (isearch-last-command-char)))
1079
1080 (defun isearch-whitespace-chars ()
1081   "Match all whitespace chars, if in regexp mode.
1082 If you want to search for just a space, type C-q SPC."
1083   (interactive)
1084   (if isearch-regexp
1085       (if (and search-whitespace-regexp (not isearch-within-brackets))
1086           (isearch-process-search-string search-whitespace-regexp " ")
1087         (isearch-printing-char))
1088     (progn
1089       ;; This way of doing word search doesn't correctly extend current search.
1090       ;;      (setq isearch-word t)
1091       ;;      (setq isearch-adjusted t)
1092       ;;      (goto-char isearch-barrier)
1093       (isearch-printing-char))))
1094
1095 (defun isearch-process-search-char (char)
1096   ;; Append the char to the search string, update the message and re-search.
1097   (isearch-process-search-string
1098    (isearch-char-to-string char)
1099    (isearch-text-char-description char)))
1100
1101 (defun isearch-process-search-string (string message)
1102   (setq isearch-string (concat isearch-string string)
1103         isearch-message (concat isearch-message message))
1104   (isearch-search-and-update))
1105
1106 \f
1107 ;;===========================================================
1108 ;; Search Ring
1109
1110 (defun isearch-ring-adjust1 (advance)
1111   ;; Helper for isearch-ring-adjust
1112   (let* ((ring (if isearch-regexp regexp-search-ring search-ring))
1113          (length (length ring))
1114          (yank-pointer-name (if isearch-regexp
1115                                 'regexp-search-ring-yank-pointer
1116                               'search-ring-yank-pointer))
1117          (yank-pointer (eval yank-pointer-name)))
1118     (if (zerop length)
1119         ()
1120       (set yank-pointer-name
1121            (setq yank-pointer
1122                  (mod (+ (or yank-pointer 0)
1123                          (if advance -1 1))
1124                       length)))
1125       (setq isearch-string (nth yank-pointer ring)
1126             isearch-message (mapconcat 'isearch-text-char-description
1127                                        isearch-string "")))))
1128
1129 (defun isearch-ring-adjust (advance)
1130   ;; Helper for isearch-ring-advance and isearch-ring-retreat
1131   (if (cdr isearch-cmds)  ;; is there more than one thing on stack?
1132       (isearch-pop-state))
1133   (isearch-ring-adjust1 advance)
1134   (isearch-push-state)
1135   (if search-ring-update
1136       (progn
1137         (isearch-search)
1138         (isearch-update))
1139     (isearch-edit-string)
1140     ))
1141
1142 (defun isearch-ring-advance ()
1143   "Advance to the next search string in the ring."
1144   ;; This could be more general to handle a prefix arg, but who would use it.
1145   (interactive)
1146   (isearch-ring-adjust 'advance))
1147
1148 (defun isearch-ring-retreat ()
1149   "Retreat to the previous search string in the ring."
1150   (interactive)
1151   (isearch-ring-adjust nil))
1152
1153 (defun isearch-ring-advance-edit (n)
1154   "Insert the next element of the search history into the minibuffer."
1155   (interactive "p")
1156   (let* ((yank-pointer-name (if isearch-regexp
1157                                 'regexp-search-ring-yank-pointer
1158                               'search-ring-yank-pointer))
1159          (yank-pointer (eval yank-pointer-name))
1160          (ring (if isearch-regexp regexp-search-ring search-ring))
1161          (length (length ring)))
1162     (if (zerop length)
1163         ()
1164       (set yank-pointer-name
1165            (setq yank-pointer
1166                  (mod (- (or yank-pointer 0) n)
1167                       length)))
1168
1169       (erase-buffer)
1170       (insert (nth yank-pointer ring))
1171       (goto-char (point-max)))))
1172
1173 (defun isearch-ring-retreat-edit (n)
1174   "Inserts the previous element of the search history into the minibuffer."
1175   (interactive "p")
1176   (isearch-ring-advance-edit (- n)))
1177
1178 ;;(defun isearch-ring-adjust-edit (advance)
1179 ;;  "Use the next or previous search string in the ring while in minibuffer."
1180 ;;  (isearch-ring-adjust1 advance)
1181 ;;  (erase-buffer)
1182 ;;  (insert isearch-string))
1183
1184 ;;(defun isearch-ring-advance-edit ()
1185 ;;  (interactive)
1186 ;;  (isearch-ring-adjust-edit 'advance))
1187
1188 ;;(defun isearch-ring-retreat-edit ()
1189 ;;  "Retreat to the previous search string in the ring while in the minibuffer."
1190 ;;  (interactive)
1191 ;;  (isearch-ring-adjust-edit nil))
1192
1193
1194 (defun isearch-complete1 ()
1195   ;; Helper for isearch-complete and isearch-complete-edit
1196   ;; Return t if completion OK, nil if no completion exists.
1197   (let* ((ring (if isearch-regexp regexp-search-ring search-ring))
1198          (alist (mapcar (function (lambda (string) (list string))) ring))
1199          (completion-ignore-case case-fold-search)
1200          (completion (try-completion isearch-string alist)))
1201     (cond
1202      ((eq completion t)
1203       ;; isearch-string stays the same
1204       t)
1205      ((or completion ; not nil, must be a string
1206           (= 0 (length isearch-string))) ; shouldnt have to say this
1207       (if (equal completion isearch-string)  ;; no extension?
1208           (if completion-auto-help
1209               (with-output-to-temp-buffer "*Isearch completions*"
1210                 (display-completion-list
1211                  (all-completions isearch-string alist))))
1212         (setq isearch-string completion))
1213       t)
1214      (t
1215       (message "No completion") ; waits a second if in minibuffer
1216       nil))))
1217
1218 (defun isearch-complete ()
1219   "Complete the search string from the strings on the search ring.
1220 The completed string is then editable in the minibuffer.
1221 If there is no completion possible, say so and continue searching."
1222   (interactive)
1223   (if (isearch-complete1)
1224       (isearch-edit-string)
1225     ;; else
1226     (sit-for 1)
1227     (isearch-update)))
1228
1229 (defun isearch-complete-edit ()
1230   "Same as `isearch-complete' except in the minibuffer."
1231   (interactive)
1232   (setq isearch-string (buffer-string))
1233   (if (isearch-complete1)
1234       (progn
1235         (erase-buffer)
1236         (insert isearch-string))))
1237
1238 \f
1239 ;;;==============================================================
1240 ;; The search status stack (and isearch window-local variables, not used).
1241 ;; Need a structure for this.
1242
1243 (defun isearch-top-state ()
1244   (let ((cmd (car isearch-cmds)))
1245     (setq isearch-string (car cmd)
1246           isearch-message (car (cdr cmd))
1247           isearch-success (nth 3 cmd)
1248           isearch-forward (nth 4 cmd)
1249           isearch-other-end (nth 5 cmd)
1250           isearch-word (nth 6 cmd)
1251           isearch-invalid-regexp (nth 7 cmd)
1252           isearch-wrapped (nth 8 cmd)
1253           isearch-barrier (nth 9 cmd)
1254           isearch-within-brackets (nth 10 cmd)
1255           isearch-case-fold-search (nth 11 cmd))
1256     (goto-char (car (cdr (cdr cmd))))))
1257
1258 (defun isearch-pop-state ()
1259   (setq isearch-cmds (cdr isearch-cmds))
1260   (isearch-top-state)
1261   )
1262
1263 (defun isearch-push-state ()
1264   (setq isearch-cmds
1265         (cons (list isearch-string isearch-message (point)
1266                     isearch-success isearch-forward isearch-other-end
1267                     isearch-word
1268                     isearch-invalid-regexp isearch-wrapped isearch-barrier
1269                     isearch-within-brackets isearch-case-fold-search)
1270               isearch-cmds)))
1271
1272 \f
1273 ;;;==================================================================
1274 ;; Message string
1275
1276 (defun isearch-message (&optional c-q-hack ellipsis)
1277   ;; Generate and print the message string.
1278   (let ((cursor-in-echo-area ellipsis)
1279         (m (concat
1280             (isearch-message-prefix c-q-hack ellipsis isearch-nonincremental)
1281             isearch-message
1282             (isearch-message-suffix c-q-hack ellipsis)
1283             )))
1284     (if c-q-hack m (message "%s" m))))
1285
1286 (defun isearch-message-prefix (&optional c-q-hack ellipsis nonincremental)
1287   ;; If about to search, and previous search regexp was invalid,
1288   ;; check that it still is.  If it is valid now,
1289   ;; let the message we display while searching say that it is valid.
1290   (and isearch-invalid-regexp ellipsis
1291        (condition-case ()
1292            (progn (re-search-forward isearch-string (point) t)
1293                   (setq isearch-invalid-regexp nil
1294                         isearch-within-brackets nil))
1295          (error nil)))
1296   ;; If currently failing, display no ellipsis.
1297   (or isearch-success (setq ellipsis nil))
1298   (let ((m (concat (if isearch-success "" "failing ")
1299                    (if isearch-wrapped "wrapped ")
1300                    (if isearch-word "word " "")
1301                    (if isearch-regexp "regexp " "")
1302                    (if nonincremental "search" "I-search")
1303                    (if isearch-forward ": " " backward: ")
1304                    )))
1305     (aset m 0 (upcase (aref m 0)))
1306     m))
1307
1308
1309 (defun isearch-message-suffix (&optional c-q-hack ellipsis)
1310   (concat (if c-q-hack "^Q" "")
1311           (if isearch-invalid-regexp
1312               (concat " [" isearch-invalid-regexp "]")
1313             "")))
1314
1315 \f
1316 ;;;========================================================
1317 ;;; Searching
1318
1319 (defun isearch-search ()
1320   ;; Do the search with the current search string.
1321   (isearch-message nil t)
1322   (if (and (eq isearch-case-fold-search t) search-upper-case)
1323       (setq isearch-case-fold-search
1324             (isearch-no-upper-case-p isearch-string isearch-regexp)))
1325   (condition-case lossage
1326       (let ((inhibit-quit nil)
1327             (case-fold-search isearch-case-fold-search))
1328         (if isearch-regexp (setq isearch-invalid-regexp nil))
1329         (setq isearch-within-brackets nil)
1330         (setq isearch-success
1331               (funcall
1332                (cond (isearch-word
1333                       (if isearch-forward
1334                           'word-search-forward 'word-search-backward))
1335                      (isearch-regexp
1336                       (if isearch-forward
1337                           're-search-forward 're-search-backward))
1338                      (t
1339                       (if isearch-forward 'search-forward 'search-backward)))
1340                isearch-string nil t))
1341         (if isearch-success
1342             (setq isearch-other-end
1343                   (if isearch-forward (match-beginning 0) (match-end 0)))))
1344
1345     (quit (isearch-unread ?\C-g)
1346           (setq isearch-success nil))
1347
1348     (invalid-regexp
1349      (setq isearch-invalid-regexp (car (cdr lossage)))
1350      (setq isearch-within-brackets (string-match "\\`Unmatched \\["
1351                                                  isearch-invalid-regexp))
1352      (if (string-match
1353           "\\`Premature \\|\\`Unmatched \\|\\`Invalid "
1354           isearch-invalid-regexp)
1355          (setq isearch-invalid-regexp "incomplete input")))
1356     (error
1357      ;; stack overflow in regexp search.
1358      (setq isearch-invalid-regexp (car (cdr lossage)))))
1359
1360   (if isearch-success
1361       nil
1362     ;; Ding if failed this time after succeeding last time.
1363     (and (nth 3 (car isearch-cmds))
1364          (ding))
1365     (goto-char (nth 2 (car isearch-cmds)))))
1366
1367
1368 \f
1369 ;;;========================================================
1370 ;;; Highlighting
1371
1372 (defvar isearch-overlay nil)
1373
1374 (defun isearch-highlight (beg end)
1375   (if (or (null search-highlight) (null window-system))
1376       nil
1377     (or isearch-overlay (setq isearch-overlay (make-overlay beg end)))
1378     (move-overlay isearch-overlay beg end (current-buffer))
1379     (overlay-put isearch-overlay 'face
1380                  (if (internal-find-face 'isearch nil)
1381                      'isearch 'region))))
1382
1383 (defun isearch-dehighlight (totally)
1384   (if isearch-overlay
1385       (delete-overlay isearch-overlay)))
1386
1387 ;;;===========================================================
1388 ;;; General utilities
1389
1390
1391 (defun isearch-no-upper-case-p (string regexp-flag)
1392   "Return t if there are no upper case chars in STRING.
1393 If REGEXP-FLAG is non-nil, disregard letters preceeded by `\\' (but not `\\\\')
1394 since they have special meaning in a regexp."
1395   (let ((case-fold-search nil))
1396     (not (string-match (if regexp-flag "\\(^\\|\\\\\\\\\\|[^\\]\\)[A-Z]"
1397                          "[A-Z]")
1398                        string))))
1399
1400
1401 ;;;=================================================
1402 ;; Portability functions to support various Emacs versions.
1403
1404 ;; To quiet the byte-compiler.
1405 (defvar unread-command-event)
1406 (defvar unread-command-events)
1407 (defvar last-command-event)
1408
1409 (defun isearch-char-to-string (c)
1410   (if (integerp c)
1411       (make-string 1 c)
1412     (if (and (symbolp c) (get c 'ascii-character))
1413         (make-string 1 (get c 'ascii-character))
1414       (make-string 1 (event-to-character c)))))
1415
1416 (defun isearch-text-char-description (c)
1417   (if (and (integerp c) (or (< c ?\ ) (= c ?\^?)))
1418       (text-char-description c)
1419     (isearch-char-to-string c)))
1420
1421 (defun isearch-unread (&rest char-or-events)
1422   ;; General function to unread characters or events.
1423   (if isearch-gnu-emacs-events
1424       (setq unread-command-events
1425             (append char-or-events unread-command-events))
1426     (let ((char (if (cdr char-or-events)
1427                     (progn
1428                       (while (cdr char-or-events)
1429                         (setq char-or-events (cdr char-or-events)))
1430                       (+ 128 (car char-or-events)))
1431                   (car char-or-events))))
1432       (if isearch-event-data-type
1433           (setq unread-command-event char)
1434         (setq unread-command-char char)))))
1435
1436 (defun isearch-last-command-char ()
1437   ;; General function to return the last command character.
1438   (if isearch-event-data-type
1439       last-command-event
1440     last-command-char))
1441
1442 ;;; isearch.el ends here