m4/putenv.m4

   1 # putenv.m4 serial 21
   2 dnl Copyright (C) 2002-2017 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Jim Meyering.
   8 dnl
   9 dnl Check whether putenv ("FOO") removes FOO from the environment.
  10 dnl The putenv in libc on at least SunOS 4.1.4 does *not* do that.
  11
  12 AC_DEFUN([gl_FUNC_PUTENV],
  13 [
  14   AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
  15   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  16   AC_CACHE_CHECK([for putenv compatible with GNU and SVID],
  17    [gl_cv_func_svid_putenv],
  18    [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],[[
  19     /* Put it in env.  */
  20     if (putenv ("CONFTEST_putenv=val"))
  21       return 1;
  22
  23     /* Try to remove it.  */
  24     if (putenv ("CONFTEST_putenv"))
  25       return 2;
  26
  27     /* Make sure it was deleted.  */
  28     if (getenv ("CONFTEST_putenv") != 0)
  29       return 3;
  30
  31     return 0;
  32               ]])],
  33              gl_cv_func_svid_putenv=yes,
  34              gl_cv_func_svid_putenv=no,
  35              dnl When crosscompiling, assume putenv is broken.
  36              [case "$host_os" in
  37                         # Guess yes on glibc systems.
  38                 *-gnu*) gl_cv_func_svid_putenv="guessing yes" ;;
  39                         # Guess no on native Windows.
  40                 mingw*) gl_cv_func_svid_putenv="guessing no" ;;
  41                         # If we don't know, assume the worst.
  42                 *)      gl_cv_func_svid_putenv="guessing no" ;;
  43               esac
  44              ])
  45    ])
  46   case "$gl_cv_func_svid_putenv" in
  47     *yes) ;;
  48     *)
  49       REPLACE_PUTENV=1
  50       ;;
  51   esac
  52 ])
  53
  54 # Prerequisites of lib/putenv.c.
  55 AC_DEFUN([gl_PREREQ_PUTENV],
  56 [
  57   AC_CHECK_DECLS([_putenv])
  58 ])