lisp/vc-hg.el

   1 ;;; vc-hg.el --- VC backend for the mercurial version control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Ivan Kanis
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This is a mercurial version control backend
  26
  27 ;;; Thanks:
  28
  29 ;;; Bugs:
  30
  31 ;;; Installation:
  32
  33 ;;; Todo:
  34
  35 ;; 1) Implement the rest of the vc interface. See the comment at the
  36 ;; beginning of vc.el. The current status is:
  37
  38 ;; FUNCTION NAME                               STATUS
  39 ;; BACKEND PROPERTIES
  40 ;; * revision-granularity                      OK
  41 ;; STATE-QUERYING FUNCTIONS
  42 ;; * registered (file)                         OK
  43 ;; * state (file)                              OK
  44 ;; - state-heuristic (file)                    NOT NEEDED
  45 ;; - dir-status (dir update-function)          OK
  46 ;; - dir-status-files (dir files ds uf)        OK
  47 ;; - dir-extra-headers (dir)                   OK
  48 ;; - dir-printer (fileinfo)                    OK
  49 ;; * working-revision (file)                   OK
  50 ;; - latest-on-branch-p (file)                 ??
  51 ;; * checkout-model (files)                    OK
  52 ;; - workfile-unchanged-p (file)               OK
  53 ;; - mode-line-string (file)                   NOT NEEDED
  54 ;; STATE-CHANGING FUNCTIONS
  55 ;; * register (files &optional rev comment)    OK
  56 ;; * create-repo ()                            OK
  57 ;; - init-revision ()                          NOT NEEDED
  58 ;; - responsible-p (file)                      OK
  59 ;; - could-register (file)                     OK
  60 ;; - receive-file (file rev)                   ?? PROBABLY NOT NEEDED
  61 ;; - unregister (file)                         COMMENTED OUT, MAY BE INCORRECT
  62 ;; * checkin (files rev comment)               OK
  63 ;; * find-revision (file rev buffer)           OK
  64 ;; * checkout (file &optional editable rev)    OK
  65 ;; * revert (file &optional contents-done)     OK
  66 ;; - rollback (files)                          ?? PROBABLY NOT NEEDED
  67 ;; - merge (file rev1 rev2)                    NEEDED
  68 ;; - merge-news (file)                         NEEDED
  69 ;; - steal-lock (file &optional revision)      NOT NEEDED
  70 ;; HISTORY FUNCTIONS
  71 ;; * print-log (files buffer &optional shortlog start-revision limit) OK
  72 ;; - log-view-mode ()                          OK
  73 ;; - show-log-entry (revision)                 NOT NEEDED, DEFAULT IS GOOD
  74 ;; - comment-history (file)                    NOT NEEDED
  75 ;; - update-changelog (files)                  NOT NEEDED
  76 ;; * diff (files &optional rev1 rev2 buffer)   OK
  77 ;; - revision-completion-table (files)         OK?
  78 ;; - annotate-command (file buf &optional rev) OK
  79 ;; - annotate-time ()                          OK
  80 ;; - annotate-current-time ()                  NOT NEEDED
  81 ;; - annotate-extract-revision-at-line ()      OK
  82 ;; TAG SYSTEM
  83 ;; - create-tag (dir name branchp)             NEEDED
  84 ;; - retrieve-tag (dir name update)            NEEDED
  85 ;; MISCELLANEOUS
  86 ;; - make-version-backups-p (file)             ??
  87 ;; - repository-hostname (dirname)             ??
  88 ;; - previous-revision (file rev)              OK
  89 ;; - next-revision (file rev)                  OK
  90 ;; - check-headers ()                          ??
  91 ;; - clear-headers ()                          ??
  92 ;; - delete-file (file)                        TEST IT
  93 ;; - rename-file (old new)                     OK
  94 ;; - find-file-hook ()                         PROBABLY NOT NEEDED
  95
  96 ;; 2) Implement Stefan Monnier's advice:
  97 ;; vc-hg-registered and vc-hg-state
  98 ;; Both of those functions should be super extra careful to fail gracefully in
  99 ;; unexpected circumstances. The reason this is important is that any error
 100 ;; there will prevent the user from even looking at the file :-(
 101 ;; Ideally, just like in vc-arch and vc-cvs, checking that the file is under
 102 ;; mercurial's control and extracting the current revision should be done
 103 ;; without even using `hg' (this way even if you don't have `hg' installed,
 104 ;; Emacs is able to tell you this file is under mercurial's control).
 105
 106 ;;; History:
 107 ;;
 108
 109 ;;; Code:
 110
 111 (eval-when-compile
 112   (require 'cl)
 113   (require 'vc)
 114   (require 'vc-dir))
 115
 116 ;;; Customization options
 117
 118 (defcustom vc-hg-global-switches nil
 119   "Global switches to pass to any Hg command."
 120   :type '(choice (const :tag "None" nil)
 121          (string :tag "Argument String")
 122          (repeat :tag "Argument List" :value ("") string))
 123   :version "22.2"
 124   :group 'vc)
 125
 126 (defcustom vc-hg-diff-switches t ; Hg doesn't support common args like -u
 127   "String or list of strings specifying switches for Hg diff under VC.
 128 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
 129   :type '(choice (const :tag "Unspecified" nil)
 130                  (const :tag "None" t)
 131                  (string :tag "Argument String")
 132                  (repeat :tag "Argument List" :value ("") string))
 133   :version "23.1"
 134   :group 'vc)
 135
 136 \f
 137 ;;; Properties of the backend
 138
 139 (defun vc-hg-revision-granularity () 'repository)
 140 (defun vc-hg-checkout-model (files) 'implicit)
 141
 142 ;;; State querying functions
 143
 144 ;;;###autoload (defun vc-hg-registered (file)
 145 ;;;###autoload   "Return non-nil if FILE is registered with hg."
 146 ;;;###autoload   (if (vc-find-root file ".hg")       ; short cut
 147 ;;;###autoload       (progn
 148 ;;;###autoload         (load "vc-hg")
 149 ;;;###autoload         (vc-hg-registered file))))
 150
 151 ;; Modeled after the similar function in vc-bzr.el
 152 (defun vc-hg-registered (file)
 153   "Return non-nil if FILE is registered with hg."
 154   (when (vc-hg-root file)           ; short cut
 155     (let ((state (vc-hg-state file)))  ; expensive
 156       (and state (not (memq state '(ignored unregistered)))))))
 157
 158 (defun vc-hg-state (file)
 159   "Hg-specific version of `vc-state'."
 160   (let*
 161       ((status nil)
 162        (default-directory (file-name-directory file))
 163        (out
 164         (with-output-to-string
 165           (with-current-buffer
 166               standard-output
 167             (setq status
 168                   (condition-case nil
 169                       ;; Ignore all errors.
 170                       (let ((process-environment
 171                              ;; Avoid localization of messages so we
 172                              ;; can parse the output.
 173                              (append (list "TERM=dumb" "LANGUAGE=C")
 174                                      process-environment)))
 175                         (process-file
 176                          "hg" nil t nil
 177                          "--config" "alias.status=status"
 178                          "--config" "defaults.status="
 179                          "status" "-A" (file-relative-name file)))
 180                     ;; Some problem happened.  E.g. We can't find an `hg'
 181                     ;; executable.
 182                     (error nil)))))))
 183     (when (eq 0 status)
 184         (when (null (string-match ".*: No such file or directory$" out))
 185           (let ((state (aref out 0)))
 186             (cond
 187              ((eq state ?=) 'up-to-date)
 188              ((eq state ?A) 'added)
 189              ((eq state ?M) 'edited)
 190              ((eq state ?I) 'ignored)
 191              ((eq state ?R) 'removed)
 192              ((eq state ?!) 'missing)
 193              ((eq state ??) 'unregistered)
 194              ((eq state ?C) 'up-to-date) ;; Older mercurials use this
 195              (t 'up-to-date)))))))
 196
 197 (defun vc-hg-working-revision (file)
 198   "Hg-specific version of `vc-working-revision'."
 199   (let*
 200       ((status nil)
 201        (default-directory (file-name-directory file))
 202        ;; Avoid localization of messages so we can parse the output.
 203        (avoid-local-env (append (list "TERM=dumb" "LANGUAGE=C")
 204                                      process-environment))
 205        (out
 206         (with-output-to-string
 207           (with-current-buffer
 208               standard-output
 209             (setq status
 210                   (condition-case nil
 211                       (let ((process-environment avoid-local-env))
 212                         ;; Ignore all errors.
 213                         (process-file
 214                          "hg" nil t nil
 215                          "--config" "alias.parents=parents"
 216                          "--config" "defaults.parents="
 217                          "parents" "--template" "{rev}" (file-relative-name file)))
 218                     ;; Some problem happened.  E.g. We can't find an `hg'
 219                     ;; executable.
 220                     (error nil)))))))
 221     (if (eq 0 status)
 222         out
 223       ;; Check if the file is in the 'added state, the above hg
 224       ;; command does not distinguish between 'added and 'unregistered.
 225       (setq status
 226             (condition-case nil
 227                 (let ((process-environment avoid-local-env))
 228                   (process-file
 229                    "hg" nil nil nil
 230                    ;; We use "log" here, if there's a faster command
 231                    ;; that returns true for an 'added file and false
 232                    ;; for an 'unregistered one, we could use that.
 233                    "log" "-l1" (file-relative-name file)))
 234               ;; Some problem happened.  E.g. We can't find an `hg'
 235               ;; executable.
 236               (error nil)))
 237       (when (eq 0 status) "0"))))
 238
 239 ;;; History functions
 240
 241 (defcustom vc-hg-log-switches nil
 242   "String or list of strings specifying switches for hg log under VC."
 243   :type '(choice (const :tag "None" nil)
 244                  (string :tag "Argument String")
 245                  (repeat :tag "Argument List" :value ("") string))
 246   :group 'vc-hg)
 247
 248 (defun vc-hg-print-log (files buffer &optional shortlog start-revision limit)
 249   "Get change log associated with FILES."
 250   ;; `vc-do-command' creates the buffer, but we need it before running
 251   ;; the command.
 252   (vc-setup-buffer buffer)
 253   ;; If the buffer exists from a previous invocation it might be
 254   ;; read-only.
 255   (let ((inhibit-read-only t))
 256     (with-current-buffer
 257         buffer
 258       (apply 'vc-hg-command buffer 0 files "log"
 259              (nconc
 260               (when start-revision (list (format "-r%s:" start-revision)))
 261               (when limit (list "-l" (format "%s" limit)))
 262               (when shortlog (list "--style" "compact"))
 263               vc-hg-log-switches)))))
 264
 265 (defvar log-view-message-re)
 266 (defvar log-view-file-re)
 267 (defvar log-view-font-lock-keywords)
 268 (defvar log-view-per-file-logs)
 269
 270 (define-derived-mode vc-hg-log-view-mode log-view-mode "Hg-Log-View"
 271   (require 'add-log) ;; we need the add-log faces
 272   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 273   (set (make-local-variable 'log-view-per-file-logs) nil)
 274   (set (make-local-variable 'log-view-message-re)
 275        (if (eq vc-log-view-type 'short)
 276            "^\\([0-9]+\\)\\(\\[.*\\]\\)? +\\([0-9a-z]\\{12\\}\\) +\\(\\(?:[0-9]+\\)-\\(?:[0-9]+\\)-\\(?:[0-9]+\\) \\(?:[0-9]+\\):\\(?:[0-9]+\\) \\(?:[-+0-9]+\\)\\) +\\(.*\\)$"
 277          "^changeset:[ \t]*\\([0-9]+\\):\\(.+\\)"))
 278   (set (make-local-variable 'log-view-font-lock-keywords)
 279        (if (eq vc-log-view-type 'short)
 280            (append `((,log-view-message-re
 281                       (1 'log-view-message-face)
 282                       (2 'highlight nil lax)
 283                       (3 'log-view-message-face)
 284                       (4 'change-log-date)
 285                       (5 'change-log-name))))
 286        (append
 287         log-view-font-lock-keywords
 288         '(
 289           ;; Handle the case:
 290           ;; user: FirstName LastName <foo@bar>
 291           ("^user:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 292            (1 'change-log-name)
 293            (2 'change-log-email))
 294           ;; Handle the cases:
 295           ;; user: foo@bar
 296           ;; and
 297           ;; user: foo
 298           ("^user:[ \t]+\\([A-Za-z0-9_.+-]+\\(?:@[A-Za-z0-9_.-]+\\)?\\)"
 299            (1 'change-log-email))
 300           ("^date: \\(.+\\)" (1 'change-log-date))
 301           ("^tag: +\\([^ ]+\\)$" (1 'highlight))
 302           ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message)))))))
 303
 304 (defun vc-hg-diff (files &optional oldvers newvers buffer)
 305   "Get a difference report using hg between two revisions of FILES."
 306   (let* ((firstfile (car files))
 307          (working (and firstfile (vc-working-revision firstfile))))
 308     (when (and (equal oldvers working) (not newvers))
 309       (setq oldvers nil))
 310     (when (and (not oldvers) newvers)
 311       (setq oldvers working))
 312     (apply #'vc-hg-command (or buffer "*vc-diff*") nil files "diff"
 313            (append
 314             (vc-switches 'hg 'diff)
 315             (when oldvers
 316               (if newvers
 317                   (list "-r" oldvers "-r" newvers)
 318                 (list "-r" oldvers)))))))
 319
 320 (defun vc-hg-revision-table (files)
 321   (let ((default-directory (file-name-directory (car files))))
 322     (with-temp-buffer
 323       (vc-hg-command t nil files "log" "--template" "{rev} ")
 324       (split-string
 325        (buffer-substring-no-properties (point-min) (point-max))))))
 326
 327 ;; Modeled after the similar function in vc-cvs.el
 328 (defun vc-hg-revision-completion-table (files)
 329   (lexical-let ((files files)
 330                 table)
 331     (setq table (lazy-completion-table
 332                  table (lambda () (vc-hg-revision-table files))))
 333     table))
 334
 335 (defun vc-hg-annotate-command (file buffer &optional revision)
 336   "Execute \"hg annotate\" on FILE, inserting the contents in BUFFER.
 337 Optional arg REVISION is a revision to annotate from."
 338   (vc-hg-command buffer 0 file "annotate" "-d" "-n" "--follow"
 339                  (when revision (concat "-r" revision))))
 340
 341 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 342
 343 ;; The format for one line output by "hg annotate -d -n" looks like this:
 344 ;;215 Wed Jun 20 21:22:58 2007 -0700: CONTENTS
 345 ;; i.e: VERSION_NUMBER DATE: CONTENTS
 346 ;; If the user has set the "--follow" option, the output looks like:
 347 ;;215 Wed Jun 20 21:22:58 2007 -0700 foo.c: CONTENTS
 348 ;; i.e. VERSION_NUMBER DATE FILENAME: CONTENTS
 349 (defconst vc-hg-annotate-re
 350   "^[ \t]*\\([0-9]+\\) \\(.\\{30\\}\\)\\(?:\\(: \\)\\|\\(?: +\\(.+\\): \\)\\)")
 351
 352 (defun vc-hg-annotate-time ()
 353   (when (looking-at vc-hg-annotate-re)
 354     (goto-char (match-end 0))
 355     (vc-annotate-convert-time
 356      (date-to-time (match-string-no-properties 2)))))
 357
 358 (defun vc-hg-annotate-extract-revision-at-line ()
 359   (save-excursion
 360     (beginning-of-line)
 361     (when (looking-at vc-hg-annotate-re)
 362       (if (match-beginning 3)
 363           (match-string-no-properties 1)
 364         (cons (match-string-no-properties 1)
 365               (expand-file-name (match-string-no-properties 4)
 366                                 (vc-hg-root default-directory)))))))
 367
 368 (defun vc-hg-previous-revision (file rev)
 369   (let ((newrev (1- (string-to-number rev))))
 370     (when (>= newrev 0)
 371       (number-to-string newrev))))
 372
 373 (defun vc-hg-next-revision (file rev)
 374   (let ((newrev (1+ (string-to-number rev)))
 375         (tip-revision
 376          (with-temp-buffer
 377            (vc-hg-command t 0 nil "tip")
 378            (goto-char (point-min))
 379            (re-search-forward "^changeset:[ \t]*\\([0-9]+\\):")
 380            (string-to-number (match-string-no-properties 1)))))
 381     ;; We don't want to exceed the maximum possible revision number, ie
 382     ;; the tip revision.
 383     (when (<= newrev tip-revision)
 384       (number-to-string newrev))))
 385
 386 ;; Modeled after the similar function in vc-bzr.el
 387 (defun vc-hg-delete-file (file)
 388   "Delete FILE and delete it in the hg repository."
 389   (condition-case ()
 390       (delete-file file)
 391     (file-error nil))
 392   (vc-hg-command nil 0 file "remove" "--after" "--force"))
 393
 394 ;; Modeled after the similar function in vc-bzr.el
 395 (defun vc-hg-rename-file (old new)
 396   "Rename file from OLD to NEW using `hg mv'."
 397   (vc-hg-command nil 0 new "mv" old))
 398
 399 (defun vc-hg-register (files &optional rev comment)
 400   "Register FILES under hg.
 401 REV is ignored.
 402 COMMENT is ignored."
 403   (vc-hg-command nil 0 files "add"))
 404
 405 (defun vc-hg-create-repo ()
 406   "Create a new Mercurial repository."
 407   (vc-hg-command nil 0 nil "init"))
 408
 409 (defalias 'vc-hg-responsible-p 'vc-hg-root)
 410
 411 ;; Modeled after the similar function in vc-bzr.el
 412 (defun vc-hg-could-register (file)
 413   "Return non-nil if FILE could be registered under hg."
 414   (and (vc-hg-responsible-p file)      ; shortcut
 415        (condition-case ()
 416            (with-temp-buffer
 417              (vc-hg-command t nil file "add" "--dry-run"))
 418              ;; The command succeeds with no output if file is
 419              ;; registered.
 420          (error))))
 421
 422 ;; FIXME: This would remove the file. Is that correct?
 423 ;; (defun vc-hg-unregister (file)
 424 ;;   "Unregister FILE from hg."
 425 ;;   (vc-hg-command nil nil file "remove"))
 426
 427 (declare-function log-edit-extract-headers "log-edit" (headers string))
 428
 429 (defun vc-hg-checkin (files rev comment)
 430   "Hg-specific version of `vc-backend-checkin'.
 431 REV is ignored."
 432   (apply 'vc-hg-command nil 0 files
 433          (nconc (list "commit" "-m")
 434                 (log-edit-extract-headers '(("Author" . "--user")
 435                                             ("Date" . "--date"))
 436                                           comment))))
 437
 438 (defun vc-hg-find-revision (file rev buffer)
 439   (let ((coding-system-for-read 'binary)
 440         (coding-system-for-write 'binary))
 441     (if rev
 442         (vc-hg-command buffer 0 file "cat" "-r" rev)
 443       (vc-hg-command buffer 0 file "cat"))))
 444
 445 ;; Modeled after the similar function in vc-bzr.el
 446 (defun vc-hg-checkout (file &optional editable rev)
 447   "Retrieve a revision of FILE.
 448 EDITABLE is ignored.
 449 REV is the revision to check out into WORKFILE."
 450   (let ((coding-system-for-read 'binary)
 451         (coding-system-for-write 'binary))
 452   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 453     (if rev
 454         (vc-hg-command t 0 file "cat" "-r" rev)
 455       (vc-hg-command t 0 file "cat")))))
 456
 457 ;; Modeled after the similar function in vc-bzr.el
 458 (defun vc-hg-workfile-unchanged-p (file)
 459   (eq 'up-to-date (vc-hg-state file)))
 460
 461 ;; Modeled after the similar function in vc-bzr.el
 462 (defun vc-hg-revert (file &optional contents-done)
 463   (unless contents-done
 464     (with-temp-buffer (vc-hg-command t 0 file "revert"))))
 465
 466 ;;; Hg specific functionality.
 467
 468 (defvar vc-hg-extra-menu-map
 469   (let ((map (make-sparse-keymap)))
 470     map))
 471
 472 (defun vc-hg-extra-menu () vc-hg-extra-menu-map)
 473
 474 (defun vc-hg-extra-status-menu () vc-hg-extra-menu-map)
 475
 476 (defvar log-view-vc-backend)
 477
 478 (defstruct (vc-hg-extra-fileinfo
 479             (:copier nil)
 480             (:constructor vc-hg-create-extra-fileinfo (rename-state extra-name))
 481             (:conc-name vc-hg-extra-fileinfo->))
 482   rename-state        ;; rename or copy state
 483   extra-name)         ;; original name for copies and rename targets, new name for
 484
 485 (declare-function vc-default-dir-printer "vc-dir" (backend fileentry))
 486
 487 (defun vc-hg-dir-printer (info)
 488   "Pretty-printer for the vc-dir-fileinfo structure."
 489   (let ((extra (vc-dir-fileinfo->extra info)))
 490     (vc-default-dir-printer 'Hg info)
 491     (when extra
 492       (insert (propertize
 493                (format "   (%s %s)"
 494                        (case (vc-hg-extra-fileinfo->rename-state extra)
 495                          ('copied "copied from")
 496                          ('renamed-from "renamed from")
 497                          ('renamed-to "renamed to"))
 498                        (vc-hg-extra-fileinfo->extra-name extra))
 499                'face 'font-lock-comment-face)))))
 500
 501 (defun vc-hg-after-dir-status (update-function)
 502   (let ((status-char nil)
 503         (file nil)
 504         (translation '((?= . up-to-date)
 505                        (?C . up-to-date)
 506                        (?A . added)
 507                        (?R . removed)
 508                        (?M . edited)
 509                        (?I . ignored)
 510                        (?! . missing)
 511                        (?  . copy-rename-line)
 512                        (?? . unregistered)))
 513         (translated nil)
 514         (result nil)
 515         (last-added nil)
 516         (last-line-copy nil))
 517       (goto-char (point-min))
 518       (while (not (eobp))
 519         (setq translated (cdr (assoc (char-after) translation)))
 520         (setq file
 521               (buffer-substring-no-properties (+ (point) 2)
 522                                               (line-end-position)))
 523         (cond ((not translated)
 524                (setq last-line-copy nil))
 525               ((eq translated 'up-to-date)
 526                (setq last-line-copy nil))
 527               ((eq translated 'copy-rename-line)
 528                ;; For copied files the output looks like this:
 529                ;; A COPIED_FILE_NAME
 530                ;;   ORIGINAL_FILE_NAME
 531                (setf (nth 2 last-added)
 532                      (vc-hg-create-extra-fileinfo 'copied file))
 533                (setq last-line-copy t))
 534               ((and last-line-copy (eq translated 'removed))
 535                ;; For renamed files the output looks like this:
 536                ;; A NEW_FILE_NAME
 537                ;;   ORIGINAL_FILE_NAME
 538                ;; R ORIGINAL_FILE_NAME
 539                ;; We need to adjust the previous entry to not think it is a copy.
 540                (setf (vc-hg-extra-fileinfo->rename-state (nth 2 last-added))
 541                      'renamed-from)
 542                (push (list file translated
 543                            (vc-hg-create-extra-fileinfo
 544                             'renamed-to (nth 0 last-added))) result)
 545                (setq last-line-copy nil))
 546               (t
 547                (setq last-added (list file translated nil))
 548                (push last-added result)
 549                (setq last-line-copy nil)))
 550         (forward-line))
 551       (funcall update-function result)))
 552
 553 (defun vc-hg-dir-status (dir update-function)
 554   (vc-hg-command (current-buffer) 'async dir "status" "-C")
 555   (vc-exec-after
 556    `(vc-hg-after-dir-status (quote ,update-function))))
 557
 558 (defun vc-hg-dir-status-files (dir files default-state update-function)
 559   (apply 'vc-hg-command (current-buffer) 'async dir "status" "-C" files)
 560   (vc-exec-after
 561    `(vc-hg-after-dir-status (quote ,update-function))))
 562
 563 (defun vc-hg-dir-extra-header (name &rest commands)
 564   (concat (propertize name 'face 'font-lock-type-face)
 565           (propertize
 566            (with-temp-buffer
 567              (apply 'vc-hg-command (current-buffer) 0 nil commands)
 568              (buffer-substring-no-properties (point-min) (1- (point-max))))
 569            'face 'font-lock-variable-name-face)))
 570
 571 (defun vc-hg-dir-extra-headers (dir)
 572   "Generate extra status headers for a Mercurial tree."
 573   (let ((default-directory dir))
 574     (concat
 575      (vc-hg-dir-extra-header "Root       : " "root") "\n"
 576      (vc-hg-dir-extra-header "Branch     : " "id" "-b") "\n"
 577      (vc-hg-dir-extra-header "Tags       : " "id" "-t") ; "\n"
 578      ;; these change after each commit
 579      ;; (vc-hg-dir-extra-header "Local num  : " "id" "-n") "\n"
 580      ;; (vc-hg-dir-extra-header "Global id  : " "id" "-i")
 581      )))
 582
 583 (defun vc-hg-log-incoming (buffer remote-location)
 584   (vc-hg-command buffer 1 nil "incoming" "-n" (unless (string= remote-location "")
 585                                                 remote-location)))
 586
 587 (defun vc-hg-log-outgoing (buffer remote-location)
 588   (vc-hg-command buffer 1 nil "outgoing" "-n" (unless (string= remote-location "")
 589                                                 remote-location)))
 590
 591 (declare-function log-view-get-marked "log-view" ())
 592
 593 ;; XXX maybe also add key bindings for these functions.
 594 (defun vc-hg-push ()
 595   (interactive)
 596   (let ((marked-list (log-view-get-marked)))
 597     (if marked-list
 598         (apply #'vc-hg-command
 599                nil 0 nil
 600                "push"
 601                (apply 'nconc
 602                       (mapcar (lambda (arg) (list "-r" arg)) marked-list)))
 603       (error "No log entries selected for push"))))
 604
 605 (defun vc-hg-pull ()
 606   (interactive)
 607   (let ((marked-list (log-view-get-marked)))
 608     (if marked-list
 609         (apply #'vc-hg-command
 610                nil 0 nil
 611                "pull"
 612                (apply 'nconc
 613                       (mapcar (lambda (arg) (list "-r" arg)) marked-list)))
 614       (error "No log entries selected for pull"))))
 615
 616 ;;; Internal functions
 617
 618 (defun vc-hg-command (buffer okstatus file-or-list &rest flags)
 619   "A wrapper around `vc-do-command' for use in vc-hg.el.
 620 The difference to vc-do-command is that this function always invokes `hg',
 621 and that it passes `vc-hg-global-switches' to it before FLAGS."
 622   (apply 'vc-do-command (or buffer "*vc*") okstatus "hg" file-or-list
 623          (if (stringp vc-hg-global-switches)
 624              (cons vc-hg-global-switches flags)
 625            (append vc-hg-global-switches
 626                    flags))))
 627
 628 (defun vc-hg-root (file)
 629   (vc-find-root file ".hg"))
 630
 631 (provide 'vc-hg)
 632
 633 ;; arch-tag: bd094dc5-715a-434f-a331-37b9fb7cd954
 634 ;;; vc-hg.el ends here