lisp/term/w32-win.el

   1 ;;; w32-win.el --- parse switches controlling interface with W32 window system -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 1993-1994, 2001-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Kevin Gallo
   6 ;; Keywords: terminals
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; w32-win.el:  this file is loaded from ../lisp/startup.el when it recognizes
  26 ;; that W32 windows are to be used.  Command line switches are parsed and those
  27 ;; pertaining to W32 are processed and removed from the command line.  The
  28 ;; W32 display is opened and hooks are set for popping up the initial window.
  29
  30 ;; startup.el will then examine startup files, and eventually call the hooks
  31 ;; which create the first window (s).
  32
  33 ;;; Code:
  34 \f
  35
  36 ;; These are the standard X switches from the Xt Initialize.c file of
  37 ;; Release 4.
  38
  39 ;; Command line         Resource Manager string
  40
  41 ;; +rv                  *reverseVideo
  42 ;; +synchronous         *synchronous
  43 ;; -background          *background
  44 ;; -bd                  *borderColor
  45 ;; -bg                  *background
  46 ;; -bordercolor         *borderColor
  47 ;; -borderwidth         .borderWidth
  48 ;; -bw                  .borderWidth
  49 ;; -display             .display
  50 ;; -fg                  *foreground
  51 ;; -fn                  *font
  52 ;; -font                *font
  53 ;; -foreground          *foreground
  54 ;; -geometry            .geometry
  55 ;; -i                   .iconType
  56 ;; -itype               .iconType
  57 ;; -iconic              .iconic
  58 ;; -name                .name
  59 ;; -reverse             *reverseVideo
  60 ;; -rv                  *reverseVideo
  61 ;; -selectionTimeout    .selectionTimeout
  62 ;; -synchronous         *synchronous
  63 ;; -xrm
  64
  65 ;; An alist of X options and the function which handles them.  See
  66 ;; ../startup.el.
  67
  68 ;; (if (not (eq window-system 'w32))
  69 ;;     (error "%s: Loading w32-win.el but not compiled for w32" (invocation-name)))
  70
  71 (eval-when-compile (require 'cl-lib))
  72 (require 'frame)
  73 (require 'mouse)
  74 (require 'scroll-bar)
  75 (require 'faces)
  76 (require 'select)
  77 (require 'menu-bar)
  78 (require 'dnd)
  79 (require 'w32-vars)
  80
  81 ;; Keep an obsolete alias for w32-focus-frame and w32-select-font in case
  82 ;; they are used by code outside Emacs.
  83 (define-obsolete-function-alias 'w32-focus-frame 'x-focus-frame "23.1")
  84 (declare-function x-select-font "w32font.c"
  85                   (&optional frame exclude-proportional))
  86 (define-obsolete-function-alias 'w32-select-font 'x-select-font "23.1")
  87
  88 (defvar w32-color-map) ;; defined in w32fns.c
  89 (make-obsolete 'w32-default-color-map nil "24.1")
  90
  91 (declare-function w32-send-sys-command "w32fns.c")
  92 (declare-function set-message-beep "w32fns.c")
  93
  94 (declare-function cygwin-convert-file-name-from-windows "cygw32.c"
  95                   (path &optional absolute_p))
  96
  97 ;; Conditional on new-fontset so bootstrapping works on non-GUI compiles
  98 (if (fboundp 'new-fontset)
  99     (require 'fontset))
 100
 101 ;; The following definition is used for debugging scroll bar events.
 102 ;(defun w32-handle-scroll-bar-event (event) (interactive "e") (princ event))
 103
 104 ;; (defun w32-drag-n-drop-debug (event)
 105 ;;   "Print the drag-n-drop EVENT in a readable form."
 106 ;;   (interactive "e")
 107 ;;   (princ event))
 108
 109 (defun w32-handle-dropped-file (window file-name)
 110   (let ((f (if (eq system-type 'cygwin)
 111                (cygwin-convert-file-name-from-windows file-name t)
 112              (subst-char-in-string ?\\ ?/ file-name)))
 113         (coding (if (eq system-type 'windows-nt)
 114                     ;; Native w32 build pretends that its file names
 115                     ;; are encoded in UTF-8, and converts to the
 116                     ;; appropriate encoding internally.
 117                     'utf-8
 118                   (or file-name-coding-system
 119                       default-file-name-coding-system))))
 120
 121     (setq file-name
 122           (mapconcat 'url-hexify-string
 123                      (split-string (encode-coding-string f coding)
 124                                    "/")
 125                      "/")))
 126                 (dnd-handle-one-url window 'private
 127                                     (concat
 128                                      (if (eq system-type 'cygwin)
 129                                          "file://"
 130                                        "file:")
 131                                      file-name)))
 132
 133 (defun w32-drag-n-drop (event &optional new-frame)
 134   "Edit the files listed in the drag-n-drop EVENT.
 135 Switch to a buffer editing the last file dropped."
 136   (interactive "e")
 137   (save-excursion
 138     ;; Make sure the drop target has positive co-ords
 139     ;; before setting the selected frame - otherwise it
 140     ;; won't work.  <skx@tardis.ed.ac.uk>
 141     (let* ((window (posn-window (event-start event)))
 142            (coords (posn-x-y (event-start event)))
 143            (x (car coords))
 144            (y (cdr coords)))
 145       (if (and (> x 0) (> y 0))
 146           (set-frame-selected-window nil window))
 147
 148       (when new-frame
 149         (select-frame (make-frame)))
 150       (raise-frame)
 151       (setq window (selected-window))
 152
 153       (mapc (apply-partially #'w32-handle-dropped-file window)
 154             (car (cdr (cdr event)))))))
 155
 156 (defun w32-drag-n-drop-other-frame (event)
 157   "Edit the files listed in the drag-n-drop EVENT, in other frames.
 158 May create new frames, or reuse existing ones.  The frame editing
 159 the last file dropped is selected."
 160   (interactive "e")
 161   (w32-drag-n-drop event t))
 162
 163 ;; Bind the drag-n-drop event.
 164 (global-set-key [drag-n-drop] 'w32-drag-n-drop)
 165 (global-set-key [C-drag-n-drop] 'w32-drag-n-drop-other-frame)
 166
 167 ;; Keyboard layout/language change events
 168 ;; For now ignore language-change events; in the future
 169 ;; we should switch the Emacs Input Method to match the
 170 ;; new layout/language selected by the user.
 171 (global-set-key [language-change] 'ignore)
 172
 173 (defvar x-resource-name)
 174
 175 \f
 176 ;;;; Function keys
 177
 178  ;;; make f10 activate the real menubar rather than the mini-buffer menu
 179  ;;; navigation feature.
 180  (defun w32-menu-bar-open (&optional frame)
 181    "Start key navigation of the menu bar in FRAME.
 182
 183 This initially activates the first menu-bar item, and you can then navigate
 184 with the arrow keys, select a menu entry with the Return key or cancel with
 185 the Escape key.  If FRAME has no menu bar, this function does nothing.
 186
 187 If FRAME is nil or not given, use the selected frame.
 188 If FRAME does not have the menu bar enabled, display a text menu using
 189 `tmm-menubar'."
 190    (interactive "i")
 191    (if menu-bar-mode
 192        (w32-send-sys-command ?\xf100 frame)
 193      (with-selected-frame (or frame (selected-frame))
 194        (tmm-menubar))))
 195 \f
 196
 197 ;; W32 systems have different fonts than commonly found on X, so
 198 ;; we define our own standard fontset here.
 199 (defvar w32-standard-fontset-spec
 200  "-*-Courier New-normal-r-*-*-13-*-*-*-c-*-fontset-standard"
 201  "String of fontset spec of the standard fontset.
 202 This defines a fontset consisting of the Courier New variations for
 203 European languages which are distributed with Windows as
 204 \"Multilanguage Support\".
 205
 206 See the documentation of `create-fontset-from-fontset-spec' for the format.")
 207
 208 (defun w32-win-suspend-error ()
 209   "Report an error when a suspend is attempted."
 210   (error "Suspending an Emacs running under W32 makes no sense"))
 211
 212 (defvar dynamic-library-alist)
 213 (defvar libpng-version)                 ; image.c #ifdef HAVE_NTGUI
 214 (defvar libgif-version)
 215 (defvar libjpeg-version)
 216
 217 (defvar libgnutls-version)              ; gnutls.c
 218
 219 ;;; Set default known names for external libraries
 220 (setq dynamic-library-alist
 221       (list
 222        '(xpm "libxpm.dll" "xpm4.dll" "libXpm-nox4.dll")
 223        ;; Versions of libpng 1.4.x and later are incompatible with
 224        ;; earlier versions.  Set up the list of libraries according to
 225        ;; the version we were compiled against.  (If we were compiled
 226        ;; without PNG support, libpng-version's value is -1.)
 227        (if (>= libpng-version 10400)
 228            (let ((major (/ libpng-version 10000))
 229                  (minor (mod (/ libpng-version 100) 10)))
 230              (list 'png
 231                    ;; libpngXY.dll is the default name when building
 232                    ;; with CMake or from a lpngXYY tarball on w32,
 233                    ;; libpngXY-XY.dll is the DLL name when building
 234                    ;; with libtool / autotools
 235                    (format "libpng%d%d.dll" major minor)
 236                    (format "libpng%d%d-%d%d.dll" major minor major minor)))
 237          '(png "libpng12d.dll" "libpng12.dll" "libpng3.dll" "libpng.dll"
 238                ;; these are libpng 1.2.8 from GTK+
 239                "libpng13d.dll" "libpng13.dll"))
 240        '(tiff "libtiff-5.dll" "libtiff3.dll" "libtiff.dll")
 241        (if (> libjpeg-version 62)
 242            ;; Versions of libjpeg after 6b are incompatible with
 243            ;; earlier versions, and each of versions 7, 8, and 9 is
 244            ;; also incompatible with the preceding ones (the core data
 245            ;; structures used for communications with the library
 246            ;; gained additional members with each new version).  So we
 247            ;; must use only the version of the library which Emacs was
 248            ;; compiled against.
 249            (list 'jpeg (format "libjpeg-%d.dll" (/ libjpeg-version 10)))
 250          '(jpeg "jpeg62.dll" "libjpeg.dll" "jpeg-62.dll" "jpeg.dll"))
 251        ;; Versions of giflib 5.0.0 and later changed signatures of
 252        ;; several functions used by Emacs, which makes those versions
 253        ;; incompatible with previous ones.  We select the correct
 254        ;; libraries according to the version of giflib we were
 255        ;; compiled against.  (If we were compiled without GIF support,
 256        ;; libgif-version's value is -1.)
 257        (if (>= libgif-version 50100)
 258            ;; Yes, giflib 5.0 uses 6 as the major version of the API,
 259            ;; and giflib 5.1 uses 7, thus "libgif-7.dll" and
 260            ;; "libgif-6.dll" below (giflib 4.x used 5 as the major API
 261            ;; version).  giflib5.dll is from the lua-files project,
 262            ;; and gif.dll is from luapower.
 263            '(gif "libgif-7.dll")
 264          (if (>= libgif-version 50000)
 265              '(gif "libgif-6.dll" "giflib5.dll" "gif.dll")
 266          '(gif "libgif-5.dll" "giflib4.dll" "libungif4.dll" "libungif.dll")))
 267        '(svg "librsvg-2-2.dll")
 268        '(gdk-pixbuf "libgdk_pixbuf-2.0-0.dll")
 269        '(glib "libglib-2.0-0.dll")
 270        '(gobject "libgobject-2.0-0.dll")
 271        (if (>= libgnutls-version 30400)
 272            '(gnutls "libgnutls-30.dll")
 273          '(gnutls "libgnutls-28.dll" "libgnutls-26.dll"))
 274        '(libxml2 "libxml2-2.dll" "libxml2.dll")
 275        '(zlib "zlib1.dll" "libz-1.dll")))
 276
 277 ;;; multi-tty support
 278 (defvar w32-initialized nil
 279   "Non-nil if the w32 window system has been initialized.")
 280
 281 (declare-function x-open-connection "w32fns.c"
 282                   (display &optional xrm-string must-succeed))
 283 (declare-function create-default-fontset "fontset" ())
 284 (declare-function create-fontset-from-fontset-spec "fontset"
 285                   (fontset-spec &optional style-variant noerror))
 286 (declare-function create-fontset-from-x-resource "fontset" ())
 287 (declare-function x-get-resource "frame.c"
 288                   (attribute class &optional component subclass))
 289 (declare-function x-handle-args "common-win" (args))
 290 (declare-function x-parse-geometry "frame.c" (string))
 291 (defvar x-command-line-resources)
 292
 293 (defun w32-initialize-window-system (&optional _display)
 294   "Initialize Emacs for W32 GUI frames."
 295   (cl-assert (not w32-initialized))
 296
 297   ;; Do the actual Windows setup here; the above code just defines
 298   ;; functions and variables that we use now.
 299
 300   (setq command-line-args (x-handle-args command-line-args))
 301
 302   ;; Make sure we have a valid resource name.
 303   (or (stringp x-resource-name)
 304       (setq x-resource-name
 305             ;; Change any . or * characters in x-resource-name to hyphens,
 306             ;; so as not to choke when we use it in X resource queries.
 307             (replace-regexp-in-string "[.*]" "-" (invocation-name))))
 308
 309   (x-open-connection "w32" x-command-line-resources
 310                      ;; Exit with a fatal error if this fails and we
 311                      ;; are the initial display
 312                      (eq initial-window-system 'w32))
 313
 314   ;; Create the default fontset.
 315   (create-default-fontset)
 316   ;; Create the standard fontset.
 317   (condition-case err
 318       (create-fontset-from-fontset-spec w32-standard-fontset-spec t)
 319     (error (display-warning
 320             'initialization
 321             (format "Creation of the standard fontset failed: %s" err)
 322             :error)))
 323   ;; Create fontset specified in X resources "Fontset-N" (N is 0, 1,...).
 324   (create-fontset-from-x-resource)
 325
 326   ;; Apply a geometry resource to the initial frame.  Put it at the end
 327   ;; of the alist, so that anything specified on the command line takes
 328   ;; precedence.
 329   (let* ((res-geometry (x-get-resource "geometry" "Geometry"))
 330          parsed)
 331     (if res-geometry
 332         (progn
 333           (setq parsed (x-parse-geometry res-geometry))
 334           ;; If the resource specifies a position,
 335           ;; call the position and size "user-specified".
 336           (if (or (assq 'top parsed) (assq 'left parsed))
 337               (setq parsed (cons '(user-position . t)
 338                                  (cons '(user-size . t) parsed))))
 339           ;; All geometry parms apply to the initial frame.
 340           (setq initial-frame-alist (append initial-frame-alist parsed))
 341           ;; The size parms apply to all frames.
 342           (if (and (assq 'height parsed)
 343                    (not (assq 'height default-frame-alist)))
 344               (setq default-frame-alist
 345                     (cons (cons 'height (cdr (assq 'height parsed)))
 346                           default-frame-alist))
 347           (if (and (assq 'width parsed)
 348                    (not (assq 'width default-frame-alist)))
 349               (setq default-frame-alist
 350                     (cons (cons 'width (cdr (assq 'width parsed)))
 351                           default-frame-alist)))))))
 352
 353   ;; Check the reverseVideo resource.
 354   (let ((case-fold-search t))
 355     (let ((rv (x-get-resource "reverseVideo" "ReverseVideo")))
 356       (if (and rv (string-match "^\\(true\\|yes\\|on\\)$" rv))
 357           (setq default-frame-alist
 358                 (cons '(reverse . t) default-frame-alist)))))
 359
 360   ;; Don't let Emacs suspend under Windows.
 361   (add-hook 'suspend-hook #'w32-win-suspend-error)
 362
 363   ;; Turn off window-splitting optimization; w32 is usually fast enough
 364   ;; that this is only annoying.
 365   (setq split-window-keep-point t)
 366
 367   ;; W32 expects the menu bar cut and paste commands to use the clipboard.
 368   (menu-bar-enable-clipboard)
 369
 370   ;; Don't show the frame name; that's redundant.
 371   (setq-default mode-line-frame-identification "  ")
 372
 373   ;; Set to a system sound if you want a fancy bell.
 374   (set-message-beep 'ok)
 375   (x-apply-session-resources)
 376   (setq w32-initialized t))
 377
 378 (add-to-list 'display-format-alist '("\\`w32\\'" . w32))
 379 (gui-method-define handle-args-function w32 #'x-handle-args)
 380 (gui-method-define frame-creation-function w32
 381                    #'x-create-frame-with-faces)
 382 (gui-method-define window-system-initialization w32
 383                    #'w32-initialize-window-system)
 384
 385 ;;;; Selections
 386
 387 (declare-function w32-set-clipboard-data "w32select.c"
 388                   (string &optional ignored))
 389 (declare-function w32-get-clipboard-data "w32select.c")
 390 (declare-function w32-selection-exists-p "w32select.c")
 391
 392 ;;; Fix interface to (X-specific) mouse.el
 393 (defun w32--set-selection (type value)
 394   (if (eq type 'CLIPBOARD)
 395       (w32-set-clipboard-data value)
 396     (put 'x-selections (or type 'PRIMARY) value)))
 397
 398 (defun w32--get-selection  (&optional type data-type)
 399   (if (and (eq type 'CLIPBOARD)
 400            (eq data-type 'STRING))
 401       (with-demoted-errors "w32-get-clipboard-data:%S"
 402         (w32-get-clipboard-data))
 403     (get 'x-selections (or type 'PRIMARY))))
 404
 405 (defun w32--selection-owner-p (selection)
 406   (and (memq selection '(nil PRIMARY SECONDARY))
 407        (get 'x-selections (or selection 'PRIMARY))))
 408
 409 (gui-method-define gui-set-selection w32 #'w32--set-selection)
 410 (gui-method-define gui-get-selection w32 #'w32--get-selection)
 411
 412 (gui-method-define gui-selection-owner-p w32 #'w32--selection-owner-p)
 413 (gui-method-define gui-selection-exists-p w32 #'w32-selection-exists-p)
 414
 415 (when (eq system-type 'windows-nt)
 416   ;; Make copy&pasting in w32's console interact with the system's clipboard!
 417   (gui-method-define gui-set-selection nil #'w32--set-selection)
 418   (gui-method-define gui-get-selection nil #'w32--get-selection)
 419   (gui-method-define gui-selection-owner-p nil #'w32--selection-owner-p)
 420   (gui-method-define gui-selection-exists-p nil #'w32-selection-exists-p))
 421
 422 ;; The "Windows" keys on newer keyboards bring up the Start menu
 423 ;; whether you want it or not - make Emacs ignore these keystrokes
 424 ;; rather than beep.
 425 (global-set-key [lwindow] 'ignore)
 426 (global-set-key [rwindow] 'ignore)
 427
 428 (declare-function x-server-version "w32fns.c" (&optional terminal))
 429
 430 (defun w32-version ()
 431   "Return the MS-Windows version numbers.
 432 The value is a list of three integers: the major and minor version
 433 numbers, and the build number."
 434   (x-server-version))
 435
 436 (defun w32-using-nt ()
 437   "Return non-nil if running on a Windows NT descendant.
 438 That includes all Windows systems except for 9X/Me."
 439   (getenv "SystemRoot"))
 440
 441 (provide 'w32-win)
 442
 443 ;;; w32-win.el ends here