lisp/tooltip.el

   1 ;;; tooltip.el --- show tooltip windows
   2
   3 ;; Copyright (C) 1997, 1999-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Gerd Moellmann <gerd@acm.org>
   6 ;; Keywords: help c mouse tools
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (defvar comint-prompt-regexp)
  29
  30 (defgroup tooltip nil
  31   "Customization group for the `tooltip' package."
  32   :group 'help
  33   :group 'gud
  34   :group 'mouse
  35   :group 'tools
  36   :version "21.1"
  37   :tag "Tool Tips")
  38 \f
  39 ;;; Switching tooltips on/off
  40
  41 (define-minor-mode tooltip-mode
  42   "Toggle Tooltip mode.
  43 With a prefix argument ARG, enable Tooltip mode if ARG is positive,
  44 and disable it otherwise.  If called from Lisp, enable the mode
  45 if ARG is omitted or nil.
  46
  47 When this global minor mode is enabled, Emacs displays help
  48 text (e.g. for buttons and menu items that you put the mouse on)
  49 in a pop-up window.
  50
  51 When Tooltip mode is disabled, Emacs displays help text in the
  52 echo area, instead of making a pop-up window."
  53   :global t
  54   ;; Even if we start on a text-only terminal, make this non-nil by
  55   ;; default because we can open a graphical frame later (multi-tty).
  56   :init-value t
  57   :initialize 'custom-initialize-delay
  58   :group 'tooltip
  59   (unless (or (null tooltip-mode) (fboundp 'x-show-tip))
  60     (error "Sorry, tooltips are not yet available on this system"))
  61   (if tooltip-mode
  62       (progn
  63         (add-hook 'pre-command-hook 'tooltip-hide)
  64         (add-hook 'tooltip-functions 'tooltip-help-tips))
  65     (unless (and (boundp 'gud-tooltip-mode) gud-tooltip-mode)
  66       (remove-hook 'pre-command-hook 'tooltip-hide))
  67     (remove-hook 'tooltip-functions 'tooltip-help-tips))
  68   (setq show-help-function
  69         (if tooltip-mode 'tooltip-show-help 'tooltip-show-help-non-mode)))
  70
  71 \f
  72 ;;; Customizable settings
  73
  74 (defcustom tooltip-delay 0.7
  75   "Seconds to wait before displaying a tooltip the first time."
  76   :type 'number
  77   :group 'tooltip)
  78
  79 (defcustom tooltip-short-delay 0.1
  80   "Seconds to wait between subsequent tooltips on different items."
  81   :type 'number
  82   :group 'tooltip)
  83
  84 (defcustom tooltip-recent-seconds 1
  85   "Display tooltips if changing tip items within this many seconds.
  86 Do so after `tooltip-short-delay'."
  87   :type 'number
  88   :group 'tooltip)
  89
  90 (defcustom tooltip-hide-delay 10
  91   "Hide tooltips automatically after this many seconds."
  92   :type 'number
  93   :group 'tooltip)
  94
  95 (defcustom tooltip-x-offset 5
  96   "X offset, in pixels, for the display of tooltips.
  97 The offset is the distance between the X position of the mouse and
  98 the left border of the tooltip window.  It must be chosen so that the
  99 tooltip window doesn't contain the mouse when it pops up, or it may
 100 interfere with clicking where you wish.
 101
 102 If `tooltip-frame-parameters' includes the `left' parameter,
 103 the value of `tooltip-x-offset' is ignored."
 104   :type 'integer
 105   :group 'tooltip)
 106
 107 (defcustom tooltip-y-offset +20
 108   "Y offset, in pixels, for the display of tooltips.
 109 The offset is the distance between the Y position of the mouse and
 110 the top border of the tooltip window.  It must be chosen so that the
 111 tooltip window doesn't contain the mouse when it pops up, or it may
 112 interfere with clicking where you wish.
 113
 114 If `tooltip-frame-parameters' includes the `top' parameter,
 115 the value of `tooltip-y-offset' is ignored."
 116   :type 'integer
 117   :group 'tooltip)
 118
 119 (defcustom tooltip-frame-parameters
 120   '((name . "tooltip")
 121     (internal-border-width . 2)
 122     (border-width . 1))
 123   "Frame parameters used for tooltips.
 124
 125 If `left' or `top' parameters are included, they specify the absolute
 126 position to pop up the tooltip.
 127
 128 Note that font and color parameters are ignored, and the attributes
 129 of the `tooltip' face are used instead."
 130   :type 'sexp
 131   :group 'tooltip)
 132
 133 (defface tooltip
 134   '((((class color))
 135      :background "lightyellow"
 136      :foreground "black"
 137      :inherit variable-pitch)
 138     (t
 139      :inherit variable-pitch))
 140   "Face for tooltips."
 141   :group 'tooltip
 142   :group 'basic-faces)
 143
 144 (defcustom tooltip-use-echo-area nil
 145   "Use the echo area instead of tooltip frames for help and GUD tooltips.
 146 This variable is obsolete; instead of setting it to t, disable
 147 `tooltip-mode' (which has a similar effect)."
 148   :type 'boolean
 149   :group 'tooltip)
 150
 151 (make-obsolete-variable 'tooltip-use-echo-area
 152                         "disable Tooltip mode instead" "24.1")
 153
 154 \f
 155 ;;; Variables that are not customizable.
 156
 157 (define-obsolete-variable-alias 'tooltip-hook 'tooltip-functions "23.1")
 158
 159 (defvar tooltip-functions nil
 160   "Functions to call to display tooltips.
 161 Each function is called with one argument EVENT which is a copy
 162 of the last mouse movement event that occurred.  If one of these
 163 functions displays the tooltip, it should return non-nil and the
 164 rest are not called.")
 165
 166 (defvar tooltip-timeout-id nil
 167   "The id of the timeout started when Emacs becomes idle.")
 168
 169 (defvar tooltip-last-mouse-motion-event nil
 170   "A copy of the last mouse motion event seen.")
 171
 172 (defvar tooltip-hide-time nil
 173   "Time when the last tooltip was hidden.")
 174
 175 (defvar gud-tooltip-mode) ;; Prevent warning.
 176
 177 ;;; Event accessors
 178
 179 (defun tooltip-event-buffer (event)
 180   "Return the buffer over which event EVENT occurred.
 181 This might return nil if the event did not occur over a buffer."
 182   (let ((window (posn-window (event-end event))))
 183     (and window (window-buffer window))))
 184
 185 \f
 186 ;;; Timeout for tooltip display
 187
 188 (defun tooltip-delay ()
 189   "Return the delay in seconds for the next tooltip."
 190   (if (and tooltip-hide-time
 191            (< (- (float-time) tooltip-hide-time) tooltip-recent-seconds))
 192       tooltip-short-delay
 193     tooltip-delay))
 194
 195 (defun tooltip-cancel-delayed-tip ()
 196   "Disable the tooltip timeout."
 197   (when tooltip-timeout-id
 198     (disable-timeout tooltip-timeout-id)
 199     (setq tooltip-timeout-id nil)))
 200
 201 (defun tooltip-start-delayed-tip ()
 202   "Add a one-shot timeout to call function `tooltip-timeout'."
 203   (setq tooltip-timeout-id
 204         (add-timeout (tooltip-delay) 'tooltip-timeout nil)))
 205
 206 (defun tooltip-timeout (_object)
 207   "Function called when timer with id `tooltip-timeout-id' fires."
 208   (run-hook-with-args-until-success 'tooltip-functions
 209                                     tooltip-last-mouse-motion-event))
 210
 211 \f
 212 ;;; Displaying tips
 213
 214 (defun tooltip-set-param (alist key value)
 215   "Change the value of KEY in alist ALIST to VALUE.
 216 If there's no association for KEY in ALIST, add one, otherwise
 217 change the existing association.  Value is the resulting alist."
 218   (let ((param (assq key alist)))
 219     (if (consp param)
 220         (setcdr param value)
 221       (push (cons key value) alist))
 222     alist))
 223
 224 (declare-function x-show-tip "xfns.c"
 225                   (string &optional frame parms timeout dx dy))
 226
 227 (defun tooltip-show (text &optional use-echo-area)
 228   "Show a tooltip window displaying TEXT.
 229
 230 Text larger than `x-max-tooltip-size' is clipped.
 231
 232 If the alist in `tooltip-frame-parameters' includes `left' and `top'
 233 parameters, they determine the x and y position where the tooltip
 234 is displayed.  Otherwise, the tooltip pops at offsets specified by
 235 `tooltip-x-offset' and `tooltip-y-offset' from the current mouse
 236 position.
 237
 238 Optional second arg USE-ECHO-AREA non-nil means to show tooltip
 239 in echo area."
 240   (if use-echo-area
 241       (tooltip-show-help-non-mode text)
 242     (condition-case error
 243         (let ((params (copy-sequence tooltip-frame-parameters))
 244               (fg (face-attribute 'tooltip :foreground))
 245               (bg (face-attribute 'tooltip :background)))
 246           (when (stringp fg)
 247             (setq params (tooltip-set-param params 'foreground-color fg))
 248             (setq params (tooltip-set-param params 'border-color fg)))
 249           (when (stringp bg)
 250             (setq params (tooltip-set-param params 'background-color bg)))
 251           (x-show-tip (propertize text 'face 'tooltip)
 252                       (selected-frame)
 253                       params
 254                       tooltip-hide-delay
 255                       tooltip-x-offset
 256                       tooltip-y-offset))
 257       (error
 258        (message "Error while displaying tooltip: %s" error)
 259        (sit-for 1)
 260        (message "%s" text)))))
 261
 262 (declare-function x-hide-tip "xfns.c" ())
 263
 264 (defun tooltip-hide (&optional _ignored-arg)
 265   "Hide a tooltip, if one is displayed.
 266 Value is non-nil if tooltip was open."
 267   (tooltip-cancel-delayed-tip)
 268   (when (x-hide-tip)
 269     (setq tooltip-hide-time (float-time))))
 270
 271 \f
 272 ;;; Debugger-related functions
 273
 274 (defun tooltip-identifier-from-point (point)
 275   "Extract the identifier at POINT, if any.
 276 Value is nil if no identifier exists at point.  Identifier extraction
 277 is based on the current syntax table."
 278   (save-excursion
 279     (goto-char point)
 280     (let ((start (progn (skip-syntax-backward "w_") (point))))
 281       (unless (looking-at "[0-9]")
 282         (skip-syntax-forward "w_")
 283         (when (> (point) start)
 284           (buffer-substring start (point)))))))
 285
 286 (defmacro tooltip-region-active-p ()
 287   "Value is non-nil if the region should override command actions."
 288   `(use-region-p))
 289
 290 (defun tooltip-expr-to-print (event)
 291   "Return an expression that should be printed for EVENT.
 292 If a region is active and the mouse is inside the region, print
 293 the region.  Otherwise, figure out the identifier around the point
 294 where the mouse is."
 295   (with-current-buffer (tooltip-event-buffer event)
 296     (let ((point (posn-point (event-end event))))
 297       (if (tooltip-region-active-p)
 298           (when (and (<= (region-beginning) point) (<= point (region-end)))
 299             (buffer-substring (region-beginning) (region-end)))
 300         (tooltip-identifier-from-point point)))))
 301
 302 (defun tooltip-process-prompt-regexp (process)
 303   "Return regexp matching the prompt of PROCESS at the end of a string.
 304 The prompt is taken from the value of `comint-prompt-regexp' in
 305 the buffer of PROCESS."
 306   (let ((prompt-regexp (with-current-buffer (process-buffer process)
 307                          comint-prompt-regexp)))
 308     (concat "\n*"
 309             ;; Most start with `^' but the one for `sdb' cannot be easily
 310             ;; stripped.  Code the prompt for `sdb' fixed here.
 311             (if (= (aref prompt-regexp 0) ?^)
 312                 (substring prompt-regexp 1)
 313               "\\*")
 314             "$")))
 315
 316 (defun tooltip-strip-prompt (process output)
 317   "Return OUTPUT with any prompt of PROCESS stripped from its end."
 318   (save-match-data
 319     (if (string-match (tooltip-process-prompt-regexp process) output)
 320         (substring output 0 (match-beginning 0))
 321       output)))
 322
 323 \f
 324 ;;; Tooltip help.
 325
 326 (defvar tooltip-help-message nil
 327   "The last help message received via `show-help-function'.
 328 This is used by `tooltip-show-help' and
 329 `tooltip-show-help-non-mode'.")
 330
 331 (defvar tooltip-previous-message nil
 332   "The previous content of the echo area.")
 333
 334 (defun tooltip-show-help-non-mode (help)
 335   "Function installed as `show-help-function' when Tooltip mode is off.
 336 It is also called if Tooltip mode is on, for text-only displays."
 337   (when (and (not (window-minibuffer-p)) ;Don't overwrite minibuffer contents.
 338              (not cursor-in-echo-area))  ;Don't overwrite a prompt.
 339     (cond
 340      ((stringp help)
 341       (setq help (replace-regexp-in-string "\n" ", " help))
 342       (unless (or tooltip-previous-message
 343                   (string-equal help (current-message))
 344                   (and (stringp tooltip-help-message)
 345                        (string-equal tooltip-help-message
 346                                      (current-message))))
 347         (setq tooltip-previous-message (current-message)))
 348       (setq tooltip-help-message help)
 349       (let ((message-truncate-lines t)
 350             (message-log-max nil))
 351         (message "%s" help)))
 352      ((stringp tooltip-previous-message)
 353       (let ((message-log-max nil))
 354         (message "%s" tooltip-previous-message)
 355         (setq tooltip-previous-message nil)))
 356      (t
 357       (message nil)))))
 358
 359 (defun tooltip-show-help (msg)
 360   "Function installed as `show-help-function'.
 361 MSG is either a help string to display, or nil to cancel the display."
 362   (if (display-graphic-p)
 363       (let ((previous-help tooltip-help-message))
 364         (setq tooltip-help-message msg)
 365         (cond ((null msg)
 366                ;; Cancel display.  This also cancels a delayed tip, if
 367                ;; there is one.
 368                (tooltip-hide))
 369               ((equal previous-help msg)
 370                ;; Same help as before (but possibly the mouse has moved).
 371                ;; Keep what we have.
 372                )
 373               (t
 374                ;; A different help.  Remove a previous tooltip, and
 375                ;; display a new one, with some delay.
 376                (tooltip-hide)
 377                (tooltip-start-delayed-tip))))
 378     ;; On text-only displays, try `tooltip-show-help-non-mode'.
 379     (tooltip-show-help-non-mode msg)))
 380
 381 (defun tooltip-help-tips (_event)
 382   "Hook function to display a help tooltip.
 383 This is installed on the hook `tooltip-functions', which
 384 is run when the timer with id `tooltip-timeout-id' fires.
 385 Value is non-nil if this function handled the tip."
 386   (when (stringp tooltip-help-message)
 387     (tooltip-show tooltip-help-message tooltip-use-echo-area)
 388     t))
 389
 390 (provide 'tooltip)
 391
 392 ;;; tooltip.el ends here