lisp/find-file.el

   1 ;;; find-file.el --- find a file corresponding to this one given a pattern
   2
   3 ;; Author: Henry Guillaume <henri@tibco.com, henry@c032.aone.net.au>
   4 ;; Maintainer: FSF
   5 ;; Keywords: c, matching, tools
   6
   7 ;; Copyright (C) 1994, 1995, 2002, 2003 Free Software Foundation, Inc.
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; PURPOSE:
  29 ;; This package features a function called ff-find-other-file, which performs
  30 ;; the following function:
  31 ;;
  32 ;;     When in a .c file, find the first corresponding .h file in a set
  33 ;;     of directories and display it, and vice-versa from the .h file.
  34 ;;
  35 ;; Many people maintain their include file in a directory separate to their
  36 ;; src directory, and very often you may be editing a file and have a need to
  37 ;; visit the "other file". This package searches through a set of directories
  38 ;; to find that file.
  39 ;;
  40 ;; THE "OTHER FILE", or "corresponding file", generally has the same basename,
  41 ;; and just has a different extension as described by the ff-other-file-alist
  42 ;; variable:
  43 ;;
  44 ;;   '(("\\.cc$"  (".hh" ".h"))
  45 ;;     ("\\.hh$"  (".cc" ".C" ".CC" ".cxx" ".cpp")))
  46 ;;
  47 ;; If the current file has a .cc extension, ff-find-other-file will attempt
  48 ;; to look for a .hh file, and then a .h file in some directory as described
  49 ;; below. The mechanism here is to replace the matched part of the original
  50 ;; filename with each of the corresponding extensions in turn.
  51 ;;
  52 ;; Alternatively, there are situations where the filename of the other file
  53 ;; cannot be determined easily with regexps. For example, a .c file may
  54 ;; have two corresponding .h files, for its public and private parts, or
  55 ;; the filename for the .c file contains part of the pathname of the .h
  56 ;; file, as between src/fooZap.cc and include/FOO/zap.hh. In that case, the
  57 ;; format above can be changed to include a function to be called when the
  58 ;; current file matches the regexp:
  59 ;;
  60 ;;   '(("\\.cc$"  cc--function)
  61 ;;     ("\\.hh$"  hh-function))
  62 ;;
  63 ;; These functions must return a list consisting of the possible names of the
  64 ;; corresponding file, with or without path. There is no real need for more
  65 ;; than one function, and one could imagine the following value for cc-other-
  66 ;; file-alist:
  67 ;;
  68 ;;    (setq cc-other-file-alist
  69 ;;        '(("\\.cc$"  ff-cc-hh-converter)
  70 ;;          ("\\.hh$"  ff-cc-hh-converter)
  71 ;;          ("\\.c$"   (".h"))
  72 ;;          ("\\.h$"   (".c" ".cc" ".C" ".CC" ".cxx" ".cpp"))))
  73 ;;
  74 ;; ff-cc-hh-converter is included at the end of this file as a reference.
  75 ;;
  76 ;; SEARCHING is carried out in a set of directories specified by the
  77 ;; ff-search-directories variable:
  78 ;;
  79 ;;     ("." "../../src" "../include/*" "/usr/local/*/src/*" "$PROJECT/src")
  80 ;;
  81 ;; This means that the corresponding file will be searched for first in
  82 ;; the current directory, then in ../../src, then in one of the directories
  83 ;; under ../include, and so on. The star is _not_ a general wildcard
  84 ;; character: it just indicates that the subdirectories of this directory
  85 ;; must each be searched in turn. Environment variables will be expanded in
  86 ;; the ff-search-directories variable.
  87 ;;
  88 ;; If the point is on a #include line, the file to be #included is searched
  89 ;; for in the same manner. This can be disabled with the ff-ignore-include
  90 ;; variable, or by calling ff-get-other-file instead of ff-find-other-file.
  91 ;;
  92 ;; If the file was not found, ff-find-other-file will prompt you for where
  93 ;; to create the new "corresponding file" (defaults to the current directory),
  94 ;; unless the variable ff-always-try-to-create is set to nil.
  95 ;;
  96 ;; GIVEN AN ARGUMENT (with the ^U prefix), ff-find-other-file will get the
  97 ;; other file in another (the other?) window (see find-file-other-window and
  98 ;; switch-to-buffer-other-window). This can be set on a more permanent basis
  99 ;; by setting ff-always-in-other-window to t in which case the ^U prefix will
 100 ;; do the opposite of what was described above.
 101 ;;
 102 ;; THERE ARE FIVE AVAILABLE HOOKS, called in this order if non-nil:
 103 ;;
 104 ;; - ff-pre-find-hook     - called before the search for the other file starts
 105 ;; - ff-not-found-hook    - called when the other file could not be found
 106 ;; - ff-pre-load-hook     - called just before the other file is 'loaded'
 107 ;; - ff-file-created-hook - called when the other file is created
 108 ;; - ff-post-load-hook    - called just after the other file is 'loaded'
 109 ;;
 110 ;; The *load-hook allow you to place point where you want it in the other
 111 ;; file.
 112
 113 ;; CREDITS:
 114 ;; Many thanks go to TUSC Computer Systems Pty Ltd for providing an environ-
 115 ;; ment that made the development of this package possible.
 116 ;;
 117 ;; Many thanks also go to all those who provided valuable feedback throughout
 118 ;; the development of this package:
 119 ;;     Rolf Ebert in particular, Fritz Knabe, Heddy Boubaker, Sebastian Kremer,
 120 ;;     Vasco Lopes Paulo, Mark A. Plaksin, Robert Lang, Trevor West, Kevin
 121 ;;     Pereira, Benedict Lofstedt & Justin Vallon.
 122
 123 ;;; Code:
 124 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 125 ;; User definable variables:
 126
 127 (defgroup ff nil
 128   "Find a file corresponding to this one given a pattern."
 129   :prefix "ff-"
 130   :link '(emacs-commentary-link "find-file")
 131   :group 'find-file)
 132
 133 (defcustom ff-pre-find-hook nil
 134   "*List of functions to be called before the search for the file starts."
 135   :type 'hook
 136   :group 'ff)
 137
 138 (defcustom ff-pre-load-hook nil
 139   "*List of functions to be called before the other file is loaded."
 140   :type 'hook
 141   :group 'ff)
 142
 143 (defcustom ff-post-load-hook nil
 144   "*List of functions to be called after the other file is loaded."
 145   :type 'hook
 146   :group 'ff)
 147
 148 (defcustom ff-not-found-hook nil
 149   "*List of functions to be called if the other file could not be found."
 150   :type 'hook
 151   :group 'ff)
 152
 153 (defcustom ff-file-created-hook nil
 154   "*List of functions to be called if the other file needs to be created."
 155   :type 'hook
 156   :group 'ff)
 157
 158 (defcustom ff-case-fold-search nil
 159   "*Non-nil means ignore cases in matches (see `case-fold-search').
 160 If you have extensions in different cases, you will want this to be nil."
 161   :type 'boolean
 162   :group 'ff)
 163
 164 (defcustom ff-always-in-other-window nil
 165   "*If non-nil, find the corresponding file in another window by default.
 166 To override this, give an argument to `ff-find-other-file'."
 167   :type 'boolean
 168   :group 'ff)
 169
 170 (defcustom ff-ignore-include nil
 171   "*If non-nil, ignore `#include' lines."
 172   :type 'boolean
 173   :group 'ff)
 174
 175 (defcustom ff-always-try-to-create t
 176   "*If non-nil, always attempt to create the other file if it was not found."
 177   :type 'boolean
 178   :group 'ff)
 179
 180 (defcustom ff-quiet-mode nil
 181   "*If non-nil, trace which directories are being searched."
 182   :type 'boolean
 183   :group 'ff)
 184
 185 ;;;###autoload
 186 (defvar ff-special-constructs
 187   '(
 188     ;; C/C++ include, for NeXTSTEP too
 189     ("^\#\\s *\\(include\\|import\\)\\s +[<\"]\\(.*\\)[>\"]" .
 190      (lambda ()
 191        (setq fname (buffer-substring (match-beginning 2) (match-end 2)))))
 192     )
 193   "*A list of regular expressions for `ff-find-file'.
 194 Specifies how to recognise special constructs such as include files
 195 etc. and an associated method for extracting the filename from that
 196 construct.")
 197
 198 (defvaralias 'ff-related-file-alist 'ff-other-file-alist)
 199 (defcustom ff-other-file-alist 'cc-other-file-alist
 200   "*Alist of extensions to find given the current file's extension.
 201
 202 This list should contain the most used extensions before the others,
 203 since the search algorithm searches sequentially through each
 204 directory specified in `ff-search-directories'.  If a file is not found,
 205 a new one is created with the first matching extension (`.cc' yields `.hh').
 206 This alist should be set by the major mode."
 207   :type '(choice (repeat (list regexp (choice (repeat string) function)))
 208                  symbol)
 209   :group 'ff)
 210
 211 (defcustom ff-search-directories 'cc-search-directories
 212   "*List of directories to search for a specific file.
 213
 214 Set by default to `cc-search-directories', expanded at run-time.
 215
 216 This list is searched through with each extension specified in
 217 `ff-other-file-alist' that matches this file's extension.  So the
 218 longer the list, the longer it'll take to realise that a file
 219 may not exist.
 220
 221 A typical format is
 222
 223     '(\".\" \"/usr/include\" \"$PROJECT/*/include\")
 224
 225 Environment variables can be inserted between slashes (`/').
 226 They will be replaced by their definition. If a variable does
 227 not exist, it is replaced (silently) with an empty string.
 228
 229 The stars are *not* wildcards: they are searched for together with
 230 the preceding slash.  The star represents all the subdirectories except
 231 `..', and each of these subdirectories will be searched in turn."
 232   :type '(choice (repeat directory) symbol)
 233   :group 'ff)
 234
 235 (defcustom cc-search-directories
 236   '("." "/usr/include" "/usr/local/include/*")
 237   "*See the description of the `ff-search-directories' variable."
 238   :type '(repeat directory)
 239   :group 'ff)
 240
 241 (defcustom cc-other-file-alist
 242   '(("\\.cc\\'"  (".hh" ".h"))
 243     ("\\.hh\\'"  (".cc" ".C"))
 244
 245     ("\\.c\\'"   (".h"))
 246     ("\\.h\\'"   (".c" ".cc" ".C" ".CC" ".cxx" ".cpp"))
 247
 248     ("\\.C\\'"   (".H"  ".hh" ".h"))
 249     ("\\.H\\'"   (".C"  ".CC"))
 250
 251     ("\\.CC\\'"  (".HH" ".H"  ".hh" ".h"))
 252     ("\\.HH\\'"  (".CC"))
 253
 254     ("\\.c\\+\\+\\'" (".h++" ".hh" ".h"))
 255     ("\\.h\\+\\+\\'" (".c++"))
 256
 257     ("\\.cpp\\'" (".hpp" ".hh" ".h"))
 258     ("\\.hpp\\'" (".cpp"))
 259
 260     ("\\.cxx\\'" (".hxx" ".hh" ".h"))
 261     ("\\.hxx\\'" (".cxx")))
 262   "*Alist of extensions to find given the current file's extension.
 263
 264 This list should contain the most used extensions before the others,
 265 since the search algorithm searches sequentially through each directory
 266 specified in `ff-search-directories'.  If a file is not found, a new one
 267 is created with the first matching extension (`.cc' yields `.hh')."
 268   :type '(repeat (list regexp (choice (repeat string) function)))
 269   :group 'ff)
 270
 271 (defcustom modula2-other-file-alist
 272   '(
 273     ("\\.mi$" (".md")) ;; Modula-2 module definition
 274     ("\\.md$" (".mi")) ;; and implementation.
 275     )
 276   "*See the description for the `ff-search-directories' variable."
 277   :type '(repeat (list regexp (choice (repeat string) function)))
 278   :group 'ff)
 279
 280
 281 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 282 ;; No user definable variables beyond this point!
 283 ;; ==============================================
 284
 285 (make-variable-buffer-local 'ff-pre-find-hook)
 286 (make-variable-buffer-local 'ff-pre-load-hook)
 287 (make-variable-buffer-local 'ff-post-load-hook)
 288 (make-variable-buffer-local 'ff-not-found-hook)
 289 (make-variable-buffer-local 'ff-file-created-hook)
 290 (make-variable-buffer-local 'ff-case-fold-search)
 291 (make-variable-buffer-local 'ff-always-in-other-window)
 292 (make-variable-buffer-local 'ff-ignore-include)
 293 (make-variable-buffer-local 'ff-quiet-mode)
 294 (make-variable-buffer-local 'ff-other-file-alist)
 295 (make-variable-buffer-local 'ff-search-directories)
 296
 297 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 298 ;; User entry points
 299
 300 ;;;###autoload
 301 (defun ff-get-other-file (&optional in-other-window)
 302   "Find the header or source file corresponding to this file.
 303 See also the documentation for `ff-find-other-file'.
 304
 305 If optional IN-OTHER-WINDOW is non-nil, find the file in another window."
 306   (interactive "P")
 307   (let ((ignore ff-ignore-include))
 308     (setq ff-ignore-include t)
 309     (ff-find-the-other-file in-other-window)
 310     (setq ff-ignore-include ignore)))
 311
 312 ;;;###autoload
 313 (defalias 'ff-find-related-file 'ff-find-other-file)
 314
 315 ;;;###autoload
 316 (defun ff-find-other-file (&optional in-other-window ignore-include)
 317   "Find the header or source file corresponding to this file.
 318 Being on a `#include' line pulls in that file.
 319
 320 If optional IN-OTHER-WINDOW is non-nil, find the file in the other window.
 321 If optional IGNORE-INCLUDE is non-nil, ignore being on `#include' lines.
 322
 323 Variables of interest include:
 324
 325  - `ff-case-fold-search'
 326    Non-nil means ignore cases in matches (see `case-fold-search').
 327    If you have extensions in different cases, you will want this to be nil.
 328
 329  - `ff-always-in-other-window'
 330    If non-nil, always open the other file in another window, unless an
 331    argument is given to `ff-find-other-file'.
 332
 333  - `ff-ignore-include'
 334    If non-nil, ignores #include lines.
 335
 336  - `ff-always-try-to-create'
 337    If non-nil, always attempt to create the other file if it was not found.
 338
 339  - `ff-quiet-mode'
 340    If non-nil, traces which directories are being searched.
 341
 342  - `ff-special-constructs'
 343    A list of regular expressions specifying how to recognise special
 344    constructs such as include files etc, and an associated method for
 345    extracting the filename from that construct.
 346
 347  - `ff-other-file-alist'
 348    Alist of extensions to find given the current file's extension.
 349
 350  - `ff-search-directories'
 351    List of directories searched through with each extension specified in
 352    `ff-other-file-alist' that matches this file's extension.
 353
 354  - `ff-pre-find-hook'
 355    List of functions to be called before the search for the file starts.
 356
 357  - `ff-pre-load-hook'
 358    List of functions to be called before the other file is loaded.
 359
 360  - `ff-post-load-hook'
 361    List of functions to be called after the other file is loaded.
 362
 363  - `ff-not-found-hook'
 364    List of functions to be called if the other file could not be found.
 365
 366  - `ff-file-created-hook'
 367    List of functions to be called if the other file has been created."
 368   (interactive "P")
 369   (let ((ignore ff-ignore-include))
 370     (setq ff-ignore-include ignore-include)
 371     (ff-find-the-other-file in-other-window)
 372     (setq ff-ignore-include ignore)))
 373
 374 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 375 ;; Support functions
 376
 377 (defun ff-find-the-other-file (&optional in-other-window)
 378   "Find the header or source file corresponding to the current file.
 379 Being on a `#include' line pulls in that file, but see the help on
 380 the `ff-ignore-include' variable.
 381
 382 If optional IN-OTHER-WINDOW is non-nil, find the file in another window."
 383
 384   (let (match           ;; matching regexp for this file
 385         suffixes        ;; set of replacing regexps for the matching regexp
 386         action          ;; function to generate the names of the other files
 387         fname           ;; basename of this file
 388         pos             ;; where we start matching filenames
 389         stub            ;; name of the file without extension
 390         alist           ;; working copy of the list of file extensions
 391         pathname        ;; the pathname of the file or the #include line
 392         default-name    ;; file we should create if none found
 393         format          ;; what we have to match
 394         found           ;; name of the file or buffer found - nil if none
 395         dirs            ;; local value of ff-search-directories
 396         no-match)       ;; whether we know about this kind of file
 397
 398     (run-hooks 'ff-pre-find-hook 'ff-pre-find-hooks)
 399
 400     (message "Working...")
 401
 402     (setq dirs
 403           (if (symbolp ff-search-directories)
 404               (ff-list-replace-env-vars (symbol-value ff-search-directories))
 405             (ff-list-replace-env-vars ff-search-directories)))
 406
 407     (save-excursion
 408       (beginning-of-line 1)
 409       (setq fname (ff-treat-as-special)))
 410
 411     (cond
 412      ((and (not ff-ignore-include) fname)
 413       (setq default-name fname)
 414       (setq found (ff-get-file dirs fname nil in-other-window)))
 415
 416      ;; let's just get the corresponding file
 417      (t
 418       (setq alist (if (symbolp ff-other-file-alist)
 419                       (symbol-value ff-other-file-alist)
 420                     ff-other-file-alist)
 421             pathname (if (buffer-file-name)
 422                          (buffer-file-name)
 423                        "/none.none"))
 424
 425       (setq fname (file-name-nondirectory pathname)
 426             no-match nil
 427             match (car alist))
 428
 429       ;; find the table entry corresponding to this file
 430       (setq pos (ff-string-match (car match) fname))
 431       (while (and match (if (and pos (>= pos 0)) nil (not pos)))
 432         (setq alist (cdr alist))
 433         (setq match (car alist))
 434         (setq pos (ff-string-match (car match) fname)))
 435
 436       ;; no point going on if we haven't found anything
 437       (if (not match)
 438           (setq no-match t)
 439
 440         ;; otherwise, suffixes contains what we need
 441         (setq suffixes (car (cdr match))
 442               action (car (cdr match))
 443               found nil)
 444
 445         ;; if we have a function to generate new names,
 446         ;; invoke it with the name of the current file
 447         (if (and (atom action) (fboundp action))
 448             (progn
 449               (setq suffixes (funcall action (buffer-file-name))
 450                     match (cons (car match) (list suffixes))
 451                     stub nil
 452                     default-name (car suffixes)))
 453
 454           ;; otherwise build our filename stub
 455           (cond
 456
 457            ;; get around the problem that 0 and nil both mean false!
 458            ((= pos 0)
 459             (setq format "")
 460             (setq stub "")
 461             )
 462
 463            (t
 464             (setq format (concat "\\(.+\\)" (car match)))
 465             (string-match format fname)
 466             (setq stub (substring fname (match-beginning 1) (match-end 1)))
 467             ))
 468
 469           ;; if we find nothing, we should try to get a file like this one
 470           (setq default-name
 471                 (concat stub (car (car (cdr match))))))
 472
 473         ;; do the real work - find the file
 474         (setq found
 475               (ff-get-file dirs
 476                            stub
 477                            suffixes
 478                            in-other-window)))))
 479
 480     (cond
 481      (no-match                     ;; could not even determine the other file
 482       (message ""))
 483
 484      (t
 485       (cond
 486
 487        ((not found)                ;; could not find the other file
 488
 489         (run-hooks 'ff-not-found-hook 'ff-not-found-hooks)
 490
 491         (cond
 492          (ff-always-try-to-create  ;; try to create the file
 493           (let (name pathname)
 494
 495             (setq name
 496                   (expand-file-name
 497                    (read-file-name
 498                     (format "Find or create %s in: " default-name)
 499                     default-directory default-name nil)))
 500
 501             (setq pathname
 502                   (if (file-directory-p name)
 503                       (concat (file-name-as-directory name) default-name)
 504                     (setq found name)))
 505
 506             (ff-find-file pathname in-other-window t)))
 507
 508          (t                        ;; don't create the file, just whinge
 509           (message "No file found for %s" fname))))
 510
 511        (t                          ;; matching file found
 512         nil))))
 513
 514     found))                        ;; return buffer-name or filename
 515
 516 (defun ff-other-file-name ()
 517   "Return name of the header or source file corresponding to the current file.
 518 Being on a `#include' line pulls in that file, but see the help on
 519 the `ff-ignore-include' variable."
 520
 521   (let (match           ;; matching regexp for this file
 522         suffixes        ;; set of replacing regexps for the matching regexp
 523         action          ;; function to generate the names of the other files
 524         fname           ;; basename of this file
 525         pos             ;; where we start matching filenames
 526         stub            ;; name of the file without extension
 527         alist           ;; working copy of the list of file extensions
 528         pathname        ;; the pathname of the file or the #include line
 529         default-name    ;; file we should create if none found
 530         format          ;; what we have to match
 531         found           ;; name of the file or buffer found - nil if none
 532         dirs            ;; local value of ff-search-directories
 533         no-match)       ;; whether we know about this kind of file
 534
 535     (message "Working...")
 536
 537     (setq dirs
 538           (if (symbolp ff-search-directories)
 539               (ff-list-replace-env-vars (symbol-value ff-search-directories))
 540             (ff-list-replace-env-vars ff-search-directories)))
 541
 542     (save-excursion
 543       (beginning-of-line 1)
 544       (setq fname (ff-treat-as-special)))
 545
 546     (cond
 547      ((and (not ff-ignore-include) fname)
 548       (setq default-name fname)
 549       (setq found (ff-get-file-name dirs fname nil)))
 550
 551      ;; let's just get the corresponding file
 552      (t
 553       (setq alist (if (symbolp ff-other-file-alist)
 554                       (symbol-value ff-other-file-alist)
 555                     ff-other-file-alist)
 556             pathname (if (buffer-file-name)
 557                          (buffer-file-name)
 558                        "/none.none"))
 559
 560       (setq fname (file-name-nondirectory pathname)
 561             no-match nil
 562             match (car alist))
 563
 564       ;; find the table entry corresponding to this file
 565       (setq pos (ff-string-match (car match) fname))
 566       (while (and match (if (and pos (>= pos 0)) nil (not pos)))
 567         (setq alist (cdr alist))
 568         (setq match (car alist))
 569         (setq pos (ff-string-match (car match) fname)))
 570
 571       ;; no point going on if we haven't found anything
 572       (if (not match)
 573           (setq no-match t)
 574
 575         ;; otherwise, suffixes contains what we need
 576         (setq suffixes (car (cdr match))
 577               action (car (cdr match))
 578               found nil)
 579
 580         ;; if we have a function to generate new names,
 581         ;; invoke it with the name of the current file
 582         (if (and (atom action) (fboundp action))
 583             (progn
 584               (setq suffixes (funcall action (buffer-file-name))
 585                     match (cons (car match) (list suffixes))
 586                     stub nil
 587                     default-name (car suffixes)))
 588
 589           ;; otherwise build our filename stub
 590           (cond
 591
 592            ;; get around the problem that 0 and nil both mean false!
 593            ((= pos 0)
 594             (setq format "")
 595             (setq stub "")
 596             )
 597
 598            (t
 599             (setq format (concat "\\(.+\\)" (car match)))
 600             (string-match format fname)
 601             (setq stub (substring fname (match-beginning 1) (match-end 1)))
 602             ))
 603
 604           ;; if we find nothing, we should try to get a file like this one
 605           (setq default-name
 606                 (concat stub (car (car (cdr match))))))
 607
 608         ;; do the real work - find the file
 609         (setq found
 610               (ff-get-file-name dirs stub suffixes)))))
 611     found))                        ;; return buffer-name or filename
 612
 613 (defun ff-get-file (search-dirs filename &optional suffix-list other-window)
 614   "Find a file in the SEARCH-DIRS with the given FILENAME (or filename stub).
 615 If (optional) SUFFIX-LIST is nil, search for fname, otherwise search
 616 for fname with each of the given suffixes.  Get the file or the buffer
 617 corresponding to the name of the first file found, or nil."
 618   (let ((filename (ff-get-file-name search-dirs filename suffix-list)))
 619
 620     (cond
 621      ((not filename)
 622       nil)
 623
 624      ((bufferp (get-file-buffer filename))
 625       (ff-switch-to-buffer (get-file-buffer filename) other-window)
 626       filename)
 627
 628      ((file-exists-p filename)
 629       (ff-find-file filename other-window nil)
 630       filename)
 631
 632      (t
 633       nil))))
 634
 635 (defun ff-get-file-name (search-dirs fname-stub &optional suffix-list)
 636   "Find a file in SEARCH-DIRS with the given name (or stub) FNAME-STUB.
 637 If (optional) SUFFIX-LIST is nil, search for FNAME-STUB, otherwise
 638 search for FNAME-STUB with each of the given suffixes.  Return the
 639 name of the first file found."
 640   (let* (dirs         ;; working copy of dirs to search
 641          dir          ;; the current dir considered
 642          file         ;; filename being looked for
 643          rest         ;; pathname after first /*
 644          this-suffix  ;; the suffix we are currently considering
 645          suffixes     ;; working copy of suffix-list
 646          filename     ;; built filename
 647          blist        ;; list of live buffers
 648          buf          ;; current buffer in blist
 649          found)       ;; whether we have found anything
 650
 651     (setq suffixes suffix-list)
 652
 653     ;; suffixes is nil => fname-stub is the file we are looking for
 654     ;; otherwise fname-stub is a stub, and we append a suffix
 655     (if suffixes
 656         (setq this-suffix (car suffixes))
 657       (setq this-suffix "")
 658       (setq suffixes (list "")))
 659
 660     ;; find whether the file is in a buffer first
 661     (while (and suffixes (not found))
 662       (setq filename (concat fname-stub this-suffix))
 663
 664       (if (not ff-quiet-mode)
 665           (message "Finding buffer %s..." filename))
 666
 667       (if (bufferp (get-file-buffer filename))
 668           (setq found (buffer-file-name (get-file-buffer filename))))
 669
 670       (setq blist (buffer-list))
 671       (setq buf (buffer-name (car blist)))
 672       (while (and blist (not found))
 673
 674         (if (string-match (concat filename "<[0-9]+>") buf)
 675             (setq found (buffer-file-name (car blist))))
 676
 677         (setq blist (cdr blist))
 678         (setq buf (buffer-name (car blist))))
 679
 680       (setq suffixes (cdr suffixes))
 681       (setq this-suffix (car suffixes)))
 682
 683     ;; now look for the real file
 684     (setq dirs search-dirs)
 685     (setq dir  (car dirs))
 686     (while (and (not found) dirs)
 687
 688       (setq suffixes suffix-list)
 689
 690       ;; if dir does not contain '/*', look for the file
 691       (if (and dir (not (string-match "\\([^*]*\\)/\\\*\\(/.*\\)*" dir)))
 692           (progn
 693
 694             ;; suffixes is nil => fname-stub is the file we are looking for
 695             ;; otherwise fname-stub is a stub, and we append a suffix
 696             (if suffixes
 697                 (setq this-suffix (car suffixes))
 698               (setq this-suffix "")
 699               (setq suffixes (list "")))
 700
 701             (while (and suffixes (not found))
 702
 703               (setq filename (concat fname-stub this-suffix))
 704               (setq file (concat dir "/" filename))
 705
 706               (if (not ff-quiet-mode)
 707                   (message "Finding %s..." file))
 708
 709               (if (file-exists-p file)
 710                   (setq found file))
 711
 712               (setq suffixes (cdr suffixes))
 713               (setq this-suffix (car suffixes))))
 714
 715         ;; otherwise dir matches the '/*', so search each dir separately
 716         (progn
 717           (if (match-beginning 2)
 718               (setq rest (substring dir (match-beginning 2) (match-end 2)))
 719             (setq rest "")
 720             )
 721           (setq dir  (substring dir (match-beginning 1) (match-end 1)))
 722
 723           (let ((dirlist (ff-all-dirs-under dir '("..")))
 724                 this-dir compl-dirs)
 725
 726             (setq this-dir (car dirlist))
 727             (while dirlist
 728               (setq compl-dirs
 729                     (append
 730                      compl-dirs
 731                      (list (concat this-dir rest))
 732                      ))
 733               (setq dirlist  (cdr dirlist))
 734               (setq this-dir (car dirlist)))
 735
 736             (if compl-dirs
 737                 (setq found (ff-get-file-name compl-dirs
 738                                               fname-stub
 739                                               suffix-list))))))
 740       (setq dirs (cdr dirs))
 741       (setq dir (car dirs)))
 742
 743     (if found
 744         (message "%s found" found))
 745
 746     found))
 747
 748 (defun ff-string-match (regexp string &optional start)
 749   "Like `string-match', but set `case-fold-search' temporarily.
 750 The value used comes from `ff-case-fold-search'."
 751   (let ((case-fold-search ff-case-fold-search))
 752     (if regexp
 753         (string-match regexp string start))))
 754
 755 (defun ff-list-replace-env-vars (search-list)
 756   "Replace environment variables (of the form $VARIABLE) in SEARCH-LIST."
 757   (let (list
 758         (var (car search-list)))
 759     (while search-list
 760       (if (string-match "\\(.*\\)\\$[({]*\\([a-zA-Z0-9_]+\\)[)}]*\\(.*\\)" var)
 761           (setq var
 762                 (concat
 763                  (substring var (match-beginning 1) (match-end 1))
 764                  (getenv (substring var (match-beginning 2) (match-end 2)))
 765                  (substring var (match-beginning 3) (match-end 3)))))
 766       (setq search-list (cdr search-list))
 767       (setq list (cons var list))
 768       (setq var (car search-list)))
 769     (setq search-list (reverse list))))
 770
 771 (defun ff-treat-as-special ()
 772   "Return the file to look for if the construct was special, else nil.
 773 The construct is defined in the variable `ff-special-constructs'."
 774   (let* (fname
 775          (list ff-special-constructs)
 776          (elem (car list))
 777          (regexp (car elem))
 778          (match (cdr elem)))
 779     (while (and list (not fname))
 780       (if (and (looking-at regexp) match)
 781           (setq fname (funcall match)))
 782       (setq list (cdr list))
 783       (setq elem (car list))
 784       (setq regexp (car elem))
 785       (setq match (cdr elem)))
 786     fname))
 787
 788 (defun ff-basename (string)
 789   "Return the basename of pathname STRING."
 790   (setq string (concat "/" string))
 791   (string-match ".*/\\([^/]+\\)$" string)
 792   (setq string (substring string (match-beginning 1) (match-end 1))))
 793
 794 (defun ff-all-dirs-under (here &optional exclude)
 795   "Get all the directory files under directory HERE.
 796 Exclude all files in the optional EXCLUDE list."
 797   (if (file-directory-p here)
 798       (condition-case nil
 799           (progn
 800             (let ((files (directory-files here t))
 801                   (dirlist (list))
 802                   file)
 803               (while files
 804                 (setq file (car files))
 805                 (if (and
 806                      (file-directory-p file)
 807                      (not (member (ff-basename file) exclude)))
 808                     (setq dirlist (cons file dirlist)))
 809                 (setq files (cdr files)))
 810               (setq dirlist (reverse dirlist))))
 811         (error nil))
 812     nil))
 813
 814 (defun ff-switch-file (f1 f2 file &optional in-other-window new-file)
 815   "Call F1 or F2 on FILE, according to IN-OTHER-WINDOW.
 816 In addition, this runs various hooks.
 817
 818 Either F1 or F2 receives FILE as the sole argument.
 819 The decision of which one to call is based on IN-OTHER-WINDOW
 820 and on the global variable `ff-always-in-other-window'.
 821
 822 F1 and F2 are typically `find-file' / `find-file-other-window'
 823 or `switch-to-buffer' / `switch-to-buffer-other-window' function pairs.
 824
 825 If optional NEW-FILE is t, then a special hook (`ff-file-created-hook') is
 826 called before `ff-post-load-hook'."
 827   (run-hooks 'ff-pre-load-hook 'ff-pre-load-hooks)
 828   (if (or
 829        (and in-other-window (not ff-always-in-other-window))
 830        (and (not in-other-window) ff-always-in-other-window))
 831       (funcall f2 file)
 832     (funcall f1 file))
 833   (if new-file
 834       (run-hooks 'ff-file-created-hook 'ff-file-created-hooks))
 835   (run-hooks 'ff-post-load-hook 'ff-post-load-hooks))
 836
 837 (defun ff-find-file (file &optional in-other-window new-file)
 838   "Like `find-file', but may show the file in another window."
 839   (ff-switch-file 'find-file
 840                   'find-file-other-window
 841                   file in-other-window new-file))
 842
 843 (defun ff-switch-to-buffer (buffer-or-name &optional in-other-window)
 844   "Like `switch-to-buffer', but may show the buffer in another window."
 845
 846   (ff-switch-file 'switch-to-buffer
 847                   'switch-to-buffer-other-window
 848                   buffer-or-name in-other-window nil))
 849
 850 ;;;###autoload
 851 (defun ff-mouse-find-other-file (event)
 852   "Visit the file you click on."
 853   (interactive "e")
 854   (save-excursion
 855     (mouse-set-point event)
 856     (ff-find-other-file nil)))
 857
 858 ;;;###autoload
 859 (defun ff-mouse-find-other-file-other-window (event)
 860   "Visit the file you click on in another window."
 861   (interactive "e")
 862   (save-excursion
 863     (mouse-set-point event)
 864     (ff-find-other-file t)))
 865
 866 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 867 ;; This section offers an example of user defined function to select files
 868
 869 (defun ff-upcase-p (string &optional start end)
 870   "Return t if STRING is all uppercase.
 871 Given START and/or END, checks between these characters."
 872   (let (match str)
 873     (if (not start)
 874         (setq start 0))
 875     (if (not end)
 876         (setq end (length string)))
 877     (if (= start end)
 878         (setq end (1+ end)))
 879     (setq str (substring string start end))
 880     (if (and
 881          (ff-string-match "[A-Z]+" str)
 882          (setq match (match-data))
 883          (= (car match) 0)
 884          (= (car (cdr match)) (length str)))
 885         t
 886       nil)))
 887
 888 (defun ff-cc-hh-converter (arg)
 889   "Discriminate file extensions.
 890 Build up a new file list based possibly on part of the directory name
 891 and the name of the file passed in."
 892   (ff-string-match "\\(.*\\)/\\([^/]+\\)/\\([^.]+\\).\\([^/]+\\)$" arg)
 893   (let ((path (if (match-beginning 1)
 894                   (substring arg (match-beginning 1) (match-end 1)) nil))
 895         (dire (if (match-beginning 2)
 896                   (substring arg (match-beginning 2) (match-end 2)) nil))
 897         (file (if (match-beginning 3)
 898                   (substring arg (match-beginning 3) (match-end 3)) nil))
 899         (extn (if (match-beginning 4)
 900                   (substring arg (match-beginning 4) (match-end 4)) nil))
 901         return-list)
 902     (cond
 903      ;; fooZapJunk.cc => ZapJunk.{hh,h} or fooZapJunk.{hh,h}
 904      ((and (string= extn "cc")
 905            (ff-string-match "^\\([a-z]+\\)\\([A-Z].+\\)$" file))
 906       (let ((stub  (substring file (match-beginning 2) (match-end 2))))
 907         (setq dire (upcase (substring file (match-beginning 1) (match-end 1))))
 908         (setq return-list (list (concat stub ".hh")
 909                                 (concat stub ".h")
 910                                 (concat file ".hh")
 911                                 (concat file ".h")))
 912         ))
 913      ;; FOO/ZapJunk.hh => fooZapJunk.{cc,C} or ZapJunk.{cc,C}
 914      ((and (string= extn "hh") (ff-upcase-p dire) file)
 915       (let ((stub (concat (downcase dire) file)))
 916         (setq return-list (list (concat stub ".cc")
 917                                 (concat stub ".C")
 918                                 (concat file ".cc")
 919                                 (concat file ".C")))
 920         ))
 921      ;; zap.cc => zap.hh or zap.h
 922      ((string= extn "cc")
 923       (let ((stub file))
 924         (setq return-list (list (concat stub ".hh")
 925                                 (concat stub ".h")))
 926         ))
 927      ;; zap.hh => zap.cc or zap.C
 928      ((string= extn "hh")
 929       (let ((stub file))
 930         (setq return-list (list (concat stub ".cc")
 931                                 (concat stub ".C")))
 932         ))
 933      (t
 934       nil))
 935
 936     return-list))
 937
 938 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 939 ;; This section offers an example of user defined function to place point.
 940 ;; The regexps are Ada specific.
 941
 942 (defvar ff-function-name nil "Name of the function we are in.")
 943
 944 ;; bind with (setq ff-pre-load-hook 'ff-which-function-are-we-in)
 945 ;;
 946 (defun ff-which-function-are-we-in ()
 947   "Return the name of the function whose definition/declaration point is in.
 948 Also remember that name in `ff-function-name'."
 949
 950   (setq ff-function-name nil)
 951
 952   (save-excursion
 953     (if (re-search-backward ada-procedure-start-regexp nil t)
 954         (setq ff-function-name (buffer-substring (match-beginning 0)
 955                                                  (match-end 0)))
 956       ; we didn't find a procedure start, perhaps there is a package
 957       (if (re-search-backward ada-package-start-regexp nil t)
 958           (setq ff-function-name (buffer-substring (match-beginning 0)
 959                                                    (match-end 0)))
 960         ))))
 961
 962 ;; bind with (setq ff-post-load-hook 'ff-set-point-accordingly)
 963 ;;
 964 (defun ff-set-point-accordingly ()
 965   "Find the function specified in `ff-function-name'.
 966 That name was previously determined by `ff-which-function-are-we-in'."
 967   (if ff-function-name
 968       (progn
 969         (goto-char (point-min))
 970         (search-forward ff-function-name nil t))))
 971
 972 (provide 'find-file)
 973
 974 ;;; arch-tag: 5a2fc49e-3b0a-4708-9acf-fb14e471a97a
 975 ;;; find-file.el ends here