lisp/view.el

   1 ;;; view.el --- peruse file or buffer without editing
   2
   3 ;; Copyright (C) 1985, 1989, 1994-1995, 1997, 2000-2011
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: K. Shane Hartman
   7 ;; Maintainer: Inge Frick <inge@nada.kth.se>
   8 ;; Keywords: files
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This package provides the `view' minor mode documented in the Emacs
  28 ;; user's manual.
  29 ;; View mode entry and exit is done through the functions view-mode-enter
  30 ;; and view-mode-exit.  Use these functions to enter or exit view-mode from
  31 ;; emacs lisp programs.
  32 ;; We use both view- and View- as prefix for symbols.  View- is used as
  33 ;; prefix for commands that have a key binding.  view- is used for commands
  34 ;; without key binding.  The purpose of this is to make it easier for a
  35 ;; user to use command name completion.
  36
  37 ;;; Suggested key bindings:
  38 ;;
  39 ;; (define-key ctl-x-4-map "v" 'view-file-other-window)  ; ^x4v
  40 ;; (define-key ctl-x-5-map "v" 'view-file-other-frame)  ; ^x5v
  41 ;;
  42 ;; You could also bind view-file, view-buffer, view-buffer-other-window and
  43 ;; view-buffer-other-frame to keys.
  44 \f
  45 ;;; Code:
  46
  47 (defgroup view nil
  48   "Peruse file or buffer without editing."
  49   :link '(function-link view-mode)
  50   :link '(custom-manual "(emacs)Misc File Ops")
  51   :group 'wp)
  52
  53 (defcustom view-highlight-face 'highlight
  54    "The face used for highlighting the match found by View mode search."
  55    :type 'face
  56    :group 'view)
  57
  58 (defcustom view-scroll-auto-exit nil
  59   "Non-nil means scrolling past the end of buffer exits View mode.
  60 A value of nil means attempting to scroll past the end of the buffer,
  61 only rings the bell and gives a message on how to leave."
  62   :type 'boolean
  63   :group 'view)
  64
  65 (defcustom view-try-extend-at-buffer-end nil
  66  "Non-nil means try to load more of file when reaching end of buffer.
  67 This variable is mainly intended to be temporarily set to non-nil by
  68 the F command in view-mode, but you can set it to t if you want the action
  69 for all scroll commands in view mode."
  70   :type 'boolean
  71   :group 'view)
  72
  73 ;;;###autoload
  74 (defcustom view-remove-frame-by-deleting t
  75   "Determine how View mode removes a frame no longer needed.
  76 If nil, make an icon of the frame.  If non-nil, delete the frame."
  77   :type 'boolean
  78   :group 'view
  79   :version "23.1")
  80
  81 (defcustom view-exits-all-viewing-windows nil
  82   "Non-nil means restore all windows used to view buffer.
  83 Commands that restore windows when finished viewing a buffer,
  84 apply to all windows that display the buffer and have restore
  85 information.  If `view-exits-all-viewing-windows' is nil, only
  86 the selected window is considered for restoring."
  87   :type 'boolean
  88   :group 'view)
  89
  90 (defcustom view-inhibit-help-message nil
  91   "Non-nil inhibits the help message shown upon entering View mode."
  92   :type 'boolean
  93   :group 'view
  94   :version "22.1")
  95
  96 ;;;###autoload
  97 (defvar view-mode nil
  98   "Non-nil if View mode is enabled.
  99 Don't change this variable directly, you must change it by one of the
 100 functions that enable or disable view mode.")
 101 ;;;###autoload
 102 (make-variable-buffer-local 'view-mode)
 103
 104 (defcustom view-mode-hook nil
 105   "Normal hook run when starting to view a buffer or file."
 106   :type 'hook
 107   :group 'view)
 108 \f
 109 (defvar view-old-buffer-read-only nil)
 110 (make-variable-buffer-local 'view-old-buffer-read-only)
 111
 112 (defvar view-old-Helper-return-blurb)
 113 (make-variable-buffer-local 'view-old-Helper-return-blurb)
 114
 115 (defvar view-page-size nil
 116   "Default number of lines to scroll by View page commands.
 117 If nil that means use the window size.")
 118 (make-variable-buffer-local 'view-page-size)
 119
 120 (defvar view-half-page-size nil
 121   "Default number of lines to scroll by View half page commands.
 122 If nil that means use half the window size.")
 123 (make-variable-buffer-local 'view-half-page-size)
 124
 125 (defvar view-last-regexp nil)
 126 (make-variable-buffer-local 'view-last-regexp) ; Global is better???
 127
 128 (defvar view-return-to-alist nil
 129   "What to do with used windows and where to go when finished viewing buffer.
 130 This is local in each buffer being viewed.
 131 It is added to by `view-mode-enter' when starting to view a buffer and
 132 subtracted from by `view-mode-exit' when finished viewing the buffer.
 133
 134 See RETURN-TO-ALIST argument of function `view-mode-exit' for the format of
 135 `view-return-to-alist'.")
 136 (make-obsolete-variable
 137  'view-return-to-alist "this variable is no more used." "24.1")
 138 (make-variable-buffer-local 'view-return-to-alist)
 139 (put 'view-return-to-alist 'permanent-local t)
 140
 141 (defvar view-exit-action nil
 142   "If non-nil, a function with one argument (a buffer) called when finished viewing.
 143 Commands like \\[view-file] and \\[view-file-other-window] may
 144 set this to bury or kill the viewed buffer.
 145 Observe that the buffer viewed might not appear in any window at
 146 the time this function is called.")
 147 (make-variable-buffer-local 'view-exit-action)
 148
 149 (defvar view-no-disable-on-exit nil
 150   "If non-nil, View mode \"exit\" commands don't actually disable View mode.
 151 Instead, these commands just switch buffers or windows.
 152 This is set in certain buffers by specialized features such as help commands
 153 that use View mode automatically.")
 154
 155 (defvar view-overlay nil
 156   "Overlay used to display where a search operation found its match.
 157 This is local in each buffer, once it is used.")
 158 (make-variable-buffer-local 'view-overlay)
 159 \f
 160 ;; Define keymap inside defvar to make it easier to load changes.
 161 ;; Some redundant "less"-like key bindings below have been commented out.
 162 (defvar view-mode-map
 163   (let ((map (make-sparse-keymap)))
 164     (define-key map "C" 'View-kill-and-leave)
 165     (define-key map "c" 'View-leave)
 166     (define-key map "Q" 'View-quit-all)
 167     (define-key map "E" 'View-exit-and-edit)
 168     ;; (define-key map "v" 'View-exit)
 169     (define-key map "e" 'View-exit)
 170     (define-key map "q" 'View-quit)
 171     ;; (define-key map "N" 'View-search-last-regexp-backward)
 172     (define-key map "p" 'View-search-last-regexp-backward)
 173     (define-key map "n" 'View-search-last-regexp-forward)
 174     ;; (define-key map "?" 'View-search-regexp-backward) ; Less does this.
 175     (define-key map "\\" 'View-search-regexp-backward)
 176     (define-key map "/" 'View-search-regexp-forward)
 177     (define-key map "r" 'isearch-backward)
 178     (define-key map "s" 'isearch-forward)
 179     (define-key map "m" 'point-to-register)
 180     (define-key map "'" 'register-to-point)
 181     (define-key map "x" 'exchange-point-and-mark)
 182     (define-key map "@" 'View-back-to-mark)
 183     (define-key map "." 'set-mark-command)
 184     (define-key map "%" 'View-goto-percent)
 185     ;; (define-key map "G" 'View-goto-line-last)
 186     (define-key map "g" 'View-goto-line)
 187     (define-key map "=" 'what-line)
 188     (define-key map "F" 'View-revert-buffer-scroll-page-forward)
 189     ;; (define-key map "k" 'View-scroll-line-backward)
 190     (define-key map "y" 'View-scroll-line-backward)
 191     ;; (define-key map "j" 'View-scroll-line-forward)
 192     (define-key map "\n" 'View-scroll-line-forward)
 193     (define-key map "\r" 'View-scroll-line-forward)
 194     (define-key map "u" 'View-scroll-half-page-backward)
 195     (define-key map "d" 'View-scroll-half-page-forward)
 196     (define-key map "z" 'View-scroll-page-forward-set-page-size)
 197     (define-key map "w" 'View-scroll-page-backward-set-page-size)
 198     ;; (define-key map "b" 'View-scroll-page-backward)
 199     (define-key map "\C-?" 'View-scroll-page-backward)
 200     ;; (define-key map "f" 'View-scroll-page-forward)
 201     (define-key map " " 'View-scroll-page-forward)
 202     (define-key map "o" 'View-scroll-to-buffer-end)
 203     (define-key map ">" 'end-of-buffer)
 204     (define-key map "<" 'beginning-of-buffer)
 205     (define-key map "-" 'negative-argument)
 206     (define-key map "9" 'digit-argument)
 207     (define-key map "8" 'digit-argument)
 208     (define-key map "7" 'digit-argument)
 209     (define-key map "6" 'digit-argument)
 210     (define-key map "5" 'digit-argument)
 211     (define-key map "4" 'digit-argument)
 212     (define-key map "3" 'digit-argument)
 213     (define-key map "2" 'digit-argument)
 214     (define-key map "1" 'digit-argument)
 215     (define-key map "0" 'digit-argument)
 216     (define-key map "H" 'describe-mode)
 217     (define-key map "?" 'describe-mode) ; Maybe do as less instead? See above.
 218     (define-key map "h" 'describe-mode)
 219     map))
 220 \f
 221 ;;; Commands that enter or exit view mode.
 222
 223 ;; This is used when view mode is exited, to make sure we don't try to
 224 ;; kill a buffer modified by the user.  A buffer in view mode can
 225 ;; become modified if the user types C-x C-q, edits the buffer, then
 226 ;; types C-x C-q again to return to view mode.
 227 ;;;###autoload
 228 (defun kill-buffer-if-not-modified (buf)
 229   "Like `kill-buffer', but does nothing if the buffer is modified."
 230   (let ((buf (get-buffer buf)))
 231     (and buf (not (buffer-modified-p buf))
 232          (kill-buffer buf))))
 233
 234 ;;;###autoload
 235 (defun view-file (file)
 236   "View FILE in View mode, returning to previous buffer when done.
 237 Emacs commands editing the buffer contents are not available; instead, a
 238 special set of commands (mostly letters and punctuation) are defined for
 239 moving around in the buffer.
 240 Space scrolls forward, Delete scrolls backward.
 241 For a list of all View commands, type H or h while viewing.
 242
 243 This command runs the normal hook `view-mode-hook'."
 244   (interactive "fView file: ")
 245   (unless (file-exists-p file) (error "%s does not exist" file))
 246   (let ((had-a-buf (get-file-buffer file))
 247         (buffer (find-file-noselect file)))
 248     (view-buffer buffer (and (not had-a-buf) 'kill-buffer-if-not-modified))))
 249
 250 ;;;###autoload
 251 (defun view-file-other-window (file)
 252   "View FILE in View mode in another window.
 253 When done, return that window to its previous buffer, and kill the
 254 buffer visiting FILE if unmodified and if it wasn't visited before.
 255
 256 Emacs commands editing the buffer contents are not available; instead,
 257 a special set of commands (mostly letters and punctuation)
 258 are defined for moving around in the buffer.
 259 Space scrolls forward, Delete scrolls backward.
 260 For a list of all View commands, type H or h while viewing.
 261
 262 This command runs the normal hook `view-mode-hook'."
 263   (interactive "fIn other window view file: ")
 264   (unless (file-exists-p file) (error "%s does not exist" file))
 265   (let ((had-a-buf (get-file-buffer file))
 266         (buf-to-view (find-file-noselect file)))
 267     (view-buffer-other-window buf-to-view nil
 268                               (and (not had-a-buf)
 269                                    'kill-buffer-if-not-modified))))
 270
 271 ;;;###autoload
 272 (defun view-file-other-frame (file)
 273   "View FILE in View mode in another frame.
 274 When done, kill the buffer visiting FILE if unmodified and if it wasn't
 275 visited before; also, maybe delete other frame and/or return to previous
 276 buffer.
 277
 278 Emacs commands editing the buffer contents are not available; instead,
 279 a special set of commands (mostly letters and punctuation)
 280 are defined for moving around in the buffer.
 281 Space scrolls forward, Delete scrolls backward.
 282 For a list of all View commands, type H or h while viewing.
 283
 284 This command runs the normal hook `view-mode-hook'."
 285   (interactive "fIn other frame view file: ")
 286   (unless (file-exists-p file) (error "%s does not exist" file))
 287   (let ((had-a-buf (get-file-buffer file))
 288         (buf-to-view (find-file-noselect file)))
 289     (view-buffer-other-frame buf-to-view nil
 290                              (and (not had-a-buf)
 291                                   'kill-buffer-if-not-modified))))
 292
 293
 294 ;;;###autoload
 295 (defun view-buffer (buffer &optional exit-action)
 296   "View BUFFER in View mode, returning to previous buffer when done.
 297 Emacs commands editing the buffer contents are not available; instead, a
 298 special set of commands (mostly letters and punctuation) are defined for
 299 moving around in the buffer.
 300 Space scrolls forward, Delete scrolls backward.
 301 For a list of all View commands, type H or h while viewing.
 302
 303 This command runs the normal hook `view-mode-hook'.
 304
 305 Optional argument EXIT-ACTION is either nil or a function with buffer as
 306 argument.  This function is called when finished viewing buffer.  Use
 307 this argument instead of explicitly setting `view-exit-action'.
 308
 309 Do not set EXIT-ACTION to `kill-buffer' when BUFFER visits a
 310 file: Users may suspend viewing in order to modify the buffer.
 311 Exiting View mode will then discard the user's edits.  Setting
 312 EXIT-ACTION to `kill-buffer-if-not-modified' avoids this."
 313   (interactive "bView buffer: ")
 314   (if (with-current-buffer buffer
 315         (and (eq (get major-mode 'mode-class)
 316                  'special)
 317              (null buffer-file-name)))
 318       (progn
 319         (switch-to-buffer buffer)
 320         (message "Not using View mode because the major mode is special"))
 321     (switch-to-buffer buffer)
 322     (view-mode-enter nil exit-action)))
 323
 324 ;;;###autoload
 325 (defun view-buffer-other-window (buffer &optional not-return exit-action)
 326   "View BUFFER in View mode in another window.
 327 Emacs commands editing the buffer contents are not available;
 328 instead, a special set of commands (mostly letters and
 329 punctuation) are defined for moving around in the buffer.
 330 Space scrolls forward, Delete scrolls backward.
 331 For a list of all View commands, type H or h while viewing.
 332
 333 This command runs the normal hook `view-mode-hook'.
 334
 335 Optional argument NOT-RETURN is ignored.
 336
 337 Optional argument EXIT-ACTION is either nil or a function with buffer as
 338 argument.  This function is called when finished viewing buffer.  Use
 339 this argument instead of explicitly setting `view-exit-action'."
 340   (interactive "bIn other window view buffer:\nP")
 341   (let ((pop-up-windows t))
 342     (pop-to-buffer buffer t))
 343   (view-mode-enter nil exit-action))
 344
 345 ;;;###autoload
 346 (defun view-buffer-other-frame (buffer &optional not-return exit-action)
 347   "View BUFFER in View mode in another frame.
 348 Emacs commands editing the buffer contents are not available;
 349 instead, a special set of commands (mostly letters and
 350 punctuation) are defined for moving around in the buffer.
 351 Space scrolls forward, Delete scrolls backward.
 352 For a list of all View commands, type H or h while viewing.
 353
 354 This command runs the normal hook `view-mode-hook'.
 355
 356 Optional argument NOT-RETURN is ignored.
 357
 358 Optional argument EXIT-ACTION is either nil or a function with buffer as
 359 argument.  This function is called when finished viewing buffer.  Use
 360 this argument instead of explicitly setting `view-exit-action'."
 361   (interactive "bView buffer in other frame: \nP")
 362   (let ((pop-up-frames t))
 363     (pop-to-buffer buffer t))
 364   (view-mode-enter nil exit-action))
 365 \f
 366 ;;;###autoload
 367 (define-minor-mode view-mode
 368   ;; In the following documentation string we have to use some explicit key
 369   ;; bindings instead of using the \\[] construction.  The reason for this
 370   ;; is that most commands have more than one key binding.
 371   "Toggle View mode, a minor mode for viewing text but not editing it.
 372 With a prefix argument ARG, enable View mode if ARG is positive,
 373 and disable it otherwise.  If called from Lisp, enable View mode
 374 if ARG is omitted or nil.
 375
 376 When View mode is enabled, commands that do not change the buffer
 377 contents are available as usual.  Kill commands insert text in
 378 kill buffers but do not delete.  Most other commands beep and
 379 tell the user that the buffer is read-only.
 380
 381 \\<view-mode-map>
 382
 383 The following additional commands are provided.  Most commands
 384 take prefix arguments.  Page commands default to \"page size\"
 385 lines which is almost a whole window, or number of lines set by
 386 \\[View-scroll-page-forward-set-page-size] or \\[View-scroll-page-backward-set-page-size].
 387 Half page commands default to and set \"half page size\" lines
 388 which initially is half a window full.  Search commands default
 389 to a repeat count of one.
 390
 391 H, h, ?  This message.
 392 Digits  provide prefix arguments.
 393 \\[negative-argument]   negative prefix argument.
 394 \\[beginning-of-buffer] move to the beginning of buffer.
 395 >       move to the end of buffer.
 396 \\[View-scroll-to-buffer-end]   scroll so that buffer end is at last line of window.
 397 SPC     scroll forward \"page size\" lines.
 398           With prefix scroll forward prefix lines.
 399 DEL     scroll backward \"page size\" lines.
 400           With prefix scroll backward prefix lines.
 401 \\[View-scroll-page-forward-set-page-size]      like  \\[View-scroll-page-forward]  but with prefix sets \"page size\" to prefix.
 402 \\[View-scroll-page-backward-set-page-size]     like  \\[View-scroll-page-backward]  but with prefix sets \"page size\" to prefix.
 403 \\[View-scroll-half-page-forward]       scroll forward \"half page size\" lines.  With prefix, sets
 404           \"half page size\" to prefix lines and scrolls forward that much.
 405 \\[View-scroll-half-page-backward]      scroll backward \"half page size\" lines.  With prefix, sets
 406           \"half page size\" to prefix lines and scrolls backward that much.
 407 RET, LFD  scroll forward one line.  With prefix scroll forward prefix line(s).
 408 y       scroll backward one line.  With prefix scroll backward prefix line(s).
 409 \\[View-revert-buffer-scroll-page-forward]      revert-buffer if necessary and scroll forward.
 410           Use this to view a changing file.
 411 \\[what-line]   prints the current line number.
 412 \\[View-goto-percent]   goes prefix argument (default 100) percent into buffer.
 413 \\[View-goto-line]      goes to line given by prefix argument (default first line).
 414 .       set the mark.
 415 x       exchanges point and mark.
 416 \\[View-back-to-mark]   return to mark and pops mark ring.
 417           Mark ring is pushed at start of every successful search and when
 418           jump to line occurs.  The mark is set on jump to buffer start or end.
 419 \\[point-to-register]   save current position in character register.
 420 '       go to position saved in character register.
 421 s       do forward incremental search.
 422 r       do reverse incremental search.
 423 \\[View-search-regexp-forward]  searches forward for regular expression, starting after current page.
 424           ! and @ have a special meaning at the beginning of the regexp.
 425           ! means search for a line with no match for regexp.  @ means start
 426           search at beginning (end for backward search) of buffer.
 427 \\      searches backward for regular expression, starting before current page.
 428 \\[View-search-last-regexp-forward]     searches forward for last regular expression.
 429 p       searches backward for last regular expression.
 430 \\[View-quit]   quit View mode, restoring this window and buffer to previous state.
 431           \\[View-quit] is the normal way to leave view mode.
 432 \\[View-exit]   exit View mode but stay in current buffer.  Use this if you started
 433           viewing a buffer (file) and find out you want to edit it.
 434           This command restores the previous read-only status of the buffer.
 435 \\[View-exit-and-edit]  exit View mode, and make the current buffer editable
 436           even if it was not editable before entry to View mode.
 437 \\[View-quit-all]       quit View mode, restoring all windows to previous state.
 438 \\[View-leave]  quit View mode and maybe switch buffers, but don't kill this buffer.
 439 \\[View-kill-and-leave] quit View mode, kill current buffer and go back to other buffer.
 440
 441 The effect of \\[View-leave], \\[View-quit] and \\[View-kill-and-leave] depends on how view-mode was entered.  If it was
 442 entered by view-file, view-file-other-window, view-file-other-frame, or
 443 \\[dired-view-file] \(\\[view-file], \\[view-file-other-window],
 444 \\[view-file-other-frame], or the Dired mode v command),
 445 then \\[View-quit] will try to kill the current buffer.
 446 If view-mode was entered from another buffer, by \\[view-buffer],
 447 \\[view-buffer-other-window], \\[view-buffer-other frame], \\[view-file],
 448 \\[view-file-other-window], or \\[view-file-other-frame],
 449 then \\[View-leave], \\[View-quit] and \\[View-kill-and-leave] will return to that buffer.
 450
 451 Entry to view-mode runs the normal hook `view-mode-hook'."
 452   :lighter " View" :keymap view-mode-map
 453   (if view-mode (view-mode-enable) (view-mode-disable)))
 454 \f
 455 (defun view-mode-enable ()
 456   "Turn on View mode."
 457   ;; Always leave view mode before changing major mode.
 458   ;; This is to guarantee that the buffer-read-only variable is restored.
 459   (add-hook 'change-major-mode-hook 'view-mode-disable nil t)
 460   (setq view-mode t
 461         view-page-size nil
 462         view-half-page-size nil
 463         view-old-buffer-read-only buffer-read-only
 464         buffer-read-only t)
 465   (if (boundp 'Helper-return-blurb)
 466       (setq view-old-Helper-return-blurb (and (boundp 'Helper-return-blurb)
 467                                               Helper-return-blurb)
 468             Helper-return-blurb
 469             (format "continue viewing %s"
 470                     (if (buffer-file-name)
 471                         (file-name-nondirectory (buffer-file-name))
 472                       (buffer-name)))))
 473   (force-mode-line-update)
 474   (run-hooks 'view-mode-hook))
 475
 476 (defun view-mode-disable ()
 477   "Turn off View mode."
 478   (remove-hook 'change-major-mode-hook 'view-mode-disable t)
 479   (and view-overlay (delete-overlay view-overlay))
 480   (force-mode-line-update)
 481   ;; Calling toggle-read-only while View mode is enabled
 482   ;; sets view-read-only to t as a buffer-local variable
 483   ;; after exiting View mode.  That arranges that the next toggle-read-only
 484   ;; will reenable View mode.
 485   ;; Cancelling View mode in any other way should cancel that, too,
 486   ;; so that View mode stays off if toggle-read-only is called.
 487   (if (local-variable-p 'view-read-only)
 488       (kill-local-variable 'view-read-only))
 489   (setq view-mode nil)
 490   (if (boundp 'Helper-return-blurb)
 491       (setq Helper-return-blurb view-old-Helper-return-blurb))
 492   (if buffer-read-only
 493       (setq buffer-read-only view-old-buffer-read-only)))
 494
 495 ;;;###autoload
 496 (defun view-return-to-alist-update (buffer &optional item)
 497   "Update `view-return-to-alist' of buffer BUFFER.
 498 Remove from `view-return-to-alist' all entries referencing dead
 499 windows.  Optional argument ITEM non-nil means add ITEM to
 500 `view-return-to-alist' after purging.  For a decsription of items
 501 that can be added see the RETURN-TO-ALIST argument of the
 502 function `view-mode-exit'.  If `view-return-to-alist' contains an
 503 entry for the selected window, purge that entry from
 504 `view-return-to-alist' before adding ITEM."
 505   (with-current-buffer buffer
 506     (when view-return-to-alist
 507       (let* ((list view-return-to-alist)
 508              entry entry-window last)
 509         (while list
 510           (setq entry (car list))
 511           (setq entry-window (car entry))
 512           (if (and (windowp entry-window)
 513                    (or (and item (eq entry-window (selected-window)))
 514                        (not (window-live-p entry-window))))
 515               ;; Remove that entry.
 516               (if last
 517                   (setcdr last (cdr list))
 518                 (setq view-return-to-alist
 519                       (cdr view-return-to-alist)))
 520             ;; Leave entry alone.
 521             (setq last entry))
 522           (setq list (cdr list)))))
 523     ;; Add ITEM.
 524     (when item
 525       (setq view-return-to-alist
 526             (cons item view-return-to-alist)))))
 527 (make-obsolete 'view-return-to-alist-update "this function has no effect." "24.1")
 528
 529 ;;;###autoload
 530 (defun view-mode-enter (&optional quit-restore exit-action)
 531   "Enter View mode and set up exit from view mode depending on optional arguments.
 532 Optional argument QUIT-RESTORE if non-nil must specify a valid
 533 entry for quitting and restoring any window showing the current
 534 buffer.  This entry replaces any parameter installed by
 535 `display-buffer' and is used by `view-mode-exit'.
 536
 537 Optional argument EXIT-ACTION, if non-nil, must specify a
 538 function that takes a buffer as argument.  This function will be
 539 called by `view-mode-exit'.
 540
 541 For a list of all View commands, type H or h while viewing.
 542
 543 This function runs the normal hook `view-mode-hook'."
 544   (when quit-restore
 545     (dolist (window (get-buffer-window-list nil nil t))
 546       (set-window-parameter window 'quit-restore quit-restore)))
 547
 548   (when exit-action
 549     (setq view-exit-action exit-action))
 550
 551   (unless view-mode
 552     (view-mode-enable)
 553     (force-mode-line-update)
 554     (unless view-inhibit-help-message
 555       (message "%s"
 556                (substitute-command-keys "\
 557 View mode: type \\[help-command] for help, \\[describe-mode] for commands, \\[View-quit] to quit.")))))
 558 \f
 559 ;; This is awful because it assumes that the selected window shows the
 560 ;; current buffer when this is called.
 561 (defun view-mode-exit (&optional exit-only exit-action all-windows)
 562   "Exit View mode in various ways.
 563 If all arguments are nil, remove the current buffer from the
 564 selected window using the `quit-restore' information associated
 565 with the selected window.  If optional argument ALL-WINDOWS or
 566 `view-exits-all-viewing-windows' are non-nil, remove the current
 567 buffer from all windows showing it.
 568
 569 Optional argument EXIT-ONLY non-nil means just exit `view-mode'
 570 \(unless `view-no-disable-on-exit' is non-nil) but do not change
 571 the associations of any windows with the current buffer.
 572
 573 EXIT-ACTION, if non-nil, must specify a function that is called
 574 with the current buffer as argument and is called after disabling
 575 `view-mode' and removing any associations of windows with the
 576 current buffer. "
 577   (when view-mode
 578     (let ((buffer (window-buffer)))
 579       (unless view-no-disable-on-exit
 580         (view-mode-disable))
 581
 582       (unless exit-only
 583         (cond
 584          ((or all-windows view-exits-all-viewing-windows)
 585           (dolist (window (get-buffer-window-list))
 586             (quit-window nil window)))
 587          ((eq (window-buffer) (current-buffer))
 588           (quit-window)))
 589
 590         (when exit-action
 591           (funcall exit-action buffer))
 592         (force-mode-line-update)))))
 593 \f
 594 (defun View-exit ()
 595   "Exit View mode but stay in current buffer."
 596   (interactive)
 597   (view-mode-exit t))
 598
 599 ;;;###autoload
 600 (defun View-exit-and-edit ()
 601   "Exit View mode and make the current buffer editable."
 602   (interactive)
 603   (let ((view-old-buffer-read-only nil)
 604         (view-no-disable-on-exit nil))
 605     (view-mode-exit t)))
 606
 607 (defun View-leave ()
 608   "Quit View mode and maybe switch buffers, but don't kill this buffer."
 609   (interactive)
 610   (view-mode-exit))
 611
 612 (defun View-quit ()
 613   "Quit View mode, trying to restore window and buffer to previous state.
 614 Maybe kill this buffer.  Try to restore selected window to previous state
 615 and go to previous buffer or window."
 616   (interactive)
 617   (view-mode-exit nil view-exit-action))
 618
 619 (defun View-quit-all ()
 620   "Quit View mode, trying to restore windows and buffers to previous state.
 621 Maybe kill current buffer.  Try to restore all windows viewing buffer to
 622 previous state and go to previous buffer or window."
 623   (interactive)
 624   (view-mode-exit nil view-exit-action t))
 625
 626 (defun View-kill-and-leave ()
 627   "Quit View mode, kill current buffer and return to previous buffer."
 628   (interactive)
 629   (view-mode-exit nil (or view-exit-action 'kill-buffer) t))
 630 \f
 631
 632 ;;; Some help routines.
 633
 634 (defun view-window-size ()
 635   ;; Return the height of the current window, excluding the mode line.
 636   ;; Using `window-line-height' accounts for variable-height fonts.
 637   (let ((h (window-line-height -1)))
 638     (if h
 639         (1+ (nth 1 h))
 640       ;; This should not happen, but if `window-line-height' returns
 641       ;; nil, fall back on `window-height'.
 642       (1- (window-height)))))
 643
 644 ;; (defun view-last-command (&optional who what)
 645 ;;  (setq view-last-command-entry this-command)
 646 ;;  (setq view-last-command who)
 647 ;;  (setq view-last-command-argument what))
 648
 649 ;; (defun View-repeat-last-command ()
 650 ;;  "Repeat last command issued in View mode."
 651 ;;  (interactive)
 652 ;;  (if (and view-last-command
 653 ;;         (eq view-last-command-entry last-command))
 654 ;;      (funcall view-last-command view-last-command-argument))
 655 ;;  (setq this-command view-last-command-entry))
 656
 657 (defun view-recenter ()
 658   ;; Recenter point in window and redisplay normally.
 659   (recenter '(1)))
 660
 661 (defun view-page-size-default (lines)
 662   ;; If LINES is nil, 0, or larger than `view-window-size', return nil.
 663   ;; Otherwise, return LINES.
 664   (and lines
 665        (not (zerop (setq lines (prefix-numeric-value lines))))
 666        (<= (abs lines)
 667            (abs (- (view-window-size) next-screen-context-lines)))
 668        (abs lines)))
 669
 670 (defun view-set-half-page-size-default (lines)
 671   ;; Get and maybe set half page size.
 672   (if (not lines) (or view-half-page-size
 673                       (/ (view-window-size) 2))
 674     (setq view-half-page-size
 675           (if (zerop (setq lines (prefix-numeric-value lines)))
 676               (/ (view-window-size) 2)
 677             (view-page-size-default lines)))))
 678
 679
 680 ;;; Commands for moving around in the buffer.
 681
 682 (defun View-goto-percent (&optional percent)
 683   "Move to end (or prefix PERCENT) of buffer in View mode.
 684 Display is centered at point.
 685 Also set the mark at the position where point was."
 686   (interactive "P")
 687   (push-mark)
 688   (goto-char
 689    (if percent
 690        (+ (point-min)
 691           (floor (* (- (point-max) (point-min)) 0.01
 692                     (max 0 (min 100 (prefix-numeric-value percent))))))
 693      (point-max)))
 694   (view-recenter))
 695
 696 ;; (defun View-goto-line-last (&optional line)
 697 ;; "Move to last (or prefix LINE) line in View mode.
 698 ;; Display is centered at LINE.
 699 ;; Sets mark at starting position and pushes mark ring."
 700 ;;  (interactive "P")
 701 ;;  (push-mark)
 702 ;;  (if line (goto-line (prefix-numeric-value line))
 703 ;;    (goto-char (point-max))
 704 ;;    (beginning-of-line))
 705 ;;  (view-recenter))
 706
 707 (defun View-goto-line (&optional line)
 708   "Move to first (or prefix LINE) line in View mode.
 709 Display is centered at LINE.
 710 Also set the mark at the position where point was."
 711   (interactive "p")
 712   (push-mark)
 713   (goto-char (point-min))
 714   (forward-line (1- line))
 715   (view-recenter))
 716
 717 (defun View-back-to-mark (&optional _ignore)
 718   "Return to last mark set in View mode, else beginning of file.
 719 Display that line at the center of the window.
 720 This command pops the mark ring, so that successive
 721 invocations return to earlier marks."
 722   (interactive)
 723   (goto-char (or (mark t) (point-min)))
 724   (pop-mark)
 725   (view-recenter))
 726 \f
 727 (defun view-scroll-lines (lines backward default maxdefault)
 728   ;; This function does the job for all the scrolling commands.
 729   ;; Scroll forward LINES lines.  If BACKWARD is non-nil, scroll backwards.
 730   ;; If LINES is negative scroll in the other direction.
 731   ;; If LINES is 0 or nil, scroll DEFAULT lines (if DEFAULT is nil, scroll
 732   ;; by one page).  If MAXDEFAULT is non-nil, scroll no more than a window.
 733   (if (or (null lines) (zerop (setq lines (prefix-numeric-value lines))))
 734       (setq lines default))
 735   (when (and lines (< lines 0))
 736     (setq backward (not backward) lines (- lines)))
 737   (when (and maxdefault lines (> lines (view-window-size)))
 738     (setq lines nil))
 739   (cond (backward (scroll-down lines))
 740         ((view-really-at-end)
 741          (if view-scroll-auto-exit
 742              (View-quit)
 743            (ding)
 744            (view-end-message)))
 745         (t (scroll-up lines)
 746            (if (view-really-at-end) (view-end-message)))))
 747
 748 (defun view-really-at-end ()
 749   ;; Return true if buffer end visible.  Maybe revert buffer and test.
 750   (and (pos-visible-in-window-p (point-max))
 751        (let ((buf (current-buffer))
 752              (bufname (buffer-name))
 753              (file (buffer-file-name)))
 754          (or (not view-try-extend-at-buffer-end)
 755              (null file)
 756              (verify-visited-file-modtime buf)
 757              (not (file-exists-p file))
 758              (when (buffer-modified-p buf)
 759                (setq file (file-name-nondirectory file))
 760                (not (yes-or-no-p
 761                      (format
 762                       "File %s changed on disk.  Discard your edits%s? "
 763                       file
 764                       (if (string= bufname file) ""
 765                         (concat " in " bufname))))))
 766              (progn
 767                (revert-buffer t t t)
 768                (pos-visible-in-window-p (point-max)))))))
 769
 770 (defun view-end-message ()
 771   ;; Tell that we are at end of buffer.
 772   (goto-char (point-max))
 773   (if (window-parameter nil 'quit-restore)
 774       (message "End of buffer.  Type %s to quit viewing."
 775                (substitute-command-keys
 776                 (if view-scroll-auto-exit "\\[View-scroll-page-forward]"
 777                   "\\[View-quit]")))
 778     (message "End of buffer")))
 779 \f
 780 (defun View-scroll-to-buffer-end ()
 781   "Scroll backward or forward so that buffer end is at last line of window."
 782   (interactive)
 783   (let ((p (if (pos-visible-in-window-p (point-max)) (point))))
 784     (goto-char (point-max))
 785     (recenter -1)
 786     (and p (goto-char p))))
 787
 788 (defun View-scroll-page-forward (&optional lines)
 789   "Scroll \"page size\" or prefix LINES lines forward in View mode.
 790 Exit if end of text is visible and `view-scroll-auto-exit' is non-nil.
 791 \"page size\" is whole window full, or number of lines set by
 792 \\[View-scroll-page-forward-set-page-size] or
 793 \\[View-scroll-page-backward-set-page-size].
 794 If LINES is more than a window-full, only the last window-full is shown."
 795   (interactive "P")
 796   (view-scroll-lines lines nil (view-page-size-default view-page-size) nil))
 797
 798 (defun View-scroll-page-backward (&optional lines)
 799   "Scroll \"page size\" or prefix LINES lines backward in View mode.
 800 See also `View-scroll-page-forward'."
 801   (interactive "P")
 802   (view-scroll-lines lines t (view-page-size-default view-page-size) nil))
 803
 804 (defun View-scroll-page-forward-set-page-size (&optional lines)
 805   "Scroll forward LINES lines in View mode, setting the \"page size\".
 806 This is the number of lines which \\[View-scroll-page-forward] and
 807 \\[View-scroll-page-backward] scroll by default.
 808 If LINES is omitted or = 0, sets \"page size\" to window height and
 809 scrolls forward that much, otherwise scrolls forward LINES lines and sets
 810 \"page size\" to the minimum of window height and the absolute value of LINES.
 811 See also `View-scroll-page-forward'."
 812   (interactive "P")
 813   (view-scroll-lines lines nil
 814                      (setq view-page-size (view-page-size-default lines))
 815                      nil))
 816
 817 (defun View-scroll-page-backward-set-page-size (&optional lines)
 818   "Scroll backward prefix LINES lines in View mode, setting the \"page size\".
 819 See also `View-scroll-page-forward-set-page-size'."
 820   (interactive "P")
 821   (view-scroll-lines lines t
 822                      (setq view-page-size (view-page-size-default lines))
 823                      nil))
 824
 825 (defun View-scroll-line-forward (&optional lines)
 826   "Scroll forward one line (or prefix LINES lines) in View mode.
 827 See also `View-scroll-page-forward', but note that scrolling is limited
 828 to minimum of LINES and one window-full."
 829   (interactive "P")
 830   (view-scroll-lines lines nil 1 t))
 831
 832 (defun View-scroll-line-backward (&optional lines)
 833   "Scroll backward one line (or prefix LINES lines) in View mode.
 834 See also `View-scroll-line-forward'."
 835   (interactive "P")
 836   (view-scroll-lines lines t 1 t))
 837
 838 (defun View-scroll-half-page-forward (&optional lines)
 839   "Scroll forward a \"half page\" (or prefix LINES) lines in View mode.
 840 If LINES is not omitted, the \"half page size\" is set to the minimum of
 841 window height and the absolute value of LINES.
 842 LINES=0 resets \"half page size\" to half window height."
 843   (interactive "P")
 844   (view-scroll-lines lines nil (view-set-half-page-size-default lines) t))
 845
 846 (defun View-scroll-half-page-backward (&optional lines)
 847   "Scroll backward a \"half page\" (or prefix LINES) lines in View mode.
 848 See also `View-scroll-half-page-forward'."
 849   (interactive "P")
 850   (view-scroll-lines lines t (view-set-half-page-size-default lines) t))
 851
 852 (defun View-revert-buffer-scroll-page-forward (&optional lines)
 853   "Scroll forward, reverting buffer if needed, in View mode.
 854 If buffer has not been changed and the corresponding file is newer, first
 855 revert the buffer, then scroll.
 856 This command is useful if you are viewing a changing file.
 857
 858 The prefix argument LINES says how many lines to scroll.
 859 If you don't specify a prefix argument, it uses the number of lines set by
 860 \\[View-scroll-page-forward-set-page-size] or
 861 \\[View-scroll-page-backward-set-page-size].
 862 If LINES is more than a window-full, only the last window-full is shown."
 863   (interactive "P")
 864   (let ((view-scroll-auto-exit nil)
 865         (view-try-extend-at-buffer-end t))
 866     (view-scroll-lines lines nil (view-page-size-default view-page-size) nil)))
 867 \f
 868 (defun View-search-regexp-forward (n regexp)
 869   "Search forward for first (or prefix Nth) occurrence of REGEXP in View mode.
 870
 871 Displays line found at center of window.  Sets mark at starting position and
 872 pushes mark ring.
 873
 874 Characters @ and ! are special at the beginning of REGEXP.  They modify
 875 the search rather than become part of the pattern searched for.
 876 @ means search all the buffer i.e. start search at the beginning of buffer.
 877 ! means search for a line that contains no match for the pattern.
 878 If REGEXP is empty or only consist of these control characters, then
 879 an earlier remembered REGEXP is used, otherwise REGEXP is remembered
 880 for use by later search commands.
 881
 882 The variable `view-highlight-face' controls the face that is used
 883 for highlighting the match that is found."
 884   (interactive "p\nsSearch forward (regexp): ")
 885   (view-search n regexp))
 886
 887 (defun View-search-regexp-backward (n regexp)
 888   "Search backward for first (or prefix Nth) occurrence of REGEXP in View mode.
 889
 890 Displays line found at center of window.  Sets mark at starting position and
 891 pushes mark ring.
 892
 893 Characters @ and ! are special at the beginning of REGEXP.  They modify
 894 the search rather than become part of the pattern searched for.
 895 @ means search all the buffer i.e. start search at the end of buffer.
 896 ! means search for a line that contains no match for the pattern.
 897 If REGEXP is empty or only consist of these control characters, then
 898 an earlier remembered REGEXP is used, otherwise REGEXP is remembered
 899 for use by later search commands.
 900
 901 The variable `view-highlight-face' controls the face that is used
 902 for highlighting the match that is found."
 903   (interactive "p\nsSearch backward (regexp): ")
 904   (view-search (- n) regexp))
 905
 906 (defun View-search-last-regexp-forward (n) "\
 907 Search forward for first (or prefix Nth) instance of last regexp in View mode.
 908 Displays line found at center of window.  Sets mark at starting position and
 909 pushes mark ring.
 910
 911 The variable `view-highlight-face' controls the face that is used
 912 for highlighting the match that is found."
 913   (interactive "p")
 914   (view-search n nil))
 915
 916 (defun View-search-last-regexp-backward (n) "\
 917 Search backward for first (or prefix Nth) instance of last regexp in View mode.
 918 Displays line found at center of window.  Sets mark at starting position and
 919 pushes mark ring.
 920
 921 The variable `view-highlight-face' controls the face that is used
 922 for highlighting the match that is found."
 923   (interactive "p")
 924   (view-search (- n) nil))
 925
 926 (defun view-search (times regexp)
 927   ;; This function does the job for all the View-search- commands.
 928   ;; Search for the TIMESth match for REGEXP.  If TIMES is negative
 929   ;; search backwards.  If REGEXP is nil use `view-last-regexp'.
 930   ;; Characters "!" and "@" have a special meaning at the beginning of
 931   ;; REGEXP and are removed from REGEXP before the search "!" means
 932   ;; search for lines with no match for REGEXP.  "@" means search in
 933   ;; the whole buffer, don't start searching from the present point.
 934   (let (where no end ln)
 935     (cond
 936      ((and regexp (> (length regexp) 0)
 937            (or (not (memq (string-to-char regexp) '(?! ?@)))
 938                (progn
 939                  (if (member (substring regexp 0 2) '("!@" "@!"))
 940                      (setq end t no t ln 2)
 941                    (setq no (not (setq end (eq ?@ (string-to-char regexp))))
 942                          ln 1))
 943                  (> (length (setq regexp (substring regexp ln))) 0))))
 944       (setq view-last-regexp (if no (list regexp) regexp)))
 945      ((consp view-last-regexp)
 946       (setq regexp (car view-last-regexp))
 947       (unless (setq no (not no)) (setq view-last-regexp regexp)))
 948      (view-last-regexp (setq regexp view-last-regexp)
 949                        (if no (setq view-last-regexp (list regexp))))
 950      (t (error "No previous View-mode search")))
 951     (save-excursion
 952       (if end (goto-char (if (< times 0) (point-max) (point-min)))
 953         (move-to-window-line (if (< times 0) 0 -1)))
 954       (if (if no (view-search-no-match-lines times regexp)
 955             (re-search-forward regexp nil t times))
 956           (setq where (point))))
 957     (if where
 958         (progn
 959           (push-mark)
 960           (goto-char where)
 961           (if view-overlay
 962               (move-overlay view-overlay (match-beginning 0) (match-end 0))
 963             (setq view-overlay
 964                   (make-overlay (match-beginning 0) (match-end 0))))
 965           (overlay-put view-overlay 'face view-highlight-face)
 966           (beginning-of-line)
 967           (view-recenter))
 968       (message "Can't find occurrence %d of %s%s"
 969                times (if no "no " "") regexp)
 970       (sit-for 4))))
 971
 972 ;; This is the dumb approach, looking at each line.  The original
 973 ;; version of this function looked like it might have been trying to
 974 ;; do something clever, but not succeeding:
 975 ;; http://lists.gnu.org/archive/html/bug-gnu-emacs/2007-09/msg00073.html
 976 (defun view-search-no-match-lines (times regexp)
 977   "Search for the TIMESth occurrence of a line with no match for REGEXP.
 978 If such a line is found, return non-nil and set the match-data to that line.
 979 If TIMES is negative, search backwards."
 980   (let ((step (if (>= times 0) 1
 981                 (setq times (- times))
 982                 -1)))
 983     ;; Note that we do not check the current line.
 984     (while (and (> times 0)
 985                 (zerop (forward-line step)))
 986       ;; (forward-line 1) returns 0 on moving within the last line.
 987       (if (eobp)
 988           (setq times -1)
 989         (or (re-search-forward regexp (line-end-position) t)
 990             (setq times (1- times))))))
 991   (and (zerop times)
 992        (looking-at ".*")))
 993
 994 (provide 'view)
 995
 996 ;;; view.el ends here