lisp/pcvs.el

   1 ;;; pcvs.el --- a front-end to CVS
   2
   3 ;; Copyright (C) 1991, 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2000, 2002, 2003, 2004  Free Software Foundation, Inc.
   5
   6 ;; Author: (The PCL-CVS Trust) pcl-cvs@cyclic.com
   7 ;;      (Per Cederqvist) ceder@lysator.liu.se
   8 ;;      (Greg A. Woods) woods@weird.com
   9 ;;      (Jim Blandy) jimb@cyclic.com
  10 ;;      (Karl Fogel) kfogel@floss.red-bean.com
  11 ;;      (Jim Kingdon) kingdon@cyclic.com
  12 ;;      (Stefan Monnier) monnier@cs.yale.edu
  13 ;;      (Greg Klanderman) greg@alphatech.com
  14 ;;      (Jari Aalto+mail.emacs) jari.aalto@poboxes.com
  15 ;; Maintainer: (Stefan Monnier) monnier@gnu.org
  16 ;; Keywords: CVS, version control, release management
  17
  18 ;; This file is part of GNU Emacs.
  19
  20 ;; GNU Emacs is free software; you can redistribute it and/or modify
  21 ;; it under the terms of the GNU General Public License as published by
  22 ;; the Free Software Foundation; either version 2, or (at your option)
  23 ;; any later version.
  24
  25 ;; GNU Emacs is distributed in the hope that it will be useful,
  26 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  27 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  28 ;; GNU General Public License for more details.
  29
  30 ;; You should have received a copy of the GNU General Public License
  31 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  32 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  33 ;; Boston, MA 02111-1307, USA.
  34
  35 ;;; Commentary:
  36
  37 ;; PCL-CVS is a front-end to the CVS version control system.  For people
  38 ;; familiar with VC, it is somewhat like VC-dired: it presents the status of
  39 ;; all the files in your working area and allows you to commit/update several
  40 ;; of them at a time.  Compared to VC-dired, it is considerably better and
  41 ;; faster (but only for CVS).
  42
  43 ;; PCL-CVS was originally written by Per Cederqvist many years ago.  This
  44 ;; version derives from the XEmacs-21 version, itself based on the 2.0b2
  45 ;; version (last release from Per).  It is a thorough rework.
  46
  47 ;; Contrary to what you'd expect, PCL-CVS is not a replacement for VC but only
  48 ;; for VC-dired.  As such, I've tried to make PCL-CVS and VC interoperate
  49 ;; seamlessly (I also use VC).
  50
  51 ;; To use PCL-CVS just use `M-x cvs-examine RET <dir> RET'.
  52 ;; There is a TeXinfo manual, which can be helpful to get started.
  53
  54 ;;; Bugs:
  55
  56 ;; - Extracting an old version seems not to recognize encoding correctly.
  57 ;;   That's probably because it's done via a process rather than a file.
  58
  59 ;;; Todo:
  60
  61 ;; ******** FIX THE DOCUMENTATION *********
  62 ;;
  63 ;; - rework the displaying of error messages.
  64 ;; - allow to flush messages only
  65 ;; - allow to protect files like ChangeLog from flushing
  66 ;; - automatically cvs-mode-insert files from find-file-hook
  67 ;;   (and don't flush them as long as they are visited)
  68 ;; - query the user for cvs-get-marked (for some cmds or if nothing's selected)
  69 ;; - don't return the first (resp last) FI if the cursor is before
  70 ;;   (resp after) it.
  71 ;; - allow cvs-confirm-removals to force always confirmation.
  72 ;; - cvs-checkout should ask for a revision (with completion).
  73 ;; - removal confirmation should allow specifying another file name.
  74 ;;
  75 ;; - hide fileinfos without getting rid of them (will require ewok work).
  76 ;; - add toolbar entries
  77 ;; - marking
  78 ;;    marking directories should jump to just after the dir.
  79 ;;    allow (un)marking directories at a time with the mouse.
  80 ;;    allow cvs-cmd-do to either clear the marks or not.
  81 ;;    add a "marks active" notion, like transient-mark-mode does.
  82 ;; - liveness indicator
  83 ;; - indicate in docstring if the cmd understands the `b' prefix(es).
  84 ;; - call smerge-mode when opening CONFLICT files.
  85 ;; - have vc-checkin delegate to cvs-mode-commit when applicable
  86 ;; - higher-level CVS operations
  87 ;;    cvs-mode-rename
  88 ;;    cvs-mode-branch
  89 ;; - module-level commands
  90 ;;    add support for parsing 'modules' file ("cvs co -c")
  91 ;;    cvs-mode-rcs2log
  92 ;;    cvs-rdiff
  93 ;;    cvs-release
  94 ;;    cvs-import
  95 ;;    C-u M-x cvs-checkout should ask for a cvsroot
  96 ;;    cvs-mode-handle-new-vendor-version
  97 ;;      - checks out module, or alternately does update join
  98 ;;      - does "cvs -n tag LAST_VENDOR" to find old files into *cvs*
  99 ;;    cvs-export
 100 ;;      (with completion on tag names and hooks to help generate full releases)
 101 ;; - display stickiness information.  And current CVS/Tag as well.
 102 ;; - write 'cvs-mode-admin' to do arbitrary 'cvs admin' commands
 103 ;;   Most interesting would be version removal and log message replacement.
 104 ;;   The last one would be neat when called from log-view-mode.
 105 ;; - cvs-mode-incorporate
 106 ;;      It would merge in the status from one *cvs* buffer into another.
 107 ;;      This would be used to populate such a buffer that had been created with
 108 ;;      a `cvs {update,status,checkout} -l'.
 109 ;; - cvs-mode-(i)diff-other-{file,buffer,cvs-buffer}
 110 ;; - offer the choice to kill the process when the user kills the cvs buffer.
 111 ;;      right now, it's killed without further ado.
 112 ;; - make `cvs-mode-ignore' allow manually entering a pattern.
 113 ;;      to which dir should it apply ?
 114 ;; - cvs-mode-ignore should try to remove duplicate entries.
 115 ;; - maybe poll/check CVS/Entries files to react to external `cvs' commands ?
 116 ;; - some kind of `cvs annotate' support ?
 117 ;;      but vc-annotate can be used instead.
 118 ;; - proper `g' that passes safe args and uses either cvs-status or cvs-examine
 119 ;;   maybe also use cvs-update depending on I-don't-know-what.
 120 ;; - add message-levels so that we can hide some levels of messages
 121
 122 ;;; Code:
 123
 124 (eval-when-compile (require 'cl))
 125 (require 'ewoc)                         ;Ewoc was once cookie
 126 (require 'pcvs-defs)
 127 (require 'pcvs-util)
 128 (require 'pcvs-parse)
 129 (require 'pcvs-info)
 130
 131 \f
 132 ;;;;
 133 ;;;; global vars
 134 ;;;;
 135
 136 (defvar cvs-cookies) ;;nil
 137   ;;"Handle for the cookie structure that is displayed in the *cvs* buffer.")
 138 ;;(make-variable-buffer-local 'cvs-cookies)
 139
 140 ;;;;
 141 ;;;; Dynamically scoped variables
 142 ;;;;
 143
 144 (defvar cvs-from-vc nil "Bound to t inside VC advice.")
 145
 146 ;;;;
 147 ;;;; flags variables
 148 ;;;;
 149
 150 (defun cvs-defaults (&rest defs)
 151   (let ((defs (cvs-first defs cvs-shared-start)))
 152     (append defs
 153             (make-list (- cvs-shared-start (length defs)) (car defs))
 154             cvs-shared-flags)))
 155
 156 ;; For cvs flags, we need to add "-f" to override the cvsrc settings
 157 ;; we also want to evict the annoying -q and -Q options that hide useful
 158 ;; information from pcl-cvs.
 159 (cvs-flags-define cvs-cvs-flags '(("-f")))
 160
 161 (cvs-flags-define cvs-checkout-flags (cvs-defaults '("-P")))
 162 (cvs-flags-define cvs-status-flags (cvs-defaults '("-v") nil))
 163 (cvs-flags-define cvs-log-flags (cvs-defaults nil))
 164 (cvs-flags-define cvs-diff-flags (cvs-defaults '("-u" "-N") '("-c" "-N") '("-u" "-b")))
 165 (cvs-flags-define cvs-tag-flags (cvs-defaults nil))
 166 (cvs-flags-define cvs-add-flags (cvs-defaults nil))
 167 (cvs-flags-define cvs-commit-flags (cvs-defaults nil))
 168 (cvs-flags-define cvs-remove-flags (cvs-defaults nil))
 169 ;;(cvs-flags-define cvs-undo-flags (cvs-defaults nil))
 170 (cvs-flags-define cvs-update-flags (cvs-defaults '("-d" "-P")))
 171
 172 (defun cvs-reread-cvsrc ()
 173   "Reset the default arguments to those in the `cvs-cvsrc-file'."
 174   (interactive)
 175   (condition-case nil
 176       (with-temp-buffer
 177         (insert-file-contents cvs-cvsrc-file)
 178         ;; fetch the values
 179         (dolist (cmd '("cvs" "checkout" "status" "log" "diff" "tag"
 180                        "add" "commit" "remove" "update"))
 181           (goto-char (point-min))
 182           (when (re-search-forward
 183                  (concat "^" cmd "\\(\\s-+\\(.*\\)\\)?$") nil t)
 184             (let* ((sym (intern (concat "cvs-" cmd "-flags")))
 185                    (val (cvs-string->strings (or (match-string 2) ""))))
 186               (cvs-flags-set sym 0 val))))
 187         ;; ensure that cvs doesn't have -q or -Q
 188         (cvs-flags-set 'cvs-cvs-flags 0
 189                        (cons "-f"
 190                              (cdr (cvs-partition
 191                                    (lambda (x) (member x '("-q" "-Q" "-f")))
 192                                    (cvs-flags-query 'cvs-cvs-flags
 193                                                     nil 'noquery))))))
 194       (file-error nil)))
 195
 196 ;; initialize to cvsrc's default values
 197 (cvs-reread-cvsrc)
 198
 199 \f
 200 ;;;;
 201 ;;;; Mouse bindings and mode motion
 202 ;;;;
 203
 204 (defvar cvs-minor-current-files)
 205
 206 (defun cvs-menu (e)
 207   "Popup the CVS menu."
 208   (interactive "e")
 209   (let ((cvs-minor-current-files
 210          (list (ewoc-data (ewoc-locate
 211                            cvs-cookies (posn-point (event-end e)))))))
 212     (popup-menu cvs-menu e)))
 213
 214 (defvar cvs-mode-line-process nil
 215   "Mode-line control for displaying info on cvs process status.")
 216
 217
 218 ;;;;
 219 ;;;; Query-Type-Descriptor for Tags
 220 ;;;;
 221
 222 (autoload 'cvs-status-get-tags "cvs-status")
 223 (defun cvs-tags-list ()
 224   "Return a list of acceptable tags, ready for completions."
 225   (assert (cvs-buffer-p))
 226   (let ((marked (cvs-get-marked)))
 227     (list* '("BASE") '("HEAD")
 228            (when marked
 229              (with-temp-buffer
 230                (call-process cvs-program
 231                              nil        ;no input
 232                              t          ;output to current-buffer
 233                              nil        ;don't update display while running
 234                              "status"
 235                              "-v"
 236                              (cvs-fileinfo->full-path (car marked)))
 237                (goto-char (point-min))
 238                (let ((tags (cvs-status-get-tags)))
 239                  (when (listp tags) tags)))))))
 240
 241 (defvar cvs-tag-history nil)
 242 (defconst cvs-qtypedesc-tag
 243   (cvs-qtypedesc-create 'identity 'identity 'cvs-tags-list 'cvs-tag-history))
 244
 245 ;;;;
 246
 247 (defun cvs-mode! (&optional -cvs-mode!-fun)
 248   "Switch to the *cvs* buffer.
 249 If -CVS-MODE!-FUN is provided, it is executed *cvs* being the current buffer
 250   and with its window selected.  Else, the *cvs* buffer is simply selected.
 251 -CVS-MODE!-FUN is called interactively if applicable and else with no argument."
 252   (let* ((-cvs-mode!-buf (current-buffer))
 253          (cvsbuf (cond ((cvs-buffer-p) (current-buffer))
 254                        ((and cvs-buffer (cvs-buffer-p cvs-buffer)) cvs-buffer)
 255                        (t (error "can't find the *cvs* buffer"))))
 256          (-cvs-mode!-wrapper cvs-minor-wrap-function)
 257          (-cvs-mode!-cont (lambda ()
 258                             (save-current-buffer
 259                               (if (commandp -cvs-mode!-fun)
 260                                   (call-interactively -cvs-mode!-fun)
 261                                 (funcall -cvs-mode!-fun))))))
 262     (if (not -cvs-mode!-fun) (set-buffer cvsbuf)
 263       (let ((cvs-mode!-buf (current-buffer))
 264             (cvs-mode!-owin (selected-window))
 265             (cvs-mode!-nwin (get-buffer-window cvsbuf 'visible)))
 266         (unwind-protect
 267             (progn
 268               (set-buffer cvsbuf)
 269               (when cvs-mode!-nwin (select-window cvs-mode!-nwin))
 270               (if -cvs-mode!-wrapper
 271                   (funcall -cvs-mode!-wrapper -cvs-mode!-buf -cvs-mode!-cont)
 272                 (funcall -cvs-mode!-cont)))
 273           (set-buffer cvs-mode!-buf)
 274           (when (and cvs-mode!-nwin (eq cvs-mode!-nwin (selected-window)))
 275             ;; the selected window has not been changed by FUN
 276             (select-window cvs-mode!-owin)))))))
 277
 278 ;;;;
 279 ;;;; Prefixes
 280 ;;;;
 281
 282 (defvar cvs-branches (list cvs-vendor-branch "HEAD" "HEAD"))
 283 (cvs-prefix-define cvs-branch-prefix
 284   "Current selected branch."
 285   "version"
 286   (cons cvs-vendor-branch cvs-branches)
 287   cvs-qtypedesc-tag)
 288
 289 (defun cvs-set-branch-prefix (arg)
 290   "Set the branch prefix to take action at the next command.
 291 See `cvs-prefix-set' for a further the description of the behavior.
 292 \\[universal-argument] 1 selects the vendor branch
 293 and \\[universal-argument] 2 selects the HEAD."
 294   (interactive "P")
 295   (cvs-mode!)
 296   (cvs-prefix-set 'cvs-branch-prefix arg))
 297
 298 (defun cvs-add-branch-prefix (flags &optional arg)
 299   "Add branch selection argument if the branch prefix was set.
 300 The argument is added (or not) to the list of FLAGS and is constructed
 301 by appending the branch to ARG which defaults to \"-r\"."
 302   (let ((branch (cvs-prefix-get 'cvs-branch-prefix)))
 303     ;; deactivate the secondary prefix, even if not used.
 304     (cvs-prefix-get 'cvs-secondary-branch-prefix)
 305     (if branch (cons (concat (or arg "-r") branch) flags) flags)))
 306
 307 (cvs-prefix-define cvs-secondary-branch-prefix
 308   "Current secondary selected branch."
 309   "version"
 310   (cons cvs-vendor-branch cvs-branches)
 311   cvs-qtypedesc-tag)
 312
 313 (defun cvs-set-secondary-branch-prefix (arg)
 314   "Set the branch prefix to take action at the next command.
 315 See `cvs-prefix-set' for a further the description of the behavior.
 316 \\[universal-argument] 1 selects the vendor branch
 317 and \\[universal-argument] 2 selects the HEAD."
 318   (interactive "P")
 319   (cvs-mode!)
 320   (cvs-prefix-set 'cvs-secondary-branch-prefix arg))
 321
 322 (defun cvs-add-secondary-branch-prefix (flags &optional arg)
 323   "Add branch selection argument if the secondary branch prefix was set.
 324 The argument is added (or not) to the list of FLAGS and is constructed
 325 by appending the branch to ARG which defaults to \"-r\".
 326 Since the `cvs-secondary-branch-prefix' is only active if the primary
 327 prefix is active, it is important to read the secondary prefix before
 328 the primay since reading the primary can deactivate it."
 329   (let ((branch (and (cvs-prefix-get 'cvs-branch-prefix 'read-only)
 330                      (cvs-prefix-get 'cvs-secondary-branch-prefix))))
 331     (if branch (cons (concat (or arg "-r") branch) flags) flags)))
 332
 333 ;;;;
 334
 335 (define-minor-mode cvs-minor-mode
 336   "This mode is used for buffers related to a main *cvs* buffer.
 337 All the `cvs-mode' buffer operations are simply rebound under
 338 the \\[cvs-mode-map] prefix."
 339   nil " CVS"
 340   :group 'pcl-cvs)
 341 (put 'cvs-minor-mode 'permanent-local t)
 342
 343
 344 (defvar cvs-temp-buffers nil)
 345 (defun cvs-temp-buffer (&optional cmd normal nosetup)
 346   "Create a temporary buffer to run CMD in.
 347 If CMD is a string, use it to lookup `cvs-buffer-name-alist' to find
 348 the buffer name to be used and its `major-mode'.
 349
 350 The selected window will not be changed.  The new buffer will not maintain undo
 351 information and will be read-only unless NORMAL is non-nil.  It will be emptied
 352 \(unless NOSETUP is non-nil\) and its `default-directory' will be inherited
 353 from the current buffer."
 354   (let* ((cvs-buf (current-buffer))
 355          (info (cdr (assoc cmd cvs-buffer-name-alist)))
 356          (name (eval (nth 0 info)))
 357          (mode (nth 1 info))
 358          (dir default-directory)
 359          (buf (cond
 360                (name (cvs-get-buffer-create name))
 361                ((and (bufferp cvs-temp-buffer) (buffer-name cvs-temp-buffer))
 362                 cvs-temp-buffer)
 363                (t
 364                 (set (make-local-variable 'cvs-temp-buffer)
 365                      (cvs-get-buffer-create
 366                       (eval cvs-temp-buffer-name) 'noreuse))))))
 367
 368     ;; handle the potential pre-existing process
 369     (let ((proc (get-buffer-process buf)))
 370       (when (and (not normal) (processp proc)
 371                  (memq (process-status proc) '(run stop)))
 372         (if cmd
 373             ;; When CMD is specified, the buffer is normally shown to the
 374             ;; user, so interrupting the process is not harmful.
 375             ;; Use `delete-process' rather than `kill-process' otherwise
 376             ;; the pending output of the process will still get inserted
 377             ;; after we erase the buffer.
 378             (delete-process proc)
 379           (error "Can not run two cvs processes simultaneously"))))
 380
 381     (if (not name) (kill-local-variable 'other-window-scroll-buffer)
 382       ;; Strangely, if no window is created, `display-buffer' ends up
 383       ;; doing a `switch-to-buffer' which does a `set-buffer', hence
 384       ;; the need for `save-excursion'.
 385       (unless nosetup (save-excursion (display-buffer buf)))
 386       ;; FIXME: this doesn't do the right thing if the user later on
 387       ;; does a `find-file-other-window' and `scroll-other-window'
 388       (set (make-local-variable 'other-window-scroll-buffer) buf))
 389
 390     (add-to-list 'cvs-temp-buffers buf)
 391
 392     (with-current-buffer buf
 393       (setq buffer-read-only nil)
 394       (setq default-directory dir)
 395       (unless nosetup (erase-buffer))
 396       (set (make-local-variable 'cvs-buffer) cvs-buf)
 397       ;;(cvs-minor-mode 1)
 398       (let ((lbd list-buffers-directory))
 399         (if (fboundp mode) (funcall mode) (fundamental-mode))
 400         (when lbd (set (make-local-variable 'list-buffers-directory) lbd)))
 401       (cvs-minor-mode 1)
 402       ;;(set (make-local-variable 'cvs-buffer) cvs-buf)
 403       (unless normal
 404         (setq buffer-read-only t)
 405         (buffer-disable-undo))
 406       buf)))
 407
 408 (defun cvs-mode-kill-buffers ()
 409   "Kill all the \"temporary\" buffers created by the *cvs* buffer."
 410   (interactive)
 411   (dolist (buf cvs-temp-buffers) (ignore-errors (kill-buffer buf))))
 412
 413 (defun cvs-make-cvs-buffer (dir &optional new)
 414   "Create the *cvs* buffer for directory DIR.
 415 If non-nil, NEW means to create a new buffer no matter what."
 416   ;; the real cvs-buffer creation
 417   (setq dir (cvs-expand-dir-name dir))
 418   (let* ((buffer-name (eval cvs-buffer-name))
 419          (buffer
 420           (or (and (not new)
 421                    (eq cvs-reuse-cvs-buffer 'current)
 422                    (cvs-buffer-p)       ;reuse the current buffer if possible
 423                    (current-buffer))
 424               ;; look for another cvs buffer visiting the same directory
 425               (save-excursion
 426                 (unless new
 427                   (dolist (buffer (cons (current-buffer) (buffer-list)))
 428                     (set-buffer buffer)
 429                     (and (cvs-buffer-p)
 430                          (case cvs-reuse-cvs-buffer
 431                            (always t)
 432                            (subdir
 433                             (or (cvs-string-prefix-p default-directory dir)
 434                                 (cvs-string-prefix-p dir default-directory)))
 435                            (samedir (string= default-directory dir)))
 436                          (return buffer)))))
 437               ;; we really have to create a new buffer:
 438               ;; we temporarily bind cwd to "" to prevent
 439               ;; create-file-buffer from using directory info
 440               ;; unless it is explicitly in the cvs-buffer-name.
 441               (cvs-get-buffer-create buffer-name new))))
 442     (with-current-buffer buffer
 443       (or
 444        (and (string= dir default-directory) (cvs-buffer-p)
 445             ;; just a refresh
 446             (ignore-errors
 447               (cvs-cleanup-collection cvs-cookies nil nil t)
 448               (current-buffer)))
 449        ;; setup from scratch
 450        (progn
 451          (setq default-directory dir)
 452          (setq buffer-read-only nil)
 453          (erase-buffer)
 454          (insert "Repository : " (directory-file-name (cvs-get-cvsroot))
 455                  "\nModule     : " (cvs-get-module)
 456                  "\nWorking dir: " (abbreviate-file-name dir)
 457                  (if (not (file-readable-p "CVS/Tag")) "\n"
 458                    (let ((tag (cvs-file-to-string "CVS/Tag")))
 459                      (cond
 460                       ((string-match "\\`T" tag)
 461                        (concat "\nTag        : " (substring tag 1)))
 462                       ((string-match "\\`D" tag)
 463                        (concat "\nDate       : " (substring tag 1)))
 464                       ("\n"))))
 465                  "\n")
 466          (setq buffer-read-only t)
 467          (cvs-mode)
 468          (set (make-local-variable 'list-buffers-directory) buffer-name)
 469          ;;(set (make-local-variable 'cvs-temp-buffer) (cvs-temp-buffer))
 470          (let ((cookies (ewoc-create 'cvs-fileinfo-pp "\n" "")))
 471            (set (make-local-variable 'cvs-cookies) cookies)
 472            (add-hook 'kill-buffer-hook
 473                      (lambda ()
 474                        (ignore-errors (kill-buffer cvs-temp-buffer)))
 475                      nil t)
 476            ;;(set-buffer buf)
 477            buffer))))))
 478
 479 (defun* cvs-cmd-do (cmd dir flags fis new
 480                         &key cvsargs noexist dont-change-disc noshow)
 481   (let* ((dir (file-name-as-directory
 482                (abbreviate-file-name (expand-file-name dir))))
 483          (cvsbuf (cvs-make-cvs-buffer dir new)))
 484     ;; Check that dir is under CVS control.
 485     (unless (file-directory-p dir)
 486       (error "%s is not a directory" dir))
 487     (unless (or noexist (file-directory-p (expand-file-name "CVS" dir))
 488                 (file-expand-wildcards (expand-file-name "*/CVS" dir)))
 489       (error "%s does not contain CVS controlled files" dir))
 490
 491     (set-buffer cvsbuf)
 492     (cvs-mode-run cmd flags fis
 493                   :cvsargs cvsargs :dont-change-disc dont-change-disc)
 494
 495     (if noshow cvsbuf
 496       (let ((pop-up-windows nil)) (pop-to-buffer cvsbuf)))))
 497 ;;      (funcall (if (and (boundp 'pop-up-frames) pop-up-frames)
 498 ;;                 'pop-to-buffer 'switch-to-buffer)
 499 ;;             cvsbuf))))
 500
 501 (defun cvs-run-process (args fis postprocess &optional single-dir)
 502   (assert (cvs-buffer-p cvs-buffer))
 503   (save-current-buffer
 504     (let ((procbuf (current-buffer))
 505           (cvsbuf cvs-buffer)
 506           (single-dir (or single-dir (eq cvs-execute-single-dir t))))
 507
 508       (set-buffer procbuf)
 509       (goto-char (point-max))
 510       (unless (bolp) (let ((inhibit-read-only t)) (insert "\n")))
 511       ;; find the set of files we'll process in this round
 512       (let* ((dir+files+rest
 513               (if (or (null fis) (not single-dir))
 514                   ;; not single-dir mode: just process the whole thing
 515                   (list "" (mapcar 'cvs-fileinfo->full-path fis) nil)
 516                 ;; single-dir mode: extract the same-dir-elements
 517                 (let ((dir (cvs-fileinfo->dir (car fis))))
 518                   ;; output the concerned dir so the parser can translate paths
 519                   (let ((inhibit-read-only t))
 520                     (insert "pcl-cvs: descending directory " dir "\n"))
 521                   ;; loop to find the same-dir-elems
 522                   (do* ((files () (cons (cvs-fileinfo->file fi) files))
 523                         (fis fis (cdr fis))
 524                         (fi (car fis) (car fis)))
 525                       ((not (and fis (string= dir (cvs-fileinfo->dir fi))))
 526                        (list dir files fis))))))
 527              (dir (nth 0 dir+files+rest))
 528              (files (nth 1 dir+files+rest))
 529              (rest (nth 2 dir+files+rest)))
 530
 531         ;; setup the (current) process buffer
 532         (set (make-local-variable 'cvs-postprocess)
 533              (if (null rest)
 534                  ;; this is the last invocation
 535                  postprocess
 536                ;; else, we have to register ourselves to be rerun on the rest
 537                `(cvs-run-process ',args ',rest ',postprocess ',single-dir)))
 538         (add-hook 'kill-buffer-hook
 539                   (lambda ()
 540                     (let ((proc (get-buffer-process (current-buffer))))
 541                       (when (processp proc)
 542                         (set-process-filter proc nil)
 543                         (set-process-sentinel proc nil)
 544                         (delete-process proc))))
 545                   nil t)
 546
 547         ;; create the new process and setup the procbuffer correspondingly
 548         (let* ((args (append (cvs-flags-query 'cvs-cvs-flags nil 'noquery)
 549                              (if cvs-cvsroot (list "-d" cvs-cvsroot))
 550                              args
 551                              files))
 552                ;; If process-connection-type is nil and the repository
 553                ;; is accessed via SSH, a bad interaction between libc,
 554                ;; CVS and SSH can lead to garbled output.
 555                ;; It might be a glibc-specific problem (but it also happens
 556                ;; under Mac OS X, it seems).
 557                ;; Until the problem is cleared, we'll use a pty rather than
 558                ;; a pipe.
 559                ;; (process-connection-type nil) ; Use a pipe, not a pty.
 560                (process
 561                 ;; the process will be run in the selected dir
 562                 (let ((default-directory (cvs-expand-dir-name dir)))
 563                   (apply 'start-process "cvs" procbuf cvs-program args))))
 564           (set-process-sentinel process 'cvs-sentinel)
 565           (set-process-filter process 'cvs-update-filter)
 566           (set-marker (process-mark process) (point-max))
 567           (ignore-errors (process-send-eof process)) ;close its stdin to avoid hangs
 568
 569           ;; now finish setting up the cvs-buffer
 570           (set-buffer cvsbuf)
 571           (setq cvs-mode-line-process (symbol-name (process-status process)))
 572           (force-mode-line-update)))))
 573
 574   ;; The following line is said to improve display updates on some
 575   ;; emacsen. It shouldn't be needed, but it does no harm.
 576   (sit-for 0))
 577
 578 (defun cvs-header-msg (args fis)
 579   (let* ((lastarg nil)
 580          (args (mapcar (lambda (arg)
 581                          (cond
 582                           ;; filter out the largish commit message
 583                           ((and (eq lastarg nil) (string= arg "commit"))
 584                            (setq lastarg 'commit) arg)
 585                           ((and (eq lastarg 'commit) (string= arg "-m"))
 586                            (setq lastarg '-m) arg)
 587                           ((eq lastarg '-m)
 588                            (setq lastarg 'done) "<log message>")
 589                           ;; filter out the largish `admin -mrev:msg' message
 590                           ((and (eq lastarg nil) (string= arg "admin"))
 591                            (setq lastarg 'admin) arg)
 592                           ((and (eq lastarg 'admin)
 593                                 (string-match "\\`-m[^:]*:" arg))
 594                            (setq lastarg 'done)
 595                            (concat (match-string 0 arg) "<log message>"))
 596                           ;; Keep the rest as is.
 597                           (t arg)))
 598                        args)))
 599     (concat cvs-program " "
 600             (cvs-strings->string
 601              (append (cvs-flags-query 'cvs-cvs-flags nil 'noquery)
 602                      (if cvs-cvsroot (list "-d" cvs-cvsroot))
 603                      args
 604                      (mapcar 'cvs-fileinfo->full-path fis))))))
 605
 606 (defun cvs-update-header (cmd add)
 607   (let* ((hf (ewoc-get-hf cvs-cookies))
 608          (str (car hf))
 609          (done "")
 610          (tin (ewoc-nth cvs-cookies 0)))
 611     (if (eq (length str) 1) (setq str ""))
 612     ;; look for the first *real* fileinfo (to determine emptyness)
 613     (while
 614         (and tin
 615              (memq (cvs-fileinfo->type (ewoc-data tin))
 616                    '(MESSAGE DIRCHANGE)))
 617       (setq tin (ewoc-next cvs-cookies tin)))
 618     (if add
 619         (setq str (concat "-- Running " cmd " ...\n" str))
 620       (if (not (string-match
 621                 (concat "^-- Running " (regexp-quote cmd) " \\.\\.\\.\n") str))
 622           (error "Internal PCL-CVS error while removing message")
 623         (setq str (replace-match "" t t str))
 624         (if (zerop (length str)) (setq str "\n"))
 625         (setq done (concat "-- last cmd: " cmd " --"))))
 626     ;; set the new header and footer
 627     (ewoc-set-hf cvs-cookies
 628                  str (concat "\n--------------------- "
 629                              (if tin "End" "Empty")
 630                              " ---------------------\n"
 631                              done))))
 632
 633
 634 (defun cvs-sentinel (proc msg)
 635   "Sentinel for the cvs update process.
 636 This is responsible for parsing the output from the cvs update when
 637 it is finished."
 638   (when (memq (process-status proc) '(signal exit))
 639     (if (null (buffer-name (process-buffer proc)))
 640         ;;(set-process-buffer proc nil)
 641         (error "cvs' process buffer was killed")
 642       (let* ((obuf (current-buffer))
 643              (procbuffer (process-buffer proc)))
 644         (set-buffer (with-current-buffer procbuffer cvs-buffer))
 645         (setq cvs-mode-line-process (symbol-name (process-status proc)))
 646         (force-mode-line-update)
 647         (set-buffer procbuffer)
 648         (let ((cvs-postproc cvs-postprocess))
 649           ;; Since the buffer and mode line will show that the
 650           ;; process is dead, we can delete it now.  Otherwise it
 651           ;; will stay around until M-x list-processes.
 652           (delete-process proc)
 653           (setq cvs-postprocess nil)
 654           ;; do the postprocessing like parsing and such
 655           (save-excursion (eval cvs-postproc))
 656           ;; check whether something is left
 657           (unless cvs-postprocess
 658             ;; IIRC, we enable undo again once the process is finished
 659             ;; for cases where the output was inserted in *vc-diff* or
 660             ;; in a file-like buffer.  -stef
 661             (buffer-enable-undo)
 662             (with-current-buffer cvs-buffer
 663               (message "CVS process has completed in %s" (buffer-name)))))
 664         ;; This might not even be necessary
 665         (set-buffer obuf)))))
 666
 667 (defun cvs-parse-process (dcd &optional subdir old-fis)
 668   "Parse the output of a cvs process.
 669 DCD is the `dont-change-disc' flag to use when parsing that output.
 670 SUBDIR is the subdirectory (if any) where this command was run.
 671 OLD-FIS is the list of fileinfos on which the cvs command was applied and
 672   which should be considered up-to-date if they are missing from the output."
 673   (when (eq system-type 'darwin)
 674     ;; Fixup the ^D^H^H inserted at beginning of buffer sometimes on MacOSX
 675     ;; because of the call to `process-send-eof'.
 676     (save-excursion
 677       (goto-char (point-min))
 678       (while (re-search-forward "^\\^D\b+" nil t)
 679         (let ((inhibit-read-only t))
 680           (delete-region (match-beginning 0) (match-end 0))))))
 681   (let* ((fileinfos (cvs-parse-buffer 'cvs-parse-table dcd subdir))
 682          last)
 683     (with-current-buffer cvs-buffer
 684       ;; Expand OLD-FIS to actual files.
 685       (let ((fis nil))
 686         (dolist (fi old-fis)
 687           (setq fis (if (eq (cvs-fileinfo->type fi) 'DIRCHANGE)
 688                         (nconc (ewoc-collect cvs-cookies 'cvs-dir-member-p
 689                                              (cvs-fileinfo->dir fi))
 690                                fis)
 691                       (cons fi fis))))
 692         (setq old-fis fis))
 693       ;; Drop OLD-FIS which were already up-to-date.
 694       (let ((fis nil))
 695         (dolist (fi old-fis)
 696           (unless (eq (cvs-fileinfo->type fi) 'UP-TO-DATE) (push fi fis)))
 697         (setq old-fis fis))
 698       ;; Add the new fileinfos to the ewoc.
 699       (dolist (fi fileinfos)
 700         (setq last (cvs-addto-collection cvs-cookies fi last))
 701         ;; This FI was in the output, so remove it from OLD-FIS.
 702         (setq old-fis (delq (ewoc-data last) old-fis)))
 703       ;; Process the "silent output" (i.e. absence means up-to-date).
 704       (dolist (fi old-fis)
 705         (setf (cvs-fileinfo->type fi) 'UP-TO-DATE)
 706         (setq last (cvs-addto-collection cvs-cookies fi last)))
 707       (setq fileinfos (nconc old-fis fileinfos))
 708       ;; Clean up the ewoc as requested by the user.
 709       (cvs-cleanup-collection cvs-cookies
 710                               (eq cvs-auto-remove-handled t)
 711                               cvs-auto-remove-directories
 712                               nil)
 713       ;; Revert buffers if necessary.
 714       (when (and cvs-auto-revert (not dcd) (not cvs-from-vc))
 715         (cvs-revert-if-needed fileinfos)))))
 716
 717 (defmacro defun-cvs-mode (fun args docstring interact &rest body)
 718   "Define a function to be used in a *cvs* buffer.
 719 This will look for a *cvs* buffer and execute BODY in it.
 720 Since the interactive arguments might need to be queried after
 721 switching to the *cvs* buffer, the generic code is rather ugly,
 722 but luckily we can often use simpler alternatives.
 723
 724 FUN can be either a symbol (i.e. STYLE is nil) or a cons (FUN . STYLE).
 725 ARGS and DOCSTRING are the normal argument list.
 726 INTERACT is the interactive specification or nil for non-commands.
 727
 728 STYLE can be either SIMPLE, NOARGS or DOUBLE.  It's an error for it
 729 to have any other value, unless other details of the function make it
 730 clear what alternative to use.
 731 - SIMPLE will get all the interactive arguments from the original buffer.
 732 - NOARGS will get all the arguments from the *cvs* buffer and will
 733   always behave as if called interactively.
 734 - DOUBLE is the generic case."
 735   (declare (debug (&define sexp lambda-list stringp ("interactive" interactive) def-body)))
 736   (let ((style (cvs-cdr fun))
 737         (fun (cvs-car fun)))
 738     (cond
 739      ;; a trivial interaction, no need to move it
 740      ((or (eq style 'SIMPLE)
 741           (null (nth 1 interact))
 742           (stringp (nth 1 interact)))
 743       `(defun ,fun ,args ,docstring ,interact
 744          (cvs-mode! (lambda () ,@body))))
 745
 746      ;; fun is only called interactively:  move all the args to the inner fun
 747      ((eq style 'NOARGS)
 748       `(defun ,fun () ,docstring (interactive)
 749          (cvs-mode! (lambda ,args ,interact ,@body))))
 750
 751      ;; bad case
 752      ((eq style 'DOUBLE)
 753       (string-match ".*" docstring)
 754       (let ((line1 (match-string 0 docstring))
 755             (fun-1 (intern (concat (symbol-name fun) "-1"))))
 756         `(progn
 757            (defun ,fun-1 ,args
 758              ,(concat docstring "\nThis function only works within a *cvs* buffer.
 759 For interactive use, use `" (symbol-name fun) "' instead.")
 760              ,interact
 761              ,@body)
 762            (defun ,fun ()
 763              ,(concat line1 "\nWrapper function that switches to a *cvs* buffer
 764 before calling the real function `" (symbol-name fun-1) "'.\n")
 765              (interactive)
 766              (cvs-mode! ',fun-1)))))
 767
 768      (t (error "Unknown style %s in `defun-cvs-mode'" style)))))
 769
 770 (defun-cvs-mode cvs-mode-kill-process ()
 771   "Kill the temporary buffer and associated process."
 772   (interactive)
 773   (when (and (bufferp cvs-temp-buffer) (buffer-name cvs-temp-buffer))
 774     (let ((proc (get-buffer-process cvs-temp-buffer)))
 775       (when proc (delete-process proc)))))
 776
 777 ;;
 778 ;; Maintaining the collection in the face of updates
 779 ;;
 780
 781 (defun cvs-addto-collection (c fi &optional tin)
 782   "Add FI to C and return FI's corresponding tin.
 783 FI is inserted in its proper place or maybe even merged with a preexisting
 784   fileinfo if applicable.
 785 TIN specifies an optional starting point."
 786   (unless tin (setq tin (ewoc-nth c 0)))
 787   (while (and tin (cvs-fileinfo< fi (ewoc-data tin)))
 788     (setq tin (ewoc-prev c tin)))
 789   (if (null tin) (ewoc-enter-first c fi) ;empty collection
 790     (assert (not (cvs-fileinfo< fi (ewoc-data tin))))
 791     (let ((next-tin (ewoc-next c tin)))
 792       (while (not (or (null next-tin)
 793                       (cvs-fileinfo< fi (ewoc-data next-tin))))
 794         (setq tin next-tin next-tin (ewoc-next c next-tin)))
 795       (if (or (cvs-fileinfo< (ewoc-data tin) fi)
 796               (eq (cvs-fileinfo->type  fi) 'MESSAGE))
 797           ;; tin < fi < next-tin
 798           (ewoc-enter-after c tin fi)
 799         ;; fi == tin
 800         (cvs-fileinfo-update (ewoc-data tin) fi)
 801         (ewoc-invalidate c tin)
 802         ;; Move cursor back to where it belongs.
 803         (when (bolp) (cvs-move-to-goal-column))
 804         tin))))
 805
 806 (defcustom cvs-cleanup-functions nil
 807   "Functions to tweak the cleanup process.
 808 The functions are called with a single argument (a FILEINFO) and should
 809 return a non-nil value if that fileinfo should be removed."
 810   :group 'pcl-cvs
 811   :type '(hook :options (cvs-cleanup-removed)))
 812
 813 (defun cvs-cleanup-removed (fi)
 814   "Non-nil if FI has been cvs-removed but still exists.
 815 This is intended for use on `cvs-cleanup-functions' when you have cvs-removed
 816 automatically generated files (which should hence not be under CVS control)
 817 but can't commit the removal because the repository's owner doesn't understand
 818 the problem."
 819   (and (or (eq (cvs-fileinfo->type fi) 'REMOVED)
 820            (and (eq (cvs-fileinfo->type fi) 'CONFLICT)
 821                 (eq (cvs-fileinfo->subtype fi) 'REMOVED)))
 822        (file-exists-p (cvs-fileinfo->full-path fi))))
 823
 824 ;; called at the following times:
 825 ;; - postparse  ((eq cvs-auto-remove-handled t) cvs-auto-remove-directories nil)
 826 ;; - pre-run    ((eq cvs-auto-remove-handled 'delayed) nil t)
 827 ;; - remove-handled (t (or cvs-auto-remove-directories 'handled) t)
 828 ;; - cvs-cmd-do (nil nil t)
 829 ;; - post-ignore (nil nil nil)
 830 ;; - acknowledge (nil nil nil)
 831 ;; - remove     (nil nil nil)
 832 (defun cvs-cleanup-collection (c rm-handled rm-dirs rm-msgs)
 833   "Remove undesired entries.
 834 C is the collection
 835 RM-HANDLED if non-nil means remove handled entries.
 836 RM-DIRS behaves like `cvs-auto-remove-directories'.
 837 RM-MSGS if non-nil means remove messages."
 838   (let (last-fi first-dir (rerun t))
 839     (while rerun
 840       (setq rerun nil)
 841       (setq first-dir t)
 842       (setq last-fi (cvs-create-fileinfo 'DEAD "../" "" "")) ;place-holder
 843       (ewoc-filter
 844        c (lambda (fi)
 845            (let* ((type (cvs-fileinfo->type fi))
 846                   (subtype (cvs-fileinfo->subtype fi))
 847                   (keep
 848                    (case type
 849                      ;; remove temp messages and keep the others
 850                      (MESSAGE (not (or rm-msgs (eq subtype 'TEMP))))
 851                      ;; remove entries
 852                      (DEAD nil)
 853                      ;; handled also?
 854                      (UP-TO-DATE (not rm-handled))
 855                      ;; keep the rest
 856                      (t (not (run-hook-with-args-until-success
 857                               'cvs-cleanup-functions fi))))))
 858
 859              ;; mark dirs for removal
 860              (when (and keep rm-dirs
 861                         (eq (cvs-fileinfo->type last-fi) 'DIRCHANGE)
 862                         (not (when first-dir (setq first-dir nil) t))
 863                         (or (eq rm-dirs 'all)
 864                             (not (cvs-string-prefix-p
 865                                   (cvs-fileinfo->dir last-fi)
 866                                   (cvs-fileinfo->dir fi)))
 867                             (and (eq type 'DIRCHANGE) (eq rm-dirs 'empty))
 868                             (eq subtype 'FOOTER)))
 869                (setf (cvs-fileinfo->type last-fi) 'DEAD)
 870                (setq rerun t))
 871              (when keep (setq last-fi fi)))))
 872       ;; remove empty last dir
 873       (when (and rm-dirs
 874                  (not first-dir)
 875                  (eq (cvs-fileinfo->type last-fi) 'DIRCHANGE))
 876         (setf (cvs-fileinfo->type last-fi) 'DEAD)
 877         (setq rerun t)))))
 878
 879 (defun cvs-get-cvsroot ()
 880   "Gets the CVSROOT for DIR."
 881   (let ((cvs-cvsroot-file (expand-file-name "Root" "CVS")))
 882     (or (cvs-file-to-string cvs-cvsroot-file t)
 883         cvs-cvsroot
 884         (getenv "CVSROOT")
 885         "?????")))
 886
 887 (defun cvs-get-module ()
 888   "Return the current CVS module.
 889 This usually doesn't really work but is a handy initval in a prompt."
 890   (let* ((repfile (expand-file-name "Repository" "CVS"))
 891          (rep (cvs-file-to-string repfile t)))
 892     (cond
 893      ((null rep) "")
 894      ((not (file-name-absolute-p rep)) rep)
 895      (t
 896       (let* ((root (cvs-get-cvsroot))
 897              (str (concat (file-name-as-directory (or root "/")) " || " rep)))
 898         (if (and root (string-match "\\(.*\\) || \\1\\(.*\\)\\'" str))
 899             (match-string 2 str)
 900           (file-name-nondirectory rep)))))))
 901
 902
 903 \f
 904 ;;;;
 905 ;;;; running a "cvs checkout".
 906 ;;;;
 907
 908 ;;;###autoload
 909 (defun cvs-checkout (modules dir flags)
 910   "Run a 'cvs checkout MODULES' in DIR.
 911 Feed the output to a *cvs* buffer, display it in the current window,
 912 and run `cvs-mode' on it.
 913
 914 With a prefix argument, prompt for cvs FLAGS to use."
 915   (interactive
 916    (list (cvs-string->strings (read-string "Module(s): " (cvs-get-module)))
 917          (read-directory-name "CVS Checkout Directory: "
 918                          nil default-directory nil)
 919          (cvs-add-branch-prefix
 920           (cvs-flags-query 'cvs-checkout-flags "cvs checkout flags"))))
 921   (when (eq flags t)
 922     (setf flags (cvs-flags-query 'cvs-checkout-flags nil 'noquery)))
 923   (cvs-cmd-do "checkout" (or dir default-directory)
 924               (append flags modules) nil 'new
 925               :noexist t))
 926
 927 (defun-cvs-mode (cvs-mode-checkout . NOARGS) (dir)
 928   "Run cvs checkout against the current branch.
 929 The files are stored to DIR."
 930   (interactive
 931    (let* ((branch (cvs-prefix-get 'cvs-branch-prefix))
 932           (prompt (format "CVS Checkout Directory for `%s%s': "
 933                          (cvs-get-module)
 934                          (if branch (format " (branch: %s)" branch)
 935                            ""))))
 936      (list (read-directory-name prompt nil default-directory nil))))
 937   (let ((modules (cvs-string->strings (cvs-get-module)))
 938         (flags (cvs-add-branch-prefix
 939                 (cvs-flags-query 'cvs-checkout-flags "cvs checkout flags")))
 940         (cvs-cvsroot (cvs-get-cvsroot)))
 941     (cvs-checkout modules dir flags)))
 942 \f
 943 ;;;;
 944 ;;;; The code for running a "cvs update" and friends in various ways.
 945 ;;;;
 946
 947 (defun-cvs-mode (cvs-mode-revert-buffer . SIMPLE)
 948                 (&optional ignore-auto noconfirm)
 949   "Rerun `cvs-examine' on the current directory with the default flags."
 950   (interactive)
 951   (cvs-examine default-directory t))
 952
 953 (defun cvs-query-directory (msg)
 954   ;; last-command-char = ?\r hints that the command was run via M-x
 955   (if (and (cvs-buffer-p)
 956            (not current-prefix-arg)
 957            (not (eq last-command-char ?\r)))
 958       default-directory
 959     (read-directory-name msg nil default-directory nil)))
 960
 961 ;;;###autoload
 962 (defun cvs-quickdir (dir &optional flags noshow)
 963   "Open a *cvs* buffer on DIR without running cvs.
 964 With a prefix argument, prompt for a directory to use.
 965 A prefix arg >8 (ex: \\[universal-argument] \\[universal-argument]),
 966   prevents reuse of an existing *cvs* buffer.
 967 Optional argument NOSHOW if non-nil means not to display the buffer.
 968 FLAGS is ignored."
 969   (interactive (list (cvs-query-directory "CVS quickdir (directory): ")))
 970   ;; FIXME: code duplication with cvs-cmd-do and cvs-parse-process
 971   (let* ((dir (file-name-as-directory
 972                (abbreviate-file-name (expand-file-name dir))))
 973          (new (> (prefix-numeric-value current-prefix-arg) 8))
 974          (cvsbuf (cvs-make-cvs-buffer dir new))
 975          last)
 976     ;; Check that dir is under CVS control.
 977     (unless (file-directory-p dir)
 978       (error "%s is not a directory" dir))
 979     (unless (file-directory-p (expand-file-name "CVS" dir))
 980       (error "%s does not contain CVS controlled files" dir))
 981     (set-buffer cvsbuf)
 982     (dolist (fi (cvs-fileinfo-from-entries ""))
 983       (setq last (cvs-addto-collection cvs-cookies fi last)))
 984     (cvs-cleanup-collection cvs-cookies
 985                             (eq cvs-auto-remove-handled t)
 986                             cvs-auto-remove-directories
 987                             nil)
 988     (if noshow cvsbuf
 989       (let ((pop-up-windows nil)) (pop-to-buffer cvsbuf)))))
 990
 991 ;;;###autoload
 992 (defun cvs-examine (directory flags &optional noshow)
 993   "Run a `cvs -n update' in the specified DIRECTORY.
 994 That is, check what needs to be done, but don't change the disc.
 995 Feed the output to a *cvs* buffer and run `cvs-mode' on it.
 996 With a prefix argument, prompt for a directory and cvs FLAGS to use.
 997 A prefix arg >8 (ex: \\[universal-argument] \\[universal-argument]),
 998   prevents reuse of an existing *cvs* buffer.
 999 Optional argument NOSHOW if non-nil means not to display the buffer."
1000   (interactive (list (cvs-query-directory "CVS Examine (directory): ")
1001                      (cvs-flags-query 'cvs-update-flags "cvs -n update flags")))
1002   (when (eq flags t)
1003     (setf flags (cvs-flags-query 'cvs-update-flags nil 'noquery)))
1004   (when find-file-visit-truename (setq directory (file-truename directory)))
1005   (cvs-cmd-do "update" directory flags nil
1006               (> (prefix-numeric-value current-prefix-arg) 8)
1007               :cvsargs '("-n")
1008               :noshow noshow
1009               :dont-change-disc t))
1010
1011
1012 ;;;###autoload
1013 (defun cvs-update (directory flags)
1014   "Run a `cvs update' in the current working DIRECTORY.
1015 Feed the output to a *cvs* buffer and run `cvs-mode' on it.
1016 With a \\[universal-argument] prefix argument, prompt for a directory to use.
1017 A prefix arg >8 (ex: \\[universal-argument] \\[universal-argument]),
1018   prevents reuse of an existing *cvs* buffer.
1019 The prefix is also passed to `cvs-flags-query' to select the FLAGS
1020   passed to cvs."
1021   (interactive (list (cvs-query-directory "CVS Update (directory): ")
1022                      (cvs-flags-query 'cvs-update-flags "cvs update flags")))
1023   (when (eq flags t)
1024     (setf flags (cvs-flags-query 'cvs-update-flags nil 'noquery)))
1025   (cvs-cmd-do "update" directory flags nil
1026               (> (prefix-numeric-value current-prefix-arg) 8)))
1027
1028
1029 ;;;###autoload
1030 (defun cvs-status (directory flags &optional noshow)
1031   "Run a `cvs status' in the current working DIRECTORY.
1032 Feed the output to a *cvs* buffer and run `cvs-mode' on it.
1033 With a prefix argument, prompt for a directory and cvs FLAGS to use.
1034 A prefix arg >8 (ex: \\[universal-argument] \\[universal-argument]),
1035   prevents reuse of an existing *cvs* buffer.
1036 Optional argument NOSHOW if non-nil means not to display the buffer."
1037   (interactive (list (cvs-query-directory "CVS Status (directory): ")
1038                      (cvs-flags-query 'cvs-status-flags "cvs status flags")))
1039   (when (eq flags t)
1040     (setf flags (cvs-flags-query 'cvs-status-flags nil 'noquery)))
1041   (cvs-cmd-do "status" directory flags nil
1042               (> (prefix-numeric-value current-prefix-arg) 8)
1043               :noshow noshow :dont-change-disc t))
1044
1045 (defun cvs-update-filter (proc string)
1046   "Filter function for pcl-cvs.
1047 This function gets the output that CVS sends to stdout.  It inserts
1048 the STRING into (process-buffer PROC) but it also checks if CVS is waiting
1049 for a lock file.  If so, it inserts a message cookie in the *cvs* buffer."
1050   (save-match-data
1051     (with-current-buffer (process-buffer proc)
1052       (let ((inhibit-read-only t))
1053         (save-excursion
1054           ;; Insert the text, moving the process-marker.
1055           (goto-char (process-mark proc))
1056           (insert string)
1057           (set-marker (process-mark proc) (point))
1058           ;; FIXME: Delete any old lock message
1059           ;;(if (tin-nth cookies 1)
1060           ;;  (tin-delete cookies
1061           ;;          (tin-nth cookies 1)))
1062           ;; Check if CVS is waiting for a lock.
1063           (beginning-of-line 0)       ;Move to beginning of last complete line.
1064           (when (looking-at "^[ a-z]+: \\(.*waiting for .*lock in \\(.*\\)\\)$")
1065             (let ((msg (match-string 1))
1066                   (lock (match-string 2)))
1067               (with-current-buffer cvs-buffer
1068                 (set (make-local-variable 'cvs-lock-file) lock)
1069                 ;; display the lock situation in the *cvs* buffer:
1070                 (ewoc-enter-last
1071                  cvs-cookies
1072                  (cvs-create-fileinfo
1073                   'MESSAGE "" " "
1074                   (concat msg
1075                           (when (file-exists-p lock)
1076                             (substitute-command-keys
1077                              "\n\t(type \\[cvs-mode-delete-lock] to delete it)")))
1078                   :subtype 'TEMP))
1079                 (pop-to-buffer (current-buffer))
1080                 (goto-char (point-max))
1081                 (beep)))))))))
1082
1083 \f
1084 ;;;;
1085 ;;;; The cvs-mode and its associated commands.
1086 ;;;;
1087
1088 (cvs-prefix-define cvs-force-command "" "" '("/F") cvs-qtypedesc-string1)
1089 (defun-cvs-mode cvs-mode-force-command (arg)
1090   "Force the next cvs command to operate on all the selected files.
1091 By default, cvs commands only operate on files on which the command
1092 \"makes sense\".  This overrides the safety feature on the next cvs command.
1093 It actually behaves as a toggle.  If prefixed by \\[universal-argument] \\[universal-argument],
1094 the override will persist until the next toggle."
1095   (interactive "P")
1096   (cvs-prefix-set 'cvs-force-command arg))
1097
1098 (put 'cvs-mode 'mode-class 'special)
1099 (define-derived-mode cvs-mode nil "CVS"
1100   "Mode used for PCL-CVS, a frontend to CVS.
1101 Full documentation is in the Texinfo file."
1102   (setq mode-line-process
1103         '("" cvs-force-command cvs-ignore-marks-modif
1104           ":" (cvs-branch-prefix
1105                ("" cvs-branch-prefix (cvs-secondary-branch-prefix
1106                                       ("->" cvs-secondary-branch-prefix))))
1107           " " cvs-mode-line-process))
1108   (if buffer-file-name
1109       (error "Use M-x cvs-quickdir to get a *cvs* buffer."))
1110   (buffer-disable-undo)
1111   ;;(set (make-local-variable 'goal-column) cvs-cursor-column)
1112   (set (make-local-variable 'revert-buffer-function) 'cvs-mode-revert-buffer)
1113   (setq truncate-lines t)
1114   (cvs-prefix-make-local 'cvs-branch-prefix)
1115   (cvs-prefix-make-local 'cvs-secondary-branch-prefix)
1116   (cvs-prefix-make-local 'cvs-force-command)
1117   (cvs-prefix-make-local 'cvs-ignore-marks-modif)
1118   (make-local-variable 'cvs-mode-line-process)
1119   (make-local-variable 'cvs-temp-buffers))
1120
1121
1122 (defun cvs-buffer-p (&optional buffer)
1123   "Return whether the (by default current) BUFFER is a `cvs-mode' buffer."
1124   (save-excursion
1125     (if buffer (set-buffer buffer))
1126     (and (eq major-mode 'cvs-mode))))
1127
1128 (defun cvs-buffer-check ()
1129   "Check that the current buffer follows cvs-buffer's conventions."
1130   (let ((buf (current-buffer))
1131         (check 'none))
1132     (or (and (setq check 'collection)
1133              (eq (ewoc-buffer cvs-cookies) buf)
1134              (setq check 'cvs-temp-buffer)
1135              (or (null cvs-temp-buffer)
1136                  (null (buffer-name cvs-temp-buffer))
1137                  (and (eq (with-current-buffer cvs-temp-buffer cvs-buffer) buf)
1138                       (equal (with-current-buffer cvs-temp-buffer
1139                                default-directory)
1140                              default-directory)))
1141              t)
1142         (error "Inconsistent %s in buffer %s" check (buffer-name buf)))))
1143
1144
1145 (defun cvs-mode-quit ()
1146   "Quit PCL-CVS, killing the *cvs* buffer."
1147   (interactive)
1148   (and (y-or-n-p "Quit pcl-cvs? ") (kill-buffer (current-buffer))))
1149
1150 ;; Give help....
1151
1152 (defun cvs-help ()
1153   "Display help for various PCL-CVS commands."
1154   (interactive)
1155   (if (eq last-command 'cvs-help)
1156       (describe-function 'cvs-mode)   ; would need minor-mode for log-edit-mode
1157     (message
1158      (substitute-command-keys
1159       "`\\[cvs-help]':help `\\[cvs-mode-add]':add `\\[cvs-mode-commit]':commit \
1160 `\\[cvs-mode-diff-map]':diff* `\\[cvs-mode-log]':log \
1161 `\\[cvs-mode-remove]':remove `\\[cvs-mode-status]':status \
1162 `\\[cvs-mode-undo]':undo"))))
1163
1164 ;; Move around in the buffer
1165
1166 (defun cvs-move-to-goal-column ()
1167   (let* ((eol (line-end-position))
1168          (fpos (next-single-property-change (point) 'cvs-goal-column nil eol)))
1169     (when (< fpos eol)
1170       (goto-char fpos))))
1171
1172 (defun-cvs-mode cvs-mode-previous-line (arg)
1173   "Go to the previous line.
1174 If a prefix argument is given, move by that many lines."
1175   (interactive "p")
1176   (ewoc-goto-prev cvs-cookies arg)
1177   (cvs-move-to-goal-column))
1178
1179 (defun-cvs-mode cvs-mode-next-line (arg)
1180   "Go to the next line.
1181 If a prefix argument is given, move by that many lines."
1182   (interactive "p")
1183   (ewoc-goto-next cvs-cookies arg)
1184   (cvs-move-to-goal-column))
1185
1186 ;;;;
1187 ;;;; Mark handling
1188 ;;;;
1189
1190 (defun-cvs-mode cvs-mode-mark (&optional arg)
1191   "Mark the fileinfo on the current line.
1192 If the fileinfo is a directory, all the contents of that directory are
1193 marked instead. A directory can never be marked."
1194   (interactive)
1195   (let* ((tin (ewoc-locate cvs-cookies))
1196          (fi (ewoc-data tin)))
1197     (if (eq (cvs-fileinfo->type fi) 'DIRCHANGE)
1198         ;; it's a directory: let's mark all files inside
1199         (ewoc-map
1200          (lambda (f dir)
1201            (when (cvs-dir-member-p f dir)
1202              (setf (cvs-fileinfo->marked f)
1203                    (not (if (eq arg 'toggle) (cvs-fileinfo->marked f) arg)))
1204              t))                        ;Tell cookie to redisplay this cookie.
1205          cvs-cookies
1206          (cvs-fileinfo->dir fi))
1207       ;; not a directory: just do the obvious
1208       (setf (cvs-fileinfo->marked fi)
1209             (not (if (eq arg 'toggle) (cvs-fileinfo->marked fi) arg)))
1210       (ewoc-invalidate cvs-cookies tin)
1211       (cvs-mode-next-line 1))))
1212
1213 (defalias 'cvs-mouse-toggle-mark 'cvs-mode-toggle-mark)
1214 (defun cvs-mode-toggle-mark (e)
1215   "Toggle the mark of the entry at point."
1216   (interactive (list last-input-event))
1217   (save-excursion
1218     (posn-set-point (event-end e))
1219     (cvs-mode-mark 'toggle)))
1220
1221 (defun-cvs-mode cvs-mode-unmark ()
1222   "Unmark the fileinfo on the current line."
1223   (interactive)
1224   (cvs-mode-mark t))
1225
1226 (defun-cvs-mode cvs-mode-mark-all-files ()
1227   "Mark all files."
1228   (interactive)
1229   (ewoc-map (lambda (cookie)
1230               (unless (eq (cvs-fileinfo->type cookie) 'DIRCHANGE)
1231                 (setf (cvs-fileinfo->marked cookie) t)))
1232             cvs-cookies))
1233
1234 (defun-cvs-mode (cvs-mode-mark-on-state . SIMPLE) (state)
1235   "Mark all files in state STATE."
1236   (interactive
1237    (list
1238     (let ((default
1239             (condition-case nil
1240                 (downcase
1241                  (symbol-name
1242                   (cvs-fileinfo->type
1243                    (cvs-mode-marked nil nil :read-only t :one t :noquery t))))
1244               (error nil))))
1245       (intern
1246        (upcase
1247         (completing-read
1248          (concat
1249           "Mark files in state" (if default (concat " [" default "]")) ": ")
1250          (mapcar (lambda (x)
1251                    (list (downcase (symbol-name (car x)))))
1252                  cvs-states)
1253          nil t nil nil default))))))
1254   (ewoc-map (lambda (fi)
1255               (when (eq (cvs-fileinfo->type fi) state)
1256                 (setf (cvs-fileinfo->marked fi) t)))
1257             cvs-cookies))
1258
1259 (defun-cvs-mode cvs-mode-mark-matching-files (regex)
1260   "Mark all files matching REGEX."
1261   (interactive "sMark files matching: ")
1262   (ewoc-map (lambda (cookie)
1263               (when (and (not (eq (cvs-fileinfo->type cookie) 'DIRCHANGE))
1264                          (string-match regex (cvs-fileinfo->file cookie)))
1265                 (setf (cvs-fileinfo->marked cookie) t)))
1266             cvs-cookies))
1267
1268 (defun-cvs-mode cvs-mode-unmark-all-files ()
1269   "Unmark all files.
1270 Directories are also unmarked, but that doesn't matter, since
1271 they should always be unmarked."
1272   (interactive)
1273   (ewoc-map (lambda (cookie)
1274               (setf (cvs-fileinfo->marked cookie) nil)
1275               t)
1276             cvs-cookies))
1277
1278 (defun-cvs-mode cvs-mode-unmark-up ()
1279   "Unmark the file on the previous line."
1280   (interactive)
1281   (let ((tin (ewoc-goto-prev cvs-cookies 1)))
1282     (when tin
1283       (setf (cvs-fileinfo->marked (ewoc-data tin)) nil)
1284       (ewoc-invalidate cvs-cookies tin)))
1285   (cvs-move-to-goal-column))
1286
1287 (defconst cvs-ignore-marks-alternatives
1288   '(("toggle-marks"     . "/TM")
1289     ("force-marks"      . "/FM")
1290     ("ignore-marks"     . "/IM")))
1291
1292 (cvs-prefix-define cvs-ignore-marks-modif
1293   "Prefix to decide whether to ignore marks or not."
1294   "active"
1295   (mapcar 'cdr cvs-ignore-marks-alternatives)
1296   (cvs-qtypedesc-create
1297    (lambda (str) (cdr (assoc str cvs-ignore-marks-alternatives)))
1298    (lambda (obj) (car (rassoc obj cvs-ignore-marks-alternatives)))
1299    (lambda () cvs-ignore-marks-alternatives)
1300    nil t))
1301
1302 (defun-cvs-mode cvs-mode-toggle-marks (arg)
1303   "Toggle whether the next CVS command uses marks.
1304 See `cvs-prefix-set' for further description of the behavior.
1305 \\[universal-argument] 1 selects `force-marks',
1306 \\[universal-argument] 2 selects `ignore-marks',
1307 \\[universal-argument] 3 selects `toggle-marks'."
1308   (interactive "P")
1309   (cvs-prefix-set 'cvs-ignore-marks-modif arg))
1310
1311 (defun cvs-ignore-marks-p (cmd &optional read-only)
1312   (let ((default (if (member cmd cvs-invert-ignore-marks)
1313                      (not cvs-default-ignore-marks)
1314                    cvs-default-ignore-marks))
1315         (modif (cvs-prefix-get 'cvs-ignore-marks-modif read-only)))
1316     (cond
1317      ((equal modif "/IM") t)
1318      ((equal modif "/TM") (not default))
1319      ((equal modif "/FM") nil)
1320      (t default))))
1321
1322 (defun cvs-mode-mark-get-modif (cmd)
1323   (if (cvs-ignore-marks-p cmd 'read-only) "/IM" "/FM"))
1324
1325 (defun cvs-get-marked (&optional ignore-marks ignore-contents)
1326   "Return a list of all selected fileinfos.
1327 If there are any marked tins, and IGNORE-MARKS is nil, return them.
1328 Otherwise, if the cursor selects a directory, and IGNORE-CONTENTS is
1329 nil, return all files in it, else return just the directory.
1330 Otherwise return (a list containing) the file the cursor points to, or
1331 an empty list if it doesn't point to a file at all."
1332   (let ((fis nil))
1333     (dolist (fi (if (and (boundp 'cvs-minor-current-files)
1334                          (consp cvs-minor-current-files))
1335                     (mapcar
1336                      (lambda (f)
1337                        (if (cvs-fileinfo-p f) f
1338                          (let ((f (file-relative-name f)))
1339                            (if (file-directory-p f)
1340                                (cvs-create-fileinfo
1341                                 'DIRCHANGE (file-name-as-directory f) "." "")
1342                              (let ((dir (file-name-directory f))
1343                                    (file (file-name-nondirectory f)))
1344                                (cvs-create-fileinfo
1345                                 'UNKNOWN (or dir "") file ""))))))
1346                      cvs-minor-current-files)
1347                   (or (and (not ignore-marks)
1348                            (ewoc-collect cvs-cookies 'cvs-fileinfo->marked))
1349                       (list (ewoc-data (ewoc-locate cvs-cookies))))))
1350
1351       (if (or ignore-contents (not (eq (cvs-fileinfo->type fi) 'DIRCHANGE)))
1352           (push fi fis)
1353         ;; If a directory is selected, return members, if any.
1354         (setq fis
1355               (append (ewoc-collect
1356                        cvs-cookies 'cvs-dir-member-p (cvs-fileinfo->dir fi))
1357                       fis))))
1358     (nreverse fis)))
1359
1360 (defun* cvs-mode-marked (filter &optional cmd
1361                                 &key read-only one file noquery)
1362   "Get the list of marked FIS.
1363 CMD is used to determine whether to use the marks or not.
1364 Only files for which FILTER is applicable are returned.
1365 If READ-ONLY is non-nil, the current toggling is left intact.
1366 If ONE is non-nil, marks are ignored and a single FI is returned.
1367 If FILE is non-nil, directory entries won't be selected."
1368   (unless cmd (setq cmd (symbol-name filter)))
1369   (let* ((fis (cvs-get-marked (or one (cvs-ignore-marks-p cmd read-only))
1370                               (and (not file)
1371                                    (cvs-applicable-p 'DIRCHANGE filter))))
1372          (force (cvs-prefix-get 'cvs-force-command))
1373          (fis (car (cvs-partition
1374                     (lambda (fi) (cvs-applicable-p fi (and (not force) filter)))
1375                     fis))))
1376     (when (and (or (null fis) (and one (cdr fis))) (not noquery))
1377       (message (if (null fis)
1378                    "`%s' is not applicable to any of the selected files."
1379                  "`%s' is only applicable to a single file.") cmd)
1380       (sit-for 1)
1381       (setq fis (list (cvs-insert-file
1382                        (read-file-name (format "File to %s: " cmd))))))
1383     (if one (car fis) fis)))
1384
1385 (defun cvs-enabledp (filter)
1386   "Determine whether FILTER applies to at least one of the selected files."
1387   (ignore-errors (cvs-mode-marked filter nil :read-only t :noquery t)))
1388
1389 (defun cvs-mode-files (&rest -cvs-mode-files-args)
1390   (cvs-mode!
1391    (lambda ()
1392      (mapcar 'cvs-fileinfo->full-path
1393              (apply 'cvs-mode-marked -cvs-mode-files-args)))))
1394
1395 ;;
1396 ;; Interface between Log-Edit and PCL-CVS
1397 ;;
1398
1399 (defun cvs-mode-commit-setup ()
1400   "Run `cvs-mode-commit' with setup."
1401   (interactive)
1402   (cvs-mode-commit 'force))
1403
1404 (defcustom cvs-mode-commit-hook nil
1405   "Hook run after setting up the commit buffer."
1406   :type 'hook
1407   :options '(cvs-mode-diff)
1408   :group 'pcl-cvs)
1409
1410 (defun cvs-mode-commit (setup)
1411   "Check in all marked files, or the current file.
1412 The user will be asked for a log message in a buffer.
1413 The buffer's mode and name is determined by the \"message\" setting
1414   of `cvs-buffer-name-alist'.
1415 The POSTPROC specified there (typically `log-edit') is then called,
1416   passing it the SETUP argument."
1417   (interactive "P")
1418   ;; It seems that the save-excursion that happens if I use the better
1419   ;; form of `(cvs-mode! (lambda ...))' screws up a couple things which
1420   ;; end up being rather annoying (like log-edit-mode's message being
1421   ;; displayed in the wrong minibuffer).
1422   (cvs-mode!)
1423   (let ((buf (cvs-temp-buffer "message" 'normal 'nosetup))
1424         (lbd list-buffers-directory)
1425         (setupfun (or (nth 2 (cdr (assoc "message" cvs-buffer-name-alist)))
1426                       'log-edit)))
1427     (funcall setupfun 'cvs-do-commit setup 'cvs-commit-filelist buf)
1428     (set (make-local-variable 'cvs-minor-wrap-function) 'cvs-commit-minor-wrap)
1429     (set (make-local-variable 'list-buffers-directory) lbd)
1430     (run-hooks 'cvs-mode-commit-hook)))
1431
1432 (defun cvs-commit-minor-wrap (buf f)
1433   (let ((cvs-ignore-marks-modif (cvs-mode-mark-get-modif "commit")))
1434     (funcall f)))
1435
1436 (defun cvs-commit-filelist ()
1437   (cvs-mode-files 'commit nil :read-only t :file t :noquery t))
1438
1439 (defun cvs-do-commit (flags)
1440   "Do the actual commit, using the current buffer as the log message."
1441   (interactive (list (cvs-flags-query 'cvs-commit-flags "cvs commit flags")))
1442   (let ((msg (buffer-substring-no-properties (point-min) (point-max))))
1443     (cvs-mode!)
1444     ;;(pop-to-buffer cvs-buffer)
1445     (cvs-mode-do "commit" (list* "-m" msg flags) 'commit)))
1446
1447
1448 ;;;; Editing existing commit log messages.
1449
1450 (defun cvs-edit-log-text-at-point ()
1451   (save-excursion
1452     (end-of-line)
1453     (when (re-search-backward "^revision " nil t)
1454       (forward-line 1)
1455       (if (looking-at "date:") (forward-line 1))
1456       (if (looking-at "branches:") (forward-line 1))
1457       (buffer-substring
1458        (point)
1459        (if (re-search-forward
1460             "^\\(-\\{28\\}\\|=\\{77\\}\\|revision [.0-9]+\\)$"
1461             nil t)
1462            (match-beginning 0)
1463          (point))))))
1464
1465 (defvar cvs-edit-log-revision)
1466 (defun cvs-mode-edit-log (rev &optional text)
1467   "Edit the log message at point.
1468 This is best called from a `log-view-mode' buffer."
1469   (interactive
1470    (list
1471     (or (cvs-mode! (lambda () (cvs-prefix-get 'cvs-branch-prefix)))
1472         (read-string "Revision to edit: "))
1473     (cvs-edit-log-text-at-point)))
1474   ;; It seems that the save-excursion that happens if I use the better
1475   ;; form of `(cvs-mode! (lambda ...))' screws up a couple things which
1476   ;; end up being rather annoying (like log-edit-mode's message being
1477   ;; displayed in the wrong minibuffer).
1478   (cvs-mode!)
1479   (let ((buf (cvs-temp-buffer "message" 'normal 'nosetup))
1480         (lbd list-buffers-directory)
1481         (setupfun (or (nth 2 (cdr (assoc "message" cvs-buffer-name-alist)))
1482                       'log-edit)))
1483     (funcall setupfun 'cvs-do-edit-log nil 'cvs-edit-log-filelist buf)
1484     (when text (erase-buffer) (insert text))
1485     (set (make-local-variable 'cvs-edit-log-revision) rev)
1486     (set (make-local-variable 'cvs-minor-wrap-function) 'cvs-edit-log-minor-wrap)
1487     (set (make-local-variable 'list-buffers-directory) lbd)
1488     ;; (run-hooks 'cvs-mode-commit-hook)
1489     ))
1490
1491 (defun cvs-edit-log-minor-wrap (buf f)
1492   (let ((cvs-ignore-marks-modif (cvs-mode-mark-get-modif "commit")))
1493     (funcall f)))
1494
1495 (defun cvs-edit-log-filelist ()
1496   (cvs-mode-files nil nil :read-only t :file t :noquery t))
1497
1498 (defun cvs-do-edit-log (rev)
1499   "Do the actual commit, using the current buffer as the log message."
1500   (interactive (list cvs-edit-log-revision))
1501   (let ((msg (buffer-substring-no-properties (point-min) (point-max))))
1502     (cvs-mode!)
1503     (cvs-mode-do "admin" (list (concat "-m" rev ":" msg)) nil)))
1504
1505
1506 ;;;;
1507 ;;;; CVS Mode commands
1508 ;;;;
1509
1510 (defun-cvs-mode (cvs-mode-insert . NOARGS) (file)
1511   "Insert an entry for a specific file into the current listing.
1512 This is typically used if the file is up-to-date (or has been added
1513 outside of PCL-CVS) and one wants to do some operation on it."
1514   (interactive
1515    (list (read-file-name
1516           "File to insert: "
1517           ;; Can't use ignore-errors here because interactive
1518           ;; specs aren't byte-compiled.
1519           (condition-case nil
1520               (file-name-as-directory
1521                (expand-file-name
1522                 (cvs-fileinfo->dir
1523                  (cvs-mode-marked nil nil :read-only t :one t :noquery t))))
1524             (error nil)))))
1525   (cvs-insert-file file))
1526
1527 (defun cvs-insert-file (file)
1528   "Insert FILE (and its contents if it's a dir) and return its FI."
1529   (let ((file (file-relative-name (directory-file-name file))) last)
1530     (dolist (fi (cvs-fileinfo-from-entries file))
1531       (setq last (cvs-addto-collection cvs-cookies fi last)))
1532     ;; There should have been at least one entry.
1533     (goto-char (ewoc-location last))
1534     (ewoc-data last)))
1535
1536 (defun cvs-mark-fis-dead (fis)
1537   ;; Helper function, introduced because of the need for macro-expansion.
1538   (dolist (fi fis)
1539     (setf (cvs-fileinfo->type fi) 'DEAD)))
1540
1541 (defun-cvs-mode (cvs-mode-add . SIMPLE) (flags)
1542   "Add marked files to the cvs repository.
1543 With prefix argument, prompt for cvs flags."
1544   (interactive (list (cvs-flags-query 'cvs-add-flags "cvs add flags")))
1545   (let ((fis (cvs-mode-marked 'add))
1546         (needdesc nil) (dirs nil))
1547     ;; find directories and look for fis needing a description
1548     (dolist (fi fis)
1549       (cond
1550        ((file-directory-p (cvs-fileinfo->full-path fi)) (push fi dirs))
1551        ((eq (cvs-fileinfo->type fi) 'UNKNOWN) (setq needdesc t))))
1552     ;; prompt for description if necessary
1553     (let* ((msg (if (and needdesc
1554                          (or current-prefix-arg (not cvs-add-default-message)))
1555                     (read-from-minibuffer "Enter description: ")
1556                   (or cvs-add-default-message "")))
1557            (flags (list* "-m" msg flags))
1558            (postproc
1559             ;; setup postprocessing for the directory entries
1560             (when dirs
1561               `((cvs-run-process (list "-n" "update")
1562                                  ',dirs
1563                                  '(cvs-parse-process t))
1564                 (cvs-mark-fis-dead ',dirs)))))
1565       (cvs-mode-run "add" flags fis :postproc postproc))))
1566
1567 (defun-cvs-mode (cvs-mode-diff . DOUBLE) (flags)
1568   "Diff the selected files against the repository.
1569 This command compares the files in your working area against the
1570 revision which they are based upon."
1571   (interactive
1572    (list (cvs-add-branch-prefix
1573           (cvs-add-secondary-branch-prefix
1574            (cvs-flags-query 'cvs-diff-flags "cvs diff flags")))))
1575   (cvs-mode-do "diff" flags 'diff
1576                :show t)) ;; :ignore-exit t
1577
1578 (defun-cvs-mode (cvs-mode-diff-head . SIMPLE) (flags)
1579   "Diff the selected files against the head of the current branch.
1580 See ``cvs-mode-diff'' for more info."
1581   (interactive (list (cvs-flags-query 'cvs-diff-flags "cvs diff flags")))
1582   (cvs-mode-diff-1 (cons "-rHEAD" flags)))
1583
1584 (defun-cvs-mode (cvs-mode-diff-repository . SIMPLE) (flags)
1585   "Diff the files for changes in the repository since last co/update/commit.
1586 See ``cvs-mode-diff'' for more info."
1587   (interactive (list (cvs-flags-query 'cvs-diff-flags "cvs diff flags")))
1588   (cvs-mode-diff-1 (cons "-rBASE" (cons "-rHEAD" flags))))
1589
1590 (defun-cvs-mode (cvs-mode-diff-yesterday . SIMPLE) (flags)
1591   "Diff the selected files against yesterday's head of the current branch.
1592 See ``cvs-mode-diff'' for more info."
1593   (interactive (list (cvs-flags-query 'cvs-diff-flags "cvs diff flags")))
1594   (cvs-mode-diff-1 (cons "-Dyesterday" flags)))
1595
1596 (defun-cvs-mode (cvs-mode-diff-vendor . SIMPLE) (flags)
1597   "Diff the selected files against the head of the vendor branch.
1598 See ``cvs-mode-diff'' for more info."
1599   (interactive (list (cvs-flags-query 'cvs-diff-flags "cvs diff flags")))
1600   (cvs-mode-diff-1 (cons (concat "-r" cvs-vendor-branch) flags)))
1601
1602 ;; sadly, this is not provided by cvs, so we have to roll our own
1603 (defun-cvs-mode (cvs-mode-diff-backup . SIMPLE) (flags)
1604   "Diff the files against the backup file.
1605 This command can be used on files that are marked with \"Merged\"
1606 or \"Conflict\" in the *cvs* buffer."
1607   (interactive (list (cvs-flags-query 'cvs-diff-flags "diff flags")))
1608   (unless (listp flags) (error "flags should be a list of strings"))
1609   (save-some-buffers)
1610   (let* ((marked (cvs-get-marked (cvs-ignore-marks-p "diff")))
1611          (fis (car (cvs-partition 'cvs-fileinfo->backup-file marked))))
1612     (unless (consp fis)
1613       (error "No files with a backup file selected!"))
1614     ;; let's extract some info into the environment for `buffer-name'
1615     (let* ((dir (cvs-fileinfo->dir (car fis)))
1616            (file (cvs-fileinfo->file (car fis))))
1617       (set-buffer (cvs-temp-buffer "diff")))
1618     (message "cvs diff backup...")
1619     (cvs-execute-single-file-list fis 'cvs-diff-backup-extractor
1620                                   cvs-diff-program flags))
1621   (message "cvs diff backup... Done."))
1622
1623 (defun cvs-diff-backup-extractor (fileinfo)
1624   "Return the filename and the name of the backup file as a list.
1625 Signal an error if there is no backup file."
1626   (let ((backup-file (cvs-fileinfo->backup-file fileinfo)))
1627     (unless backup-file
1628       (error "%s has no backup file" (cvs-fileinfo->full-path fileinfo)))
1629     (list backup-file (cvs-fileinfo->full-path fileinfo))))
1630
1631 ;;
1632 ;; Emerge support
1633 ;;
1634 (defun cvs-emerge-diff (b1 b2) (emerge-buffers b1 b2 b1))
1635 (defun cvs-emerge-merge (b1 b2 base out)
1636   (emerge-buffers-with-ancestor b1 b2 base (find-file-noselect out)))
1637
1638 ;;
1639 ;; Ediff support
1640 ;;
1641
1642 (defvar ediff-after-quit-destination-buffer)
1643 (defvar ediff-after-quit-hook-internal)
1644 (defvar cvs-transient-buffers)
1645 (defun cvs-ediff-startup-hook ()
1646   (add-hook 'ediff-after-quit-hook-internal
1647             `(lambda ()
1648                (cvs-ediff-exit-hook
1649                 ',ediff-after-quit-destination-buffer ',cvs-transient-buffers))
1650             nil 'local))
1651
1652 (defun cvs-ediff-exit-hook (cvs-buf tmp-bufs)
1653   ;; kill the temp buffers (and their associated windows)
1654   (dolist (tb tmp-bufs)
1655     (when (and tb (buffer-live-p tb) (not (buffer-modified-p tb)))
1656       (let ((win (get-buffer-window tb t)))
1657         (kill-buffer tb)
1658         (when (window-live-p win) (ignore-errors (delete-window win))))))
1659   ;; switch back to the *cvs* buffer
1660   (when (and cvs-buf (buffer-live-p cvs-buf)
1661              (not (get-buffer-window cvs-buf t)))
1662     (ignore-errors (switch-to-buffer cvs-buf))))
1663
1664 (defun cvs-ediff-diff (b1 b2)
1665   (let ((ediff-after-quit-destination-buffer (current-buffer))
1666         (startup-hook '(cvs-ediff-startup-hook)))
1667     (ediff-buffers b1 b2 startup-hook 'ediff-revision)))
1668
1669 (defun cvs-ediff-merge (b1 b2 base out)
1670   (let ((ediff-after-quit-destination-buffer (current-buffer))
1671         (startup-hook '(cvs-ediff-startup-hook)))
1672     (ediff-merge-buffers-with-ancestor
1673      b1 b2 base startup-hook
1674      'ediff-merge-revisions-with-ancestor
1675      out)))
1676
1677 ;;
1678 ;; Interactive merge/diff support.
1679 ;;
1680
1681 (defun cvs-retrieve-revision (fileinfo rev)
1682   "Retrieve the given REVision of the file in FILEINFO into a new buffer."
1683   (let* ((file (cvs-fileinfo->full-path fileinfo))
1684          (buffile (concat file "." rev)))
1685     (or (find-buffer-visiting buffile)
1686         (with-current-buffer (create-file-buffer buffile)
1687           (message "Retrieving revision %s..." rev)
1688           ;; Discard stderr output to work around the CVS+SSH+libc
1689           ;; problem when stdout and stderr are the same.
1690           ;; FIXME: this doesn't seem to make any difference :-(
1691           (let ((res (apply 'call-process cvs-program nil '(t . nil) nil
1692                             "-q" "update" "-p"
1693                             ;; If `rev' is HEAD, don't pass it at all:
1694                             ;; the default behavior is to get the head
1695                             ;; of the current branch whereas "-r HEAD"
1696                             ;; stupidly gives you the head of the trunk.
1697                             (append (unless (equal rev "HEAD") (list "-r" rev))
1698                                     (list file)))))
1699             (when (and res (not (and (equal 0 res))))
1700               (error "Something went wrong retrieving revision %s: %s" rev res))
1701             (set-buffer-modified-p nil)
1702             (let ((buffer-file-name (expand-file-name file)))
1703               (after-find-file))
1704             (toggle-read-only 1)
1705             (message "Retrieving revision %s... Done" rev)
1706             (current-buffer))))))
1707
1708 (eval-and-compile (autoload 'smerge-ediff "smerge-mode"))
1709
1710 ;; FIXME: The user should be able to specify ancestor/head/backup and we should
1711 ;; provide sensible defaults when merge info is unavailable (rather than rely
1712 ;; on smerge-ediff).  Also provide sane defaults for need-merge files.
1713 (defun-cvs-mode cvs-mode-imerge ()
1714   "Merge interactively appropriate revisions of the selected file."
1715   (interactive)
1716   (let ((fi (cvs-mode-marked 'merge nil :one t :file t)))
1717     (let ((merge (cvs-fileinfo->merge fi))
1718           (file (cvs-fileinfo->full-path fi))
1719           (backup-file (cvs-fileinfo->backup-file fi)))
1720       (if (not (and merge backup-file))
1721           (let ((buf (find-file-noselect file)))
1722             (message "Missing merge info or backup file, using VC.")
1723             (with-current-buffer buf
1724               (smerge-ediff)))
1725         (let* ((ancestor-buf (cvs-retrieve-revision fi (car merge)))
1726                (head-buf (cvs-retrieve-revision fi (cdr merge)))
1727                (backup-buf (let ((auto-mode-alist nil))
1728                              (find-file-noselect backup-file)))
1729                ;; this binding is used by cvs-ediff-startup-hook
1730                (cvs-transient-buffers (list ancestor-buf backup-buf head-buf)))
1731           (with-current-buffer backup-buf
1732             (let ((buffer-file-name (expand-file-name file)))
1733               (after-find-file)))
1734           (funcall (cdr cvs-idiff-imerge-handlers)
1735                    backup-buf head-buf ancestor-buf file))))))
1736
1737 (cvs-flags-define cvs-idiff-version
1738                   (list "BASE" cvs-vendor-branch cvs-vendor-branch "BASE" "BASE")
1739                   "version: " cvs-qtypedesc-tag)
1740
1741 (defun-cvs-mode (cvs-mode-idiff . NOARGS) (&optional rev1 rev2)
1742   "Diff interactively current file to revisions."
1743   (interactive
1744    (let* ((rev1 (cvs-prefix-get 'cvs-branch-prefix))
1745           (rev2 (and rev1 (cvs-prefix-get 'cvs-secondary-branch-prefix))))
1746      (list (or rev1 (cvs-flags-query 'cvs-idiff-version))
1747            rev2)))
1748   (let ((fi (cvs-mode-marked 'diff "idiff" :one t :file t)))
1749     (let* ((file (cvs-fileinfo->full-path fi))
1750            (rev1-buf (cvs-retrieve-revision fi (or rev1 "BASE")))
1751            (rev2-buf (if rev2 (cvs-retrieve-revision fi rev2)))
1752            ;; this binding is used by cvs-ediff-startup-hook
1753            (cvs-transient-buffers (list rev1-buf rev2-buf)))
1754       (funcall (car cvs-idiff-imerge-handlers)
1755                rev1-buf (or rev2-buf (find-file-noselect file))))))
1756
1757 (defun-cvs-mode (cvs-mode-idiff-other . NOARGS) ()
1758   "Diff interactively current file to revisions."
1759   (interactive)
1760   (let* ((rev1 (cvs-prefix-get 'cvs-branch-prefix))
1761          (rev2 (and rev1 (cvs-prefix-get 'cvs-secondary-branch-prefix)))
1762          (fis (cvs-mode-marked 'diff "idiff" :file t)))
1763     (when (> (length fis) 2)
1764       (error "idiff-other cannot be applied to more than 2 files at a time"))
1765     (let* ((fi1 (car fis))
1766            (rev1-buf (if rev1 (cvs-retrieve-revision fi1 rev1)
1767                        (find-file-noselect (cvs-fileinfo->full-path fi1))))
1768            rev2-buf)
1769       (if (cdr fis)
1770           (let ((fi2 (nth 1 fis)))
1771             (setq rev2-buf
1772                   (if rev2 (cvs-retrieve-revision fi2 rev2)
1773                     (find-file-noselect (cvs-fileinfo->full-path fi2)))))
1774         (error "idiff-other doesn't know what other file/buffer to use"))
1775       (let* (;; this binding is used by cvs-ediff-startup-hook
1776              (cvs-transient-buffers (list rev1-buf rev2-buf)))
1777         (funcall (car cvs-idiff-imerge-handlers)
1778                  rev1-buf rev2-buf)))))
1779
1780
1781 (defun cvs-is-within-p (fis dir)
1782   "Non-nil if buffer is inside one of FIS (in DIR)."
1783   (when (stringp buffer-file-name)
1784     (setq buffer-file-name (expand-file-name buffer-file-name))
1785     (let (ret)
1786       (dolist (fi (or fis (list (cvs-create-fileinfo 'DIRCHANGE "" "." ""))))
1787         (when (cvs-string-prefix-p
1788                (expand-file-name (cvs-fileinfo->full-path fi) dir)
1789                buffer-file-name)
1790           (setq ret t)))
1791       ret)))
1792
1793 (defun* cvs-mode-run (cmd flags fis
1794                       &key (buf (cvs-temp-buffer))
1795                            dont-change-disc cvsargs postproc)
1796   "Generic cvs-mode-<foo> function.
1797 Executes `cvs CVSARGS CMD FLAGS FIS'.
1798 BUF is the buffer to be used for cvs' output.
1799 DONT-CHANGE-DISC non-nil indicates that the command will not change the
1800   contents of files.  This is only used by the parser.
1801 POSTPROC is a list of expressions to be evaluated at the very end (after
1802   parsing if applicable).  It will be prepended with `progn' if necessary."
1803   (let ((def-dir default-directory))
1804     ;; Save the relevant buffers
1805     (save-some-buffers nil (lambda () (cvs-is-within-p fis def-dir))))
1806   (unless (listp flags) (error "flags should be a list of strings"))
1807   ;; Some w32 versions of CVS don't like an explicit . too much.
1808   (when (and (car fis) (null (cdr fis))
1809              (eq (cvs-fileinfo->type (car fis)) 'DIRCHANGE)
1810              ;; (equal (cvs-fileinfo->file (car fis)) ".")
1811              (equal (cvs-fileinfo->dir (car fis)) ""))
1812     (setq fis nil))
1813   (let* ((single-dir (or (not (listp cvs-execute-single-dir))
1814                          (member cmd cvs-execute-single-dir)))
1815          (parse (member cmd cvs-parse-known-commands))
1816          (args (append cvsargs (list cmd) flags))
1817          (after-mode (nth 2 (cdr (assoc cmd cvs-buffer-name-alist)))))
1818     (cvs-cleanup-collection cvs-cookies ;cleanup remaining messages
1819                             (eq cvs-auto-remove-handled 'delayed) nil t)
1820     (when (fboundp after-mode)
1821       (setq postproc (append postproc `((,after-mode)))))
1822     (when parse
1823       (let ((old-fis
1824              (when (member cmd '("status" "update"))    ;FIXME: Yuck!!
1825                 ;; absence of `cvs update' output has a specific meaning.
1826                 (or fis (list (cvs-create-fileinfo 'DIRCHANGE "" "." ""))))))
1827         (push `(cvs-parse-process ',dont-change-disc nil ',old-fis) postproc)))
1828     (let ((msg (cvs-header-msg args fis)))
1829       (cvs-update-header msg 'add)
1830       (push `(with-current-buffer cvs-buffer
1831                (cvs-update-header ',msg nil))
1832             postproc))
1833     (setq postproc (if (cdr postproc) (cons 'progn postproc) (car postproc)))
1834     (with-current-buffer buf
1835       (let ((inhibit-read-only t)) (erase-buffer))
1836       (message "Running cvs %s ..." cmd)
1837       (cvs-run-process args fis postproc single-dir))))
1838
1839
1840 (defun* cvs-mode-do (cmd flags filter
1841                      &key show dont-change-disc cvsargs postproc)
1842   "Generic cvs-mode-<foo> function.
1843 Executes `cvs CVSARGS CMD FLAGS' on the selected files.
1844 FILTER is passed to `cvs-applicable-p' to only apply the command to
1845   files for which it makes sense.
1846 SHOW indicates that CMD should be not be run in the default temp buffer and
1847   should be shown to the user.  The buffer and mode to be used is determined
1848   by `cvs-buffer-name-alist'.
1849 DONT-CHANGE-DISC non-nil indicates that the command will not change the
1850   contents of files.  This is only used by the parser."
1851   (cvs-mode-run cmd flags (cvs-mode-marked filter cmd)
1852                 :buf (cvs-temp-buffer (when show cmd))
1853                 :dont-change-disc dont-change-disc
1854                 :cvsargs cvsargs
1855                 :postproc postproc))
1856
1857 (defun-cvs-mode (cvs-mode-status . SIMPLE) (flags)
1858   "Show cvs status for all marked files.
1859 With prefix argument, prompt for cvs flags."
1860   (interactive (list (cvs-flags-query 'cvs-status-flags "cvs status flags")))
1861   (cvs-mode-do "status" flags nil :dont-change-disc t :show t
1862                :postproc (when (eq cvs-auto-remove-handled 'status)
1863                            '((with-current-buffer ,(current-buffer)
1864                                (cvs-mode-remove-handled))))))
1865
1866 (defun-cvs-mode (cvs-mode-tree . SIMPLE) (flags)
1867   "Call cvstree using the file under the point as a keyfile."
1868   (interactive (list (cvs-flags-query 'cvs-status-flags "cvs status flags")))
1869   (cvs-mode-run "status" (cons "-v" flags) (cvs-mode-marked nil "status")
1870                 :buf (cvs-temp-buffer "tree")
1871                 :dont-change-disc t
1872                 :postproc '((cvs-status-cvstrees))))
1873
1874 ;; cvs log
1875
1876 (defun-cvs-mode (cvs-mode-log . NOARGS) (flags)
1877   "Display the cvs log of all selected files.
1878 With prefix argument, prompt for cvs flags."
1879   (interactive (list (cvs-add-branch-prefix
1880                       (cvs-flags-query 'cvs-log-flags "cvs log flags"))))
1881   (cvs-mode-do "log" flags nil :show t))
1882
1883
1884 (defun-cvs-mode (cvs-mode-update . NOARGS) (flags)
1885   "Update all marked files.
1886 With a prefix argument, prompt for cvs flags."
1887   (interactive
1888    (list (cvs-add-branch-prefix
1889           (cvs-add-secondary-branch-prefix
1890            (cvs-flags-query 'cvs-update-flags "cvs update flags")
1891            "-j") "-j")))
1892   (cvs-mode-do "update" flags 'update))
1893
1894
1895 (defun-cvs-mode (cvs-mode-examine . NOARGS) (flags)
1896   "Re-examine all marked files.
1897 With a prefix argument, prompt for cvs flags."
1898   (interactive
1899    (list (cvs-add-branch-prefix
1900           (cvs-add-secondary-branch-prefix
1901            (cvs-flags-query 'cvs-update-flags "cvs -n update flags")
1902            "-j") "-j")))
1903   (cvs-mode-do "update" flags nil :cvsargs '("-n") :dont-change-disc t))
1904
1905
1906 (defun-cvs-mode cvs-mode-ignore (&optional pattern)
1907   "Arrange so that CVS ignores the selected files.
1908 This command ignores files that are not flagged as `Unknown'."
1909   (interactive)
1910   (dolist (fi (cvs-mode-marked 'ignore))
1911     (cvs-append-to-ignore (cvs-fileinfo->dir fi) (cvs-fileinfo->file fi)
1912                           (eq (cvs-fileinfo->subtype fi) 'NEW-DIR))
1913     (setf (cvs-fileinfo->type fi) 'DEAD))
1914   (cvs-cleanup-collection cvs-cookies nil nil nil))
1915
1916
1917 (defun cvs-append-to-ignore (dir str &optional old-dir)
1918   "Add STR to the .cvsignore file in DIR.
1919 If OLD-DIR is non-nil, then this is a directory that we don't want
1920 to hear about anymore."
1921   (with-current-buffer
1922       (find-file-noselect (expand-file-name ".cvsignore" dir))
1923     (when (ignore-errors
1924             (and buffer-read-only
1925                  (eq 'CVS (vc-backend buffer-file-name))
1926                  (not (vc-editable-p buffer-file-name))))
1927       ;; CVSREAD=on special case
1928       (vc-checkout buffer-file-name t))
1929     (goto-char (point-max))
1930     (unless (bolp) (insert "\n"))
1931     (insert str (if old-dir "/\n" "\n"))
1932     (if cvs-sort-ignore-file (sort-lines nil (point-min) (point-max)))
1933     (save-buffer)))
1934
1935
1936 (defun cvs-mode-find-file-other-window (e)
1937   "Select a buffer containing the file in another window."
1938   (interactive (list last-input-event))
1939   (cvs-mode-find-file e t))
1940
1941
1942 (defun cvs-mode-display-file (e)
1943   "Show a buffer containing the file in another window."
1944   (interactive (list last-input-event))
1945   (cvs-mode-find-file e 'dont-select))
1946
1947
1948 (defun cvs-mode-view-file (e)
1949   "View the file."
1950   (interactive (list last-input-event))
1951   (cvs-mode-find-file e nil t))
1952
1953
1954 (defun cvs-mode-view-file-other-window (e)
1955   "View the file."
1956   (interactive (list last-input-event))
1957   (cvs-mode-find-file e t t))
1958
1959
1960 (defun cvs-find-modif (fi)
1961   (with-temp-buffer
1962     (call-process cvs-program nil (current-buffer) nil
1963                   "-f" "diff" (cvs-fileinfo->file fi))
1964     (goto-char (point-min))
1965     (if (re-search-forward "^\\([0-9]+\\)" nil t)
1966         (string-to-number (match-string 1))
1967       1)))
1968
1969
1970 (defun cvs-mode-find-file (e &optional other view)
1971   "Select a buffer containing the file.
1972 With a prefix, opens the buffer in an OTHER window."
1973   (interactive (list last-input-event current-prefix-arg))
1974   ;; If the event moves point, check that it moves it to a valid location.
1975   (when (and (/= (point) (progn (posn-set-point (event-end e)) (point)))
1976              (not (memq (get-text-property (1- (line-end-position))
1977                                            'font-lock-face)
1978                         '(cvs-header-face cvs-filename-face))))
1979     (error "Not a file name"))
1980   (cvs-mode!
1981    (lambda (&optional rev)
1982      (interactive (list (cvs-prefix-get 'cvs-branch-prefix)))
1983      (let* ((cvs-buf (current-buffer))
1984             (fi (cvs-mode-marked nil nil :one t)))
1985        (if (eq (cvs-fileinfo->type fi) 'DIRCHANGE)
1986            (let ((odir default-directory))
1987              (setq default-directory
1988                    (cvs-expand-dir-name (cvs-fileinfo->dir fi)))
1989              (cond ((eq other 'dont-select)
1990                     (display-buffer (find-file-noselect default-directory)))
1991                    (other (dired-other-window default-directory))
1992                    (t (dired default-directory)))
1993              (set-buffer cvs-buf)
1994              (setq default-directory odir))
1995          (let ((buf (if rev (cvs-retrieve-revision fi rev)
1996                       (find-file-noselect (cvs-fileinfo->full-path fi)))))
1997            (funcall (cond ((eq other 'dont-select) 'display-buffer)
1998                           (other
1999                            (if view 'view-buffer-other-window
2000                              'switch-to-buffer-other-window))
2001                           (t (if view 'view-buffer 'switch-to-buffer)))
2002                     buf)
2003            (when (and cvs-find-file-and-jump (cvs-applicable-p fi 'diff-base))
2004              (goto-line (cvs-find-modif fi)))
2005            buf))))))
2006
2007
2008 (defun-cvs-mode (cvs-mode-undo . SIMPLE) (flags)
2009   "Undo local changes to all marked files.
2010 The file is removed and `cvs update FILE' is run."
2011   ;;"With prefix argument, prompt for cvs FLAGS."
2012   (interactive (list nil));; (cvs-flags-query 'cvs-undo-flags "undo flags")
2013   (if current-prefix-arg (call-interactively 'cvs-mode-revert-to-rev)
2014     (let* ((fis (cvs-do-removal 'undo "update" 'all))
2015            (removedp (lambda (fi)
2016                        (or (eq (cvs-fileinfo->type fi) 'REMOVED)
2017                            (and (eq (cvs-fileinfo->type fi) 'CONFLICT)
2018                                 (eq (cvs-fileinfo->subtype fi) 'REMOVED)))))
2019            (fis-split (cvs-partition removedp fis))
2020            (fis-removed (car fis-split))
2021            (fis-other (cdr fis-split)))
2022       (if (null fis-other)
2023           (when fis-removed (cvs-mode-run "add" nil fis-removed))
2024         (cvs-mode-run "update" flags fis-other
2025                       :postproc
2026                       (when fis-removed
2027                         `((with-current-buffer ,(current-buffer)
2028                             (cvs-mode-run "add" nil ',fis-removed)))))))))
2029
2030
2031 (defun-cvs-mode (cvs-mode-revert-to-rev . NOARGS) (rev)
2032   "Revert the selected files to an old revision."
2033   (interactive
2034    (list (or (cvs-prefix-get 'cvs-branch-prefix)
2035              (let ((current-prefix-arg '(4)))
2036                (cvs-flags-query 'cvs-idiff-version)))))
2037   (let* ((fis (cvs-mode-marked 'revert "revert" :file t))
2038          (tag (concat "tmp_pcl_tag_" (make-temp-name "")))
2039          (untag `((with-current-buffer ,(current-buffer)
2040                     (cvs-mode-run "tag" (list "-d" ',tag) ',fis))))
2041          (update `((with-current-buffer ,(current-buffer)
2042                      (cvs-mode-run "update" (list "-j" ',tag "-j" ',rev) ',fis
2043                                    :postproc ',untag)))))
2044     (cvs-mode-run "tag" (list tag) fis :postproc update)))
2045
2046
2047 (defun-cvs-mode cvs-mode-delete-lock ()
2048   "Delete the lock file that CVS is waiting for.
2049 Note that this can be dangerous.  You should only do this
2050 if you are convinced that the process that created the lock is dead."
2051   (interactive)
2052   (let* ((default-directory (cvs-expand-dir-name cvs-lock-file))
2053          (locks (directory-files default-directory nil cvs-lock-file-regexp)))
2054     (cond
2055      ((not locks) (error "No lock files found"))
2056      ((yes-or-no-p (concat "Really delete locks in " cvs-lock-file "? "))
2057       (dolist (lock locks)
2058         (cond ((file-directory-p lock) (delete-directory lock))
2059               ((file-exists-p lock) (delete-file lock))))))))
2060
2061
2062 (defun-cvs-mode cvs-mode-remove-handled ()
2063   "Remove all lines that are handled.
2064 Empty directories are removed."
2065   (interactive)
2066   (cvs-cleanup-collection cvs-cookies
2067                           t (or cvs-auto-remove-directories 'handled) t))
2068
2069
2070 (defun-cvs-mode cvs-mode-acknowledge ()
2071   "Remove all marked files from the buffer."
2072   (interactive)
2073   (dolist (fi (cvs-get-marked (cvs-ignore-marks-p "acknowledge") t))
2074     (setf (cvs-fileinfo->type fi) 'DEAD))
2075   (cvs-cleanup-collection cvs-cookies nil nil nil))
2076
2077 (defun cvs-do-removal (filter &optional cmd all)
2078   "Remove files.
2079 Returns a list of FIS that should be `cvs remove'd."
2080   (let* ((files (cvs-mode-marked filter cmd :file t :read-only t))
2081          (fis (cdr (cvs-partition (lambda (fi)
2082                                     (eq (cvs-fileinfo->type fi) 'UNKNOWN))
2083                                   (cvs-mode-marked filter cmd))))
2084          (silent (or (not cvs-confirm-removals)
2085                      (cvs-every (lambda (fi)
2086                                   (or (not (file-exists-p
2087                                             (cvs-fileinfo->full-path fi)))
2088                                       (cvs-applicable-p fi 'safe-rm)))
2089                                 files)))
2090          (tmpbuf (cvs-temp-buffer)))
2091     (when (and (not silent) (equal cvs-confirm-removals 'list))
2092       (with-current-buffer tmpbuf
2093         (let ((inhibit-read-only t))
2094           (cvs-insert-strings (mapcar 'cvs-fileinfo->full-path fis))
2095           (cvs-pop-to-buffer-same-frame (current-buffer))
2096           (shrink-window-if-larger-than-buffer))))
2097     (if (not (or silent
2098                  (unwind-protect
2099                      (yes-or-no-p
2100                       (let ((nfiles (length files))
2101                             (verb (if (eq filter 'undo) "Undo" "Delete")))
2102                         (if (= 1 nfiles)
2103                             (format "%s file: \"%s\" ? "
2104                                     verb
2105                                     (cvs-fileinfo->file (car files)))
2106                           (format "%s %d files? "
2107                                   verb
2108                                   nfiles))))
2109                    (cvs-bury-buffer tmpbuf cvs-buffer))))
2110         (progn (message "Aborting") nil)
2111       (dolist (fi files)
2112         (let* ((type (cvs-fileinfo->type fi))
2113                (file (cvs-fileinfo->full-path fi)))
2114           (when (or all (eq type 'UNKNOWN))
2115             (when (file-exists-p file) (delete-file file))
2116             (unless all (setf (cvs-fileinfo->type fi) 'DEAD) t))))
2117       fis)))
2118
2119 (defun-cvs-mode (cvs-mode-remove . SIMPLE) (flags)
2120   "Remove all marked files.
2121 With prefix argument, prompt for cvs flags."
2122   (interactive (list (cvs-flags-query 'cvs-remove-flags "cvs remove flags")))
2123   (let ((fis (cvs-do-removal 'remove)))
2124     (if fis (cvs-mode-run "remove" (cons "-f" flags) fis)
2125       (cvs-cleanup-collection cvs-cookies nil nil nil))))
2126
2127
2128 (defvar cvs-tag-name "")
2129 (defun-cvs-mode (cvs-mode-tag . SIMPLE) (tag &optional flags)
2130   "Run `cvs tag TAG' on all selected files.
2131 With prefix argument, prompt for cvs flags.
2132 By default this can only be used on directories.
2133 Use \\[cvs-mode-force-command] or change `cvs-force-dir-tag' if you need
2134 to use it on individual files."
2135   (interactive
2136    (list (setq cvs-tag-name
2137                (cvs-query-read cvs-tag-name "Tag name: " cvs-qtypedesc-tag))
2138          (cvs-flags-query 'cvs-tag-flags "tag flags")))
2139   (cvs-mode-do "tag" (append flags (list tag))
2140                (when cvs-force-dir-tag 'tag)))
2141
2142 (defun-cvs-mode (cvs-mode-untag . SIMPLE) (tag &optional flags)
2143   "Run `cvs tag -d TAG' on all selected files.
2144 With prefix argument, prompt for cvs flags."
2145   (interactive
2146    (list (setq cvs-tag-name
2147                (cvs-query-read cvs-tag-name "Tag to delete: " cvs-qtypedesc-tag))
2148          (cvs-flags-query 'cvs-tag-flags "tag flags")))
2149   (cvs-mode-do "tag" (append '("-d") flags (list tag))
2150                (when cvs-force-dir-tag 'tag)))
2151
2152
2153 ;; Byte compile files.
2154
2155 (defun-cvs-mode cvs-mode-byte-compile-files ()
2156   "Run byte-compile-file on all selected files that end in '.el'."
2157   (interactive)
2158   (let ((marked (cvs-get-marked (cvs-ignore-marks-p "byte-compile"))))
2159     (dolist (fi marked)
2160       (let ((filename (cvs-fileinfo->full-path fi)))
2161         (when (string-match "\\.el\\'" filename)
2162           (byte-compile-file filename))))))
2163
2164 ;; ChangeLog support.
2165
2166 (defun-cvs-mode cvs-mode-add-change-log-entry-other-window ()
2167   "Add a ChangeLog entry in the ChangeLog of the current directory."
2168   (interactive)
2169   (dolist (fi (cvs-mode-marked nil nil))
2170     (let* ((default-directory (cvs-expand-dir-name (cvs-fileinfo->dir fi)))
2171            (buffer-file-name (expand-file-name (cvs-fileinfo->file fi))))
2172       (kill-local-variable 'change-log-default-name)
2173       (save-excursion (add-change-log-entry-other-window)))))
2174
2175 ;; interactive commands to set optional flags
2176
2177 (defun cvs-mode-set-flags (flag)
2178   "Ask for new setting of cvs-FLAG-flags."
2179   (interactive
2180    (list (completing-read
2181           "Which flag: "
2182           '("cvs" "diff" "update" "status" "log" "tag" ;"rtag"
2183             "commit" "remove" "undo" "checkout")
2184           nil t)))
2185   (let* ((sym (intern (concat "cvs-" flag "-flags"))))
2186     (let ((current-prefix-arg '(16)))
2187       (cvs-flags-query sym (concat flag " flags")))))
2188
2189 \f
2190 ;;;;
2191 ;;;; Utilities for the *cvs* buffer
2192 ;;;;
2193
2194 (defun cvs-dir-member-p (fileinfo dir)
2195   "Return true if FILEINFO represents a file in directory DIR."
2196   (and (not (eq (cvs-fileinfo->type fileinfo) 'DIRCHANGE))
2197        (cvs-string-prefix-p dir (cvs-fileinfo->dir fileinfo))))
2198
2199 (defun cvs-execute-single-file (fi extractor program constant-args)
2200   "Internal function for `cvs-execute-single-file-list'."
2201   (let* ((arg-list (funcall extractor fi))
2202          (inhibit-read-only t))
2203
2204     ;; Execute the command unless extractor returned t.
2205     (when (listp arg-list)
2206       (let* ((args (append constant-args arg-list)))
2207
2208         (insert (format "=== %s %s\n\n"
2209                         program (cvs-strings->string args)))
2210
2211         ;; FIXME: return the exit status?
2212         (apply 'call-process program nil t t args)
2213         (goto-char (point-max))))))
2214
2215 ;; FIXME: make this run in the background ala cvs-run-process...
2216 (defun cvs-execute-single-file-list (fis extractor program constant-args)
2217   "Run PROGRAM on all elements on FIS.
2218 CONSTANT-ARGS is a list of strings to pass as arguments to PROGRAM.
2219 The arguments given to the program will be CONSTANT-ARGS followed by
2220 the list that EXTRACTOR returns.
2221
2222 EXTRACTOR will be called once for each file on FIS.  It is given
2223 one argument, the cvs-fileinfo.  It can return t, which means ignore
2224 this file, or a list of arguments to send to the program."
2225   (dolist (fi fis)
2226     (cvs-execute-single-file fi extractor program constant-args)))
2227
2228 \f
2229 (defun cvs-revert-if-needed (fis)
2230   (dolist (fileinfo fis)
2231     (let* ((file (cvs-fileinfo->full-path fileinfo))
2232            (buffer (find-buffer-visiting file)))
2233       ;; For a revert to happen the user must be editing the file...
2234       (unless (or (null buffer)
2235                   (eq (cvs-fileinfo->type fileinfo) 'MESSAGE)
2236                   ;; FIXME: check whether revert is really needed.
2237                   ;; `(verify-visited-file-modtime buffer)' doesn't cut it
2238                   ;; because it only looks at the time stamp (it ignores
2239                   ;; read-write changes) which is not changed by `commit'.
2240                   (buffer-modified-p buffer))
2241         (with-current-buffer buffer
2242           (ignore-errors
2243             (revert-buffer 'ignore-auto 'dont-ask 'preserve-modes)
2244             ;; `preserve-modes' avoids changing the (minor) modes.  But we
2245             ;; do want to reset the mode for VC, so we do it explicitly.
2246             (vc-find-file-hook)
2247             (when (eq (cvs-fileinfo->type fileinfo) 'CONFLICT)
2248               (smerge-mode 1))))))))
2249
2250 \f
2251 (defun cvs-change-cvsroot (newroot)
2252   "Change the cvsroot."
2253   (interactive "DNew repository: ")
2254   (if (or (file-directory-p (expand-file-name "CVSROOT" newroot))
2255           (y-or-n-p (concat "Warning: no CVSROOT found inside repository."
2256                             " Change cvs-cvsroot anyhow?")))
2257       (setq cvs-cvsroot newroot)))
2258
2259 ;;;;
2260 ;;;; useful global settings
2261 ;;;;
2262
2263 ;;;###autoload
2264 (add-to-list 'completion-ignored-extensions "CVS/")
2265
2266 ;;
2267 ;; Hook to allow calling PCL-CVS by visiting the /CVS subdirectory
2268 ;;
2269
2270 ;;;###autoload
2271 (defcustom cvs-dired-action 'cvs-quickdir
2272   "The action to be performed when opening a CVS directory.
2273 Sensible values are `cvs-examine', `cvs-status' and `cvs-quickdir'."
2274   :group 'pcl-cvs
2275   :type '(choice (const cvs-examine) (const cvs-status) (const cvs-quickdir)))
2276
2277 ;;;###autoload
2278 (defcustom cvs-dired-use-hook '(4)
2279   "Whether or not opening a CVS directory should run PCL-CVS.
2280 nil means never do it.
2281 ALWAYS means to always do it unless a prefix argument is given to the
2282   command that prompted the opening of the directory.
2283 Anything else means to do it only if the prefix arg is equal to this value."
2284   :group 'pcl-cvs
2285   :type '(choice (const :tag "Never" nil)
2286                  (const :tag "Always" always)
2287                  (const :tag "Prefix" (4))))
2288
2289 ;;;###autoload
2290 (progn (defun cvs-dired-noselect (dir)
2291   "Run `cvs-examine' if DIR is a CVS administrative directory.
2292 The exact behavior is determined also by `cvs-dired-use-hook'."
2293   (when (stringp dir)
2294     (setq dir (directory-file-name dir))
2295     (when (and (string= "CVS" (file-name-nondirectory dir))
2296                (file-readable-p (expand-file-name "Entries" dir))
2297                cvs-dired-use-hook
2298                (if (eq cvs-dired-use-hook 'always)
2299                    (not current-prefix-arg)
2300                  (equal current-prefix-arg cvs-dired-use-hook)))
2301       (save-excursion
2302         (funcall cvs-dired-action (file-name-directory dir) t t))))))
2303
2304 ;;
2305 ;; hook into VC
2306 ;;
2307
2308 (add-hook 'vc-post-command-functions 'cvs-vc-command-advice)
2309
2310 (defun cvs-vc-command-advice (command file flags)
2311   (when (and (equal command "cvs")
2312              (progn
2313                (while (and (stringp (car flags))
2314                            (string-match "\\`-" (car flags)))
2315                  (pop flags))
2316                ;; don't parse output we don't understand.
2317                (member (car flags) cvs-parse-known-commands))
2318              ;; Don't parse "update -p" output.
2319              (not (and (member (car flags) '("update" "checkout"))
2320                        (let ((found-p nil))
2321                          (dolist (flag flags found-p)
2322                            (if (equal flag "-p") (setq found-p t)))))))
2323     (save-current-buffer
2324       (let ((buffer (current-buffer))
2325             (dir default-directory)
2326             (cvs-from-vc t))
2327         (dolist (cvs-buf (buffer-list))
2328           (set-buffer cvs-buf)
2329           ;; look for a corresponding pcl-cvs buffer
2330           (when (and (eq major-mode 'cvs-mode)
2331                      (cvs-string-prefix-p default-directory dir))
2332             (let ((subdir (substring dir (length default-directory))))
2333               (set-buffer buffer)
2334               (set (make-local-variable 'cvs-buffer) cvs-buf)
2335               ;; `cvs -q add file' produces no useful output :-(
2336               (when (and (equal (car flags) "add")
2337                          (goto-char (point-min))
2338                          (looking-at ".*to add this file permanently\n\\'"))
2339                 (insert "cvs add: scheduling file `"
2340                         (file-name-nondirectory file)
2341                         "' for addition\n"))
2342               ;; VC never (?) does `cvs -n update' so dcd=nil
2343               ;; should probably always be the right choice.
2344               (cvs-parse-process nil subdir))))))))
2345
2346 ;;
2347 ;; Hook into write-buffer
2348 ;;
2349
2350 (defun cvs-mark-buffer-changed ()
2351   (let* ((file (expand-file-name buffer-file-name))
2352          (version (and (fboundp 'vc-backend)
2353                        (eq (vc-backend file) 'CVS)
2354                        (vc-workfile-version file))))
2355     (when version
2356       (save-excursion
2357         (dolist (cvs-buf (buffer-list))
2358           (set-buffer cvs-buf)
2359           ;; look for a corresponding pcl-cvs buffer
2360           (when (and (eq major-mode 'cvs-mode)
2361                      (cvs-string-prefix-p default-directory file))
2362             (let* ((file (substring file (length default-directory)))
2363                    (fi (cvs-create-fileinfo
2364                         (if (string= "0" version)
2365                             'ADDED 'MODIFIED)
2366                         (or (file-name-directory file) "")
2367                         (file-name-nondirectory file)
2368                         "cvs-mark-buffer-changed")))
2369               (cvs-addto-collection cvs-cookies fi))))))))
2370
2371 (add-hook 'after-save-hook 'cvs-mark-buffer-changed)
2372
2373 \f
2374 (provide 'pcvs)
2375
2376 ;; arch-tag: 8e3a7494-0453-4389-9ab3-a557ce9fab61
2377 ;;; pcvs.el ends here