lisp/type-break.el

   1 ;;; type-break.el --- encourage rests from typing at appropriate intervals
   2
   3 ;; Copyright (C) 1994, 1995, 1997, 2000, 2002, 2003,
   4 ;;   2004, 2005 Free Software Foundation, Inc.
   5
   6 ;; Author: Noah Friedman
   7 ;; Maintainer: Noah Friedman <friedman@splode.com>
   8 ;; Keywords: extensions, timers
   9 ;; Status: Works in GNU Emacs 19.25 or later, some versions of XEmacs
  10 ;; Created: 1994-07-13
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software; you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation; either version 2, or (at your option)
  17 ;; any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  26 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  27 ;; Boston, MA 02110-1301, USA.
  28
  29 ;;; Commentary:
  30
  31 ;; The docstring for the function `type-break-mode' summarizes most of the
  32 ;; details of the interface.
  33
  34 ;; This package relies on the assumption that you live entirely in Emacs,
  35 ;; as the author does.  If that's not the case for you (e.g. you often
  36 ;; suspend Emacs or work in other windows) then this won't help very much;
  37 ;; it will depend on just how often you switch back to Emacs.  At the very
  38 ;; least, you will want to turn off the keystroke thresholds and rest
  39 ;; interval tracking.
  40
  41 ;; If you prefer not to be queried about taking breaks, but instead just
  42 ;; want to be reminded, do the following:
  43 ;;
  44 ;;   (setq type-break-query-mode nil)
  45 ;;
  46 ;; Or call the command `type-break-query-mode' with a negative prefix
  47 ;; argument.
  48
  49 ;; If you find echo area messages annoying and would prefer to see messages
  50 ;; in the mode line instead, do M-x type-break-mode-line-message-mode
  51 ;; or set the variable of the same name to `t'.
  52
  53 ;; This program can truly cons up a storm because of all the calls to
  54 ;; `current-time' (which always returns 3 fresh conses).  I'm dismayed by
  55 ;; this, but I think the health of my hands is far more important than a
  56 ;; few pages of virtual memory.
  57
  58 ;; This program has no hope of working in Emacs 18.
  59
  60 ;; This package was inspired by Roland McGrath's hanoi-break.el.
  61 ;; Several people contributed feedback and ideas, including
  62 ;;      Roland McGrath <roland@gnu.org>
  63 ;;      Kleanthes Koniaris <kgk@koniaris.com>
  64 ;;      Mark Ashton <mpashton@gnu.org>
  65 ;;      Matt Wilding <wilding@cli.com>
  66 ;;      Robert S. Boyer <boyer@cs.utexas.edu>
  67
  68 ;;; Code:
  69
  70 \f
  71 (defgroup type-break nil
  72   "Encourage the user to take a rest from typing at suitable intervals."
  73   :prefix "type-break"
  74   :group 'keyboard)
  75
  76 ;;;###autoload
  77 (defcustom type-break-mode nil
  78   "Toggle typing break mode.
  79 See the docstring for the `type-break-mode' command for more information.
  80 Setting this variable directly does not take effect;
  81 use either \\[customize] or the function `type-break-mode'."
  82   :set (lambda (symbol value)
  83          (type-break-mode (if value 1 -1)))
  84   :initialize 'custom-initialize-default
  85   :type 'boolean
  86   :group 'type-break
  87   :require 'type-break)
  88
  89 ;;;###autoload
  90 (defcustom type-break-interval (* 60 60)
  91   "*Number of seconds between scheduled typing breaks."
  92   :type 'integer
  93   :group 'type-break)
  94
  95 ;;;###autoload
  96 (defcustom type-break-good-rest-interval (/ type-break-interval 6)
  97   "*Number of seconds of idle time considered to be an adequate typing rest.
  98
  99 When this variable is non-nil, Emacs checks the idle time between
 100 keystrokes.  If this idle time is long enough to be considered a \"good\"
 101 rest from typing, then the next typing break is simply rescheduled for later.
 102
 103 If a break is interrupted before this much time elapses, the user will be
 104 asked whether or not really to interrupt the break."
 105   :type 'integer
 106   :group 'type-break)
 107
 108 ;;;###autoload
 109 (defcustom type-break-good-break-interval nil
 110   "*Number of seconds considered to be an adequate explicit typing rest.
 111
 112 When this variable is non-nil, its value is considered to be a \"good\"
 113 length (in seconds) for a break initiated by the command `type-break',
 114 overriding `type-break-good-rest-interval'.  This provides querying of
 115 break interruptions when `type-break-good-rest-interval' is nil."
 116   :type 'integer
 117   :group 'type-break)
 118
 119 ;;;###autoload
 120 (defcustom type-break-keystroke-threshold
 121   ;; Assuming typing speed is 35wpm (on the average, do you really
 122   ;; type more than that in a minute?  I spend a lot of time reading mail
 123   ;; and simply studying code in buffers) and average word length is
 124   ;; about 5 letters, default upper threshold to the average number of
 125   ;; keystrokes one is likely to type in a break interval.  That way if the
 126   ;; user goes through a furious burst of typing activity, cause a typing
 127   ;; break to be required sooner than originally scheduled.
 128   ;; Conversely, the minimum threshold should be about a fifth of this.
 129   (let* ((wpm 35)
 130          (avg-word-length 5)
 131          (upper (* wpm avg-word-length (/ type-break-interval 60)))
 132          (lower (/ upper 5)))
 133     (cons lower upper))
 134   "*Upper and lower bound on number of keystrokes for considering typing break.
 135 This structure is a pair of numbers (MIN . MAX).
 136
 137 The first number is the minimum number of keystrokes that must have been
 138 entered since the last typing break before considering another one, even if
 139 the scheduled time has elapsed; the break is simply rescheduled until later
 140 if the minimum threshold hasn't been reached.  If this first value is nil,
 141 then there is no minimum threshold; as soon as the scheduled time has
 142 elapsed, the user will always be queried.
 143
 144 The second number is the maximum number of keystrokes that can be entered
 145 before a typing break is requested immediately, pre-empting the originally
 146 scheduled break.  If this second value is nil, then no pre-emptive breaks
 147 will occur; only scheduled ones will.
 148
 149 Keys with bucky bits (shift, control, meta, etc) are counted as only one
 150 keystroke even though they really require multiple keys to generate them.
 151
 152 The command `type-break-guesstimate-keystroke-threshold' can be used to
 153 guess a reasonably good pair of values for this variable."
 154   :type 'sexp
 155   :group 'type-break)
 156
 157 (defcustom type-break-query-mode t
 158   "*Non-nil means ask whether or not to prompt user for breaks.
 159 If so, call the function specified in the value of the variable
 160 `type-break-query-function' to do the asking."
 161   :type 'boolean
 162   :group 'type-break)
 163
 164 (defcustom type-break-query-function 'yes-or-no-p
 165   "*Function to use for making query for a typing break.
 166 It should take a string as an argument, the prompt.
 167 Usually this should be set to `yes-or-no-p' or `y-or-n-p'.
 168
 169 To avoid being queried at all, set `type-break-query-mode' to nil."
 170   :type '(radio function
 171                 (function-item yes-or-no-p)
 172                 (function-item y-or-n-p))
 173   :group 'type-break)
 174
 175 (defcustom type-break-query-interval 60
 176   "*Number of seconds between queries to take a break, if put off.
 177 The user will continue to be prompted at this interval until he or she
 178 finally submits to taking a typing break."
 179   :type 'integer
 180   :group 'type-break)
 181
 182 (defcustom type-break-time-warning-intervals '(300 120 60 30)
 183   "*List of time intervals for warnings about upcoming typing break.
 184 At each of the intervals (specified in seconds) away from a scheduled
 185 typing break, print a warning in the echo area."
 186   :type '(repeat integer)
 187   :group 'type-break)
 188
 189 (defcustom type-break-keystroke-warning-intervals '(300 200 100 50)
 190   "*List of keystroke measurements for warnings about upcoming typing break.
 191 At each of the intervals (specified in keystrokes) away from the upper
 192 keystroke threshold, print a warning in the echo area.
 193 If either this variable or the upper threshold is set, then no warnings
 194 will occur."
 195   :type '(repeat integer)
 196   :group 'type-break)
 197
 198 (defcustom type-break-warning-repeat 40
 199   "*Number of keystrokes for which warnings should be repeated.
 200 That is, for each of this many keystrokes the warning is redisplayed
 201 in the echo area to make sure it's really seen."
 202   :type 'integer
 203   :group 'type-break)
 204
 205 (defcustom type-break-time-stamp-format "[%H:%M] "
 206   "*Timestamp format used to prefix messages.
 207 Format specifiers are as used by `format-time-string'."
 208   :type 'string
 209   :group 'type-break)
 210
 211 (defcustom type-break-demo-functions
 212   '(type-break-demo-boring type-break-demo-life type-break-demo-hanoi)
 213   "*List of functions to consider running as demos during typing breaks.
 214 When a typing break begins, one of these functions is selected randomly
 215 to have Emacs do something interesting.
 216
 217 Any function in this list should start a demo which ceases as soon as a
 218 key is pressed."
 219   :type '(repeat function)
 220   :group 'type-break)
 221
 222 (defcustom type-break-demo-boring-stats nil
 223   "*Show word per minute and keystroke figures in the Boring demo."
 224   :type 'boolean
 225   :group 'type-break)
 226
 227 (defcustom type-break-terse-messages nil
 228   "*Use slightly terser messages."
 229   :type 'boolean
 230   :group 'type-break)
 231
 232 (defcustom type-break-file-name (convert-standard-filename "~/.type-break")
 233   "*Name of file used to save state across sessions.
 234 If this is nil, no data will be saved across sessions."
 235   :type 'file
 236   :group 'type-break)
 237
 238 (defvar type-break-post-command-hook '(type-break-check)
 239   "Hook run indirectly by `post-command-hook' for typing break functions.
 240 This is not really intended to be set by the user, but it's probably
 241 harmless to do so.  Mainly it is used by various parts of the typing break
 242 program to delay actions until after the user has completed some command.
 243 It exists because `post-command-hook' itself is inaccessible while its
 244 functions are being run, and some type-break--related functions want to
 245 remove themselves after running.")
 246
 247 \f
 248 ;; Mode line frobs
 249
 250 (defcustom type-break-mode-line-message-mode nil
 251   "*Non-nil means put type-break related messages in the mode line.
 252 Otherwise, messages typically go in the echo area.
 253
 254 See also `type-break-mode-line-format' and its members."
 255   :type 'boolean
 256   :group 'type-break)
 257
 258 (defvar type-break-mode-line-format
 259   '(type-break-mode-line-message-mode
 260     (""
 261      type-break-mode-line-break-message
 262      type-break-mode-line-warning))
 263   "*Format of messages in the mode line concerning typing breaks.")
 264
 265 (defvar type-break-mode-line-break-message
 266   '(type-break-mode-line-break-message-p
 267     type-break-mode-line-break-string))
 268
 269 (defvar type-break-mode-line-break-message-p nil)
 270 (defvar type-break-mode-line-break-string " *** TAKE A TYPING BREAK NOW ***")
 271
 272 (defvar type-break-mode-line-warning
 273       '(type-break-mode-line-break-message-p
 274         ("")
 275         (type-break-warning-countdown-string
 276          (" *** "
 277           "Break in "
 278           type-break-warning-countdown-string
 279           " "
 280           type-break-warning-countdown-string-type
 281           "***"))))
 282
 283 (defvar type-break-warning-countdown-string nil
 284   "If non-nil, this is a countdown for the next typing break.
 285
 286 This variable, in conjunction with `type-break-warning-countdown-string-type'
 287 \(which indicates whether this value is a number of keystrokes or seconds)
 288 is installed in `mode-line-format' to notify of imminent typing breaks.")
 289
 290 (defvar type-break-warning-countdown-string-type nil
 291   "Indicates the unit type of `type-break-warning-countdown-string'.
 292 It will be either \"seconds\" or \"keystrokes\".")
 293
 294 \f
 295 ;; These are internal variables.  Do not set them yourself.
 296
 297 (defvar type-break-alarm-p nil)
 298 (defvar type-break-keystroke-count 0)
 299 (defvar type-break-time-last-break nil)
 300 (defvar type-break-time-next-break nil)
 301 (defvar type-break-time-last-command (current-time))
 302 (defvar type-break-current-time-warning-interval nil)
 303 (defvar type-break-current-keystroke-warning-interval nil)
 304 (defvar type-break-time-warning-count 0)
 305 (defvar type-break-keystroke-warning-count 0)
 306 (defvar type-break-interval-start nil)
 307
 308 \f
 309 ;;;###autoload
 310 (defun type-break-mode (&optional prefix)
 311   "Enable or disable typing-break mode.
 312 This is a minor mode, but it is global to all buffers by default.
 313
 314 When this mode is enabled, the user is encouraged to take typing breaks at
 315 appropriate intervals; either after a specified amount of time or when the
 316 user has exceeded a keystroke threshold.  When the time arrives, the user
 317 is asked to take a break.  If the user refuses at that time, Emacs will ask
 318 again in a short period of time.  The idea is to give the user enough time
 319 to find a good breaking point in his or her work, but be sufficiently
 320 annoying to discourage putting typing breaks off indefinitely.
 321
 322 A negative prefix argument disables this mode.
 323 No argument or any non-negative argument enables it.
 324
 325 The user may enable or disable this mode by setting the variable of the
 326 same name, though setting it in that way doesn't reschedule a break or
 327 reset the keystroke counter.
 328
 329 If the mode was previously disabled and is enabled as a consequence of
 330 calling this function, it schedules a break with `type-break-schedule' to
 331 make sure one occurs (the user can call that command to reschedule the
 332 break at any time).  It also initializes the keystroke counter.
 333
 334 The variable `type-break-interval' specifies the number of seconds to
 335 schedule between regular typing breaks.  This variable doesn't directly
 336 affect the time schedule; it simply provides a default for the
 337 `type-break-schedule' command.
 338
 339 If set, the variable `type-break-good-rest-interval' specifies the minimum
 340 amount of time which is considered a reasonable typing break.  Whenever
 341 that time has elapsed, typing breaks are automatically rescheduled for
 342 later even if Emacs didn't prompt you to take one first.  Also, if a break
 343 is ended before this much time has elapsed, the user will be asked whether
 344 or not to continue.  A nil value for this variable prevents automatic
 345 break rescheduling, making `type-break-interval' an upper bound on the time
 346 between breaks.  In this case breaks will be prompted for as usual before
 347 the upper bound if the keystroke threshold is reached.
 348
 349 If `type-break-good-rest-interval' is nil and
 350 `type-break-good-break-interval' is set, then confirmation is required to
 351 interrupt a break before `type-break-good-break-interval' seconds
 352 have passed.  This provides for an upper bound on the time between breaks
 353 together with confirmation of interruptions to these breaks.
 354
 355 The variable `type-break-keystroke-threshold' is used to determine the
 356 thresholds at which typing breaks should be considered.  You can use
 357 the command `type-break-guesstimate-keystroke-threshold' to try to
 358 approximate good values for this.
 359
 360 There are several variables that affect how or when warning messages about
 361 imminent typing breaks are displayed.  They include:
 362
 363         `type-break-mode-line-message-mode'
 364         `type-break-time-warning-intervals'
 365         `type-break-keystroke-warning-intervals'
 366         `type-break-warning-repeat'
 367         `type-break-warning-countdown-string'
 368         `type-break-warning-countdown-string-type'
 369
 370 There are several variables that affect if, how, and when queries to begin
 371 a typing break occur.  They include:
 372
 373         `type-break-query-mode'
 374         `type-break-query-function'
 375         `type-break-query-interval'
 376
 377 The command `type-break-statistics' prints interesting things.
 378
 379 Finally, a file (named `type-break-file-name') is used to store information
 380 across Emacs sessions.  This provides recovery of the break status between
 381 sessions and after a crash.  Manual changes to the file may result in
 382 problems."
 383   (interactive "P")
 384   (type-break-check-post-command-hook)
 385
 386   (let ((already-enabled type-break-mode))
 387     (setq type-break-mode (>= (prefix-numeric-value prefix) 0))
 388
 389     (cond
 390      ((and already-enabled type-break-mode)
 391       (and (interactive-p)
 392            (message "Type Break mode is already enabled")))
 393      (type-break-mode
 394       (when type-break-file-name
 395         (with-current-buffer (find-file-noselect type-break-file-name 'nowarn)
 396           (setq buffer-save-without-query t)))
 397
 398       (or global-mode-string
 399           (setq global-mode-string '("")))
 400       (or (assq 'type-break-mode-line-message-mode
 401                 minor-mode-alist)
 402           (setq minor-mode-alist
 403                 (cons type-break-mode-line-format
 404                       minor-mode-alist)))
 405       (type-break-keystroke-reset)
 406       (type-break-mode-line-countdown-or-break nil)
 407
 408       (setq type-break-time-last-break
 409             (or (type-break-get-previous-time)
 410                 (current-time)))
 411
 412       ;; schedule according to break time from session file
 413       (type-break-schedule
 414        (let (diff)
 415          (if (and type-break-time-last-break
 416                   (< (setq diff (type-break-time-difference
 417                                  type-break-time-last-break
 418                                  (current-time)))
 419                      type-break-interval))
 420              ;; use the file's value
 421              (progn
 422                (setq type-break-keystroke-count
 423                      (type-break-get-previous-count))
 424                ;; file the time, in case it was read from the auto-save file
 425                (type-break-file-time type-break-interval-start)
 426                (setq type-break-interval-start type-break-time-last-break)
 427                (- type-break-interval diff))
 428            ;; schedule from now
 429            (setq type-break-interval-start (current-time))
 430            (type-break-file-time type-break-interval-start)
 431            type-break-interval))
 432        type-break-interval-start
 433        type-break-interval)
 434
 435       (and (interactive-p)
 436            (message "Type Break mode is enabled and set")))
 437      (t
 438       (type-break-keystroke-reset)
 439       (type-break-mode-line-countdown-or-break nil)
 440       (type-break-cancel-schedule)
 441       (do-auto-save)
 442       (when type-break-file-name
 443         (with-current-buffer (find-file-noselect type-break-file-name
 444                                                  'nowarn)
 445           (set-buffer-modified-p nil)
 446           (unlock-buffer)
 447           (kill-this-buffer)))
 448       (and (interactive-p)
 449            (message "Type Break mode is disabled")))))
 450   type-break-mode)
 451
 452 (defun type-break-mode-line-message-mode (&optional prefix)
 453   "Enable or disable warnings in the mode line about typing breaks.
 454
 455 A negative PREFIX argument disables this mode.
 456 No argument or any non-negative argument enables it.
 457
 458 The user may also enable or disable this mode simply by setting the
 459 variable of the same name.
 460
 461 Variables controlling the display of messages in the mode line include:
 462
 463         `mode-line-format'
 464         `global-mode-string'
 465         `type-break-mode-line-break-message'
 466         `type-break-mode-line-warning'"
 467   (interactive "P")
 468   (setq type-break-mode-line-message-mode
 469         (>= (prefix-numeric-value prefix) 0))
 470   (and (interactive-p)
 471        (if type-break-mode-line-message-mode
 472            (message "type-break-mode-line-message-mode is enabled")
 473          (message "type-break-mode-line-message-mode is disabled")))
 474   type-break-mode-line-message-mode)
 475
 476 (defun type-break-query-mode (&optional prefix)
 477   "Enable or disable warnings in the mode line about typing breaks.
 478
 479 When enabled, the user is periodically queried about whether to take a
 480 typing break at that moment.  The function which does this query is
 481 specified by the variable `type-break-query-function'.
 482
 483 A negative PREFIX argument disables this mode.
 484 No argument or any non-negative argument enables it.
 485
 486 The user may also enable or disable this mode simply by setting the
 487 variable of the same name."
 488   (interactive "P")
 489   (setq type-break-query-mode
 490         (>= (prefix-numeric-value prefix) 0))
 491   (and (interactive-p)
 492        (if type-break-query-mode
 493            (message "type-break-query-mode is enabled")
 494          (message "type-break-query-mode is disabled")))
 495   type-break-query-mode)
 496
 497 \f
 498 ;;; session file functions
 499
 500 (defvar type-break-auto-save-file-name
 501   (let ((buffer-file-name type-break-file-name))
 502     (make-auto-save-file-name))
 503   "Auto-save name of `type-break-file-name'.")
 504
 505 (defun type-break-file-time (&optional time)
 506   "File break time in `type-break-file-name', unless the file is locked."
 507   (if (and type-break-file-name
 508            (not (stringp (file-locked-p type-break-file-name))))
 509       (with-current-buffer (find-file-noselect type-break-file-name
 510                                                'nowarn)
 511         (let ((inhibit-read-only t))
 512           (erase-buffer)
 513           (insert (format "%s\n\n" (or time type-break-interval-start)))
 514           ;; file saving is left to auto-save
 515           ))))
 516
 517 (defun type-break-file-keystroke-count ()
 518   "File keystroke count in `type-break-file-name', unless the file is locked."
 519   (if (and type-break-file-name
 520            (not (stringp (file-locked-p type-break-file-name))))
 521       ;; Prevent deactivation of the mark in some other buffer.
 522       (let (deactivate-mark)
 523         (with-current-buffer (find-file-noselect type-break-file-name
 524                                                  'nowarn)
 525           (save-excursion
 526             (let ((inhibit-read-only t))
 527               (goto-char (point-min))
 528               (forward-line)
 529               (delete-region (point) (save-excursion (end-of-line) (point)))
 530               (insert (format "%s" type-break-keystroke-count))
 531               ;; file saving is left to auto-save
 532               ))))))
 533
 534 (defun timep (time)
 535   "If TIME is in the format returned by `current-time' then
 536 return TIME, else return nil."
 537   (and (listp time)
 538        (eq (length time) 3)
 539        (integerp (car time))
 540        (integerp (nth 1 time))
 541        (integerp (nth 2 time))
 542        time))
 543
 544 (defun type-break-choose-file ()
 545   "Return file to read from."
 546   (cond
 547    ((not type-break-file-name)
 548     nil)
 549    ((and (file-exists-p type-break-auto-save-file-name)
 550          (file-readable-p type-break-auto-save-file-name))
 551     type-break-auto-save-file-name)
 552    ((and (file-exists-p type-break-file-name)
 553          (file-readable-p type-break-file-name))
 554     type-break-file-name)
 555    (t nil)))
 556
 557 (defun type-break-get-previous-time ()
 558   "Get previous break time from `type-break-file-name'.
 559 Returns nil if the file is missing or if the time breaks with the
 560 `current-time' format."
 561   (let ((file (type-break-choose-file)))
 562     (if file
 563         (timep ;; returns expected format, else nil
 564          (with-current-buffer (find-file-noselect file 'nowarn)
 565            (save-excursion
 566              (goto-char (point-min))
 567              (read (current-buffer))))))))
 568
 569 (defun type-break-get-previous-count ()
 570   "Get previous keystroke count from `type-break-file-name'.
 571 Return 0 if the file is missing or if the form read is not an
 572 integer."
 573   (let ((file (type-break-choose-file)))
 574     (if (and file
 575              (integerp
 576               (setq file
 577                     (with-current-buffer
 578                         (find-file-noselect file 'nowarn)
 579                       (save-excursion
 580                         (goto-char (point-min))
 581                         (forward-line 1)
 582                         (read (current-buffer)))))))
 583         file
 584       0)))
 585
 586 \f
 587 ;;;###autoload
 588 (defun type-break ()
 589   "Take a typing break.
 590
 591 During the break, a demo selected from the functions listed in
 592 `type-break-demo-functions' is run.
 593
 594 After the typing break is finished, the next break is scheduled
 595 as per the function `type-break-schedule'."
 596   (interactive)
 597   (do-auto-save)
 598   (type-break-cancel-schedule)
 599   ;; remove any query scheduled during interactive invocation
 600   (remove-hook 'type-break-post-command-hook 'type-break-do-query)
 601   (let ((continue t)
 602         (start-time (current-time)))
 603     (setq type-break-time-last-break start-time)
 604     (while continue
 605       (save-window-excursion
 606         ;; Eat the screen.
 607         (and (eq (selected-window) (minibuffer-window))
 608              (other-window 1))
 609         (delete-other-windows)
 610         (scroll-right (window-width))
 611         (unless type-break-terse-messages
 612           (message "Press any key to resume from typing break."))
 613
 614         (random t)
 615         (let* ((len (length type-break-demo-functions))
 616                (idx (random len))
 617                (fn (nth idx type-break-demo-functions)))
 618           (condition-case ()
 619               (funcall fn)
 620             (error nil))))
 621
 622       (let ((good-interval (or type-break-good-rest-interval
 623                                type-break-good-break-interval)))
 624         (cond
 625          (good-interval
 626           (let ((break-secs (type-break-time-difference
 627                              start-time (current-time))))
 628             (cond
 629              ((>= break-secs good-interval)
 630               (setq continue nil))
 631              ;; 60 seconds may be too much leeway if the break is only 3
 632              ;; minutes to begin with.  You can just say "no" to the query
 633              ;; below if you're in that much of a hurry.
 634              ;;((> 60 (abs (- break-secs good-interval)))
 635              ;; (setq continue nil))
 636              ((funcall
 637                type-break-query-function
 638                (format
 639                 (if type-break-terse-messages
 640                     "%s%s remaining.  Continue break? "
 641                   "%sYou really ought to rest %s more.  Continue break? ")
 642                 (type-break-time-stamp)
 643                 (type-break-format-time (- good-interval
 644                                            break-secs)))))
 645              (t
 646               (setq continue nil)))))
 647          (t (setq continue nil))))))
 648
 649   (type-break-keystroke-reset)
 650   (type-break-file-time)
 651   (type-break-mode-line-countdown-or-break nil)
 652   (type-break-schedule))
 653
 654 \f
 655 (defun type-break-schedule (&optional time start interval)
 656   "Schedule a typing break for TIME seconds from now.
 657 If time is not specified it defaults to `type-break-interval'.
 658 START and INTERVAL are used when recovering a break.
 659 START is the start of the break (defaults to now).
 660 INTERVAL is the full length of an interval (defaults to TIME)."
 661   (interactive (list (and current-prefix-arg
 662                           (prefix-numeric-value current-prefix-arg))))
 663   (or time (setq time type-break-interval))
 664   (type-break-check-post-command-hook)
 665   (type-break-cancel-schedule)
 666   (type-break-time-warning-schedule time 'reset)
 667   (type-break-run-at-time (max 1 time) nil 'type-break-alarm)
 668   (setq type-break-time-next-break
 669         (type-break-time-sum (or start (current-time))
 670                              (or interval time))))
 671
 672 (defun type-break-cancel-schedule ()
 673   (type-break-cancel-time-warning-schedule)
 674   (type-break-cancel-function-timers 'type-break-alarm)
 675   (setq type-break-alarm-p nil)
 676   (setq type-break-time-next-break nil))
 677
 678 (defun type-break-time-warning-schedule (&optional time resetp)
 679   (let ((type-break-current-time-warning-interval nil))
 680     (type-break-cancel-time-warning-schedule))
 681   (add-hook 'type-break-post-command-hook 'type-break-time-warning 'append)
 682   (cond
 683    (type-break-time-warning-intervals
 684     (and resetp
 685          (setq type-break-current-time-warning-interval
 686                type-break-time-warning-intervals))
 687
 688     (or time
 689         (setq time (type-break-time-difference (current-time)
 690                                                type-break-time-next-break)))
 691
 692     (while (and type-break-current-time-warning-interval
 693                 (> (car type-break-current-time-warning-interval) time))
 694       (setq type-break-current-time-warning-interval
 695             (cdr type-break-current-time-warning-interval)))
 696
 697     (cond
 698      (type-break-current-time-warning-interval
 699       (setq time (- time (car type-break-current-time-warning-interval)))
 700       (setq type-break-current-time-warning-interval
 701             (cdr type-break-current-time-warning-interval))
 702
 703       ;(let (type-break-current-time-warning-interval)
 704       ;  (type-break-cancel-time-warning-schedule))
 705       (type-break-run-at-time (max 1 time) nil 'type-break-time-warning-alarm)
 706
 707       (cond
 708        (resetp
 709         (setq type-break-warning-countdown-string nil))
 710        (t
 711         (setq type-break-warning-countdown-string (number-to-string time))
 712         (setq type-break-warning-countdown-string-type "seconds"))))))))
 713
 714 (defun type-break-cancel-time-warning-schedule ()
 715   (type-break-cancel-function-timers 'type-break-time-warning-alarm)
 716   (remove-hook 'type-break-post-command-hook 'type-break-time-warning)
 717   (setq type-break-current-time-warning-interval
 718         type-break-time-warning-intervals)
 719   (setq type-break-time-warning-count 0) ; avoid warnings after break
 720   (setq type-break-warning-countdown-string nil))
 721
 722 (defun type-break-alarm ()
 723   (type-break-check-post-command-hook)
 724   (setq type-break-alarm-p t)
 725   (type-break-mode-line-countdown-or-break 'break))
 726
 727 (defun type-break-time-warning-alarm ()
 728   (type-break-check-post-command-hook)
 729   (type-break-time-warning-schedule)
 730   (setq type-break-time-warning-count type-break-warning-repeat)
 731   (type-break-time-warning)
 732   (type-break-mode-line-countdown-or-break 'countdown))
 733
 734 \f
 735 (defun type-break-run-tb-post-command-hook ()
 736   (and type-break-mode
 737        (run-hooks 'type-break-post-command-hook)))
 738
 739 (defun type-break-check ()
 740   "Ask to take a typing break if appropriate.
 741 This may be the case either because the scheduled time has come \(and the
 742 minimum keystroke threshold has been reached\) or because the maximum
 743 keystroke threshold has been exceeded."
 744   (type-break-file-keystroke-count)
 745   (let* ((min-threshold (car type-break-keystroke-threshold))
 746          (max-threshold (cdr type-break-keystroke-threshold)))
 747     (and type-break-good-rest-interval
 748          (progn
 749            (and (> (type-break-time-difference
 750                     type-break-time-last-command (current-time))
 751                    type-break-good-rest-interval)
 752                 (progn
 753                   (type-break-keystroke-reset)
 754                   (type-break-mode-line-countdown-or-break nil)
 755                   (setq type-break-time-last-break (current-time))
 756                   (type-break-schedule)))
 757            (setq type-break-time-last-command (current-time))))
 758
 759     (and type-break-keystroke-threshold
 760          (let ((keys (this-command-keys)))
 761            (cond
 762             ;; Ignore mouse motion
 763             ((and (vectorp keys)
 764                   (consp (aref keys 0))
 765                   (memq (car (aref keys 0)) '(mouse-movement))))
 766             (t
 767              (setq type-break-keystroke-count
 768                    (+ type-break-keystroke-count (length keys)))))))
 769
 770     (cond
 771      (type-break-alarm-p
 772       (cond
 773        ((input-pending-p))
 774        ((eq (selected-window) (minibuffer-window)))
 775        ((and min-threshold
 776              (< type-break-keystroke-count min-threshold))
 777         (type-break-schedule))
 778        (t
 779         ;; If keystroke count is within min-threshold of
 780         ;; max-threshold, lower it to reduce the likelihood of an
 781         ;; immediate subsequent query.
 782         (and max-threshold
 783              min-threshold
 784              (< (- max-threshold type-break-keystroke-count) min-threshold)
 785              (progn
 786                (type-break-keystroke-reset)
 787                (setq type-break-keystroke-count min-threshold)))
 788         (type-break-query))))
 789      ((and type-break-keystroke-warning-intervals
 790            max-threshold
 791            (= type-break-keystroke-warning-count 0)
 792            (type-break-check-keystroke-warning)))
 793      ((and max-threshold
 794            (> type-break-keystroke-count max-threshold)
 795            (not (input-pending-p))
 796            (not (eq (selected-window) (minibuffer-window))))
 797       (type-break-keystroke-reset)
 798       (setq type-break-keystroke-count (or min-threshold 0))
 799       (type-break-query)))))
 800
 801 ;; This should return t if warnings were enabled, nil otherwise.
 802 (defun type-break-check-keystroke-warning ()
 803   ;; This is safe because the caller should have checked that the cdr was
 804   ;; non-nil already.
 805   (let ((left (- (cdr type-break-keystroke-threshold)
 806                  type-break-keystroke-count)))
 807     (cond
 808      ((null (car type-break-current-keystroke-warning-interval))
 809       nil)
 810      ((> left (car type-break-current-keystroke-warning-interval))
 811       nil)
 812      (t
 813       (while (and (car type-break-current-keystroke-warning-interval)
 814                   (< left (car type-break-current-keystroke-warning-interval)))
 815         (setq type-break-current-keystroke-warning-interval
 816               (cdr type-break-current-keystroke-warning-interval)))
 817       (setq type-break-keystroke-warning-count type-break-warning-repeat)
 818       (add-hook 'type-break-post-command-hook 'type-break-keystroke-warning)
 819       (setq type-break-warning-countdown-string (number-to-string left))
 820       (setq type-break-warning-countdown-string-type "keystrokes")
 821       (type-break-mode-line-countdown-or-break 'countdown)
 822       t))))
 823
 824 ;; Arrange for a break query to be made, when the user stops typing furiously.
 825 (defun type-break-query ()
 826   (add-hook 'type-break-post-command-hook 'type-break-do-query))
 827
 828 (defun type-break-do-query ()
 829   (cond
 830    ((not type-break-query-mode)
 831     (type-break-noninteractive-query)
 832     (type-break-schedule type-break-query-interval)
 833     (remove-hook 'type-break-post-command-hook 'type-break-do-query))
 834    ((sit-for 2)
 835     (condition-case ()
 836         (cond
 837          ((let ((type-break-mode nil)
 838                 ;; yes-or-no-p sets this-command to exit-minibuffer,
 839                 ;; which hoses undo or yank-pop (if you happened to be
 840                 ;; yanking just when the query occurred).
 841                 (this-command this-command))
 842             ;; Cancel schedule to prevent possibility of a second query
 843             ;; from taking place before this one has even returned.
 844             ;; The condition-case wrapper will reschedule on quit.
 845             (type-break-cancel-schedule)
 846             ;; Also prevent a second query when the break is interrupted.
 847             (remove-hook 'type-break-post-command-hook 'type-break-do-query)
 848             (funcall type-break-query-function
 849                      (format "%s%s"
 850                              (type-break-time-stamp)
 851                              (if type-break-terse-messages
 852                                  "Break now? "
 853                                "Take a break from typing now? "))))
 854           (type-break))
 855          (t
 856           (type-break-schedule type-break-query-interval)))
 857       (quit
 858        (type-break-schedule type-break-query-interval))))))
 859
 860 (defun type-break-noninteractive-query (&optional ignored-args)
 861   "Null query function which doesn't interrupt user and assumes `no'.
 862 It prints a reminder in the echo area to take a break, but doesn't enforce
 863 this or ask the user to start one right now."
 864   (cond
 865    (type-break-mode-line-message-mode)
 866    (t
 867     (beep t)
 868     (message "%sYou should take a typing break now.  Do `M-x type-break'."
 869              (type-break-time-stamp))
 870     (sit-for 1)
 871     (beep t)
 872     ;; return nil so query caller knows to reset reminder, as if user
 873     ;; said "no" in response to yes-or-no-p.
 874     nil)))
 875
 876 (defun type-break-time-warning ()
 877   (cond
 878    ((and (car type-break-keystroke-threshold)
 879          (< type-break-keystroke-count (car type-break-keystroke-threshold))))
 880    ((> type-break-time-warning-count 0)
 881     (let ((timeleft (type-break-time-difference (current-time)
 882                                                 type-break-time-next-break)))
 883       (setq type-break-warning-countdown-string (number-to-string timeleft))
 884       (cond
 885        ((eq (selected-window) (minibuffer-window)))
 886        ;; Do nothing if the command was just a prefix arg, since that will
 887        ;; immediately be followed by some other interactive command.
 888        ;; Otherwise, it is particularly annoying for the sit-for below to
 889        ;; delay redisplay when one types sequences like `C-u -1 C-l'.
 890        ((memq this-command '(digit-argument universal-argument)))
 891        ((not type-break-mode-line-message-mode)
 892         ;; Pause for a moment so any previous message can be seen.
 893         (sit-for 2)
 894         (message "%sWarning: typing break due in %s."
 895                  (type-break-time-stamp)
 896                  (type-break-format-time timeleft))
 897         (setq type-break-time-warning-count
 898               (1- type-break-time-warning-count))))))
 899    (t
 900     (remove-hook 'type-break-post-command-hook 'type-break-time-warning)
 901     (setq type-break-warning-countdown-string nil))))
 902
 903 (defun type-break-keystroke-warning ()
 904   (cond
 905    ((> type-break-keystroke-warning-count 0)
 906     (setq type-break-warning-countdown-string
 907           (number-to-string (- (cdr type-break-keystroke-threshold)
 908                                type-break-keystroke-count)))
 909     (cond
 910      ((eq (selected-window) (minibuffer-window)))
 911      ;; Do nothing if the command was just a prefix arg, since that will
 912      ;; immediately be followed by some other interactive command.
 913      ;; Otherwise, it is particularly annoying for the sit-for below to
 914      ;; delay redisplay when one types sequences like `C-u -1 C-l'.
 915      ((memq this-command '(digit-argument universal-argument)))
 916      ((not type-break-mode-line-message-mode)
 917       (sit-for 2)
 918       (message "%sWarning: typing break due in %s keystrokes."
 919                (type-break-time-stamp)
 920                (- (cdr type-break-keystroke-threshold)
 921                   type-break-keystroke-count))
 922       (setq type-break-keystroke-warning-count
 923             (1- type-break-keystroke-warning-count)))))
 924    (t
 925     (remove-hook 'type-break-post-command-hook
 926                  'type-break-keystroke-warning)
 927     (setq type-break-warning-countdown-string nil))))
 928
 929 (defun type-break-mode-line-countdown-or-break (&optional type)
 930   (cond
 931    ((not type-break-mode-line-message-mode))
 932    ((eq type 'countdown)
 933     ;(setq type-break-mode-line-break-message-p nil)
 934     (add-hook 'type-break-post-command-hook
 935               'type-break-force-mode-line-update 'append))
 936    ((eq type 'break)
 937     ;; Alternate
 938     (setq type-break-mode-line-break-message-p
 939           (not type-break-mode-line-break-message-p))
 940     (remove-hook 'type-break-post-command-hook
 941                  'type-break-force-mode-line-update))
 942    (t
 943     (setq type-break-mode-line-break-message-p nil)
 944     (setq type-break-warning-countdown-string nil)
 945     (remove-hook 'type-break-post-command-hook
 946                  'type-break-force-mode-line-update)))
 947   (type-break-force-mode-line-update))
 948
 949 \f
 950 ;;;###autoload
 951 (defun type-break-statistics ()
 952   "Print statistics about typing breaks in a temporary buffer.
 953 This includes the last time a typing break was taken, when the next one is
 954 scheduled, the keystroke thresholds and the current keystroke count, etc."
 955   (interactive)
 956   (with-output-to-temp-buffer "*Typing Break Statistics*"
 957     (princ (format "Typing break statistics\n-----------------------\n
 958 Typing break mode is currently %s.
 959 Interactive query for breaks is %s.
 960 Warnings of imminent typing breaks in mode line is %s.
 961
 962 Last typing break ended     : %s
 963 Next scheduled typing break : %s\n
 964 Minimum keystroke threshold : %s
 965 Maximum keystroke threshold : %s
 966 Current keystroke count     : %s"
 967                    (if type-break-mode "enabled" "disabled")
 968                    (if type-break-query-mode "enabled" "disabled")
 969                    (if type-break-mode-line-message-mode "enabled" "disabled")
 970                    (if type-break-time-last-break
 971                        (current-time-string type-break-time-last-break)
 972                      "never")
 973                    (if (and type-break-mode type-break-time-next-break)
 974                        (format "%s\t(%s from now)"
 975                                (current-time-string type-break-time-next-break)
 976                                (type-break-format-time
 977                                 (type-break-time-difference
 978                                 (current-time)
 979                                 type-break-time-next-break)))
 980                      "none scheduled")
 981                    (or (car type-break-keystroke-threshold) "none")
 982                    (or (cdr type-break-keystroke-threshold) "none")
 983                    type-break-keystroke-count))))
 984
 985 ;;;###autoload
 986 (defun type-break-guesstimate-keystroke-threshold (wpm &optional wordlen frac)
 987   "Guess values for the minimum/maximum keystroke threshold for typing breaks.
 988
 989 If called interactively, the user is prompted for their guess as to how
 990 many words per minute they usually type.  This value should not be your
 991 maximum WPM, but your average.  Of course, this is harder to gauge since it
 992 can vary considerably depending on what you are doing.  For example, one
 993 tends to type less when debugging a program as opposed to writing
 994 documentation.  (Perhaps a separate program should be written to estimate
 995 average typing speed.)
 996
 997 From that, this command sets the values in `type-break-keystroke-threshold'
 998 based on a fairly simple algorithm involving assumptions about the average
 999 length of words (5).  For the minimum threshold, it uses about a fifth of
1000 the computed maximum threshold.
1001
1002 When called from Lisp programs, the optional args WORDLEN and FRAC can be
1003 used to override the default assumption about average word length and the
1004 fraction of the maximum threshold to which to set the minimum threshold.
1005 FRAC should be the inverse of the fractional value; for example, a value of
1006 2 would mean to use one half, a value of 4 would mean to use one quarter, etc."
1007   (interactive "NOn average, how many words per minute do you type? ")
1008   (let* ((upper (* wpm (or wordlen 5) (/ type-break-interval 60)))
1009          (lower (/ upper (or frac 5))))
1010     (or type-break-keystroke-threshold
1011         (setq type-break-keystroke-threshold (cons nil nil)))
1012     (setcar type-break-keystroke-threshold lower)
1013     (setcdr type-break-keystroke-threshold upper)
1014     (if (interactive-p)
1015         (message "min threshold: %d\tmax threshold: %d" lower upper))
1016     type-break-keystroke-threshold))
1017
1018 \f
1019 ;;; misc functions
1020
1021 ;; Compute the difference, in seconds, between a and b, two structures
1022 ;; similar to those returned by `current-time'.
1023 ;; Use addition rather than logand since that is more robust; the low 16
1024 ;; bits of the seconds might have been incremented, making it more than 16
1025 ;; bits wide.
1026 (defun type-break-time-difference (a b)
1027   (+ (lsh (- (car b) (car a)) 16)
1028      (- (car (cdr b)) (car (cdr a)))))
1029
1030 ;; Return (in a new list the same in structure to that returned by
1031 ;; `current-time') the sum of the arguments.  Each argument may be a time
1032 ;; list or a single integer, a number of seconds.
1033 ;; This function keeps the high and low 16 bits of the seconds properly
1034 ;; balanced so that the lower value never exceeds 16 bits.  Otherwise, when
1035 ;; the result is passed to `current-time-string' it will toss some of the
1036 ;; "low" bits and format the time incorrectly.
1037 (defun type-break-time-sum (&rest tmlist)
1038   (let ((high 0)
1039         (low 0)
1040         (micro 0)
1041         tem)
1042     (while tmlist
1043       (setq tem (car tmlist))
1044       (setq tmlist (cdr tmlist))
1045       (cond
1046        ((numberp tem)
1047         (setq low (+ low tem)))
1048        (t
1049         (setq high  (+ high  (or (car tem) 0)))
1050         (setq low   (+ low   (or (car (cdr tem)) 0)))
1051         (setq micro (+ micro (or (car (cdr (cdr tem))) 0))))))
1052
1053     (and (>= micro 1000000)
1054          (progn
1055            (setq tem (/ micro 1000000))
1056            (setq low (+ low tem))
1057            (setq micro (- micro (* tem 1000000)))))
1058
1059     (setq tem (lsh low -16))
1060     (and (> tem 0)
1061          (progn
1062            (setq low (logand low 65535))
1063            (setq high (+ high tem))))
1064
1065     (list high low micro)))
1066
1067 (defun type-break-time-stamp (&optional when)
1068   (if (fboundp 'format-time-string)
1069       (format-time-string type-break-time-stamp-format when)
1070     ;; Emacs 19.28 and prior do not have format-time-string.
1071     ;; In that case, result is not customizable.  Upgrade today!
1072     (format "[%s] " (substring (current-time-string when) 11 16))))
1073
1074 (defun type-break-format-time (secs)
1075   (let ((mins (/ secs 60)))
1076     (cond
1077      ((= mins 1) (format "%d minute" mins))
1078      ((> mins 0) (format "%d minutes" mins))
1079      ((= secs 1) (format "%d second" secs))
1080      (t (format "%d seconds" secs)))))
1081
1082 (defun type-break-keystroke-reset ()
1083   (setq type-break-interval-start (current-time)) ; not a keystroke
1084   (setq type-break-keystroke-count 0)
1085   (setq type-break-keystroke-warning-count 0)
1086   (setq type-break-current-keystroke-warning-interval
1087         type-break-keystroke-warning-intervals)
1088   (remove-hook 'type-break-post-command-hook 'type-break-keystroke-warning))
1089
1090 (defun type-break-force-mode-line-update (&optional all)
1091   "Force the mode-line of the current buffer to be redisplayed.
1092 With optional non-nil ALL, force redisplay of all mode-lines."
1093   (and all (save-excursion (set-buffer (other-buffer))))
1094   (set-buffer-modified-p (buffer-modified-p)))
1095
1096 ;; If an exception occurs in Emacs while running the post command hook, the
1097 ;; value of that hook is clobbered.  This is because the value of the
1098 ;; variable is temporarily set to nil while it's running to prevent
1099 ;; recursive application, but it also means an exception aborts the routine
1100 ;; of restoring it.  This function is called from the timers to restore it,
1101 ;; just in case.
1102 (defun type-break-check-post-command-hook ()
1103   (add-hook 'post-command-hook 'type-break-run-tb-post-command-hook 'append))
1104
1105 \f
1106 ;;; Timer wrapper functions
1107 ;;;
1108 ;;; These shield type-break from variations in the interval timer packages
1109 ;;; for different versions of Emacs.
1110
1111 (defun type-break-run-at-time (time repeat function)
1112   (condition-case nil (or (require 'timer) (require 'itimer)) (error nil))
1113   (run-at-time time repeat function))
1114
1115 (defvar timer-dont-exit)
1116 (defun type-break-cancel-function-timers (function)
1117   (let ((timer-dont-exit t))
1118     (cancel-function-timers function)))
1119
1120 \f
1121 ;;; Demo wrappers
1122
1123 ;; This is a wrapper around hanoi that calls it with an arg large enough to
1124 ;; make the largest discs possible that will fit in the window.
1125 ;; Also, clean up the *Hanoi* buffer after we're done.
1126 (defun type-break-demo-hanoi ()
1127   "Take a hanoiing typing break."
1128   (and (get-buffer "*Hanoi*")
1129        (kill-buffer "*Hanoi*"))
1130   (condition-case ()
1131       (progn
1132         (hanoi (/ (window-width) 8))
1133         ;; Wait for user to come back.
1134         (read-char)
1135         (kill-buffer "*Hanoi*"))
1136     (quit
1137      ;; eat char
1138      (read-char)
1139      (and (get-buffer "*Hanoi*")
1140           (kill-buffer "*Hanoi*")))))
1141
1142 ;; This is a wrapper around life that calls it with a `sleep' arg to make
1143 ;; it run a little more leisurely.
1144 ;; Also, clean up the *Life* buffer after we're done.
1145 (defun type-break-demo-life ()
1146   "Take a typing break and get a life."
1147   (let ((continue t))
1148     (while continue
1149       (setq continue nil)
1150       (and (get-buffer "*Life*")
1151            (kill-buffer "*Life*"))
1152       (condition-case ()
1153           (progn
1154             (life 3)
1155             ;; wait for user to return
1156             (read-char)
1157             (kill-buffer "*Life*"))
1158         (life-extinct
1159          (message "%s" (get 'life-extinct 'error-message))
1160          (sit-for 3)
1161          ;; restart demo
1162          (setq continue t))
1163         (quit
1164          (and (get-buffer "*Life*")
1165               (kill-buffer "*Life*")))))))
1166
1167 ;; Boring demo, but doesn't use many cycles
1168 (defun type-break-demo-boring ()
1169   "Boring typing break demo."
1170   (let ((rmsg (if type-break-terse-messages
1171                   ""
1172                 "Press any key to resume from typing break"))
1173         (buffer-name "*Typing Break Buffer*")
1174         lines elapsed timeleft tmsg)
1175     (condition-case ()
1176         (progn
1177           (switch-to-buffer (get-buffer-create buffer-name))
1178           (buffer-disable-undo (current-buffer))
1179           (setq lines (/ (window-body-height) 2))
1180           (unless type-break-terse-messages (setq lines (1- lines)))
1181           (if type-break-demo-boring-stats
1182               (setq lines (- lines 2)))
1183           (setq lines (make-string lines ?\C-j))
1184           (while (not (input-pending-p))
1185             (erase-buffer)
1186             (setq elapsed (type-break-time-difference
1187                            type-break-time-last-break
1188                            (current-time)))
1189             (let ((good-interval (or type-break-good-rest-interval
1190                                      type-break-good-break-interval)))
1191               (cond
1192                (good-interval
1193                 (setq timeleft (- good-interval elapsed))
1194                 (if (> timeleft 0)
1195                     (setq tmsg
1196                           (format (if type-break-terse-messages
1197                                       "Break remaining: %s"
1198                                     "You should rest for %s more")
1199                                   (type-break-format-time timeleft)))
1200                   (setq tmsg
1201                         (format (if type-break-terse-messages
1202                                     "Break complete (%s elapsed in total)"
1203                                   "Typing break has lasted %s")
1204                                 (type-break-format-time elapsed)))))
1205                (t
1206                 (setq tmsg
1207                       (format (if type-break-terse-messages
1208                                   "Break has lasted %s"
1209                                 "Typing break has lasted %s")
1210                               (type-break-format-time elapsed))))))
1211             (insert lines
1212                     (make-string (/ (- (window-width) (length tmsg)) 2) ?\ )
1213                     tmsg)
1214             (if (> (length rmsg) 0)
1215                 (insert "\n"
1216                         (make-string (/ (- (window-width) (length rmsg)) 2)
1217                                      ?\ )
1218                         rmsg))
1219             (if type-break-demo-boring-stats
1220                 (let*
1221                     ((message
1222                       (format
1223                        (if type-break-terse-messages
1224                            "Since last break: %s keystrokes\n"
1225                          "Since your last break you've typed %s keystrokes\n")
1226                        type-break-keystroke-count))
1227                      (column-spaces
1228                       (make-string (/ (- (window-width) (length message)) 2)
1229                                    ?\ ))
1230                      (wpm (/ (/ (float type-break-keystroke-count) 5)
1231                              (/ (type-break-time-difference
1232                                  type-break-interval-start
1233                                  type-break-time-last-break)
1234                                 60.0))))
1235                   (insert "\n\n" column-spaces message)
1236                   (if type-break-terse-messages
1237                       (insert (format "                  %s%.2f wpm"
1238                                       column-spaces
1239                                       wpm))
1240                     (setq message
1241                           (format "at an average of %.2f words per minute"
1242                                   wpm))
1243                     (insert
1244                      (make-string (/ (- (window-width) (length message)) 2)
1245                                   ?\ )
1246                      message))))
1247             (goto-char (point-min))
1248             (sit-for 60))
1249           (read-char)
1250           (kill-buffer buffer-name))
1251       (quit
1252        (and (get-buffer buffer-name)
1253             (kill-buffer buffer-name))))))
1254
1255 \f
1256 (provide 'type-break)
1257
1258 (if type-break-mode
1259     (type-break-mode 1))
1260
1261 ;;; arch-tag: 943a2eb3-07e6-420b-993f-96e4796f5fd0
1262 ;;; type-break.el ends here