lisp/dirtrack.el

   1 ;;; dirtrack.el --- Directory Tracking by watching the prompt
   2
   3 ;; Copyright (C) 1996, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Peter Breton <pbreton@cs.umb.edu>
   7 ;; Created: Sun Nov 17 1996
   8 ;; Keywords: processes
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Shell directory tracking by watching the prompt.
  30 ;;
  31 ;; This is yet another attempt at a directory-tracking package for
  32 ;; Emacs shell-mode.  However, this package makes one strong assumption:
  33 ;; that you can customize your shell's prompt to contain the
  34 ;; current working directory.  Most shells do support this, including
  35 ;; almost every type of Bourne and C shell on Unix, the native shells on
  36 ;; Windows95 (COMMAND.COM) and Windows NT (CMD.EXE), and most 3rd party
  37 ;; Windows shells.  If you cannot do this, or do not wish to, this package
  38 ;; will be useless to you.
  39 ;;
  40 ;; Installation:
  41 ;;
  42 ;; 1) Set your shell's prompt to contain the current working directory.
  43 ;; You may need to consult your shell's documentation to find out how to
  44 ;; do this.
  45 ;;
  46 ;; Note that directory tracking is done by matching regular expressions,
  47 ;; therefore it is *VERY IMPORTANT* for your prompt to be easily
  48 ;; distinguishable from other output.  If your prompt regexp is too general,
  49 ;; you will see error messages from the dirtrack filter as it attempts to cd
  50 ;; to non-existent directories.
  51 ;;
  52 ;; 2) Set the variable `dirtrack-list' to an appropriate value.  This
  53 ;; should be a list of two elements: the first is a regular expression
  54 ;; which matches your prompt up to and including the pathname part.
  55 ;; The second is a number which tells which regular expression group to
  56 ;; match to extract only the pathname.  If you use a multi-line prompt,
  57 ;; add 't' as a third element.  Note that some of the functions in
  58 ;; 'comint.el' assume a single-line prompt (eg, comint-bol).
  59 ;;
  60 ;; Determining this information may take some experimentation.  Using
  61 ;; `dirtrack-debug-mode' may help; it causes the directory-tracking
  62 ;; filter to log messages to the buffer `dirtrack-debug-buffer'.
  63 ;;
  64 ;; 3) Activate `dirtrack-mode'.  You may wish to turn ordinary shell
  65 ;; tracking off by calling `shell-dirtrack-mode'.
  66 ;;
  67 ;; Examples:
  68 ;;
  69 ;; 1) On Windows NT, my prompt is set to emacs$S$P$G.
  70 ;; 'dirtrack-list' is set to (list "^emacs \\([a-zA-Z]:.*\\)>" 1)
  71 ;;
  72 ;; 2) On Solaris running bash, my prompt is set like this:
  73 ;;    PS1="\w\012emacs@\h(\!) [\t]% "
  74 ;;    'dirtrack-list' is set to (list "^\\([/~].*\\)\nemacs@[^%]+% *" 1 t)
  75 ;;
  76 ;; I'd appreciate other examples from people who use this package.
  77 ;;
  78 ;; Here's one from Stephen Eglen:
  79 ;;
  80 ;;   Running under tcsh:
  81 ;;   (setq-default dirtrack-list '("^%E \\([^ ]+\\)" 1))
  82 ;;
  83 ;;   It might be worth mentioning in your file that emacs sources start up
  84 ;;   files of the form: ~/.emacs_<SHELL> where <SHELL> is the name of the
  85 ;;   shell.  So for example, I have the following in ~/.emacs_tcsh:
  86 ;;
  87 ;;   set prompt = "%%E %~ %h% "
  88 ;;
  89 ;;   This produces a prompt of the form:
  90 ;;   %E /var/spool 10%
  91 ;;
  92 ;;   This saves me from having to use the %E prefix in other non-emacs
  93 ;;   shells.
  94 ;;
  95 ;; A final note:
  96 ;;
  97 ;;   I run LOTS of shell buffers through Emacs, sometimes as different users
  98 ;;   (eg, when logged in as myself, I'll run a root shell in the same Emacs).
  99 ;;   If you do this, and the shell prompt contains a ~, Emacs will interpret
 100 ;;   this relative to the user which owns the Emacs process, not the user
 101 ;;   who owns the shell buffer.  This may cause dirtrack to behave strangely
 102 ;;   (typically it reports that it is unable to cd to a directory
 103 ;;   with a ~ in it).
 104 ;;
 105 ;;   The same behavior can occur if you use dirtrack with remote filesystems
 106 ;;   (using telnet, rlogin, etc) as Emacs will be checking the local
 107 ;;   filesystem, not the remote one.  This problem is not specific to dirtrack,
 108 ;;   but also affects file completion, etc.
 109
 110 ;;; Code:
 111
 112 (eval-when-compile
 113   (require 'comint)
 114   (require 'shell))
 115
 116 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 117 ;; Customization Variables
 118 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 119
 120 (defgroup dirtrack nil
 121   "Directory tracking by watching the prompt."
 122   :prefix "dirtrack-"
 123   :group 'shell)
 124
 125 (defcustom dirtrack-list (list "^emacs \\([a-zA-Z]:.*\\)>" 1)
 126   "List for directory tracking.
 127 First item is a regexp that describes where to find the path in a prompt.
 128 Second is a number, the regexp group to match.  Optional third item is
 129 whether the prompt is multi-line.  If nil or omitted, prompt is assumed to
 130 be on a single line."
 131   :group 'dirtrack
 132   :type  '(sexp (regexp  :tag "Prompt Expression")
 133                 (integer :tag "Regexp Group")
 134                 (boolean :tag "Multiline Prompt")))
 135
 136 (make-variable-buffer-local 'dirtrack-list)
 137
 138 (defcustom dirtrack-debug nil
 139   "If non-nil, the function `dirtrack' will report debugging info."
 140   :group 'dirtrack
 141   :type  'boolean)
 142
 143 (defcustom dirtrack-debug-buffer "*Directory Tracking Log*"
 144   "Buffer in which to write directory tracking debug information."
 145   :group 'dirtrack
 146   :type  'string)
 147
 148 (defcustom dirtrackp t
 149   "If non-nil, directory tracking via `dirtrack' is enabled."
 150   :group 'dirtrack
 151   :type  'boolean)
 152
 153 (make-variable-buffer-local 'dirtrackp)
 154
 155 (defcustom dirtrack-directory-function
 156   (if (memq system-type (list 'ms-dos 'windows-nt 'cygwin))
 157       'dirtrack-windows-directory-function
 158     'file-name-as-directory)
 159   "Function to apply to the prompt directory for comparison purposes."
 160   :group 'dirtrack
 161   :type  'function)
 162
 163 (defcustom dirtrack-canonicalize-function
 164   (if (memq system-type (list 'ms-dos 'windows-nt 'cygwin))
 165       'downcase 'identity)
 166   "Function to apply to the default directory for comparison purposes."
 167   :group 'dirtrack
 168   :type  'function)
 169
 170 (defcustom dirtrack-directory-change-hook nil
 171   "Hook that is called when a directory change is made."
 172   :group 'dirtrack
 173   :type 'hook)
 174
 175
 176 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 177 ;; Functions
 178 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 179
 180
 181 (defun dirtrack-windows-directory-function (dir)
 182   "Return a canonical directory for comparison purposes.
 183 Such a directory is all lowercase, has forward-slashes as delimiters,
 184 and ends with a forward slash."
 185   (file-name-as-directory (downcase (subst-char-in-string ?\\ ?/ dir))))
 186
 187 (defun dirtrack-cygwin-directory-function (dir)
 188   "Return a canonical directory taken from a Cygwin path for comparison purposes."
 189   (if (string-match "/cygdrive/\\([A-Z]\\)\\(.*\\)" dir)
 190       (concat (match-string 1 dir) ":" (match-string 2 dir))
 191     dir))
 192
 193
 194 ;;;###autoload
 195 (define-minor-mode dirtrack-mode
 196   "Enable or disable Dirtrack directory tracking in a shell buffer.
 197 This method requires that your shell prompt contain the full
 198 current working directory at all times, and that `dirtrack-list'
 199 is set to match the prompt.  This is an alternative to
 200 `shell-dirtrack-mode', which works differently, by tracking `cd'
 201 and similar commands which change the shell working directory."
 202   nil nil nil
 203   (if dirtrack-mode
 204       (add-hook 'comint-preoutput-filter-functions 'dirtrack nil t)
 205     (remove-hook 'comint-preoutput-filter-functions 'dirtrack t)))
 206
 207 (define-obsolete-function-alias 'dirtrack-toggle 'dirtrack-mode "23.1")
 208 (define-obsolete-variable-alias 'dirtrackp 'dirtrack-mode "23.1")
 209
 210
 211 (define-minor-mode dirtrack-debug-mode
 212   "Enable or disable Dirtrack debugging."
 213   nil nil nil
 214   (if dirtrack-debug-mode
 215       (display-buffer (get-buffer-create dirtrack-debug-buffer))))
 216
 217 (define-obsolete-function-alias 'dirtrack-debug-toggle 'dirtrack-debug-mode
 218   "23.1")
 219 (define-obsolete-variable-alias 'dirtrack-debug 'dirtrack-debug-mode "23.1")
 220
 221
 222 (defun dirtrack-debug-message (string)
 223   "Insert string at the end of `dirtrack-debug-buffer'."
 224   (when dirtrack-debug-mode
 225     (with-current-buffer (get-buffer-create dirtrack-debug-buffer)
 226       (goto-char (point-max))
 227       (insert (concat string "\n")))))
 228
 229 ;;;###autoload
 230 (defun dirtrack (input)
 231   "Determine the current directory by scanning the process output for a prompt.
 232 The prompt to look for is the first item in `dirtrack-list'.
 233
 234 You can toggle directory tracking by using the function `dirtrack-mode'.
 235
 236 If directory tracking does not seem to be working, you can use the
 237 function `dirtrack-debug-mode' to turn on debugging output."
 238   (unless (or (null dirtrack-mode)
 239               (eq (point) (point-min)))     ; no output?
 240     (let (prompt-path
 241           (current-dir default-directory)
 242           (dirtrack-regexp    (nth 0 dirtrack-list))
 243           (match-num          (nth 1 dirtrack-list))
 244           ;; Currently unimplemented, it seems.  --Stef
 245           (multi-line         (nth 2 dirtrack-list)))
 246       (save-excursion
 247         ;; No match
 248         (if (not (string-match dirtrack-regexp input))
 249             (dirtrack-debug-message
 250              (format "Input `%s' failed to match `dirtrack-regexp'" input))
 251           (setq prompt-path (match-string match-num input))
 252           ;; Empty string
 253           (if (not (> (length prompt-path) 0))
 254               (dirtrack-debug-message "Match is empty string")
 255             ;; Transform prompts into canonical forms
 256             (setq prompt-path (funcall dirtrack-directory-function
 257                                        prompt-path)
 258                   current-dir (funcall dirtrack-canonicalize-function
 259                                        current-dir))
 260             (dirtrack-debug-message
 261              (format "Prompt is %s\nCurrent directory is %s"
 262                      prompt-path current-dir))
 263             ;; Compare them
 264             (if (or (string= current-dir prompt-path)
 265                     (string= current-dir (abbreviate-file-name prompt-path)))
 266                 (dirtrack-debug-message (format "Not changing directory"))
 267               ;; It's possible that Emacs will think the directory
 268               ;; won't exist (eg, rlogin buffers)
 269               (if (file-accessible-directory-p prompt-path)
 270                   ;; Change directory
 271                   (and (shell-process-cd prompt-path)
 272                        (run-hooks 'dirtrack-directory-change-hook)
 273                        (dirtrack-debug-message
 274                         (format "Changing directory to %s" prompt-path)))
 275                 (error "Directory %s does not exist" prompt-path)))
 276             )))))
 277   input)
 278
 279 (provide 'dirtrack)
 280
 281 ;; arch-tag: 168de071-be88-4937-aff6-2aba9f328d5a
 282 ;;; dirtrack.el ends here