lisp/xml.el

   1 ;;; xml.el --- XML parser
   2
   3 ;; Copyright (C) 2000, 01, 03, 2004  Free Software Foundation, Inc.
   4
   5 ;; Author: Emmanuel Briot  <briot@gnat.com>
   6 ;; Maintainer: Mark A. Hershberger <mah@everybody.org>
   7 ;; Keywords: xml, data
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This file contains a somewhat incomplete non-validating XML parser.  It
  29 ;; parses a file, and returns a list that can be used internally by
  30 ;; any other Lisp libraries.
  31
  32 ;;; FILE FORMAT
  33
  34 ;; The document type declaration may either be ignored or (optionally)
  35 ;; parsed, but currently the parsing will only accept element
  36 ;; declarations.  The XML file is assumed to be well-formed.  In case
  37 ;; of error, the parsing stops and the XML file is shown where the
  38 ;; parsing stopped.
  39 ;;
  40 ;; It also knows how to ignore comments and processing instructions.
  41 ;;
  42 ;; The XML file should have the following format:
  43 ;;    <node1 attr1="name1" attr2="name2" ...>value
  44 ;;       <node2 attr3="name3" attr4="name4">value2</node2>
  45 ;;       <node3 attr5="name5" attr6="name6">value3</node3>
  46 ;;    </node1>
  47 ;; Of course, the name of the nodes and attributes can be anything.  There can
  48 ;; be any number of attributes (or none), as well as any number of children
  49 ;; below the nodes.
  50 ;;
  51 ;; There can be only top level node, but with any number of children below.
  52
  53 ;;; LIST FORMAT
  54
  55 ;; The functions `xml-parse-file', `xml-parse-region' and
  56 ;; `xml-parse-tag' return a list with the following format:
  57 ;;
  58 ;;    xml-list   ::= (node node ...)
  59 ;;    node       ::= (qname attribute-list . child_node_list)
  60 ;;    child_node_list ::= child_node child_node ...
  61 ;;    child_node ::= node | string
  62 ;;    qname      ::= (:namespace-uri . "name") | "name"
  63 ;;    attribute_list ::= ((qname . "value") (qname . "value") ...)
  64 ;;                       | nil
  65 ;;    string     ::= "..."
  66 ;;
  67 ;; Some macros are provided to ease the parsing of this list.
  68 ;; Whitespace is preserved.  Fixme: There should be a tree-walker that
  69 ;; can remove it.
  70
  71 ;; TODO:
  72 ;;  * xml:base, xml:space support
  73 ;;  * more complete DOCTYPE parsing
  74 ;;  * pi support
  75
  76 ;;; Code:
  77
  78 ;; Note that {buffer-substring,match-string}-no-properties were
  79 ;; formerly used in several places, but that removes composition info.
  80
  81 ;;*******************************************************************
  82 ;;**
  83 ;;**  Macros to parse the list
  84 ;;**
  85 ;;*******************************************************************
  86
  87 (defvar xml-entity-alist
  88   '(("lt"   . "<")
  89     ("gt"   . ">")
  90     ("apos" . "'")
  91     ("quot" . "\"")
  92     ("amp"  . "&"))
  93   "The defined entities.  Entities are added to this when the DTD is parsed.")
  94
  95 (defvar xml-sub-parser nil
  96   "Dynamically set this to a non-nil value if you want to parse an XML fragment.")
  97
  98 (defvar xml-validating-parser nil
  99   "Set to non-nil to get validity checking.")
 100
 101 (defsubst xml-node-name (node)
 102   "Return the tag associated with NODE.
 103 Without namespace-aware parsing, the tag is a symbol.
 104
 105 With namespace-aware parsing, the tag is a cons of a string
 106 representing the uri of the namespace with the local name of the
 107 tag.  For example,
 108
 109     <foo>
 110
 111 would be represented by
 112
 113     '(\"\" . \"foo\")."
 114
 115   (car node))
 116
 117 (defsubst xml-node-attributes (node)
 118   "Return the list of attributes of NODE.
 119 The list can be nil."
 120   (nth 1 node))
 121
 122 (defsubst xml-node-children (node)
 123   "Return the list of children of NODE.
 124 This is a list of nodes, and it can be nil."
 125   (cddr node))
 126
 127 (defun xml-get-children (node child-name)
 128   "Return the children of NODE whose tag is CHILD-NAME.
 129 CHILD-NAME should match the value returned by `xml-node-name'."
 130   (let ((match ()))
 131     (dolist (child (xml-node-children node))
 132       (if (and (listp child)
 133                (equal (xml-node-name child) child-name))
 134           (push child match)))
 135     (nreverse match)))
 136
 137 (defun xml-get-attribute-or-nil (node attribute)
 138   "Get from NODE the value of ATTRIBUTE.
 139 Return nil if the attribute was not found.
 140
 141 See also `xml-get-attribute'."
 142   (cdr (assoc attribute (xml-node-attributes node))))
 143
 144 (defsubst xml-get-attribute (node attribute)
 145   "Get from NODE the value of ATTRIBUTE.
 146 An empty string is returned if the attribute was not found.
 147
 148 See also `xml-get-attribute-or-nil'."
 149   (or (xml-get-attribute-or-nil node attribute) ""))
 150
 151 ;;*******************************************************************
 152 ;;**
 153 ;;**  Creating the list
 154 ;;**
 155 ;;*******************************************************************
 156
 157 ;;;###autoload
 158 (defun xml-parse-file (file &optional parse-dtd parse-ns)
 159   "Parse the well-formed XML file FILE.
 160 If FILE is already visited, use its buffer and don't kill it.
 161 Returns the top node with all its children.
 162 If PARSE-DTD is non-nil, the DTD is parsed rather than skipped.
 163 If PARSE-NS is non-nil, then QNAMES are expanded."
 164   (let ((keep))
 165     (if (get-file-buffer file)
 166         (progn
 167           (set-buffer (get-file-buffer file))
 168           (setq keep (point)))
 169       (let (auto-mode-alist)            ; no need for xml-mode
 170         (find-file file)))
 171
 172     (let ((xml (xml-parse-region (point-min)
 173                                  (point-max)
 174                                  (current-buffer)
 175                                  parse-dtd parse-ns)))
 176       (if keep
 177           (goto-char keep)
 178         (kill-buffer (current-buffer)))
 179       xml)))
 180
 181
 182 (let* ((start-chars (concat "[:alpha:]:_"))
 183        (name-chars  (concat "-[:digit:]." start-chars))
 184 ;;[3]           S          ::=          (#x20 | #x9 | #xD | #xA)+
 185        (whitespace  "[ \t\n\r]"))
 186 ;;[4] NameStartChar ::= ":" | [A-Z] | "_" | [a-z] | [#xC0-#xD6]
 187 ;;                      | [#xD8-#xF6] | [#xF8-#x2FF] | [#x370-#x37D] | [#x37F-#x1FFF]
 188 ;;                      | [#x200C-#x200D] | [#x2070-#x218F] | [#x2C00-#x2FEF] | [#x3001-#xD7FF]
 189 ;;                      | [#xF900-#xFDCF] | [#xFDF0-#xFFFD] | [#x10000-#xEFFFF]
 190   (defvar xml-name-start-char-re (concat "[" start-chars "]"))
 191 ;;[4a] NameChar ::= NameStartChar | "-" | "." | [0-9] | #xB7 | [#x0300-#x036F] | [#x203F-#x2040]
 192   (defvar xml-name-char-re       (concat "[" name-chars  "]"))
 193 ;;[5] Name     ::= NameStartChar (NameChar)*
 194   (defvar xml-name-re            (concat xml-name-start-char-re xml-name-char-re "*"))
 195 ;;[6] Names    ::= Name (#x20 Name)*
 196   (defvar xml-names-re           (concat xml-name-re "\\(?: " xml-name-re "\\)*"))
 197 ;;[7] Nmtoken ::= (NameChar)+
 198   (defvar xml-nmtoken-re         (concat xml-name-char-re "+"))
 199 ;;[8] Nmtokens ::= Nmtoken (#x20 Nmtoken)*
 200   (defvar xml-nmtokens-re        (concat xml-nmtoken-re "\\(?: " xml-name-re "\\)*"))
 201 ;;[66] CharRef ::= '&#' [0-9]+ ';' | '&#x' [0-9a-fA-F]+ ';'
 202   (defvar xml-char-ref-re        "\\(?:&#[0-9]+;\\|&#x[0-9a-fA-F]+;\\)")
 203 ;;[68] EntityRef   ::= '&' Name ';'
 204   (defvar xml-entity-ref         (concat "&" xml-name-re ";"))
 205 ;;[69] PEReference ::= '%' Name ';'
 206   (defvar xml-pe-reference-re    (concat "%" xml-name-re ";"))
 207 ;;[67] Reference   ::= EntityRef | CharRef
 208   (defvar xml-reference-re       (concat "\\(?:" xml-entity-ref "\\|" xml-char-ref-re "\\)"))
 209 ;;[9] EntityValue ::= '"' ([^%&"] | PEReference | Reference)* '"'
 210 ;;                 |  "'" ([^%&'] | PEReference | Reference)* "'"
 211   (defvar xml-entity-value-re    (concat "\\(?:\"\\(?:[^%&\"]\\|" xml-pe-reference-re
 212                                          "\\|" xml-reference-re "\\)*\"\\|'\\(?:[^%&']\\|"
 213                                          xml-pe-reference-re "\\|" xml-reference-re "\\)*'\\)")))
 214 ;;[75] ExternalID ::= 'SYSTEM' S SystemLiteral
 215 ;;                 | 'PUBLIC' S PubidLiteral S SystemLiteral
 216 ;;[76] NDataDecl ::=    S 'NDATA' S
 217 ;;[73] EntityDef  ::= EntityValue| (ExternalID NDataDecl?)
 218 ;;[71] GEDecl     ::= '<!ENTITY' S Name S EntityDef S? '>'
 219 ;;[74] PEDef      ::= EntityValue | ExternalID
 220 ;;[72] PEDecl     ::= '<!ENTITY' S '%' S Name S PEDef S? '>'
 221 ;;[70] EntityDecl ::= GEDecl | PEDecl
 222
 223 ;; Note that this is setup so that we can do whitespace-skipping with
 224 ;; `(skip-syntax-forward " ")', inter alia.  Previously this was slow
 225 ;; compared with `re-search-forward', but that has been fixed.  Also
 226 ;; note that the standard syntax table contains other characters with
 227 ;; whitespace syntax, like NBSP, but they are invalid in contexts in
 228 ;; which we might skip whitespace -- specifically, they're not
 229 ;; NameChars [XML 4].
 230
 231 (defvar xml-syntax-table
 232   (let ((table (make-syntax-table)))
 233     ;; Get space syntax correct per XML [3].
 234     (dotimes (c 31)
 235       (modify-syntax-entry c "." table)) ; all are space in standard table
 236     (dolist (c '(?\t ?\n ?\r))          ; these should be space
 237       (modify-syntax-entry c " " table))
 238     ;; For skipping attributes.
 239     (modify-syntax-entry ?\" "\"" table)
 240     (modify-syntax-entry ?' "\"" table)
 241     ;; Non-alnum name chars should be symbol constituents (`-' and `_'
 242     ;; are OK by default).
 243     (modify-syntax-entry ?. "_" table)
 244     (modify-syntax-entry ?: "_" table)
 245     ;; XML [89]
 246     (dolist (c '(#x00B7 #x02D0 #x02D1 #x0387 #x0640 #x0E46 #x0EC6 #x3005
 247                  #x3031 #x3032 #x3033 #x3034 #x3035 #x309D #x309E #x30FC
 248                  #x30FD #x30FE))
 249       (modify-syntax-entry (decode-char 'ucs c) "w" table))
 250     ;; Fixme: rest of [4]
 251     table)
 252   "Syntax table used by `xml-parse-region'.")
 253
 254 ;; XML [5]
 255 ;; Note that [:alpha:] matches all multibyte chars with word syntax.
 256 (eval-and-compile
 257   (defconst xml-name-regexp "[[:alpha:]_:][[:alnum:]._:-]*"))
 258
 259 ;; Fixme:  This needs re-writing to deal with the XML grammar properly, i.e.
 260 ;;   document    ::=    prolog element Misc*
 261 ;;   prolog    ::=    XMLDecl? Misc* (doctypedecl Misc*)?
 262
 263 ;;;###autoload
 264 (defun xml-parse-region (beg end &optional buffer parse-dtd parse-ns)
 265   "Parse the region from BEG to END in BUFFER.
 266 If BUFFER is nil, it defaults to the current buffer.
 267 Returns the XML list for the region, or raises an error if the region
 268 is not well-formed XML.
 269 If PARSE-DTD is non-nil, the DTD is parsed rather than skipped,
 270 and returned as the first element of the list.
 271 If PARSE-NS is non-nil, then QNAMES are expanded."
 272   (save-restriction
 273     (narrow-to-region beg end)
 274     ;; Use fixed syntax table to ensure regexp char classes and syntax
 275     ;; specs DTRT.
 276     (with-syntax-table (standard-syntax-table)
 277       (let ((case-fold-search nil)      ; XML is case-sensitive.
 278             xml result dtd)
 279         (save-excursion
 280           (if buffer
 281               (set-buffer buffer))
 282           (goto-char (point-min))
 283           (while (not (eobp))
 284             (if (search-forward "<" nil t)
 285                 (progn
 286                   (forward-char -1)
 287                   (setq result (xml-parse-tag parse-dtd parse-ns))
 288                   (if (and xml result (not xml-sub-parser))
 289                       ;;  translation of rule [1] of XML specifications
 290                       (error "XML: (Not Well-Formed) Only one root tag allowed")
 291                     (cond
 292                      ((null result))
 293                      ((and (listp (car result))
 294                            parse-dtd)
 295                       (setq dtd (car result))
 296                       (if (cdr result)  ; possible leading comment
 297                           (add-to-list 'xml (cdr result))))
 298                      (t
 299                       (add-to-list 'xml result)))))
 300               (goto-char (point-max))))
 301           (if parse-dtd
 302               (cons dtd (nreverse xml))
 303             (nreverse xml)))))))
 304
 305 (defun xml-maybe-do-ns (name default xml-ns)
 306   "Perform any namespace expansion.
 307 NAME is the name to perform the expansion on.
 308 DEFAULT is the default namespace.  XML-NS is a cons of namespace
 309 names to uris.  When namespace-aware parsing is off, then XML-NS
 310 is nil.
 311
 312 During namespace-aware parsing, any name without a namespace is
 313 put into the namespace identified by DEFAULT.  nil is used to
 314 specify that the name shouldn't be given a namespace."
 315   (if (consp xml-ns)
 316       (let* ((nsp (string-match ":" name))
 317              (lname (if nsp (substring name (match-end 0)) name))
 318              (prefix (if nsp (substring name 0 (match-beginning 0)) default))
 319              (special (and (string-equal lname "xmlns") (not prefix)))
 320              ;; Setting default to nil will insure that there is not
 321              ;; matching cons in xml-ns.  In which case we
 322              (ns (or (cdr (assoc (if special "xmlns" prefix)
 323                                  xml-ns))
 324                      "")))
 325         (cons ns (if special "" lname)))
 326     (intern name)))
 327
 328 (defun xml-parse-fragment (&optional parse-dtd parse-ns)
 329   "Parse xml-like fragments."
 330   (let ((xml-sub-parser t)
 331         children)
 332     (while (not (eobp))
 333       (let ((bit (xml-parse-tag
 334                   parse-dtd parse-ns)))
 335         (if children
 336             (setq children (append (list bit) children))
 337           (if (stringp bit)
 338               (setq children (list bit))
 339             (setq children bit)))))
 340     (reverse children)))
 341
 342 (defun xml-parse-tag (&optional parse-dtd parse-ns)
 343   "Parse the tag at point.
 344 If PARSE-DTD is non-nil, the DTD of the document, if any, is parsed and
 345 returned as the first element in the list.
 346 If PARSE-NS is non-nil, then QNAMES are expanded.
 347 Returns one of:
 348  - a list : the matching node
 349  - nil    : the point is not looking at a tag.
 350  - a pair : the first element is the DTD, the second is the node."
 351   (let ((xml-validating-parser (or parse-dtd xml-validating-parser))
 352         (xml-ns (if (consp parse-ns)
 353                     parse-ns
 354                   (if parse-ns
 355                       (list
 356                        ;; Default for empty prefix is no namespace
 357                        (cons ""      "")
 358                        ;; "xml" namespace
 359                        (cons "xml"   "http://www.w3.org/XML/1998/namespace")
 360                        ;; We need to seed the xmlns namespace
 361                        (cons "xmlns" "http://www.w3.org/2000/xmlns/"))))))
 362     (cond
 363      ;; Processing instructions (like the <?xml version="1.0"?> tag at the
 364      ;; beginning of a document).
 365      ((looking-at "<\\?")
 366       (search-forward "?>")
 367       (skip-syntax-forward " ")
 368       (xml-parse-tag parse-dtd xml-ns))
 369      ;;  Character data (CDATA) sections, in which no tag should be interpreted
 370      ((looking-at "<!\\[CDATA\\[")
 371       (let ((pos (match-end 0)))
 372         (unless (search-forward "]]>" nil t)
 373           (error "XML: (Not Well Formed) CDATA section does not end anywhere in the document"))
 374         (concat
 375          (buffer-substring pos (match-beginning 0))
 376          (xml-parse-string))))
 377      ;;  DTD for the document
 378      ((looking-at "<!DOCTYPE")
 379       (let ((dtd (xml-parse-dtd parse-ns)))
 380         (skip-syntax-forward " ")
 381         (if xml-validating-parser
 382             (cons dtd (xml-parse-tag nil xml-ns))
 383           (xml-parse-tag nil xml-ns))))
 384      ;;  skip comments
 385      ((looking-at "<!--")
 386       (search-forward "-->")
 387       nil)
 388      ;;  end tag
 389      ((looking-at "</")
 390       '())
 391      ;;  opening tag
 392      ((looking-at "<\\([^/>[:space:]]+\\)")
 393       (goto-char (match-end 1))
 394
 395       ;; Parse this node
 396       (let* ((node-name (match-string 1))
 397              ;; Parse the attribute list.
 398              (attrs (xml-parse-attlist xml-ns))
 399              children pos)
 400
 401         ;; add the xmlns:* attrs to our cache
 402         (when (consp xml-ns)
 403           (dolist (attr attrs)
 404             (when (and (consp (car attr))
 405                        (equal "http://www.w3.org/2000/xmlns/"
 406                               (caar attr)))
 407               (push (cons (cdar attr) (cdr attr))
 408                     xml-ns))))
 409
 410         (setq children (list attrs (xml-maybe-do-ns node-name "" xml-ns)))
 411
 412         ;; is this an empty element ?
 413         (if (looking-at "/>")
 414             (progn
 415               (forward-char 2)
 416               (nreverse children))
 417
 418           ;; is this a valid start tag ?
 419           (if (eq (char-after) ?>)
 420               (progn
 421                 (forward-char 1)
 422                 ;;  Now check that we have the right end-tag. Note that this
 423                 ;;  one might contain spaces after the tag name
 424                 (let ((end (concat "</" node-name "\\s-*>")))
 425                   (while (not (looking-at end))
 426                     (cond
 427                      ((looking-at "</")
 428                       (error "XML: (Not Well-Formed) Invalid end tag (expecting %s) at pos %d"
 429                              node-name (point)))
 430                      ((= (char-after) ?<)
 431                       (let ((tag (xml-parse-tag nil xml-ns)))
 432                         (when tag
 433                           (push tag children))))
 434                      (t
 435                       (let ((expansion (xml-parse-string)))
 436                         (setq children
 437                               (if (stringp expansion)
 438                                   (if (stringp (car children))
 439                                       ;; The two strings were separated by a comment.
 440                                       (setq children (append (concat (car children) expansion)
 441                                                              (cdr children)))
 442                                     (setq children (append (list expansion) children)))
 443                                 (setq children (append expansion children))))))))
 444
 445                   (goto-char (match-end 0))
 446                   (nreverse children)))
 447             ;;  This was an invalid start tag (Expected ">", but didn't see it.)
 448             (error "XML: (Well-Formed) Couldn't parse tag: %s"
 449                    (buffer-substring (- (point) 10) (+ (point) 1)))))))
 450      (t ;; (Not one of PI, CDATA, Comment, End tag, or Start tag)
 451       (unless xml-sub-parser            ; Usually, we error out.
 452         (error "XML: (Well-Formed) Invalid character"))
 453
 454       ;; However, if we're parsing incrementally, then we need to deal
 455       ;; with stray CDATA.
 456       (xml-parse-string)))))
 457
 458 (defun xml-parse-string ()
 459   "Parse the next whatever.  Could be a string, or an element."
 460     (let* ((pos (point))
 461            (string (progn (if (search-forward "<" nil t)
 462                               (forward-char -1)
 463                             (goto-char (point-max)))
 464                           (buffer-substring pos (point)))))
 465       ;; Clean up the string.  As per XML specifications, the XML
 466       ;; processor should always pass the whole string to the
 467       ;; application.  But \r's should be replaced:
 468       ;; http://www.w3.org/TR/2000/REC-xml-20001006#sec-line-ends
 469       (setq pos 0)
 470       (while (string-match "\r\n?" string pos)
 471         (setq string (replace-match "\n" t t string))
 472         (setq pos (1+ (match-beginning 0))))
 473
 474       (xml-substitute-special string)))
 475
 476 (defun xml-parse-attlist (&optional xml-ns)
 477   "Return the attribute-list after point.
 478 Leave point at the first non-blank character after the tag."
 479   (let ((attlist ())
 480         end-pos name)
 481     (skip-syntax-forward " ")
 482     (while (looking-at (eval-when-compile
 483                          (concat "\\(" xml-name-regexp "\\)\\s-*=\\s-*")))
 484       (setq end-pos (match-end 0))
 485       (setq name (xml-maybe-do-ns (match-string 1) nil xml-ns))
 486       (goto-char end-pos)
 487
 488       ;; See also: http://www.w3.org/TR/2000/REC-xml-20001006#AVNormalize
 489
 490       ;; Do we have a string between quotes (or double-quotes),
 491       ;;  or a simple word ?
 492       (if (looking-at "\"\\([^\"]*\\)\"")
 493           (setq end-pos (match-end 0))
 494         (if (looking-at "'\\([^']*\\)'")
 495             (setq end-pos (match-end 0))
 496           (error "XML: (Not Well-Formed) Attribute values must be given between quotes")))
 497
 498       ;; Each attribute must be unique within a given element
 499       (if (assoc name attlist)
 500           (error "XML: (Not Well-Formed) Each attribute must be unique within an element"))
 501
 502       ;; Multiple whitespace characters should be replaced with a single one
 503       ;; in the attributes
 504       (let ((string (match-string 1))
 505             (pos 0))
 506         (replace-regexp-in-string "\\s-\\{2,\\}" " " string)
 507         (let ((expansion (xml-substitute-special string)))
 508           (unless (stringp expansion)
 509             ; We say this is the constraint.  It is acctually that
 510             ; external entities nor "<" can be in an attribute value.
 511             (error "XML: (Not Well-Formed) Entities in attributes cannot expand into elements"))
 512           (push (cons name expansion) attlist)))
 513
 514       (goto-char end-pos)
 515       (skip-syntax-forward " "))
 516     (nreverse attlist)))
 517
 518 ;;*******************************************************************
 519 ;;**
 520 ;;**  The DTD (document type declaration)
 521 ;;**  The following functions know how to skip or parse the DTD of
 522 ;;**  a document
 523 ;;**
 524 ;;*******************************************************************
 525
 526 ;; Fixme: This fails at least if the DTD contains conditional sections.
 527
 528 (defun xml-skip-dtd ()
 529   "Skip the DTD at point.
 530 This follows the rule [28] in the XML specifications."
 531   (let ((xml-validating-parser nil))
 532     (xml-parse-dtd)))
 533
 534 (defun xml-parse-dtd (&optional parse-ns)
 535   "Parse the DTD at point."
 536   (forward-char (eval-when-compile (length "<!DOCTYPE")))
 537   (skip-syntax-forward " ")
 538   (if (and (looking-at ">")
 539            xml-validating-parser)
 540       (error "XML: (Validity) Invalid DTD (expecting name of the document)"))
 541
 542   ;;  Get the name of the document
 543   (looking-at xml-name-regexp)
 544   (let ((dtd (list (match-string 0) 'dtd))
 545         type element end-pos)
 546     (goto-char (match-end 0))
 547
 548     (skip-syntax-forward " ")
 549     ;; XML [75]
 550     (cond ((looking-at "PUBLIC\\s-+")
 551            (goto-char (match-end 0))
 552            (unless (or (re-search-forward
 553                         "\\=\"\\([[:space:][:alnum:]-'()+,./:=?;!*#@$_%]*\\)\""
 554                         nil t)
 555                        (re-search-forward
 556                         "\\='\\([[:space:][:alnum:]-()+,./:=?;!*#@$_%]*\\)'"
 557                         nil t))
 558              (error "XML: Missing Public ID"))
 559            (let ((pubid (match-string 1)))
 560              (skip-syntax-forward " ")
 561              (unless (or (re-search-forward "\\='\\([^']*\\)'" nil t)
 562                          (re-search-forward "\\=\"\\([^\"]*\\)\"" nil t))
 563                (error "XML: Missing System ID"))
 564              (push (list pubid (match-string 1) 'public) dtd)))
 565           ((looking-at "SYSTEM\\s-+")
 566            (goto-char (match-end 0))
 567            (unless (or (re-search-forward "\\='\\([^']*\\)'" nil t)
 568                        (re-search-forward "\\=\"\\([^\"]*\\)\"" nil t))
 569              (error "XML: Missing System ID"))
 570            (push (list (match-string 1) 'system) dtd)))
 571     (skip-syntax-forward " ")
 572     (if (eq ?> (char-after))
 573         (forward-char)
 574       (if (not (eq (char-after) ?\[))
 575           (error "XML: Bad DTD")
 576         (forward-char)
 577         ;;  Parse the rest of the DTD
 578         ;;  Fixme: Deal with ATTLIST, NOTATION, PIs.
 579         (while (not (looking-at "\\s-*\\]"))
 580           (skip-syntax-forward " ")
 581           (cond
 582
 583            ;;  Translation of rule [45] of XML specifications
 584            ((looking-at
 585              "<!ELEMENT\\s-+\\([[:alnum:].%;]+\\)\\s-+\\([^>]+\\)>")
 586
 587             (setq element (match-string 1)
 588                   type    (match-string-no-properties 2))
 589             (setq end-pos (match-end 0))
 590
 591             ;;  Translation of rule [46] of XML specifications
 592             (cond
 593              ((string-match "^EMPTY[ \t\n\r]*$" type) ;; empty declaration
 594               (setq type 'empty))
 595              ((string-match "^ANY[ \t\n\r]*$" type) ;; any type of contents
 596               (setq type 'any))
 597              ((string-match "^(\\(.*\\))[ \t\n\r]*$" type) ;; children ([47])
 598               (setq type (xml-parse-elem-type (match-string 1 type))))
 599              ((string-match "^%[^;]+;[ \t\n\r]*$" type) ;; substitution
 600               nil)
 601              (t
 602               (if xml-validating-parser
 603                   (error "XML: (Validity) Invalid element type in the DTD"))))
 604
 605             ;;  rule [45]: the element declaration must be unique
 606             (if (and (assoc element dtd)
 607                      xml-validating-parser)
 608                 (error "XML: (Validity) Element declarations must be unique in a DTD (<%s>)"
 609                        element))
 610
 611             ;;  Store the element in the DTD
 612             (push (list element type) dtd)
 613             (goto-char end-pos))
 614            ((looking-at "<!--")
 615             (search-forward "-->"))
 616            ((looking-at (concat "<!ENTITY[ \t\n\r]*\\(" xml-name-re
 617                                 "\\)[ \t\n\r]*\\(" xml-entity-value-re
 618                                 "\\)[ \t\n\r]*>"))
 619             (let ((name  (buffer-substring (nth 2 (match-data))
 620                                            (nth 3 (match-data))))
 621                   (value (buffer-substring (+ (nth 4 (match-data)) 1)
 622                                            (- (nth 5 (match-data)) 1))))
 623               (goto-char (nth 1 (match-data)))
 624               (setq xml-entity-alist
 625                     (append xml-entity-alist
 626                             (list (cons name
 627                                         (with-temp-buffer
 628                                           (insert value)
 629                                           (goto-char (point-min))
 630                                           (xml-parse-fragment
 631                                            xml-validating-parser
 632                                            parse-ns))))))))
 633            ((or (looking-at (concat "<!ENTITY[ \t\n\r]+\\(" xml-name-re
 634                                     "\\)[ \t\n\r]+SYSTEM[ \t\n\r]+"
 635                                     "\\(\"[^\"]*\"\\|'[^']*'\\)[ \t\n\r]*>"))
 636                 (looking-at (concat "<!ENTITY[ \t\n\r]+\\(" xml-name-re
 637                                     "\\)[ \t\n\r]+PUBLIC[ \t\n\r]+"
 638                                     "\"[- \r\na-zA-Z0-9'()+,./:=?;!*#@$_%]*\""
 639                                     "\\|'[- \r\na-zA-Z0-9()+,./:=?;!*#@$_%]*'"
 640                                     "[ \t\n\r]+\\(\"[^\"]*\"\\|'[^']*'\\)"
 641                                     "[ \t\n\r]*>")))
 642             (let ((name  (buffer-substring (nth 2 (match-data))
 643                                            (nth 3 (match-data))))
 644                   (file  (buffer-substring (+ (nth 4 (match-data)) 1)
 645                                            (- (nth 5 (match-data)) 1))))
 646               (goto-char (nth 1 (match-data)))
 647               (setq xml-entity-alist
 648                     (append xml-entity-alist
 649                             (list (cons name (with-temp-buffer
 650                                                (insert-file-contents file)
 651                                                (goto-char (point-min))
 652                                                (xml-parse-fragment
 653                                                 xml-validating-parser
 654                                                 parse-ns))))))))
 655            ;; skip parameter entity declarations
 656            ((or (looking-at (concat "<!ENTITY[ \t\n\r]+%[ \t\n\r]+\\(" xml-name-re
 657                                     "\\)[ \t\n\r]+SYSTEM[ \t\n\r]+"
 658                                     "\\(\"[^\"]*\"\\|'[^']*'\\)[ \t\n\r]*>"))
 659                 (looking-at (concat "<!ENTITY[ \t\n\r]+"
 660                                     "%[ \t\n\r]+"
 661                                     "\\(" xml-name-re "\\)[ \t\n\r]+"
 662                                     "PUBLIC[ \t\n\r]+"
 663                                     "\\(\"[- \r\na-zA-Z0-9'()+,./:=?;!*#@$_%]*\""
 664                                     "\\|'[- \r\na-zA-Z0-9()+,./:=?;!*#@$_%]*'\\)[ \t\n\r]+"
 665                                     "\\(\"[^\"]+\"\\|'[^']+'\\)"
 666                                     "[ \t\n\r]*>")))
 667             (goto-char (match-end 0)))
 668            ;; skip parameter entities
 669            ((looking-at (concat "%" xml-name-re ";"))
 670             (goto-char (match-end 0)))
 671            (t
 672             (when xml-validating-parser
 673               (error "XML: (Validity) Invalid DTD item"))))))
 674       (if (looking-at "\\s-*]>")
 675           (goto-char (nth 1 (match-data)))))
 676     (nreverse dtd)))
 677
 678 (defun xml-parse-elem-type (string)
 679   "Convert element type STRING into a Lisp structure."
 680
 681   (let (elem modifier)
 682     (if (string-match "(\\([^)]+\\))\\([+*?]?\\)" string)
 683         (progn
 684           (setq elem     (match-string 1 string)
 685                 modifier (match-string 2 string))
 686           (if (string-match "|" elem)
 687               (setq elem (cons 'choice
 688                                (mapcar 'xml-parse-elem-type
 689                                        (split-string elem "|"))))
 690             (if (string-match "," elem)
 691                 (setq elem (cons 'seq
 692                                  (mapcar 'xml-parse-elem-type
 693                                          (split-string elem ",")))))))
 694       (if (string-match "[ \t\n\r]*\\([^+*?]+\\)\\([+*?]?\\)" string)
 695           (setq elem     (match-string 1 string)
 696                 modifier (match-string 2 string))))
 697
 698     (if (and (stringp elem) (string= elem "#PCDATA"))
 699         (setq elem 'pcdata))
 700
 701     (cond
 702      ((string= modifier "+")
 703       (list '+ elem))
 704      ((string= modifier "*")
 705       (list '* elem))
 706      ((string= modifier "?")
 707       (list '\? elem))
 708      (t
 709       elem))))
 710
 711 ;;*******************************************************************
 712 ;;**
 713 ;;**  Substituting special XML sequences
 714 ;;**
 715 ;;*******************************************************************
 716
 717 (defun xml-substitute-special (string)
 718   "Return STRING, after subsituting entity references."
 719   ;; This originally made repeated passes through the string from the
 720   ;; beginning, which isn't correct, since then either "&amp;amp;" or
 721   ;; "&#38;amp;" won't DTRT.
 722
 723   (let ((point 0)
 724         children end-point)
 725     (while (string-match "&\\([^;]*\\);" string point)
 726       (setq end-point (match-end 0))
 727       (let* ((this-part (match-string 1 string))
 728              (prev-part (substring string point (match-beginning 0)))
 729              (entity (assoc this-part xml-entity-alist))
 730              (expansion
 731               (cond ((string-match "#\\([0-9]+\\)" this-part)
 732                      (let ((c (decode-char
 733                                'ucs
 734                                (string-to-number (match-string 1 this-part)))))
 735                        (if c (string c))))
 736                     ((string-match "#x\\([[:xdigit:]]+\\)" this-part)
 737                      (let ((c (decode-char
 738                                'ucs
 739                                (string-to-number (match-string 1 this-part) 16))))
 740                        (if c (string c))))
 741                     (entity
 742                      (cdr entity))
 743                     ((eq (length this-part) 0)
 744                      (error "XML: (Not Well-Formed) No entity given"))
 745                     (t
 746                      (when xml-validating-parser
 747                          (error "XML: (Validity) Undefined entity `%s'"
 748                                 this-part))))))
 749
 750         (cond ((null children)
 751                ;; FIXME: If we have an entity that expands into XML, this won't work.
 752                (setq children
 753                      (concat prev-part expansion)))
 754               ((stringp children)
 755                (if (stringp expansion)
 756                    (setq children (concat children prev-part expansion))
 757                  (setq children (list expansion (concat prev-part children)))))
 758               ((and (stringp expansion)
 759                     (stringp (car children)))
 760                (setcar children (concat prev-part expansion (car children))))
 761               ((stringp expansion)
 762                (setq children (append (concat prev-part expansion)
 763                                       children)))
 764               ((stringp (car children))
 765                (setcar children (concat (car children) prev-part))
 766                (setq children (append expansion children)))
 767               (t
 768                (setq children (list expansion
 769                                     prev-part
 770                                     children))))
 771         (setq point end-point)))
 772     (cond ((stringp children)
 773            (concat children (substring string point)))
 774           ((stringp (car (last children)))
 775            (concat (car (last children)) (substring string point)))
 776           ((null children)
 777            string)
 778           (t
 779            (concat (mapconcat 'identity
 780                               (nreverse children)
 781                               "")
 782                    (substring string point))))))
 783
 784 ;;*******************************************************************
 785 ;;**
 786 ;;**  Printing a tree.
 787 ;;**  This function is intended mainly for debugging purposes.
 788 ;;**
 789 ;;*******************************************************************
 790
 791 (defun xml-debug-print (xml &optional indent-string)
 792   "Outputs the XML in the current buffer.
 793 XML can be a tree or a list of nodes.
 794 The first line is indented with the optional INDENT-STRING."
 795   (setq indent-string (or indent-string ""))
 796   (dolist (node xml)
 797     (xml-debug-print-internal node indent-string)))
 798
 799 (defalias 'xml-print 'xml-debug-print)
 800
 801 (defun xml-debug-print-internal (xml indent-string)
 802   "Outputs the XML tree in the current buffer.
 803 The first line is indented with INDENT-STRING."
 804   (let ((tree xml)
 805         attlist)
 806     (insert indent-string ?< (symbol-name (xml-node-name tree)))
 807
 808     ;;  output the attribute list
 809     (setq attlist (xml-node-attributes tree))
 810     (while attlist
 811       (insert ?\  (symbol-name (caar attlist)) "=\"" (cdar attlist) ?\")
 812       (setq attlist (cdr attlist)))
 813
 814     (setq tree (xml-node-children tree))
 815
 816     (if (null tree)
 817         (insert ?/ ?>)
 818       (insert ?>)
 819
 820       ;;  output the children
 821       (dolist (node tree)
 822         (cond
 823          ((listp node)
 824           (insert ?\n)
 825           (xml-debug-print-internal node (concat indent-string "  ")))
 826          ((stringp node) (insert node))
 827          (t
 828           (error "Invalid XML tree"))))
 829
 830       (when (not (and (null (cdr tree))
 831                       (stringp (car tree))))
 832         (insert ?\n indent-string))
 833       (insert ?< ?/ (symbol-name (xml-node-name xml)) ?>))))
 834
 835 (provide 'xml)
 836
 837 ;; arch-tag: 5864b283-5a68-4b59-a20d-36a72b353b9b
 838 ;;; xml.el ends here