configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.2.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 dnl Fairly arbitrary, older versions might work too.
  30 AM_INIT_AUTOMAKE(1.11)
  31
  32 dnl Support for --program-prefix, --program-suffix and
  33 dnl --program-transform-name options
  34 AC_ARG_PROGRAM
  35
  36 dnl It is important that variables on the RHS not be expanded here,
  37 dnl hence the single quotes.  This is per the GNU coding standards, see
  38 dnl (autoconf) Installation Directory Variables
  39 dnl See also epaths.h below.
  40 lispdir='${datadir}/emacs/${version}/lisp'
  41 leimdir='${datadir}/emacs/${version}/leim'
  42 standardlisppath='${lispdir}:${leimdir}'
  43 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  44 '${datadir}/emacs/site-lisp'
  45 lisppath='${locallisppath}:${standardlisppath}'
  46 etcdir='${datadir}/emacs/${version}/etc'
  47 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  48 docdir='${datadir}/emacs/${version}/etc'
  49 gamedir='${localstatedir}/games/emacs'
  50
  51 dnl Special option to disable the most of other options.
  52 AC_ARG_WITH(all,
  53 [AS_HELP_STRING([--without-all],
  54                 [omit almost all features and build
  55                 small executable with minimal dependencies])],
  56   with_features=$withval,
  57   with_features=yes)
  58
  59 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  60 dnl Create a new --with option that defaults to being disabled.
  61 dnl NAME is the base name of the option.  The shell variable with_NAME
  62 dnl   will be set to either the user's value (if the option is
  63 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  64 dnl   option is not specified).  Note that the shell variable name is
  65 dnl   constructed as autoconf does, by replacing non-alphanumeric
  66 dnl   characters with "_".
  67 dnl HELP-STRING is the help text for the option.
  68 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  69   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  70     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  71 ])dnl
  72
  73 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  74 dnl Create a new --with option that defaults to $enable_features.
  75 dnl NAME is the base name of the option.  The shell variable with_NAME
  76 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  77 dnl   'yes' (if the option is not specified).  Note that the shell
  78 dnl   variable name is constructed as autoconf does, by replacing
  79 dnl   non-alphanumeric characters with "_".
  80 dnl HELP-STRING is the help text for the option.
  81 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  82   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  83    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
  84 ])dnl
  85
  86 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  87 if test "$with_pop" = yes; then
  88    AC_DEFINE(MAIL_USE_POP)
  89 fi
  90 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  91
  92 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  93 if test "$with_kerberos" != no; then
  94    AC_DEFINE(KERBEROS)
  95 fi
  96 AH_TEMPLATE(KERBEROS,
  97             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  98
  99 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 100 if test "${with_kerberos5}" != no; then
 101   if test "${with_kerberos}" = no; then
 102     with_kerberos=yes
 103     AC_DEFINE(KERBEROS)
 104   fi
 105   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 106 fi
 107
 108 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 109 dnl FIXME hesiod support may not be present, so it seems like an error
 110 dnl to define, or at least use, this unconditionally.
 111 if test "$with_hesiod" != no; then
 112   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 113 fi
 114
 115 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 116 if test "$with_mmdf" != no; then
 117    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 118 fi
 119
 120 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 121 if test "$with_mail_unlink" != no; then
 122    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 123 fi
 124
 125 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 126     [string giving default POP mail host])],
 127     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 128
 129 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 130
 131 OPTION_DEFAULT_ON([sync-input],[don't process async input synchronously])
 132 if test "$with_sync_input" = yes; then
 133    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 134 fi
 135
 136 dnl FIXME currently it is not the last.
 137 dnl This should be the last --with option, because --with-x is
 138 dnl added later on when we find the path of X, and it's best to
 139 dnl keep them together visually.
 140 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 141  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 142 [         case "${withval}" in
 143             y | ye | yes )      val=gtk ;;
 144             n | no )            val=no  ;;
 145             l | lu | luc | luci | lucid )       val=lucid ;;
 146             a | at | ath | athe | athen | athena )      val=athena ;;
 147             m | mo | mot | moti | motif )       val=motif ;;
 148             g | gt | gtk  )     val=gtk ;;
 149             gtk2  )     val=gtk2 ;;
 150             gtk3  )     val=gtk3 ;;
 151             * )
 152 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 153 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 154 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 155 `athena' and `lucid' are synonyms.])
 156             ;;
 157           esac
 158           with_x_toolkit=$val
 159 ])
 160
 161 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 162 if test "$with_wide_int" = yes; then
 163   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 164 fi
 165
 166 dnl _ON results in a '--without' option in the --help output, so
 167 dnl the help text should refer to "don't compile", etc.
 168 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 169 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 170 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 171 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 172 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 173 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 174 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 175 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 176
 177 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 178 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 179 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 180
 181 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 182 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 183 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 184 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 185
 186 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 187 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 188 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 189 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 190 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 191 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 192
 193 ## For the times when you want to build Emacs but don't have
 194 ## a suitable makeinfo, and can live without the manuals.
 195 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 196 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 197
 198 ## Makefile.in needs the cache file name.
 199 AC_SUBST(cache_file)
 200
 201 ## This is an option because I do not know if all info/man support
 202 ## compressed files, nor how to test if they do so.
 203 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 204 if test $with_compress_info = yes; then
 205    GZIP_INFO=yes
 206 else
 207    GZIP_INFO=
 208 fi
 209 AC_SUBST(GZIP_INFO)
 210
 211 AC_ARG_WITH([pkg-config-prog],dnl
 212 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 213                   [path to pkg-config for finding GTK and librsvg])])
 214 if test "X${with_pkg_config_prog}" != X; then
 215    if test "${with_pkg_config_prog}" != yes; then
 216       PKG_CONFIG="${with_pkg_config_prog}"
 217    fi
 218 fi
 219
 220 CRT_DIR=
 221 AC_ARG_WITH([crt-dir],dnl
 222 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 223 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 224 CRT_DIR="${with_crt_dir}"
 225
 226 AC_ARG_WITH(gameuser,dnl
 227 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 228 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 229   && gameuser="${with_gameuser}"
 230 test "X$gameuser" = X && gameuser=games
 231
 232 AC_ARG_WITH([gnustep-conf],dnl
 233 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 234 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 235   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 236 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 237      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 238
 239 AC_ARG_ENABLE(ns-self-contained,
 240 [AS_HELP_STRING([--disable-ns-self-contained],
 241                 [disable self contained build under NeXTstep])],
 242    EN_NS_SELF_CONTAINED=$enableval,
 243    EN_NS_SELF_CONTAINED=yes)
 244
 245 AC_ARG_ENABLE(locallisppath,
 246 [AS_HELP_STRING([--enable-locallisppath=PATH],
 247                 [directories Emacs should search for lisp files specific
 248                  to this site])],
 249 if test "${enableval}" = "no"; then
 250   locallisppath=
 251 elif test "${enableval}" != "yes"; then
 252   locallisppath=${enableval}
 253 fi)
 254
 255 AC_ARG_ENABLE(checking,
 256 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 257                 [enable expensive run-time checks.  With LIST,
 258                  enable only specific categories of checks.
 259                  Categories are: all,yes,no.
 260                  Flags are: stringbytes, stringoverrun, stringfreelist,
 261                  xmallocoverrun, conslist, glyphs])],
 262 [ac_checking_flags="${enableval}"],[])
 263 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 264 for check in $ac_checking_flags
 265 do
 266         case $check in
 267         # these set all the flags to specific states
 268         yes)            ac_enable_checking=1 ;;
 269         no)             ac_enable_checking= ;
 270                         ac_gc_check_stringbytes= ;
 271                         ac_gc_check_string_overrun= ;
 272                         ac_gc_check_string_free_list= ;
 273                         ac_xmalloc_overrun= ;
 274                         ac_gc_check_cons_list= ;
 275                         ac_glyphs_debug= ;;
 276         all)            ac_enable_checking=1 ;
 277                         ac_gc_check_stringbytes=1 ;
 278                         ac_gc_check_string_overrun=1 ;
 279                         ac_gc_check_string_free_list=1 ;
 280                         ac_xmalloc_overrun=1 ;
 281                         ac_gc_check_cons_list=1 ;
 282                         ac_glyphs_debug=1 ;;
 283         # these enable particular checks
 284         stringbytes)    ac_gc_check_stringbytes=1 ;;
 285         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 286         stringfreelist) ac_gc_check_string_free_list=1 ;;
 287         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 288         conslist)       ac_gc_check_cons_list=1 ;;
 289         glyphs)         ac_glyphs_debug=1 ;;
 290         *)      AC_MSG_ERROR(unknown check category $check) ;;
 291         esac
 292 done
 293 IFS="$ac_save_IFS"
 294
 295 if test x$ac_enable_checking != x ; then
 296   AC_DEFINE(ENABLE_CHECKING, 1,
 297 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 298 fi
 299 if test x$ac_gc_check_stringbytes != x ; then
 300   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 301 [Define this temporarily to hunt a bug.  If defined, the size of
 302    strings is redundantly recorded in sdata structures so that it can
 303    be compared to the sizes recorded in Lisp strings.])
 304 fi
 305 if test x$ac_gc_check_string_overrun != x ; then
 306   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 307 [Define this to check for short string overrun.])
 308 fi
 309 if test x$ac_gc_check_string_free_list != x ; then
 310   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 311 [Define this to check the string free list.])
 312 fi
 313 if test x$ac_xmalloc_overrun != x ; then
 314   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 315 [Define this to check for malloc buffer overrun.])
 316 fi
 317 if test x$ac_gc_check_cons_list != x ; then
 318   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 319 [Define this to check for errors in cons list.])
 320 fi
 321 if test x$ac_glyphs_debug != x ; then
 322   AC_DEFINE(GLYPH_DEBUG, 1,
 323 [Define this to enable glyphs debugging code.])
 324 fi
 325
 326 AC_ARG_ENABLE(check-lisp-object-type,
 327 [AS_HELP_STRING([--enable-check-lisp-object-type],
 328                 [enable compile time checks for the Lisp_Object data type.
 329                 This is useful for development for catching certain types of bugs.])],
 330 if test "${enableval}" != "no"; then
 331    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 332    [Define this to enable compile time checks for the Lisp_Object data type.])
 333 fi)
 334
 335
 336 AC_ARG_ENABLE(profiling,
 337 [AS_HELP_STRING([--enable-profiling],
 338                 [build emacs with profiling support.
 339                  This might not work on all platforms])],
 340 [ac_enable_profiling="${enableval}"],[])
 341 if test x$ac_enable_profiling != x ; then
 342    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 343 else
 344    PROFILING_CFLAGS=
 345 fi
 346 AC_SUBST(PROFILING_CFLAGS)
 347
 348 AC_ARG_ENABLE(autodepend,
 349 [AS_HELP_STRING([--enable-autodepend],
 350                 [automatically generate dependencies to .h-files.
 351                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 352                  found])],
 353 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 354
 355 #### Make srcdir absolute, if it isn't already.  It's important to
 356 #### avoid running the path through pwd unnecessarily, since pwd can
 357 #### give you automounter prefixes, which can go away.  We do all this
 358 #### so Emacs can find its files when run uninstalled.
 359 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 360 unset CDPATH
 361 case "${srcdir}" in
 362   /* ) ;;
 363   . )
 364     ## We may be able to use the $PWD environment variable to make this
 365     ## absolute.  But sometimes PWD is inaccurate.
 366     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 367     ## but that tested only for a well-formed and valid PWD,
 368     ## it did not object when PWD was well-formed and valid but just wrong.
 369     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 370     then
 371       srcdir="$PWD"
 372     else
 373       srcdir="`(cd ${srcdir}; pwd)`"
 374     fi
 375   ;;
 376   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 377 esac
 378
 379 ### Canonicalize the configuration name.
 380
 381 AC_CANONICAL_HOST
 382 canonical=$host
 383 configuration=${host_alias-${build_alias-$host}}
 384
 385 dnl This used to use changequote, but, apart from `changequote is evil'
 386 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 387 dnl the great gob of text.  Thus it's not processed for possible expansion.
 388 dnl Just make sure the brackets remain balanced.
 389 dnl
 390 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 391 dnl indicated by comments.
 392 dnl quotation begins
 393 [
 394
 395 ### If you add support for a new configuration, add code to this
 396 ### switch statement to recognize your configuration name and select
 397 ### the appropriate operating system file.
 398
 399 ### You would hope that you could choose an s/*.h
 400 ### file based on the operating system portion.  However, it turns out
 401 ### that each s/*.h file is pretty manufacturer-specific.
 402 ### So we basically have to have a special case for each
 403 ### configuration name.
 404 ###
 405 ### As far as handling version numbers on operating systems is
 406 ### concerned, make sure things will fail in a fixable way.  If
 407 ### /etc/MACHINES doesn't say anything about version numbers, be
 408 ### prepared to handle anything reasonably.  If version numbers
 409 ### matter, be sure /etc/MACHINES says something about it.
 410
 411 opsys='' unported=no
 412 case "${canonical}" in
 413
 414   ## GNU/Linux and similar ports
 415   *-*-linux* )
 416     opsys=gnu-linux
 417   ;;
 418
 419   ## FreeBSD ports
 420   *-*-freebsd* )
 421     opsys=freebsd
 422   ;;
 423
 424   ## FreeBSD kernel + glibc based userland
 425   *-*-kfreebsd*gnu* )
 426     opsys=gnu-kfreebsd
 427   ;;
 428
 429   ## NetBSD ports
 430   *-*-netbsd* )
 431     opsys=netbsd
 432   ;;
 433
 434   ## OpenBSD ports
 435   *-*-openbsd* )
 436     opsys=openbsd
 437   ;;
 438
 439   ## Apple Darwin / Mac OS X
 440   *-apple-darwin* )
 441     case "${canonical}" in
 442       i[3456]86-* )  ;;
 443       powerpc-* )    ;;
 444       x86_64-* )     ;;
 445       * )            unported=yes ;;
 446     esac
 447     opsys=darwin
 448     ## Use fink packages if available.
 449     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 450 ##    if test -d /sw/include && test -d /sw/lib; then
 451 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 452 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 453 ##    fi
 454   ;;
 455
 456   ## HP 9000 series 700 and 800, running HP/UX
 457   hppa*-hp-hpux10.2* )
 458     opsys=hpux10-20
 459   ;;
 460   hppa*-hp-hpux1[1-9]* )
 461     opsys=hpux11
 462     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 463   ;;
 464
 465   ## IBM machines
 466   rs6000-ibm-aix4.[23]* )
 467     opsys=aix4-2
 468   ;;
 469   powerpc-ibm-aix4.[23]*  )
 470     opsys=aix4-2
 471   ;;
 472   rs6000-ibm-aix[56]* )
 473     opsys=aix4-2
 474   ;;
 475   powerpc-ibm-aix[56]*  )
 476     opsys=aix4-2
 477   ;;
 478
 479   ## Silicon Graphics machines
 480   ## Iris 4D
 481   mips-sgi-irix6.5 )
 482     opsys=irix6-5
 483     # Without defining _LANGUAGE_C, things get masked out in the headers
 484     # so that, for instance, grepping for `free' in stdlib.h fails and
 485     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 486     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 487   ;;
 488
 489   ## Suns
 490   *-sun-solaris* \
 491     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 492     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 493     case "${canonical}" in
 494       i[3456]86-*-* )   ;;
 495       amd64-*-*|x86_64-*-*) ;;
 496       sparc* )          ;;
 497       * )               unported=yes ;;
 498     esac
 499     case "${canonical}" in
 500       *-sunos5.6* | *-solaris2.6* )
 501                 opsys=sol2-6
 502                 RANLIB="ar -ts"
 503                 ;;
 504       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 505                 opsys=sol2-6
 506                 emacs_check_sunpro_c=yes
 507                 ;;
 508       *-sunos5* | *-solaris* )
 509                 opsys=sol2-10
 510                 emacs_check_sunpro_c=yes
 511                 ;;
 512     esac
 513     ## Watch out for a compiler that we know will not work.
 514     case "${canonical}" in
 515      *-solaris* | *-sunos5* )
 516                 if [ "x$CC" = x/usr/ucb/cc ]; then
 517                   ## /usr/ucb/cc doesn't work;
 518                   ## we should find some other compiler that does work.
 519                   unset CC
 520                 fi
 521                 ;;
 522       *) ;;
 523     esac
 524   ;;
 525
 526   ## Intel 386 machines where we don't care about the manufacturer.
 527   i[3456]86-*-* )
 528     case "${canonical}" in
 529       *-cygwin )                opsys=cygwin ;;
 530       *-darwin* )               opsys=darwin ;;
 531       *-sysv4.2uw* )            opsys=unixware ;;
 532       *-sysv5uw* )              opsys=unixware ;;
 533       *-sysv5OpenUNIX* )        opsys=unixware ;;
 534       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 535     esac
 536   ;;
 537
 538   * )
 539     unported=yes
 540   ;;
 541 esac
 542
 543 ### If the code above didn't choose an operating system, just choose
 544 ### an operating system based on the configuration name.  You really
 545 ### only want to use this when you have no idea what the right
 546 ### operating system is; if you know what operating systems a machine
 547 ### runs, it's cleaner to make it explicit in the case statement
 548 ### above.
 549 if test x"${opsys}" = x; then
 550   case "${canonical}" in
 551     *-gnu* )                            opsys=gnu ;;
 552     * )
 553       unported=yes
 554     ;;
 555   esac
 556 fi
 557
 558 ]
 559 dnl quotation ends
 560
 561 if test $unported = yes; then
 562   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 563 Check `etc/MACHINES' for recognized configuration names.])
 564 fi
 565
 566
 567 #### Choose a compiler.
 568
 569 dnl Sets GCC=yes if using gcc.
 570 AC_PROG_CC
 571 AM_PROG_CC_C_O
 572
 573 if test x$GCC = xyes; then
 574   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 575 else
 576   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 577 fi
 578
 579 # Initialize gnulib right after choosing the compiler.
 580 gl_EARLY
 581
 582 # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 583 # if -g3 works and the user does not specify CFLAGS.
 584 # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 585 if test "$ac_test_CFLAGS" != set; then
 586   case $CFLAGS in
 587     '-g')
 588       emacs_g3_CFLAGS='-g3';;
 589     '-g -O2')
 590       emacs_g3_CFLAGS='-g3 -O2';;
 591     *)
 592       emacs_g3_CFLAGS='';;
 593   esac
 594   if test -n "$emacs_g3_CFLAGS"; then
 595     emacs_save_CFLAGS=$CFLAGS
 596     CFLAGS=$emacs_g3_CFLAGS
 597     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 598       [emacs_cv_prog_cc_g3],
 599       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 600          [emacs_cv_prog_cc_g3=yes],
 601          [emacs_cv_prog_cc_g3=no])])
 602     if test $emacs_cv_prog_cc_g3 = yes; then
 603       CFLAGS=$emacs_g3_CFLAGS
 604     else
 605       CFLAGS=$emacs_save_CFLAGS
 606     fi
 607   fi
 608 fi
 609
 610 AC_ARG_ENABLE([gcc-warnings],
 611   [AS_HELP_STRING([--enable-gcc-warnings],
 612                   [turn on lots of GCC warnings. This is intended for
 613                    developers, and may generate false alarms when used
 614                    with older or non-GNU development tools.])],
 615   [case $enableval in
 616      yes|no) ;;
 617      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 618    esac
 619    gl_gcc_warnings=$enableval],
 620   [gl_gcc_warnings=no]
 621 )
 622
 623 AC_ARG_ENABLE(link-time-optimization,
 624 [AS_HELP_STRING([--enable-link-time-optimization],
 625                 [build emacs with link-time optimization.
 626                  This is supported only for GCC since 4.5.0.])],
 627 if test "${enableval}" != "no"; then
 628    AC_MSG_CHECKING([whether link-time optimization is supported])
 629    ac_lto_supported=no
 630    if test x$GCC = xyes; then
 631       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 632       if test x$CPUS != x; then
 633          LTO="-flto=$CPUS"
 634       else
 635          LTO="-flto"
 636       fi
 637       old_CFLAGS=$CFLAGS
 638       CFLAGS="$CFLAGS $LTO"
 639       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 640         [ac_lto_supported=yes], [ac_lto_supported=no])
 641       CFLAGS="$old_CFLAGS"
 642    fi
 643    AC_MSG_RESULT([$ac_lto_supported])
 644    if test "$ac_lto_supported" = "yes"; then
 645       CFLAGS="$CFLAGS $LTO"
 646    fi
 647 fi)
 648
 649 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 650 # ------------------------------------------------
 651 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 652 # Otherwise, run RUN-IF-NOT-FOUND.
 653 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 654   [AC_PREPROC_IFELSE(
 655     [AC_LANG_PROGRAM(
 656       [[
 657 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 658 /* ok */
 659 #else
 660 # error "your version of gcc is older than $1.$2"
 661 #endif
 662       ]]),
 663     ], [$3], [$4])
 664   ]
 665 )
 666
 667 # When compiling with GCC, prefer -isystem to -I when including system
 668 # include files, to avoid generating useless diagnostics for the files.
 669 if test "$gl_gcc_warnings" != yes; then
 670   isystem='-I'
 671 else
 672   isystem='-isystem '
 673
 674   # This, $nw, is the list of warnings we disable.
 675   nw=
 676
 677   case $with_x_toolkit in
 678     lucid | athena | motif)
 679        # Old toolkits mishandle 'const'.
 680        nw="$nw -Wwrite-strings"
 681        ;;
 682     *)
 683        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 684        ;;
 685   esac
 686   AC_SUBST([WERROR_CFLAGS])
 687
 688   nw="$nw -Waggregate-return"       # anachronistic
 689   nw="$nw -Wlong-long"              # C90 is anachronistic
 690   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 691   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 692   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 693   nw="$nw -Wcast-qual"              # Too many warnings for now
 694   nw="$nw -Wconversion"             # Too many warnings for now
 695   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 696   nw="$nw -Wsign-conversion"        # Too many warnings for now
 697   nw="$nw -Woverlength-strings"     # Not a problem these days
 698   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 699   nw="$nw -Wunreachable-code"       # so buggy that it's now silently ignored
 700   nw="$nw -Wpadded"                 # Our structs are not padded
 701   nw="$nw -Wredundant-decls"        # we regularly (re)declare functions
 702   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 703   nw="$nw -Wformat-nonliteral"      # we do this a lot
 704   nw="$nw -Wvla"                    # warnings in gettext.h
 705   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 706   nw="$nw -Wswitch-enum"            # Too many warnings for now
 707   nw="$nw -Wswitch-default"         # Too many warnings for now
 708   nw="$nw -Wfloat-equal"            # warns about high-quality code
 709   nw="$nw -Winline"                 # OK to ignore 'inline'
 710   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 711   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 712   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 713
 714   # Emacs doesn't care about shadowing; see
 715   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 716   nw="$nw -Wshadow"
 717
 718   # The following lines should be removable at some point.
 719   nw="$nw -Wstack-protector"
 720   nw="$nw -Wstrict-overflow"
 721   nw="$nw -Wsuggest-attribute=pure"
 722
 723   gl_MANYWARN_ALL_GCC([ws])
 724   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 725   for w in $ws; do
 726     gl_WARN_ADD([$w])
 727   done
 728   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 729   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 730   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 731   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 732   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 733   gl_WARN_ADD([-Wno-format-nonliteral])
 734
 735   # In spite of excluding -Wlogical-op above, it is enabled, as of
 736   # gcc 4.5.0 20090517.
 737   gl_WARN_ADD([-Wno-logical-op])
 738
 739   gl_WARN_ADD([-fdiagnostics-show-option])
 740   gl_WARN_ADD([-funit-at-a-time])
 741
 742   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 743   AH_VERBATIM([FORTIFY_SOURCE],
 744   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 745       without upsetting glibc 2.15+. */
 746    #if defined __OPTIMIZE__ && __OPTIMIZE__
 747    # define _FORTIFY_SOURCE 2
 748    #endif
 749   ])
 750   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 751
 752   # We use a slightly smaller set of warning options for lib/.
 753   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 754   nw=
 755   nw="$nw -Wunused-macros"
 756
 757   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 758   AC_SUBST([GNULIB_WARN_CFLAGS])
 759 fi
 760
 761
 762
 763 dnl Some other nice autoconf tests.
 764 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 765 dnl AC_PROG_INSTALL
 766 dnl AC_PROG_MKDIR_P
 767 dnl if test "x$RANLIB" = x; then
 768 dnl   AC_PROG_RANLIB
 769 dnl fi
 770 AC_PROG_LN_S
 771
 772 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 773   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 774 dnl Don't use GZIP, which is used by gzip for additional parameters.
 775 AC_PATH_PROG(GZIP_PROG, gzip)
 776
 777 if test $opsys = gnu-linux; then
 778   AC_PATH_PROG(PAXCTL, paxctl,,
 779     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 780   if test "X$PAXCTL" != X; then
 781     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
 782     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 783       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
 784       else AC_MSG_RESULT(no); PAXCTL=""; fi])
 785   fi
 786 fi
 787
 788 ## Need makeinfo >= 4.7 (?) to build the manuals.
 789 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 790 dnl By this stage, configure has already checked for egrep and set EGREP,
 791 dnl or exited with an error if no egrep was found.
 792 if test "$MAKEINFO" != "no" && \
 793   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 794    MAKEINFO=no
 795 fi
 796
 797 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 798 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 799 ## therefore in the category of "special tools" not normally required, which
 800 ## configure does not have to check for (eg autoconf itself).
 801 ## In a Bazaar checkout on the other hand, the manuals are not included.
 802 ## So makeinfo is a requirement to build from Bazaar, and configure
 803 ## should test for it as it does for any other build requirement.
 804 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 805 ## with pre-built manuals, from a Bazaar checkout.
 806 HAVE_MAKEINFO=yes
 807
 808 if test "$MAKEINFO" = "no"; then
 809   MAKEINFO=makeinfo
 810   if test "x${with_makeinfo}" = "xno"; then
 811     HAVE_MAKEINFO=no
 812   elif test ! -e $srcdir/info/emacs; then
 813     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 814 source tree does not seem to have pre-built manuals in the `info' directory.
 815 Either install a suitable version of makeinfo, or re-run configure
 816 with the `--without-makeinfo' option to build without the manuals.] )
 817   fi
 818 fi
 819 AC_SUBST(HAVE_MAKEINFO)
 820
 821 dnl Just so that there is only a single place we need to edit.
 822 INFO_EXT=.info
 823 INFO_OPTS=--no-split
 824 AC_SUBST(INFO_EXT)
 825 AC_SUBST(INFO_OPTS)
 826
 827 dnl Add our options to ac_link now, after it is set up.
 828
 829 if test x$GCC = xyes; then
 830   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 831     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 832 else
 833   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 834     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 835 fi
 836
 837 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 838 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 839 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 840 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 841 dnl if not built to support GNU ld.
 842
 843 late_LDFLAGS=$LDFLAGS
 844 if test x$GCC = xyes; then
 845   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 846 else
 847   LDFLAGS="$LDFLAGS -znocombreloc"
 848 fi
 849
 850 AC_MSG_CHECKING([for -znocombreloc])
 851 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 852   [AC_MSG_RESULT(yes)],
 853   LDFLAGS=$late_LDFLAGS
 854   [AC_MSG_RESULT(no)])
 855
 856
 857 dnl The function dump-emacs will not be defined and temacs will do
 858 dnl (load "loadup") automatically unless told otherwise.
 859 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 860 case "$opsys" in
 861   your-opsys-here) CANNOT_DUMP=yes ;;
 862 esac
 863
 864 test "$CANNOT_DUMP" = "yes" && \
 865   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 866
 867 AC_SUBST(CANNOT_DUMP)
 868
 869
 870 UNEXEC_OBJ=unexelf.o
 871 case "$opsys" in
 872   # MSDOS uses unexcoff.o
 873   # MSWindows uses unexw32.o
 874   aix4-2)
 875    UNEXEC_OBJ=unexaix.o
 876    ;;
 877   cygwin)
 878    UNEXEC_OBJ=unexcw.o
 879    ;;
 880   darwin)
 881    UNEXEC_OBJ=unexmacosx.o
 882    ;;
 883   hpux10-20 | hpux11)
 884    UNEXEC_OBJ=unexhp9k800.o
 885    ;;
 886   sol2-10)
 887    # Use the Solaris dldump() function, called from unexsol.c, to dump
 888    # emacs, instead of the generic ELF dump code found in unexelf.c.
 889    # The resulting binary has a complete symbol table, and is better
 890    # for debugging and other observability tools (debuggers, pstack, etc).
 891    #
 892    # If you encounter a problem using dldump(), please consider sending
 893    # a message to the OpenSolaris tools-linking mailing list:
 894    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 895    #
 896    # It is likely that dldump() works with older Solaris too, but this has
 897    # not been tested, so for now this change is for Solaris 10 or newer.
 898    UNEXEC_OBJ=unexsol.o
 899    ;;
 900 esac
 901
 902 LD_SWITCH_SYSTEM=
 903 case "$opsys" in
 904   freebsd)
 905    ## Let `ld' find image libs and similar things in /usr/local/lib.
 906    ## The system compiler, GCC, has apparently been modified to not
 907    ## look there, contrary to what a stock GCC would do.
 908 ### It's not our place to do this.  See bug#10313#17.
 909 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 910       :
 911    ;;
 912
 913   gnu-linux)
 914    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 915    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 916    ;;
 917
 918   netbsd)
 919 ### It's not our place to do this.  See bug#10313#17.
 920 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 921       :
 922    ;;
 923
 924   openbsd)
 925    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 926    ## otherwise Emacs dumps core on elf systems.
 927    LD_SWITCH_SYSTEM="-Z"
 928    ;;
 929 esac
 930 AC_SUBST(LD_SWITCH_SYSTEM)
 931
 932 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 933
 934 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 935 ## which has not been defined yet.  When this was handled with cpp,
 936 ## it was expanded to null when configure sourced the s/*.h file.
 937 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 938 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 939 ## (or somesuch), but because it is supposed to go at the _front_
 940 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 941 ## Compare with the gnu-linux case below, which added to the end
 942 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 943 ## LD_SWITCH_SYSTEM_TEMACS.
 944 case "$opsys" in
 945   netbsd|openbsd)
 946    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 947 esac
 948
 949
 950 C_SWITCH_MACHINE=
 951 case $canonical in
 952  alpha*)
 953   AC_CHECK_DECL([__ELF__])
 954   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 955     ## With ELF, make sure that all common symbols get allocated to in the
 956     ## data section.  Otherwise, the dump of temacs may miss variables in
 957     ## the shared library that have been initialized.  For example, with
 958     ## GNU libc, __malloc_initialized would normally be resolved to the
 959     ## shared library's .bss section, which is fatal.
 960     if test "x$GCC" = "xyes"; then
 961       C_SWITCH_MACHINE="-fno-common"
 962     else
 963       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 964     fi
 965   else
 966     UNEXEC_OBJ=unexalpha.o
 967   fi
 968   ;;
 969 esac
 970 AC_SUBST(C_SWITCH_MACHINE)
 971
 972 AC_SUBST(UNEXEC_OBJ)
 973
 974 C_SWITCH_SYSTEM=
 975 ## Some programs in src produce warnings saying certain subprograms
 976 ## are too complex and need a MAXMEM value greater than 2000 for
 977 ## additional optimization.  --nils@exp-math.uni-essen.de
 978 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 979   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 980 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 981 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 982 AC_SUBST(C_SWITCH_SYSTEM)
 983
 984
 985 LIBS_SYSTEM=
 986 case "$opsys" in
 987   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 988   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 989
 990   freebsd) LIBS_SYSTEM="-lutil" ;;
 991
 992   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 993
 994   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 995
 996   ## Motif needs -lgen.
 997   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 998 esac
 999 AC_SUBST(LIBS_SYSTEM)
1000
1001
1002 ### Make sure subsequent tests use flags consistent with the build flags.
1003
1004 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1005   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1006 else
1007   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1008 fi
1009
1010 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1011 AC_DEFUN([AC_TYPE_SIZE_T])
1012 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1013 AC_DEFUN([AC_TYPE_UID_T])
1014
1015
1016 LIB_MATH=-lm
1017 LIB_STANDARD=
1018 START_FILES=
1019 dnl Current possibilities handled by sed (aix4-2 -> aix,
1020 dnl gnu-linux -> gnu/linux, etc.):
1021 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1022 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1023 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1024
1025 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
1026 case $opsys in
1027   cygwin )
1028     LIB_MATH=
1029     START_FILES='pre-crt0.o'
1030     ;;
1031   darwin )
1032     ## Adding -lm confuses the dynamic linker, so omit it.
1033     LIB_MATH=
1034     START_FILES='pre-crt0.o'
1035     ;;
1036   freebsd )
1037     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1038     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1039     SYSTEM_TYPE=berkeley-unix
1040     ;;
1041   gnu-linux | gnu-kfreebsd )
1042     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1043     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1044     ;;
1045   hpux10-20 | hpux11 )
1046     LIB_STANDARD=-lc
1047     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1048     ;;
1049   dnl NB this may be adjusted below.
1050   netbsd | openbsd )
1051     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1052     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1053     SYSTEM_TYPE=berkeley-unix
1054     ;;
1055
1056   sol2* | unixware )
1057     SYSTEM_TYPE=usg-unix-v
1058     ;;
1059
1060 esac
1061
1062 AC_SUBST(LIB_MATH)
1063 AC_SUBST(START_FILES)
1064 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1065   [The type of system you are compiling for; sets `system-type'.])
1066
1067 dnl Not all platforms use crtn.o files.  Check if the current one does.
1068 crt_files=
1069
1070 for file in x $LIB_STANDARD $START_FILES; do
1071   case "$file" in
1072     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1073   esac
1074 done
1075
1076 if test "x$crt_files" != x; then
1077
1078   ## If user specified a crt-dir, use that unconditionally.
1079   crt_gcc=no
1080
1081   if test "X$CRT_DIR" = "X"; then
1082
1083     CRT_DIR=/usr/lib            # default
1084
1085     case "$canonical" in
1086       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1087       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1088       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1089       ## For anything else (eg /usr/lib32), it is up the user to specify
1090       ## the location (bug#5655).
1091       ## Test for crtn.o, not just the directory, because sometimes the
1092       ## directory exists but does not have the relevant files (bug#1287).
1093       ## FIXME better to test for binary compatibility somehow.
1094       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1095       ;;
1096
1097       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1098     esac
1099
1100     case "$opsys" in
1101       hpux10-20) CRT_DIR=/lib ;;
1102     esac
1103
1104     test "x${GCC}" = xyes && crt_gcc=yes
1105
1106   fi                            # CRT_DIR = ""
1107
1108   crt_missing=
1109
1110   for file in $crt_files; do
1111
1112     ## If we're using gcc, try to determine it automatically by asking
1113     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1114     ## system-dependent default from above.]
1115     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1116
1117        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1118        case "$crt_file" in
1119          */*)
1120            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1121            ;;
1122        esac
1123     fi
1124
1125     dnl We expect all the files to be in a single directory, so after the
1126     dnl first there is no point asking gcc.
1127     crt_gcc=no
1128
1129     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1130   done                          # $crt_files
1131
1132   test "x$crt_missing" = x || \
1133     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1134 Try using the --with-crt-dir option.])
1135
1136 fi                              # crt_files != ""
1137
1138 AC_SUBST(CRT_DIR)
1139
1140 case $opsys in
1141   netbsd | openbsd )
1142     if test -f $CRT_DIR/crti.o; then
1143
1144         test -f $CRT_DIR/crtn.o || \
1145           AC_MSG_ERROR([Required file not found: crtn.o])
1146
1147         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1148         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1149     fi
1150     ;;
1151 esac
1152
1153
1154 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1155 pre_PKG_CONFIG_LIBS=$LIBS
1156
1157 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1158
1159 dnl This function definition taken from Gnome 2.0
1160 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1161 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1162 dnl also defines GSTUFF_PKG_ERRORS on error
1163 AC_DEFUN([PKG_CHECK_MODULES], [
1164   succeeded=no
1165
1166   if test "$PKG_CONFIG" = "no" ; then
1167      ifelse([$4], , [AC_MSG_ERROR([
1168       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1169   else
1170      PKG_CONFIG_MIN_VERSION=0.9.0
1171      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1172         AC_MSG_CHECKING(for $2)
1173
1174         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1175            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1176            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1177             edit_cflags="
1178               s,///*,/,g
1179               s/^/ /
1180               s/ -I/ $isystem/g
1181               s/^ //
1182             "
1183             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1184             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1185             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1186             succeeded=yes
1187         else
1188             AC_MSG_RESULT(no)
1189             $1_CFLAGS=""
1190             $1_LIBS=""
1191             ## If we have a custom action on failure, don't print errors, but
1192             ## do set a variable so people can do so.  Do it in a subshell
1193             ## to capture any diagnostics in invoking pkg-config.
1194             $1_PKG_ERRORS=`($PKG_CONFIG --print-errors "$2") 2>&1`
1195             ifelse([$4], ,echo "$$1_PKG_ERRORS",)
1196         fi
1197
1198         AC_SUBST($1_CFLAGS)
1199         AC_SUBST($1_LIBS)
1200      else
1201         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1202         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1203      fi
1204   fi
1205
1206   if test $succeeded = yes; then
1207      ifelse([$3], , :, [$3])
1208   else
1209      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1210   fi
1211 ])
1212
1213
1214 if test "${with_sound}" != "no"; then
1215   # Sound support for GNU/Linux and the free BSDs.
1216   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1217     have_sound_header=yes)
1218   # Emulation library used on NetBSD.
1219   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1220   AC_SUBST(LIBSOUND)
1221
1222   ALSA_REQUIRED=1.0.0
1223   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1224   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1225   if test $HAVE_ALSA = yes; then
1226     SAVE_CFLAGS="$CFLAGS"
1227     SAVE_LIBS="$LIBS"
1228     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1229     LIBS="$ALSA_LIBS $LIBS"
1230     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1231                     emacs_alsa_normal=yes,
1232                     emacs_alsa_normal=no)
1233     if test "$emacs_alsa_normal" != yes; then
1234       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1235                      [[snd_lib_error_set_handler (0);]])],
1236                      emacs_alsa_subdir=yes,
1237                      emacs_alsa_subdir=no)
1238       if test "$emacs_alsa_subdir" != yes; then
1239         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1240       fi
1241       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1242     fi
1243
1244     CFLAGS="$SAVE_CFLAGS"
1245     LIBS="$SAVE_LIBS"
1246     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1247     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1248     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1249   fi
1250
1251   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1252   dnl compiles only on the specified platforms.  For others, it
1253   dnl probably doesn't make sense to try.
1254   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1255      case "$opsys" in
1256        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1257        gnu-linux|freebsd|netbsd)
1258          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1259          ;;
1260      esac
1261   fi
1262
1263   AC_SUBST(CFLAGS_SOUND)
1264 fi
1265
1266 dnl checks for header files
1267 AC_CHECK_HEADERS_ONCE(
1268   linux/version.h sys/systeminfo.h
1269   stdio_ext.h fcntl.h coff.h pty.h
1270   sys/vlimit.h sys/resource.h
1271   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1272
1273 AC_MSG_CHECKING(if personality LINUX32 can be set)
1274 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1275                emacs_cv_personality_linux32=yes,
1276                emacs_cv_personality_linux32=no)
1277 AC_MSG_RESULT($emacs_cv_personality_linux32)
1278
1279 if test $emacs_cv_personality_linux32 = yes; then
1280   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1281             [Define to 1 if personality LINUX32 can be set.])
1282 fi
1283
1284 dnl On Solaris 8 there's a compilation warning for term.h because
1285 dnl it doesn't define `bool'.
1286 AC_CHECK_HEADERS(term.h, , , -)
1287 AC_HEADER_TIME
1288 AC_CHECK_DECLS([sys_siglist])
1289 if test $ac_cv_have_decl_sys_siglist != yes; then
1290   # For Tru64, at least:
1291   AC_CHECK_DECLS([__sys_siglist])
1292   if test $ac_cv_have_decl___sys_siglist = yes; then
1293     AC_DEFINE(sys_siglist, __sys_siglist,
1294               [Define to any substitute for sys_siglist.])
1295   fi
1296 fi
1297 AC_HEADER_SYS_WAIT
1298
1299 dnl Check for speed_t typedef.
1300 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1301   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1302     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1303 if test $emacs_cv_speed_t = yes; then
1304   AC_DEFINE(HAVE_SPEED_T, 1,
1305            [Define to 1 if `speed_t' is declared by <termios.h>.])
1306 fi
1307
1308 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1309 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1310 #if HAVE_SYS_SOCKET_H
1311 #include <sys/socket.h>
1312 #endif])
1313 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1314 #if HAVE_SYS_SOCKET_H
1315 #include <sys/socket.h>
1316 #endif])
1317 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1318 #if HAVE_SYS_SOCKET_H
1319 #include <sys/socket.h>
1320 #endif])
1321
1322 dnl checks for structure members
1323 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1324                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1325                   struct ifreq.ifr_addr,
1326                   struct ifreq.ifr_addr.sa_len], , ,
1327                  [AC_INCLUDES_DEFAULT
1328 #if HAVE_SYS_SOCKET_H
1329 #include <sys/socket.h>
1330 #endif
1331 #if HAVE_NET_IF_H
1332 #include <net/if.h>
1333 #endif])
1334
1335 dnl Check for endianness.
1336 dnl AC_C_BIGENDIAN is done by gnulib.
1337
1338 dnl check for Make feature
1339 dnl AC_PROG_MAKE_SET is done by Automake.
1340
1341 DEPFLAGS=
1342 MKDEPDIR=":"
1343 deps_frag=deps.mk
1344 dnl check for GNU Make if we have GCC and autodepend is on.
1345 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1346    AC_MSG_CHECKING([whether we are using GNU Make])
1347    HAVE_GNU_MAKE=no
1348    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1349    if test "x$testval" != x; then
1350       HAVE_GNU_MAKE=yes
1351    else
1352       ac_enable_autodepend=no
1353    fi
1354    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1355    if test $HAVE_GNU_MAKE = yes; then
1356       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1357       SAVE_CFLAGS="$CFLAGS"
1358       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1359       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1360       CFLAGS="$SAVE_CFLAGS"
1361       test -f deps.d || ac_enable_autodepend=no
1362       rm -rf deps.d
1363       AC_MSG_RESULT([$ac_enable_autodepend])
1364    fi
1365    if test $ac_enable_autodepend = yes; then
1366       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1367       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1368       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1369       deps_frag=autodeps.mk
1370    fi
1371 fi
1372 deps_frag=$srcdir/src/$deps_frag
1373 AC_SUBST(MKDEPDIR)
1374 AC_SUBST(DEPFLAGS)
1375 AC_SUBST_FILE(deps_frag)
1376
1377
1378 lisp_frag=$srcdir/src/lisp.mk
1379 AC_SUBST_FILE(lisp_frag)
1380
1381
1382 dnl checks for operating system services
1383 AC_SYS_LONG_FILE_NAMES
1384
1385 #### Choose a window system.
1386
1387 ## We leave window_system equal to none if
1388 ## we end up building without one.  Any new window system should
1389 ## set window_system to an appropriate value and add objects to
1390 ## window-system-specific substs.
1391
1392 window_system=none
1393 AC_PATH_X
1394 if test "$no_x" != yes; then
1395   window_system=x11
1396 fi
1397
1398 LD_SWITCH_X_SITE_RPATH=
1399 if test "${x_libraries}" != NONE; then
1400   if test -n "${x_libraries}"; then
1401     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1402     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1403   fi
1404   x_default_search_path=""
1405   x_search_path=${x_libraries}
1406   if test -z "${x_search_path}"; then
1407     x_search_path=/usr/lib
1408   fi
1409   for x_library in `echo ${x_search_path}: | \
1410                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1411     x_search_path="\
1412 ${x_library}/X11/%L/%T/%N%C%S:\
1413 ${x_library}/X11/%l/%T/%N%C%S:\
1414 ${x_library}/X11/%T/%N%C%S:\
1415 ${x_library}/X11/%L/%T/%N%S:\
1416 ${x_library}/X11/%l/%T/%N%S:\
1417 ${x_library}/X11/%T/%N%S"
1418     if test x"${x_default_search_path}" = x; then
1419       x_default_search_path=${x_search_path}
1420     else
1421       x_default_search_path="${x_search_path}:${x_default_search_path}"
1422     fi
1423   done
1424 fi
1425 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1426
1427 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1428   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1429 fi
1430
1431 if test x"${x_includes}" = x; then
1432   bitmapdir=/usr/include/X11/bitmaps
1433 else
1434   # accumulate include directories that have X11 bitmap subdirectories
1435   bmd_acc="dummyval"
1436   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1437     if test -d "${bmd}/X11/bitmaps"; then
1438       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1439     fi
1440     if test -d "${bmd}/bitmaps"; then
1441       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1442     fi
1443   done
1444   if test ${bmd_acc} != "dummyval"; then
1445     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1446   fi
1447 fi
1448
1449 HAVE_NS=no
1450 NS_IMPL_COCOA=no
1451 NS_IMPL_GNUSTEP=no
1452 tmp_CPPFLAGS="$CPPFLAGS"
1453 tmp_CFLAGS="$CFLAGS"
1454 CPPFLAGS="$CPPFLAGS -x objective-c"
1455 CFLAGS="$CFLAGS -x objective-c"
1456 TEMACS_LDFLAGS2="\${LDFLAGS}"
1457 GNU_OBJC_CFLAGS=
1458 if test "${with_ns}" != no; then
1459   if test "${opsys}" = darwin; then
1460      NS_IMPL_COCOA=yes
1461      ns_appdir=`pwd`/nextstep/Emacs.app
1462      ns_appbindir=${ns_appdir}/Contents/MacOS
1463      ns_appresdir=${ns_appdir}/Contents/Resources
1464      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1465   elif test -f $GNUSTEP_CONFIG_FILE; then
1466      NS_IMPL_GNUSTEP=yes
1467      ns_appdir=`pwd`/nextstep/Emacs.app
1468      ns_appbindir=${ns_appdir}
1469      ns_appresdir=${ns_appdir}/Resources
1470      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1471      dnl FIXME sourcing this several times in subshells seems inefficient.
1472      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1473      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1474      dnl I seemed to need these as well with GNUstep-startup 0.25.
1475      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1476      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1477      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1478        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1479      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1480        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1481      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1482      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1483      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1484      LIB_STANDARD=
1485      START_FILES=
1486      TEMACS_LDFLAGS2=
1487      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1488      dnl If they had chosen to either define it or not, we could have
1489      dnl just used AC_CHECK_DECL here.
1490      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1491        emacs_cv_objc_exceptions,
1492 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1493 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1494 1;
1495 #else
1496 fail;
1497 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1498      if test $emacs_cv_objc_exceptions = yes; then
1499        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1500        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1501          [Define if GNUstep uses ObjC exceptions.])
1502        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1503      fi
1504   fi
1505
1506   dnl This is only used while we test the NS headers, it gets reset below.
1507   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1508
1509   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1510                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1511   files are missing or cannot be compiled.])])
1512   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1513                                      [NSInteger i;])],
1514                     ns_have_nsinteger=yes,
1515                     ns_have_nsinteger=no)
1516   if test $ns_have_nsinteger = yes; then
1517     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1518   fi
1519 fi
1520 AC_SUBST(TEMACS_LDFLAGS2)
1521
1522 INSTALL_ARCH_INDEP_EXTRA=install-etc
1523 ns_self_contained=no
1524 ns_frag=/dev/null
1525 NS_OBJ=
1526 NS_OBJC_OBJ=
1527 if test "${HAVE_NS}" = yes; then
1528   if test "$with_toolkit_scroll_bars" = "no"; then
1529     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1530   fi
1531
1532   window_system=nextstep
1533   # set up packaging dirs
1534   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1535      ns_self_contained=yes
1536      prefix=${ns_appresdir}
1537      exec_prefix=${ns_appbindir}
1538      dnl This one isn't really used, only archlibdir is.
1539      libexecdir="\${ns_appbindir}/libexec"
1540      archlibdir="\${ns_appbindir}/libexec"
1541      docdir="\${ns_appresdir}/etc"
1542      etcdir="\${ns_appresdir}/etc"
1543      dnl FIXME maybe set datarootdir instead.
1544      dnl That would also get applications, icons, man.
1545      infodir="\${ns_appresdir}/info"
1546      mandir="\${ns_appresdir}/man"
1547      lispdir="\${ns_appresdir}/lisp"
1548      leimdir="\${ns_appresdir}/leim"
1549      INSTALL_ARCH_INDEP_EXTRA=
1550   fi
1551   ns_frag=$srcdir/src/ns.mk
1552   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1553 fi
1554 CFLAGS="$tmp_CFLAGS"
1555 CPPFLAGS="$tmp_CPPFLAGS"
1556 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1557 AC_SUBST(ns_self_contained)
1558 AC_SUBST(NS_OBJ)
1559 AC_SUBST(NS_OBJC_OBJ)
1560 AC_SUBST(LIB_STANDARD)
1561 AC_SUBST_FILE(ns_frag)
1562
1563 ## $window_system is now set to the window system we will
1564 ## ultimately use.
1565
1566 term_header=
1567 HAVE_X_WINDOWS=no
1568 HAVE_X11=no
1569 USE_X_TOOLKIT=none
1570
1571 case "${window_system}" in
1572   x11 )
1573     HAVE_X_WINDOWS=yes
1574     HAVE_X11=yes
1575     term_header=xterm.h
1576     case "${with_x_toolkit}" in
1577       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1578       motif ) USE_X_TOOLKIT=MOTIF ;;
1579       gtk ) with_gtk=yes
1580             term_header=gtkutil.h
1581 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1582 dnl USE_X_TOOLKIT is set.
1583             USE_X_TOOLKIT=none ;;
1584       gtk2 ) with_gtk2=yes
1585              term_header=gtkutil.h
1586              USE_X_TOOLKIT=none ;;
1587       gtk3 ) with_gtk3=yes
1588              term_header=gtkutil.h
1589              USE_X_TOOLKIT=none ;;
1590       no ) USE_X_TOOLKIT=none ;;
1591 dnl If user did not say whether to use a toolkit, make this decision later:
1592 dnl use the toolkit if we have gtk, or X11R5 or newer.
1593       * ) USE_X_TOOLKIT=maybe ;;
1594     esac
1595   ;;
1596   nextstep )
1597     term_header=nsterm.h
1598   ;;
1599 esac
1600
1601 if test -n "${term_header}"; then
1602     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
1603         [Define to the header for the built-in window system.])
1604 fi
1605
1606 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1607    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1608    if test "$HAVE_XSERVER" = true ||
1609       test -n "$DISPLAY" ||
1610       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1611         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1612 were found.  You should install the relevant development files for X
1613 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1614 sure you have development files for image handling, i.e.
1615 tiff, gif, jpeg, png and xpm.
1616 If you are sure you want Emacs compiled without X window support, pass
1617   --without-x
1618 to configure.])
1619    fi
1620 fi
1621
1622 ### If we're using X11, we should use the X menu package.
1623 HAVE_MENUS=no
1624 case ${HAVE_X11} in
1625   yes ) HAVE_MENUS=yes ;;
1626 esac
1627
1628 # Does the opsystem file prohibit the use of the GNU malloc?
1629 # Assume not, until told otherwise.
1630 GNU_MALLOC=yes
1631
1632 AC_CACHE_CHECK(
1633   [whether malloc is Doug Lea style],
1634   [emacs_cv_var_doug_lea_malloc],
1635   [AC_LINK_IFELSE(
1636      [AC_LANG_PROGRAM(
1637         [[#include <malloc.h>
1638           static void hook (void) {}]],
1639         [[malloc_set_state (malloc_get_state ());
1640           __after_morecore_hook = hook;
1641           __malloc_initialize_hook = hook;]])],
1642      [emacs_cv_var_doug_lea_malloc=yes],
1643      [emacs_cv_var_doug_lea_malloc=no])])
1644 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1645
1646
1647 dnl See comments in aix4-2.h about maybe using system malloc there.
1648 system_malloc=no
1649 case "$opsys" in
1650   ## darwin ld insists on the use of malloc routines in the System framework.
1651   darwin|sol2-10) system_malloc=yes ;;
1652 esac
1653
1654 if test "${system_malloc}" = "yes"; then
1655   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1656   GNU_MALLOC=no
1657   GNU_MALLOC_reason="
1658     (The GNU allocators don't work with this system configuration.)"
1659   GMALLOC_OBJ=
1660   VMLIMIT_OBJ=
1661 else
1662   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1663   VMLIMIT_OBJ=vm-limit.o
1664 fi
1665 AC_SUBST(GMALLOC_OBJ)
1666 AC_SUBST(VMLIMIT_OBJ)
1667
1668 if test "$doug_lea_malloc" = "yes" ; then
1669   if test "$GNU_MALLOC" = yes ; then
1670     GNU_MALLOC_reason="
1671       (Using Doug Lea's new malloc from the GNU C Library.)"
1672   fi
1673   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1674             [Define to 1 if you are using the GNU C Library.])
1675
1676   ## Use mmap directly for allocating larger buffers.
1677   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1678   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1679   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1680   case "$opsys" in
1681     gnu*) REL_ALLOC=no ;;
1682   esac
1683 fi
1684
1685 if test x"${REL_ALLOC}" = x; then
1686   REL_ALLOC=${GNU_MALLOC}
1687 fi
1688
1689 use_mmap_for_buffers=no
1690 case "$opsys" in
1691   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1692 esac
1693
1694 AC_FUNC_MMAP
1695 if test $use_mmap_for_buffers = yes; then
1696   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1697   REL_ALLOC=no
1698 fi
1699
1700 LIBS="$LIBS_SYSTEM $LIBS"
1701
1702 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1703 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1704 AC_CHECK_LIB(dnet, dnet_ntoa)
1705 dnl This causes -lresolv to get used in subsequent tests,
1706 dnl which causes failures on some systems such as HPUX 9.
1707 dnl AC_CHECK_LIB(resolv, gethostbyname)
1708
1709 dnl FIXME replace main with a function we actually want from this library.
1710 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1711
1712 dnl Check if pthreads is available.
1713 LIB_PTHREAD=
1714 AC_CHECK_HEADERS_ONCE(pthread.h)
1715 if test "$ac_cv_header_pthread_h"; then
1716   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1717   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1718   dnl testing for pthread_self if Emacs uses gmalloc.c.
1719   if test "$GMALLOC_OBJ" = gmalloc.o; then
1720     emacs_pthread_function=pthread_atfork
1721   else
1722     emacs_pthread_function=pthread_self
1723   fi
1724   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1725 fi
1726 if test "$HAVE_PTHREAD" = yes; then
1727   case "${canonical}" in
1728     *-hpux*) ;;
1729     *) LIB_PTHREAD="-lpthread"
1730        LIBS="$LIB_PTHREAD $LIBS" ;;
1731   esac
1732   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1733 fi
1734 AC_SUBST([LIB_PTHREAD])
1735
1736 AC_CHECK_LIB(pthreads, cma_open)
1737
1738 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1739 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1740 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1741 ## added to LIBS in configure would never contain the pthreads part,
1742 ## but the value used in Makefiles might.  FIXME?
1743 ##
1744 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1745 ## be harmless on older versions of X where it happens to exist.
1746 test "$opsys" = "aix4-2" && \
1747   test $ac_cv_lib_pthreads_cma_open = yes && \
1748   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1749
1750 dnl Check for need for bigtoc support on IBM AIX
1751
1752 case ${host_os} in
1753 aix*)
1754   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1755     case $GCC in
1756     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1757     *) gdb_cv_bigtoc=-bbigtoc ;;
1758     esac
1759
1760     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1761     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1762   ])
1763   ;;
1764 esac
1765
1766 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1767 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1768 # REAL_CPPFLAGS later on.
1769
1770 REAL_CFLAGS="$CFLAGS"
1771 REAL_CPPFLAGS="$CPPFLAGS"
1772
1773 if test "${HAVE_X11}" = "yes"; then
1774   DEFS="$C_SWITCH_X_SITE $DEFS"
1775   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1776   LIBS="-lX11 $LIBS"
1777   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1778   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1779
1780   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1781   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1782   # but it's more convenient here to set LD_RUN_PATH since this
1783   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1784   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1785     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1786     export LD_RUN_PATH
1787   fi
1788
1789   if test "${opsys}" = "gnu-linux"; then
1790     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1791     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1792      [[XOpenDisplay ("foo");]])],
1793      [xgnu_linux_first_failure=no],
1794      [xgnu_linux_first_failure=yes])
1795     if test "${xgnu_linux_first_failure}" = "yes"; then
1796       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1797       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1798       OLD_CPPFLAGS="$CPPFLAGS"
1799       OLD_LIBS="$LIBS"
1800       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1801       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1802       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1803       LIBS="$LIBS -b i486-linuxaout"
1804       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1805        [[XOpenDisplay ("foo");]])],
1806        [xgnu_linux_second_failure=no],
1807        [xgnu_linux_second_failure=yes])
1808       if test "${xgnu_linux_second_failure}" = "yes"; then
1809         # If we get the same failure with -b, there is no use adding -b.
1810         # So take it out.  This plays safe.
1811         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1812         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1813         CPPFLAGS="$OLD_CPPFLAGS"
1814         LIBS="$OLD_LIBS"
1815         AC_MSG_RESULT(no)
1816       else
1817         AC_MSG_RESULT(yes)
1818       fi
1819     else
1820       AC_MSG_RESULT(no)
1821     fi
1822   fi
1823
1824   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1825   # header files included from there.
1826   AC_MSG_CHECKING(for Xkb)
1827   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1828 #include <X11/XKBlib.h>]],
1829         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1830         emacs_xkb=yes, emacs_xkb=no)
1831   AC_MSG_RESULT($emacs_xkb)
1832   if test $emacs_xkb = yes; then
1833     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1834   fi
1835
1836   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1837 XScreenNumberOfScreen)
1838 fi
1839
1840 if test "${window_system}" = "x11"; then
1841   AC_MSG_CHECKING(X11 version 6)
1842   AC_CACHE_VAL(emacs_cv_x11_version_6,
1843   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1844 [[#if XlibSpecificationRelease < 6
1845 fail;
1846 #endif
1847 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1848   if test $emacs_cv_x11_version_6 = yes; then
1849     AC_MSG_RESULT(6 or newer)
1850     AC_DEFINE(HAVE_X11R6, 1,
1851               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1852     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1853     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1854     ## XIM support.
1855     case "$opsys" in
1856       sol2-*) : ;;
1857       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1858            [Define if you have usable X11R6-style XIM support.])
1859          ;;
1860     esac
1861   else
1862     AC_MSG_RESULT(before 6)
1863   fi
1864 fi
1865
1866
1867 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1868 HAVE_RSVG=no
1869 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1870   if test "${with_rsvg}" != "no"; then
1871     RSVG_REQUIRED=2.11.0
1872     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1873
1874     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1875     AC_SUBST(RSVG_CFLAGS)
1876     AC_SUBST(RSVG_LIBS)
1877
1878     if test $HAVE_RSVG = yes; then
1879       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1880       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1881       LIBS="$RSVG_LIBS $LIBS"
1882     fi
1883   fi
1884 fi
1885
1886 HAVE_IMAGEMAGICK=no
1887 if test "${HAVE_X11}" = "yes"; then
1888   if test "${with_imagemagick}" != "no"; then
1889     ## 6.2.8 is the earliest version known to work, but earlier versions
1890     ## might work - let us know if you find one.
1891     ## 6.0.7 does not work.  See bug#7955.
1892     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1893     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1894     AC_SUBST(IMAGEMAGICK_CFLAGS)
1895     AC_SUBST(IMAGEMAGICK_LIBS)
1896
1897     if test $HAVE_IMAGEMAGICK = yes; then
1898       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1899       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1900       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1901       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
1902     fi
1903   fi
1904 fi
1905
1906
1907 HAVE_GTK=no
1908 GTK_OBJ=
1909 check_gtk2=no
1910 gtk3_pkg_errors=
1911 if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1912   GLIB_REQUIRED=2.28
1913   GTK_REQUIRED=3.0
1914   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1915
1916   dnl Checks for libraries.
1917   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1918   if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
1919      AC_MSG_ERROR($GTK_PKG_ERRORS)
1920   fi
1921   if test "$pkg_check_gtk" = "yes"; then
1922      AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1923      GTK_OBJ=emacsgtkfixed.o
1924      term_header=gtkutil.h
1925   else
1926      check_gtk2=yes
1927      gtk3_pkg_errors="$GTK_PKG_ERRORS "
1928   fi
1929 fi
1930
1931 if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
1932   GLIB_REQUIRED=2.10
1933   GTK_REQUIRED=2.10
1934   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1935
1936   dnl Checks for libraries.
1937   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1938   if test "$pkg_check_gtk" = "no" &&
1939      { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
1940   then
1941     AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
1942   fi
1943 fi
1944
1945 if test x"$pkg_check_gtk" = xyes; then
1946
1947   AC_SUBST(GTK_CFLAGS)
1948   AC_SUBST(GTK_LIBS)
1949   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1950   CFLAGS="$CFLAGS $GTK_CFLAGS"
1951   LIBS="$GTK_LIBS $LIBS"
1952   dnl Try to compile a simple GTK program.
1953   GTK_COMPILES=no
1954   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1955   if test "${GTK_COMPILES}" != "yes"; then
1956     if test "$USE_X_TOOLKIT" != "maybe"; then
1957       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1958     fi
1959   else
1960     HAVE_GTK=yes
1961     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1962     GTK_OBJ="gtkutil.o $GTK_OBJ"
1963     USE_X_TOOLKIT=none
1964     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1965       :
1966     else
1967       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1968        closing open displays.  This is no problem if you just use
1969        one display, but if you use more than one and close one of them
1970        Emacs may crash.]])
1971       sleep 3
1972     fi
1973   fi
1974
1975 fi
1976 AC_SUBST(GTK_OBJ)
1977
1978
1979 if test "${HAVE_GTK}" = "yes"; then
1980
1981   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1982   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1983   if test "$with_toolkit_scroll_bars" != no; then
1984     with_toolkit_scroll_bars=yes
1985   fi
1986
1987   dnl  Check if we have the old file selection dialog declared and
1988   dnl  in the link library.  In 2.x it may be in the library,
1989   dnl  but not declared if deprecated featured has been selected out.
1990   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1991   HAVE_GTK_FILE_SELECTION=no
1992   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1993                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1994 #include <gtk/gtk.h>])
1995   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1996     AC_CHECK_FUNCS(gtk_file_selection_new)
1997   fi
1998
1999
2000   dnl Check for functions introduced in 2.14 and later.
2001   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2002                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2003                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2004                  gtk_orientable_set_orientation \
2005                  gtk_window_set_has_resize_grip)
2006
2007  term_header=gtkutil.h
2008 fi
2009
2010 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2011 dnl other platforms.
2012 HAVE_DBUS=no
2013 DBUS_OBJ=
2014 if test "${with_dbus}" = "yes"; then
2015    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2016    if test "$HAVE_DBUS" = yes; then
2017      LIBS="$LIBS $DBUS_LIBS"
2018      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2019      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2020      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2021      dnl D-Bus 1.5.12.
2022      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2023                     dbus_type_is_valid \
2024                     dbus_validate_bus_name \
2025                     dbus_validate_path \
2026                     dbus_validate_interface \
2027                     dbus_validate_member)
2028      DBUS_OBJ=dbusbind.o
2029    fi
2030 fi
2031 AC_SUBST(DBUS_OBJ)
2032
2033 dnl GSettings has been tested under GNU/Linux only.
2034 HAVE_GSETTINGS=no
2035 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2036    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2037    if test "$HAVE_GSETTINGS" = "yes"; then
2038       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2039       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2040       SETTINGS_LIBS="$GSETTINGS_LIBS"
2041    fi
2042 fi
2043
2044 dnl GConf has been tested under GNU/Linux only.
2045 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2046 HAVE_GCONF=no
2047 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2048    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2049    if test "$HAVE_GCONF" = yes; then
2050       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2051       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2052       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2053       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2054    fi
2055 fi
2056
2057 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2058     PKG_CHECK_MODULES(GOBJECT, gobject-2.0 >= 2.0, HAVE_GOBJECT=yes, HAVE_GOBJECT=no)
2059     if test "$HAVE_GOBJECT" = "yes"; then
2060        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2061        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2062     fi
2063     SAVE_CFLAGS="$CFLAGS"
2064     SAVE_LIBS="$LIBS"
2065     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2066     LIBS="$SETTINGS_LIBS $LIBS"
2067     AC_CHECK_FUNCS([g_type_init])
2068     CFLAGS="$SAVE_CFLAGS"
2069     LIBS="$SAVE_LIBS"
2070 fi
2071 AC_SUBST(SETTINGS_CFLAGS)
2072 AC_SUBST(SETTINGS_LIBS)
2073
2074
2075 dnl SELinux is available for GNU/Linux only.
2076 HAVE_LIBSELINUX=no
2077 LIBSELINUX_LIBS=
2078 if test "${with_selinux}" = "yes"; then
2079    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2080    if test "$HAVE_LIBSELINUX" = yes; then
2081       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2082       LIBSELINUX_LIBS=-lselinux
2083    fi
2084 fi
2085 AC_SUBST(LIBSELINUX_LIBS)
2086
2087 HAVE_GNUTLS=no
2088 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2089 if test "${with_gnutls}" = "yes" ; then
2090   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2091   if test "${HAVE_GNUTLS}" = "yes"; then
2092     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2093   fi
2094
2095   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2096   LIBS="$LIBGNUTLS_LIBS $LIBS"
2097   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2098
2099   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2100     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2101   fi
2102 fi
2103
2104 AC_SUBST(LIBGNUTLS_LIBS)
2105 AC_SUBST(LIBGNUTLS_CFLAGS)
2106
2107 dnl Do not put whitespace before the #include statements below.
2108 dnl Older compilers (eg sunos4 cc) choke on it.
2109 HAVE_XAW3D=no
2110 LUCID_LIBW=
2111 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2112   if test "$with_xaw3d" != no; then
2113     AC_CACHE_VAL(emacs_cv_xaw3d,
2114     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2115 #include <X11/Intrinsic.h>
2116 #include <X11/Xaw3d/Simple.h>]],
2117       [[]])],
2118       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2119                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2120       emacs_cv_xaw3d=no)])
2121   else
2122     emacs_cv_xaw3d=no
2123   fi
2124   if test $emacs_cv_xaw3d = yes; then
2125     AC_MSG_CHECKING(for xaw3d)
2126     AC_MSG_RESULT([yes; using Lucid toolkit])
2127     USE_X_TOOLKIT=LUCID
2128     HAVE_XAW3D=yes
2129     LUCID_LIBW=-lXaw3d
2130     AC_DEFINE(HAVE_XAW3D, 1,
2131               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2132   else
2133     AC_MSG_CHECKING(for xaw3d)
2134     AC_MSG_RESULT(no)
2135     AC_MSG_CHECKING(for libXaw)
2136     AC_CACHE_VAL(emacs_cv_xaw,
2137     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2138 #include <X11/Intrinsic.h>
2139 #include <X11/Xaw/Simple.h>]],
2140       [[]])],
2141       emacs_cv_xaw=yes,
2142       emacs_cv_xaw=no)])
2143     if test $emacs_cv_xaw = yes; then
2144       AC_MSG_RESULT([yes; using Lucid toolkit])
2145       USE_X_TOOLKIT=LUCID
2146       LUCID_LIBW=-lXaw
2147     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2148       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2149     else
2150       AC_MSG_ERROR([No X toolkit could be found.
2151 If you are sure you want Emacs compiled without an X toolkit, pass
2152   --with-x-toolkit=no
2153 to configure.  Otherwise, install the development libraries for the toolkit
2154 that you want to use (e.g. Gtk+) and re-run configure.])
2155     fi
2156   fi
2157 fi
2158
2159 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2160
2161 LIBXTR6=
2162 if test "${USE_X_TOOLKIT}" != "none"; then
2163   AC_MSG_CHECKING(X11 toolkit version)
2164   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2165   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2166 [[#if XtSpecificationRelease < 6
2167 fail;
2168 #endif
2169 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2170   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2171   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2172     AC_MSG_RESULT(6 or newer)
2173     AC_DEFINE(HAVE_X11XTR6, 1,
2174               [Define to 1 if you have the X11R6 or newer version of Xt.])
2175     LIBXTR6="-lSM -lICE"
2176     case "$opsys" in
2177       ## Use libw.a along with X11R6 Xt.
2178       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2179     esac
2180   else
2181     AC_MSG_RESULT(before 6)
2182   fi
2183
2184 dnl If using toolkit, check whether libXmu.a exists.
2185 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2186   OLDLIBS="$LIBS"
2187   if test x$HAVE_X11XTR6 = xyes; then
2188     LIBS="-lXt -lSM -lICE $LIBS"
2189   else
2190     LIBS="-lXt $LIBS"
2191   fi
2192   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2193   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2194   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2195 fi
2196 AC_SUBST(LIBXTR6)
2197
2198 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2199 dnl Why not just test for libxmu in the normal way?
2200 LIBXMU=-lXmu
2201 case $opsys in
2202   ## These systems don't supply Xmu.
2203   hpux* | aix4-2 )
2204     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2205     ;;
2206 esac
2207 AC_SUBST(LIBXMU)
2208
2209 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2210 if test "${HAVE_X11}" = "yes"; then
2211   if test "${USE_X_TOOLKIT}" != "none"; then
2212     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2213   fi
2214 fi
2215
2216 LIBXP=
2217 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2218   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2219   if test -d /usr/include/openmotif; then
2220     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2221     emacs_cv_openmotif=yes
2222     case "$canonical" in
2223       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2224       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2225       ;;
2226       *)
2227       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2228     esac
2229   else
2230     emacs_cv_openmotif=no
2231   fi
2232   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2233   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2234     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2235 int x = 5;
2236 #else
2237 Motif version prior to 2.1.
2238 #endif]])],
2239     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2240   if test $emacs_cv_motif_version_2_1 = yes; then
2241     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2242     if test x$emacs_cv_openmotif = xyes; then
2243       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2244     fi
2245   else
2246     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2247     # We put this in CFLAGS temporarily to precede other -I options
2248     # that might be in CFLAGS temporarily.
2249     # We put this in CPPFLAGS where it precedes the other -I options.
2250     OLD_CPPFLAGS=$CPPFLAGS
2251     OLD_CFLAGS=$CFLAGS
2252     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2253     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2254     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2255       [[int x = 5;]])],
2256       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2257     if test $emacs_cv_lesstif = yes; then
2258       # Make sure this -I option remains in CPPFLAGS after it is set
2259       # back to REAL_CPPFLAGS.
2260       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2261       # have those other -I options anyway.  Ultimately, having this
2262       # directory ultimately in CPPFLAGS will be enough.
2263       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2264       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2265     else
2266       CFLAGS=$OLD_CFLAGS
2267       CPPFLAGS=$OLD_CPPFLAGS
2268     fi
2269   fi
2270   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2271     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2272 fi
2273
2274 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2275 dnl using Motif or Xaw3d is available, and unless
2276 dnl --with-toolkit-scroll-bars=no was specified.
2277
2278 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2279             [Define to 1 if we should use toolkit scroll bars.])dnl
2280 USE_TOOLKIT_SCROLL_BARS=no
2281 if test "${with_toolkit_scroll_bars}" != "no"; then
2282   if test "${USE_X_TOOLKIT}" != "none"; then
2283     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2284       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2285       HAVE_XAW3D=no
2286       USE_TOOLKIT_SCROLL_BARS=yes
2287     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2288       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2289       USE_TOOLKIT_SCROLL_BARS=yes
2290     fi
2291   elif test "${HAVE_GTK}" = "yes"; then
2292     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2293     USE_TOOLKIT_SCROLL_BARS=yes
2294   elif test "${HAVE_NS}" = "yes"; then
2295     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2296     USE_TOOLKIT_SCROLL_BARS=yes
2297   fi
2298 fi
2299
2300 dnl See if XIM is available.
2301 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2302           #include <X11/Xlib.h>
2303           #include <X11/Xresource.h>]],
2304          [[XIMProc  callback;]])],
2305          [HAVE_XIM=yes
2306          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2307          HAVE_XIM=no)
2308
2309 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2310
2311 if test "${with_xim}" != "no"; then
2312   AC_DEFINE(USE_XIM, 1,
2313             [Define to 1 if we should use XIM, if it is available.])
2314 fi
2315
2316
2317 if test "${HAVE_XIM}" != "no"; then
2318   late_CFLAGS=$CFLAGS
2319   if test "$GCC" = yes; then
2320     CFLAGS="$CFLAGS --pedantic-errors"
2321   fi
2322   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2323 #include <X11/Xlib.h>
2324 #include <X11/Xresource.h>]],
2325 [[Display *display;
2326 XrmDatabase db;
2327 char *res_name;
2328 char *res_class;
2329 XIMProc  callback;
2330 XPointer *client_data;
2331 #ifndef __GNUC__
2332 /* If we're not using GCC, it's probably not XFree86, and this is
2333    probably right, but we can't use something like --pedantic-errors.  */
2334 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2335                                            char*, XIMProc, XPointer*);
2336 #endif
2337 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2338    client_data);]])],
2339     [emacs_cv_arg6_star=yes])
2340   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2341          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2342 either XPointer or XPointer*.])dnl
2343   if test "$emacs_cv_arg6_star" = yes; then
2344     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2345   else
2346     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2347   fi
2348   CFLAGS=$late_CFLAGS
2349 fi
2350
2351 ### Start of font-backend (under any platform) section.
2352 # (nothing here yet -- this is a placeholder)
2353 ### End of font-backend (under any platform) section.
2354
2355 ### Start of font-backend (under X11) section.
2356 if test "${HAVE_X11}" = "yes"; then
2357    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2358
2359    ## Use -lXft if available, unless `--with-xft=no'.
2360    HAVE_XFT=maybe
2361     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2362       with_xft="no";
2363     fi
2364     if test "x${with_xft}" != "xno"; then
2365
2366       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2367       ## Because xftfont.c uses XRenderQueryExtension, we also
2368       ## need to link to -lXrender.
2369       HAVE_XRENDER=no
2370       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2371       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2372         OLD_CPPFLAGS="$CPPFLAGS"
2373         OLD_CFLAGS="$CFLAGS"
2374         OLD_LIBS="$LIBS"
2375         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2376         CFLAGS="$CFLAGS $XFT_CFLAGS"
2377         XFT_LIBS="-lXrender $XFT_LIBS"
2378         LIBS="$XFT_LIBS $LIBS"
2379         AC_CHECK_HEADER(X11/Xft/Xft.h,
2380           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2381
2382         if test "${HAVE_XFT}" = "yes"; then
2383           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2384             AC_SUBST(XFT_LIBS)
2385           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2386         else
2387           CPPFLAGS="$OLD_CPPFLAGS"
2388           CFLAGS="$OLD_CFLAGS"
2389           LIBS="$OLD_LIBS"
2390         fi                        # "${HAVE_XFT}" = "yes"
2391       fi                          # "$HAVE_XFT" != no
2392     fi                            # "x${with_xft}" != "xno"
2393
2394     ## We used to allow building with FreeType and without Xft.
2395     ## However, the ftx font backend driver is not in good shape.
2396     if test "$HAVE_XFT" != "yes"; then
2397        dnl For the "Does Emacs use" message at the end.
2398        HAVE_XFT=no
2399        HAVE_FREETYPE=no
2400     else
2401        dnl Strict linkers fail with
2402        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2403        dnl if -lfreetype is not specified.
2404        dnl The following is needed to set FREETYPE_LIBS.
2405        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2406                          HAVE_FREETYPE=no)
2407
2408        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2409     fi
2410
2411     HAVE_LIBOTF=no
2412     if test "${HAVE_FREETYPE}" = "yes"; then
2413       AC_DEFINE(HAVE_FREETYPE, 1,
2414                 [Define to 1 if using the freetype and fontconfig libraries.])
2415       if test "${with_libotf}" != "no"; then
2416         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2417                           HAVE_LIBOTF=no)
2418         if test "$HAVE_LIBOTF" = "yes"; then
2419           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2420           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2421                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2422                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2423           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2424             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2425                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2426           fi
2427         fi
2428       fi
2429     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2430     dnl Does the new font backend require it, or can it work without it?
2431     fi
2432
2433     HAVE_M17N_FLT=no
2434     if test "${HAVE_LIBOTF}" = yes; then
2435       if test "${with_m17n_flt}" != "no"; then
2436         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2437         if test "$HAVE_M17N_FLT" = "yes"; then
2438           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2439         fi
2440       fi
2441     fi
2442 else
2443     HAVE_XFT=no
2444     HAVE_FREETYPE=no
2445     HAVE_LIBOTF=no
2446     HAVE_M17N_FLT=no
2447 fi
2448
2449 ### End of font-backend (under X11) section.
2450
2451 AC_SUBST(FREETYPE_CFLAGS)
2452 AC_SUBST(FREETYPE_LIBS)
2453 AC_SUBST(FONTCONFIG_CFLAGS)
2454 AC_SUBST(FONTCONFIG_LIBS)
2455 AC_SUBST(LIBOTF_CFLAGS)
2456 AC_SUBST(LIBOTF_LIBS)
2457 AC_SUBST(M17N_FLT_CFLAGS)
2458 AC_SUBST(M17N_FLT_LIBS)
2459
2460 ### Use -lXpm if available, unless `--with-xpm=no'.
2461 HAVE_XPM=no
2462 LIBXPM=
2463 if test "${HAVE_X11}" = "yes"; then
2464   if test "${with_xpm}" != "no"; then
2465     AC_CHECK_HEADER(X11/xpm.h,
2466       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2467     if test "${HAVE_XPM}" = "yes"; then
2468       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2469       AC_EGREP_CPP(no_return_alloc_pixels,
2470       [#include "X11/xpm.h"
2471 #ifndef XpmReturnAllocPixels
2472 no_return_alloc_pixels
2473 #endif
2474       ], HAVE_XPM=no, HAVE_XPM=yes)
2475
2476       if test "${HAVE_XPM}" = "yes"; then
2477         AC_MSG_RESULT(yes)
2478       else
2479         AC_MSG_RESULT(no)
2480       fi
2481     fi
2482   fi
2483
2484   if test "${HAVE_XPM}" = "yes"; then
2485     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2486     LIBXPM=-lXpm
2487   fi
2488 fi
2489 AC_SUBST(LIBXPM)
2490
2491 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2492 HAVE_JPEG=no
2493 LIBJPEG=
2494 if test "${HAVE_X11}" = "yes"; then
2495   if test "${with_jpeg}" != "no"; then
2496     dnl Checking for jpeglib.h can lose because of a redefinition of
2497     dnl  HAVE_STDLIB_H.
2498     AC_CHECK_HEADER(jerror.h,
2499       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2500   fi
2501
2502   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2503   if test "${HAVE_JPEG}" = "yes"; then
2504     AC_DEFINE(HAVE_JPEG)
2505     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2506         [#include <jpeglib.h>
2507          version=JPEG_LIB_VERSION
2508 ],
2509         [AC_DEFINE(HAVE_JPEG)],
2510         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2511         HAVE_JPEG=no])
2512   fi
2513   if test "${HAVE_JPEG}" = "yes"; then
2514     LIBJPEG=-ljpeg
2515   fi
2516 fi
2517 AC_SUBST(LIBJPEG)
2518
2519 ### Use -lpng if available, unless `--with-png=no'.
2520 HAVE_PNG=no
2521 LIBPNG=
2522 if test "${HAVE_X11}" = "yes"; then
2523   if test "${with_png}" != "no"; then
2524     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2525     # in /usr/include/libpng.
2526     AC_CHECK_HEADERS(png.h libpng/png.h, break)
2527     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2528       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2529     fi
2530   fi
2531
2532   if test "${HAVE_PNG}" = "yes"; then
2533     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2534     LIBPNG="-lpng -lz -lm"
2535
2536     AC_CHECK_DECL(png_longjmp,
2537       [],
2538       [AC_DEFINE(PNG_DEPSTRUCT, [],
2539          [Define to empty to suppress deprecation warnings when building
2540           with --enable-gcc-warnings and with libpng versions before 1.5,
2541           which lack png_longjmp.])],
2542       [[#ifdef HAVE_LIBPNG_PNG_H
2543         # include <libpng/png.h>
2544         #else
2545         # include <png.h>
2546         #endif
2547       ]])
2548   fi
2549 fi
2550 AC_SUBST(LIBPNG)
2551
2552 ### Use -ltiff if available, unless `--with-tiff=no'.
2553 HAVE_TIFF=no
2554 LIBTIFF=
2555 if test "${HAVE_X11}" = "yes"; then
2556   if test "${with_tiff}" != "no"; then
2557     AC_CHECK_HEADER(tiffio.h,
2558       [tifflibs="-lz -lm"
2559       # At least one tiff package requires the jpeg library.
2560       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2561       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2562   fi
2563
2564   if test "${HAVE_TIFF}" = "yes"; then
2565     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2566     dnl FIXME -lz -lm, as per libpng?
2567     LIBTIFF=-ltiff
2568   fi
2569 fi
2570 AC_SUBST(LIBTIFF)
2571
2572 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2573 HAVE_GIF=no
2574 LIBGIF=
2575 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2576   AC_CHECK_HEADER(gif_lib.h,
2577 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2578 # Earlier versions can crash Emacs.
2579     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2580
2581   if test "$HAVE_GIF" = yes; then
2582     LIBGIF=-lgif
2583   elif test "$HAVE_GIF" = maybe; then
2584 # If gif_lib.h but no libgif, try libungif.
2585     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2586     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2587   fi
2588
2589   if test "${HAVE_GIF}" = "yes"; then
2590     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2591   fi
2592 fi
2593 AC_SUBST(LIBGIF)
2594
2595 dnl Check for required libraries.
2596 if test "${HAVE_X11}" = "yes"; then
2597   MISSING=""
2598   WITH_NO=""
2599   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2600     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2601   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2602     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2603   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2604     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2605   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2606     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2607   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2608     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2609
2610   if test "X${MISSING}" != X; then
2611     AC_MSG_ERROR([The following required libraries were not found:
2612     $MISSING
2613 Maybe some development libraries/packages are missing?
2614 If you don't want to link with them give
2615     $WITH_NO
2616 as options to configure])
2617   fi
2618 fi
2619
2620 ### Use -lgpm if available, unless `--with-gpm=no'.
2621 HAVE_GPM=no
2622 LIBGPM=
2623 if test "${with_gpm}" != "no"; then
2624   AC_CHECK_HEADER(gpm.h,
2625     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2626
2627   if test "${HAVE_GPM}" = "yes"; then
2628     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2629     LIBGPM=-lgpm
2630   fi
2631 fi
2632 AC_SUBST(LIBGPM)
2633
2634 dnl Check for malloc/malloc.h on darwin
2635 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2636
2637 GNUSTEP_CFLAGS=
2638 ### Use NeXTstep API to implement GUI.
2639 if test "${HAVE_NS}" = "yes"; then
2640   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2641   if test "${NS_IMPL_COCOA}" = "yes"; then
2642     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2643   fi
2644   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2645     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2646     # See also .m.o rule in Makefile.in */
2647     # FIXME: are all these flags really needed?  Document here why.  */
2648     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2649     ## Extra CFLAGS applied to src/*.m files.
2650     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2651   fi
2652   # We also have mouse menus.
2653   HAVE_MENUS=yes
2654   OTHER_FILES=ns-app
2655 fi
2656
2657
2658 ### Use session management (-lSM -lICE) if available
2659 HAVE_X_SM=no
2660 LIBXSM=
2661 if test "${HAVE_X11}" = "yes"; then
2662   AC_CHECK_HEADER(X11/SM/SMlib.h,
2663     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2664
2665   if test "${HAVE_X_SM}" = "yes"; then
2666     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2667     LIBXSM="-lSM -lICE"
2668     case "$LIBS" in
2669       *-lSM*) ;;
2670       *)      LIBS="$LIBXSM $LIBS" ;;
2671     esac
2672   fi
2673 fi
2674 AC_SUBST(LIBXSM)
2675
2676 ### Use libxml (-lxml2) if available
2677 HAVE_LIBXML2=no
2678 if test "${with_xml2}" != "no"; then
2679   ### I'm not sure what the version number should be, so I just guessed.
2680   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2681   if test "${HAVE_LIBXML2}" = "yes"; then
2682     LIBS="$LIBXML2_LIBS $LIBS"
2683     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2684     if test "${HAVE_LIBXML2}" = "yes"; then
2685       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2686     else
2687       LIBXML2_LIBS=""
2688       LIBXML2_CFLAGS=""
2689     fi
2690   fi
2691 fi
2692 AC_SUBST(LIBXML2_LIBS)
2693 AC_SUBST(LIBXML2_CFLAGS)
2694
2695 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2696 AC_CACHE_CHECK(whether netdb declares h_errno,
2697                emacs_cv_netdb_declares_h_errno,
2698 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2699   [[return h_errno;]])],
2700   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2701 if test $emacs_cv_netdb_declares_h_errno = yes; then
2702   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2703 fi
2704
2705 # sqrt and other floating-point functions such as fmod and frexp
2706 # are found in -lm on most systems.
2707 AC_CHECK_LIB(m, sqrt)
2708
2709 # Check for mail-locking functions in a "mail" library.  Probably this should
2710 # have the same check as for liblockfile below.
2711 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2712 if test $have_mail = yes; then
2713   LIBS_MAIL=-lmail
2714   LIBS="$LIBS_MAIL $LIBS"
2715   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2716 else
2717   LIBS_MAIL=
2718 fi
2719 dnl Debian, at least:
2720 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2721 if test $have_lockfile = yes; then
2722    LIBS_MAIL=-llockfile
2723    LIBS="$LIBS_MAIL $LIBS"
2724    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2725 else
2726 # If we have the shared liblockfile, assume we must use it for mail
2727 # locking (e.g. Debian).  If we couldn't link against liblockfile
2728 # (no liblockfile.a installed), ensure that we don't need to.
2729   dnl This works for files generally, not just executables.
2730   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2731   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2732                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2733   if test $ac_cv_prog_liblockfile = yes; then
2734     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2735 This probably means that movemail could lose mail.
2736 There may be a `development' package to install containing liblockfile.])
2737   fi
2738 fi
2739 AC_CHECK_HEADERS_ONCE(maillock.h)
2740 AC_SUBST(LIBS_MAIL)
2741
2742 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2743 ## interlock access to the mail spool.  The alternative is a lock file named
2744 ## /usr/spool/mail/$USER.lock.
2745 mail_lock=no
2746 case "$opsys" in
2747   aix4-2) mail_lock="lockf" ;;
2748
2749   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2750
2751   ## On GNU/Linux systems, both methods are used by various mail programs.
2752   ## I assume most people are using newer mailers that have heard of flock.
2753   ## Change this if you need to.
2754   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2755   ## configure gets the right answers, and that means *NOT* using flock.
2756   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2757   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2758   ## Debian maintainer hasn't provided a clean fix for Emacs.
2759   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2760   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2761   ## correct logic.  -- fx
2762   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2763   ## liblockfile is a Free Software replacement for libmail, used on
2764   ## Debian systems and elsewhere. -rfr.
2765   gnu-*)
2766     mail_lock="flock"
2767     if test $have_mail = yes || test $have_lockfile = yes; then
2768       test $ac_cv_header_maillock_h = yes && mail_lock=no
2769     fi
2770     ;;
2771 esac
2772
2773 BLESSMAIL_TARGET=
2774 case "$mail_lock" in
2775   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2776
2777   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2778
2779   *) BLESSMAIL_TARGET="need-blessmail" ;;
2780 esac
2781 AC_SUBST(BLESSMAIL_TARGET)
2782
2783
2784 AC_CHECK_FUNCS(gethostname \
2785 closedir getrusage get_current_dir_name \
2786 lrand48 setsid \
2787 fpathconf select euidaccess getpagesize setlocale \
2788 utimes getrlimit setrlimit setpgid getcwd shutdown getaddrinfo \
2789 __fpending strsignal setitimer \
2790 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
2791 gai_strerror mkstemp getline getdelim fsync sync \
2792 difftime posix_memalign \
2793 getpwent endpwent getgrent endgrent \
2794 touchlock \
2795 cfmakeraw cfsetspeed copysign __executable_start)
2796
2797 dnl getwd appears to be buggy on SVR4.2, so we don't use it.
2798 if test $opsys = unixware; then
2799   dnl In case some other test ends up checking for getwd.
2800   AC_DEFINE(BROKEN_GETWD, 1, [Define if getwd should not be used.])
2801 else
2802   AC_CHECK_FUNCS(getwd)
2803 fi
2804
2805 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
2806 ## has a broken `rint' in some library versions including math library
2807 ## version number A.09.05.
2808 ## You can fix the math library by installing patch number PHSS_4630.
2809 ## But we can fix it more reliably for Emacs by just not using rint.
2810 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
2811 case $opsys in
2812    hpux*) : ;;
2813    *) AC_CHECK_FUNCS(random rint) ;;
2814 esac
2815
2816 dnl Cannot use AC_CHECK_FUNCS
2817 AC_CACHE_CHECK([for __builtin_unwind_init],
2818                emacs_cv_func___builtin_unwind_init,
2819 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2820                 emacs_cv_func___builtin_unwind_init=yes,
2821                 emacs_cv_func___builtin_unwind_init=no)])
2822 if test $emacs_cv_func___builtin_unwind_init = yes; then
2823   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2824             [Define to 1 if you have the `__builtin_unwind_init' function.])
2825 fi
2826
2827 AC_CHECK_HEADERS_ONCE(sys/un.h)
2828
2829 AC_FUNC_FSEEKO
2830
2831 AC_FUNC_GETPGRP
2832
2833 # UNIX98 PTYs.
2834 AC_CHECK_FUNCS(grantpt)
2835
2836 # PTY-related GNU extensions.
2837 AC_CHECK_FUNCS(getpt posix_openpt)
2838
2839 # Check this now, so that we will NOT find the above functions in ncurses.
2840 # That is because we have not set up to link ncurses in lib-src.
2841 # It's better to believe a function is not available
2842 # than to expect to find it in ncurses.
2843 # Also we need tputs and friends to be able to build at all.
2844 AC_MSG_CHECKING([for library containing tputs])
2845 # Run a test program that contains a call to tputs, a call that is
2846 # never executed.  This tests whether a pre-'main' dynamic linker
2847 # works with the library.  It's too much trouble to actually call
2848 # tputs in the test program, due to portability hassles.  When
2849 # cross-compiling, assume the test program will run if it links.
2850 AC_DEFUN([tputs_link_source], [
2851   AC_LANG_SOURCE(
2852      [[extern void tputs (const char *, int, int (*)(int));
2853        int main (int argc, char **argv)
2854        {
2855           if (argc == 10000)
2856             tputs (argv[0], 0, 0);
2857           return 0;
2858        }]])
2859 ])
2860 # Maybe curses should be tried earlier?
2861 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2862 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2863   OLIBS=$LIBS
2864   if test -z "$tputs_library"; then
2865     LIBS_TERMCAP=
2866     msg='none required'
2867   else
2868     LIBS_TERMCAP=-l$tputs_library
2869     msg=$LIBS_TERMCAP
2870     LIBS="$LIBS_TERMCAP $LIBS"
2871   fi
2872   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2873     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2874   LIBS=$OLIBS
2875   if test "X$msg" != Xno; then
2876     break
2877   fi
2878 done
2879 AC_MSG_RESULT([$msg])
2880 if test "X$msg" = Xno; then
2881   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2882 The following libraries were tried (in order):
2883   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2884 Please try installing whichever of these libraries is most appropriate
2885 for your system, together with its header files.
2886 For example, a libncurses-dev(el) or similar package.])
2887 fi
2888
2889 ## Use termcap instead of terminfo?
2890 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2891 TERMINFO=yes
2892 ## FIXME?  In the cases below where we unconditionally set
2893 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2894 ## if that was found above to have tputs.
2895 ## Should we use the gnu* logic everywhere?
2896 case "$opsys" in
2897   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2898   ##  The ncurses library has been moved out of the System framework in
2899   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2900   ##  option to use it.
2901   darwin) LIBS_TERMCAP="-lncurses" ;;
2902
2903   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2904
2905   freebsd)
2906     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2907     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2908     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2909 [[#if __FreeBSD_version < 400000
2910 fail;
2911 #endif
2912 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2913
2914     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2915
2916     if test $emacs_cv_freebsd_terminfo = yes; then
2917       LIBS_TERMCAP="-lncurses"
2918     else
2919       TERMINFO=no
2920       LIBS_TERMCAP="-ltermcap"
2921     fi
2922     ;;
2923
2924   netbsd)
2925     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2926       TERMINFO=no
2927       LIBS_TERMCAP="-ltermcap"
2928     fi
2929     ;;
2930
2931   openbsd) LIBS_TERMCAP="-lncurses" ;;
2932
2933   ## hpux: Make sure we get select from libc rather than from libcurses
2934   ##  because libcurses on HPUX 10.10 has a broken version of select.
2935   ##  We used to use -lc -lcurses, but this may be cleaner.
2936   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2937   # set that way, now it uses the default).  Isn't this a contradiction?
2938   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2939
2940 esac
2941
2942 TERMCAP_OBJ=tparam.o
2943 if test $TERMINFO = yes; then
2944   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2945   TERMCAP_OBJ=terminfo.o
2946 fi
2947 AC_SUBST(LIBS_TERMCAP)
2948 AC_SUBST(TERMCAP_OBJ)
2949
2950
2951 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2952 # On Darwin, res_init appears not to be useful: see bug#562 and
2953 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
2954 resolv=no
2955
2956 if test $opsys != darwin; then
2957
2958   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2959 #include <arpa/nameser.h>
2960 #include <resolv.h>]],
2961     [[return res_init();]])],
2962     have_res_init=yes, have_res_init=no)
2963   if test "$have_res_init" = no; then
2964     OLIBS="$LIBS"
2965     LIBS="$LIBS -lresolv"
2966     AC_MSG_CHECKING(for res_init with -lresolv)
2967     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2968 #include <arpa/nameser.h>
2969 #include <resolv.h>]],
2970       [[return res_init();]])],
2971       have_res_init=yes, have_res_init=no)
2972     AC_MSG_RESULT($have_res_init)
2973     if test "$have_res_init" = yes ; then
2974       resolv=yes
2975     fi
2976     LIBS="$OLIBS"
2977   fi
2978
2979   if test "$have_res_init" = yes; then
2980     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2981   fi
2982 fi                              dnl !darwin
2983
2984 # Do we need the Hesiod library to provide the support routines?
2985 dnl FIXME?  Should we be skipping this on Darwin too?
2986 LIBHESIOD=
2987 if test "$with_hesiod" != no ; then
2988   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2989   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2990      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2991                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2992   if test "$resolv" = yes ; then
2993     RESOLVLIB=-lresolv
2994   else
2995     RESOLVLIB=
2996   fi
2997   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2998         hesiod=yes, :, $RESOLVLIB)])
2999
3000   if test x"$hesiod" = xyes; then
3001     AC_DEFINE(HAVE_LIBHESIOD, 1,
3002               [Define to 1 if you have the hesiod library (-lhesiod).])
3003     LIBHESIOD=-lhesiod
3004   fi
3005 fi
3006 AC_SUBST(LIBHESIOD)
3007
3008 # Do we need libresolv (due to res_init or Hesiod)?
3009 if test "$resolv" = yes && test $opsys != darwin; then
3010   AC_DEFINE(HAVE_LIBRESOLV, 1,
3011             [Define to 1 if you have the resolv library (-lresolv).])
3012   LIBRESOLV=-lresolv
3013 else
3014   LIBRESOLV=
3015 fi
3016 AC_SUBST(LIBRESOLV)
3017
3018 # These tell us which Kerberos-related libraries to use.
3019 COM_ERRLIB=
3020 CRYPTOLIB=
3021 KRB5LIB=
3022 DESLIB=
3023 KRB4LIB=
3024
3025 if test "${with_kerberos}" != no; then
3026   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3027   if test $have_com_err = yes; then
3028     COM_ERRLIB=-lcom_err
3029     LIBS="$COM_ERRLIB $LIBS"
3030     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
3031   fi
3032   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3033   if test $have_crypto = yes; then
3034     CRYPTOLIB=-lcrypto
3035     LIBS="$CRYPTOLIB $LIBS"
3036     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
3037   fi
3038   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3039   if test $have_k5crypto = yes; then
3040     CRYPTOLIB=-lk5crypto
3041     LIBS="$CRYPTOLIB $LIBS"
3042     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
3043   fi
3044   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3045   if test $have_krb5=yes; then
3046     KRB5LIB=-lkrb5
3047     LIBS="$KRB5LIB $LIBS"
3048     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
3049   fi
3050   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3051   if test "${with_kerberos5}" = no; then
3052     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3053     if test $have_des425 = yes; then
3054       DESLIB=-ldes425
3055       LIBS="$DESLIB $LIBS"
3056       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
3057     else
3058       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3059       if test $have_des = yes; then
3060         DESLIB=-ldes
3061         LIBS="$DESLIB $LIBS"
3062         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
3063       fi
3064     fi
3065     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3066     if test $have_krb4 = yes; then
3067       KRB4LIB=-lkrb4
3068       LIBS="$KRB4LIB $LIBS"
3069       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
3070     else
3071       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3072       if test $have_krb = yes; then
3073         KRB4LIB=-lkrb
3074         LIBS="$KRB4LIB $LIBS"
3075         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3076       fi
3077     fi
3078   fi
3079
3080   if test "${with_kerberos5}" != no; then
3081     AC_CHECK_HEADERS(krb5.h,
3082       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3083                         [#include <krb5.h>])])
3084   else
3085     AC_CHECK_HEADERS(des.h,,
3086                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3087                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3088     AC_CHECK_HEADERS(krb.h,,
3089                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3090                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3091   fi
3092   AC_CHECK_HEADERS(com_err.h)
3093 fi
3094
3095 AC_SUBST(COM_ERRLIB)
3096 AC_SUBST(CRYPTOLIB)
3097 AC_SUBST(KRB5LIB)
3098 AC_SUBST(DESLIB)
3099 AC_SUBST(KRB4LIB)
3100
3101 AC_CHECK_FUNCS_ONCE(tzset)
3102 AC_MSG_CHECKING(whether localtime caches TZ)
3103 AC_CACHE_VAL(emacs_cv_localtime_cache,
3104 [if test x$ac_cv_func_tzset = xyes; then
3105 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3106 char TZ_GMT0[] = "TZ=GMT0";
3107 char TZ_PST8[] = "TZ=PST8";
3108 main()
3109 {
3110   time_t now = time ((time_t *) 0);
3111   int hour_GMT0, hour_unset;
3112   if (putenv (TZ_GMT0) != 0)
3113     exit (1);
3114   hour_GMT0 = localtime (&now)->tm_hour;
3115   unsetenv("TZ");
3116   hour_unset = localtime (&now)->tm_hour;
3117   if (putenv (TZ_PST8) != 0)
3118     exit (1);
3119   if (localtime (&now)->tm_hour == hour_GMT0)
3120     exit (1);
3121   unsetenv("TZ");
3122   if (localtime (&now)->tm_hour != hour_unset)
3123     exit (1);
3124   exit (0);
3125 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3126 [# If we have tzset, assume the worst when cross-compiling.
3127 emacs_cv_localtime_cache=yes])
3128 else
3129         # If we lack tzset, report that localtime does not cache TZ,
3130         # since we can't invalidate the cache if we don't have tzset.
3131         emacs_cv_localtime_cache=no
3132 fi])dnl
3133 AC_MSG_RESULT($emacs_cv_localtime_cache)
3134 if test $emacs_cv_localtime_cache = yes; then
3135   AC_DEFINE(LOCALTIME_CACHE, 1,
3136             [Define to 1 if localtime caches TZ.])
3137 fi
3138
3139 ok_so_far=yes
3140 AC_CHECK_FUNC(socket, , ok_so_far=no)
3141 if test $ok_so_far = yes; then
3142   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3143 fi
3144 if test $ok_so_far = yes; then
3145   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3146 fi
3147 if test $ok_so_far = yes; then
3148 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3149   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3150             [Define to 1 if you have inet sockets.])
3151 fi
3152
3153 if test -f /usr/lpp/X11/bin/smt.exp; then
3154   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3155             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3156 fi
3157
3158 AC_MSG_CHECKING(whether system supports dynamic ptys)
3159 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3160   AC_MSG_RESULT(yes)
3161   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3162 else
3163   AC_MSG_RESULT(no)
3164 fi
3165
3166 AC_FUNC_FORK
3167
3168 AC_CHECK_FUNCS(snprintf)
3169
3170 dnl Adapted from Haible's version.
3171 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3172   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3173     [[char* cs = nl_langinfo(CODESET);]])],
3174     emacs_cv_langinfo_codeset=yes,
3175     emacs_cv_langinfo_codeset=no)
3176   ])
3177 if test $emacs_cv_langinfo_codeset = yes; then
3178   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3179     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3180 fi
3181
3182 AC_TYPE_MBSTATE_T
3183
3184 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3185   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3186                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3187 if test "$emacs_cv_c_restrict_arr" = yes; then
3188   AC_DEFINE(__restrict_arr, __restrict,
3189     [Define to compiler's equivalent of C99 restrict keyword in array
3190      declarations.  Define as empty for no equivalent.])
3191 fi
3192
3193 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3194 dnl how the tty code is related to POSIX and/or other versions of termios.
3195 dnl The following looks like a useful start.
3196 dnl
3197 dnl AC_SYS_POSIX_TERMIOS
3198 dnl if test $ac_cv_sys_posix_termios = yes; then
3199 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3200 dnl                                and macros for terminal control.])
3201 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3202 dnl fi
3203
3204 dnl Turned on June 1996 supposing nobody will mind it.
3205 AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3206   in the full name stands for the login id.])
3207
3208 dnl Every platform that uses configure (ie every non-MS platform)
3209 dnl supports this.  There is a create-lockfiles option you can
3210 dnl customize if you do not want the lock files to be written.
3211 dnl So it is not clear that this #define still needs to exist.
3212 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3213   so that Emacs can tell instantly when you try to modify a file that
3214   someone else has modified in his/her Emacs.])
3215
3216 dnl Everybody supports this, except MS.
3217 dnl Seems like the kind of thing we should be testing for, though.
3218 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3219 AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3220
3221 dnl Everybody supports this, except MS-DOS.
3222 dnl Seems like the kind of thing we should be testing for, though.
3223 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3224 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3225   4.2-compatible sockets.])
3226
3227 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3228
3229 AC_DEFINE(NULL_DEVICE, ["/dev/null"], [Name of the file to open to get
3230   a null file, or a data sink.])
3231
3232 AC_DEFINE(SEPCHAR, [':'], [Character that separates PATH elements.])
3233
3234 dnl Everybody supports this, except MS-DOS.
3235 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3236
3237 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3238
3239
3240 AC_DEFINE(DIRECTORY_SEP, ['/'],
3241   [Character that separates directories in a file name.])
3242
3243 dnl Only used on MS platforms.
3244 AH_TEMPLATE(DEVICE_SEP, [Character that separates a device in a file name.])
3245
3246 AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3247   [Returns true if character is a device separator.])
3248
3249 AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3250   [Returns true if character is a directory separator.])
3251
3252 dnl On MS, this also accepts IS_DEVICE_SEP.
3253 AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3254   [Returns true if character is any form of separator.])
3255
3256
3257 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3258
3259 case $opsys in
3260   aix4-2)
3261     dnl Unfortunately without libXmu we cannot support EditRes.
3262     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
3263       AC_DEFINE(NO_EDITRES, 1)
3264     fi
3265     ;;
3266
3267   hpux*)
3268     dnl Assar Westerlund <assar@sics.se> says this is necessary for
3269     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
3270     AC_DEFINE(NO_EDITRES, 1)
3271     ;;
3272 esac
3273
3274
3275 case $opsys in
3276   irix6-5 | sol2* | unixware )
3277     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
3278     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
3279     dnl need the constant to dimension an array.  So wire in the appropriate
3280     dnl value here.
3281     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
3282     ;;
3283 esac
3284
3285 emacs_broken_SIGIO=no
3286
3287 case $opsys in
3288   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3289   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3290   hpux* | irix6-5 | openbsd | sol2* | unixware )
3291     emacs_broken_SIGIO=yes
3292     ;;
3293
3294   aix4-2)
3295     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
3296     dnl the way this system works, libc functions that return malloced
3297     dnl memory use the libc malloc implementation. Calling xfree or
3298     dnl xrealloc on the results of such functions results in a crash.
3299     dnl
3300     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
3301     dnl but that does not currently work on this system.
3302     dnl
3303     dnl It is possible to completely override the malloc implementation on
3304     dnl AIX, but that involves putting the malloc functions in a shared
3305     dnl library and setting the MALLOCTYPE environment variable to point to
3306     dnl that shared library.
3307     dnl
3308     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
3309     dnl to avoid a crash just use the Emacs implementation for that function.
3310     dnl
3311     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
3312     dnl of this file, so that we do not check for get_current_dir_name
3313     dnl on AIX.  But that might be fragile if something else ends
3314     dnl up testing for get_current_dir_name as a dependency.
3315     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
3316       get_current_dir_name should not be used.])
3317     ;;
3318
3319   freebsd)
3320     dnl Circumvent a bug in FreeBSD.  In the following sequence of
3321     dnl writes/reads on a PTY, read(2) returns bogus data:
3322     dnl
3323     dnl write(2)  1022 bytes
3324     dnl write(2)   954 bytes, get EAGAIN
3325     dnl read(2)   1024 bytes in process_read_output
3326     dnl read(2)     11 bytes in process_read_output
3327     dnl
3328     dnl That is, read(2) returns more bytes than have ever been written
3329     dnl successfully.  The 1033 bytes read are the 1022 bytes written
3330     dnl successfully after processing (for example with CRs added if the
3331     dnl terminal is set up that way which it is here).  The same bytes will
3332     dnl be seen again in a later read(2), without the CRs.
3333     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
3334       work around an issue when reading from a PTY.])
3335     ;;
3336 esac
3337
3338 case $opsys in
3339   gnu-* | sol2-10 )
3340     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3341     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3342   ;;
3343 esac
3344
3345 case $opsys in
3346   darwin | freebsd | netbsd | openbsd )
3347     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
3348       close a pty to make it a controlling terminal (it is already a
3349       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
3350   ;;
3351 esac
3352
3353 dnl FIXME Surely we can test for this rather than hard-code it.
3354 case $opsys in
3355   netbsd | openbsd) sound_device="/dev/audio" ;;
3356   *) sound_device="/dev/dsp" ;;
3357 esac
3358
3359 dnl Used in sound.c
3360 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
3361   [Name of the default sound device.])
3362
3363
3364 dnl Emacs can read input using SIGIO and buffering characters itself,
3365 dnl or using CBREAK mode and making C-g cause SIGINT.
3366 dnl The choice is controlled by the variable interrupt_input.
3367 dnl
3368 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
3369 dnl
3370 dnl Emacs uses the presence of the USABLE_SIGIO macro
3371 dnl to indicate whether or not signal-driven I/O is possible.  It uses
3372 dnl INTERRUPT_INPUT to decide whether to use it by default.
3373 dnl
3374 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
3375 dnl CBREAK mode has two disadvantages
3376 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
3377 dnl I hear that in system V this problem does not exist.
3378 dnl 2) Control-G causes output to be discarded.
3379 dnl I do not know whether this can be fixed in system V.
3380 dnl
3381 dnl Another method of doing input is planned but not implemented.
3382 dnl It would have Emacs fork off a separate process
3383 dnl to read the input and send it to the true Emacs process
3384 dnl through a pipe.
3385 case $opsys in
3386   darwin | gnu-linux | gnu-kfreebsd )
3387     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
3388   ;;
3389 esac
3390
3391
3392 dnl If the system's imake configuration file defines `NeedWidePrototypes'
3393 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
3394 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
3395 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
3396 dnl taking float or double parameters.
3397 case $opsys in
3398   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
3399     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
3400       file defines `NeedWidePrototypes' as `NO'.])
3401   ;;
3402 esac
3403
3404
3405 dnl Used in process.c, this must be a loop, even if it only runs once.
3406 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
3407 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
3408 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
3409 dnl trying suffixes 0-16.
3410 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
3411   first PTY, if PTYs are supported.])
3412 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
3413 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
3414   end of a PTY, if non-standard.])
3415 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
3416   end of a PTY, if non-standard.])
3417
3418 case $opsys in
3419   aix4-2 )
3420     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
3421     dnl You allocate a pty by opening /dev/ptc to get the master side.
3422     dnl To get the name of the slave side, you just ttyname() the master side.
3423     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
3424     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
3425     ;;
3426
3427   cygwin )
3428     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3429     dnl multi-line AC_DEFINEs are hard. :(
3430     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (0)])
3431     AC_DEFINE(PTY_NAME_SPRINTF, [])
3432     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3433     ;;
3434
3435   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
3436   darwin )
3437     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3438     dnl Not used, because PTY_ITERATION is defined.
3439     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3440     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
3441     dnl But we don't have to block SIGCHLD because it is blocked in the
3442     dnl implementation of grantpt.
3443     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (0)])
3444     AC_DEFINE(PTY_NAME_SPRINTF, [])
3445     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3446     ;;
3447
3448   gnu | openbsd )
3449     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3450     ;;
3451
3452   gnu-linux | gnu-kfreebsd | freebsd | netbsd )
3453     dnl if HAVE_GRANTPT
3454     if test "x$ac_cv_func_grantpt" = xyes; then
3455       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
3456       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3457       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
3458       dnl to prevent sigchld_handler from intercepting the child's death.
3459       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3460       dnl if HAVE_POSIX_OPENPT
3461       if test "x$ac_cv_func_posix_openpt" = xyes; then
3462         AC_DEFINE(PTY_OPEN, [fd = posix_openpt (O_RDWR | O_NOCTTY)])
3463         AC_DEFINE(PTY_NAME_SPRINTF, [])
3464       dnl if HAVE_GETPT
3465       elif test "x$ac_cv_func_getpt" = xyes; then
3466         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
3467         AC_DEFINE(PTY_NAME_SPRINTF, [])
3468       else
3469         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3470       fi
3471     else
3472       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3473     fi
3474     ;;
3475
3476   hpux*)
3477     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3478     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
3479     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
3480     ;;
3481
3482   irix6-5 )
3483     dnl It looks like this cannot be right, because it is not a loop.
3484     dnl However, process.c actually does this:
3485     dnl # ifndef __sgi
3486     dnl   continue;
3487     dnl # else
3488     dnl   return -1;
3489     dnl # endif
3490     dnl which presumably makes it OK, since irix == sgi (?).
3491     dnl FIXME it seems like this special treatment is unnecessary?
3492     dnl Why can't irix use a single-trip loop like eg cygwin?
3493     AC_DEFINE(PTY_ITERATION, [])
3494     dnl Not used, because PTY_ITERATION is defined.
3495     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
3496     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
3497     dnl No need to get the pty name at all.
3498     AC_DEFINE(PTY_NAME_SPRINTF, [])
3499     dnl No need to use sprintf to get the tty name--we get that from _getpty.
3500     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3501     ;;
3502
3503   sol2* )
3504     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
3505     dnl from intercepting that death.  If any child but grantpt's should die
3506     dnl within, it should be caught after sigrelse(2).
3507     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3508     ;;
3509
3510   unixware )
3511     dnl Comments are as per sol2*.
3512     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3513     ;;
3514 esac
3515
3516
3517 case $opsys in
3518   sol2* | unixware )
3519     dnl This change means that we don't loop through allocate_pty too
3520     dnl many times in the (rare) event of a failure.
3521     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
3522     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3523     dnl Push various streams modules onto a PTY channel.  Used in process.c.
3524     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
3525     ;;
3526 esac
3527
3528
3529 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
3530 "typing" a signal character on the pty.])
3531
3532 case $opsys in
3533   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
3534   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
3535   aix4-2 | cygwin | gnu | irix6-5 | freebsd | netbsd | openbsd )
3536     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3537     ;;
3538
3539   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
3540   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
3541   gnu-linux | gnu-kfreebsd )
3542
3543     AC_MSG_CHECKING([for signals via characters])
3544     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3545 #include <linux/version.h>
3546 #if LINUX_VERSION_CODE < 0x20400
3547 # error "Linux version too old"
3548 #endif
3549       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
3550
3551     AC_MSG_RESULT([$emacs_signals_via_chars])
3552     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3553     ;;
3554 esac
3555
3556
3557 dnl Used in dispnew.c
3558 AH_TEMPLATE(PENDING_OUTPUT_COUNT, [Number of chars of output in the
3559   buffer of a stdio stream.])
3560
3561 AC_MSG_CHECKING([whether we are using the GNU C library])
3562 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3563 #include <features.h>
3564 #ifndef __GNU_LIBRARY__
3565 # error "this is not the GNU C library"
3566 #endif
3567   ]], [[]])], emacs_glibc=yes, emacs_glibc=no)
3568 AC_MSG_RESULT([$emacs_glibc])
3569
3570 if test $emacs_glibc = yes; then
3571
3572   emacs_pending_output=unknown
3573
3574   case $opsys in
3575     gnu | gnu-linux | gnu-kfreebsd )
3576       AC_MSG_CHECKING([for style of pending output formalism])
3577       dnl In autoconf 2.67 and later, we could use a single test
3578       dnl since the preprocessed output is accessible in "conftest.i".
3579       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3580 #include <stdio.h>
3581 #if !defined (_IO_STDIO_H) && !defined (_STDIO_USES_IOSTREAM)
3582 # error "stdio definitions not found"
3583 #endif
3584         ]], [[]])], emacs_pending_output=new, [])
3585
3586       if test $emacs_pending_output = unknown; then
3587         case $opsys in
3588           gnu-linux | gnu-kfreebsd)
3589             AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3590 #include <stdio.h>
3591 #ifndef __UCLIBC__
3592 # error "not using uclibc"
3593 #endif
3594             ]], [[]])], emacs_pending_output=uclibc, emacs_pending_output=old)
3595             ;;
3596         esac
3597       fi
3598
3599       AC_MSG_RESULT([$emacs_pending_output])
3600
3601       case $emacs_pending_output in
3602         new)
3603           dnl New C libio names.
3604           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3605             [((FILE)->_IO_write_ptr - (FILE)->_IO_write_base)])
3606           ;;
3607         uclibc)
3608           dnl Using the uClibc library.
3609           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3610             [((FILE)->__bufpos - (FILE)->__bufstart)])
3611           ;;
3612         old)
3613           dnl Old C++ iostream names.
3614           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3615             [((FILE)->_pptr - (FILE)->_pbase)])
3616           ;;
3617       esac
3618     ;;
3619   esac                          dnl opsys
3620
3621   if test $emacs_pending_output = unknown; then
3622     AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->__bufp - (FILE)->__buffer)])
3623   fi
3624
3625 else                            dnl !emacs_glibc
3626
3627   case $opsys in
3628     cygwin | darwin | freebsd | netbsd | openbsd )
3629       AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->_p - (FILE)->_bf._base)])
3630       ;;
3631
3632     unixware)
3633       AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->__ptr - (FILE)->__base)])
3634       ;;
3635
3636     *)
3637       dnl HAVE_STDIO_EXT_H && HAVE___FPENDING
3638       if test x$ac_cv_header_stdio_ext_h = xyes && \
3639         test x$ac_cv_func___fpending = xyes; then
3640         AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [__fpending (FILE)])
3641         AC_DEFINE(DISPNEW_NEEDS_STDIO_EXT, 1,
3642           [Define if dispnew.c should include stdio_ext.h.])
3643       else
3644         AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->_ptr - (FILE)->_base)])
3645       fi
3646       ;;
3647   esac
3648 fi                              dnl emacs_glibc
3649
3650
3651 dnl Used in vm-limit.c
3652 AH_TEMPLATE(DATA_START, [Address of the start of the data segment.])
3653 dnl Used in lisp.h, emacs.c, mem-limits.h
3654 dnl NEWS.18 describes this as "a number which contains
3655 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
3656 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
3657 stored in a Lisp_Object.])
3658 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
3659
3660 case $opsys in
3661   gnu)
3662     dnl libc defines data_start.
3663     AC_DEFINE(DATA_START, [({ extern int data_start; (char *) &data_start; })])
3664     ;;
3665
3666   hpux*)
3667     dnl The data segment on this machine always starts at address 0x40000000.
3668     AC_DEFINE(DATA_START, [0x40000000])
3669     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
3670     ;;
3671   irix6-5)
3672     AC_DEFINE(DATA_START, [0x10000000])
3673     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
3674     ;;
3675 esac
3676
3677
3678 AH_TEMPLATE(ULIMIT_BREAK_VALUE, [Undocumented.])
3679 AH_TEMPLATE(TAB3, [Undocumented.])
3680
3681 case $opsys in
3682   darwin) AC_DEFINE(TAB3, OXTABS) ;;
3683
3684   gnu | freebsd | netbsd | openbsd )
3685     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
3686     AC_DEFINE(TAB3, OXTABS)
3687     ;;
3688
3689   gnu-linux | gnu-kfreebsd )
3690     dnl libc-linux/sysdeps/linux/i386/ulimit.c says that due to shared
3691     dnl library, we cannot get the maximum address for brk.
3692     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3693 #ifndef __i386__
3694 # error "not i386"
3695 #endif
3696       ]], [[]])], AC_DEFINE(ULIMIT_BREAK_VALUE, [(32*1024*1024)]), [])
3697
3698     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3699 #ifndef __ia64__
3700 # error "not ia64"
3701 #endif
3702       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
3703         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (0)],
3704         [Mark a secondary stack, like the register stack on the ia64.]), [])
3705     ;;
3706
3707   hpux*)
3708     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
3709       run_time_remap; for HPUX.])
3710     ;;
3711
3712   irix6-5)
3713     dnl Ulimit(UL_GMEMLIM) is busted...
3714     AC_DEFINE(ULIMIT_BREAK_VALUE, [0x14000000])
3715     ;;
3716 esac
3717
3718
3719 dnl These won't be used automatically yet.  We also need to know, at least,
3720 dnl that the stack is continuous.
3721 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
3722   registers relevant for conservative garbage collection in the jmp_buf.])
3723
3724 AH_TEMPLATE(GC_MARK_STACK, [Define to GC_USE_GCPROS_AS_BEFORE if
3725   conservative garbage collection is not known to work.])
3726
3727
3728 case $opsys in
3729   aix4-2 | hpux* | unixware)
3730     dnl Conservative garbage collection has not been tested, so for now
3731     dnl play it safe and stick with the old-fashioned way of marking.
3732     AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE])
3733     ;;
3734
3735   dnl Not all the architectures are tested, but there are Debian packages
3736   dnl for SCM and/or Guile on them, so the technique must work.  See also
3737   dnl comments in alloc.c concerning setjmp and gcc.
3738   dnl Fixme: it's probably safe to just use the GCC conditional below.
3739   gnu-linux | gnu-kfreebsd )
3740     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3741 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
3742   || defined __alpha__ || defined __mips__ || defined __s390__ \
3743   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
3744   || defined __ia64__ || defined __sh__
3745 /* ok */
3746 #else
3747 # error "setjmp not known to work on this arch"
3748 #endif
3749     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1),
3750       AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE]) )
3751     ;;
3752 esac
3753
3754
3755 if test x$GCC = xyes; then
3756    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
3757    AC_DEFINE(GC_SETJMP_WORKS, 1)
3758 else
3759   case $opsys in
3760     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
3761     freebsd | netbsd | openbsd | irix6-5 | sol2* )
3762       AC_DEFINE(GC_SETJMP_WORKS, 1)
3763       ;;
3764   esac
3765 fi                              dnl GCC?
3766
3767 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
3768   [AC_LINK_IFELSE(
3769      [AC_LANG_PROGRAM(
3770        [[#include <setjmp.h>
3771        ]],
3772        [[jmp_buf j;
3773          if (! _setjmp (j))
3774            _longjmp (j, 1);]])],
3775      [emacs_cv_func__setjmp=yes],
3776      [emacs_cv_func__setjmp=no])])
3777 if test $emacs_cv_func__setjmp = yes; then
3778   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
3779 else
3780   AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
3781     [AC_LINK_IFELSE(
3782        [AC_LANG_PROGRAM(
3783          [[#include <setjmp.h>
3784          ]],
3785          [[sigjmp_buf j;
3786            if (! sigsetjmp (j, 1))
3787              siglongjmp (j, 1);]])],
3788        [emacs_cv_func_sigsetjmp=yes],
3789        [emacs_cv_func_sigsetjmp=no])])
3790   if test $emacs_cv_func_sigsetjmp = yes; then
3791     AC_DEFINE([HAVE_SIGSETJMP], 1,
3792       [Define to 1 if sigsetjmp and siglongjmp work.
3793        The value of this symbol is irrelevant if HAVE__SETJMP is defined.])
3794   fi
3795 fi
3796
3797 case $opsys in
3798   sol2* | unixware )
3799     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
3800     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
3801     dnl and this is all we need.
3802     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
3803     ;;
3804 esac
3805
3806
3807 case $opsys in
3808   hpux* | sol2* )
3809     dnl Used in xfaces.c.
3810     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
3811       some systems, where it requires time.h.])
3812     ;;
3813 esac
3814
3815
3816 dnl Define symbols to identify the version of Unix this is.
3817 dnl Define all the symbols that apply correctly.
3818 AH_TEMPLATE(BSD4_2, [Define if the system is compatible with BSD 4.2.])
3819 AH_TEMPLATE(BSD_SYSTEM, [Define if the system is compatible with BSD 4.2.])
3820 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
3821 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
3822 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
3823 AH_TEMPLATE(USG5, [Define if the system is compatible with System V.])
3824 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
3825
3826 case $opsys in
3827   aix4-2)
3828     AC_DEFINE(USG, [])
3829     AC_DEFINE(USG5, [])
3830     dnl This symbol should be defined on AIX Version 3  ???????
3831     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3832 #ifndef _AIX
3833 # error "_AIX not defined"
3834 #endif
3835     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
3836     ;;
3837
3838   cygwin)
3839     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
3840     ;;
3841
3842   darwin)
3843     dnl BSD4_3 and BSD4_4 are already defined in sys/param.h.
3844     AC_DEFINE(BSD4_2, [])
3845     AC_DEFINE(BSD_SYSTEM, [])
3846     dnl More specific than the above two.  We cannot use __APPLE__ as this
3847     dnl may not be defined on non-OSX Darwin, and we cannot define DARWIN
3848     dnl here because Panther and lower CoreFoundation.h uses DARWIN to
3849     dnl distinguish OS X from pure Darwin.
3850     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
3851     ;;
3852
3853   freebsd)
3854     AC_DEFINE(BSD4_2, [])
3855     dnl Hack to avoid calling AC_PREPROC_IFELSE multiple times.
3856     dnl Would not be needed with autoconf >= 2.67, where the
3857     dnl preprocessed output is accessible in "conftest.i".
3858     AC_DEFINE(BSD_SYSTEM_AHB, 1, [Define if AH_BOTTOM should change BSD_SYSTEM.])
3859     ;;
3860
3861   gnu | netbsd | openbsd )
3862     AC_DEFINE(BSD4_2, [])
3863     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3864 #ifndef BSD_SYSTEM
3865 # error "BSD_SYSTEM not defined"
3866 #endif
3867     ]], [[]])], [], AC_DEFINE(BSD_SYSTEM, 43) )
3868     ;;
3869
3870   gnu-linux | gnu-kfreebsd )
3871     AC_DEFINE(USG, [])
3872     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
3873     ;;
3874
3875   hpux*)
3876     AC_DEFINE(USG, [])
3877     AC_DEFINE(USG5, [])
3878     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
3879     ;;
3880
3881   irix6-5)
3882     AC_DEFINE(USG, [])
3883     AC_DEFINE(USG5, [])
3884     AC_DEFINE(USG5_4, [])
3885     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
3886     ;;
3887
3888   sol2*)
3889     AC_DEFINE(USG, [])
3890     AC_DEFINE(USG5, [])
3891     AC_DEFINE(USG5_4, [])
3892     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
3893     ;;
3894
3895   unixware)
3896     AC_DEFINE(USG, [])
3897     AC_DEFINE(USG5, [])
3898     AC_DEFINE(USG5_4, [])
3899     ;;
3900 esac
3901
3902 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
3903   [case $opsys in
3904      aix4-2)
3905        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
3906        emacs_cv_usable_FIONREAD=no
3907        ;;
3908
3909      *)
3910        AC_COMPILE_IFELSE(
3911          [AC_LANG_PROGRAM([[#include <sys/types.h>
3912                             #include <sys/ioctl.h>
3913                             #ifdef USG5_4
3914                             # include <sys/filio.h>
3915                             #endif
3916                           ]],
3917                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
3918          [emacs_cv_usable_FIONREAD=yes],
3919          [emacs_cv_usable_FIONREAD=no])
3920        ;;
3921    esac])
3922 if test $emacs_cv_usable_FIONREAD = yes; then
3923   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
3924
3925   if test $emacs_broken_SIGIO = no; then
3926     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
3927       [AC_COMPILE_IFELSE(
3928          [AC_LANG_PROGRAM([[#include <fcntl.h>
3929                             #include <signal.h>
3930                           ]],
3931                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
3932          [emacs_cv_usable_SIGIO=yes],
3933          [emacs_cv_usable_SIGIO=no])],
3934       [emacs_cv_usable_SIGIO=yes],
3935       [emacs_cv_usable_SIGIO=no])
3936     if test $emacs_cv_usable_SIGIO = yes; then
3937       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
3938     fi
3939   fi
3940 fi
3941
3942
3943 case $opsys in
3944   dnl Emacs supplies its own malloc, but glib (part of Gtk+) calls
3945   dnl memalign and on Cygwin, that becomes the Cygwin-supplied memalign.
3946   dnl As malloc is not the Cygwin malloc, the Cygwin memalign always
3947   dnl returns ENOSYS.  A workaround is to set G_SLICE=always-malloc. */
3948   cygwin)
3949     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
3950       G_SLICE environment variable to "always-malloc" at startup, if
3951       using GTK.])
3952     ;;
3953
3954   hpux11)
3955     dnl See comments in sysdep.c:sys_signal.
3956     dnl SA_RESTART resets the timeout of `select' on hpux11.
3957     dnl Defining BROKEN_SA_RESTART is not the same as undef'ing SA_RESTART.
3958     AC_DEFINE(BROKEN_SA_RESTART, 1, [Define if SA_RESTART should only
3959       be used in batch mode.])
3960     dnl It works to open the pty's tty in the parent (Emacs), then
3961     dnl close and reopen it in the child.
3962     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
3963       works to open a pty's tty in the parent process, then close and
3964       reopen it in the child.])
3965     ;;
3966
3967   irix6-5)
3968     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
3969       use VSUSP instead of VSWTCH.])
3970     AC_DEFINE(SETPGRP_RELEASES_CTTY, 1, [Define if process.c:child_setup
3971       should not call setpgrp.])
3972     ;;
3973
3974   sol2-10)
3975     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
3976       on Solaris.])
3977     ;;
3978 esac
3979
3980 # Set up the CFLAGS for real compilation, so we can substitute it.
3981 CFLAGS="$REAL_CFLAGS"
3982 CPPFLAGS="$REAL_CPPFLAGS"
3983
3984 ## Hack to detect a buggy GCC version.
3985 if test "x$GCC" = xyes \
3986    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3987    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3988    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3989    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3990 fi
3991
3992 version=$PACKAGE_VERSION
3993
3994 ### Specify what sort of things we'll be editing into Makefile and config.h.
3995 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3996 AC_SUBST(version)
3997 AC_SUBST(configuration)
3998 ## Unused?
3999 AC_SUBST(canonical)
4000 AC_SUBST(srcdir)
4001 AC_SUBST(prefix)
4002 AC_SUBST(exec_prefix)
4003 AC_SUBST(bindir)
4004 AC_SUBST(datadir)
4005 AC_SUBST(sharedstatedir)
4006 AC_SUBST(libexecdir)
4007 AC_SUBST(mandir)
4008 AC_SUBST(infodir)
4009 AC_SUBST(lispdir)
4010 AC_SUBST(leimdir)
4011 AC_SUBST(standardlisppath)
4012 AC_SUBST(locallisppath)
4013 AC_SUBST(lisppath)
4014 AC_SUBST(x_default_search_path)
4015 AC_SUBST(etcdir)
4016 AC_SUBST(archlibdir)
4017 AC_SUBST(docdir)
4018 AC_SUBST(bitmapdir)
4019 AC_SUBST(gamedir)
4020 AC_SUBST(gameuser)
4021 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4022 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4023 ## end of LIBX_BASE, but nothing ever set it.
4024 AC_SUBST(LD_SWITCH_X_SITE)
4025 AC_SUBST(C_SWITCH_X_SITE)
4026 AC_SUBST(GNUSTEP_CFLAGS)
4027 AC_SUBST(CFLAGS)
4028 ## Used in lwlib/Makefile.in.
4029 AC_SUBST(X_TOOLKIT_TYPE)
4030 AC_SUBST(ns_appdir)
4031 AC_SUBST(ns_appbindir)
4032 AC_SUBST(ns_appresdir)
4033 AC_SUBST(ns_appsrc)
4034 AC_SUBST(GNU_OBJC_CFLAGS)
4035 AC_SUBST(OTHER_FILES)
4036
4037 if test -n "${term_header}"; then
4038     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4039         [Define to the header for the built-in window system.])
4040 fi
4041
4042 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4043                    [Define to the canonical Emacs configuration name.])
4044 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
4045                    [Define to the options passed to configure.])
4046 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4047   define this to include extra configuration information.])
4048
4049 XMENU_OBJ=
4050 XOBJ=
4051 FONT_OBJ=
4052 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4053   AC_DEFINE(HAVE_X_WINDOWS, 1,
4054             [Define to 1 if you want to use the X window system.])
4055   XMENU_OBJ=xmenu.o
4056   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o xgselect.o"
4057   FONT_OBJ=xfont.o
4058   if test "$HAVE_XFT" = "yes"; then
4059     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4060   elif test "$HAVE_FREETYPE" = "yes"; then
4061     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4062   fi
4063   AC_SUBST(FONT_OBJ)
4064 fi
4065 AC_SUBST(XMENU_OBJ)
4066 AC_SUBST(XOBJ)
4067 AC_SUBST(FONT_OBJ)
4068
4069 WIDGET_OBJ=
4070 MOTIF_LIBW=
4071 if test "${USE_X_TOOLKIT}" != "none" ; then
4072   WIDGET_OBJ=widget.o
4073   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4074   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4075     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4076   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4077     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4078     MOTIF_LIBW=-lXm
4079     case "$opsys" in
4080       gnu-linux)
4081         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4082         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4083         ;;
4084
4085       unixware)
4086         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4087         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4088         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4089         ;;
4090
4091       aix4-2)
4092         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4093         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4094         ;;
4095     esac
4096     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4097   fi
4098 fi
4099 AC_SUBST(WIDGET_OBJ)
4100
4101 TOOLKIT_LIBW=
4102 case "$USE_X_TOOLKIT" in
4103   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4104   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4105   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4106 esac
4107 AC_SUBST(TOOLKIT_LIBW)
4108
4109 if test "$USE_X_TOOLKIT" = "none"; then
4110   LIBXT_OTHER="\$(LIBXSM)"
4111   OLDXMENU_TARGET="really-oldXMenu"
4112 else
4113   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4114   OLDXMENU_TARGET="really-lwlib"
4115 fi
4116 AC_SUBST(LIBXT_OTHER)
4117
4118 ## The X Menu stuff is present in the X10 distribution, but missing
4119 ## from X11.  If we have X10, just use the installed library;
4120 ## otherwise, use our own copy.
4121 if test "${HAVE_X11}" = "yes" ; then
4122   AC_DEFINE(HAVE_X11, 1,
4123             [Define to 1 if you want to use version 11 of X windows.
4124              Otherwise, Emacs expects to use version 10.])
4125
4126   if test "$USE_X_TOOLKIT" = "none"; then
4127     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
4128   else
4129     OLDXMENU="\${lwlibdir}/liblw.a"
4130   fi
4131   LIBXMENU="\$(OLDXMENU)"
4132   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4133   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
4134 else
4135   ## For a syntactically valid Makefile; not actually used for anything.
4136   ## See comments in src/Makefile.in.
4137   OLDXMENU=nothing
4138   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
4139   if test "${HAVE_X_WINDOWS}" = "yes"; then
4140     LIBXMENU="-lXMenu"
4141   else
4142     LIBXMENU=
4143   fi
4144   LIBX_OTHER=
4145   OLDXMENU_DEPS=
4146 fi
4147
4148 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
4149   OLDXMENU_TARGET=
4150   OLDXMENU=nothing
4151   LIBXMENU=
4152   OLDXMENU_DEPS=
4153 fi
4154
4155 AC_SUBST(OLDXMENU_TARGET)
4156 AC_SUBST(OLDXMENU)
4157 AC_SUBST(LIBXMENU)
4158 AC_SUBST(LIBX_OTHER)
4159 AC_SUBST(OLDXMENU_DEPS)
4160
4161 if test "${HAVE_MENUS}" = "yes" ; then
4162   AC_DEFINE(HAVE_MENUS, 1,
4163             [Define to 1 if you have mouse menus.
4164              (This is automatic if you use X, but the option to specify it remains.)
4165              It is also defined with other window systems that support xmenu.c.])
4166 fi
4167
4168 if test "${GNU_MALLOC}" = "yes" ; then
4169   AC_DEFINE(GNU_MALLOC, 1,
4170             [Define to 1 if you want to use the GNU memory allocator.])
4171 fi
4172
4173 RALLOC_OBJ=
4174 if test "${REL_ALLOC}" = "yes" ; then
4175   AC_DEFINE(REL_ALLOC, 1,
4176             [Define REL_ALLOC if you want to use the relocating allocator for
4177              buffer space.])
4178
4179   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4180 fi
4181 AC_SUBST(RALLOC_OBJ)
4182
4183 if test "$opsys" = "cygwin"; then
4184   CYGWIN_OBJ="sheap.o"
4185   ## Cygwin differs because of its unexec().
4186   PRE_ALLOC_OBJ=
4187   POST_ALLOC_OBJ=lastfile.o
4188 else
4189   CYGWIN_OBJ=
4190   PRE_ALLOC_OBJ=lastfile.o
4191   POST_ALLOC_OBJ=
4192 fi
4193 AC_SUBST(CYGWIN_OBJ)
4194 AC_SUBST(PRE_ALLOC_OBJ)
4195 AC_SUBST(POST_ALLOC_OBJ)
4196
4197 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4198 # it temporarily reverts them to their pre-pkg-config values,
4199 # because gnulib needs to work with both src (which uses the
4200 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4201 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4202 # and it therefore needs to run in an environment where LIBS does not
4203 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4204 # for some package unrelated to lib-src.
4205 SAVE_CFLAGS=$CFLAGS
4206 SAVE_LIBS=$LIBS
4207 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4208 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4209 gl_ASSERT_NO_GNULIB_POSIXCHECK
4210 gl_ASSERT_NO_GNULIB_TESTS
4211 gl_INIT
4212 CFLAGS=$SAVE_CFLAGS
4213 LIBS=$SAVE_LIBS
4214
4215 case "$opsys" in
4216   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4217
4218   darwin)
4219    ## The -headerpad option tells ld (see man page) to leave room at the
4220    ## end of the header for adding load commands.  Needed for dumping.
4221    ## 0x690 is the total size of 30 segment load commands (at 56
4222    ## each); under Cocoa 31 commands are required.
4223    if test "$HAVE_NS" = "yes"; then
4224      libs_nsgui="-framework AppKit"
4225      headerpad_extra=6C8
4226    else
4227      libs_nsgui=
4228      headerpad_extra=690
4229    fi
4230    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4231
4232    ## This is here because src/Makefile.in did some extra fiddling around
4233    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
4234    ##   #ifndef LD_SWITCH_SYSTEM
4235    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
4236    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
4237    ## not using gcc, darwin.
4238    ## Because this was done in src/Makefile.in, the resulting part of
4239    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
4240    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
4241    ## rather than LD_SWITCH_SYSTEM.
4242    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4243      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4244    ;;
4245
4246   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4247   ## find X at run-time.
4248   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4249   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4250   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4251   ## had different values in configure (in ac_link) and src/Makefile.in.
4252   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4253   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4254
4255   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4256 esac
4257
4258 if test "$NS_IMPL_GNUSTEP" = "yes"; then
4259   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
4260 fi
4261
4262 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4263
4264
4265 LD_FIRSTFLAG=
4266 ORDINARY_LINK=
4267 case "$opsys" in
4268   ## gnu: GNU needs its own crt0.
4269   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
4270
4271   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
4272   ## library search parth, i.e. it won't search /usr/lib for libc and
4273   ## friends.  Using -nostartfiles instead avoids this problem, and
4274   ## will also work on earlier NetBSD releases.
4275   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
4276
4277   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
4278   ##   MkLinux/LinuxPPC needs this.
4279   ## s390x-* only supports opsys = gnu-linux so it can be added here.
4280   gnu-*)
4281     case "$canonical" in
4282       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
4283     esac
4284     ;;
4285 esac
4286
4287
4288 if test "x$ORDINARY_LINK" = "xyes"; then
4289
4290   LD_FIRSTFLAG=""
4291   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
4292
4293 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
4294 ## freebsd, gnu-* not on powerpc*|s390x*.
4295 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
4296
4297   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
4298   ## places that are difficult to figure out at make time.  Fortunately,
4299   ## these same versions allow you to pass arbitrary flags on to the
4300   ## linker, so there is no reason not to use it as a linker.
4301   ##
4302   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
4303   ## searching for libraries in its internal directories, so we have to
4304   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
4305   LD_FIRSTFLAG="-nostdlib"
4306 fi
4307
4308 ## FIXME? What setting of EDIT_LDFLAGS should this have?
4309 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
4310
4311 AC_SUBST(LD_FIRSTFLAG)
4312
4313
4314 ## FIXME? The logic here is not precisely the same as that above.
4315 ## There is no check here for a pre-defined LD_FIRSTFLAG.
4316 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
4317 LIB_GCC=
4318 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
4319
4320   case "$opsys" in
4321     freebsd|netbsd|openbsd) LIB_GCC= ;;
4322
4323     gnu-*)
4324       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
4325       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
4326       case $host_cpu in
4327       arm*)
4328         LIB_GCC="-lgcc_s"
4329         ;;
4330       *)
4331         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
4332         ## immediately undefine it again and redefine it to empty.
4333         ## Was the C_SWITCH_X_SITE part really necessary?
4334 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
4335         LIB_GCC=
4336         ;;
4337       esac
4338       ;;
4339
4340     ## Ask GCC where to find libgcc.a.
4341     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
4342   esac
4343 fi                              dnl if $GCC
4344 AC_SUBST(LIB_GCC)
4345
4346 ## Common for all window systems
4347 if test "$window_system" != "none"; then
4348   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4349   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
4350   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4351 fi
4352
4353 AC_SUBST(WINDOW_SYSTEM_OBJ)
4354
4355 AH_TOP([/* GNU Emacs site configuration template file.
4356
4357 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
4358   Free Software Foundation, Inc.
4359
4360 This file is part of GNU Emacs.
4361
4362 GNU Emacs is free software: you can redistribute it and/or modify
4363 it under the terms of the GNU General Public License as published by
4364 the Free Software Foundation, either version 3 of the License, or
4365 (at your option) any later version.
4366
4367 GNU Emacs is distributed in the hope that it will be useful,
4368 but WITHOUT ANY WARRANTY; without even the implied warranty of
4369 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4370 GNU General Public License for more details.
4371
4372 You should have received a copy of the GNU General Public License
4373 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4374
4375
4376 /* No code in Emacs #includes config.h twice, but some bits of code
4377    intended to work with other packages as well (like gmalloc.c)
4378    think they can include it as many times as they like.  */
4379 #ifndef EMACS_CONFIG_H
4380 #define EMACS_CONFIG_H
4381 ])dnl
4382
4383 AH_BOTTOM([#include <conf_post.h>
4384
4385 #endif /* EMACS_CONFIG_H */
4386
4387 /*
4388 Local Variables:
4389 mode: c
4390 End:
4391 */
4392 ])dnl
4393
4394 #### Report on what we decided to do.
4395 #### Report GTK as a toolkit, even if it doesn't use Xt.
4396 #### It makes printing result more understandable as using GTK sets
4397 #### toolkit_scroll_bars to yes by default.
4398 if test "${HAVE_GTK}" = "yes"; then
4399   USE_X_TOOLKIT=GTK
4400 fi
4401
4402 echo "
4403 Configured for \`${canonical}'.
4404
4405   Where should the build process find the source code?    ${srcdir}
4406   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4407   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4408   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4409   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4410   What window system should Emacs use?                    ${window_system}
4411   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4412
4413 if test -n "${x_includes}"; then
4414 echo "  Where do we find X Windows header files?                ${x_includes}"
4415 else
4416 echo "  Where do we find X Windows header files?                Standard dirs"
4417 fi
4418 if test -n "${x_libraries}"; then
4419 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4420 else
4421 echo "  Where do we find X Windows libraries?                   Standard dirs"
4422 fi
4423
4424 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4425 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4426 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4427 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4428 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4429 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
4430 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4431 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4432
4433 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
4434 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
4435 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
4436 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
4437 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
4438 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
4439 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
4440
4441 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
4442 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
4443 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
4444 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
4445
4446 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
4447 echo
4448
4449 if test -n "${EMACSDATA}"; then
4450    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
4451 fi
4452 if test -n "${EMACSDOC}"; then
4453    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
4454 fi
4455
4456 echo
4457
4458 if test "$HAVE_NS" = "yes"; then
4459    echo
4460    echo "You must run \"${MAKE-make} install\" in order to test the built application.
4461 The installed application will go to nextstep/Emacs.app and can be
4462 run or moved from there."
4463    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
4464       echo "The application will be fully self-contained."
4465     else
4466       echo "The lisp resources for the application will be installed under ${prefix}.
4467 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
4468 to run if these resources are not installed."
4469    fi
4470    echo
4471 fi
4472
4473 if test "${opsys}" = "cygwin"; then
4474   case `uname -r` in
4475     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
4476            echo
4477            ;;
4478   esac
4479 fi
4480
4481 # Remove any trailing slashes in these variables.
4482 [test "${prefix}" != NONE &&
4483   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
4484 test "${exec_prefix}" != NONE &&
4485   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
4486
4487 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
4488 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
4489 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
4490 dnl (else you get "no `Makefile.am' found for any configure output").
4491 dnl This will work, but you get a config.status that is not quite right
4492 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
4493 dnl That doesn't have any obvious consequences for Emacs, but on the whole
4494 dnl it seems better to just live with the duplication.
4495 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
4496
4497 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
4498        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
4499        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
4500        leim/Makefile])
4501
4502 dnl test/ is not present in release tarfiles.
4503 opt_makefile=test/automated/Makefile
4504
4505 if test -f $srcdir/${opt_makefile}.in; then
4506   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4507   dnl Again, it's best not to use a variable.  Though you can add
4508   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
4509   AC_CONFIG_FILES([test/automated/Makefile])
4510 fi
4511
4512
4513 dnl admin/ may or may not be present.
4514 opt_makefile=admin/unidata/Makefile
4515
4516 if test -f $srcdir/${opt_makefile}.in; then
4517   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4518   AC_CONFIG_FILES([admin/unidata/Makefile])
4519 fi
4520
4521
4522 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
4523
4524 AC_SUBST(SUBDIR_MAKEFILES_IN)
4525
4526 dnl Make the necessary directories, if they don't exist.
4527 AC_CONFIG_COMMANDS([mkdirs], [
4528 for dir in etc lisp ; do
4529   test -d ${dir} || mkdir ${dir}
4530 done
4531 ])
4532
4533 dnl You might wonder (I did) why epaths.h is generated by running make,
4534 dnl rather than just letting configure generate it from epaths.in.
4535 dnl One reason is that the various paths are not fully expanded (see above);
4536 dnl eg gamedir=${prefix}/var/games/emacs.
4537 dnl Secondly, the GNU Coding standards require that one should be able
4538 dnl to run `make prefix=/some/where/else' and override the values set
4539 dnl by configure.  This also explains the `move-if-change' test and
4540 dnl the use of force in the `epaths-force' rule in Makefile.in.
4541 AC_CONFIG_COMMANDS([epaths], [
4542 echo creating src/epaths.h
4543 ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
4544 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
4545
4546 AC_CONFIG_COMMANDS([gdbinit], [
4547 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
4548   echo creating src/.gdbinit
4549   echo source $srcdir/src/.gdbinit > src/.gdbinit
4550 fi
4551 ])
4552
4553 AC_OUTPUT