| blob | 8bcd982eb55e3edbe14966222790b2452f7eafc6 |
1 dnl Autoconf script for GNU Emacs
2 dnl To rebuild the `configure' script from this, execute the command
3 dnl autoconf
4 dnl in the directory containing this script.
5 dnl
6 dnl Copyright (C) 1994, 1995 Free Software Foundation, Inc.
7 dnl
8 dnl This file is part of GNU Emacs.
9 dnl
10 dnl GNU Emacs is free software; you can redistribute it and/or modify
11 dnl it under the terms of the GNU General Public License as published by
12 dnl the Free Software Foundation; either version 2, or (at your option)
13 dnl any later version.
14 dnl
15 dnl GNU Emacs is distributed in the hope that it will be useful,
16 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
17 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18 dnl GNU General Public License for more details.
19 dnl
20 dnl You should have received a copy of the GNU General Public License
21 dnl along with GNU Emacs; see the file COPYING. If not, write to
22 dnl the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
24 AC_PREREQ(2.4.1)dnl
25 AC_INIT(src/lisp.h)
26 AC_CONFIG_HEADER(src/config.h:src/config.in)
28 lispdir='${datadir}/emacs/${version}/lisp'
29 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
30 '${datadir}/emacs/site-lisp'
31 lisppath='${locallisppath}:${lispdir}'
32 etcdir='${datadir}/emacs/${version}/etc'
33 lockdir='${sharedstatedir}/emacs/lock'
34 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
35 docdir='${datadir}/emacs/${version}/etc'
37 AC_ARG_WITH(gcc,
38 [ --with-gcc use GCC to compile Emacs])
39 AC_ARG_WITH(pop,
40 [ --with-pop support POP for mail retrieval],
41 [AC_DEFINE(MAIL_USE_POP)])
42 AC_ARG_WITH(kerberos,
43 [ --with-kerberos support Kerberos-authenticated POP],
44 [AC_DEFINE(KERBEROS)])
45 AC_ARG_WITH(hesiod,
46 [ --with-hesiod support Hesiod to get the POP server host],
47 [AC_DEFINE(HESIOD)])
48 dnl This should be the last --with option, because --with-x is
49 dnl added later on when we find the path of X, and it's best to
50 dnl keep them together visually.
51 AC_ARG_WITH(x-toolkit,
52 [ --with-x-toolkit=KIT use an X toolkit (KIT = yes/lucid/athena/motif)],
53 [ case "${withval}" in
54 y | ye | yes ) val=athena ;;
55 n | no ) val=no ;;
56 l | lu | luc | luci | lucid ) val=lucid ;;
57 a | at | ath | athe | athen | athena ) val=athena ;;
58 m | mo | mot | moti | motif ) val=motif ;;
59 dnl These don't currently work.
60 dnl o | op | ope | open | open- | open-l | open-lo \
61 dnl | open-loo | open-look ) val=open-look ;;
62 * )
63 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
64 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
65 AC_MSG_ERROR([\`--with-x-toolkit=$withval' is invalid\;
66 this option's value should be \`yes', \`no', \`lucid', \`athena', or \`motif'.
67 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
68 ;;
69 esac
70 with_x_toolkit=$val
71 ])
73 #### Make srcdir absolute, if it isn't already. It's important to
74 #### avoid running the path through pwd unnecessary, since pwd can
75 #### give you automounter prefixes, which can go away. We do all this
76 #### so Emacs can find its files when run uninstalled.
77 case "${srcdir}" in
78 /* ) ;;
79 . )
80 ## We may be able to use the $PWD environment variable to make this
81 ## absolute. But sometimes PWD is inaccurate.
82 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
83 CDPATH=
84 if test "${PWD}" != "" && test "`(cd ${PWD} ; sh -c pwd)`" = "`pwd`" ;
85 then
86 srcdir="$PWD"
87 else
88 srcdir="`(cd ${srcdir}; pwd)`"
89 fi
90 ;;
91 * ) srcdir="`(cd ${srcdir}; pwd)`" ;;
92 esac
94 #### Check if the source directory already has a configured system in it.
95 if test `pwd` != `(cd ${srcdir} && pwd)` \
96 && test -f "${srcdir}/src/config.h" ; then
97 AC_MSG_WARN([The directory tree \`${srcdir}' is being used
98 as a build directory right now; it has been configured in its own
99 right. To configure in another directory as well, you MUST
100 use GNU make. If you do not have GNU make, then you must
101 now do \`make distclean' in ${srcdir},
102 and then run $0 again.])
104 changequote(, )dnl
105 extrasub='/^VPATH[ ]*=/c\
106 changequote([, ])dnl
107 vpath %.c $(srcdir)\
108 vpath %.h $(srcdir)\
109 vpath %.y $(srcdir)\
110 vpath %.l $(srcdir)\
111 vpath %.s $(srcdir)\
112 vpath %.in $(srcdir)'
113 fi
115 #### Given the configuration name, set machfile and opsysfile to the
116 #### names of the m/*.h and s/*.h files we should use.
118 ### Canonicalize the configuration name.
120 AC_CANONICAL_HOST
121 canonical=$host
122 configuration=$host_alias
124 changequote(, )dnl
126 ### If you add support for a new configuration, add code to this
127 ### switch statement to recognize your configuration name and select
128 ### the appropriate operating system and machine description files.
130 ### You would hope that you could choose an m/*.h file pretty much
131 ### based on the machine portion of the configuration name, and an s-
132 ### file based on the operating system portion. However, it turns out
133 ### that each m/*.h file is pretty manufacturer-specific - for
134 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
135 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
136 ### machines. So we basically have to have a special case for each
137 ### configuration name.
138 ###
139 ### As far as handling version numbers on operating systems is
140 ### concerned, make sure things will fail in a fixable way. If
141 ### /etc/MACHINES doesn't say anything about version numbers, be
142 ### prepared to handle anything reasonably. If version numbers
143 ### matter, be sure /etc/MACHINES says something about it.
144 ###
145 ### Eric Raymond says we should accept strings like "sysvr4" to mean
146 ### "System V Release 4"; he writes, "The old convention encouraged
147 ### confusion between `system' and `release' levels'."
149 machine='' opsys='' unported=no
150 case "${canonical}" in
152 ## NetBSD ports
153 *-*-netbsd* )
154 opsys=netbsd
155 case "${canonical}" in
156 i[345]86-*-netbsd*) machine=intel386 ;;
157 m68k-*-netbsd*)
158 # This is somewhat bogus.
159 machine=hp9000s300 ;;
160 mips-*-netbsd*) machine=pmax ;;
161 ns32k-*-netbsd*) machine=ns32000 ;;
162 sparc-*-netbsd*) machine=sparc ;;
163 esac
164 ;;
166 ## Acorn RISCiX:
167 arm-acorn-riscix1.1* )
168 machine=acorn opsys=riscix1-1
169 ;;
170 arm-acorn-riscix1.2* | arm-acorn-riscix )
171 machine=acorn opsys=riscix1-2
172 ;;
174 ## Alliant machines
175 ## Strictly speaking, we need the version of the alliant operating
176 ## system to choose the right machine file, but currently the
177 ## configuration name doesn't tell us enough to choose the right
178 ## one; we need to give alliants their own operating system name to
179 ## do this right. When someone cares, they can help us.
180 fx80-alliant-* )
181 machine=alliant4 opsys=bsd4-2
182 ;;
183 i860-alliant-* )
184 machine=alliant-2800 opsys=bsd4-3
185 ;;
187 ## Alpha (DEC) machines.
188 alpha-dec-osf* )
189 machine=alpha opsys=osf1
190 ;;
192 alpha-*-linux* )
193 machine=alpha opsys=linux
194 ;;
196 ## Altos 3068
197 m68*-altos-sysv* )
198 machine=altos opsys=usg5-2
199 ;;
201 ## Amdahl UTS
202 580-amdahl-sysv* )
203 machine=amdahl opsys=usg5-2-2
204 ;;
206 ## Apollo, Domain/OS
207 m68*-apollo-* )
208 machine=apollo opsys=bsd4-3
209 ;;
211 ## AT&T 3b2, 3b5, 3b15, 3b20
212 we32k-att-sysv* )
213 machine=att3b opsys=usg5-2-2
214 ;;
216 ## AT&T 3b1 - The Mighty Unix PC!
217 m68*-att-sysv* )
218 machine=7300 opsys=usg5-2-2
219 ;;
221 ## Bull dpx20
222 rs6000-bull-bosx* )
223 machine=ibmrs6000 opsys=aix3-2
224 ;;
226 ## Bull dpx2
227 m68*-bull-sysv3* )
228 machine=dpx2 opsys=usg5-3
229 ;;
231 ## Bull sps7
232 m68*-bull-sysv2* )
233 machine=sps7 opsys=usg5-2
234 ;;
236 ## CCI 5/32, 6/32 -- see "Tahoe".
238 ## Celerity
239 ## I don't know what configuration name to use for this; config.sub
240 ## doesn't seem to know anything about it. Hey, Celerity users, get
241 ## in touch with us!
242 celerity-celerity-bsd* )
243 machine=celerity opsys=bsd4-2
244 ;;
246 ## Clipper
247 ## What operating systems does this chip run that Emacs has been
248 ## tested on?
249 clipper-* )
250 machine=clipper
251 ## We'll use the catch-all code at the bottom to guess the
252 ## operating system.
253 ;;
255 ## Convex
256 *-convex-bsd* | *-convex-convexos* )
257 machine=convex opsys=bsd4-3
258 ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
259 NON_GNU_CPP="cc -E -P"
260 ;;
262 ## Cubix QBx/386
263 i[345]86-cubix-sysv* )
264 machine=intel386 opsys=usg5-3
265 ;;
267 ## Cydra 5
268 cydra*-cydrome-sysv* )
269 machine=cydra5 opsys=usg5-3
270 ;;
272 ## Data General AViiON Machines
273 m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
274 machine=aviion opsys=dgux5-4r3
275 ;;
276 m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
277 machine=aviion opsys=dgux5-4r2
278 ;;
279 m88k-dg-dgux* )
280 machine=aviion opsys=dgux
281 ;;
283 ## DECstations
284 mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
285 machine=pmax opsys=bsd4-2
286 ;;
287 mips-dec-ultrix4.[12]* | mips-dec-bsd* )
288 machine=pmax opsys=bsd4-3
289 ;;
290 mips-dec-ultrix* )
291 machine=pmax opsys=ultrix4-3
292 ;;
293 mips-dec-osf* )
294 machine=pmax opsys=osf1
295 ;;
296 mips-dec-mach_bsd4.3* )
297 machine=pmax opsys=mach-bsd4-3
298 ;;
300 ## Motorola Delta machines
301 m68k-motorola-sysv* | m68000-motorola-sysv* )
302 machine=delta opsys=usg5-3
303 if test -z "`type gnucc | grep 'not found'`"
304 then
305 if test -s /etc/167config
306 then CC="gnucc -m68040"
307 else CC="gnucc -m68881"
308 fi
309 else
310 if test -z "`type gcc | grep 'not found'`"
311 then CC=gcc
312 else CC=cc
313 fi
314 fi
315 ;;
316 m88k-motorola-sysv4* )
317 # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
318 # needs POSIX_SIGNALS and therefore needs usg5-4-2.
319 # I hope there are not other 4.0 versions for this machine
320 # which really need usg5-4 instead.
321 machine=delta88k opsys=usg5-4-2
322 ;;
323 m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
324 machine=delta88k opsys=usg5-3
325 ;;
327 ## Dual machines
328 m68*-dual-sysv* )
329 machine=dual opsys=usg5-2
330 ;;
331 m68*-dual-uniplus* )
332 machine=dual opsys=unipl5-2
333 ;;
335 ## Elxsi 6400
336 elxsi-elxsi-sysv* )
337 machine=elxsi opsys=usg5-2
338 ;;
340 ## Encore machines
341 ns16k-encore-bsd* )
342 machine=ns16000 opsys=umax
343 ;;
345 ## The GEC 93 - apparently, this port isn't really finished yet.
347 ## Gould Power Node and NP1
348 pn-gould-bsd4.2* )
349 machine=gould opsys=bsd4-2
350 ;;
351 pn-gould-bsd4.3* )
352 machine=gould opsys=bsd4-3
353 ;;
354 np1-gould-bsd* )
355 machine=gould-np1 opsys=bsd4-3
356 ;;
358 ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
359 ## as far as Emacs is concerned).
360 m88k-harris-cxux* )
361 # Build needs to be different on 7.0 and later releases
362 case "`uname -r`" in
363 [56].[0-9] ) machine=nh4000 opsys=cxux ;;
364 [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
365 esac
366 NON_GNU_CPP="/lib/cpp"
367 ;;
368 ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
369 m68k-harris-cxux* )
370 machine=nh3000 opsys=cxux
371 ;;
372 ## Harris power pc NightHawk running Power UNIX (Series 6000)
373 powerpc-harris-powerunix )
374 machine=nh6000 opsys=powerunix
375 NON_GNU_CPP="cc -Xo -E -P"
376 ;;
378 ## Honeywell XPS100
379 xps*-honeywell-sysv* )
380 machine=xps100 opsys=usg5-2
381 ;;
383 ## HP 9000 series 200 or 300
384 m68*-hp-bsd* )
385 machine=hp9000s300 opsys=bsd4-3
386 ;;
387 ## HP/UX 7, 8, 9, and 10 are supported on these machines.
388 m68*-hp-hpux* )
389 case "`uname -r`" in
390 ## Someone's system reports A.B8.05 for this.
391 ## I wonder what other possibilities there are.
392 *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
393 *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
394 *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
395 *.10.* ) machine=hp9000s300 opsys=hpux9shr ;;
396 *) machine=hp9000s300 opsys=hpux ;;
397 esac
398 ;;
400 ## HP 9000 series 700 and 800, running HP/UX
401 hppa*-hp-hpux7* )
402 machine=hp800 opsys=hpux
403 ;;
404 hppa*-hp-hpux8* )
405 machine=hp800 opsys=hpux8
406 ;;
407 hppa*-hp-hpux9shr* )
408 machine=hp800 opsys=hpux9shr
409 ;;
410 hppa*-hp-hpux9* )
411 machine=hp800 opsys=hpux9
412 ;;
413 hppa*-hp-hpux10* )
414 machine=hp800 opsys=hpux10
415 ;;
417 ## HP 9000 series 700 and 800, running HP/UX
418 hppa*-hp-hpux* )
419 ## Cross-compilation? Nah!
420 case "`uname -r`" in
421 ## Someone's system reports A.B8.05 for this.
422 ## I wonder what other possibilities there are.
423 *.B8.* ) machine=hp800 opsys=hpux8 ;;
424 *.08.* ) machine=hp800 opsys=hpux8 ;;
425 *.09.* ) machine=hp800 opsys=hpux9 ;;
426 *) machine=hp800 opsys=hpux ;;
427 esac
428 ;;
429 hppa-*-nextstep* )
430 machine=hp800 opsys=nextstep
431 ;;
433 ## Orion machines
434 orion-orion-bsd* )
435 machine=orion opsys=bsd4-2
436 ;;
437 clipper-orion-bsd* )
438 machine=orion105 opsys=bsd4-2
439 ;;
441 ## IBM machines
442 i[345]86-ibm-aix1.1* )
443 machine=ibmps2-aix opsys=usg5-2-2
444 ;;
445 i[345]86-ibm-aix1.[23]* | i[345]86-ibm-aix* )
446 machine=ibmps2-aix opsys=usg5-3
447 ;;
448 i370-ibm-aix*)
449 machine=ibm370aix opsys=usg5-3
450 ;;
451 rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1* )
452 machine=ibmrs6000 opsys=aix3-1
453 ;;
454 rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
455 machine=ibmrs6000 opsys=aix3-2-5
456 ;;
457 rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1* )
458 machine=ibmrs6000 opsys=aix4-1
459 ;;
460 rs6000-ibm-aix4* | powerpc-ibm-aix4* )
461 machine=ibmrs6000 opsys=aix4
462 ;;
463 rs6000-ibm-aix* | powerpc-ibm-aix* )
464 machine=ibmrs6000 opsys=aix3-2
465 ;;
466 romp-ibm-bsd4.3* )
467 machine=ibmrt opsys=bsd4-3
468 ;;
469 romp-ibm-bsd4.2* )
470 machine=ibmrt opsys=bsd4-2
471 ;;
472 romp-ibm-aos4.3* )
473 machine=ibmrt opsys=bsd4-3
474 ;;
475 romp-ibm-aos4.2* )
476 machine=ibmrt opsys=bsd4-2
477 ;;
478 romp-ibm-aos* )
479 machine=ibmrt opsys=bsd4-3
480 ;;
481 romp-ibm-bsd* )
482 machine=ibmrt opsys=bsd4-3
483 ;;
484 romp-ibm-aix* )
485 machine=ibmrt-aix opsys=usg5-2-2
486 ;;
488 ## Integrated Solutions `Optimum V'
489 m68*-isi-bsd4.2* )
490 machine=isi-ov opsys=bsd4-2
491 ;;
492 m68*-isi-bsd4.3* )
493 machine=isi-ov opsys=bsd4-3
494 ;;
496 ## Intel 386 machines where we do care about the manufacturer
497 i[345]86-intsys-sysv* )
498 machine=is386 opsys=usg5-2-2
499 ;;
501 ## Prime EXL
502 i[345]86-prime-sysv* )
503 machine=i386 opsys=usg5-3
504 ;;
506 ## Sequent Symmetry running Dynix
507 i[345]86-sequent-bsd* )
508 machine=symmetry opsys=bsd4-3
509 ;;
511 ## Sequent Symmetry running DYNIX/ptx
512 ## Use the old cpp rather than the newer ANSI one.
513 i[345]86-sequent-ptx* )
514 machine=sequent-ptx opsys=ptx
515 NON_GNU_CPP="/lib/cpp"
516 ;;
518 ## Unspecified sysv on an ncr machine defaults to svr4.2.
519 ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
520 i[345]86-ncr-sysv* )
521 machine=ncr386 opsys=usg5-4-2
522 ;;
524 ## Intel Paragon OSF/1
525 i860-intel-osf1* )
526 machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
527 ;;
529 ## Intel 860
530 i860-*-sysv4* )
531 machine=i860 opsys=usg5-4
532 NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
533 NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
534 ;;
536 ## Masscomp machines
537 m68*-masscomp-rtu* )
538 machine=masscomp opsys=rtu
539 ;;
541 ## Megatest machines
542 m68*-megatest-bsd* )
543 machine=mega68 opsys=bsd4-2
544 ;;
546 ## Workstations sold by MIPS
547 ## This is not necessarily all workstations using the MIPS processor -
548 ## Irises are produced by SGI, and DECstations by DEC.
550 ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
551 ## and usg5-2-2 and bsd4-3 as possible OS files. The only guidance
552 ## it gives for choosing between the alternatives seems to be "Use
553 ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
554 ## the BSD world." I'll assume that these are instructions for
555 ## handling two odd situations, and that every other situation
556 ## should use mips.h and usg5-2-2, they being listed first.
557 mips-mips-usg* )
558 machine=mips4
559 ## Fall through to the general code at the bottom to decide on the OS.
560 ;;
561 mips-mips-riscos4* )
562 machine=mips4 opsys=bsd4-3
563 NON_GNU_CC="cc -systype bsd43"
564 NON_GNU_CPP="cc -systype bsd43 -E"
565 ;;
566 mips-mips-riscos5* )
567 machine=mips4 opsys=riscos5
568 NON_GNU_CC="cc -systype bsd43"
569 NON_GNU_CPP="cc -systype bsd43 -E"
570 ;;
571 mips-mips-bsd* )
572 machine=mips opsys=bsd4-3
573 ;;
574 mips-mips-* )
575 machine=mips opsys=usg5-2-2
576 ;;
578 ## NeXT
579 m68*-next-* | m68k-*-nextstep* )
580 machine=m68k opsys=nextstep
581 ;;
583 ## The complete machine from National Semiconductor
584 ns32k-ns-genix* )
585 machine=ns32000 opsys=usg5-2
586 ;;
588 ## NCR machines
589 m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
590 machine=tower32 opsys=usg5-2-2
591 ;;
592 m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
593 machine=tower32v3 opsys=usg5-3
594 ;;
596 ## Nixdorf Targon 31
597 m68*-nixdorf-sysv* )
598 machine=targon31 opsys=usg5-2-2
599 ;;
601 ## Nu (TI or LMI)
602 m68*-nu-sysv* )
603 machine=nu opsys=usg5-2
604 ;;
606 ## Plexus
607 m68*-plexus-sysv* )
608 machine=plexus opsys=usg5-2
609 ;;
611 ## Pyramid machines
612 ## I don't really have any idea what sort of processor the Pyramid has,
613 ## so I'm assuming it is its own architecture.
614 pyramid-pyramid-bsd* )
615 machine=pyramid opsys=bsd4-2
616 ;;
618 ## Sequent Balance
619 ns32k-sequent-bsd4.2* )
620 machine=sequent opsys=bsd4-2
621 ;;
622 ns32k-sequent-bsd4.3* )
623 machine=sequent opsys=bsd4-3
624 ;;
626 ## Siemens Nixdorf
627 mips-siemens-sysv* | mips-sni-sysv*)
628 machine=mips-siemens opsys=usg5-4
629 NON_GNU_CC=/usr/ccs/bin/cc
630 NON_GNU_CPP=/usr/ccs/lib/cpp
631 ;;
633 ## Silicon Graphics machines
634 ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
635 m68*-sgi-iris3.5* )
636 machine=irist opsys=iris3-5
637 ;;
638 m68*-sgi-iris3.6* | m68*-sgi-iris*)
639 machine=irist opsys=iris3-6
640 ;;
641 ## Iris 4D
642 mips-sgi-irix3* )
643 machine=iris4d opsys=irix3-3
644 ;;
645 mips-sgi-irix4* )
646 machine=iris4d opsys=irix4-0
647 ;;
648 mips-sgi-irix6* )
649 machine=iris4d opsys=irix6-0 NON_GNU_CPP=/lib/cpp
650 ;;
651 mips-sgi-irix5.[01]* )
652 machine=iris4d opsys=irix5-0
653 ;;
654 mips-sgi-irix5* | mips-sgi-irix* )
655 machine=iris4d opsys=irix5-2
656 ;;
658 ## SONY machines
659 m68*-sony-bsd4.2* )
660 machine=news opsys=bsd4-2
661 ;;
662 m68*-sony-bsd4.3* )
663 machine=news opsys=bsd4-3
664 ;;
665 m68*-sony-newsos3* | m68*-sony-news3*)
666 machine=news opsys=bsd4-3
667 ;;
668 mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
669 machine=news-risc opsys=bsd4-3
670 ;;
671 mips-sony-news* )
672 machine=news-risc opsys=newsos5
673 ;;
675 ## Stride
676 m68*-stride-sysv* )
677 machine=stride opsys=usg5-2
678 ;;
680 ## Suns
681 *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
682 | i[345]86-*-solaris2* | i[345]86-*-sunos5* | powerpc*-*-solaris2* \
683 | rs6000-*-solaris2*)
684 case "${canonical}" in
685 m68*-sunos1* ) machine=sun1 ;;
686 m68*-sunos2* ) machine=sun2 ;;
687 m68* ) machine=sun3 ;;
688 i[345]86-sun-sunos[34]* ) machine=sun386 ;;
689 i[345]86-*-* ) machine=intel386 ;;
690 powerpc* | rs6000* ) machine=rs6000 ;;
691 sparc* ) machine=sparc ;;
692 * ) unported=yes ;;
693 esac
694 case "${canonical}" in
695 ## The Sun386 didn't get past 4.0.
696 i[345]86-*-sunos4 ) opsys=sunos4-0 ;;
697 *-sunos4.0* ) opsys=sunos4-0 ;;
698 *-sunos4.1.[3-9]* | *-sunos4shr*)
699 opsys=sunos4shr
700 NON_GNU_CPP=/usr/lib/cpp
701 ;;
702 *-sunos4.1.[3-9]*-noshare )
703 opsys=sunos4-1-3
704 NON_GNU_CPP=/usr/lib/cpp
705 NON_GCC_TEST_OPTIONS=-Bstatic
706 GCC_TEST_OPTIONS=-static
707 ;;
708 *-sunos4* | *-sunos )
709 opsys=sunos4-1
710 NON_GCC_TEST_OPTIONS=-Bstatic
711 GCC_TEST_OPTIONS=-static
712 ;;
713 *-sunos5.3* | *-solaris2.3* )
714 opsys=sol2-3
715 NON_GNU_CPP=/usr/ccs/lib/cpp
716 ;;
717 *-sunos5.4* | *-solaris2.4* )
718 opsys=sol2-4
719 NON_GNU_CPP=/usr/ccs/lib/cpp
720 RANLIB="ar -ts"
721 ;;
722 *-sunos5.5* | *-solaris2.5* )
723 opsys=sol2-5
724 NON_GNU_CPP=/usr/ccs/lib/cpp
725 RANLIB="ar -ts"
726 ;;
727 *-sunos5* | *-solaris* )
728 opsys=sol2-4
729 NON_GNU_CPP=/usr/ccs/lib/cpp
730 ;;
731 * ) opsys=bsd4-2 ;;
732 esac
733 ## Watch out for a compiler that we know will not work.
734 case "${canonical}" in
735 *-solaris* | *-sunos5* )
736 if [ "x$CC" = x/usr/ucb/cc ]; then
737 ## /usr/ucb/cc doesn't work;
738 ## we should find some other compiler that does work.
739 unset CC
740 fi
741 ;;
742 *) ;;
743 esac
744 ;;
745 sparc-*-nextstep* )
746 machine=sparc opsys=nextstep
747 ;;
749 ## Tadpole 68k
750 m68*-tadpole-sysv* )
751 machine=tad68k opsys=usg5-3
752 ;;
754 ## Tahoe machines
755 tahoe-tahoe-bsd4.2* )
756 machine=tahoe opsys=bsd4-2
757 ;;
758 tahoe-tahoe-bsd4.3* )
759 machine=tahoe opsys=bsd4-3
760 ;;
762 ## Tandem Integrity S2
763 mips-tandem-sysv* )
764 machine=tandem-s2 opsys=usg5-3
765 ;;
767 ## Tektronix XD88
768 m88k-tektronix-sysv3* )
769 machine=tekxd88 opsys=usg5-3
770 ;;
772 ## Tektronix 16000 box (6130?)
773 ns16k-tektronix-bsd* )
774 machine=ns16000 opsys=bsd4-2
775 ;;
776 ## Tektronix 4300
777 ## src/m/tek4300.h hints that this is a m68k machine.
778 m68*-tektronix-bsd* )
779 machine=tek4300 opsys=bsd4-3
780 ;;
782 ## Titan P2 or P3
783 ## We seem to have lost the machine-description file titan.h!
784 titan-titan-sysv* )
785 machine=titan opsys=usg5-3
786 ;;
788 ## Ustation E30 (SS5E)
789 m68*-unisys-uniplus* )
790 machine=ustation opsystem=unipl5-2
791 ;;
793 ## Vaxen.
794 vax-dec-* )
795 machine=vax
796 case "${canonical}" in
797 *-bsd4.1* ) opsys=bsd4-1 ;;
798 *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* ) opsys=bsd4-2 ;;
799 *-bsd4.3* | *-ultrix* ) opsys=bsd4-3 ;;
800 *-sysv[01]* | *-sysvr[01]* ) opsys=usg5-0 ;;
801 *-sysv2* | *-sysvr2* ) opsys=usg5-2 ;;
802 *-vms* ) opsys=vms ;;
803 * ) unported=yes
804 esac
805 ;;
807 ## Whitechapel MG1
808 ns16k-whitechapel-* )
809 machine=mg1
810 ## We don't know what sort of OS runs on these; we'll let the
811 ## operating system guessing code below try.
812 ;;
814 ## Wicat
815 m68*-wicat-sysv* )
816 machine=wicat opsys=usg5-2
817 ;;
819 ## Intel 386 machines where we don't care about the manufacturer
820 i[345]86-*-* )
821 machine=intel386
822 case "${canonical}" in
823 *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
824 *-isc2.2* ) opsys=isc2-2 ;;
825 *-isc4.0* ) opsys=isc4-0 ;;
826 *-isc4.* ) opsys=isc4-1
827 GCC_TEST_OPTIONS=-posix
828 NON_GCC_TEST_OPTIONS=-Xp
829 ;;
830 *-isc* ) opsys=isc3-0 ;;
831 *-esix5* ) opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
832 *-esix* ) opsys=esix ;;
833 *-xenix* ) opsys=xenix ;;
834 *-linux* ) opsys=linux ;;
835 *-sco3.2v4* ) opsys=sco4 ; NON_GNU_CPP=/lib/cpp ;;
836 *-bsd386* | *-bsdi1* ) opsys=bsd386 ;;
837 *-bsdi2* ) opsys=bsdos2 ;;
838 *-386bsd* ) opsys=386bsd ;;
839 *-freebsd* ) opsys=freebsd ;;
840 *-nextstep* ) opsys=nextstep ;;
841 ## Otherwise, we'll fall through to the generic opsys code at the bottom.
842 esac
843 ;;
845 ## Linux/68k
846 m68k-*-linux* )
847 machine=m68k opsys=linux
848 ;;
850 * )
851 unported=yes
852 ;;
853 esac
855 ### If the code above didn't choose an operating system, just choose
856 ### an operating system based on the configuration name. You really
857 ### only want to use this when you have no idea what the right
858 ### operating system is; if you know what operating systems a machine
859 ### runs, it's cleaner to make it explicit in the case statement
860 ### above.
861 if test x"${opsys}" = x; then
862 case "${canonical}" in
863 *-gnu* ) opsys=gnu ;;
864 *-bsd4.[01] ) opsys=bsd4-1 ;;
865 *-bsd4.2 ) opsys=bsd4-2 ;;
866 *-bsd4.3 ) opsys=bsd4-3 ;;
867 *-sysv0 | *-sysvr0 ) opsys=usg5-0 ;;
868 *-sysv2 | *-sysvr2 ) opsys=usg5-2 ;;
869 *-sysv2.2 | *-sysvr2.2 ) opsys=usg5-2-2 ;;
870 *-sysv3* | *-sysvr3* ) opsys=usg5-3 ;;
871 *-sysv4.1* | *-sysvr4.1* )
872 NON_GNU_CPP=/usr/lib/cpp
873 opsys=usg5-4 ;;
874 *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
875 if [ x$NON_GNU_CPP = x ]; then
876 NON_GNU_CPP=/usr/ccs/lib/cpp
877 fi
878 opsys=usg5-4-2 ;;
879 *-sysv4* | *-sysvr4* ) opsys=usg5-4 ;;
880 * )
881 unported=yes
882 ;;
883 esac
884 fi
886 if test "x$RANLIB" = x; then
887 RANLIB=ranlib
888 fi
890 changequote([, ])dnl
892 if test $unported = yes; then
893 AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
894 Check \`etc/MACHINES' for recognized configuration names.])
895 fi
897 machfile="m/${machine}.h"
898 opsysfile="s/${opsys}.h"
901 #### Choose a compiler.
902 test -n "$CC" && cc_specified=yes
904 # Save the value of CFLAGS that the user specified.
905 SPECIFIED_CFLAGS="$CFLAGS"
907 case ${with_gcc} in
908 "yes" ) CC="gcc" GCC=yes ;;
909 "no" ) : ${CC=cc} ;;
910 * ) AC_PROG_CC
911 esac
913 # On Suns, sometimes $CPP names a directory.
914 if test -n "$CPP" && test -d "$CPP"; then
915 CPP=
916 fi
918 #### Some systems specify a CPP to use unless we are using GCC.
919 #### Now that we know whether we are using GCC, we can decide whether
920 #### to use that one.
921 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
922 then
923 CPP="$NON_GNU_CPP"
924 fi
926 #### Some systems specify a CC to use unless we are using GCC.
927 #### Now that we know whether we are using GCC, we can decide whether
928 #### to use that one.
929 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
930 test x$cc_specified != xyes
931 then
932 CC="$NON_GNU_CC"
933 fi
935 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
936 then
937 CC="$CC $GCC_TEST_OPTIONS"
938 fi
940 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
941 then
942 CC="$CC $NON_GCC_TEST_OPTIONS"
943 fi
945 #### Some other nice autoconf tests. If you add a test here which
946 #### should make an entry in src/config.h, don't forget to add an
947 #### #undef clause to src/config.h.in for autoconf to modify.
949 dnl checks for programs
950 AC_PROG_LN_S
951 AC_PROG_CPP
952 AC_PROG_INSTALL
953 AC_PROG_YACC
955 dnl checks for Unix variants
956 AC_AIX
958 dnl checks for header files
959 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h)
960 AC_HEADER_STDC
961 AC_HEADER_TIME
962 AC_DECL_SYS_SIGLIST
964 dnl Some systems have utime.h but don't declare the struct anyplace.
965 AC_MSG_CHECKING(for struct utimbuf)
966 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
967 #include <sys/time.h>
968 #include <time.h>
969 #else
970 #ifdef HAVE_SYS_TIME_H
971 #include <sys/time.h>
972 #else
973 #include <time.h>
974 #endif
975 #endif
976 #ifdef HAVE_UTIME_H
977 #include <utime.h>
978 #endif], [static struct utimbuf x; x.actime = x.modtime;],
979 [AC_MSG_RESULT(yes)
980 AC_DEFINE(HAVE_STRUCT_UTIMBUF)],
981 AC_MSG_RESULT(no))
983 dnl checks for typedefs
984 AC_TYPE_SIGNAL
986 AC_MSG_CHECKING(for struct timeval)
987 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
988 #include <sys/time.h>
989 #include <time.h>
990 #else
991 #ifdef HAVE_SYS_TIME_H
992 #include <sys/time.h>
993 #else
994 #include <time.h>
995 #endif
996 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
997 [AC_MSG_RESULT(yes)
998 HAVE_TIMEVAL=yes
999 AC_DEFINE(HAVE_TIMEVAL)],
1000 [AC_MSG_RESULT(no)
1001 HAVE_TIMEVAL=no])
1003 dnl checks for structure members
1004 AC_STRUCT_TM
1005 AC_STRUCT_TIMEZONE
1007 dnl checks for compiler characteristics
1008 AC_C_CONST
1010 dnl check for Make feature
1011 AC_PROG_MAKE_SET
1013 dnl checks for operating system services
1014 AC_SYS_LONG_FILE_NAMES
1016 #### Choose a window system.
1018 AC_PATH_X
1019 if test "$no_x" = yes; then
1020 window_system=none
1021 else
1022 window_system=x11
1023 fi
1025 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1026 LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1027 LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1028 fi
1029 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1030 C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1031 fi
1033 if test x"${x_includes}" = x; then
1034 bitmapdir=/usr/include/X11/bitmaps
1035 else
1036 # accumulate include directories that have X11 bitmap subdirectories
1037 bmd_acc="dummyval"
1038 for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1039 if test -d "${bmd}/X11/bitmaps"; then
1040 bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1041 elif test -d "${bmd}/bitmaps"; then
1042 bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1043 fi
1044 done
1045 if test ${bmd_acc} != "dummyval"; then
1046 bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1047 fi
1048 fi
1050 case "${window_system}" in
1051 x11 )
1052 HAVE_X_WINDOWS=yes
1053 HAVE_X11=yes
1054 case "${with_x_toolkit}" in
1055 athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1056 motif ) USE_X_TOOLKIT=MOTIF ;;
1057 dnl open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1058 no ) USE_X_TOOLKIT=none ;;
1059 dnl If user did not say whether to use a toolkit,
1060 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1061 * ) USE_X_TOOLKIT=maybe ;;
1062 esac
1063 ;;
1064 none )
1065 HAVE_X_WINDOWS=no
1066 HAVE_X11=no
1067 USE_X_TOOLKIT=none
1068 ;;
1069 esac
1071 ### If we're using X11, we should use the X menu package.
1072 HAVE_MENUS=no
1073 case ${HAVE_X11} in
1074 yes ) HAVE_MENUS=yes ;;
1075 esac
1077 if test "${opsys}" = "hpux9"; then
1078 case "${x_libraries}" in
1079 *X11R4* )
1080 opsysfile="s/hpux9-x11r4.h"
1081 ;;
1082 esac
1083 fi
1085 if test "${opsys}" = "hpux9shr"; then
1086 case "${x_libraries}" in
1087 *X11R4* )
1088 opsysfile="s/hpux9shxr4.h"
1089 ;;
1090 esac
1091 fi
1093 #### Extract some information from the operating system and machine files.
1095 AC_CHECKING([the machine- and system-dependent files to find out
1096 - which libraries the lib-src programs will want, and
1097 - whether the GNU malloc routines are usable])
1099 ### First figure out CFLAGS (which we use for running the compiler here)
1100 ### and REAL_CFLAGS (which we use for real compilation).
1101 ### The two are the same except on a few systems, where they are made
1102 ### different to work around various lossages. For example,
1103 ### GCC 2.5 on Linux needs them to be different because it treats -g
1104 ### as implying static linking.
1106 ### If the CFLAGS env var is specified, we use that value
1107 ### instead of the default.
1109 ### It's not important that this name contain the PID; you can't run
1110 ### two configures in the same directory and have anything work
1111 ### anyway.
1112 tempcname="conftest.c"
1114 echo '
1115 #include "'${srcdir}'/src/'${opsysfile}'"
1116 #include "'${srcdir}'/src/'${machfile}'"
1117 #ifndef LIBS_MACHINE
1118 #define LIBS_MACHINE
1119 #endif
1120 #ifndef LIBS_SYSTEM
1121 #define LIBS_SYSTEM
1122 #endif
1123 #ifndef C_SWITCH_SYSTEM
1124 #define C_SWITCH_SYSTEM
1125 #endif
1126 #ifndef C_SWITCH_MACHINE
1127 #define C_SWITCH_MACHINE
1128 #endif
1129 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1130 configure___ c_switch_system=C_SWITCH_SYSTEM
1131 configure___ c_switch_machine=C_SWITCH_MACHINE
1133 #ifndef LIB_X11_LIB
1134 #define LIB_X11_LIB -lX11
1135 #endif
1137 #ifndef LIBX11_MACHINE
1138 #define LIBX11_MACHINE
1139 #endif
1141 #ifndef LIBX11_SYSTEM
1142 #define LIBX11_SYSTEM
1143 #endif
1144 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1146 #ifdef UNEXEC
1147 configure___ unexec=UNEXEC
1148 #else
1149 configure___ unexec=unexec.o
1150 #endif
1152 #ifdef SYSTEM_MALLOC
1153 configure___ system_malloc=yes
1154 #else
1155 configure___ system_malloc=no
1156 #endif
1158 #ifndef C_DEBUG_SWITCH
1159 #define C_DEBUG_SWITCH -g
1160 #endif
1162 #ifndef C_OPTIMIZE_SWITCH
1163 #define C_OPTIMIZE_SWITCH -O
1164 #endif
1166 #ifdef THIS_IS_CONFIGURE
1168 /* Get the CFLAGS for tests in configure. */
1169 #ifdef __GNUC__
1170 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1171 #else
1172 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1173 #endif
1175 #else /* not THIS_IS_CONFIGURE */
1177 /* Get the CFLAGS for real compilation. */
1178 #ifdef __GNUC__
1179 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1180 #else
1181 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1182 #endif
1184 #endif /* not THIS_IS_CONFIGURE */
1185 ' > ${tempcname}
1187 # The value of CPP is a quoted variable reference, so we need to do this
1188 # to get its actual value...
1189 CPP=`eval "echo $CPP"`
1190 changequote(, )dnl
1191 eval `${CPP} -Isrc ${tempcname} \
1192 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1193 if test "x$SPECIFIED_CFLAGS" = x; then
1194 eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1195 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1196 else
1197 REAL_CFLAGS="$CFLAGS"
1198 fi
1199 changequote([, ])dnl
1200 rm ${tempcname}
1202 ### Compute the unexec source name from the object name.
1203 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1205 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1206 # Assume not, until told otherwise.
1207 GNU_MALLOC=yes
1208 if test "${system_malloc}" = "yes"; then
1209 GNU_MALLOC=no
1210 GNU_MALLOC_reason="
1211 (The GNU allocators don't work with this system configuration.)"
1212 fi
1214 if test x"${REL_ALLOC}" = x; then
1215 REL_ALLOC=${GNU_MALLOC}
1216 fi
1218 LISP_FLOAT_TYPE=yes
1221 #### Add the libraries to LIBS and check for some functions.
1223 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1224 LIBS="$libsrc_libs $LIBS"
1226 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1227 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1228 AC_CHECK_LIB(dnet, dnet_ntoa)
1229 dnl This causes -lresolv to get used in subsequent tests,
1230 dnl which causes failures on some systems such as HPUX 9.
1231 dnl AC_CHECK_LIB(resolv, gethostbyname)
1233 dnl FIXME replace main with a function we actually want from this library.
1234 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1236 AC_CHECK_LIB(pthreads, cma_open)
1238 AC_MSG_CHECKING(for XFree86)
1239 if test -d /usr/X386/include; then
1240 HAVE_XFREE386=yes
1241 : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1242 else
1243 HAVE_XFREE386=no
1244 fi
1245 AC_MSG_RESULT($HAVE_XFREE386)
1247 # Change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1248 # for the tests that follow. We set it back to REAL_CFLAGS later on.
1250 if test "${HAVE_X11}" = "yes"; then
1251 DEFS="$C_SWITCH_X_SITE $DEFS"
1252 LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1253 LIBS="$LIBX $LIBS"
1254 CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1256 # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1257 # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1258 # but it's more convenient here to set LD_RUN_PATH
1259 # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1260 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1261 LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1262 export LD_RUN_PATH
1263 fi
1265 if test "${opsys}" = "linux"; then
1266 AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1267 AC_TRY_LINK([],
1268 [XOpenDisplay ("foo");],
1269 [xlinux_first_failure=no],
1270 [xlinux_first_failure=yes])
1271 if test "${xlinux_first_failure}" = "yes"; then
1272 OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1273 OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1274 OLD_CPPFLAGS="$CPPFLAGS"
1275 OLD_LIBS="$LIBS"
1276 LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1277 C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1278 CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1279 LIBS="$LIBS -b i486-linuxaout"
1280 AC_TRY_LINK([],
1281 [XOpenDisplay ("foo");],
1282 [xlinux_second_failure=no],
1283 [xlinux_second_failure=yes])
1284 if test "${xlinux_second_failure}" = "yes"; then
1285 # If we get the same failure with -b, there is no use adding -b.
1286 # So take it out. This plays safe.
1287 LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1288 C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1289 CPPFLAGS="$OLD_CPPFLAGS"
1290 LIBS="$OLD_LIBS"
1291 AC_MSG_RESULT(no)
1292 else
1293 AC_MSG_RESULT(yes)
1294 fi
1295 else
1296 AC_MSG_RESULT(no)
1297 fi
1298 fi
1300 AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1301 XScreenNumberOfScreen XSetWMProtocols)
1302 fi
1304 if test "${window_system}" = "x11"; then
1305 AC_MSG_CHECKING(X11 version 6)
1306 AC_TRY_LINK([#include <X11/Xlib.h>],
1307 [#if XlibSpecificationRelease < 6
1308 fail;
1309 #endif
1310 ], [AC_MSG_RESULT(6)
1311 AC_DEFINE(HAVE_X11R6)],
1312 [AC_MSG_RESULT(not 6)])
1313 fi
1315 if test x"${USE_X_TOOLKIT}" = xmaybe; then
1316 AC_MSG_CHECKING(X11 version 5)
1317 AC_TRY_LINK([#include <X11/Xlib.h>],
1318 [#if XlibSpecificationRelease < 5
1319 fail;
1320 #endif
1321 ], [AC_MSG_RESULT(5, use toolkit)
1322 USE_X_TOOLKIT=LUCID
1323 AC_DEFINE(HAVE_X11R5)],
1324 [AC_MSG_RESULT(not 5, do not use toolkit)
1325 USE_X_TOOLKIT=none])
1326 fi
1328 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1330 if test "${USE_X_TOOLKIT}" != "none"; then
1331 AC_MSG_CHECKING(X11 toolkit version)
1332 AC_TRY_LINK([#include <X11/Intrinsic.h>],
1333 [#if XtSpecificationRelease < 6
1334 fail;
1335 #endif
1336 ], [AC_MSG_RESULT(6)
1337 AC_DEFINE(HAVE_X11XTR6)],
1338 [AC_MSG_RESULT(not 6)])
1340 dnl If using toolkit, check whether libXmu.a exists.
1341 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1342 OLDLIBS="$LIBS"
1343 LIBS="-lXt $LIBS"
1344 AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1345 LIBS="$OLDLIBS"
1346 fi
1348 # If netdb.h doesn't declare h_errno, we must declare it by hand.
1349 AC_MSG_CHECKING(whether netdb declares h_errno)
1350 AC_TRY_LINK([#include <netdb.h>],
1351 [return h_errno;],
1352 [AC_MSG_RESULT(yes)
1353 AC_DEFINE(HAVE_H_ERRNO)],
1354 [AC_MSG_RESULT(no)])
1356 AC_FUNC_ALLOCA
1358 # fmod, logb, and frexp are found in -lm on most systems.
1359 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
1360 AC_CHECK_LIB(m, sqrt(0.0) + t)
1361 AC_CHECK_FUNCS(gettimeofday gethostname dup2 rename closedir mkdir rmdir \
1362 random lrand48 bcopy bcmp logb frexp fmod ftime res_init setsid \
1363 strerror fpathconf select mktime eaccess getpagesize tzset)
1365 AC_MSG_CHECKING(whether localtime caches TZ)
1366 AC_CACHE_VAL(emacs_cv_localtime_cache,
1367 [if test $ac_cv_func_tzset = yes; then
1368 AC_TRY_RUN([#include <time.h>
1369 #if STDC_HEADERS
1370 # include <stdlib.h>
1371 #endif
1372 main()
1373 {
1374 time_t now = time ((time_t *) 0);
1375 int hour;
1376 if (putenv ("TZ=GMT0") != 0)
1377 exit (1);
1378 hour = localtime (&now)->tm_hour;
1379 if (putenv ("TZ=PST8") != 0)
1380 exit (1);
1381 exit (localtime (&now)->tm_hour == hour);
1382 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
1383 [# If we have tzset, assume the worst when cross-compiling.
1384 emacs_cv_localtime_cache=yes])
1385 else
1386 # If we lack tzset, report that localtime does not cache TZ,
1387 # since we can't invalidate the cache if we don't have tzset.
1388 emacs_cv_localtime_cache=no
1389 fi])dnl
1390 AC_MSG_RESULT($emacs_cv_localtime_cache)
1391 if test $emacs_cv_localtime_cache = yes; then
1392 AC_DEFINE(LOCALTIME_CACHE)
1393 fi
1395 if test "x$HAVE_TIMEVAL" = xyes; then
1396 AC_MSG_CHECKING(whether gettimeofday can't accept two arguments)
1397 AC_TRY_LINK([
1398 #ifdef TIME_WITH_SYS_TIME
1399 #include <sys/time.h>
1400 #include <time.h>
1401 #else
1402 #ifdef HAVE_SYS_TIME_H
1403 #include <sys/time.h>
1404 #else
1405 #include <time.h>
1406 #endif
1407 #endif
1408 ],
1409 [
1410 struct timeval time;
1411 struct timezone dummy;
1412 gettimeofday (&time, &dummy);
1413 ],
1414 [AC_MSG_RESULT(no)],
1415 [AC_MSG_RESULT(yes)
1416 AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)])
1417 fi
1419 ok_so_far=yes
1420 AC_CHECK_FUNC(socket, , ok_so_far=no)
1421 if test $ok_so_far = yes; then
1422 AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
1423 fi
1424 if test $ok_so_far = yes; then
1425 AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
1426 fi
1427 if test $ok_so_far = yes; then
1428 AC_DEFINE(HAVE_INET_SOCKETS)
1429 fi
1431 if test -f /usr/lpp/X11/bin/smt.exp; then
1432 AC_DEFINE(HAVE_AIX_SMT_EXP)
1433 fi
1435 # Set up the CFLAGS for real compilation, so we can substitute it.
1436 CFLAGS="$REAL_CFLAGS"
1438 changequote(, )dnl
1439 #### Find out which version of Emacs this is.
1440 version=`grep 'defconst[ ]*emacs-version' ${srcdir}/lisp/version.el \
1441 | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
1442 changequote([, ])dnl
1443 if test x"${version}" = x; then
1444 AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
1445 fi
1447 ### Specify what sort of things we'll be editing into Makefile and config.h.
1448 ### Use configuration here uncanonicalized to avoid exceeding size limits.
1449 AC_SUBST(version)
1450 AC_SUBST(configuration)
1451 AC_SUBST(canonical)
1452 AC_SUBST(srcdir)
1453 AC_SUBST(prefix)
1454 AC_SUBST(exec_prefix)
1455 AC_SUBST(bindir)
1456 AC_SUBST(datadir)
1457 AC_SUBST(sharedstatedir)
1458 AC_SUBST(libexecdir)
1459 AC_SUBST(mandir)
1460 AC_SUBST(infodir)
1461 AC_SUBST(lispdir)
1462 AC_SUBST(locallisppath)
1463 AC_SUBST(lisppath)
1464 AC_SUBST(etcdir)
1465 AC_SUBST(lockdir)
1466 AC_SUBST(archlibdir)
1467 AC_SUBST(docdir)
1468 AC_SUBST(bitmapdir)
1469 AC_SUBST(c_switch_system)
1470 AC_SUBST(c_switch_machine)
1471 AC_SUBST(LD_SWITCH_X_SITE)
1472 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1473 AC_SUBST(C_SWITCH_X_SITE)
1474 AC_SUBST(CFLAGS)
1475 AC_SUBST(X_TOOLKIT_TYPE)
1476 AC_SUBST(machfile)
1477 AC_SUBST(opsysfile)
1478 AC_SUBST(RANLIB)
1480 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "${canonical}")
1481 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}")
1482 AC_DEFINE_UNQUOTED(config_machfile, "${machfile}")
1483 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}")
1484 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE})
1485 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX})
1486 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE, ${C_SWITCH_X_SITE})
1487 AC_DEFINE_UNQUOTED(UNEXEC_SRC, ${UNEXEC_SRC})
1489 if test "${HAVE_X_WINDOWS}" = "yes" ; then
1490 AC_DEFINE(HAVE_X_WINDOWS)
1491 fi
1492 if test "${USE_X_TOOLKIT}" != "none" ; then
1493 AC_DEFINE(USE_X_TOOLKIT)
1494 fi
1495 if test "${HAVE_X11}" = "yes" ; then
1496 AC_DEFINE(HAVE_X11)
1497 fi
1498 if test "${HAVE_XFREE386}" = "yes" ; then
1499 AC_DEFINE(HAVE_XFREE386)
1500 fi
1501 if test "${HAVE_MENUS}" = "yes" ; then
1502 AC_DEFINE(HAVE_MENUS)
1503 fi
1504 if test "${GNU_MALLOC}" = "yes" ; then
1505 AC_DEFINE(GNU_MALLOC)
1506 fi
1507 if test "${REL_ALLOC}" = "yes" ; then
1508 AC_DEFINE(REL_ALLOC)
1509 fi
1510 if test "${LISP_FLOAT_TYPE}" = "yes" ; then
1511 AC_DEFINE(LISP_FLOAT_TYPE)
1512 fi
1514 #### Report on what we decided to do.
1515 echo "
1516 Configured for \`${canonical}'.
1518 Where should the build process find the source code? ${srcdir}
1519 What operating system and machine description files should Emacs use?
1520 \`${opsysfile}' and \`${machfile}'
1521 What compiler should emacs be built with? ${CC} ${CFLAGS}
1522 Should Emacs use the GNU version of malloc? ${GNU_MALLOC}${GNU_MALLOC_reason}
1523 Should Emacs use the relocating allocator for buffers? ${REL_ALLOC}
1524 What window system should Emacs use? ${window_system}
1525 What toolkit should Emacs use? ${USE_X_TOOLKIT}"
1527 if test -n "${x_includes}"; then
1528 echo " Where do we find X Windows header files? ${x_includes}"
1529 else
1530 echo " Where do we find X Windows header files? Standard dirs"
1531 fi
1532 if test -n "${x_libraries}"; then
1533 echo " Where do we find X Windows libraries? ${x_libraries}"
1534 else
1535 echo " Where do we find X Windows libraries? Standard dirs"
1536 fi
1538 echo
1540 # Remove any trailing slashes in these variables.
1541 changequote(, )dnl
1542 test "${prefix}" != NONE &&
1543 prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
1544 test "${exec_prefix}" != NONE &&
1545 exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
1546 changequote([, ])dnl
1548 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
1549 man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in, [
1551 ### Make the necessary directories, if they don't exist.
1552 for dir in cpp etc ; do
1553 test -d ${dir} || mkdir ${dir}
1554 done
1556 # Build src/Makefile from ${srcdir}/src/Makefile.c
1557 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
1558 # This must be done after src/config.h is built, since we rely on that file.
1560 changequote(, )dnl The horror, the horror.
1561 # Now get this: Some word that is part of the ${srcdir} directory name
1562 # or the ${configuration} value might, just might, happen to be an
1563 # identifier like `sun4' or `i386' or something, and be predefined by
1564 # the C preprocessor to some helpful value like 1, or maybe the empty
1565 # string. Needless to say consequent macro substitutions are less
1566 # than conducive to the makefile finding the correct directory.
1567 undefs="`echo $top_srcdir $configuration $canonical |
1568 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/ *$//' \
1569 -e 's/ */ -U/g' -e 's/-U[0-9][^ ]*//g' \
1570 `"
1571 changequote([, ])dnl
1573 echo creating lib-src/Makefile
1574 ( cd lib-src
1575 rm -f junk.c junk1.c junk2.c
1576 sed -e '/start of cpp stuff/q' \
1577 < Makefile.c > junk1.c
1578 sed -e '1,/start of cpp stuff/d'\
1579 -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1580 < Makefile.c > junk.c
1581 $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1582 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
1583 cat junk1.c junk2.c > Makefile.new
1584 rm -f junk.c junk1.c junk2.c
1585 chmod 444 Makefile.new
1586 mv -f Makefile.new Makefile
1587 )
1589 echo creating src/Makefile
1590 ( cd src
1591 rm -f junk.c junk1.c junk2.c
1592 sed -e '/start of cpp stuff/q' \
1593 < Makefile.c > junk1.c
1594 sed -e '1,/start of cpp stuff/d'\
1595 -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1596 < Makefile.c > junk.c
1597 $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1598 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
1599 cat junk1.c junk2.c > Makefile.new
1600 rm -f junk.c junk1.c junk2.c
1601 chmod 444 Makefile.new
1602 mv -f Makefile.new Makefile
1603 )
1605 if test ! -f src/.gdbinit && test -f $top_srcdir/src/.gdbinit; then
1606 echo creating src/.gdbinit
1607 echo source $top_srcdir/src/.gdbinit > src/.gdbinit
1608 fi
1610 ], [CPP="$CPP" CPPFLAGS="$CPPFLAGS"])