lisp/faces.el

   1 ;;; faces.el --- Lisp faces
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile
  28   (require 'cl)
  29   ;; Warning suppression -- can't require x-win in batch:
  30   (autoload 'xw-defined-colors "x-win"))
  31
  32 (require 'cus-face)
  33
  34 \f
  35 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  36 ;;; Font selection.
  37 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  38
  39 (defgroup font-selection nil
  40   "Influencing face font selection."
  41   :group 'faces)
  42
  43
  44 (defcustom face-font-selection-order
  45   '(:width :height :weight :slant)
  46   "*A list specifying how face font selection chooses fonts.
  47 Each of the four symbols `:width', `:height', `:weight', and `:slant'
  48 must appear once in the list, and the list must not contain any other
  49 elements.  Font selection tries to find a best matching font for
  50 those face attributes first that appear first in the list.  For
  51 example, if `:slant' appears before `:height', font selection first
  52 tries to find a font with a suitable slant, even if this results in
  53 a font height that isn't optimal."
  54   :tag "Font selection order."
  55   :type '(list symbol symbol symbol symbol)
  56   :group 'font-selection
  57   :set #'(lambda (symbol value)
  58            (set-default symbol value)
  59            (internal-set-font-selection-order value)))
  60
  61
  62 ;; This is defined originally in xfaces.c.
  63 (defcustom face-font-family-alternatives
  64   '(("courier" "fixed")
  65     ("helv" "helvetica" "arial" "fixed"))
  66   "*Alist of alternative font family names.
  67 Each element has the the form (FAMILY ALTERNATIVE1 ALTERNATIVE2 ...).
  68 If fonts of family FAMILY can't be loaded, try ALTERNATIVE1, then
  69 ALTERNATIVE2 etc."
  70   :tag "Alternative font families to try."
  71   :type '(repeat (repeat string))
  72   :group 'font-selection
  73   :set #'(lambda (symbol value)
  74            (set-default symbol value)
  75            (internal-set-alternative-font-family-alist value)))
  76
  77
  78 ;; This is defined originally in xfaces.c.
  79 (defcustom face-font-registry-alternatives
  80   '(("gb2312.1980" "gb2312.80&gb8565.88" "gbk*")
  81     ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  82     ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  83     ("muletibetan-2" "muletibetan-0"))
  84   "*Alist of alternative font registry names.
  85 Each element has the the form (REGISTRY ALTERNATIVE1 ALTERNATIVE2 ...).
  86 If fonts of registry REGISTRY can be loaded, font selection
  87 tries to find a best matching font among all fonts of registry
  88 REGISTRY, ALTERNATIVE1, ALTERNATIVE2, and etc."
  89   :tag "Alternative font registries to try."
  90   :type '(repeat (repeat string))
  91   :version "21.1"
  92   :group 'font-selection
  93   :set #'(lambda (symbol value)
  94            (set-default symbol value)
  95            (internal-set-alternative-font-registry-alist value)))
  96
  97
  98 \f
  99 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 100 ;;; Creation, copying.
 101 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 102
 103
 104 (defun face-list ()
 105   "Return a list of all defined face names."
 106   (mapcar #'car face-new-frame-defaults))
 107
 108
 109 ;;; ### If not frame-local initialize by what X resources?
 110
 111 (defun make-face (face &optional no-init-from-resources)
 112   "Define a new face with name FACE, a symbol.
 113 NO-INIT-FROM-RESOURCES non-nil means don't initialize frame-local
 114 variants of FACE from X resources.  (X resources recognized are found
 115 in the global variable `face-x-resources'.)  If FACE is already known
 116 as a face, leave it unmodified.  Value is FACE."
 117   (interactive "SMake face: ")
 118   (unless (facep face)
 119     ;; Make frame-local faces (this also makes the global one).
 120     (dolist (frame (frame-list))
 121       (internal-make-lisp-face face frame))
 122     ;; Add the face to the face menu.
 123     (when (fboundp 'facemenu-add-new-face)
 124       (facemenu-add-new-face face))
 125     ;; Define frame-local faces for all frames from X resources.
 126     (unless no-init-from-resources
 127       (make-face-x-resource-internal face)))
 128   face)
 129
 130
 131 (defun make-empty-face (face)
 132   "Define a new, empty face with name FACE.
 133 If the face already exists, it is left unmodified.  Value is FACE."
 134   (interactive "SMake empty face: ")
 135   (make-face face 'no-init-from-resources))
 136
 137
 138 (defun copy-face (old-face new-face &optional frame new-frame)
 139   "Define a face just like OLD-FACE, with name NEW-FACE.
 140
 141 If NEW-FACE already exists as a face, it is modified to be like
 142 OLD-FACE.  If it doesn't already exist, it is created.
 143
 144 If the optional argument FRAME is given as a frame,  NEW-FACE is
 145 changed on FRAME only.
 146 If FRAME is t, the frame-independent default specification for OLD-FACE
 147 is copied to NEW-FACE.
 148 If FRAME is nil, copying is done for the frame-independent defaults
 149 and for each existing frame.
 150
 151 If the optional fourth argument NEW-FRAME is given,
 152 copy the information from face OLD-FACE on frame FRAME
 153 to NEW-FACE on frame NEW-FRAME."
 154   (let ((inhibit-quit t))
 155     (if (null frame)
 156         (progn
 157           (dolist (frame (frame-list))
 158             (copy-face old-face new-face frame))
 159           (copy-face old-face new-face t))
 160       (internal-copy-lisp-face old-face new-face frame new-frame))
 161     new-face))
 162
 163
 164 \f
 165 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 166 ;;; Obsolete functions
 167 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 168
 169 ;; The functions in this section are defined because Lisp packages use
 170 ;; them, despite the prefix `internal-' suggesting that they are
 171 ;; private to the face implementation.
 172
 173 (defun internal-find-face (name &optional frame)
 174   "Retrieve the face named NAME.
 175 Return nil if there is no such face.
 176 If the optional argument FRAME is given, this gets the face NAME for
 177 that frame; otherwise, it uses the selected frame.
 178 If FRAME is the symbol t, then the global, non-frame face is returned.
 179 If NAME is already a face, it is simply returned.
 180
 181 This function is defined for compatibility with Emacs 20.2.  It
 182 should not be used anymore."
 183   (facep name))
 184 (make-obsolete 'internal-find-face 'facep "21.1")
 185
 186
 187 (defun internal-get-face (name &optional frame)
 188   "Retrieve the face named NAME; error if there is none.
 189 If the optional argument FRAME is given, this gets the face NAME for
 190 that frame; otherwise, it uses the selected frame.
 191 If FRAME is the symbol t, then the global, non-frame face is returned.
 192 If NAME is already a face, it is simply returned.
 193
 194 This function is defined for compatibility with Emacs 20.2.  It
 195 should not be used anymore."
 196   (or (internal-find-face name frame)
 197       (check-face name)))
 198 (make-obsolete 'internal-get-face "See `facep' and `check-face'." "21.1")
 199
 200 \f
 201 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 202 ;;; Predicates, type checks.
 203 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 204
 205 (defun facep (face)
 206   "Return non-nil if FACE is a face name."
 207   (internal-lisp-face-p face))
 208
 209
 210 (defun check-face (face)
 211   "Signal an error if FACE doesn't name a face.
 212 Value is FACE."
 213   (unless (facep face)
 214     (error "Not a face: %s" face))
 215   face)
 216
 217
 218 ;; The ID returned is not to be confused with the internally used IDs
 219 ;; of realized faces.  The ID assigned to Lisp faces is used to
 220 ;; support faces in display table entries.
 221
 222 (defun face-id (face &optional frame)
 223   "Return the interNal ID of face with name FACE.
 224 If optional argument FRAME is nil or omitted, use the selected frame."
 225   (check-face face)
 226   (get face 'face))
 227
 228
 229 (defun face-equal (face1 face2 &optional frame)
 230   "Non-nil if faces FACE1 and FACE2 are equal.
 231 Faces are considered equal if all their attributes are equal.
 232 If the optional argument FRAME is given, report on face FACE in that frame.
 233 If FRAME is t, report on the defaults for face FACE (for new frames).
 234 If FRAME is omitted or nil, use the selected frame."
 235   (internal-lisp-face-equal-p face1 face2 frame))
 236
 237
 238 (defun face-differs-from-default-p (face &optional frame)
 239   "Non-nil if FACE displays differently from the default face.
 240 If the optional argument FRAME is given, report on face FACE in that frame.
 241 If FRAME is t, report on the defaults for face FACE (for new frames).
 242 If FRAME is omitted or nil, use the selected frame.
 243 A face is considered to be ``the same'' as the default face if it is
 244 actually specified in the same way (equal attributes) or if it is
 245 fully-unspecified, and thus inherits the attributes of any face it
 246 is displayed on top of."
 247   (cond ((eq frame t) (setq frame nil))
 248         ((null frame) (setq frame (selected-frame))))
 249   (let* ((v1 (internal-lisp-face-p face frame))
 250          (n (if v1 (length v1) 0))
 251          (v2 (internal-lisp-face-p 'default frame))
 252          (i 1))
 253     (unless v1
 254       (error "Not a face: %S" face))
 255     (while (and (< i n)
 256                 (or (eq 'unspecified (aref v1 i))
 257                     (equal (aref v1 i) (aref v2 i))))
 258       (setq i (1+ i)))
 259     (< i n)))
 260
 261
 262 (defun face-nontrivial-p (face &optional frame)
 263   "True if face FACE has some non-nil attribute.
 264 If the optional argument FRAME is given, report on face FACE in that frame.
 265 If FRAME is t, report on the defaults for face FACE (for new frames).
 266 If FRAME is omitted or nil, use the selected frame."
 267   (not (internal-lisp-face-empty-p face frame)))
 268
 269
 270 \f
 271 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 272 ;;; Setting face attributes from X resources.
 273 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 274
 275 (defcustom face-x-resources
 276   '((:family (".attributeFamily" . "Face.AttributeFamily"))
 277     (:width (".attributeWidth" . "Face.AttributeWidth"))
 278     (:height (".attributeHeight" . "Face.AttributeHeight"))
 279     (:weight (".attributeWeight" . "Face.AttributeWeight"))
 280     (:slant (".attributeSlant" . "Face.AttributeSlant"))
 281     (:foreground (".attributeForeground" . "Face.AttributeForeground"))
 282     (:background (".attributeBackground" . "Face.AttributeBackground"))
 283     (:overline (".attributeOverline" . "Face.AttributeOverline"))
 284     (:strike-through (".attributeStrikeThrough" . "Face.AttributeStrikeThrough"))
 285     (:box (".attributeBox" . "Face.AttributeBox"))
 286     (:underline (".attributeUnderline" . "Face.AttributeUnderline"))
 287     (:inverse-video (".attributeInverse" . "Face.AttributeInverse"))
 288     (:stipple
 289      (".attributeStipple" . "Face.AttributeStipple")
 290      (".attributeBackgroundPixmap" . "Face.AttributeBackgroundPixmap"))
 291     (:bold (".attributeBold" . "Face.AttributeBold"))
 292     (:italic (".attributeItalic" . "Face.AttributeItalic"))
 293     (:font (".attributeFont" . "Face.AttributeFont"))
 294     (:inherit (".attributeInherit" . "Face.AttributeInherit")))
 295   "*List of X resources and classes for face attributes.
 296 Each element has the form (ATTRIBUTE ENTRY1 ENTRY2...) where ATTRIBUTE is
 297 the name of a face attribute, and each ENTRY is a cons of the form
 298 (RESOURCE . CLASS) with RESOURCE being the resource and CLASS being the
 299 X resource class for the attribute."
 300   :type '(repeat (cons symbol (repeat (cons string string))))
 301   :group 'faces)
 302
 303
 304 (defun set-face-attribute-from-resource (face attribute resource class frame)
 305   "Set FACE's ATTRIBUTE from X resource RESOURCE, class CLASS on FRAME.
 306 Value is the attribute value specified by the resource, or nil
 307 if not present.  This function displays a message if the resource
 308 specifies an invalid attribute."
 309   (let* ((face-name (face-name face))
 310          (value (internal-face-x-get-resource (concat face-name resource)
 311                                               class frame)))
 312     (when value
 313       (condition-case ()
 314           (internal-set-lisp-face-attribute-from-resource
 315            face attribute (downcase value) frame)
 316         (error
 317          (message "Face %s, frame %s: invalid attribute %s %s from X resource"
 318                   face-name frame attribute value))))
 319     value))
 320
 321
 322 (defun set-face-attributes-from-resources (face frame)
 323   "Set attributes of FACE from X resources for FRAME."
 324   (when (memq (framep frame) '(x w32 mac))
 325     (dolist (definition face-x-resources)
 326       (let ((attribute (car definition)))
 327         (dolist (entry (cdr definition))
 328           (set-face-attribute-from-resource face attribute (car entry)
 329                                             (cdr entry) frame))))))
 330
 331
 332 (defun make-face-x-resource-internal (face &optional frame)
 333   "Fill frame-local FACE on FRAME from X resources.
 334 FRAME nil or not specified means do it for all frames."
 335   (if (null frame)
 336       (dolist (frame (frame-list))
 337         (set-face-attributes-from-resources face frame))
 338     (set-face-attributes-from-resources face frame)))
 339
 340
 341 \f
 342 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 343 ;;; Retrieving face attributes.
 344 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 345
 346 (defun face-name (face)
 347   "Return the name of face FACE."
 348   (symbol-name (check-face face)))
 349
 350
 351 (defun face-attribute (face attribute &optional frame)
 352   "Return the value of FACE's ATTRIBUTE on FRAME.
 353 If the optional argument FRAME is given, report on face FACE in that frame.
 354 If FRAME is t, report on the defaults for face FACE (for new frames).
 355 If FRAME is omitted or nil, use the selected frame."
 356   (internal-get-lisp-face-attribute face attribute frame))
 357
 358
 359 (defun face-foreground (face &optional frame)
 360   "Return the foreground color name of FACE, or nil if unspecified.
 361 If the optional argument FRAME is given, report on face FACE in that frame.
 362 If FRAME is t, report on the defaults for face FACE (for new frames).
 363 If FRAME is omitted or nil, use the selected frame."
 364   (let ((value (internal-get-lisp-face-attribute face :foreground frame)))
 365     (if (eq value 'unspecified)
 366         nil
 367       value)))
 368
 369
 370 (defun face-background (face &optional frame)
 371   "Return the background color name of FACE, or nil if unspecified.
 372 If the optional argument FRAME is given, report on face FACE in that frame.
 373 If FRAME is t, report on the defaults for face FACE (for new frames).
 374 If FRAME is omitted or nil, use the selected frame."
 375   (let ((value (internal-get-lisp-face-attribute face :background frame)))
 376     (if (eq value 'unspecified)
 377         nil
 378       value)))
 379
 380
 381 (defun face-stipple (face &optional frame)
 382  "Return the stipple pixmap name of FACE, or nil if unspecified.
 383 If the optional argument FRAME is given, report on face FACE in that frame.
 384 If FRAME is t, report on the defaults for face FACE (for new frames).
 385 If FRAME is omitted or nil, use the selected frame."
 386   (let ((value (internal-get-lisp-face-attribute face :stipple frame)))
 387     (if (eq value 'unspecified)
 388         nil
 389       value)))
 390
 391
 392 (defalias 'face-background-pixmap 'face-stipple)
 393
 394
 395 (defun face-underline-p (face &optional frame)
 396  "Return non-nil if FACE is underlined.
 397 If the optional argument FRAME is given, report on face FACE in that frame.
 398 If FRAME is t, report on the defaults for face FACE (for new frames).
 399 If FRAME is omitted or nil, use the selected frame."
 400  (eq (face-attribute face :underline frame) t))
 401
 402
 403 (defun face-inverse-video-p (face &optional frame)
 404  "Return non-nil if FACE is in inverse video on FRAME.
 405 If the optional argument FRAME is given, report on face FACE in that frame.
 406 If FRAME is t, report on the defaults for face FACE (for new frames).
 407 If FRAME is omitted or nil, use the selected frame."
 408  (eq (face-attribute face :inverse-video frame) t))
 409
 410
 411 (defun face-bold-p (face &optional frame)
 412   "Return non-nil if the font of FACE is bold on FRAME.
 413 If the optional argument FRAME is given, report on face FACE in that frame.
 414 If FRAME is t, report on the defaults for face FACE (for new frames).
 415 If FRAME is omitted or nil, use the selected frame.
 416 Use `face-attribute' for finer control."
 417   (let ((bold (face-attribute face :weight frame)))
 418     (memq bold '(semi-bold bold extra-bold ultra-bold))))
 419
 420
 421 (defun face-italic-p (face &optional frame)
 422   "Return non-nil if the font of FACE is italic on FRAME.
 423 If the optional argument FRAME is given, report on face FACE in that frame.
 424 If FRAME is t, report on the defaults for face FACE (for new frames).
 425 If FRAME is omitted or nil, use the selected frame.
 426 Use `face-attribute' for finer control."
 427   (let ((italic (face-attribute face :slant frame)))
 428     (memq italic '(italic oblique))))
 429
 430
 431 \f
 432 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 433 ;;; Face documentation.
 434 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 435
 436 (defun face-documentation (face)
 437   "Get the documentation string for FACE."
 438   (get face 'face-documentation))
 439
 440
 441 (defun set-face-documentation (face string)
 442   "Set the documentation string for FACE to STRING."
 443   ;; Perhaps the text should go in DOC.
 444   (put face 'face-documentation (purecopy string)))
 445
 446
 447 (defalias 'face-doc-string 'face-documentation)
 448 (defalias 'set-face-doc-string 'set-face-documentation)
 449
 450
 451 \f
 452 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 453 ;; Setting face attributes.
 454 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 455
 456
 457 (defun set-face-attribute (face frame &rest args)
 458   "Set attributes of FACE on FRAME from ARGS.
 459
 460 FRAME nil means change attributes on all frames.  FRAME t means change
 461 the default for new frames (this is done automatically each time an
 462 attribute is changed on all frames).
 463
 464 ARGS must come in pairs ATTRIBUTE VALUE.  ATTRIBUTE must be a valid
 465 face attribute name.  All attributes can be set to `unspecified';
 466 this fact is not further mentioned below.
 467
 468 The following attributes are recognized:
 469
 470 `:family'
 471
 472 VALUE must be a string specifying the font family, e.g. ``courier'',
 473 or a fontset alias name.  If a font family is specified, wild-cards `*'
 474 and `?' are allowed.
 475
 476 `:width'
 477
 478 VALUE specifies the relative proportionate width of the font to use.
 479 It must be one of the symbols `ultra-condensed', `extra-condensed',
 480 `condensed', `semi-condensed', `normal', `semi-expanded', `expanded',
 481 `extra-expanded', or `ultra-expanded'.
 482
 483 `:height'
 484
 485 VALUE must be either an integer specifying the height of the font to use
 486 in 1/10 pt, a floating point number specifying the amount by which to
 487 scale any underlying face, or a function, which is called with the old
 488 height (from the underlying face), and should return the new height.
 489
 490 `:weight'
 491
 492 VALUE specifies the weight of the font to use.  It must be one of the
 493 symbols `ultra-bold', `extra-bold', `bold', `semi-bold', `normal',
 494 `semi-light', `light', `extra-light', `ultra-light'.
 495
 496 `:slant'
 497
 498 VALUE specifies the slant of the font to use.  It must be one of the
 499 symbols `italic', `oblique', `normal', `reverse-italic', or
 500 `reverse-oblique'.
 501
 502 `:foreground', `:background'
 503
 504 VALUE must be a color name, a string.
 505
 506 `:underline'
 507
 508 VALUE specifies whether characters in FACE should be underlined.  If
 509 VALUE is t, underline with foreground color of the face.  If VALUE is
 510 a string, underline with that color.  If VALUE is nil, explicitly
 511 don't underline.
 512
 513 `:overline'
 514
 515 VALUE specifies whether characters in FACE should be overlined.  If
 516 VALUE is t, overline with foreground color of the face.  If VALUE is a
 517 string, overline with that color.  If VALUE is nil, explicitly don't
 518 overline.
 519
 520 `:strike-through'
 521
 522 VALUE specifies whether characters in FACE should be drawn with a line
 523 striking through them.  If VALUE is t, use the foreground color of the
 524 face.  If VALUE is a string, strike-through with that color.  If VALUE
 525 is nil, explicitly don't strike through.
 526
 527 `:box'
 528
 529 VALUE specifies whether characters in FACE should have a box drawn
 530 around them.  If VALUE is nil, explicitly don't draw boxes.  If
 531 VALUE is t, draw a box with lines of width 1 in the foreground color
 532 of the face.  If VALUE is a string, the string must be a color name,
 533 and the box is drawn in that color with a line width of 1.  Otherwise,
 534 VALUE must be a property list of the form `(:line-width WIDTH
 535 :color COLOR :style STYLE)'.  If a keyword/value pair is missing from
 536 the property list, a default value will be used for the value, as
 537 specified below.  WIDTH specifies the width of the lines to draw; it
 538 defaults to 1.  COLOR is the name of the color to draw in, default is
 539 the foreground color of the face for simple boxes, and the background
 540 color of the face for 3D boxes.  STYLE specifies whether a 3D box
 541 should be draw.  If STYLE is `released-button', draw a box looking
 542 like a released 3D button.  If STYLE is `pressed-button' draw a box
 543 that appears like a pressed button.  If STYLE is nil, the default if
 544 the property list doesn't contain a style specification, draw a 2D
 545 box.
 546
 547 `:inverse-video'
 548
 549 VALUE specifies whether characters in FACE should be displayed in
 550 inverse video.  VALUE must be one of t or nil.
 551
 552 `:stipple'
 553
 554 If VALUE is a string, it must be the name of a file of pixmap data.
 555 The directories listed in the `x-bitmap-file-path' variable are
 556 searched.  Alternatively, VALUE may be a list of the form (WIDTH
 557 HEIGHT DATA) where WIDTH and HEIGHT are the size in pixels, and DATA
 558 is a string containing the raw bits of the bitmap.  VALUE nil means
 559 explicitly don't use a stipple pattern.
 560
 561 For convenience, attributes `:family', `:width', `:height', `:weight',
 562 and `:slant' may also be set in one step from an X font name:
 563
 564 `:font'
 565
 566 Set font-related face attributes from VALUE.  VALUE must be a valid
 567 XLFD font name.  If it is a font name pattern, the first matching font
 568 will be used.
 569
 570 For compatibility with Emacs 20, keywords `:bold' and `:italic' can
 571 be used to specify that a bold or italic font should be used.  VALUE
 572 must be t or nil in that case.  A value of `unspecified' is not allowed.
 573
 574 `:inherit'
 575
 576 VALUE is the name of a face from which to inherit attributes, or a list
 577 of face names.  Attributes from inherited faces are merged into the face
 578 like an underlying face would be, with higher priority than underlying faces."
 579   (let ((where (if (null frame) 0 frame)))
 580     (setq args (purecopy args))
 581     (while args
 582       (internal-set-lisp-face-attribute face (car args)
 583                                         (purecopy (cadr args))
 584                                         where)
 585       (setq args (cdr (cdr args))))))
 586
 587
 588 (defun make-face-bold (face &optional frame noerror)
 589   "Make the font of FACE be bold, if possible.
 590 FRAME nil or not specified means change face on all frames.
 591 Argument NOERROR is ignored and retained for compatibility.
 592 Use `set-face-attribute' for finer control of the font weight."
 593   (interactive (list (read-face-name "Make which face bold ")))
 594   (set-face-attribute face frame :weight 'bold))
 595
 596
 597 (defun make-face-unbold (face &optional frame noerror)
 598   "Make the font of FACE be non-bold, if possible.
 599 FRAME nil or not specified means change face on all frames.
 600 Argument NOERROR is ignored and retained for compatibility."
 601   (interactive (list (read-face-name "Make which face non-bold ")))
 602   (set-face-attribute face frame :weight 'normal))
 603
 604
 605 (defun make-face-italic (face &optional frame noerror)
 606   "Make the font of FACE be italic, if possible.
 607 FRAME nil or not specified means change face on all frames.
 608 Argument NOERROR is ignored and retained for compatibility.
 609 Use `set-face-attribute' for finer control of the font slant."
 610   (interactive (list (read-face-name "Make which face italic ")))
 611   (set-face-attribute face frame :slant 'italic))
 612
 613
 614 (defun make-face-unitalic (face &optional frame noerror)
 615   "Make the font of FACE be non-italic, if possible.
 616 FRAME nil or not specified means change face on all frames.
 617 Argument NOERROR is ignored and retained for compatibility."
 618   (interactive (list (read-face-name "Make which face non-italic ")))
 619   (set-face-attribute face frame :slant 'normal))
 620
 621
 622 (defun make-face-bold-italic (face &optional frame noerror)
 623   "Make the font of FACE be bold and italic, if possible.
 624 FRAME nil or not specified means change face on all frames.
 625 Argument NOERROR is ignored and retained for compatibility.
 626 Use `set-face-attribute' for finer control of font weight and slant."
 627   (interactive (list (read-face-name "Make which face bold-italic: ")))
 628   (set-face-attribute face frame :weight 'bold :slant 'italic))
 629
 630
 631 (defun set-face-font (face font &optional frame)
 632   "Change font-related attributes of FACE to those of FONT (a string).
 633 FRAME nil or not specified means change face on all frames.
 634 This sets the attributes `:family', `:width', `:height', `:weight',
 635 and `:slant'.  When called interactively, prompt for the face and font."
 636   (interactive (read-face-and-attribute :font))
 637   (set-face-attribute face frame :font font))
 638
 639
 640 ;; Implementation note: Emulating gray background colors with a
 641 ;; stipple pattern is now part of the face realization process, and is
 642 ;; done in C depending on the frame on which the face is realized.
 643
 644 (defun set-face-background (face color &optional frame)
 645   "Change the background color of face FACE to COLOR (a string).
 646 FRAME nil or not specified means change face on all frames.
 647 When called interactively, prompt for the face and color."
 648   (interactive (read-face-and-attribute :background))
 649   (set-face-attribute face frame :background color))
 650
 651
 652 (defun set-face-foreground (face color &optional frame)
 653   "Change the foreground color of face FACE to COLOR (a string).
 654 FRAME nil or not specified means change face on all frames.
 655 When called interactively, prompt for the face and color."
 656   (interactive (read-face-and-attribute :foreground))
 657   (set-face-attribute face frame :foreground color))
 658
 659
 660 (defun set-face-stipple (face stipple &optional frame)
 661   "Change the stipple pixmap of face FACE to STIPPLE.
 662 FRAME nil or not specified means change face on all frames.
 663 STIPPLE should be a string, the name of a file of pixmap data.
 664 The directories listed in the `x-bitmap-file-path' variable are searched.
 665
 666 Alternatively, STIPPLE may be a list of the form (WIDTH HEIGHT DATA)
 667 where WIDTH and HEIGHT are the size in pixels,
 668 and DATA is a string, containing the raw bits of the bitmap."
 669   (interactive (read-face-and-attribute :stipple))
 670   (set-face-attribute face frame :stipple stipple))
 671
 672
 673 (defun set-face-underline (face underline &optional frame)
 674   "Specify whether face FACE is underlined.
 675 UNDERLINE nil means FACE explicitly doesn't underline.
 676 UNDERLINE non-nil means FACE explicitly does underlining
 677 with the same of the foreground color.
 678 If UNDERLINE is a string, underline with the color named UNDERLINE.
 679 FRAME nil or not specified means change face on all frames.
 680 Use `set-face-attribute' to ``unspecify'' underlining."
 681   (interactive
 682    (let ((list (read-face-and-attribute :underline)))
 683      (list (car list) (eq (car (cdr list)) t))))
 684   (set-face-attribute face frame :underline underline))
 685
 686
 687 (defun set-face-underline-p (face underline-p &optional frame)
 688   "Specify whether face FACE is underlined.
 689 UNDERLINE-P nil means FACE explicitly doesn't underline.
 690 UNDERLINE-P non-nil means FACE explicitly does underlining.
 691 FRAME nil or not specified means change face on all frames.
 692 Use `set-face-attribute' to ``unspecify'' underlining."
 693   (interactive
 694    (let ((list (read-face-and-attribute :underline)))
 695      (list (car list) (eq (car (cdr list)) t))))
 696   (set-face-attribute face frame :underline underline-p))
 697
 698
 699 (defun set-face-inverse-video-p (face inverse-video-p &optional frame)
 700   "Specify whether face FACE is in inverse video.
 701 INVERSE-VIDEO-P non-nil means FACE displays explicitly in inverse video.
 702 INVERSE-VIDEO-P nil means FACE explicitly is not in inverse video.
 703 FRAME nil or not specified means change face on all frames.
 704 Use `set-face-attribute' to ``unspecify'' the inverse video attribute."
 705   (interactive
 706    (let ((list (read-face-and-attribute :inverse-video)))
 707      (list (car list) (eq (car (cdr list)) t))))
 708   (set-face-attribute face frame :inverse-video inverse-video-p))
 709
 710
 711 (defun set-face-bold-p (face bold-p &optional frame)
 712   "Specify whether face FACE is bold.
 713 BOLD-P non-nil means FACE should explicitly display bold.
 714 BOLD-P nil means FACE should explicitly display non-bold.
 715 FRAME nil or not specified means change face on all frames.
 716 Use `set-face-attribute' or `modify-face' for finer control."
 717   (if (null bold-p)
 718       (make-face-unbold face frame)
 719     (make-face-bold face frame)))
 720
 721
 722 (defun set-face-italic-p (face italic-p &optional frame)
 723   "Specify whether face FACE is italic.
 724 ITALIC-P non-nil means FACE should explicitly display italic.
 725 ITALIC-P nil means FACE should explicitly display non-italic.
 726 FRAME nil or not specified means change face on all frames.
 727 Use `set-face-attribute' or `modify-face' for finer control."
 728   (if (null italic-p)
 729       (make-face-unitalic face frame)
 730     (make-face-italic face frame)))
 731
 732
 733 (defalias 'set-face-background-pixmap 'set-face-stipple)
 734
 735
 736 (defun invert-face (face &optional frame)
 737   "Swap the foreground and background colors of FACE.
 738 FRAME nil or not specified means change face on all frames.
 739 If FACE specifies neither foreground nor background color,
 740 set its foreground and background to the background and foreground
 741 of the default face.  Value is FACE."
 742   (interactive (list (read-face-name "Invert face ")))
 743   (let ((fg (face-attribute face :foreground frame))
 744         (bg (face-attribute face :background frame)))
 745     (if (or fg bg)
 746         (set-face-attribute face frame :foreground bg :background fg)
 747       (set-face-attribute face frame
 748                           :foreground
 749                           (face-attribute 'default :background frame)
 750                           :background
 751                           (face-attribute 'default :foreground frame))))
 752   face)
 753
 754 \f
 755 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 756 ;;; Interactively modifying faces.
 757 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 758
 759 (defun read-face-name (prompt)
 760   "Read and return a face symbol, prompting with PROMPT.
 761 Value is a symbol naming a known face."
 762   (let ((face-list (mapcar #'(lambda (x) (cons (symbol-name x) x))
 763                            (face-list)))
 764         (def (thing-at-point 'symbol))
 765         face)
 766     (cond ((assoc def face-list)
 767            (setq prompt (concat prompt " (default " def "): ")))
 768           (t (setq def nil)
 769              (setq prompt (concat prompt ": "))))
 770     (while (equal "" (setq face (completing-read
 771                                  prompt face-list nil t nil nil def))))
 772     (intern face)))
 773
 774
 775 (defun face-valid-attribute-values (attribute &optional frame)
 776   "Return valid values for face attribute ATTRIBUTE.
 777 The optional argument FRAME is used to determine available fonts
 778 and colors.  If it is nil or not specified, the selected frame is
 779 used.  Value is an alist of (NAME . VALUE) if ATTRIBUTE expects a value
 780 out of a set of discrete values.  Value is `integerp' if ATTRIBUTE expects
 781 an integer value."
 782   (let (valid)
 783     (setq valid
 784           (case attribute
 785             (:family
 786              (if window-system
 787                  (mapcar #'(lambda (x) (cons (car x) (car x)))
 788                          (x-font-family-list))
 789                ;; Only one font on TTYs.
 790                (list (cons "default" "default"))))
 791             ((:width :weight :slant :inverse-video)
 792              (mapcar #'(lambda (x) (cons (symbol-name x) x))
 793                      (internal-lisp-face-attribute-values attribute)))
 794             ((:underline :overline :strike-through :box)
 795              (if window-system
 796                  (nconc (mapcar #'(lambda (x) (cons (symbol-name x) x))
 797                                 (internal-lisp-face-attribute-values attribute))
 798                         (mapcar #'(lambda (c) (cons c c))
 799                                 (x-defined-colors frame)))
 800                (mapcar #'(lambda (x) (cons (symbol-name x) x))
 801                        (internal-lisp-face-attribute-values attribute))))
 802             ((:foreground :background)
 803              (mapcar #'(lambda (c) (cons c c))
 804                      (defined-colors frame)))
 805             ((:height)
 806              'integerp)
 807             (:stipple
 808              (and (memq window-system '(x w32 mac))
 809                   (mapcar #'list
 810                           (apply #'nconc
 811                                  (mapcar (lambda (dir)
 812                                            (and (file-readable-p dir)
 813                                                 (file-directory-p dir)
 814                                                 (directory-files dir)))
 815                                          x-bitmap-file-path)))))
 816             (:inherit
 817              (cons '("none" . nil)
 818                    (mapcar #'(lambda (c) (cons (symbol-name c) c))
 819                            (face-list))))
 820             (t
 821              (error "Internal error"))))
 822     (if (and (listp valid) (not (memq attribute '(:inherit))))
 823         (nconc (list (cons "unspecified" 'unspecified)) valid)
 824       valid)))
 825
 826
 827
 828 (defvar face-attribute-name-alist
 829   '((:family . "font family")
 830     (:width . "character set width")
 831     (:height . "height in 1/10 pt")
 832     (:weight . "weight")
 833     (:slant . "slant")
 834     (:underline . "underline")
 835     (:overline . "overline")
 836     (:strike-through . "strike-through")
 837     (:box . "box")
 838     (:inverse-video . "inverse-video display")
 839     (:foreground . "foreground color")
 840     (:background . "background color")
 841     (:stipple . "background stipple")
 842     (:inherit . "inheritance"))
 843   "An alist of descriptive names for face attributes.
 844 Each element has the form (ATTRIBUTE-NAME . DESCRIPTION) where
 845 ATTRIBUTE-NAME is a face attribute name (a keyword symbol), and
 846 DESCRIPTION is a descriptive name for ATTRIBUTE-NAME.")
 847
 848
 849 (defun face-descriptive-attribute-name (attribute)
 850   "Return a descriptive name for ATTRIBUTE."
 851   (cdr (assq attribute face-attribute-name-alist)))
 852
 853
 854 (defun face-read-string (face default name &optional completion-alist)
 855   "Interactively read a face attribute string value.
 856 FACE is the face whose attribute is read.  If non-nil, DEFAULT is the
 857 default string to return if no new value is entered.  NAME is a
 858 descriptive name of the attribute for prompting.  COMPLETION-ALIST is an
 859 alist of valid values, if non-nil.
 860
 861 Entering nothing accepts the default string DEFAULT.
 862 Value is the new attribute value."
 863   ;; Capitalize NAME (we don't use `capitalize' because that capitalizes
 864   ;; each word in a string separately).
 865   (setq name (concat (upcase (substring name 0 1)) (substring name 1)))
 866   (let* ((completion-ignore-case t)
 867          (value (completing-read
 868                  (if default
 869                      (format "%s for face `%s' (default %s): "
 870                              name face default)
 871                    (format "%s for face `%s': " name face))
 872                  completion-alist)))
 873     (if (equal value "") default value)))
 874
 875
 876 (defun face-read-integer (face default name)
 877   "Interactively read an integer face attribute value.
 878 FACE is the face whose attribute is read.  DEFAULT is the default
 879 value to return if no new value is entered.  NAME is a descriptive
 880 name of the attribute for prompting.  Value is the new attribute value."
 881   (let ((new-value
 882          (face-read-string face
 883                            (format "%s" default)
 884                            name
 885                            (list (cons "unspecified" 'unspecified)))))
 886     (cond ((equal new-value "unspecified")
 887            'unspecified)
 888           ((member new-value '("unspecified-fg" "unspecified-bg"))
 889            new-value)
 890           (t
 891            (string-to-int new-value)))))
 892
 893
 894 (defun read-face-attribute (face attribute &optional frame)
 895   "Interactively read a new value for FACE's ATTRIBUTE.
 896 Optional argument FRAME nil or unspecified means read an attribute value
 897 of a global face.  Value is the new attribute value."
 898   (let* ((old-value (face-attribute face attribute frame))
 899          (attribute-name (face-descriptive-attribute-name attribute))
 900          (valid (face-valid-attribute-values attribute frame))
 901          new-value)
 902     ;; Represent complex attribute values as strings by printing them
 903     ;; out.  Stipple can be a vector; (WIDTH HEIGHT DATA).  Box can be
 904     ;; a list `(:width WIDTH :color COLOR)' or `(:width WIDTH :shadow
 905     ;; SHADOW)'.
 906     (when (and (or (eq attribute :stipple)
 907                    (eq attribute :box))
 908                (or (consp old-value)
 909                    (vectorp old-value)))
 910       (setq old-value (prin1-to-string old-value)))
 911     (cond ((listp valid)
 912            (let ((default
 913                    (or (car (rassoc old-value valid))
 914                        (format "%s" old-value))))
 915              (setq new-value
 916                    (face-read-string face default attribute-name valid))
 917              (if (equal new-value default)
 918                  ;; Nothing changed, so don't bother with all the stuff
 919                  ;; below.  In particular, this avoids a non-tty color
 920                  ;; from being canonicalized for a tty when the user
 921                  ;; just uses the default.
 922                  (setq new-value old-value)
 923                ;; Terminal frames can support colors that don't appear
 924                ;; explicitly in VALID, using color approximation code
 925                ;; in tty-colors.el.
 926                (when (and (memq attribute '(:foreground :background))
 927                           (not (memq window-system '(x w32 mac)))
 928                           (not (member new-value
 929                                        '("unspecified"
 930                                          "unspecified-fg" "unspecified-bg"))))
 931                  (setq new-value (car (tty-color-desc new-value frame))))
 932                (when (assoc new-value valid)
 933                  (setq new-value (cdr (assoc new-value valid)))))))
 934           ((eq valid 'integerp)
 935            (setq new-value (face-read-integer face old-value attribute-name)))
 936           (t (error "Internal error")))
 937     ;; Convert stipple and box value text we read back to a list or
 938     ;; vector if it looks like one.  This makes the assumption that a
 939     ;; pixmap file name won't start with an open-paren.
 940     (when (and (or (eq attribute :stipple)
 941                    (eq attribute :box))
 942                (stringp new-value)
 943                (string-match "^[[(]" new-value))
 944       (setq new-value (read new-value)))
 945     new-value))
 946
 947
 948 (defun read-face-font (face &optional frame)
 949   "Read the name of a font for FACE on FRAME.
 950 If optional argument FRAME Is nil or omitted, use the selected frame."
 951   (let ((completion-ignore-case t))
 952     (completing-read (format "Set font attributes of face `%s' from font: " face)
 953                      (mapcar 'list (x-list-fonts "*" nil frame)))))
 954
 955
 956 (defun read-all-face-attributes (face &optional frame)
 957   "Interactively read all attributes for FACE.
 958 If optional argument FRAME Is nil or omitted, use the selected frame.
 959 Value is a property list of attribute names and new values."
 960   (let (result)
 961     (dolist (attribute face-attribute-name-alist result)
 962       (setq result (cons (car attribute)
 963                          (cons (read-face-attribute face (car attribute) frame)
 964                                result))))))
 965
 966
 967 (defun modify-face (&optional frame)
 968   "Modify attributes of faces interactively.
 969 If optional argument FRAME is nil or omitted, modify the face used
 970 for newly created frame, i.e. the global face."
 971   (interactive)
 972   (let ((face (read-face-name "Modify face")))
 973     (apply #'set-face-attribute face frame
 974            (read-all-face-attributes face frame))))
 975
 976
 977 (defun read-face-and-attribute (attribute &optional frame)
 978   "Read face name and face attribute value.
 979 ATTRIBUTE is the attribute whose new value is read.
 980 FRAME nil or unspecified means read attribute value of global face.
 981 Value is a list (FACE NEW-VALUE) where FACE is the face read
 982 (a symbol), and NEW-VALUE is value read."
 983   (cond ((eq attribute :font)
 984          (let* ((prompt "Set font-related attributes of face")
 985                 (face (read-face-name prompt))
 986                 (font (read-face-font face frame)))
 987            (list face font)))
 988         (t
 989          (let* ((attribute-name (face-descriptive-attribute-name attribute))
 990                 (prompt (format "Set %s of face" attribute-name))
 991                 (face (read-face-name prompt))
 992                 (new-value (read-face-attribute face attribute frame)))
 993            (list face new-value)))))
 994
 995
 996 \f
 997 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 998 ;;; Listing faces.
 999 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1000
1001 (defvar list-faces-sample-text
1002   "abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ"
1003   "*Text string to display as the sample text for `list-faces-display'.")
1004
1005
1006 ;; The name list-faces would be more consistent, but let's avoid a
1007 ;; conflict with Lucid, which uses that name differently.
1008
1009 (defun list-faces-display ()
1010   "List all faces, using the same sample text in each.
1011 The sample text is a string that comes from the variable
1012 `list-faces-sample-text'."
1013   (interactive)
1014   (let ((faces (sort (face-list) #'string-lessp))
1015         (face nil)
1016         (frame (selected-frame))
1017         disp-frame window face-name)
1018     (with-output-to-temp-buffer "*Faces*"
1019       (save-excursion
1020         (set-buffer standard-output)
1021         (setq truncate-lines t)
1022         (insert
1023          (substitute-command-keys
1024           (concat
1025            "Use "
1026            (if (display-mouse-p) "\\[help-follow-mouse] or ")
1027            "\\[help-follow] on a face name to customize it\n"
1028            "or on its sample text for a decription of the face.\n\n")))
1029         (setq help-xref-stack nil)
1030         (while faces
1031           (setq face (car faces))
1032           (setq faces (cdr faces))
1033           (setq face-name (symbol-name face))
1034           (insert (format "%25s " face-name))
1035           ;; Hyperlink to a customization buffer for the face.  Using
1036           ;; the help xref mechanism may not be the best way.
1037           (save-excursion
1038             (save-match-data
1039               (search-backward face-name)
1040               (help-xref-button 0 (lambda (f)
1041                                     (if help-xref-stack
1042                                         (pop help-xref-stack))
1043                                     (customize-face f))
1044                                 face-name
1045                                 "mouse-2: customize this face")))
1046           (let ((beg (point)))
1047             (insert list-faces-sample-text)
1048             ;; Hyperlink to a help buffer for the face.
1049             (save-excursion
1050               (save-match-data
1051                 (search-backward list-faces-sample-text)
1052                 (help-xref-button 0 #'describe-face face
1053                                   "mouse-2: describe this face")))
1054             (insert "\n")
1055             (put-text-property beg (1- (point)) 'face face)
1056             ;; If the sample text has multiple lines, line up all of them.
1057             (goto-char beg)
1058             (forward-line 1)
1059             (while (not (eobp))
1060               (insert "                          ")
1061               (forward-line 1))))
1062         (goto-char (point-min)))
1063       (print-help-return-message))
1064     ;; If the *Faces* buffer appears in a different frame,
1065     ;; copy all the face definitions from FRAME,
1066     ;; so that the display will reflect the frame that was selected.
1067     (setq window (get-buffer-window (get-buffer "*Faces*") t))
1068     (setq disp-frame (if window (window-frame window)
1069                        (car (frame-list))))
1070     (or (eq frame disp-frame)
1071         (let ((faces (face-list)))
1072           (while faces
1073             (copy-face (car faces) (car faces) frame disp-frame)
1074             (setq faces (cdr faces)))))))
1075
1076
1077 (defun describe-face (face &optional frame)
1078   "Display the properties of face FACE on FRAME.
1079 If the optional argument FRAME is given, report on face FACE in that frame.
1080 If FRAME is t, report on the defaults for face FACE (for new frames).
1081 If FRAME is omitted or nil, use the selected frame."
1082   (interactive (list (read-face-name "Describe face")))
1083   (let* ((attrs '((:family . "Family")
1084                   (:width . "Width")
1085                   (:height . "Height")
1086                   (:weight . "Weight")
1087                   (:slant . "Slant")
1088                   (:foreground . "Foreground")
1089                   (:background . "Background")
1090                   (:underline . "Underline")
1091                   (:overline . "Overline")
1092                   (:strike-through . "Strike-through")
1093                   (:box . "Box")
1094                   (:inverse-video . "Inverse")
1095                   (:stipple . "Stipple")
1096                   (:font . "Font or fontset")
1097                   (:inherit . "Inherit")))
1098         (max-width (apply #'max (mapcar #'(lambda (x) (length (cdr x)))
1099                                         attrs))))
1100     (with-output-to-temp-buffer "*Help*"
1101       (save-excursion
1102         (set-buffer standard-output)
1103         (dolist (a attrs)
1104           (let ((attr (face-attribute face (car a) frame)))
1105             (insert (make-string (- max-width (length (cdr a))) ?\ )
1106                     (cdr a) ": " (format "%s" attr) "\n")))
1107         (insert "\nDocumentation:\n\n"
1108                 (or (face-documentation face)
1109                     "not documented as a face."))
1110         (let ((customize-label "customize"))
1111           (terpri)
1112           (terpri)
1113           (princ (concat "You can " customize-label " this face."))
1114           (with-current-buffer "*Help*"
1115             (save-excursion
1116               (re-search-backward
1117                (concat "\\(" customize-label "\\)") nil t)
1118               (help-xref-button 1 #'customize-face face
1119                                 "mouse-2, RET: customize face")))))
1120       (print-help-return-message)
1121       (with-current-buffer "*Help*"
1122         (help-setup-xref (list #'describe-face face) (interactive-p))
1123         (buffer-string)))))
1124 \f
1125 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1126 ;;; Face specifications (defface).
1127 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1128
1129 ;; Parameter FRAME Is kept for call compatibility to with previous
1130 ;; face implementation.
1131
1132 (defun face-attr-construct (face &optional frame)
1133   "Return a defface-style attribute list for FACE on FRAME.
1134 Value is a property list of pairs ATTRIBUTE VALUE for all specified
1135 face attributes of FACE where ATTRIBUTE is the attribute name and
1136 VALUE is the specified value of that attribute."
1137   (let (result)
1138     (dolist (entry face-attribute-name-alist result)
1139       (let* ((attribute (car entry))
1140              (value (face-attribute face attribute)))
1141         (unless (eq value 'unspecified)
1142           (setq result (nconc (list attribute value) result)))))))
1143
1144
1145 (defun face-spec-set-match-display (display frame)
1146   "Non-nil if DISPLAY matches FRAME.
1147 DISPLAY is part of a spec such as can be used in `defface'.
1148 If FRAME is nil, the current FRAME is used."
1149   (let* ((conjuncts display)
1150          conjunct req options
1151          ;; t means we have succeeded against all the conjuncts in
1152          ;; DISPLAY that have been tested so far.
1153          (match t))
1154     (if (eq conjuncts t)
1155         (setq conjuncts nil))
1156     (while (and conjuncts match)
1157       (setq conjunct (car conjuncts)
1158             conjuncts (cdr conjuncts)
1159             req (car conjunct)
1160             options (cdr conjunct)
1161             match (cond ((eq req 'type)
1162                          (or (memq window-system options)
1163                              ;; FIXME: This should be revisited to use
1164                              ;; display-graphic-p, provided that the
1165                              ;; color selection depends on the number
1166                              ;; of supported colors, and all defface's
1167                              ;; are changed to look at number of colors
1168                              ;; instead of (type graphic) etc.
1169                              (and (null window-system)
1170                                   (memq 'tty options))
1171                              (and (memq 'motif options)
1172                                   (featurep 'motif))
1173                              (and (memq 'lucid options)
1174                                   (featurep 'x-toolkit)
1175                                   (not (featurep 'motif)))
1176                              (and (memq 'x-toolkit options)
1177                                   (featurep 'x-toolkit))))
1178                         ((eq req 'class)
1179                          (memq (frame-parameter frame 'display-type) options))
1180                         ((eq req 'background)
1181                          (memq (frame-parameter frame 'background-mode)
1182                                options))
1183                         (t (error "Unknown req `%S' with options `%S'"
1184                                   req options)))))
1185     match))
1186
1187
1188 (defun face-spec-choose (spec &optional frame)
1189   "Choose the proper attributes for FRAME, out of SPEC.
1190 If SPEC is nil, return nil."
1191   (unless frame
1192     (setq frame (selected-frame)))
1193   (let ((tail spec)
1194         result)
1195     (while tail
1196       (let* ((entry (pop tail))
1197              (display (car entry))
1198              (attrs (cdr entry)))
1199         (when (face-spec-set-match-display display frame)
1200           (setq result (if (listp (car attrs))
1201                            ;; Old-style entry, the attribute list is the
1202                            ;; first element.
1203                            (car attrs)
1204                          attrs)
1205                 tail nil))))
1206     result))
1207
1208
1209 (defun face-spec-reset-face (face &optional frame)
1210   "Reset all attributes of FACE on FRAME to unspecified."
1211   (let ((attrs face-attribute-name-alist))
1212     (while attrs
1213       (let ((attr-and-name (car attrs)))
1214         (set-face-attribute face frame (car attr-and-name) 'unspecified))
1215       (setq attrs (cdr attrs)))))
1216
1217
1218 (defun face-spec-set (face spec &optional frame)
1219   "Set FACE's attributes according to the first matching entry in SPEC.
1220 FRAME is the frame whose frame-local face is set.  FRAME nil means
1221 do it on all frames.  See `defface' for information about SPEC.
1222 If SPEC is nil, do nothing."
1223   (let ((attrs (face-spec-choose spec frame)))
1224     (when attrs
1225       (face-spec-reset-face face frame))
1226     (while attrs
1227       (let ((attribute (car attrs))
1228             (value (car (cdr attrs))))
1229         ;; Support some old-style attribute names and values.
1230         (case attribute
1231           (:bold (setq attribute :weight value (if value 'bold 'normal)))
1232           (:italic (setq attribute :slant value (if value 'italic 'normal)))
1233           (t (unless (assq attribute face-x-resources)
1234                (setq attribute nil))))
1235         (when attribute
1236           (set-face-attribute face frame attribute value)))
1237       (setq attrs (cdr (cdr attrs))))))
1238
1239
1240 (defun face-attr-match-p (face attrs &optional frame)
1241   "Return t if attributes of FACE match values in plist ATTRS.
1242 Optional parameter FRAME is the frame whose definition of FACE
1243 is used.  If nil or omitted, use the selected frame."
1244   (unless frame
1245     (setq frame (selected-frame)))
1246   (let ((list face-attribute-name-alist)
1247         (match t))
1248     (while (and match (not (null list)))
1249       (let* ((attr (car (car list)))
1250              (specified-value
1251               (if (plist-member attrs attr)
1252                   (plist-get attrs attr)
1253                 'unspecified))
1254              (value-now (face-attribute face attr frame)))
1255         (setq match (equal specified-value value-now))
1256         (setq list (cdr list))))
1257     match))
1258
1259 (defun face-spec-match-p (face spec &optional frame)
1260   "Return t if FACE, on FRAME, matches what SPEC says it should look like."
1261   (face-attr-match-p face (face-spec-choose spec frame) frame))
1262
1263 (defsubst face-default-spec (face)
1264   "Return the default face-spec for FACE, ignoring any user customization.
1265 If there is no default for FACE, return nil."
1266   (get face 'face-defface-spec))
1267
1268 (defsubst face-user-default-spec (face)
1269   "Return the user's customized face-spec for FACE, or the default if none.
1270 If there is neither a user setting or a default for FACE, return nil."
1271   (or (get face 'saved-face)
1272       (face-default-spec face)))
1273
1274 \f
1275 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1276 ;;; Frame-type independent color support.
1277 ;;; We keep the old x-* names as aliases for back-compatibility.
1278 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1279
1280 (defun defined-colors (&optional frame)
1281   "Return a list of colors supported for a particular frame.
1282 The argument FRAME specifies which frame to try.
1283 The value may be different for frames on different display types.
1284 If FRAME doesn't support colors, the value is nil."
1285   (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1286       (xw-defined-colors frame)
1287     (mapcar 'car (tty-color-alist frame))))
1288 (defalias 'x-defined-colors 'defined-colors)
1289
1290 (defun color-defined-p (color &optional frame)
1291   "Return non-nil if color COLOR is supported on frame FRAME.
1292 If FRAME is omitted or nil, use the selected frame.
1293 If COLOR is the symbol `unspecified' or one of the strings
1294 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1295   (if (member color '(unspecified "unspecified-bg" "unspecified-fg"))
1296       nil
1297     (if (member (framep (or frame (selected-frame))) '(x w32 mac))
1298         (xw-color-defined-p color frame)
1299       (numberp (tty-color-translate color frame)))))
1300 (defalias 'x-color-defined-p 'color-defined-p)
1301
1302 (defun color-values (color &optional frame)
1303   "Return a description of the color named COLOR on frame FRAME.
1304 The value is a list of integer RGB values--\(RED GREEN BLUE\).
1305 These values appear to range from 0 65535; white is \(65535 65535 65535\).
1306 If FRAME is omitted or nil, use the selected frame.
1307 If FRAME cannot display COLOR, the value is nil.
1308 If COLOR is the symbol `unspecified' or one of the strings
1309 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1310   (if (member color '(unspecified "unspecified-fg" "unspecified-bg"))
1311       nil
1312     (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1313         (xw-color-values color frame)
1314       (tty-color-values color frame))))
1315 (defalias 'x-color-values 'color-values)
1316
1317 (defun display-color-p (&optional display)
1318   "Return t if DISPLAY supports color.
1319 The optional argument DISPLAY specifies which display to ask about.
1320 DISPLAY should be either a frame or a display name (a string).
1321 If omitted or nil, that stands for the selected frame's display."
1322   (if (memq (framep-on-display display) '(x w32 mac))
1323       (xw-display-color-p display)
1324     (tty-display-color-p display)))
1325 (defalias 'x-display-color-p 'display-color-p)
1326
1327 (defun display-grayscale-p (&optional display)
1328   "Return non-nil if frames on DISPLAY can display shades of gray."
1329   (let ((frame-type (framep-on-display display)))
1330     (cond
1331      ((memq frame-type '(x w32 mac))
1332       (x-display-grayscale-p display))
1333      (t
1334       (> (tty-color-gray-shades display) 2)))))
1335
1336 \f
1337 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1338 ;;; Background mode.
1339 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1340
1341 (defcustom frame-background-mode nil
1342   "*The brightness of the background.
1343 Set this to the symbol `dark' if your background color is dark, `light' if
1344 your background is light, or nil (default) if you want Emacs to
1345 examine the brightness for you.  Don't set this variable with `setq';
1346 this won't have the expected effect."
1347   :group 'faces
1348   :set #'(lambda (var value)
1349            (set-default var value)
1350            (mapc 'frame-set-background-mode (frame-list)))
1351   :initialize 'custom-initialize-changed
1352   :type '(choice (choice-item dark)
1353                  (choice-item light)
1354                  (choice-item :tag "default" nil)))
1355
1356
1357 (defun frame-set-background-mode (frame)
1358   "Set up display-dependent faces on FRAME.
1359 Display-dependent faces are those which have different definitions
1360 according to the `background-mode' and `display-type' frame parameters."
1361   (let* ((bg-resource
1362           (and window-system
1363                (x-get-resource ".backgroundMode" "BackgroundMode")))
1364          (bg-color (frame-parameter frame 'background-color))
1365          (bg-mode
1366           (cond (frame-background-mode)
1367                 (bg-resource
1368                  (intern (downcase bg-resource)))
1369                 ((and (null window-system) (null bg-color))
1370                  ;; No way to determine this automatically (?).
1371                  'dark)
1372                 ;; Unspecified frame background color can only happen
1373                 ;; on tty's.
1374                 ((member bg-color '(unspecified "unspecified-bg"))
1375                  'dark)
1376                 ((equal bg-color "unspecified-fg") ; inverted colors
1377                  'light)
1378                 ((>= (apply '+ (x-color-values bg-color frame))
1379                     ;; Just looking at the screen, colors whose
1380                     ;; values add up to .6 of the white total
1381                     ;; still look dark to me.
1382                     (* (apply '+ (x-color-values "white" frame)) .6))
1383                  'light)
1384                 (t 'dark)))
1385          (display-type
1386           (cond ((null window-system)
1387                  (if (tty-display-color-p frame) 'color 'mono))
1388                 ((x-display-color-p frame)
1389                  'color)
1390                 ((x-display-grayscale-p frame)
1391                  'grayscale)
1392                 (t 'mono)))
1393          (old-bg-mode
1394           (frame-parameter frame 'background-mode))
1395          (old-display-type
1396           (frame-parameter frame 'display-type)))
1397
1398     (unless (and (eq bg-mode old-bg-mode) (eq display-type old-display-type))
1399       (let ((locally-modified-faces nil))
1400         ;; Before modifying the frame parameters, we collect a list of
1401         ;; faces that don't match what their face-spec says they should
1402         ;; look like; we then avoid changing these faces below.  A
1403         ;; negative list is used on the assumption that most faces will
1404         ;; be unmodified, so we can avoid consing in the common case.
1405         (dolist (face (face-list))
1406           (when (not (face-spec-match-p face
1407                                         (face-user-default-spec face)
1408                                         (selected-frame)))
1409             (push face locally-modified-faces)))
1410         ;; Now change to the new frame parameters
1411         (modify-frame-parameters frame
1412                                  (list (cons 'background-mode bg-mode)
1413                                        (cons 'display-type display-type)))
1414         ;; For all named faces, choose face specs matching the new frame
1415         ;; parameters, unless they have been locally modified.
1416         (dolist (face (face-list))
1417           (unless (memq face locally-modified-faces)
1418             (face-spec-set face (face-user-default-spec face) frame)))))))
1419
1420 \f
1421 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1422 ;;; Frame creation.
1423 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1424
1425 (defun x-handle-named-frame-geometry (parameters)
1426   "Add geometry parameters for a named frame to parameter list PARAMETERS.
1427 Value is the new parameter list."
1428   (let* ((name (or (cdr (assq 'name parameters))
1429                    (cdr (assq 'name default-frame-alist))))
1430          (x-resource-name name)
1431          (res-geometry (if name (x-get-resource "geometry" "Geometry"))))
1432     (when res-geometry
1433       (let ((parsed (x-parse-geometry res-geometry)))
1434         ;; If the resource specifies a position, call the position
1435         ;; and size "user-specified".
1436         (when (or (assq 'top parsed)
1437                   (assq 'left parsed))
1438           (setq parsed (append '((user-position . t) (user-size . t)) parsed)))
1439         ;; Put the geometry parameters at the end.  Copy
1440         ;; default-frame-alist so that they go after it.
1441         (setq parameters (append parameters default-frame-alist parsed))))
1442     parameters))
1443
1444
1445 (defun x-handle-reverse-video (frame parameters)
1446   "Handle the reverse-video frame parameter and X resource.
1447 `x-create-frame' does not handle this one."
1448   (when (cdr (or (assq 'reverse parameters)
1449                  (assq 'reverse default-frame-alist)
1450                  (let ((resource (x-get-resource "reverseVideo"
1451                                                  "ReverseVideo")))
1452                    (if resource
1453                        (cons nil (member (downcase resource)
1454                                          '("on" "true")))))))
1455       (let* ((params (frame-parameters frame))
1456              (bg (cdr (assq 'foreground-color params)))
1457              (fg (cdr (assq 'background-color params))))
1458         (modify-frame-parameters frame
1459                                  (list (cons 'foreground-color fg)
1460                                        (cons 'background-color bg)))
1461         (if (equal bg (cdr (assq 'border-color params)))
1462             (modify-frame-parameters frame
1463                                      (list (cons 'border-color fg))))
1464         (if (equal bg (cdr (assq 'mouse-color params)))
1465             (modify-frame-parameters frame
1466                                      (list (cons 'mouse-color fg))))
1467         (if (equal bg (cdr (assq 'cursor-color params)))
1468             (modify-frame-parameters frame
1469                                      (list (cons 'cursor-color fg)))))))
1470
1471
1472 (defun x-create-frame-with-faces (&optional parameters)
1473   "Create a frame from optional frame parameters PARAMETERS.
1474 Parameters not specified by PARAMETERS are taken from
1475 `default-frame-alist'.  If PARAMETERS specify a frame name,
1476 handle X geometry resources for that name.  If either PARAMETERS
1477 or `default-frame-alist' contains a `reverse' parameter, or
1478 the X resource ``reverseVideo'' is present, handle that.
1479 Value is the new frame created."
1480   (setq parameters (x-handle-named-frame-geometry parameters))
1481   (let ((visibility-spec (assq 'visibility parameters))
1482         (frame-list (frame-list))
1483         (frame (x-create-frame (cons '(visibility . nil) parameters)))
1484         success)
1485     (unwind-protect
1486         (progn
1487           (x-handle-reverse-video frame parameters)
1488           (frame-set-background-mode frame)
1489           (face-set-after-frame-default frame)
1490           (if (or (null frame-list) (null visibility-spec))
1491               (make-frame-visible frame)
1492             (modify-frame-parameters frame (list visibility-spec)))
1493           (setq success t))
1494       (unless success
1495         (delete-frame frame)))
1496     frame))
1497
1498
1499 (defun face-set-after-frame-default (frame)
1500   "Set frame-local faces of FRAME from face specs and resources.
1501 Initialize colors of certain faces from frame parameters."
1502   (dolist (face (face-list))
1503     (face-spec-set face (face-user-default-spec face) frame)
1504     (internal-merge-in-global-face face frame)
1505     (when (and (memq window-system '(x w32 mac))
1506                (or (not (boundp 'inhibit-default-face-x-resources))
1507                    (not (eq face 'default))))
1508       (make-face-x-resource-internal face frame)))
1509
1510   ;; Initialize attributes from frame parameters.
1511   (let ((params '((foreground-color default :foreground)
1512                   (background-color default :background)
1513                   (border-color border :background)
1514                   (cursor-color cursor :background)
1515                   (scroll-bar-foreground scroll-bar :foreground)
1516                   (scroll-bar-background scroll-bar :background)
1517                   (mouse-color mouse :background))))
1518     (dolist (param params)
1519       (let ((frame-param (frame-parameter frame (nth 0 param)))
1520             (face (nth 1 param))
1521             (attr (nth 2 param)))
1522         (when (and frame-param
1523                    ;; Don't override face attributes explicitly
1524                    ;; specified for new frames.
1525                    (eq (face-attribute face attr t) 'unspecified))
1526           (set-face-attribute face frame attr frame-param))))))
1527
1528
1529 (defun tty-handle-reverse-video (frame parameters)
1530   "Handle the reverse-video frame parameter for terminal frames."
1531   (when (cdr (or (assq 'reverse parameters)
1532                  (assq 'reverse default-frame-alist)))
1533     (if (null window-system)
1534         (setq inverse-video t))
1535     (let* ((params (frame-parameters frame))
1536            (bg (cdr (assq 'foreground-color params)))
1537            (fg (cdr (assq 'background-color params))))
1538       (modify-frame-parameters frame
1539                                (list (cons 'foreground-color fg)
1540                                      (cons 'background-color bg)))
1541       (if (equal bg (cdr (assq 'mouse-color params)))
1542           (modify-frame-parameters frame
1543                                    (list (cons 'mouse-color fg))))
1544       (if (equal bg (cdr (assq 'cursor-color params)))
1545           (modify-frame-parameters frame
1546                                    (list (cons 'cursor-color fg)))))))
1547
1548
1549 (defun tty-create-frame-with-faces (&optional parameters)
1550   "Create a frame from optional frame parameters PARAMETERS.
1551 Parameters not specified by PARAMETERS are taken from
1552 `default-frame-alist'.  If either PARAMETERS or `default-frame-alist'
1553 contains a `reverse' parameter, handle that.  Value is the new frame
1554 created."
1555   (let ((frame (make-terminal-frame parameters))
1556         success)
1557     (unwind-protect
1558         (progn
1559           (tty-handle-reverse-video frame (frame-parameters frame))
1560           (frame-set-background-mode frame)
1561           (face-set-after-frame-default frame)
1562           (setq success t))
1563       (unless success
1564         (delete-frame frame)))
1565     frame))
1566
1567
1568 ;; Called from C function init_display to initialize faces of the
1569 ;; dumped terminal frame on startup.
1570
1571 (defun tty-set-up-initial-frame-faces ()
1572   (let ((frame (selected-frame)))
1573     (frame-set-background-mode frame)
1574     (face-set-after-frame-default frame)))
1575
1576
1577
1578 \f
1579 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1580 ;;; Compatiblity with 20.2
1581 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1582
1583 ;; Update a frame's faces when we change its default font.
1584
1585 (defalias 'frame-update-faces 'ignore)
1586 (make-obsolete 'frame-update-faces "No longer necessary" "21.1")
1587
1588 ;; Update the colors of FACE, after FRAME's own colors have been
1589 ;; changed.
1590
1591 (defalias 'frame-update-face-colors 'frame-set-background-mode)
1592 (make-obsolete 'frame-update-face-colors 'frame-set-background-mode "21.1")
1593
1594 \f
1595 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1596 ;;; Standard faces.
1597 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1598
1599 (defgroup basic-faces nil
1600   "The standard faces of Emacs."
1601   :group 'faces)
1602
1603
1604 (defface default
1605   '((t nil))
1606   "Basic default face."
1607   :group 'basic-faces)
1608
1609
1610 (defface mode-line
1611   '((((type x w32 mac) (class color))
1612      (:box (:line-width 2 :style released-button)
1613            :background "grey75" :foreground "black"))
1614     (t
1615      (:inverse-video t)))
1616   "Basic mode line face."
1617   :version "21.1"
1618   :group 'modeline
1619   :group 'basic-faces)
1620
1621 ;; Make `modeline' an alias for `mode-line', for compatibility.
1622 (put 'modeline 'face-alias 'mode-line)
1623
1624 (defface header-line
1625   '((((type tty))
1626      ;; This used to be `:inverse-video t', but that doesn't look very
1627      ;; good when combined with inverse-video mode-lines and multiple
1628      ;; windows.  Underlining looks better, and is more consistent with
1629      ;; the window-system face variants, which deemphasize the
1630      ;; header-line in relation to the mode-line face.  If a terminal
1631      ;; can't underline, then the header-line will end up without any
1632      ;; highlighting; this may be too confusing in general, although it
1633      ;; happens to look good with the only current use of header-lines,
1634      ;; the info browser. XXX
1635      :underline t)
1636     (((class color grayscale) (background light))
1637      :inherit mode-line
1638      :background "grey90" :foreground "grey20"
1639      :box nil)
1640     (((class color grayscale) (background dark))
1641      :inherit mode-line
1642      :background "grey20" :foreground "grey90"
1643      :box nil)
1644     (((class mono) (background light))
1645      :inherit mode-line
1646      :background "white" :foreground "black"
1647      :inverse-video nil
1648      :box nil
1649      :underline t)
1650     (((class mono) (background dark))
1651      :inherit mode-line
1652      :background "black" :foreground "white"
1653      :inverse-video nil
1654      :box nil
1655      :underline t)
1656     (t
1657      :inverse-video t))
1658   "Basic header-line face."
1659   :version "21.1"
1660   :group 'basic-faces)
1661
1662
1663 (defface tool-bar
1664   '((((type x w32 mac) (class color))
1665      (:box (:line-width 1 :style released-button)
1666            :background "grey75" :foreground "black"))
1667     (((type x) (class mono))
1668      (:box (:line-width 1 :style released-button)
1669            :background "grey" :foreground "black"))
1670     (t
1671      ()))
1672   "Basic tool-bar face."
1673   :version "21.1"
1674   :group 'basic-faces)
1675
1676
1677 (defface region
1678   '((((type tty) (class color))
1679      (:background "blue" :foreground "white"))
1680     (((type tty) (class mono))
1681      (:inverse-video t))
1682     (((class color) (background dark))
1683      (:background "blue3"))
1684     (((class color) (background light))
1685      (:background "light goldenrod yellow"))
1686     (t (:background "gray")))
1687   "Basic face for highlighting the region."
1688   :version "21.1"
1689   :group 'basic-faces)
1690
1691
1692 (defface fringe
1693   '((((class color) (background light))
1694        (:background "grey95"))
1695       (((class color) (background dark))
1696        (:background "grey10"))
1697       (t
1698        (:background "gray")))
1699   "Basic face for the fringes to the left and right of windows under X."
1700   :version "21.1"
1701   :group 'frames
1702   :group 'basic-faces)
1703
1704
1705 (defface scroll-bar '()
1706   "Basic face for the scroll bar colors under X."
1707   :version "21.1"
1708   :group 'frames
1709   :group 'basic-faces)
1710
1711
1712 (defface menu
1713   '((((type tty))
1714      :inverse-video t)
1715     (((type x-toolkit))
1716      )
1717     (t
1718      :inverse-video t))
1719   "Basic menu face."
1720   :version "21.1"
1721   :group 'menu
1722   :group 'basic-faces)
1723
1724
1725 (defface border '()
1726   "Basic face for the frame border under X."
1727   :version "21.1"
1728   :group 'frames
1729   :group 'basic-faces)
1730
1731
1732 (defface cursor '()
1733   "Basic face for the cursor color under X."
1734   :version "21.1"
1735   :group 'cursor
1736   :group 'basic-faces)
1737
1738
1739 (defface mouse '()
1740   "Basic face for the mouse color under X."
1741   :version "21.1"
1742   :group 'mouse
1743   :group 'basic-faces)
1744
1745
1746 (defface bold '((t (:weight bold)))
1747   "Basic bold face."
1748   :group 'basic-faces)
1749
1750
1751 (defface italic '((t (:slant italic)))
1752   "Basic italic font."
1753   :group 'basic-faces)
1754
1755
1756 (defface bold-italic '((t (:weight bold :slant italic)))
1757   "Basic bold-italic face."
1758   :group 'basic-faces)
1759
1760
1761 (defface underline '((t (:underline t)))
1762   "Basic underlined face."
1763   :group 'basic-faces)
1764
1765
1766 (defface highlight
1767   '((((type tty) (class color))
1768      (:background "green"))
1769     (((class color) (background light))
1770      (:background "darkseagreen2"))
1771     (((class color) (background dark))
1772      (:background "darkolivegreen"))
1773     (t (:inverse-video t)))
1774   "Basic face for highlighting."
1775   :group 'basic-faces)
1776
1777
1778 (defface secondary-selection
1779   '((((type tty) (class color))
1780      (:background "cyan" :foreground "black"))
1781     (((class color) (background light))
1782      (:background "yellow"))
1783     (((class color) (background dark))
1784      (:background "SkyBlue4"))
1785     (t (:inverse-video t)))
1786   "Basic face for displaying the secondary selection."
1787   :group 'basic-faces)
1788
1789
1790 (defface fixed-pitch '((t (:family "courier")))
1791   "The basic fixed-pitch face."
1792   :group 'basic-faces)
1793
1794
1795 (defface variable-pitch '((t (:family "helv")))
1796   "The basic variable-pitch face."
1797   :group 'basic-faces)
1798
1799
1800 (defface trailing-whitespace
1801   '((((class color) (background light))
1802      (:background "red"))
1803     (((class color) (background dark))
1804      (:background "red"))
1805     (t (:inverse-video t)))
1806   "Basic face for highlighting trailing whitespace."
1807   :version "21.1"
1808   :group 'font-lock                     ; like `show-trailing-whitespace'
1809   :group 'basic-faces)
1810
1811
1812 \f
1813 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1814 ;;; Manipulating font names.
1815 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1816
1817 ;; This is here for compatibilty with Emacs 20.2.  For example,
1818 ;; international/fontset.el uses x-resolve-font-name.  The following
1819 ;; functions are not used in the face implementation itself.
1820
1821 (defvar x-font-regexp nil)
1822 (defvar x-font-regexp-head nil)
1823 (defvar x-font-regexp-weight nil)
1824 (defvar x-font-regexp-slant nil)
1825
1826 (defconst x-font-regexp-weight-subnum 1)
1827 (defconst x-font-regexp-slant-subnum 2)
1828 (defconst x-font-regexp-swidth-subnum 3)
1829 (defconst x-font-regexp-adstyle-subnum 4)
1830
1831 ;;; Regexps matching font names in "Host Portable Character Representation."
1832 ;;;
1833 (let ((-                "[-?]")
1834       (foundry          "[^-]+")
1835       (family           "[^-]+")
1836       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
1837 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
1838       (weight\?         "\\([^-]*\\)")                                  ; 1
1839       (slant            "\\([ior]\\)")                                  ; 2
1840 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
1841       (slant\?          "\\([^-]?\\)")                                  ; 2
1842 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
1843       (swidth           "\\([^-]*\\)")                                  ; 3
1844 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
1845       (adstyle          "\\([^-]*\\)")                                  ; 4
1846       (pixelsize        "[0-9]+")
1847       (pointsize        "[0-9][0-9]+")
1848       (resx             "[0-9][0-9]+")
1849       (resy             "[0-9][0-9]+")
1850       (spacing          "[cmp?*]")
1851       (avgwidth         "[0-9]+")
1852       (registry         "[^-]+")
1853       (encoding         "[^-]+")
1854       )
1855   (setq x-font-regexp
1856         (concat "\\`\\*?[-?*]"
1857                 foundry - family - weight\? - slant\? - swidth - adstyle -
1858                 pixelsize - pointsize - resx - resy - spacing - avgwidth -
1859                 registry - encoding "\\*?\\'"
1860                 ))
1861   (setq x-font-regexp-head
1862         (concat "\\`[-?*]" foundry - family - weight\? - slant\?
1863                 "\\([-*?]\\|\\'\\)"))
1864   (setq x-font-regexp-slant (concat - slant -))
1865   (setq x-font-regexp-weight (concat - weight -))
1866   nil)
1867
1868
1869 (defun x-resolve-font-name (pattern &optional face frame)
1870   "Return a font name matching PATTERN.
1871 All wildcards in PATTERN are instantiated.
1872 If PATTERN is nil, return the name of the frame's base font, which never
1873 contains wildcards.
1874 Given optional arguments FACE and FRAME, return a font which is
1875 also the same size as FACE on FRAME, or fail."
1876   (or (symbolp face)
1877       (setq face (face-name face)))
1878   (and (eq frame t)
1879        (setq frame nil))
1880   (if pattern
1881       ;; Note that x-list-fonts has code to handle a face with nil as its font.
1882       (let ((fonts (x-list-fonts pattern face frame 1)))
1883         (or fonts
1884             (if face
1885                 (if (string-match "\\*" pattern)
1886                     (if (null (face-font face))
1887                         (error "No matching fonts are the same height as the frame default font")
1888                       (error "No matching fonts are the same height as face `%s'" face))
1889                   (if (null (face-font face))
1890                       (error "Height of font `%s' doesn't match the frame default font"
1891                              pattern)
1892                     (error "Height of font `%s' doesn't match face `%s'"
1893                            pattern face)))
1894               (error "No fonts match `%s'" pattern)))
1895         (car fonts))
1896     (cdr (assq 'font (frame-parameters (selected-frame))))))
1897
1898
1899 (defun x-frob-font-weight (font which)
1900   (let ((case-fold-search t))
1901     (cond ((string-match x-font-regexp font)
1902            (concat (substring font 0
1903                               (match-beginning x-font-regexp-weight-subnum))
1904                    which
1905                    (substring font (match-end x-font-regexp-weight-subnum)
1906                               (match-beginning x-font-regexp-adstyle-subnum))
1907                    ;; Replace the ADD_STYLE_NAME field with *
1908                    ;; because the info in it may not be the same
1909                    ;; for related fonts.
1910                    "*"
1911                    (substring font (match-end x-font-regexp-adstyle-subnum))))
1912           ((string-match x-font-regexp-head font)
1913            (concat (substring font 0 (match-beginning 1)) which
1914                    (substring font (match-end 1))))
1915           ((string-match x-font-regexp-weight font)
1916            (concat (substring font 0 (match-beginning 1)) which
1917                    (substring font (match-end 1)))))))
1918 (make-obsolete 'x-frob-font-weight 'make-face-... "21.1")
1919
1920 (defun x-frob-font-slant (font which)
1921   (let ((case-fold-search t))
1922     (cond ((string-match x-font-regexp font)
1923            (concat (substring font 0
1924                               (match-beginning x-font-regexp-slant-subnum))
1925                    which
1926                    (substring font (match-end x-font-regexp-slant-subnum)
1927                               (match-beginning x-font-regexp-adstyle-subnum))
1928                    ;; Replace the ADD_STYLE_NAME field with *
1929                    ;; because the info in it may not be the same
1930                    ;; for related fonts.
1931                    "*"
1932                    (substring font (match-end x-font-regexp-adstyle-subnum))))
1933           ((string-match x-font-regexp-head font)
1934            (concat (substring font 0 (match-beginning 2)) which
1935                    (substring font (match-end 2))))
1936           ((string-match x-font-regexp-slant font)
1937            (concat (substring font 0 (match-beginning 1)) which
1938                    (substring font (match-end 1)))))))
1939 (make-obsolete 'x-frob-font-slant 'make-face-... "21.1")
1940
1941 (defun x-make-font-bold (font)
1942   "Given an X font specification, make a bold version of it.
1943 If that can't be done, return nil."
1944   (x-frob-font-weight font "bold"))
1945 (make-obsolete 'x-make-font-bold 'make-face-bold "21.1")
1946
1947 (defun x-make-font-demibold (font)
1948   "Given an X font specification, make a demibold version of it.
1949 If that can't be done, return nil."
1950   (x-frob-font-weight font "demibold"))
1951 (make-obsolete 'x-make-font-demibold 'make-face-bold "21.1")
1952
1953 (defun x-make-font-unbold (font)
1954   "Given an X font specification, make a non-bold version of it.
1955 If that can't be done, return nil."
1956   (x-frob-font-weight font "medium"))
1957 (make-obsolete 'x-make-font-unbold 'make-face-unbold "21.1")
1958
1959 (defun x-make-font-italic (font)
1960   "Given an X font specification, make an italic version of it.
1961 If that can't be done, return nil."
1962   (x-frob-font-slant font "i"))
1963 (make-obsolete 'x-make-font-italic 'make-face-italic "21.1")
1964
1965 (defun x-make-font-oblique (font) ; you say tomayto...
1966   "Given an X font specification, make an oblique version of it.
1967 If that can't be done, return nil."
1968   (x-frob-font-slant font "o"))
1969 (make-obsolete 'x-make-font-oblique 'make-face-italic "21.1")
1970
1971 (defun x-make-font-unitalic (font)
1972   "Given an X font specification, make a non-italic version of it.
1973 If that can't be done, return nil."
1974   (x-frob-font-slant font "r"))
1975 (make-obsolete 'x-make-font-unitalic 'make-face-unitalic "21.1")
1976
1977 (defun x-make-font-bold-italic (font)
1978   "Given an X font specification, make a bold and italic version of it.
1979 If that can't be done, return nil."
1980   (and (setq font (x-make-font-bold font))
1981        (x-make-font-italic font)))
1982 (make-obsolete 'x-make-font-bold-italic 'make-face-bold-italic "21.1")
1983
1984 (provide 'faces)
1985
1986 ;;; faces.el ends here