lisp/descr-text.el

   1 ;;; descr-text.el --- describe text mode
   2
   3 ;; Copyright (C) 1994-1996, 2001-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Boris Goldowsky <boris@gnu.org>
   6 ;; Maintainer: FSF
   7 ;; Keywords: faces, i18n, Unicode, multilingual
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Describe-Text Mode.
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'quail))
  31 (require 'help-mode)
  32
  33 ;;; Describe-Text Utilities.
  34
  35 (defun describe-text-widget (widget)
  36   "Insert text to describe WIDGET in the current buffer."
  37   (insert-text-button
  38    (symbol-name (if (symbolp widget) widget (car widget)))
  39    'action `(lambda (&rest ignore)
  40               (widget-browse ',widget))
  41    'help-echo "mouse-2, RET: browse this widget")
  42   (insert " ")
  43   (insert-text-button
  44    "(widget)Top" 'type 'help-info 'help-args '("(widget)Top")))
  45
  46 (defun describe-text-sexp (sexp)
  47   "Insert a short description of SEXP in the current buffer."
  48   (let ((pp (condition-case signal
  49                 (pp-to-string sexp)
  50               (error (prin1-to-string signal)))))
  51     (when (string-match-p "\n\\'" pp)
  52       (setq pp (substring pp 0 (1- (length pp)))))
  53
  54     (if (and (not (string-match-p "\n" pp))
  55              (<= (length pp) (- (window-width) (current-column))))
  56         (insert pp)
  57       (insert-text-button
  58        "[Show]" 'action `(lambda (&rest ignore)
  59                            (with-output-to-temp-buffer
  60                                "*Pp Eval Output*"
  61                              (princ ',pp)))
  62        'help-echo "mouse-2, RET: pretty print value in another buffer"))))
  63
  64 (defun describe-property-list (properties)
  65   "Insert a description of PROPERTIES in the current buffer.
  66 PROPERTIES should be a list of overlay or text properties.
  67 The `category', `face' and `font-lock-face' properties are made
  68 into help buttons that call `describe-text-category' or
  69 `describe-face' when pushed."
  70   ;; Sort the properties by the size of their value.
  71   (dolist (elt (sort (let (ret)
  72                        (while properties
  73                          (push (list (pop properties) (pop properties)) ret))
  74                        ret)
  75                      (lambda (a b) (string< (prin1-to-string (nth 0 a) t)
  76                                             (prin1-to-string (nth 0 b) t)))))
  77     (let ((key (nth 0 elt))
  78           (value (nth 1 elt)))
  79       (insert (propertize (format "  %-20s " key)
  80                           'face 'help-argument-name))
  81       (cond ((eq key 'category)
  82              (insert-text-button
  83               (symbol-name value)
  84               'action `(lambda (&rest ignore)
  85                          (describe-text-category ',value))
  86               'follow-link t
  87               'help-echo "mouse-2, RET: describe this category"))
  88             ((memq key '(face font-lock-face mouse-face))
  89              (insert-text-button
  90               (format "%S" value)
  91               'type 'help-face 'help-args (list value)))
  92             ((widgetp value)
  93              (describe-text-widget value))
  94             (t
  95              (describe-text-sexp value))))
  96     (insert "\n")))
  97 \f
  98 ;;; Describe-Text Commands.
  99
 100 (defun describe-text-category (category)
 101   "Describe a text property category."
 102   (interactive "SCategory: ")
 103   (help-setup-xref (list #'describe-text-category category)
 104                    (called-interactively-p 'interactive))
 105   (with-help-window (help-buffer)
 106     (with-current-buffer standard-output
 107       (insert "Category " (format "%S" category) ":\n\n")
 108       (describe-property-list (symbol-plist category))
 109       (goto-char (point-min)))))
 110
 111 ;;;###autoload
 112 (defun describe-text-properties (pos &optional output-buffer buffer)
 113   "Describe widgets, buttons, overlays, and text properties at POS.
 114 POS is taken to be in BUFFER or in current buffer if nil.
 115 Interactively, describe them for the character after point.
 116 If optional second argument OUTPUT-BUFFER is non-nil,
 117 insert the output into that buffer, and don't initialize or clear it
 118 otherwise."
 119   (interactive "d")
 120   (let ((src-buf (current-buffer)))
 121     (if buffer (set-buffer buffer) (setq buffer (current-buffer)))
 122   (if (>= pos (point-max))
 123       (error "No character follows specified position"))
 124   (if output-buffer
 125       (describe-text-properties-1 pos output-buffer)
 126     (if (not (or (text-properties-at pos) (overlays-at pos)))
 127         (message "This is plain text.")
 128         (with-temp-buffer
 129             (setq output-buffer (current-buffer))
 130             (insert "Text content at position " (format "%d" pos) ":\n\n")
 131           (set-buffer buffer)
 132           (describe-text-properties-1 pos output-buffer)
 133           (set-buffer src-buf)
 134           (help-setup-xref (list 'describe-text-properties pos nil buffer)
 135                            (called-interactively-p 'interactive))
 136           (with-help-window (help-buffer)
 137             (with-current-buffer standard-output
 138               (buffer-swap-text output-buffer)
 139               (goto-char (point-min)))))))))
 140
 141 (defun describe-text-properties-1 (pos output-buffer)
 142   (let* ((properties (text-properties-at pos))
 143          (overlays (overlays-at pos))
 144          (wid-field (get-char-property pos 'field))
 145          (wid-button (get-char-property pos 'button))
 146          (wid-doc (get-char-property pos 'widget-doc))
 147          ;; If button.el is not loaded, we have no buttons in the text.
 148          (button (and (fboundp 'button-at) (button-at pos)))
 149          (button-type (and button (button-type button)))
 150          (button-label (and button (button-label button)))
 151          (widget (or wid-field wid-button wid-doc)))
 152     (with-current-buffer output-buffer
 153       ;; Widgets
 154       (when (widgetp widget)
 155         (newline)
 156         (insert (cond (wid-field "This is an editable text area")
 157                       (wid-button "This is an active area")
 158                       (wid-doc "This is documentation text")))
 159         (insert " of a ")
 160         (describe-text-widget widget)
 161         (insert ".\n\n"))
 162       ;; Buttons
 163       (when (and button (not (widgetp wid-button)))
 164         (newline)
 165         (insert "Here is a `" (format "%S" button-type)
 166                 "' button labeled `" button-label "'.\n\n"))
 167       ;; Overlays
 168       (when overlays
 169         (newline)
 170         (if (eq (length overlays) 1)
 171             (insert "There is an overlay here:\n")
 172           (insert "There are " (format "%d" (length overlays))
 173                          " overlays here:\n"))
 174         (dolist (overlay overlays)
 175           (insert " From " (format "%d" (overlay-start overlay))
 176                          " to " (format "%d" (overlay-end overlay)) "\n")
 177           (describe-property-list (overlay-properties overlay)))
 178         (insert "\n"))
 179       ;; Text properties
 180       (when properties
 181         (newline)
 182         (insert "There are text properties here:\n")
 183         (describe-property-list properties)))))
 184 \f
 185 (defcustom describe-char-unidata-list
 186   '(name old-name general-category decomposition)
 187   "List of Unicode-based character property names shown by `describe-char'."
 188   :group 'mule
 189   :version "23.1"
 190   :type '(choice (const :tag "All properties" t)
 191           (set
 192            (const :tag "Unicode name" name)
 193            (const :tag "Unicode old name" old-name)
 194            (const :tag "Unicode general category " general-category)
 195            (const :tag "Unicode canonical combining class"
 196                   canonical-combining-class)
 197            (const :tag "Unicode bidi class" bidi-class)
 198            (const :tag "Unicode decomposition mapping" decomposition)
 199            (const :tag "Unicode decimal digit value" decimal-digit-value)
 200            (const :tag "Unicode digit value" digit-value)
 201            (const :tag "Unicode numeric value" numeric-value)
 202            (const :tag "Unicode mirrored" mirrored)
 203            (const :tag "Unicode ISO 10646 comment" iso-10646-comment)
 204            (const :tag "Unicode simple uppercase mapping" uppercase)
 205            (const :tag "Unicode simple lowercase mapping" lowercase)
 206            (const :tag "Unicode simple titlecase mapping" titlecase))))
 207
 208 (defcustom describe-char-unicodedata-file nil
 209   "Location of Unicode data file.
 210 This is the UnicodeData.txt file from the Unicode Consortium, used for
 211 diagnostics.  If it is non-nil `describe-char' will print data
 212 looked up from it.  This facility is mostly of use to people doing
 213 multilingual development.
 214
 215 This is a fairly large file, not typically present on GNU systems.
 216 At the time of writing it is at the URL
 217 `http://www.unicode.org/Public/UNIDATA/UnicodeData.txt'."
 218   :group 'mule
 219   :version "22.1"
 220   :type '(choice (const :tag "None" nil)
 221                  file))
 222
 223 (defun describe-char-unicode-data (char)
 224   "Return a list of Unicode data for unicode CHAR.
 225 Each element is a list of a property description and the property value.
 226 The list is null if CHAR isn't found in `describe-char-unicodedata-file'.
 227 This function is semi-obsolete.  Use `get-char-code-property'."
 228   (when describe-char-unicodedata-file
 229     (unless (file-exists-p describe-char-unicodedata-file)
 230       (error "`unicodedata-file' %s not found" describe-char-unicodedata-file))
 231     (with-current-buffer (get-buffer-create " *Unicode Data*")
 232       (when (zerop (buffer-size))
 233         ;; Don't use -literally in case of DOS line endings.
 234         (insert-file-contents describe-char-unicodedata-file))
 235       (goto-char (point-min))
 236       (let ((hex (format "%04X" char))
 237             found first last)
 238         (if (re-search-forward (concat "^" hex) nil t)
 239             (setq found t)
 240           ;; It's not listed explicitly.  Look for ranges, e.g. CJK
 241           ;; ideographs, and check whether it's in one of them.
 242           (while (and (re-search-forward "^\\([^;]+\\);[^;]+First>;" nil t)
 243                       (>= char (setq first
 244                                      (string-to-number (match-string 1) 16)))
 245                       (progn
 246                         (forward-line 1)
 247                         (looking-at "^\\([^;]+\\);[^;]+Last>;")
 248                         (> char
 249                            (setq last
 250                                  (string-to-number (match-string 1) 16))))))
 251           (if (and (>= char first)
 252                    (<= char last))
 253               (setq found t)))
 254         (if found
 255             (let ((fields (mapcar (lambda (elt)
 256                                     (if (> (length elt) 0)
 257                                         elt))
 258                                   (cdr (split-string
 259                                         (buffer-substring
 260                                          (line-beginning-position)
 261                                          (line-end-position))
 262                                         ";")))))
 263               ;; The length depends on whether the last field was empty.
 264               (unless (or (= 13 (length fields))
 265                           (= 14 (length fields)))
 266                 (error "Invalid contents in %s" describe-char-unicodedata-file))
 267               ;; The field names and values lists are slightly
 268               ;; modified from Mule-UCS unidata.el.
 269               (list
 270                (list "Name" (let ((name (nth 0 fields)))
 271                               ;; Check for <..., First>, <..., Last>
 272                               (if (string-match "\\`\\(<[^,]+\\)," name)
 273                                   (concat (match-string 1 name) ">")
 274                                 name)))
 275                (list "Category"
 276                      (let ((val (nth 1 fields)))
 277                        (or (char-code-property-description
 278                             'general-category (intern val))
 279                            val)))
 280                (list "Combining class"
 281                      (let ((val (nth 1 fields)))
 282                        (or (char-code-property-description
 283                             'canonical-combining-class (intern val))
 284                            val)))
 285                (list "Bidi category"
 286                      (let ((val (nth 1 fields)))
 287                        (or (char-code-property-description
 288                             'bidi-class (intern val))
 289                            val)))
 290                (list
 291                 "Decomposition"
 292                 (if (nth 4 fields)
 293                     (let* ((parts (split-string (nth 4 fields)))
 294                            (info (car parts)))
 295                       (if (string-match "\\`<\\(.+\\)>\\'" info)
 296                           (setq info (match-string 1 info))
 297                         (setq info nil))
 298                       (if info (setq parts (cdr parts)))
 299                       (setq parts (mapconcat
 300                                    (lambda (arg)
 301                                      (string (string-to-number arg 16)))
 302                                    parts " "))
 303                       (concat info (if info " ") parts))))
 304                (list "Decimal digit value"
 305                      (nth 5 fields))
 306                (list "Digit value"
 307                      (nth 6 fields))
 308                (list "Numeric value"
 309                      (nth 7 fields))
 310                (list "Mirrored"
 311                      (if (equal "Y" (nth 8 fields))
 312                          "yes"))
 313                (list "Old name" (nth 9 fields))
 314                (list "ISO 10646 comment" (nth 10 fields))
 315                (list "Uppercase" (and (nth 11 fields)
 316                                       (string (string-to-number
 317                                                (nth 11 fields) 16))))
 318                (list "Lowercase" (and (nth 12 fields)
 319                                       (string (string-to-number
 320                                                (nth 12 fields) 16))))
 321                (list "Titlecase" (and (nth 13 fields)
 322                                       (string (string-to-number
 323                                                (nth 13 fields) 16)))))))))))
 324
 325 ;; Not defined on builds without X, but behind display-graphic-p.
 326 (declare-function internal-char-font "fontset.c" (position &optional ch))
 327
 328 ;; Return information about how CHAR is displayed at the buffer
 329 ;; position POS.  If the selected frame is on a graphic display,
 330 ;; return a string "FONT-DRIVER:FONT-NAME (GLYPH-CODE)" where:
 331 ;;   FONT-DRIVER is the font-driver name,
 332 ;;   FONT-NAME is the font name,
 333 ;;   GLYPH-CODE is a hexadigit string representing the glyph-ID.
 334 ;; Otherwise, return a string describing the terminal codes for the
 335 ;; character.
 336 (defun describe-char-display (pos char)
 337   (if (display-graphic-p (selected-frame))
 338       (let ((char-font-info (internal-char-font pos char)))
 339         (if char-font-info
 340             (let ((type (font-get (car char-font-info) :type))
 341                   (name (font-xlfd-name (car char-font-info)))
 342                   (code (cdr char-font-info)))
 343                (if (integerp code)
 344                    (format "%s:%s (#x%02X)" type name code)
 345                  (format "%s:%s (#x%04X%04X)"
 346                          type name (car code) (cdr code))))))
 347     (let* ((charset (get-text-property pos 'charset))
 348            (coding (or (terminal-coding-system) 'us-ascii))
 349            (encoded (encode-coding-char char coding charset)))
 350       (if encoded
 351           (encoded-string-description encoded coding)))))
 352
 353 \f
 354 ;; Return a string of CH with composition for padding on both sides.
 355 ;; It is displayed without overlapping with the left/right columns.
 356 (defsubst describe-char-padded-string (ch)
 357   (if (internal-char-font nil ch)
 358       (compose-string (string ch) 0 1 (format "\t%c\t" ch))
 359     (string ch)))
 360
 361 ;; Return a nicely formated list of categories; extended category
 362 ;; description is added to the category name as a tooltip
 363 (defsubst describe-char-categories (category-set)
 364   (let ((mnemonics (category-set-mnemonics category-set)))
 365     (unless (eq mnemonics "")
 366       (list (mapconcat
 367              (lambda (x)
 368                (let* ((c (category-docstring x))
 369                       (doc (if (string-match "\\`\\(.*?\\)\n\\(.*\\)\\'" c)
 370                                (propertize (match-string 1 c)
 371                                            'help-echo (match-string 2 c))
 372                              c)))
 373                  (format "%c:%s" x doc)))
 374              mnemonics ", ")))))
 375
 376 ;;;###autoload
 377 (defun describe-char (pos &optional buffer)
 378   "Describe the character after POS (interactively, the character after point).
 379 Is POS is taken to be in buffer BUFFER or current buffer if nil.
 380 The information includes character code, charset and code points in it,
 381 syntax, category, how the character is encoded in a file,
 382 character composition information (if relevant),
 383 as well as widgets, buttons, overlays, and text properties."
 384   (interactive "d")
 385   (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 386   (let ((src-buf (current-buffer)))
 387     (set-buffer buffer)
 388     (if (>= pos (point-max))
 389         (error "No character follows specified position"))
 390     (let* ((char (char-after pos))
 391            (eight-bit-p (and (not enable-multibyte-characters) (>= char 128)))
 392            (charset (if eight-bit-p 'eight-bit
 393                       (or (get-text-property pos 'charset)
 394                           (char-charset char))))
 395            (composition (find-composition pos nil nil t))
 396            (component-chars nil)
 397            (display-table (or (window-display-table)
 398                               buffer-display-table
 399                               standard-display-table))
 400            (disp-vector (and display-table (aref display-table char)))
 401            (multibyte-p enable-multibyte-characters)
 402            (overlays (mapcar (lambda (o) (overlay-properties o))
 403                              (overlays-at pos)))
 404            (char-description (if (not multibyte-p)
 405                                  (single-key-description char)
 406                                (if (< char 128)
 407                                    (single-key-description char)
 408                                  (string-to-multibyte
 409                                   (char-to-string char)))))
 410            (text-props-desc
 411             (let ((tmp-buf (generate-new-buffer " *text-props*")))
 412               (unwind-protect
 413                   (progn
 414                     (describe-text-properties pos tmp-buf)
 415                     (with-current-buffer tmp-buf (buffer-string)))
 416                 (kill-buffer tmp-buf))))
 417            item-list max-width code)
 418
 419       (if multibyte-p
 420           (or (setq code (encode-char char charset))
 421               (setq charset (char-charset char)
 422                     code (encode-char char charset)))
 423         (setq code char))
 424       (when composition
 425         ;; When the composition is trivial (i.e. composed only with the
 426         ;; current character itself without any alternate characters),
 427         ;; we don't show the composition information.  Otherwise, store
 428         ;; two descriptive strings in the first two elements of
 429         ;; COMPOSITION.
 430         (or (catch 'tag
 431               (let ((from (car composition))
 432                     (to (nth 1 composition))
 433                     (components (nth 2 composition))
 434                     ch)
 435                 (if (and (vectorp components) (vectorp (aref components 0)))
 436                     (let ((idx (- pos from))
 437                           (nglyphs (lgstring-glyph-len components))
 438                           (i 0) j glyph glyph-from)
 439                       ;; COMPONENTS is a gstring.  Find a grapheme
 440                       ;; cluster containing the current character.
 441                       (while (and (< i nglyphs)
 442                                   (setq glyph (lgstring-glyph components i))
 443                                   (< (lglyph-to glyph) idx))
 444                         (setq i (1+ i)))
 445                       (if (or (not glyph) (= i nglyphs))
 446                           ;; The composition is broken.
 447                           (throw 'tag nil))
 448                       (setq glyph-from (lglyph-from glyph)
 449                             to (+ from (lglyph-to glyph) 1)
 450                             from (+ from glyph-from)
 451                             j i)
 452                       (while (and (< j nglyphs)
 453                                   (setq glyph (lgstring-glyph components j))
 454                                   (= (lglyph-from glyph) glyph-from))
 455                         (setq j (1+ j)))
 456                       (if (and (= to (1+ from))
 457                                (= i (1- j))
 458                                (setq glyph (lgstring-glyph components i))
 459                                (= char (lglyph-char glyph)))
 460                           ;; The composition is trivial.
 461                           (throw 'tag nil))
 462                       (nconc composition (list i (1- j))))
 463                   (dotimes (i (length components))
 464                     (if (integerp (setq ch (aref components i)))
 465                         (push (cons ch (describe-char-display pos ch))
 466                               component-chars)))
 467                   (setq component-chars (nreverse component-chars)))
 468                 (if (< from pos)
 469                     (if (< (1+ pos) to)
 470                         (setcar composition
 471                                 (concat
 472                                  " with the surrounding characters \""
 473                                  (mapconcat 'describe-char-padded-string
 474                                             (buffer-substring from pos) "")
 475                                  "\" and \""
 476                                  (mapconcat 'describe-char-padded-string
 477                                             (buffer-substring (1+ pos) to) "")
 478                                  "\""))
 479                       (setcar composition
 480                               (concat
 481                                " with the preceding character(s) \""
 482                                (mapconcat 'describe-char-padded-string
 483                                           (buffer-substring from pos) "")
 484                                "\"")))
 485                   (if (< (1+ pos) to)
 486                       (setcar composition
 487                               (concat
 488                                " with the following character(s) \""
 489                                (mapconcat 'describe-char-padded-string
 490                                           (buffer-substring (1+ pos) to) "")
 491                                "\""))
 492                     (setcar composition nil)))
 493                 (setcar (cdr composition)
 494                         (format "composed to form \"%s\" (see below)"
 495                                 (buffer-substring from to)))))
 496             (setq composition nil)))
 497
 498       (setq item-list
 499             `(("character"
 500                ,(format "%s (%d, #o%o, #x%x)"
 501                         (apply 'propertize char-description
 502                                (text-properties-at pos))
 503                         char char char))
 504               ("preferred charset"
 505                ,`(insert-text-button
 506                   ,(symbol-name charset)
 507                   'type 'help-character-set 'help-args '(,charset))
 508                ,(format "(%s)" (charset-description charset)))
 509               ("code point"
 510                ,(let ((str (if (integerp code)
 511                                (format (if (< code 256) "0x%02X" "0x%04X")
 512                                        code)
 513                              (format "0x%04X%04X" (car code) (cdr code)))))
 514                   (if (<= (charset-dimension charset) 2)
 515                       `(insert-text-button
 516                         ,str
 517                         'action (lambda (&rest ignore)
 518                                   (list-charset-chars ',charset)
 519                                   (with-selected-window
 520                                       (get-buffer-window "*Character List*" 0)
 521                                     (goto-char (point-min))
 522                                     (forward-line 2) ;Skip the header.
 523                                     (let ((case-fold-search nil))
 524                                       (if (search-forward
 525                                            ,(char-to-string char) nil t)
 526                                           (goto-char (match-beginning 0))))))
 527                         'follow-link t
 528                         'help-echo
 529                         "mouse-2, RET: show this character in its character set")
 530                     str)))
 531               ("syntax"
 532                ,(let ((syntax (syntax-after pos)))
 533                   (with-temp-buffer
 534                     (internal-describe-syntax-value syntax)
 535                     (buffer-string))))
 536               ("category"
 537                ,@(if (not eight-bit-p)
 538                      (let ((category-set (char-category-set char)))
 539                        (if category-set
 540                            (describe-char-categories category-set)
 541                          '("-- none --")))))
 542               ("to input"
 543                ,@(if (not eight-bit-p)
 544                      (let ((key-list (and (eq input-method-function
 545                                               'quail-input-method)
 546                                           (quail-find-key char))))
 547                        (if (consp key-list)
 548                            (list "type"
 549                                  (concat "\""
 550                                          (mapconcat 'identity
 551                                                     key-list "\" or \"")
 552                                          "\"")
 553                                  "with"
 554                                  `(insert-text-button
 555                                    ,current-input-method
 556                                    'type 'help-input-method
 557                                    'help-args '(,current-input-method)))))))
 558               ("buffer code"
 559                ,(if multibyte-p
 560                     (encoded-string-description
 561                      (string-as-unibyte (char-to-string char)) nil)
 562                   (format "#x%02X" char)))
 563               ("file code"
 564                ,@(if multibyte-p
 565                      (let* ((coding buffer-file-coding-system)
 566                             (encoded (encode-coding-char char coding charset)))
 567                        (if encoded
 568                            (list (encoded-string-description encoded coding)
 569                                  (format "(encoded by coding system %S)"
 570                                          coding))
 571                          (list "not encodable by coding system"
 572                                (symbol-name coding))))
 573                    (list (format "#x%02X" char))))
 574               ("display"
 575                ,(cond
 576                  (disp-vector
 577                   (setq disp-vector (copy-sequence disp-vector))
 578                   (dotimes (i (length disp-vector))
 579                     (aset disp-vector i
 580                           (cons (aref disp-vector i)
 581                                 (describe-char-display
 582                                  pos (glyph-char (aref disp-vector i))))))
 583                   (format "by display table entry [%s] (see below)"
 584                           (mapconcat
 585                            (lambda (x)
 586                              (format "?%c" (glyph-char (car x))))
 587                            disp-vector " ")))
 588                  (composition
 589                   (cadr composition))
 590                  (t
 591                   (let ((display (describe-char-display pos char)))
 592                     (if (display-graphic-p (selected-frame))
 593                         (if display
 594                             (concat "by this font (glyph code)\n    " display)
 595                           "no font available")
 596                       (if display
 597                           (format "terminal code %s" display)
 598                         "not encodable for terminal"))))))
 599               ,@(let ((face
 600                        (if (not (or disp-vector composition))
 601                            (cond
 602                             ((and show-trailing-whitespace
 603                                   (save-excursion (goto-char pos)
 604                                                   (looking-at-p "[ \t]+$")))
 605                              'trailing-whitespace)
 606                             ((and nobreak-char-display char (eq char '#xa0))
 607                              'nobreak-space)
 608                             ((and nobreak-char-display char (eq char '#xad))
 609                              'escape-glyph)
 610                             ((and (< char 32) (not (memq char '(9 10))))
 611                              'escape-glyph)))))
 612                   (if face (list (list "hardcoded face"
 613                                        `(insert-text-button
 614                                          ,(symbol-name face)
 615                                          'type 'help-face
 616                                          'help-args '(,face))))))
 617               ,@(if (not eight-bit-p)
 618                     (let ((unicodedata (describe-char-unicode-data char)))
 619                       (if unicodedata
 620                           (cons (list "Unicode data" "") unicodedata))))))
 621       (setq max-width (apply 'max (mapcar (lambda (x)
 622                                             (if (cadr x) (length (car x)) 0))
 623                                           item-list)))
 624       (set-buffer src-buf)
 625       (help-setup-xref (list 'describe-char pos buffer)
 626                        (called-interactively-p 'interactive))
 627       (with-help-window (help-buffer)
 628         (with-current-buffer standard-output
 629           (set-buffer-multibyte multibyte-p)
 630           (let ((formatter (format "%%%ds:" max-width)))
 631             (dolist (elt item-list)
 632               (when (cadr elt)
 633                 (insert (format formatter (car elt)))
 634                 (dolist (clm (cdr elt))
 635                   (if (eq (car-safe clm) 'insert-text-button)
 636                       (progn (insert " ") (eval clm))
 637                     (when (>= (+ (current-column)
 638                                  (or (string-match-p "\n" clm)
 639                                      (string-width clm))
 640                                  1)
 641                               (window-width))
 642                       (insert "\n")
 643                       (indent-to (1+ max-width)))
 644                     (unless (zerop (length clm))
 645                       (insert " " clm))))
 646                 (insert "\n"))))
 647
 648           (when overlays
 649             (save-excursion
 650               (goto-char (point-min))
 651               (re-search-forward "character:[ \t\n]+")
 652               (let ((end (+ (point) (length char-description))))
 653                 (mapc (lambda (props)
 654                         (let ((o (make-overlay (point) end)))
 655                           (while props
 656                             (overlay-put o (car props) (nth 1 props))
 657                             (setq props (cddr props)))))
 658                       overlays))))
 659
 660           (when disp-vector
 661             (insert
 662              "\nThe display table entry is displayed by ")
 663             (if (display-graphic-p (selected-frame))
 664                 (progn
 665                   (insert "these fonts (glyph codes):\n")
 666                   (dotimes (i (length disp-vector))
 667                     (insert (glyph-char (car (aref disp-vector i))) ?:
 668                             (propertize " " 'display '(space :align-to 5))
 669                             (or (cdr (aref disp-vector i)) "-- no font --")
 670                             "\n")
 671                     (let ((face (glyph-face (car (aref disp-vector i)))))
 672                       (when face
 673                         (insert (propertize " " 'display '(space :align-to 5))
 674                                 "face: ")
 675                         (insert (concat "`" (symbol-name face) "'"))
 676                         (insert "\n")))))
 677               (insert "these terminal codes:\n")
 678               (dotimes (i (length disp-vector))
 679                 (insert (car (aref disp-vector i))
 680                         (propertize " " 'display '(space :align-to 5))
 681                         (or (cdr (aref disp-vector i)) "-- not encodable --")
 682                         "\n"))))
 683
 684           (when composition
 685             (insert "\nComposed")
 686             (if (car composition)
 687                 (insert (car composition)))
 688             (if (and (vectorp (nth 2 composition))
 689                      (vectorp (aref (nth 2 composition) 0)))
 690                 (let* ((gstring (nth 2 composition))
 691                        (font (lgstring-font gstring))
 692                        (from (nth 3 composition))
 693                        (to (nth 4 composition))
 694                        glyph)
 695                   (if (fontp font)
 696                       (progn
 697                         (insert " using this font:\n  "
 698                                 (symbol-name (font-get font :type))
 699                                 ?:
 700                                 (aref (query-font font) 0)
 701                                 "\nby these glyphs:\n")
 702                         (while (and (<= from to)
 703                                     (setq glyph (lgstring-glyph gstring from)))
 704                           (insert (format "  %S\n" glyph))
 705                           (setq from (1+ from))))
 706                     (insert " by these characters:\n")
 707                     (while (and (<= from to)
 708                                 (setq glyph (lgstring-glyph gstring from)))
 709                       (insert (format " %c (#x%d)\n"
 710                                       (lglyph-char glyph) (lglyph-char glyph)))
 711                       (setq from (1+ from)))))
 712               (insert " by the rule:\n\t(")
 713               (let ((first t))
 714                 (mapc (lambda (x)
 715                         (if first (setq first nil)
 716                           (insert " "))
 717                         (if (consp x) (insert (format "%S" x))
 718                           (if (= x ?\t) (insert (single-key-description x))
 719                             (insert ??)
 720                             (insert (describe-char-padded-string x)))))
 721                       (nth 2 composition)))
 722               (insert  ")\nThe component character(s) are displayed by ")
 723               (if (display-graphic-p (selected-frame))
 724                   (progn
 725                     (insert "these fonts (glyph codes):")
 726                     (dolist (elt component-chars)
 727                       (if (/= (car elt) ?\t)
 728                           (insert "\n "
 729                                   (describe-char-padded-string (car elt))
 730                                   ?:
 731                                   (propertize " "
 732                                               'display '(space :align-to 5))
 733                                   (or (cdr elt) "-- no font --")))))
 734                 (insert "these terminal codes:")
 735                 (dolist (elt component-chars)
 736                   (insert "\n  " (car elt) ":"
 737                           (propertize " " 'display '(space :align-to 4))
 738                           (or (cdr elt) "-- not encodable --"))))
 739               (insert "\nSee the variable `reference-point-alist' for "
 740                       "the meaning of the rule.\n")))
 741
 742           (unless eight-bit-p
 743             (insert (if (not describe-char-unidata-list)
 744                         "\nCharacter code properties are not shown: "
 745                       "\nCharacter code properties: "))
 746             (insert-text-button
 747              "customize what to show"
 748              'action (lambda (&rest _ignore)
 749                        (customize-variable
 750                         'describe-char-unidata-list))
 751              'follow-link t)
 752             (insert "\n")
 753             (dolist (elt (if (eq describe-char-unidata-list t)
 754                              (nreverse (mapcar 'car char-code-property-alist))
 755                            describe-char-unidata-list))
 756               (let ((val (get-char-code-property char elt))
 757                     description)
 758                 (when val
 759                   (setq description (char-code-property-description elt val))
 760                   (insert (if description
 761                               (format "  %s: %s (%s)\n" elt val description)
 762                             (format "  %s: %s\n" elt val)))))))
 763
 764           (if text-props-desc (insert text-props-desc))
 765           (toggle-read-only 1))))))
 766
 767 (define-obsolete-function-alias 'describe-char-after 'describe-char "22.1")
 768
 769 (provide 'descr-text)
 770
 771 ;;; descr-text.el ends here