lisp/macros.el

   1 ;;; macros.el --- non-primitive commands for keyboard macros
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1992, 1994, 1995, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: abbrev
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Extension commands for keyboard macros.  These permit you to assign
  27 ;; a name to the last-defined keyboard macro, expand and insert the
  28 ;; lisp corresponding to a macro, query the user from within a macro,
  29 ;; or apply a macro to each line in the reason.
  30
  31 ;;; Code:
  32
  33 ;;;###autoload
  34 (defun name-last-kbd-macro (symbol)
  35   "Assign a name to the last keyboard macro defined.
  36 Argument SYMBOL is the name to define.
  37 The symbol's function definition becomes the keyboard macro string.
  38 Such a \"function\" cannot be called from Lisp, but it is a valid editor command."
  39   (interactive "SName for last kbd macro: ")
  40   (or last-kbd-macro
  41       (error "No keyboard macro defined"))
  42   (and (fboundp symbol)
  43        (not (stringp (symbol-function symbol)))
  44        (not (vectorp (symbol-function symbol)))
  45        (error "Function %s is already defined and not a keyboard macro"
  46               symbol))
  47   (if (string-equal symbol "")
  48       (error "No command name given"))
  49   (fset symbol last-kbd-macro))
  50
  51 ;;;###autoload
  52 (defun insert-kbd-macro (macroname &optional keys)
  53   "Insert in buffer the definition of kbd macro NAME, as Lisp code.
  54 Optional second arg KEYS means also record the keys it is on
  55 \(this is the prefix argument, when calling interactively).
  56
  57 This Lisp code will, when executed, define the kbd macro with the same
  58 definition it has now.  If you say to record the keys, the Lisp code
  59 will also rebind those keys to the macro.  Only global key bindings
  60 are recorded since executing this Lisp code always makes global
  61 bindings.
  62
  63 To save a kbd macro, visit a file of Lisp code such as your `~/.emacs',
  64 use this command, and then save the file."
  65   (interactive (list (intern (completing-read "Insert kbd macro (name): "
  66                                               obarray
  67                                               (lambda (elt)
  68                                                 (and (fboundp elt)
  69                                                      (or (stringp (symbol-function elt))
  70                                                          (vectorp (symbol-function elt))
  71                                                          (get elt 'kmacro))))
  72                                               t))
  73                      current-prefix-arg))
  74   (let (definition)
  75     (if (string= (symbol-name macroname) "")
  76         (progn
  77           (setq macroname 'last-kbd-macro definition last-kbd-macro)
  78           (insert "(setq "))
  79       (setq definition (symbol-function macroname))
  80       (insert "(fset '"))
  81     (prin1 macroname (current-buffer))
  82     (insert "\n   ")
  83     (if (stringp definition)
  84         (let ((beg (point)) end)
  85           (prin1 definition (current-buffer))
  86           (setq end (point-marker))
  87           (goto-char beg)
  88           (while (< (point) end)
  89             (let ((char (following-char)))
  90               (cond ((= char 0)
  91                      (delete-region (point) (1+ (point)))
  92                      (insert "\\C-@"))
  93                     ((< char 27)
  94                      (delete-region (point) (1+ (point)))
  95                      (insert "\\C-" (+ 96 char)))
  96                     ((= char ?\C-\\)
  97                      (delete-region (point) (1+ (point)))
  98                      (insert "\\C-\\\\"))
  99                     ((< char 32)
 100                      (delete-region (point) (1+ (point)))
 101                      (insert "\\C-" (+ 64 char)))
 102                     ((< char 127)
 103                      (forward-char 1))
 104                     ((= char 127)
 105                      (delete-region (point) (1+ (point)))
 106                      (insert "\\C-?"))
 107                     ((= char 128)
 108                      (delete-region (point) (1+ (point)))
 109                      (insert "\\M-\\C-@"))
 110                     ((= char (aref "\M-\C-\\" 0))
 111                      (delete-region (point) (1+ (point)))
 112                      (insert "\\M-\\C-\\\\"))
 113                     ((< char 155)
 114                      (delete-region (point) (1+ (point)))
 115                      (insert "\\M-\\C-" (- char 32)))
 116                     ((< char 160)
 117                      (delete-region (point) (1+ (point)))
 118                      (insert "\\M-\\C-" (- char 64)))
 119                     ((= char (aref "\M-\\" 0))
 120                      (delete-region (point) (1+ (point)))
 121                      (insert "\\M-\\\\"))
 122                     ((< char 255)
 123                      (delete-region (point) (1+ (point)))
 124                      (insert "\\M-" (- char 128)))
 125                     ((= char 255)
 126                      (delete-region (point) (1+ (point)))
 127                      (insert "\\M-\\C-?"))))))
 128       (if (vectorp definition)
 129           (let ((len (length definition)) (i 0) char mods)
 130             (while (< i len)
 131               (insert (if (zerop i) ?\[ ?\s))
 132               (setq char (aref definition i)
 133                     i (1+ i))
 134               (if (not (numberp char))
 135                   (prin1 char (current-buffer))
 136                 (princ (prin1-char char) (current-buffer))))
 137             (insert ?\]))
 138         (prin1 definition (current-buffer))))
 139     (insert ")\n")
 140     (if keys
 141         (let ((keys (where-is-internal (symbol-function macroname)
 142                                        '(keymap))))
 143           (while keys
 144             (insert "(global-set-key ")
 145             (prin1 (car keys) (current-buffer))
 146             (insert " '")
 147             (prin1 macroname (current-buffer))
 148             (insert ")\n")
 149             (setq keys (cdr keys)))))))
 150
 151 ;;;###autoload
 152 (defun kbd-macro-query (flag)
 153   "Query user during kbd macro execution.
 154   With prefix argument, enters recursive edit, reading keyboard
 155 commands even within a kbd macro.  You can give different commands
 156 each time the macro executes.
 157   Without prefix argument, asks whether to continue running the macro.
 158 Your options are: \\<query-replace-map>
 159 \\[act] Finish this iteration normally and continue with the next.
 160 \\[skip]        Skip the rest of this iteration, and start the next.
 161 \\[exit]        Stop the macro entirely right now.
 162 \\[recenter]    Redisplay the screen, then ask again.
 163 \\[edit]        Enter recursive edit; ask again when you exit from that."
 164   (interactive "P")
 165   (or executing-kbd-macro
 166       defining-kbd-macro
 167       (error "Not defining or executing kbd macro"))
 168   (if flag
 169       (let (executing-kbd-macro defining-kbd-macro)
 170         (recursive-edit))
 171     (if (not executing-kbd-macro)
 172         nil
 173       (let ((loop t)
 174             (msg (substitute-command-keys
 175                   "Proceed with macro?\\<query-replace-map>\
 176  (\\[act], \\[skip], \\[exit], \\[recenter], \\[edit]) ")))
 177         (while loop
 178           (let ((key (let ((executing-kbd-macro nil)
 179                            (defining-kbd-macro nil))
 180                        (message "%s" msg)
 181                        (read-event)))
 182                 def)
 183             (setq key (vector key))
 184             (setq def (lookup-key query-replace-map key))
 185             (cond ((eq def 'act)
 186                    (setq loop nil))
 187                   ((eq def 'skip)
 188                    (setq loop nil)
 189                    (setq executing-kbd-macro ""))
 190                   ((eq def 'exit)
 191                    (setq loop nil)
 192                    (setq executing-kbd-macro t))
 193                   ((eq def 'recenter)
 194                    (recenter nil))
 195                   ((eq def 'edit)
 196                    (let (executing-kbd-macro defining-kbd-macro)
 197                      (recursive-edit)))
 198                   ((eq def 'quit)
 199                    (setq quit-flag t))
 200                   (t
 201                    (or (eq def 'help)
 202                        (ding))
 203                    (with-output-to-temp-buffer "*Help*"
 204                      (princ
 205                       (substitute-command-keys
 206                        "Specify how to proceed with keyboard macro execution.
 207 Possibilities: \\<query-replace-map>
 208 \\[act] Finish this iteration normally and continue with the next.
 209 \\[skip]        Skip the rest of this iteration, and start the next.
 210 \\[exit]        Stop the macro entirely right now.
 211 \\[recenter]    Redisplay the screen, then ask again.
 212 \\[edit]        Enter recursive edit; ask again when you exit from that."))
 213                      (with-current-buffer standard-output
 214                        (help-mode)))))))))))
 215
 216 ;;;###autoload
 217 (defun apply-macro-to-region-lines (top bottom &optional macro)
 218   "Apply last keyboard macro to all lines in the region.
 219 For each line that begins in the region, move to the beginning of
 220 the line, and run the last keyboard macro.
 221
 222 When called from lisp, this function takes two arguments TOP and
 223 BOTTOM, describing the current region.  TOP must be before BOTTOM.
 224 The optional third argument MACRO specifies a keyboard macro to
 225 execute.
 226
 227 This is useful for quoting or unquoting included text, adding and
 228 removing comments, or producing tables where the entries are regular.
 229
 230 For example, in Usenet articles, sections of text quoted from another
 231 author are indented, or have each line start with `>'.  To quote a
 232 section of text, define a keyboard macro which inserts `>', put point
 233 and mark at opposite ends of the quoted section, and use
 234 `\\[apply-macro-to-region-lines]' to mark the entire section.
 235
 236 Suppose you wanted to build a keyword table in C where each entry
 237 looked like this:
 238
 239     { \"foo\", foo_data, foo_function },
 240     { \"bar\", bar_data, bar_function },
 241     { \"baz\", baz_data, baz_function },
 242
 243 You could enter the names in this format:
 244
 245     foo
 246     bar
 247     baz
 248
 249 and write a macro to massage a word into a table entry:
 250
 251     \\C-x (
 252        \\M-d { \"\\C-y\", \\C-y_data, \\C-y_function },
 253     \\C-x )
 254
 255 and then select the region of un-tablified names and use
 256 `\\[apply-macro-to-region-lines]' to build the table from the names."
 257   (interactive "r")
 258   (or macro
 259       (progn
 260         (if (null last-kbd-macro)
 261             (error "No keyboard macro has been defined"))
 262         (setq macro last-kbd-macro)))
 263   (save-excursion
 264     (let ((end-marker (copy-marker bottom))
 265           next-line-marker)
 266       (goto-char top)
 267       (if (not (bolp))
 268           (forward-line 1))
 269       (setq next-line-marker (point-marker))
 270       (while (< next-line-marker end-marker)
 271         (goto-char next-line-marker)
 272         (save-excursion
 273           (forward-line 1)
 274           (set-marker next-line-marker (point)))
 275         (save-excursion
 276           (let ((mark-active nil))
 277             (execute-kbd-macro macro))))
 278       (set-marker end-marker nil)
 279       (set-marker next-line-marker nil))))
 280
 281 ;;;###autoload (define-key ctl-x-map "q" 'kbd-macro-query)
 282
 283 (provide 'macros)
 284
 285 ;; arch-tag: 346ed1a5-1220-4bc8-b533-961ee704361f
 286 ;;; macros.el ends here