configure.in

   1 dnl This is an autoconf script.
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 AC_PREREQ(2.4.1)dnl
   6 AC_INIT(src/lisp.h)
   7 AC_CONFIG_HEADER(src/config.h:src/config.in)
   8
   9 lispdir='${datadir}/emacs/${version}/lisp'
  10 locallisppath='${datadir}/emacs/site-lisp'
  11 lisppath='${locallisppath}:${lispdir}'
  12 etcdir='${datadir}/emacs/${version}/etc'
  13 lockdir='${sharedstatedir}/emacs/lock'
  14 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  15 docdir='${datadir}/emacs/${version}/etc'
  16
  17 AC_ARG_WITH(gcc,
  18 [  --with-gcc              use GCC to compile Emacs])
  19 AC_ARG_WITH(pop,
  20 [  --with-pop              support POP for mail retrieval],
  21 [AC_DEFINE(MAIL_USE_POP)])
  22 AC_ARG_WITH(kerberos,
  23 [  --with-kerberos         support Kerberos-authenticated POP],
  24 [AC_DEFINE(KERBEROS)])
  25 AC_ARG_WITH(hesiod,
  26 [  --with-hesiod           support Hesiod to get the POP server host],
  27 [AC_DEFINE(HESIOD)])
  28 dnl This should be the last --with option, because --with-x is
  29 dnl added later on when we find the path of X, and it's best to
  30 dnl keep them together visually.
  31 AC_ARG_WITH(x-toolkit,
  32 [  --with-x-toolkit=KIT    use an X toolkit (KIT = yes/lucid/athena/motif)],
  33 [         case "${withval}" in
  34             y | ye | yes )      val=athena ;;
  35             n | no )            val=no  ;;
  36             l | lu | luc | luci | lucid )       val=lucid ;;
  37             a | at | ath | athe | athen | athena )      val=athena ;;
  38             m | mo | mot | moti | motif )       val=motif ;;
  39 dnl These don't currently work.
  40 dnl         o | op | ope | open | open- | open-l | open-lo \
  41 dnl             | open-loo | open-look )        val=open-look ;;
  42             * )
  43 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
  44 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
  45 AC_MSG_ERROR([\`--with-x-toolkit=$withval' is invalid\;
  46 this option's value should be \`yes', \`no', \`lucid', \`athena', or \`motif'.
  47 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
  48             ;;
  49           esac
  50           with_x_toolkit=$val
  51 ])
  52
  53 #### Make srcdir absolute, if it isn't already.  It's important to
  54 #### avoid running the path through pwd unnecessary, since pwd can
  55 #### give you automounter prefixes, which can go away.  We do all this
  56 #### so Emacs can find its files when run uninstalled.
  57 case "${srcdir}" in
  58   /* ) ;;
  59   . )
  60     ## We may be able to use the $PWD environment variable to make this
  61     ## absolute.  But sometimes PWD is inaccurate.
  62     ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
  63     CDPATH=
  64     if test "${PWD}" != "" && test "`(cd ${PWD} ; sh -c pwd)`" = "`pwd`"  ;
  65     then
  66       srcdir="$PWD"
  67     else
  68       srcdir="`(cd ${srcdir}; pwd)`"
  69     fi
  70   ;;
  71   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
  72 esac
  73
  74 #### Check if the source directory already has a configured system in it.
  75 if test `pwd` != `(cd ${srcdir} && pwd)` \
  76    && test -f "${srcdir}/src/config.h" ; then
  77   AC_MSG_WARN([The directory tree \`${srcdir}' is being used
  78    as a build directory right now; it has been configured in its own
  79    right.  To configure in another directory as well, you MUST
  80    use GNU make.  If you do not have GNU make, then you must
  81    now do \`make distclean' in ${srcdir},
  82    and then run $0 again.])
  83
  84 changequote(, )dnl
  85   extrasub='/^VPATH[     ]*=/c\
  86 changequote([, ])dnl
  87 vpath %.c $(srcdir)\
  88 vpath %.h $(srcdir)\
  89 vpath %.y $(srcdir)\
  90 vpath %.l $(srcdir)\
  91 vpath %.s $(srcdir)\
  92 vpath %.in $(srcdir)'
  93 fi
  94
  95 #### Given the configuration name, set machfile and opsysfile to the
  96 #### names of the m/*.h and s/*.h files we should use.
  97
  98 ### Canonicalize the configuration name.
  99
 100 AC_CANONICAL_HOST
 101 canonical=$host
 102 configuration=$host_alias
 103
 104 changequote(, )dnl
 105
 106 ### If you add support for a new configuration, add code to this
 107 ### switch statement to recognize your configuration name and select
 108 ### the appropriate operating system and machine description files.
 109
 110 ### You would hope that you could choose an m/*.h file pretty much
 111 ### based on the machine portion of the configuration name, and an s-
 112 ### file based on the operating system portion.  However, it turns out
 113 ### that each m/*.h file is pretty manufacturer-specific - for
 114 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
 115 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
 116 ### machines.  So we basically have to have a special case for each
 117 ### configuration name.
 118 ###
 119 ### As far as handling version numbers on operating systems is
 120 ### concerned, make sure things will fail in a fixable way.  If
 121 ### /etc/MACHINES doesn't say anything about version numbers, be
 122 ### prepared to handle anything reasonably.  If version numbers
 123 ### matter, be sure /etc/MACHINES says something about it.
 124 ###
 125 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 126 ### "System V Release 4"; he writes, "The old convention encouraged
 127 ### confusion between `system' and `release' levels'."
 128
 129 machine='' opsys='' unported=no
 130 case "${canonical}" in
 131
 132   ## NetBSD ports
 133   *-*-netbsd* )
 134     opsys=netbsd
 135     case "${canonical}" in
 136       i[345]86-*-netbsd*) machine=intel386 ;;
 137       m68k-*-netbsd*)
 138                         # This is somewhat bogus.
 139                         machine=hp9000s300 ;;
 140       mips-*-netbsd*)   machine=pmax ;;
 141       ns32k-*-netbsd*)  machine=ns32000 ;;
 142       sparc-*-netbsd*)  machine=sparc ;;
 143     esac
 144   ;;
 145
 146   ## Acorn RISCiX:
 147   arm-acorn-riscix1.1* )
 148     machine=acorn opsys=riscix1-1
 149   ;;
 150   arm-acorn-riscix1.2* | arm-acorn-riscix )
 151     machine=acorn opsys=riscix1-2
 152   ;;
 153
 154   ## Alliant machines
 155   ## Strictly speaking, we need the version of the alliant operating
 156   ## system to choose the right machine file, but currently the
 157   ## configuration name doesn't tell us enough to choose the right
 158   ## one; we need to give alliants their own operating system name to
 159   ## do this right.  When someone cares, they can help us.
 160   fx80-alliant-* )
 161     machine=alliant4 opsys=bsd4-2
 162   ;;
 163   i860-alliant-* )
 164     machine=alliant-2800 opsys=bsd4-3
 165   ;;
 166
 167   ## Alpha (DEC) machines.
 168   alpha-dec-osf* )
 169     machine=alpha opsys=osf1
 170   ;;
 171
 172   alpha-*-linux* )
 173     machine=alpha opsys=linux
 174   ;;
 175
 176   ## Altos 3068
 177   m68*-altos-sysv* )
 178     machine=altos opsys=usg5-2
 179   ;;
 180
 181   ## Amdahl UTS
 182   580-amdahl-sysv* )
 183     machine=amdahl opsys=usg5-2-2
 184   ;;
 185
 186   ## Apollo, Domain/OS
 187   m68*-apollo-* )
 188     machine=apollo opsys=bsd4-3
 189   ;;
 190
 191   ## AT&T 3b2, 3b5, 3b15, 3b20
 192   we32k-att-sysv* )
 193     machine=att3b opsys=usg5-2-2
 194   ;;
 195
 196   ## AT&T 3b1 - The Mighty Unix PC!
 197   m68*-att-sysv* )
 198     machine=7300 opsys=usg5-2-2
 199   ;;
 200
 201   ## Bull dpx20
 202   rs6000-bull-bosx* )
 203     machine=ibmrs6000 opsys=aix3-2
 204   ;;
 205
 206   ## Bull dpx2
 207   m68*-bull-sysv3* )
 208     machine=dpx2 opsys=usg5-3
 209   ;;
 210
 211   ## Bull sps7
 212   m68*-bull-sysv2* )
 213     machine=sps7 opsys=usg5-2
 214   ;;
 215
 216   ## CCI 5/32, 6/32 -- see "Tahoe".
 217
 218   ## Celerity
 219   ## I don't know what configuration name to use for this; config.sub
 220   ## doesn't seem to know anything about it.  Hey, Celerity users, get
 221   ## in touch with us!
 222   celerity-celerity-bsd* )
 223     machine=celerity opsys=bsd4-2
 224   ;;
 225
 226   ## Clipper
 227   ## What operating systems does this chip run that Emacs has been
 228   ## tested on?
 229   clipper-* )
 230     machine=clipper
 231     ## We'll use the catch-all code at the bottom to guess the
 232     ## operating system.
 233   ;;
 234
 235   ## Convex
 236   *-convex-bsd* | *-convex-convexos* )
 237     machine=convex opsys=bsd4-3
 238     ## Prevents suprious white space in makefiles - d.m.cooke@larc.nasa.gov
 239     NON_GNU_CPP="cc -E -P"
 240   ;;
 241
 242   ## Cubix QBx/386
 243   i[345]86-cubix-sysv* )
 244     machine=intel386 opsys=usg5-3
 245   ;;
 246
 247   ## Cydra 5
 248   cydra*-cydrome-sysv* )
 249     machine=cydra5 opsys=usg5-3
 250   ;;
 251
 252   ## Data General AViiON Machines
 253   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
 254     machine=aviion opsys=dgux5-4r3
 255   ;;
 256   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
 257     machine=aviion opsys=dgux5-4r2
 258   ;;
 259   m88k-dg-dgux* )
 260     machine=aviion opsys=dgux
 261   ;;
 262
 263   ## DECstations
 264   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 265     machine=pmax opsys=bsd4-2
 266   ;;
 267   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 268     machine=pmax opsys=bsd4-3
 269   ;;
 270   mips-dec-ultrix* )
 271     machine=pmax opsys=ultrix4-3
 272   ;;
 273   mips-dec-osf* )
 274     machine=pmax opsys=osf1
 275   ;;
 276   mips-dec-mach_bsd4.3* )
 277     machine=pmax opsys=mach-bsd4-3
 278   ;;
 279
 280   ## Motorola Delta machines
 281   m68k-motorola-sysv* | m68000-motorola-sysv* )
 282     machine=delta opsys=usg5-3
 283     if test -z "`type gnucc | grep 'not found'`"
 284     then
 285       if test -s /etc/167config
 286       then CC="gnucc -m68040"
 287       else CC="gnucc -m68881"
 288       fi
 289     else
 290       if test -z "`type gcc | grep 'not found'`"
 291       then CC=gcc
 292       else CC=cc
 293       fi
 294     fi
 295   ;;
 296   m88k-motorola-sysv4* )
 297     # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
 298     # needs POSIX_SIGNALS and therefore needs usg5-4-2.
 299     # I hope there are not other 4.0 versions for this machine
 300     # which really need usg5-4 instead.
 301     machine=delta88k opsys=usg5-4-2
 302   ;;
 303   m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
 304     machine=delta88k opsys=usg5-3
 305   ;;
 306
 307   ## Dual machines
 308   m68*-dual-sysv* )
 309     machine=dual opsys=usg5-2
 310   ;;
 311   m68*-dual-uniplus* )
 312     machine=dual opsys=unipl5-2
 313   ;;
 314
 315   ## Elxsi 6400
 316   elxsi-elxsi-sysv* )
 317     machine=elxsi opsys=usg5-2
 318   ;;
 319
 320   ## Encore machines
 321   ns16k-encore-bsd* )
 322     machine=ns16000 opsys=umax
 323   ;;
 324
 325   ## The GEC 93 - apparently, this port isn't really finished yet.
 326
 327   ## Gould Power Node and NP1
 328   pn-gould-bsd4.2* )
 329     machine=gould opsys=bsd4-2
 330   ;;
 331   pn-gould-bsd4.3* )
 332     machine=gould opsys=bsd4-3
 333   ;;
 334   np1-gould-bsd* )
 335     machine=gould-np1 opsys=bsd4-3
 336   ;;
 337
 338   ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
 339   ## as far as Emacs is concerned).
 340   m88k-harris-cxux* )
 341     # Build needs to be different on 7.0 and later releases
 342     case "`uname -r`" in
 343        [56].[0-9] ) machine=nh4000 opsys=cxux ;;
 344        [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
 345     esac
 346   ;;
 347   ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
 348   m68k-harris-cxux* )
 349     machine=nh3000 opsys=cxux
 350   ;;
 351
 352   ## Honeywell XPS100
 353   xps*-honeywell-sysv* )
 354     machine=xps100 opsys=usg5-2
 355   ;;
 356
 357   ## HP 9000 series 200 or 300
 358   m68*-hp-bsd* )
 359     machine=hp9000s300 opsys=bsd4-3
 360   ;;
 361   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 362   m68*-hp-hpux* )
 363     case "`uname -r`" in
 364       ## Someone's system reports A.B8.05 for this.
 365       ## I wonder what other possibilities there are.
 366       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 367       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 368       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 369       *.10.* ) machine=hp9000s300 opsys=hpux9shr ;;
 370       *) machine=hp9000s300 opsys=hpux ;;
 371     esac
 372   ;;
 373
 374   ## HP 9000 series 700 and 800, running HP/UX
 375   hppa*-hp-hpux7* )
 376     machine=hp800 opsys=hpux
 377   ;;
 378   hppa*-hp-hpux8* )
 379     machine=hp800 opsys=hpux8
 380   ;;
 381   hppa*-hp-hpux9shr* )
 382     machine=hp800 opsys=hpux9shr
 383   ;;
 384   hppa*-hp-hpux9* )
 385     machine=hp800 opsys=hpux9
 386   ;;
 387   hppa*-hp-hpux10* )
 388     machine=hp800 opsys=hpux9shr
 389   ;;
 390
 391   ## HP 9000 series 700 and 800, running HP/UX
 392   hppa*-hp-hpux* )
 393     ## Cross-compilation?  Nah!
 394     case "`uname -r`" in
 395       ## Someone's system reports A.B8.05 for this.
 396       ## I wonder what other possibilities there are.
 397       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 398       *.08.* ) machine=hp800 opsys=hpux8 ;;
 399       *.09.* ) machine=hp800 opsys=hpux9 ;;
 400       *) machine=hp800 opsys=hpux ;;
 401     esac
 402   ;;
 403
 404   ## Orion machines
 405   orion-orion-bsd* )
 406     machine=orion opsys=bsd4-2
 407   ;;
 408   clipper-orion-bsd* )
 409     machine=orion105 opsys=bsd4-2
 410   ;;
 411
 412   ## IBM machines
 413   i[345]86-ibm-aix1.1* )
 414     machine=ibmps2-aix opsys=usg5-2-2
 415   ;;
 416   i[345]86-ibm-aix1.[23]* | i[345]86-ibm-aix* )
 417     machine=ibmps2-aix opsys=usg5-3
 418   ;;
 419   i370-ibm-aix*)
 420     machine=ibm370aix opsys=usg5-3
 421   ;;
 422   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 423     machine=ibmrs6000 opsys=aix3-1
 424   ;;
 425   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 426     machine=ibmrs6000 opsys=aix3-2-5
 427   ;;
 428   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 429     machine=ibmrs6000 opsys=aix4-1
 430   ;;
 431   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 432     machine=ibmrs6000 opsys=aix4
 433   ;;
 434   rs6000-ibm-aix* | powerpc-ibm-aix* )
 435     machine=ibmrs6000 opsys=aix3-2
 436   ;;
 437   romp-ibm-bsd4.3* )
 438     machine=ibmrt opsys=bsd4-3
 439   ;;
 440   romp-ibm-bsd4.2* )
 441     machine=ibmrt opsys=bsd4-2
 442   ;;
 443   romp-ibm-aos4.3* )
 444     machine=ibmrt opsys=bsd4-3
 445   ;;
 446   romp-ibm-aos4.2* )
 447     machine=ibmrt opsys=bsd4-2
 448   ;;
 449   romp-ibm-aos* )
 450     machine=ibmrt opsys=bsd4-3
 451   ;;
 452   romp-ibm-bsd* )
 453     machine=ibmrt opsys=bsd4-3
 454   ;;
 455   romp-ibm-aix* )
 456     machine=ibmrt-aix opsys=usg5-2-2
 457   ;;
 458
 459   ## Integrated Solutions `Optimum V'
 460   m68*-isi-bsd4.2* )
 461     machine=isi-ov opsys=bsd4-2
 462   ;;
 463   m68*-isi-bsd4.3* )
 464     machine=isi-ov opsys=bsd4-3
 465   ;;
 466
 467   ## Intel 386 machines where we do care about the manufacturer
 468   i[345]86-intsys-sysv* )
 469     machine=is386 opsys=usg5-2-2
 470   ;;
 471
 472   ## Prime EXL
 473   i[345]86-prime-sysv* )
 474     machine=i386 opsys=usg5-3
 475   ;;
 476
 477   ## Sequent Symmetry running Dynix
 478   i[345]86-sequent-bsd* )
 479     machine=symmetry opsys=bsd4-3
 480   ;;
 481
 482   ## Sequent Symmetry running DYNIX/ptx
 483   ## Use the old cpp rather than the newer ANSI one.
 484   i[345]86-sequent-ptx* )
 485     machine=sequent-ptx opsys=ptx
 486     NON_GNU_CPP="/lib/cpp"
 487   ;;
 488
 489   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 490   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 491   i[345]86-ncr-sysv* )
 492     machine=ncr386 opsys=usg5-4-2
 493   ;;
 494
 495   ## Intel Paragon OSF/1
 496   i860-intel-osf1* )
 497     machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
 498   ;;
 499
 500   ## Intel 860
 501   i860-*-sysv4* )
 502     machine=i860 opsys=usg5-4
 503     NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
 504     NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
 505   ;;
 506
 507   ## Masscomp machines
 508   m68*-masscomp-rtu* )
 509     machine=masscomp opsys=rtu
 510   ;;
 511
 512   ## Megatest machines
 513   m68*-megatest-bsd* )
 514     machine=mega68 opsys=bsd4-2
 515   ;;
 516
 517   ## Workstations sold by MIPS
 518   ## This is not necessarily all workstations using the MIPS processor -
 519   ## Irises are produced by SGI, and DECstations by DEC.
 520
 521   ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
 522   ## and usg5-2-2 and bsd4-3 as possible OS files.  The only guidance
 523   ## it gives for choosing between the alternatives seems to be "Use
 524   ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
 525   ## the BSD world."  I'll assume that these are instructions for
 526   ## handling two odd situations, and that every other situation
 527   ## should use mips.h and usg5-2-2, they being listed first.
 528   mips-mips-usg* )
 529     machine=mips4
 530     ## Fall through to the general code at the bottom to decide on the OS.
 531   ;;
 532   mips-mips-riscos4* )
 533     machine=mips4 opsys=bsd4-3
 534     NON_GNU_CC="cc -systype bsd43"
 535     NON_GNU_CPP="cc -systype bsd43 -E"
 536   ;;
 537   mips-mips-riscos5* )
 538     machine=mips4 opsys=riscos5
 539     NON_GNU_CC="cc -systype bsd43"
 540     NON_GNU_CPP="cc -systype bsd43 -E"
 541   ;;
 542   mips-mips-bsd* )
 543     machine=mips opsys=bsd4-3
 544   ;;
 545   mips-mips-* )
 546     machine=mips opsys=usg5-2-2
 547   ;;
 548
 549   ## NeXT
 550   m68*-next-* | m68k-*-nextstep* )
 551     machine=m68k opsys=nextstep
 552   ;;
 553
 554   ## The complete machine from National Semiconductor
 555   ns32k-ns-genix* )
 556     machine=ns32000 opsys=usg5-2
 557   ;;
 558
 559   ## NCR machines
 560   m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
 561     machine=tower32 opsys=usg5-2-2
 562   ;;
 563   m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
 564     machine=tower32v3 opsys=usg5-3
 565   ;;
 566
 567   ## Nixdorf Targon 31
 568   m68*-nixdorf-sysv* )
 569     machine=targon31 opsys=usg5-2-2
 570   ;;
 571
 572   ## Nu (TI or LMI)
 573   m68*-nu-sysv* )
 574     machine=nu opsys=usg5-2
 575   ;;
 576
 577   ## Plexus
 578   m68*-plexus-sysv* )
 579     machine=plexus opsys=usg5-2
 580   ;;
 581
 582   ## Pyramid machines
 583   ## I don't really have any idea what sort of processor the Pyramid has,
 584   ## so I'm assuming it is its own architecture.
 585   pyramid-pyramid-bsd* )
 586     machine=pyramid opsys=bsd4-2
 587   ;;
 588
 589   ## Sequent Balance
 590   ns32k-sequent-bsd4.2* )
 591     machine=sequent opsys=bsd4-2
 592   ;;
 593   ns32k-sequent-bsd4.3* )
 594     machine=sequent opsys=bsd4-3
 595   ;;
 596
 597   ## Siemens Nixdorf
 598   mips-siemens-sysv* )
 599     machine=mips-siemens opsys=usg5-4
 600     NON_GNU_CC=/usr/ccs/bin/cc
 601     NON_GNU_CPP=/usr/ccs/lib/cpp
 602   ;;
 603
 604   ## Silicon Graphics machines
 605   ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
 606   m68*-sgi-iris3.5* )
 607     machine=irist opsys=iris3-5
 608   ;;
 609   m68*-sgi-iris3.6* | m68*-sgi-iris*)
 610     machine=irist opsys=iris3-6
 611   ;;
 612   ## Iris 4D
 613   mips-sgi-irix3* )
 614     machine=iris4d opsys=irix3-3
 615   ;;
 616   mips-sgi-irix4* )
 617     machine=iris4d opsys=irix4-0
 618   ;;
 619   mips-sgi-irix6* )
 620     machine=iris4d opsys=irix6-0
 621   ;;
 622   mips-sgi-irix5.[01]* )
 623     machine=iris4d opsys=irix5-0
 624   ;;
 625   mips-sgi-irix5* | mips-sgi-irix* )
 626     machine=iris4d opsys=irix5-2
 627   ;;
 628
 629   ## SONY machines
 630   m68*-sony-bsd4.2* )
 631     machine=news opsys=bsd4-2
 632   ;;
 633   m68*-sony-bsd4.3* )
 634     machine=news opsys=bsd4-3
 635   ;;
 636   m68*-sony-newsos3* | m68*-sony-news3*)
 637     machine=news opsys=bsd4-3
 638   ;;
 639   mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
 640     machine=news-risc opsys=bsd4-3
 641   ;;
 642   mips-sony-news* )
 643     machine=news-risc opsys=newsos5
 644   ;;
 645
 646   ## Stride
 647   m68*-stride-sysv* )
 648     machine=stride opsys=usg5-2
 649   ;;
 650
 651   ## Suns
 652   *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
 653     | i[345]86-*-solaris2* | i[345]86-*-sunos5* | powerpc*-*-solaris2* \
 654     | rs6000-*-solaris2*)
 655     case "${canonical}" in
 656       m68*-sunos1* )    machine=sun1 ;;
 657       m68*-sunos2* )    machine=sun2 ;;
 658       m68* )            machine=sun3 ;;
 659       i[345]86-sun-sunos[34]* ) machine=sun386 ;;
 660       i[345]86-*-* )     machine=intel386 ;;
 661       powerpc* | rs6000* )  machine=rs6000 ;;
 662       sparc* )          machine=sparc ;;
 663       * )               unported=yes ;;
 664     esac
 665     case "${canonical}" in
 666       ## The Sun386 didn't get past 4.0.
 667       i[345]86-*-sunos4   ) opsys=sunos4-0 ;;
 668       *-sunos4.0*         ) opsys=sunos4-0 ;;
 669       *-sunos4.1.[3-9]* | *-sunos4shr*)
 670                 opsys=sunos4shr
 671                 NON_GNU_CPP=/usr/lib/cpp
 672                 ;;
 673       *-sunos4* | *-sunos ) opsys=sunos4-1
 674                 NON_GCC_TEST_OPTIONS=-Bstatic
 675                 GCC_TEST_OPTIONS=-static
 676                 ;;
 677       *-sunos5.3* | *-solaris2.3* )
 678                 opsys=sol2-3
 679                 NON_GNU_CPP=/usr/ccs/lib/cpp
 680                 ;;
 681       *-sunos5.4* | *-solaris2.4* )
 682                 opsys=sol2-4
 683                 NON_GNU_CPP=/usr/ccs/lib/cpp
 684                 RANLIB="ar -ts"
 685                 ;;
 686       *-sunos5.5* | *-solaris2.5* )
 687                 opsys=sol2-5
 688                 NON_GNU_CPP=/usr/ccs/lib/cpp
 689                 RANLIB="ar -ts"
 690                 ;;
 691       *-sunos5* | *-solaris* )
 692                 opsys=sol2
 693                 NON_GNU_CPP=/usr/ccs/lib/cpp
 694                 ;;
 695       *                   ) opsys=bsd4-2   ;;
 696     esac
 697   ;;
 698   sparc-*-nextstep* )
 699     machine=sparc.h opsys=nextstep.h
 700   ;;
 701
 702   ## Tadpole 68k
 703   m68*-tadpole-sysv* )
 704     machine=tad68k opsys=usg5-3
 705   ;;
 706
 707   ## Tahoe machines
 708   tahoe-tahoe-bsd4.2* )
 709     machine=tahoe opsys=bsd4-2
 710   ;;
 711   tahoe-tahoe-bsd4.3* )
 712     machine=tahoe opsys=bsd4-3
 713   ;;
 714
 715   ## Tandem Integrity S2
 716   mips-tandem-sysv* )
 717     machine=tandem-s2 opsys=usg5-3
 718   ;;
 719
 720   ## Tektronix XD88
 721   m88k-tektronix-sysv3* )
 722   machine=tekxd88 opsys=usg5-3
 723   ;;
 724
 725   ## Tektronix 16000 box (6130?)
 726   ns16k-tektronix-bsd* )
 727     machine=ns16000 opsys=bsd4-2
 728   ;;
 729   ## Tektronix 4300
 730   ## src/m/tek4300.h hints that this is a m68k machine.
 731   m68*-tektronix-bsd* )
 732     machine=tek4300 opsys=bsd4-3
 733   ;;
 734
 735   ## Titan P2 or P3
 736   ## We seem to have lost the machine-description file titan.h!
 737   titan-titan-sysv* )
 738     machine=titan opsys=usg5-3
 739   ;;
 740
 741   ## Ustation E30 (SS5E)
 742   m68*-unisys-uniplus* )
 743     machine=ustation opsystem=unipl5-2
 744   ;;
 745
 746   ## Vaxen.
 747   vax-dec-* )
 748     machine=vax
 749     case "${canonical}" in
 750       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 751       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 752       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 753       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 754       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 755       *-vms* )                                          opsys=vms ;;
 756       * )                                               unported=yes
 757     esac
 758   ;;
 759
 760   ## Whitechapel MG1
 761   ns16k-whitechapel-* )
 762     machine=mg1
 763     ## We don't know what sort of OS runs on these; we'll let the
 764     ## operating system guessing code below try.
 765   ;;
 766
 767   ## Wicat
 768   m68*-wicat-sysv* )
 769     machine=wicat opsys=usg5-2
 770   ;;
 771
 772   ## Intel 386 machines where we don't care about the manufacturer
 773   i[345]86-*-* )
 774     machine=intel386
 775     case "${canonical}" in
 776       *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
 777       *-isc2.2* )               opsys=isc2-2 ;;
 778       *-isc4.0* )               opsys=isc4-0 ;;
 779       *-isc4.* )                opsys=isc4-1
 780                                 GCC_TEST_OPTIONS=-posix
 781                                 NON_GCC_TEST_OPTIONS=-Xp
 782                                 ;;
 783       *-isc* )                  opsys=isc3-0 ;;
 784       *-esix5* )                opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
 785       *-esix* )                 opsys=esix ;;
 786       *-xenix* )                opsys=xenix ;;
 787       *-linux* )                opsys=linux ;;
 788       *-sco3.2v4* )             opsys=sco4 ; NON_GNU_CPP=/lib/cpp  ;;
 789       *-bsd386* | *-bsdi1* )    opsys=bsd386 ;;
 790       *-bsdi2* )                opsys=bsdos2 ;;
 791       *-386bsd* )               opsys=386bsd ;;
 792       *-freebsd* )              opsys=freebsd ;;
 793       *-nextstep* )             opsys=nextstep ;;
 794       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 795     esac
 796   ;;
 797
 798   * )
 799     unported=yes
 800   ;;
 801 esac
 802
 803 ### If the code above didn't choose an operating system, just choose
 804 ### an operating system based on the configuration name.  You really
 805 ### only want to use this when you have no idea what the right
 806 ### operating system is; if you know what operating systems a machine
 807 ### runs, it's cleaner to make it explicit in the case statement
 808 ### above.
 809 if test x"${opsys}" = x; then
 810   case "${canonical}" in
 811     *-gnu* )                            opsys=gnu ;;
 812     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 813     *-bsd4.2 )                          opsys=bsd4-2 ;;
 814     *-bsd4.3 )                          opsys=bsd4-3 ;;
 815     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 816     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 817     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 818     *-sysv3* | *-sysvr3* )              opsys=usg5-3 ;;
 819     *-sysv4.1* | *-sysvr4.1* )
 820         NON_GNU_CPP=/usr/lib/cpp
 821         opsys=usg5-4 ;;
 822     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 823         if [ x$NON_GNU_CPP = x ]; then
 824           NON_GNU_CPP=/usr/ccs/lib/cpp
 825         fi
 826         opsys=usg5-4-2 ;;
 827     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 828     * )
 829       unported=yes
 830     ;;
 831   esac
 832 fi
 833
 834 if test "x$RANLIB" = x; then
 835   RANLIB=ranlib
 836 fi
 837
 838 changequote([, ])dnl
 839
 840 if test $unported = yes; then
 841   AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
 842 Check \`etc/MACHINES' for recognized configuration names.])
 843 fi
 844
 845 machfile="m/${machine}.h"
 846 opsysfile="s/${opsys}.h"
 847
 848
 849 #### Choose a compiler.
 850 test -n "$CC" && cc_specified=yes
 851
 852 # Save the value of CFLAGS that the user specified.
 853 SPECIFIED_CFLAGS="$CFLAGS"
 854
 855 case ${with_gcc} in
 856   "yes" ) CC="gcc" GCC=yes ;;
 857   "no"  ) : ${CC=cc} ;;
 858   * ) AC_PROG_CC
 859 esac
 860
 861 # On Suns, sometimes $CPP names a directory.
 862 if test -n "$CPP" && test -d "$CPP"; then
 863   CPP=
 864 fi
 865
 866 #### Some systems specify a CPP to use unless we are using GCC.
 867 #### Now that we know whether we are using GCC, we can decide whether
 868 #### to use that one.
 869 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 870 then
 871   CPP="$NON_GNU_CPP"
 872 fi
 873
 874 #### Some systems specify a CC to use unless we are using GCC.
 875 #### Now that we know whether we are using GCC, we can decide whether
 876 #### to use that one.
 877 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 878   test x$cc_specified != xyes
 879 then
 880   CC="$NON_GNU_CC"
 881 fi
 882
 883 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 884 then
 885   CC="$CC $GCC_TEST_OPTIONS"
 886 fi
 887
 888 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 889 then
 890   CC="$CC $NON_GCC_TEST_OPTIONS"
 891 fi
 892
 893 #### Some other nice autoconf tests.  If you add a test here which
 894 #### should make an entry in src/config.h, don't forget to add an
 895 #### #undef clause to src/config.h.in for autoconf to modify.
 896
 897 dnl checks for programs
 898 AC_PROG_LN_S
 899 AC_PROG_CPP
 900 AC_PROG_INSTALL
 901 AC_PROG_YACC
 902
 903 dnl checks for Unix variants
 904 AC_AIX
 905
 906 dnl checks for header files
 907 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h)
 908 AC_HEADER_STDC
 909 AC_HEADER_TIME
 910 AC_DECL_SYS_SIGLIST
 911
 912 dnl Some systems have utime.h but don't declare the struct anyplace.
 913 AC_MSG_CHECKING(for struct utimbuf)
 914 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
 915 #include <sys/time.h>
 916 #include <time.h>
 917 #else
 918 #ifdef HAVE_SYS_TIME_H
 919 #include <sys/time.h>
 920 #else
 921 #include <time.h>
 922 #endif
 923 #endif
 924 #ifdef HAVE_UTIME_H
 925 #include <utime.h>
 926 #endif], [static struct utimbuf x; x.actime = x.modtime;],
 927   [AC_MSG_RESULT(yes)
 928    AC_DEFINE(HAVE_STRUCT_UTIMBUF)],
 929   AC_MSG_RESULT(no))
 930
 931 dnl checks for typedefs
 932 AC_TYPE_SIGNAL
 933
 934 AC_MSG_CHECKING(for struct timeval)
 935 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
 936 #include <sys/time.h>
 937 #include <time.h>
 938 #else
 939 #ifdef HAVE_SYS_TIME_H
 940 #include <sys/time.h>
 941 #else
 942 #include <time.h>
 943 #endif
 944 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
 945   [AC_MSG_RESULT(yes)
 946    HAVE_TIMEVAL=yes
 947    AC_DEFINE(HAVE_TIMEVAL)],
 948   AC_MSG_RESULT(no))
 949
 950 dnl checks for structure members
 951 AC_STRUCT_TM
 952 AC_STRUCT_TIMEZONE
 953
 954 dnl checks for compiler characteristics
 955 AC_C_CONST
 956
 957 dnl check for Make feature
 958 AC_PROG_MAKE_SET
 959
 960 dnl checks for operating system services
 961 AC_SYS_LONG_FILE_NAMES
 962
 963 #### Choose a window system.
 964
 965 AC_PATH_X
 966 if test "$no_x" = yes; then
 967   window_system=none
 968 else
 969   window_system=x11
 970 fi
 971
 972 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
 973   LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
 974   LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
 975 fi
 976 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
 977   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
 978 fi
 979
 980 if test x"${x_includes}" = x; then
 981   bitmapdir=/usr/include/X11/bitmaps
 982 else
 983   # accumulate include directories that have X11 bitmap sudirectories
 984   bmd_acc="dummyval"
 985   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
 986     if test -d "${bmd}/X11/bitmaps"; then
 987       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
 988     elif test -d "${bmd}/bitmaps"; then
 989       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
 990     fi
 991   done
 992   if test ${bmd_acc} != "dummyval"; then
 993     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
 994   fi
 995 fi
 996
 997 case "${window_system}" in
 998   x11 )
 999     HAVE_X_WINDOWS=yes
1000     HAVE_X11=yes
1001     case "${with_x_toolkit}" in
1002       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1003       motif ) USE_X_TOOLKIT=MOTIF ;;
1004 dnl      open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1005       * ) USE_X_TOOLKIT=none ;;
1006     esac
1007   ;;
1008   none )
1009     HAVE_X_WINDOWS=no
1010     HAVE_X11=no
1011     USE_X_TOOLKIT=none
1012   ;;
1013 esac
1014 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1015
1016 ### If we're using X11, we should use the X menu package.
1017 HAVE_X_MENU=no
1018 case ${HAVE_X11} in
1019   yes ) HAVE_X_MENU=yes ;;
1020 esac
1021
1022 if test "${opsys}" = "hpux9"; then
1023   case "${x_libraries}" in
1024     *X11R4* )
1025       opsysfile="s/hpux9-x11r4.h"
1026       ;;
1027   esac
1028 fi
1029
1030 if test "${opsys}" = "hpux9shr"; then
1031   case "${x_libraries}" in
1032     *X11R4* )
1033       opsysfile="s/hpux9shxr4.h"
1034       ;;
1035   esac
1036 fi
1037
1038 #### Extract some information from the operating system and machine files.
1039
1040 AC_CHECKING([the machine- and system-dependent files to find out
1041  - which libraries the lib-src programs will want, and
1042  - whether the GNU malloc routines are usable])
1043
1044 ### First figure out CFLAGS (which we use for running the compiler here)
1045 ### and REAL_CFLAGS (which we use for real compilation).
1046 ### The two are the same except on a few systems, where they are made
1047 ### different to work around various lossages.  For example,
1048 ### GCC 2.5 on Linux needs them to be different because it treats -g
1049 ### as implying static linking.
1050
1051 ### If the CFLAGS env var is specified, we use that value
1052 ### instead of the default.
1053
1054 ### It's not important that this name contain the PID; you can't run
1055 ### two configures in the same directory and have anything work
1056 ### anyway.
1057 tempcname="conftest.c"
1058
1059 echo '
1060 #include "'${srcdir}'/src/'${opsysfile}'"
1061 #include "'${srcdir}'/src/'${machfile}'"
1062 #ifndef LIBS_MACHINE
1063 #define LIBS_MACHINE
1064 #endif
1065 #ifndef LIBS_SYSTEM
1066 #define LIBS_SYSTEM
1067 #endif
1068 #ifndef C_SWITCH_SYSTEM
1069 #define C_SWITCH_SYSTEM
1070 #endif
1071 #ifndef C_SWITCH_MACHINE
1072 #define C_SWITCH_MACHINE
1073 #endif
1074 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1075 configure___ c_switch_system=C_SWITCH_SYSTEM
1076 configure___ c_switch_machine=C_SWITCH_MACHINE
1077
1078 #ifndef LIB_X11_LIB
1079 #define LIB_X11_LIB -lX11
1080 #endif
1081
1082 #ifndef LIBX11_MACHINE
1083 #define LIBX11_MACHINE
1084 #endif
1085
1086 #ifndef LIBX11_SYSTEM
1087 #define LIBX11_SYSTEM
1088 #endif
1089 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1090
1091 #ifdef UNEXEC
1092 configure___ unexec=UNEXEC
1093 #else
1094 configure___ unexec=unexec.o
1095 #endif
1096
1097 #ifdef SYSTEM_MALLOC
1098 configure___ system_malloc=yes
1099 #else
1100 configure___ system_malloc=no
1101 #endif
1102
1103 #ifndef C_DEBUG_SWITCH
1104 #define C_DEBUG_SWITCH -g
1105 #endif
1106
1107 #ifndef C_OPTIMIZE_SWITCH
1108 #define C_OPTIMIZE_SWITCH -O
1109 #endif
1110
1111 #ifdef THIS_IS_CONFIGURE
1112
1113 /* Get the CFLAGS for tests in configure.  */
1114 #ifdef __GNUC__
1115 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1116 #else
1117 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1118 #endif
1119
1120 #else /* not THIS_IS_CONFIGURE */
1121
1122 /* Get the CFLAGS for real compilation.  */
1123 #ifdef __GNUC__
1124 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1125 #else
1126 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1127 #endif
1128
1129 #endif /* not THIS_IS_CONFIGURE */
1130 ' > ${tempcname}
1131
1132 # The value of CPP is a quoted variable reference, so we need to do this
1133 # to get its actual value...
1134 CPP=`eval "echo $CPP"`
1135 changequote(, )dnl
1136 eval `${CPP} -Isrc ${tempcname} \
1137        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1138 if test "x$SPECIFIED_CFLAGS" = x; then
1139   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1140          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1141 else
1142   REAL_CFLAGS="$CFLAGS"
1143 fi
1144 changequote([, ])dnl
1145 rm ${tempcname}
1146
1147 ### Compute the unexec source name from the object name.
1148 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1149
1150 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1151 # Assume not, until told otherwise.
1152 GNU_MALLOC=yes
1153 if test "${system_malloc}" = "yes"; then
1154   GNU_MALLOC=no
1155   GNU_MALLOC_reason="
1156   (The GNU allocators don't work with this system configuration.)"
1157 fi
1158
1159 if test x"${REL_ALLOC}" = x; then
1160   REL_ALLOC=${GNU_MALLOC}
1161 fi
1162
1163 LISP_FLOAT_TYPE=yes
1164
1165
1166 #### Add the libraries to LIBS and check for some functions.
1167
1168 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1169 LIBS="$libsrc_libs"
1170
1171 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1172 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1173 AC_CHECK_LIB(dnet, dnet_ntoa)
1174 dnl This causes -lresolv to get used in subsequent tests,
1175 dnl which causes failures on some systems such as HPUX 9.
1176 dnl AC_CHECK_LIB(resolv, gethostbyname)
1177
1178 dnl FIXME replace main with a function we actually want from this library.
1179 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1180
1181 AC_CHECK_LIB(pthreads, cma_open)
1182
1183 AC_MSG_CHECKING(for XFree86)
1184 if test -d /usr/X386/include; then
1185   HAVE_XFREE386=yes
1186   : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1187 else
1188   HAVE_XFREE386=no
1189 fi
1190 AC_MSG_RESULT($HAVE_XFREE386)
1191
1192 # Change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1193 # for the tests that follow.  We set it back to REAL_CFLAGS later on.
1194
1195 if test "${HAVE_X11}" = "yes"; then
1196   DEFS="$C_SWITCH_X_SITE $DEFS"
1197   LIBS="$LD_SWITCH_X_SITE $LIBX $LIBS"
1198   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1199
1200   if test "${opsys}" = "linux"; then
1201     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1202     AC_TRY_LINK([],
1203      [XOpenDisplay ("foo");],
1204      [xlinux_first_failure=no],
1205      [xlinux_first_failure=yes])
1206     if test "${xlinux_first_failure}" = "yes"; then
1207       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1208       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1209       OLD_CPPFLAGS="$CPPFLAGS"
1210       OLD_LIBS="$LIBS"
1211       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1212       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1213       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1214       LIBS="$LIBS -b i486-linuxaout"
1215       AC_TRY_LINK([],
1216        [XOpenDisplay ("foo");],
1217        [xlinux_second_failure=no],
1218        [xlinux_second_failure=yes])
1219       if test "${xlinux_second_failure}" = "yes"; then
1220         # If we get the same failure with -b, there is no use adding -b.
1221         # So take it out.  This plays safe.
1222         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1223         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1224         CPPFLAGS="$OLD_CPPFLAGS"
1225         LIBS="$OLD_LIBS"
1226         AC_MSG_RESULT(no)
1227       else
1228         AC_MSG_RESULT(yes)
1229       fi
1230     else
1231       AC_MSG_RESULT(no)
1232     fi
1233   fi
1234
1235   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1236 XScreenNumberOfScreen XSetWMProtocols)
1237 fi
1238
1239 if test "${USE_X_TOOLKIT}" != "none"; then
1240   AC_MSG_CHECKING(X11 toolkit version)
1241   AC_TRY_LINK([#include <X11/Intrinsic.h>],
1242 [#if XtSpecificationRelease < 6
1243 fail;
1244 #endif
1245 ], [AC_MSG_RESULT(6)
1246     AC_DEFINE(HAVE_X11XTR6)],
1247    [AC_MSG_RESULT(not 6)])
1248 fi
1249
1250 # If netdb.h doesn't declare h_errno, we must declare it by hand.
1251 AC_MSG_CHECKING(whether netdb declares h_errno)
1252 AC_TRY_LINK([#include <netdb.h>],
1253   [return h_errno;],
1254   [AC_MSG_RESULT(yes)
1255    AC_DEFINE(HAVE_H_ERRNO)],
1256   [AC_MSG_RESULT(no)])
1257
1258 AC_FUNC_ALLOCA
1259
1260 # fmod, logb, and frexp are found in -lm on most systems.
1261 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
1262 AC_CHECK_LIB(m, sqrt(0.0) + t)
1263 AC_CHECK_FUNCS(gettimeofday gethostname dup2 rename closedir mkdir rmdir \
1264 random lrand48 bcopy bcmp logb frexp fmod drem ftime res_init setsid \
1265 strerror fpathconf select mktime eaccess getpagesize tzset)
1266
1267 AC_MSG_CHECKING(whether localtime caches TZ)
1268 AC_CACHE_VAL(emacs_cv_localtime_cache,
1269 [if test $ac_cv_func_tzset = yes; then
1270 AC_TRY_RUN([#include <time.h>
1271 #if STDC_HEADERS
1272 # include <stdlib.h>
1273 #endif
1274 main()
1275 {
1276   time_t now = time ((time_t *) 0);
1277   int hour;
1278   if (putenv ("TZ=GMT0") != 0)
1279     exit (1);
1280   hour = localtime (&now)->tm_hour;
1281   if (putenv ("TZ=PST8") != 0)
1282     exit (1);
1283   exit (localtime (&now)->tm_hour == hour);
1284 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
1285 [# If we have tzset, assume the worst when cross-compiling.
1286 emacs_cv_localtime_cache=yes])
1287 else
1288         # If we lack tzset, report that localtime does not cache TZ,
1289         # since we can't invalidate the cache if we don't have tzset.
1290         emacs_cv_localtime_cache=no
1291 fi])dnl
1292 AC_MSG_RESULT($emacs_cv_localtime_cache)
1293 if test $emacs_cv_localtime_cache = yes; then
1294   AC_DEFINE(LOCALTIME_CACHE)
1295 fi
1296
1297 if test $HAVE_TIMEVAL = yes; then
1298 AC_MSG_CHECKING(whether gettimeofday can't accept two arguments)
1299 AC_TRY_LINK([
1300 #ifdef TIME_WITH_SYS_TIME
1301 #include <sys/time.h>
1302 #include <time.h>
1303 #else
1304 #ifdef HAVE_SYS_TIME_H
1305 #include <sys/time.h>
1306 #else
1307 #include <time.h>
1308 #endif
1309 #endif
1310   ],
1311   [
1312   struct timeval time;
1313   struct timezone dummy;
1314   gettimeofday (&time, &dummy);
1315 ],
1316   [AC_MSG_RESULT(no)],
1317   [AC_MSG_RESULT(yes)
1318    AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)])
1319 fi
1320
1321 ok_so_far=yes
1322 AC_CHECK_FUNC(socket, , ok_so_far=no)
1323 if test $ok_so_far = yes; then
1324   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
1325 fi
1326 if test $ok_so_far = yes; then
1327   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
1328 fi
1329 if test $ok_so_far = yes; then
1330   AC_DEFINE(HAVE_INET_SOCKETS)
1331 fi
1332
1333 if test -f /usr/lpp/X11/bin/smt.exp; then
1334   AC_DEFINE(HAVE_AIX_SMT_EXP)
1335 fi
1336
1337 # Set up the CFLAGS for real compilation, so we can substitute it.
1338 CFLAGS="$REAL_CFLAGS"
1339
1340 changequote(, )dnl
1341 #### Find out which version of Emacs this is.
1342 version=`grep 'defconst[         ]*emacs-version' ${srcdir}/lisp/version.el \
1343          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
1344 changequote([, ])dnl
1345 if test x"${version}" = x; then
1346   AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
1347 fi
1348
1349 ### Specify what sort of things we'll be editing into Makefile and config.h.
1350 ### Use configuration here uncanonicalized to avoid exceeding size limits.
1351 AC_SUBST(version)
1352 AC_SUBST(configuration)
1353 AC_SUBST(canonical)
1354 AC_SUBST(srcdir)
1355 AC_SUBST(prefix)
1356 AC_SUBST(exec_prefix)
1357 AC_SUBST(bindir)
1358 AC_SUBST(datadir)
1359 AC_SUBST(sharedstatedir)
1360 AC_SUBST(libexecdir)
1361 AC_SUBST(mandir)
1362 AC_SUBST(infodir)
1363 AC_SUBST(lispdir)
1364 AC_SUBST(locallisppath)
1365 AC_SUBST(lisppath)
1366 AC_SUBST(etcdir)
1367 AC_SUBST(lockdir)
1368 AC_SUBST(archlibdir)
1369 AC_SUBST(docdir)
1370 AC_SUBST(bitmapdir)
1371 AC_SUBST(c_switch_system)
1372 AC_SUBST(c_switch_machine)
1373 AC_SUBST(LD_SWITCH_X_SITE)
1374 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1375 AC_SUBST(C_SWITCH_X_SITE)
1376 AC_SUBST(CFLAGS)
1377 AC_SUBST(X_TOOLKIT_TYPE)
1378 AC_SUBST(machfile)
1379 AC_SUBST(opsysfile)
1380 AC_SUBST(RANLIB)
1381
1382 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}")
1383 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}")
1384 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}")
1385 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}")
1386 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE})
1387 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX})
1388 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE})
1389 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC})
1390
1391 if test "${HAVE_X_WINDOWS}" = "yes" ; then
1392   AC_DEFINE(HAVE_X_WINDOWS)
1393 fi
1394 if test "${USE_X_TOOLKIT}" != "none" ; then
1395   AC_DEFINE(USE_X_TOOLKIT)
1396 fi
1397 if test "${HAVE_X11}" = "yes" ; then
1398   AC_DEFINE(HAVE_X11)
1399 fi
1400 if test "${HAVE_XFREE386}" = "yes" ; then
1401   AC_DEFINE(HAVE_XFREE386)
1402 fi
1403 if test "${HAVE_X_MENU}" = "yes" ; then
1404   AC_DEFINE(HAVE_X_MENU)
1405 fi
1406 if test "${GNU_MALLOC}" = "yes" ; then
1407   AC_DEFINE(GNU_MALLOC)
1408 fi
1409 if test "${REL_ALLOC}" = "yes" ; then
1410   AC_DEFINE(REL_ALLOC)
1411 fi
1412 if test "${LISP_FLOAT_TYPE}" = "yes" ; then
1413   AC_DEFINE(LISP_FLOAT_TYPE)
1414 fi
1415
1416 #### Report on what we decided to do.
1417 echo "
1418 Configured for \`${canonical}'.
1419
1420   Where should the build process find the source code?    ${srcdir}
1421   What operating system and machine description files should Emacs use?
1422         \`${opsysfile}' and \`${machfile}'
1423   What compiler should emacs be built with?               ${CC} ${CFLAGS}
1424   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
1425   Should Emacs use the relocating allocator for buffers?  ${REL_ALLOC}
1426   What window system should Emacs use?                    ${window_system}
1427   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
1428
1429 if test -n "${x_includes}"; then
1430 echo "  Where do we find X Windows header files?                ${x_includes}"
1431 else
1432 echo "  Where do we find X Windows header files?                Standard dirs"
1433 fi
1434 if test -n "${x_libraries}"; then
1435 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
1436 else
1437 echo "  Where do we find X Windows libraries?                   Standard dirs"
1438 fi
1439
1440 echo
1441
1442 # Remove any trailing slashes in these variables.
1443 changequote(, )dnl
1444 test "${prefix}" != NONE &&
1445   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
1446 test "${exec_prefix}" != NONE &&
1447   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
1448 changequote([, ])dnl
1449
1450 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
1451         man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in, [
1452
1453 ### Make the necessary directories, if they don't exist.
1454 for dir in cpp etc ; do
1455   test -d ${dir} || mkdir ${dir}
1456 done
1457
1458 # Build src/Makefile from ${srcdir}/src/Makefile.c
1459 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
1460 # This must be done after src/config.h is built, since we rely on that file.
1461
1462 changequote(, )dnl The horror, the horror.
1463 # Now get this: Some word that is part of the ${srcdir} directory name
1464 # or the ${configuration} value might, just might, happen to be an
1465 # identifier like `sun4' or `i386' or something, and be predefined by
1466 # the C preprocessor to some helpful value like 1, or maybe the empty
1467 # string.  Needless to say consequent macro substitutions are less
1468 # than conducive to the makefile finding the correct directory.
1469 undefs="`echo $top_srcdir $configuration $canonical |
1470 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
1471     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
1472 `"
1473 changequote([, ])dnl
1474
1475 echo creating lib-src/Makefile
1476 ( cd lib-src
1477   rm -f junk.c junk1.c junk2.c
1478   sed -e '/start of cpp stuff/q' \
1479       < Makefile.c > junk1.c
1480   sed -e '1,/start of cpp stuff/d'\
1481       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1482       < Makefile.c > junk.c
1483   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1484       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
1485   cat junk1.c junk2.c > Makefile.new
1486   rm -f junk.c junk1.c junk2.c
1487   chmod 444 Makefile.new
1488   mv -f Makefile.new Makefile
1489 )
1490
1491 echo creating src/Makefile
1492 ( cd src
1493   rm -f junk.c junk1.c junk2.c
1494   sed -e '/start of cpp stuff/q' \
1495       < Makefile.c > junk1.c
1496   sed -e '1,/start of cpp stuff/d'\
1497       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1498       < Makefile.c > junk.c
1499   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1500       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
1501   cat junk1.c junk2.c > Makefile.new
1502   rm -f junk.c junk1.c junk2.c
1503   chmod 444 Makefile.new
1504   mv -f Makefile.new Makefile
1505 )
1506
1507 if test ! -f src/.gdbinit && test -f $top_srcdir/src/.gdbinit; then
1508   echo creating src/.gdbinit
1509   echo source $top_srcdir/src/.gdbinit > src/.gdbinit
1510 fi
1511
1512 ], [CPP="$CPP" CPPFLAGS="$CPPFLAGS"])