lisp/image.el

   1 ;;; image.el --- image API
   2
   3 ;; Copyright (C) 1998-2013 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: multimedia
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28
  29 (defgroup image ()
  30   "Image support."
  31   :group 'multimedia)
  32
  33 (defalias 'image-refresh 'image-flush)
  34
  35 (defconst image-type-header-regexps
  36   `(("\\`/[\t\n\r ]*\\*.*XPM.\\*/" . xpm)
  37     ("\\`P[1-6][[:space:]]+\\(?:#.*[[:space:]]+\\)*[0-9]+[[:space:]]+[0-9]+" . pbm)
  38     ("\\`GIF8[79]a" . gif)
  39     ("\\`\x89PNG\r\n\x1a\n" . png)
  40     ("\\`[\t\n\r ]*#define \\([a-z0-9_]+\\)_width [0-9]+\n\
  41 #define \\1_height [0-9]+\n\\(\
  42 #define \\1_x_hot [0-9]+\n\
  43 #define \\1_y_hot [0-9]+\n\\)?\
  44 static \\(unsigned \\)?char \\1_bits" . xbm)
  45     ("\\`\\(?:MM\0\\*\\|II\\*\0\\)" . tiff)
  46     ("\\`[\t\n\r ]*%!PS" . postscript)
  47     ("\\`\xff\xd8" . jpeg)    ; used to be (image-jpeg-p . jpeg)
  48     (,(let* ((incomment-re "\\(?:[^-]\\|-[^-]\\)")
  49              (comment-re (concat "\\(?:!--" incomment-re "*-->[ \t\r\n]*<\\)")))
  50         (concat "\\(?:<\\?xml[ \t\r\n]+[^>]*>\\)?[ \t\r\n]*<"
  51                 comment-re "*"
  52                 "\\(?:!DOCTYPE[ \t\r\n]+[^>]*>[ \t\r\n]*<[ \t\r\n]*" comment-re "*\\)?"
  53                 "[Ss][Vv][Gg]"))
  54      . svg)
  55     )
  56   "Alist of (REGEXP . IMAGE-TYPE) pairs used to auto-detect image types.
  57 When the first bytes of an image file match REGEXP, it is assumed to
  58 be of image type IMAGE-TYPE if IMAGE-TYPE is a symbol.  If not a symbol,
  59 IMAGE-TYPE must be a pair (PREDICATE . TYPE).  PREDICATE is called
  60 with one argument, a string containing the image data.  If PREDICATE returns
  61 a non-nil value, TYPE is the image's type.")
  62
  63 (defvar image-type-file-name-regexps
  64   '(("\\.png\\'" . png)
  65     ("\\.gif\\'" . gif)
  66     ("\\.jpe?g\\'" . jpeg)
  67     ("\\.bmp\\'" . bmp)
  68     ("\\.xpm\\'" . xpm)
  69     ("\\.pbm\\'" . pbm)
  70     ("\\.xbm\\'" . xbm)
  71     ("\\.ps\\'" . postscript)
  72     ("\\.tiff?\\'" . tiff)
  73     ("\\.svgz?\\'" . svg)
  74     )
  75   "Alist of (REGEXP . IMAGE-TYPE) pairs used to identify image files.
  76 When the name of an image file match REGEXP, it is assumed to
  77 be of image type IMAGE-TYPE.")
  78
  79 ;; We rely on `auto-mode-alist' to detect xbm and xpm files, instead
  80 ;; of content autodetection.  Their contents are just C code, so it is
  81 ;; easy to generate false matches.
  82 (defvar image-type-auto-detectable
  83   '((pbm . t)
  84     (xbm . nil)
  85     (bmp . maybe)
  86     (gif . maybe)
  87     (png . maybe)
  88     (xpm . nil)
  89     (jpeg . maybe)
  90     (tiff . maybe)
  91     (svg . maybe)
  92     (postscript . nil))
  93   "Alist of (IMAGE-TYPE . AUTODETECT) pairs used to auto-detect image files.
  94 \(See `image-type-auto-detected-p').
  95
  96 AUTODETECT can be
  97  - t      always auto-detect.
  98  - nil    never auto-detect.
  99  - maybe  auto-detect only if the image type is available
 100             (see `image-type-available-p').")
 101
 102 (defcustom image-load-path
 103   (list (file-name-as-directory (expand-file-name "images" data-directory))
 104         'data-directory 'load-path)
 105   "List of locations in which to search for image files.
 106 If an element is a string, it defines a directory to search.
 107 If an element is a variable symbol whose value is a string, that
 108 value defines a directory to search.
 109 If an element is a variable symbol whose value is a list, the
 110 value is used as a list of directories to search."
 111   :type '(repeat (choice directory variable))
 112   :initialize 'custom-initialize-delay)
 113
 114
 115 (defun image-load-path-for-library (library image &optional path no-error)
 116   "Return a suitable search path for images used by LIBRARY.
 117
 118 It searches for IMAGE in `image-load-path' (excluding
 119 \"`data-directory'/images\") and `load-path', followed by a path
 120 suitable for LIBRARY, which includes \"../../etc/images\" and
 121 \"../etc/images\" relative to the library file itself, and then
 122 in \"`data-directory'/images\".
 123
 124 Then this function returns a list of directories which contains
 125 first the directory in which IMAGE was found, followed by the
 126 value of `load-path'.  If PATH is given, it is used instead of
 127 `load-path'.
 128
 129 If NO-ERROR is non-nil and a suitable path can't be found, don't
 130 signal an error.  Instead, return a list of directories as before,
 131 except that nil appears in place of the image directory.
 132
 133 Here is an example that uses a common idiom to provide
 134 compatibility with versions of Emacs that lack the variable
 135 `image-load-path':
 136
 137     ;; Shush compiler.
 138     (defvar image-load-path)
 139
 140     (let* ((load-path (image-load-path-for-library \"mh-e\" \"mh-logo.xpm\"))
 141            (image-load-path (cons (car load-path)
 142                                   (when (boundp 'image-load-path)
 143                                     image-load-path))))
 144       (mh-tool-bar-folder-buttons-init))"
 145   (unless library (error "No library specified"))
 146   (unless image   (error "No image specified"))
 147   (let (image-directory image-directory-load-path)
 148     ;; Check for images in image-load-path or load-path.
 149     (let ((img image)
 150           (dir (or
 151                 ;; Images in image-load-path.
 152                 (image-search-load-path image)
 153                 ;; Images in load-path.
 154                 (locate-library image)))
 155           parent)
 156       ;; Since the image might be in a nested directory (for
 157       ;; example, mail/attach.pbm), adjust `image-directory'
 158       ;; accordingly.
 159       (when dir
 160         (setq dir (file-name-directory dir))
 161         (while (setq parent (file-name-directory img))
 162           (setq img (directory-file-name parent)
 163                 dir (expand-file-name "../" dir))))
 164       (setq image-directory-load-path dir))
 165
 166     ;; If `image-directory-load-path' isn't Emacs's image directory,
 167     ;; it's probably a user preference, so use it. Then use a
 168     ;; relative setting if possible; otherwise, use
 169     ;; `image-directory-load-path'.
 170     (cond
 171      ;; User-modified image-load-path?
 172      ((and image-directory-load-path
 173            (not (equal image-directory-load-path
 174                        (file-name-as-directory
 175                         (expand-file-name "images" data-directory)))))
 176       (setq image-directory image-directory-load-path))
 177      ;; Try relative setting.
 178      ((let (library-name d1ei d2ei)
 179         ;; First, find library in the load-path.
 180         (setq library-name (locate-library library))
 181         (if (not library-name)
 182             (error "Cannot find library %s in load-path" library))
 183         ;; And then set image-directory relative to that.
 184         (setq
 185          ;; Go down 2 levels.
 186          d2ei (file-name-as-directory
 187                (expand-file-name
 188                 (concat (file-name-directory library-name) "../../etc/images")))
 189          ;; Go down 1 level.
 190          d1ei (file-name-as-directory
 191                (expand-file-name
 192                 (concat (file-name-directory library-name) "../etc/images"))))
 193         (setq image-directory
 194               ;; Set it to nil if image is not found.
 195               (cond ((file-exists-p (expand-file-name image d2ei)) d2ei)
 196                     ((file-exists-p (expand-file-name image d1ei)) d1ei)))))
 197      ;; Use Emacs's image directory.
 198      (image-directory-load-path
 199       (setq image-directory image-directory-load-path))
 200      (no-error
 201       (message "Could not find image %s for library %s" image library))
 202      (t
 203       (error "Could not find image %s for library %s" image library)))
 204
 205     ;; Return an augmented `path' or `load-path'.
 206     (nconc (list image-directory)
 207            (delete image-directory (copy-sequence (or path load-path))))))
 208
 209
 210 ;; Used to be in image-type-header-regexps, but now not used anywhere
 211 ;; (since 2009-08-28).
 212 (defun image-jpeg-p (data)
 213   "Value is non-nil if DATA, a string, consists of JFIF image data.
 214 We accept the tag Exif because that is the same format."
 215   (setq data (ignore-errors (string-to-unibyte data)))
 216   (when (and data (string-match-p "\\`\xff\xd8" data))
 217     (catch 'jfif
 218       (let ((len (length data)) (i 2))
 219         (while (< i len)
 220           (when (/= (aref data i) #xff)
 221             (throw 'jfif nil))
 222           (setq i (1+ i))
 223           (when (>= (+ i 2) len)
 224             (throw 'jfif nil))
 225           (let ((nbytes (+ (lsh (aref data (+ i 1)) 8)
 226                            (aref data (+ i 2))))
 227                 (code (aref data i)))
 228             (when (and (>= code #xe0) (<= code #xef))
 229               ;; APP0 LEN1 LEN2 "JFIF\0"
 230               (throw 'jfif
 231                      (string-match-p "JFIF\\|Exif"
 232                                      (substring data i (min (+ i nbytes) len)))))
 233             (setq i (+ i 1 nbytes))))))))
 234
 235
 236 ;;;###autoload
 237 (defun image-type-from-data (data)
 238   "Determine the image type from image data DATA.
 239 Value is a symbol specifying the image type or nil if type cannot
 240 be determined."
 241   (let ((types image-type-header-regexps)
 242         type)
 243     (while types
 244       (let ((regexp (car (car types)))
 245             (image-type (cdr (car types))))
 246         (if (or (and (symbolp image-type)
 247                      (string-match-p regexp data))
 248                 (and (consp image-type)
 249                      (funcall (car image-type) data)
 250                      (setq image-type (cdr image-type))))
 251             (setq type image-type
 252                   types nil)
 253           (setq types (cdr types)))))
 254     type))
 255
 256
 257 ;;;###autoload
 258 (defun image-type-from-buffer ()
 259   "Determine the image type from data in the current buffer.
 260 Value is a symbol specifying the image type or nil if type cannot
 261 be determined."
 262   (let ((types image-type-header-regexps)
 263         type
 264         (opoint (point)))
 265     (goto-char (point-min))
 266     (while types
 267       (let ((regexp (car (car types)))
 268             (image-type (cdr (car types)))
 269             data)
 270         (if (or (and (symbolp image-type)
 271                      (looking-at-p regexp))
 272                 (and (consp image-type)
 273                      (funcall (car image-type)
 274                               (or data
 275                                   (setq data
 276                                         (buffer-substring
 277                                          (point-min)
 278                                          (min (point-max)
 279                                               (+ (point-min) 256))))))
 280                      (setq image-type (cdr image-type))))
 281             (setq type image-type
 282                   types nil)
 283           (setq types (cdr types)))))
 284     (goto-char opoint)
 285     (and type
 286          (memq type image-types)
 287          type)))
 288
 289
 290 ;;;###autoload
 291 (defun image-type-from-file-header (file)
 292   "Determine the type of image file FILE from its first few bytes.
 293 Value is a symbol specifying the image type, or nil if type cannot
 294 be determined."
 295   (unless (or (file-readable-p file)
 296               (file-name-absolute-p file))
 297     (setq file (image-search-load-path file)))
 298   (and file
 299        (file-readable-p file)
 300        (with-temp-buffer
 301          (set-buffer-multibyte nil)
 302          (insert-file-contents-literally file nil 0 256)
 303          (image-type-from-buffer))))
 304
 305
 306 ;;;###autoload
 307 (defun image-type-from-file-name (file)
 308   "Determine the type of image file FILE from its name.
 309 Value is a symbol specifying the image type, or nil if type cannot
 310 be determined."
 311   (let (type first)
 312     (or
 313      (catch 'found
 314        (dolist (elem image-type-file-name-regexps)
 315          (when (string-match-p (car elem) file)
 316            (setq type (cdr elem))
 317            (or first (setq first type))
 318            (if (image-type-available-p type)
 319                (throw 'found type)))))
 320      ;; If nothing seems to be supported, return the first type that matched.
 321      first)))
 322
 323 ;;;###autoload
 324 (defun image-type (source &optional type data-p)
 325   "Determine and return image type.
 326 SOURCE is an image file name or image data.
 327 Optional TYPE is a symbol describing the image type.  If TYPE is omitted
 328 or nil, try to determine the image type from its first few bytes
 329 of image data.  If that doesn't work, and SOURCE is a file name,
 330 use its file extension as image type.
 331 Optional DATA-P non-nil means SOURCE is a string containing image data."
 332   (when (and (not data-p) (not (stringp source)))
 333     (error "Invalid image file name `%s'" source))
 334   (unless type
 335     (setq type (if data-p
 336                    (image-type-from-data source)
 337                  (or (image-type-from-file-header source)
 338                      (image-type-from-file-name source))))
 339     (or type (error "Cannot determine image type")))
 340   (or (memq type (and (boundp 'image-types) image-types))
 341       (error "Invalid image type `%s'" type))
 342   type)
 343
 344
 345 (if (fboundp 'image-metadata)           ; eg not --without-x
 346     (define-obsolete-function-alias 'image-extension-data
 347       'image-metadata' "24.1"))
 348
 349 (define-obsolete-variable-alias
 350     'image-library-alist
 351     'dynamic-library-alist "24.1")
 352
 353 ;;;###autoload
 354 (defun image-type-available-p (type)
 355   "Return non-nil if image type TYPE is available.
 356 Image types are symbols like `xbm' or `jpeg'."
 357   (and (fboundp 'init-image-library)
 358        (init-image-library type)))
 359
 360
 361 ;;;###autoload
 362 (defun image-type-auto-detected-p ()
 363   "Return t if the current buffer contains an auto-detectable image.
 364 This function is intended to be used from `magic-fallback-mode-alist'.
 365
 366 The buffer is considered to contain an auto-detectable image if
 367 its beginning matches an image type in `image-type-header-regexps',
 368 and that image type is present in `image-type-auto-detectable' with a
 369 non-nil value.  If that value is non-nil, but not t, then the image type
 370 must be available."
 371   (let* ((type (image-type-from-buffer))
 372          (auto (and type (cdr (assq type image-type-auto-detectable)))))
 373     (and auto
 374          (or (eq auto t) (image-type-available-p type)))))
 375
 376
 377 ;;;###autoload
 378 (defun create-image (file-or-data &optional type data-p &rest props)
 379   "Create an image.
 380 FILE-OR-DATA is an image file name or image data.
 381 Optional TYPE is a symbol describing the image type.  If TYPE is omitted
 382 or nil, try to determine the image type from its first few bytes
 383 of image data.  If that doesn't work, and FILE-OR-DATA is a file name,
 384 use its file extension as image type.
 385 Optional DATA-P non-nil means FILE-OR-DATA is a string containing image data.
 386 Optional PROPS are additional image attributes to assign to the image,
 387 like, e.g. `:mask MASK'.
 388 Value is the image created, or nil if images of type TYPE are not supported.
 389
 390 Images should not be larger than specified by `max-image-size'.
 391
 392 Image file names that are not absolute are searched for in the
 393 \"images\" sub-directory of `data-directory' and
 394 `x-bitmap-file-path' (in that order)."
 395   ;; It is x_find_image_file in image.c that sets the search path.
 396   (setq type (image-type file-or-data type data-p))
 397   (when (image-type-available-p type)
 398     (append (list 'image :type type (if data-p :data :file) file-or-data)
 399             props)))
 400
 401
 402 ;;;###autoload
 403 (defun put-image (image pos &optional string area)
 404   "Put image IMAGE in front of POS in the current buffer.
 405 IMAGE must be an image created with `create-image' or `defimage'.
 406 IMAGE is displayed by putting an overlay into the current buffer with a
 407 `before-string' STRING that has a `display' property whose value is the
 408 image.  STRING is defaulted if you omit it.
 409 The overlay created will have the `put-image' property set to t.
 410 POS may be an integer or marker.
 411 AREA is where to display the image.  AREA nil or omitted means
 412 display it in the text area, a value of `left-margin' means
 413 display it in the left marginal area, a value of `right-margin'
 414 means display it in the right marginal area."
 415   (unless string (setq string "x"))
 416   (let ((buffer (current-buffer)))
 417     (unless (eq (car-safe image) 'image)
 418       (error "Not an image: %s" image))
 419     (unless (or (null area) (memq area '(left-margin right-margin)))
 420       (error "Invalid area %s" area))
 421     (setq string (copy-sequence string))
 422     (let ((overlay (make-overlay pos pos buffer))
 423           (prop (if (null area) image (list (list 'margin area) image))))
 424       (put-text-property 0 (length string) 'display prop string)
 425       (overlay-put overlay 'put-image t)
 426       (overlay-put overlay 'before-string string)
 427       overlay)))
 428
 429
 430 ;;;###autoload
 431 (defun insert-image (image &optional string area slice)
 432   "Insert IMAGE into current buffer at point.
 433 IMAGE is displayed by inserting STRING into the current buffer
 434 with a `display' property whose value is the image.  STRING
 435 defaults to a single space if you omit it.
 436 AREA is where to display the image.  AREA nil or omitted means
 437 display it in the text area, a value of `left-margin' means
 438 display it in the left marginal area, a value of `right-margin'
 439 means display it in the right marginal area.
 440 SLICE specifies slice of IMAGE to insert.  SLICE nil or omitted
 441 means insert whole image.  SLICE is a list (X Y WIDTH HEIGHT)
 442 specifying the X and Y positions and WIDTH and HEIGHT of image area
 443 to insert.  A float value 0.0 - 1.0 means relative to the width or
 444 height of the image; integer values are taken as pixel values."
 445   ;; Use a space as least likely to cause trouble when it's a hidden
 446   ;; character in the buffer.
 447   (unless string (setq string " "))
 448   (unless (eq (car-safe image) 'image)
 449     (error "Not an image: %s" image))
 450   (unless (or (null area) (memq area '(left-margin right-margin)))
 451     (error "Invalid area %s" area))
 452   (if area
 453       (setq image (list (list 'margin area) image))
 454     ;; Cons up a new spec equal but not eq to `image' so that
 455     ;; inserting it twice in a row (adjacently) displays two copies of
 456     ;; the image.  Don't try to avoid this by looking at the display
 457     ;; properties on either side so that we DTRT more often with
 458     ;; cut-and-paste.  (Yanking killed image text next to another copy
 459     ;; of it loses anyway.)
 460     (setq image (cons 'image (cdr image))))
 461   (let ((start (point)))
 462     (insert string)
 463     (add-text-properties start (point)
 464                          `(display ,(if slice
 465                                         (list (cons 'slice slice) image)
 466                                       image) rear-nonsticky (display)))))
 467
 468
 469 ;;;###autoload
 470 (defun insert-sliced-image (image &optional string area rows cols)
 471   "Insert IMAGE into current buffer at point.
 472 IMAGE is displayed by inserting STRING into the current buffer
 473 with a `display' property whose value is the image.  The default
 474 STRING is a single space.
 475 AREA is where to display the image.  AREA nil or omitted means
 476 display it in the text area, a value of `left-margin' means
 477 display it in the left marginal area, a value of `right-margin'
 478 means display it in the right marginal area.
 479 The image is automatically split into ROWS x COLS slices."
 480   (unless string (setq string " "))
 481   (unless (eq (car-safe image) 'image)
 482     (error "Not an image: %s" image))
 483   (unless (or (null area) (memq area '(left-margin right-margin)))
 484     (error "Invalid area %s" area))
 485   (if area
 486       (setq image (list (list 'margin area) image))
 487     ;; Cons up a new spec equal but not eq to `image' so that
 488     ;; inserting it twice in a row (adjacently) displays two copies of
 489     ;; the image.  Don't try to avoid this by looking at the display
 490     ;; properties on either side so that we DTRT more often with
 491     ;; cut-and-paste.  (Yanking killed image text next to another copy
 492     ;; of it loses anyway.)
 493     (setq image (cons 'image (cdr image))))
 494   (let ((x 0.0) (dx (/ 1.0001 (or cols 1)))
 495          (y 0.0) (dy (/ 1.0001 (or rows 1))))
 496     (while (< y 1.0)
 497       (while (< x 1.0)
 498         (let ((start (point)))
 499           (insert string)
 500           (add-text-properties start (point)
 501                                `(display ,(list (list 'slice x y dx dy) image)
 502                                          rear-nonsticky (display)))
 503           (setq x (+ x dx))))
 504       (setq x 0.0
 505             y (+ y dy))
 506       (insert (propertize "\n" 'line-height t)))))
 507
 508
 509
 510 ;;;###autoload
 511 (defun remove-images (start end &optional buffer)
 512   "Remove images between START and END in BUFFER.
 513 Remove only images that were put in BUFFER with calls to `put-image'.
 514 BUFFER nil or omitted means use the current buffer."
 515   (unless buffer
 516     (setq buffer (current-buffer)))
 517   (let ((overlays (overlays-in start end)))
 518     (while overlays
 519       (let ((overlay (car overlays)))
 520         (when (overlay-get overlay 'put-image)
 521           (delete-overlay overlay)))
 522       (setq overlays (cdr overlays)))))
 523
 524 (defun image-search-load-path (file &optional path)
 525   (unless path
 526     (setq path image-load-path))
 527   (let (element found filename)
 528     (while (and (not found) (consp path))
 529       (setq element (car path))
 530       (cond
 531        ((stringp element)
 532         (setq found
 533               (file-readable-p
 534                (setq filename (expand-file-name file element)))))
 535        ((and (symbolp element) (boundp element))
 536         (setq element (symbol-value element))
 537         (cond
 538          ((stringp element)
 539           (setq found
 540                 (file-readable-p
 541                  (setq filename (expand-file-name file element)))))
 542          ((consp element)
 543           (if (setq filename (image-search-load-path file element))
 544               (setq found t))))))
 545       (setq path (cdr path)))
 546     (if found filename)))
 547
 548 ;;;###autoload
 549 (defun find-image (specs)
 550   "Find an image, choosing one of a list of image specifications.
 551
 552 SPECS is a list of image specifications.
 553
 554 Each image specification in SPECS is a property list.  The contents of
 555 a specification are image type dependent.  All specifications must at
 556 least contain the properties `:type TYPE' and either `:file FILE' or
 557 `:data DATA', where TYPE is a symbol specifying the image type,
 558 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 559 string containing the actual image data.  The specification whose TYPE
 560 is supported, and FILE exists, is used to construct the image
 561 specification to be returned.  Return nil if no specification is
 562 satisfied.
 563
 564 The image is looked for in `image-load-path'.
 565
 566 Image files should not be larger than specified by `max-image-size'."
 567   (let (image)
 568     (while (and specs (null image))
 569       (let* ((spec (car specs))
 570              (type (plist-get spec :type))
 571              (data (plist-get spec :data))
 572              (file (plist-get spec :file))
 573              found)
 574         (when (image-type-available-p type)
 575           (cond ((stringp file)
 576                  (if (setq found (image-search-load-path file))
 577                      (setq image
 578                            (cons 'image (plist-put (copy-sequence spec)
 579                                                    :file found)))))
 580                 ((not (null data))
 581                  (setq image (cons 'image spec)))))
 582         (setq specs (cdr specs))))
 583     image))
 584
 585
 586 ;;;###autoload
 587 (defmacro defimage (symbol specs &optional doc)
 588   "Define SYMBOL as an image.
 589
 590 SPECS is a list of image specifications.  DOC is an optional
 591 documentation string.
 592
 593 Each image specification in SPECS is a property list.  The contents of
 594 a specification are image type dependent.  All specifications must at
 595 least contain the properties `:type TYPE' and either `:file FILE' or
 596 `:data DATA', where TYPE is a symbol specifying the image type,
 597 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 598 string containing the actual image data.  The first image
 599 specification whose TYPE is supported, and FILE exists, is used to
 600 define SYMBOL.
 601
 602 Example:
 603
 604    (defimage test-image ((:type xpm :file \"~/test1.xpm\")
 605                          (:type xbm :file \"~/test1.xbm\")))"
 606   (declare (doc-string 3))
 607   `(defvar ,symbol (find-image ',specs) ,doc))
 608
 609 \f
 610 ;;; Animated image API
 611
 612 (defconst image-animated-types '(gif)
 613   "List of supported animated image types.")
 614
 615 (defun image-animated-p (image)
 616   "Return non-nil if IMAGE can be animated.
 617 To be capable of being animated, an image must be of a type
 618 listed in `image-animated-types', and contain more than one
 619 sub-image, with a specified animation delay.  The actual return
 620 value is a cons (NIMAGES . DELAY), where NIMAGES is the number
 621 of sub-images in the animated image and DELAY is the delay in
 622 seconds until the next sub-image should be displayed."
 623   (cond
 624    ((memq (plist-get (cdr image) :type) image-animated-types)
 625     (let* ((metadata (image-metadata image))
 626            (images (plist-get metadata 'count))
 627            (delay (plist-get metadata 'delay)))
 628       (when (and images (> images 1) (numberp delay))
 629         (if (< delay 0) (setq delay 0.1))
 630         (cons images delay))))))
 631
 632 ;; "Destructively"?
 633 (defun image-animate (image &optional index limit)
 634   "Start animating IMAGE.
 635 Animation occurs by destructively altering the IMAGE spec list.
 636
 637 With optional INDEX, begin animating from that animation frame.
 638 LIMIT specifies how long to animate the image.  If omitted or
 639 nil, play the animation until the end.  If t, loop forever.  If a
 640 number, play until that number of seconds has elapsed."
 641   (let ((animation (image-animated-p image))
 642         timer)
 643     (when animation
 644       (if (setq timer (image-animate-timer image))
 645           (cancel-timer timer))
 646       (run-with-timer 0.2 nil 'image-animate-timeout
 647                       image (or index 0) (car animation)
 648                       0 limit))))
 649
 650 (defun image-animate-timer (image)
 651   "Return the animation timer for image IMAGE."
 652   ;; See cancel-function-timers
 653   (let ((tail timer-list) timer)
 654     (while tail
 655       (setq timer (car tail)
 656             tail (cdr tail))
 657       (if (and (eq (timer--function timer) 'image-animate-timeout)
 658                (eq (car-safe (timer--args timer)) image))
 659           (setq tail nil)
 660         (setq timer nil)))
 661     timer))
 662
 663 ;; FIXME? The delay may not be the same for different sub-images,
 664 ;; hence we need to call image-animated-p to return it.
 665 ;; But it also returns count, so why do we bother passing that as an
 666 ;; argument?
 667 (defun image-animate-timeout (image n count time-elapsed limit)
 668   "Display animation frame N of IMAGE.
 669 N=0 refers to the initial animation frame.
 670 COUNT is the total number of frames in the animation.
 671 TIME-ELAPSED is the total time that has elapsed since
 672 `image-animate-start' was called.
 673 LIMIT determines when to stop.  If t, loop forever.  If nil, stop
 674  after displaying the last animation frame.  Otherwise, stop
 675  after LIMIT seconds have elapsed.
 676 The minimum delay between successive frames is 0.01s."
 677   (plist-put (cdr image) :index n)
 678   (force-window-update)
 679   (setq n (1+ n))
 680   (let* ((time (float-time))
 681          (animation (image-animated-p image))
 682          ;; Subtract off the time we took to load the image from the
 683          ;; stated delay time.
 684          (delay (max (+ (cdr animation) time (- (float-time)))
 685                      0.01))
 686          done)
 687     (if (>= n count)
 688         (if limit
 689             (setq n 0)
 690           (setq done t)))
 691     (setq time-elapsed (+ delay time-elapsed))
 692     (if (numberp limit)
 693         (setq done (>= time-elapsed limit)))
 694     (unless done
 695       (run-with-timer delay nil 'image-animate-timeout
 696                       image n count time-elapsed limit))))
 697
 698 \f
 699 (defvar imagemagick-types-inhibit)
 700 (defvar imagemagick-enabled-types)
 701
 702 (defun imagemagick-filter-types ()
 703   "Return a list of the ImageMagick types to be treated as images, or nil.
 704 This is the result of `imagemagick-types', including only elements
 705 that match `imagemagick-enabled-types' and do not match
 706 `imagemagick-types-inhibit'."
 707   (when (fboundp 'imagemagick-types)
 708     (cond ((null imagemagick-enabled-types) nil)
 709           ((eq imagemagick-types-inhibit t) nil)
 710           (t
 711            (delq nil
 712                  (mapcar
 713                   (lambda (type)
 714                     (unless (memq type imagemagick-types-inhibit)
 715                       (if (eq imagemagick-enabled-types t) type
 716                         (catch 'found
 717                           (dolist (enable imagemagick-enabled-types nil)
 718                             (if (cond ((symbolp enable) (eq enable type))
 719                                       ((stringp enable)
 720                                        (string-match enable
 721                                                      (symbol-name type))))
 722                                 (throw 'found type)))))))
 723                   (imagemagick-types)))))))
 724
 725 (defvar imagemagick--file-regexp nil
 726   "File extension regexp for ImageMagick files, if any.
 727 This is the extension installed into `auto-mode-alist' and
 728 `image-type-file-name-regexps' by `imagemagick-register-types'.")
 729
 730 ;;;###autoload
 731 (defun imagemagick-register-types ()
 732   "Register file types that can be handled by ImageMagick.
 733 This function is called at startup, after loading the init file.
 734 It registers the ImageMagick types returned by `imagemagick-filter-types'.
 735
 736 Registered image types are added to `auto-mode-alist', so that
 737 Emacs visits them in Image mode.  They are also added to
 738 `image-type-file-name-regexps', so that the `image-type' function
 739 recognizes these files as having image type `imagemagick'.
 740
 741 If Emacs is compiled without ImageMagick support, this does nothing."
 742   (when (fboundp 'imagemagick-types)
 743     (let* ((types (mapcar (lambda (type) (downcase (symbol-name type)))
 744                           (imagemagick-filter-types)))
 745            (re (if types (concat "\\." (regexp-opt types) "\\'")))
 746            (ama-elt (car (member (cons imagemagick--file-regexp 'image-mode)
 747                                  auto-mode-alist)))
 748            (itfnr-elt (car (member (cons imagemagick--file-regexp 'imagemagick)
 749                                    image-type-file-name-regexps))))
 750       (if (not re)
 751           (setq auto-mode-alist (delete ama-elt auto-mode-alist)
 752                 image-type-file-name-regexps
 753                 (delete itfnr-elt image-type-file-name-regexps))
 754         (if ama-elt
 755             (setcar ama-elt re)
 756           (push (cons re 'image-mode) auto-mode-alist))
 757         (if itfnr-elt
 758             (setcar itfnr-elt re)
 759           ;; Append to `image-type-file-name-regexps', so that we
 760           ;; preferentially use specialized image libraries.
 761           (add-to-list 'image-type-file-name-regexps
 762                        (cons re 'imagemagick) t)))
 763       (setq imagemagick--file-regexp re))))
 764
 765 (defcustom imagemagick-types-inhibit
 766   '(C HTML HTM INFO M TXT PDF)
 767   "List of ImageMagick types that should never be treated as images.
 768 This should be a list of symbols, each of which should be one of
 769 the ImageMagick types listed by `imagemagick-types'.  The listed
 770 image types are not registered by `imagemagick-register-types'.
 771
 772 If the value is t, inhibit the use of ImageMagick for images.
 773
 774 If you change this without using customize, you must call
 775 `imagemagick-register-types' afterwards.
 776
 777 If Emacs is compiled without ImageMagick support, this variable
 778 has no effect."
 779   :type '(choice (const :tag "Support all ImageMagick types" nil)
 780                  (const :tag "Disable all ImageMagick types" t)
 781                  (repeat symbol))
 782   :initialize 'custom-initialize-default
 783   :set (lambda (symbol value)
 784          (set-default symbol value)
 785          (imagemagick-register-types))
 786   :version "24.3"
 787   :group 'image)
 788
 789 (defcustom imagemagick-enabled-types
 790   '(3FR ART ARW AVS BMP BMP2 BMP3 CAL CALS CMYK CMYKA CR2 CRW
 791     CUR CUT DCM DCR DCX DDS DJVU DNG DPX EXR FAX FITS GBR GIF
 792     GIF87 GRB HRZ ICB ICO ICON J2C JNG JP2 JPC JPEG JPG JPX K25
 793     KDC MIFF MNG MRW MSL MSVG MTV NEF ORF OTB PBM PCD PCDS PCL
 794     PCT PCX PDB PEF PGM PICT PIX PJPEG PNG PNG24 PNG32 PNG8 PNM
 795     PPM PSD PTIF PWP RAF RAS RBG RGB RGBA RGBO RLA RLE SCR SCT
 796     SFW SGI SR2 SRF SUN SVG SVGZ TGA TIFF TIFF64 TILE TIM TTF
 797     UYVY VDA VICAR VID VIFF VST WBMP WPG X3F XBM XC XCF XPM XV
 798     XWD YCbCr YCbCrA YUV)
 799   "List of ImageMagick types to treat as images.
 800 Each list element should be a string or symbol, representing one
 801 of the image types returned by `imagemagick-types'.  If the
 802 element is a string, it is handled as a regexp that enables all
 803 matching types.
 804
 805 The value of `imagemagick-enabled-types' may also be t, meaning
 806 to enable all types that ImageMagick supports.
 807
 808 The variable `imagemagick-types-inhibit' overrides this variable.
 809
 810 If you change this without using customize, you must call
 811 `imagemagick-register-types' afterwards.
 812
 813 If Emacs is compiled without ImageMagick support, this variable
 814 has no effect."
 815   :type '(choice (const :tag "Support all ImageMagick types" t)
 816                  (const :tag "Disable all ImageMagick types" nil)
 817                  (repeat :tag "List of types"
 818                          (choice (symbol :tag "type")
 819                                  (regexp :tag "regexp"))))
 820   :initialize 'custom-initialize-default
 821   :set (lambda (symbol value)
 822          (set-default symbol value)
 823          (imagemagick-register-types))
 824   :version "24.3"
 825   :group 'image)
 826
 827 (imagemagick-register-types)
 828
 829 (provide 'image)
 830
 831 ;;; image.el ends here