lisp/saveplace.el

   1 ;;; saveplace.el --- automatically save place in files
   2
   3 ;; Copyright (C) 1993-1994, 2001-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Karl Fogel <kfogel@red-bean.com>
   6 ;; Maintainer: FSF
   7 ;; Created: July, 1993
   8 ;; Keywords: bookmarks, placeholders
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Automatically save place in files, so that visiting them later
  28 ;; (even during a different Emacs session) automatically moves point
  29 ;; to the saved position, when the file is first found.  Uses the
  30 ;; value of buffer-local variable save-place to determine whether to
  31 ;; save position or not.
  32 ;;
  33 ;; Thanks to Stefan Schoef, who sent a patch with the
  34 ;; `save-place-version-control' stuff in it.
  35
  36 ;;; Code:
  37
  38 ;; this is what I was using during testing:
  39 ;; (define-key ctl-x-map "p" 'toggle-save-place-globally)
  40
  41 (defgroup save-place nil
  42   "Automatically save place in files."
  43   :group 'data)
  44
  45
  46 (defvar save-place-alist nil
  47   "Alist of saved places to go back to when revisiting files.
  48 Each element looks like (FILENAME . POSITION);
  49 visiting file FILENAME goes automatically to position POSITION
  50 rather than the beginning of the buffer.
  51 This alist is saved between Emacs sessions.")
  52
  53 (defcustom save-place nil
  54   "Non-nil means automatically save place in each file.
  55 This means when you visit a file, point goes to the last place
  56 where it was when you previously visited the same file.
  57 This variable is automatically buffer-local.
  58
  59 If you wish your place in any file to always be automatically saved,
  60 simply put this in your `~/.emacs' file:
  61
  62 \(setq-default save-place t)
  63 \(require 'saveplace)
  64
  65 or else use the Custom facility to set this option."
  66   :type 'boolean
  67   :require 'saveplace
  68   :group 'save-place)
  69
  70 (make-variable-buffer-local 'save-place)
  71
  72 (defcustom save-place-file (convert-standard-filename "~/.emacs-places")
  73   "Name of the file that records `save-place-alist' value."
  74   :type 'file
  75   :group 'save-place)
  76
  77 (defcustom save-place-version-control nil
  78   "Controls whether to make numbered backups of master save-place file.
  79 It can have four values: t, nil, `never', and `nospecial'.  The first
  80 three have the same meaning that they do for the variable
  81 `version-control', and the final value `nospecial' means just use the
  82 value of `version-control'."
  83   :type '(radio (const :tag "Unconditionally" t)
  84                 (const :tag "For VC Files" nil)
  85                 (const never)
  86                 (const :tag "Use value of `version-control'" nospecial))
  87   :group 'save-place)
  88
  89 (defvar save-place-loaded nil
  90   "Non-nil means that the `save-place-file' has been loaded.")
  91
  92 (defcustom save-place-limit 400
  93   "Maximum number of entries to retain in the list; nil means no limit."
  94   :version "24.1"                       ; nil -> 400
  95   :type '(choice (integer :tag "Entries" :value 1)
  96                  (const :tag "No Limit" nil))
  97   :group 'save-place)
  98
  99 (defcustom save-place-forget-unreadable-files t
 100   "Non-nil means forget place in unreadable files.
 101
 102 The filenames in `save-place-alist' that do not match
 103 `save-place-skip-check-regexp' are filtered through
 104 `file-readable-p'. if nil, their alist entries are removed.
 105
 106 You may do this anytime by calling the complementary function,
 107 `save-place-forget-unreadable-files'.  When this option is turned on,
 108 this happens automatically before saving `save-place-alist' to
 109 `save-place-file'."
 110   :type 'boolean :group 'save-place)
 111
 112 (defcustom save-place-save-skipped t
 113   "If non-nil, remember files matching `save-place-skip-check-regexp'.
 114
 115 When filtering `save-place-alist' for unreadable files, some will not
 116 be checked, based on said regexp, and instead saved or forgotten based
 117 on this flag."
 118   :type 'boolean :group 'save-place)
 119
 120 (defcustom save-place-skip-check-regexp
 121   ;; thanks to ange-ftp-name-format
 122   "\\`/\\(?:cdrom\\|floppy\\|mnt\\|\\(?:[^@/:]*@\\)?[^@/:]*[^@/:.]:\\)"
 123   "Regexp whose file names shall not be checked for readability.
 124
 125 When forgetting unreadable files, file names matching this regular
 126 expression shall not be checked for readability, but instead be
 127 subject to `save-place-save-skipped'.
 128
 129 Files for which such a check may be inconvenient include those on
 130 removable and network volumes."
 131   :type 'regexp :group 'save-place)
 132
 133 (defun toggle-save-place (&optional parg)
 134   "Toggle whether to save your place in this file between sessions.
 135 If this mode is enabled, point is recorded when you kill the buffer
 136 or exit Emacs.  Visiting this file again will go to that position,
 137 even in a later Emacs session.
 138
 139 If called with a prefix arg, the mode is enabled if and only if
 140 the argument is positive.
 141
 142 To save places automatically in all files, put this in your `.emacs' file:
 143
 144 \(setq-default save-place t\)"
 145   (interactive "P")
 146   (if (not buffer-file-name)
 147       (message "Buffer `%s' not visiting a file" (buffer-name))
 148     (if (and save-place (or (not parg) (<= parg 0)))
 149         (progn
 150           (message "No place will be saved in this file")
 151           (setq save-place nil))
 152       (message "Place will be saved")
 153       (setq save-place t))))
 154
 155 (defun save-place-to-alist ()
 156   ;; put filename and point in a cons box and then cons that onto the
 157   ;; front of the save-place-alist, if save-place is non-nil.
 158   ;; Otherwise, just delete that file from the alist.
 159   ;; first check to make sure alist has been loaded in from the master
 160   ;; file.  If not, do so, then feel free to modify the alist.  It
 161   ;; will be saved again when Emacs is killed.
 162   (or save-place-loaded (load-save-place-alist-from-file))
 163   (if buffer-file-name
 164       (progn
 165         (let ((cell (assoc buffer-file-name save-place-alist))
 166               (position (if (not (eq major-mode 'hexl-mode))
 167                             (point)
 168                           (with-no-warnings
 169                             (1+ (hexl-current-address))))))
 170           (if cell
 171               (setq save-place-alist (delq cell save-place-alist)))
 172           (if (and save-place
 173                    (not (= position 1)))  ;; Optimize out the degenerate case.
 174               (setq save-place-alist
 175                     (cons (cons buffer-file-name position)
 176                           save-place-alist)))))))
 177
 178 (defun save-place-forget-unreadable-files ()
 179   "Remove unreadable files from `save-place-alist'.
 180 For each entry in the alist, if `file-readable-p' returns nil for the
 181 filename, remove the entry.  Save the new alist \(as the first pair
 182 may have changed\) back to `save-place-alist'."
 183   (interactive)
 184   ;; the following was adapted from an in-place filtering function,
 185   ;; `filter-mod', used in the original.
 186   (unless (null save-place-alist)       ;says it better than `when'
 187     ;; first, check all except first
 188     (let ((fmprev save-place-alist) (fmcur (cdr save-place-alist)))
 189       (while fmcur                      ;not null
 190         ;; a value is only saved when it becomes FMPREV.
 191         (if (if (string-match save-place-skip-check-regexp (caar fmcur))
 192                 save-place-save-skipped
 193               (file-readable-p (caar fmcur)))
 194             (setq fmprev fmcur)
 195           (setcdr fmprev (cdr fmcur)))
 196         (setq fmcur (cdr fmcur))))
 197     ;; test first pair, keep it if OK, otherwise 2nd element, which
 198     ;; may be '()
 199     (unless (if (string-match save-place-skip-check-regexp
 200                               (caar save-place-alist))
 201                 save-place-save-skipped
 202               (file-readable-p (caar save-place-alist)))
 203       (setq save-place-alist (cdr save-place-alist)))))
 204
 205 (defun save-place-alist-to-file ()
 206   (let ((file (expand-file-name save-place-file))
 207         (coding-system-for-write 'utf-8))
 208     (with-current-buffer (get-buffer-create " *Saved Places*")
 209       (delete-region (point-min) (point-max))
 210       (when save-place-forget-unreadable-files
 211         (save-place-forget-unreadable-files))
 212       (insert (format ";;; -*- coding: %s -*-\n"
 213                       (symbol-name coding-system-for-write)))
 214       (let ((print-length nil)
 215             (print-level nil))
 216         (pp (sort save-place-alist
 217                   (lambda (a b) (string< (car a) (car b))))
 218             (current-buffer)))
 219       (let ((version-control
 220              (cond
 221               ((null save-place-version-control) nil)
 222               ((eq 'never save-place-version-control) 'never)
 223               ((eq 'nospecial save-place-version-control) version-control)
 224               (t
 225                t))))
 226         (condition-case nil
 227             ;; Don't use write-file; we don't want this buffer to visit it.
 228             (write-region (point-min) (point-max) file)
 229           (file-error (message "Saving places: can't write %s" file)))
 230         (kill-buffer (current-buffer))))))
 231
 232 (defun load-save-place-alist-from-file ()
 233   (if (not save-place-loaded)
 234       (progn
 235         (setq save-place-loaded t)
 236         (let ((file (expand-file-name save-place-file)))
 237           ;; make sure that the alist does not get overwritten, and then
 238           ;; load it if it exists:
 239           (if (file-readable-p file)
 240               ;; don't want to use find-file because we have been
 241               ;; adding hooks to it.
 242               (with-current-buffer (get-buffer-create " *Saved Places*")
 243                 (delete-region (point-min) (point-max))
 244                 (insert-file-contents file)
 245                 (goto-char (point-min))
 246                 (setq save-place-alist
 247                       (car (read-from-string
 248                             (buffer-substring (point-min) (point-max)))))
 249
 250                 ;; If there is a limit, and we're over it, then we'll
 251                 ;; have to truncate the end of the list:
 252                 (if save-place-limit
 253                     (if (<= save-place-limit 0)
 254                         ;; Zero gets special cased.  I'm not thrilled
 255                         ;; with this, but the loop for >= 1 is tight.
 256                         (setq save-place-alist nil)
 257                       ;; Else the limit is >= 1, so enforce it by
 258                       ;; counting and then `setcdr'ing.
 259                       (let ((s save-place-alist)
 260                             (count 1))
 261                         (while s
 262                           (if (>= count save-place-limit)
 263                               (setcdr s nil)
 264                             (setq count (1+ count)))
 265                           (setq s (cdr s))))))
 266
 267                 (kill-buffer (current-buffer))))
 268           nil))))
 269
 270 (defun save-places-to-alist ()
 271   ;; go through buffer-list, saving places to alist if save-place is
 272   ;; non-nil, deleting them from alist if it is nil.
 273   (let ((buf-list (buffer-list)))
 274     (while buf-list
 275       ;; put this into a save-excursion in case someone is counting on
 276       ;; another function in kill-emacs-hook to act on the last buffer
 277       ;; they were in:
 278       (with-current-buffer (car buf-list)
 279         ;; save-place checks buffer-file-name too, but we can avoid
 280         ;; overhead of function call by checking here too.
 281         (and buffer-file-name (save-place-to-alist))
 282         (setq buf-list (cdr buf-list))))))
 283
 284 (defun save-place-find-file-hook ()
 285   (or save-place-loaded (load-save-place-alist-from-file))
 286   (let ((cell (assoc buffer-file-name save-place-alist)))
 287     (if cell
 288         (progn
 289           (or revert-buffer-in-progress-p
 290               (goto-char (cdr cell)))
 291           ;; and make sure it will be saved again for later
 292           (setq save-place t)))))
 293
 294 (defun save-place-kill-emacs-hook ()
 295   ;; First update the alist.  This loads the old save-place-file if nec.
 296   (save-places-to-alist)
 297   ;; Now save the alist in the file, if we have ever loaded the file
 298   ;; (including just now).
 299   (if save-place-loaded
 300       (save-place-alist-to-file)))
 301
 302 (add-hook 'find-file-hook 'save-place-find-file-hook t)
 303
 304 (unless noninteractive
 305   (add-hook 'kill-emacs-hook 'save-place-kill-emacs-hook))
 306
 307 (add-hook 'kill-buffer-hook 'save-place-to-alist)
 308
 309 (provide 'saveplace) ; why not...
 310
 311 ;;; saveplace.el ends here